cgit.sxemacs.org Git - gnus/blob - lisp/mm-decode.el

   1 ;;; mm-decode.el --- Functions for decoding MIME things
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   4 ;;   2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 ;; For Emacs <22.2 and XEmacs.
  28 (eval-and-compile
  29   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  30
  31 (require 'mail-parse)
  32 (require 'mm-bodies)
  33 (eval-when-compile (require 'cl)
  34                    (require 'term))
  35
  36 (autoload 'gnus-map-function "gnus-util")
  37 (autoload 'gnus-replace-in-string "gnus-util")
  38 (autoload 'gnus-read-shell-command "gnus-util")
  39
  40 (autoload 'mm-inline-partial "mm-partial")
  41 (autoload 'mm-inline-external-body "mm-extern")
  42 (autoload 'mm-extern-cache-contents "mm-extern")
  43 (autoload 'mm-insert-inline "mm-view")
  44
  45 (defvar gnus-current-window-configuration)
  46
  47 (add-hook 'gnus-exit-gnus-hook 'mm-destroy-postponed-undisplay-list)
  48
  49 (defgroup mime-display ()
  50   "Display of MIME in mail and news articles."
  51   :link '(custom-manual "(emacs-mime)Display Customization")
  52   :version "21.1"
  53   :group 'mail
  54   :group 'news
  55   :group 'multimedia)
  56
  57 (defgroup mime-security ()
  58   "MIME security in mail and news articles."
  59   :link '(custom-manual "(emacs-mime)Display Customization")
  60   :group 'mail
  61   :group 'news
  62   :group 'multimedia)
  63
  64 ;;; Convenience macros.
  65
  66 (defmacro mm-handle-buffer (handle)
  67   `(nth 0 ,handle))
  68 (defmacro mm-handle-type (handle)
  69   `(nth 1 ,handle))
  70 (defsubst mm-handle-media-type (handle)
  71   (if (stringp (car handle))
  72       (car handle)
  73     (car (mm-handle-type handle))))
  74 (defsubst mm-handle-media-supertype (handle)
  75   (car (split-string (mm-handle-media-type handle) "/")))
  76 (defsubst mm-handle-media-subtype (handle)
  77   (cadr (split-string (mm-handle-media-type handle) "/")))
  78 (defmacro mm-handle-encoding (handle)
  79   `(nth 2 ,handle))
  80 (defmacro mm-handle-undisplayer (handle)
  81   `(nth 3 ,handle))
  82 (defmacro mm-handle-set-undisplayer (handle function)
  83   `(setcar (nthcdr 3 ,handle) ,function))
  84 (defmacro mm-handle-disposition (handle)
  85   `(nth 4 ,handle))
  86 (defmacro mm-handle-description (handle)
  87   `(nth 5 ,handle))
  88 (defmacro mm-handle-cache (handle)
  89   `(nth 6 ,handle))
  90 (defmacro mm-handle-set-cache (handle contents)
  91   `(setcar (nthcdr 6 ,handle) ,contents))
  92 (defmacro mm-handle-id (handle)
  93   `(nth 7 ,handle))
  94 (defmacro mm-handle-multipart-original-buffer (handle)
  95   `(get-text-property 0 'buffer (car ,handle)))
  96 (defmacro mm-handle-multipart-from (handle)
  97   `(get-text-property 0 'from (car ,handle)))
  98 (defmacro mm-handle-multipart-ctl-parameter (handle parameter)
  99   `(get-text-property 0 ,parameter (car ,handle)))
 100
 101 (defmacro mm-make-handle (&optional buffer type encoding undisplayer
 102                                     disposition description cache
 103                                     id)
 104   `(list ,buffer ,type ,encoding ,undisplayer
 105          ,disposition ,description ,cache ,id))
 106
 107 (defcustom mm-text-html-renderer
 108   (cond ((fboundp 'libxml-parse-html-region) 'shr)
 109         ((executable-find "w3m") 'gnus-w3m)
 110         ((executable-find "links") 'links)
 111         ((executable-find "lynx") 'lynx)
 112         ((locate-library "w3") 'w3)
 113         ((locate-library "html2text") 'html2text)
 114         (t nil))
 115   "Render of HTML contents.
 116 It is one of defined renderer types, or a rendering function.
 117 The defined renderer types are:
 118 `shr': use Gnus simple HTML renderer;
 119 `gnus-w3m' : use Gnus renderer based on w3m;
 120 `w3m'  : use emacs-w3m;
 121 `w3m-standalone': use w3m;
 122 `links': use links;
 123 `lynx' : use lynx;
 124 `w3'   : use Emacs/W3;
 125 `html2text' : use html2text;
 126 nil    : use external viewer (default web browser)."
 127   :version "24.1"
 128   :type '(choice (const shr)
 129                  (const gnus-w3m)
 130                  (const w3)
 131                  (const w3m :tag "emacs-w3m")
 132                  (const w3m-standalone :tag "standalone w3m" )
 133                  (const links)
 134                  (const lynx)
 135                  (const html2text)
 136                  (const nil :tag "External viewer")
 137                  (function))
 138   :group 'mime-display)
 139
 140 (defcustom mm-inline-text-html-with-images nil
 141   "If non-nil, Gnus will allow retrieving images in HTML contents with
 142 the <img> tags.  It has no effect on Emacs/w3.  See also the
 143 documentation for the `mm-w3m-safe-url-regexp' variable."
 144   :version "22.1"
 145   :type 'boolean
 146   :group 'mime-display)
 147
 148 (defcustom mm-w3m-safe-url-regexp "\\`cid:"
 149   "Regexp matching URLs which are considered to be safe.
 150 Some HTML mails might contain a nasty trick used by spammers, using
 151 the <img> tag which is far more evil than the [Click Here!] button.
 152 It is most likely intended to check whether the ominous spam mail has
 153 reached your eyes or not, in which case the spammer knows for sure
 154 that your email address is valid.  It is done by embedding an
 155 identifier string into a URL that you might automatically retrieve
 156 when displaying the image.  The default value is \"\\\\`cid:\" which only
 157 matches parts embedded to the Multipart/Related type MIME contents and
 158 Gnus will never connect to the spammer's site arbitrarily.  You may
 159 set this variable to nil if you consider all urls to be safe."
 160   :version "22.1"
 161   :type '(choice (regexp :tag "Regexp")
 162                  (const :tag "All URLs are safe" nil))
 163   :group 'mime-display)
 164
 165 (defcustom mm-inline-text-html-with-w3m-keymap t
 166   "If non-nil, use emacs-w3m command keys in the article buffer."
 167   :version "22.1"
 168   :type 'boolean
 169   :group 'mime-display)
 170
 171 (defcustom mm-enable-external t
 172   "Indicate whether external MIME handlers should be used.
 173
 174 If t, all defined external MIME handlers are used.  If nil, files are saved by
 175 `mailcap-save-binary-file'.  If it is the symbol `ask', you are prompted
 176 before the external MIME handler is invoked."
 177   :version "22.1"
 178   :type '(choice (const :tag "Always" t)
 179                  (const :tag "Never" nil)
 180                  (const :tag "Ask" ask))
 181   :group 'mime-display)
 182
 183 (defcustom mm-inline-media-tests
 184   '(("image/p?jpeg"
 185      mm-inline-image
 186      (lambda (handle)
 187        (mm-valid-and-fit-image-p 'jpeg handle)))
 188     ("image/png"
 189      mm-inline-image
 190      (lambda (handle)
 191        (mm-valid-and-fit-image-p 'png handle)))
 192     ("image/gif"
 193      mm-inline-image
 194      (lambda (handle)
 195        (mm-valid-and-fit-image-p 'gif handle)))
 196     ("image/tiff"
 197      mm-inline-image
 198      (lambda (handle)
 199        (mm-valid-and-fit-image-p 'tiff handle)) )
 200     ("image/xbm"
 201      mm-inline-image
 202      (lambda (handle)
 203        (mm-valid-and-fit-image-p 'xbm handle)))
 204     ("image/x-xbitmap"
 205      mm-inline-image
 206      (lambda (handle)
 207        (mm-valid-and-fit-image-p 'xbm handle)))
 208     ("image/xpm"
 209      mm-inline-image
 210      (lambda (handle)
 211        (mm-valid-and-fit-image-p 'xpm handle)))
 212     ("image/x-xpixmap"
 213      mm-inline-image
 214      (lambda (handle)
 215        (mm-valid-and-fit-image-p 'xpm handle)))
 216     ("image/bmp"
 217      mm-inline-image
 218      (lambda (handle)
 219        (mm-valid-and-fit-image-p 'bmp handle)))
 220     ("image/x-portable-bitmap"
 221      mm-inline-image
 222      (lambda (handle)
 223        (mm-valid-and-fit-image-p 'pbm handle)))
 224     ("text/plain" mm-inline-text identity)
 225     ("text/enriched" mm-inline-text identity)
 226     ("text/richtext" mm-inline-text identity)
 227     ("text/x-patch" mm-display-patch-inline
 228      (lambda (handle)
 229        ;; If the diff-mode.el package is installed, the function is
 230        ;; autoloaded.  Checking (locate-library "diff-mode") would be trying
 231        ;; to cater to broken installations.  OTOH checking the function
 232        ;; makes it possible to install another package which provides an
 233        ;; alternative implementation of diff-mode.  --Stef
 234        (fboundp 'diff-mode)))
 235     ;; In case mime.types uses x-diff (as does Debian's mime-support-3.40).
 236     ("text/x-diff" mm-display-patch-inline
 237      (lambda (handle) (fboundp 'diff-mode)))
 238     ("application/emacs-lisp" mm-display-elisp-inline identity)
 239     ("application/x-emacs-lisp" mm-display-elisp-inline identity)
 240     ("text/dns" mm-display-dns-inline identity)
 241     ("text/html"
 242      mm-inline-text-html
 243      (lambda (handle)
 244        mm-text-html-renderer))
 245     ("text/x-vcard"
 246      mm-inline-text-vcard
 247      (lambda (handle)
 248        (or (featurep 'vcard)
 249            (locate-library "vcard"))))
 250     ("message/delivery-status" mm-inline-text identity)
 251     ("message/rfc822" mm-inline-message identity)
 252     ("message/partial" mm-inline-partial identity)
 253     ("message/external-body" mm-inline-external-body identity)
 254     ("text/.*" mm-inline-text identity)
 255     ("audio/wav" mm-inline-audio
 256      (lambda (handle)
 257        (and (or (featurep 'nas-sound) (featurep 'native-sound))
 258             (device-sound-enabled-p))))
 259     ("audio/au"
 260      mm-inline-audio
 261      (lambda (handle)
 262        (and (or (featurep 'nas-sound) (featurep 'native-sound))
 263             (device-sound-enabled-p))))
 264     ("application/pgp-signature" ignore identity)
 265     ("application/x-pkcs7-signature" ignore identity)
 266     ("application/pkcs7-signature" ignore identity)
 267     ("application/x-pkcs7-mime" ignore identity)
 268     ("application/pkcs7-mime" ignore identity)
 269     ("multipart/alternative" ignore identity)
 270     ("multipart/mixed" ignore identity)
 271     ("multipart/related" ignore identity)
 272     ;; Disable audio and image
 273     ("audio/.*" ignore ignore)
 274     ("image/.*" ignore ignore)
 275     ;; Default to displaying as text
 276     (".*" mm-inline-text mm-readable-p))
 277   "Alist of media types/tests saying whether types can be displayed inline."
 278   :type '(repeat (list (regexp :tag "MIME type")
 279                        (function :tag "Display function")
 280                        (function :tag "Display test")))
 281   :group 'mime-display)
 282
 283 (defcustom mm-inlined-types
 284   '("image/.*" "text/.*" "message/delivery-status" "message/rfc822"
 285     "message/partial" "message/external-body" "application/emacs-lisp"
 286     "application/x-emacs-lisp"
 287     "application/pgp-signature" "application/x-pkcs7-signature"
 288     "application/pkcs7-signature" "application/x-pkcs7-mime"
 289     "application/pkcs7-mime"
 290     ;; Mutt still uses this even though it has already been withdrawn.
 291     "application/pgp")
 292   "List of media types that are to be displayed inline.
 293 See also `mm-inline-media-tests', which says how to display a media
 294 type inline."
 295   :type '(repeat regexp)
 296   :group 'mime-display)
 297
 298 (defcustom mm-keep-viewer-alive-types
 299   '("application/postscript" "application/msword" "application/vnd.ms-excel"
 300     "application/pdf" "application/x-dvi")
 301   "List of media types for which the external viewer will not be killed
 302 when selecting a different article."
 303   :version "22.1"
 304   :type '(repeat regexp)
 305   :group 'mime-display)
 306
 307 (defcustom mm-automatic-display
 308   '("text/plain" "text/enriched" "text/richtext" "text/html" "text/x-verbatim"
 309     "text/x-vcard" "image/.*" "message/delivery-status" "multipart/.*"
 310     "message/rfc822" "text/x-patch" "text/dns" "application/pgp-signature"
 311     "application/emacs-lisp" "application/x-emacs-lisp"
 312     "application/x-pkcs7-signature"
 313     "application/pkcs7-signature" "application/x-pkcs7-mime"
 314     "application/pkcs7-mime"
 315     ;; Mutt still uses this even though it has already been withdrawn.
 316     "application/pgp\\'")
 317   "A list of MIME types to be displayed automatically."
 318   :type '(repeat regexp)
 319   :group 'mime-display)
 320
 321 (defcustom mm-attachment-override-types '("text/x-vcard"
 322                                           "application/pkcs7-mime"
 323                                           "application/x-pkcs7-mime"
 324                                           "application/pkcs7-signature"
 325                                           "application/x-pkcs7-signature")
 326   "Types to have \"attachment\" ignored if they can be displayed inline."
 327   :type '(repeat regexp)
 328   :group 'mime-display)
 329
 330 (defcustom mm-inline-override-types nil
 331   "Types to be treated as attachments even if they can be displayed inline."
 332   :type '(repeat regexp)
 333   :group 'mime-display)
 334
 335 (defcustom mm-automatic-external-display nil
 336   "List of MIME type regexps that will be displayed externally automatically."
 337   :type '(repeat regexp)
 338   :group 'mime-display)
 339
 340 (defcustom mm-discouraged-alternatives nil
 341   "List of MIME types that are discouraged when viewing multipart/alternative.
 342 Viewing agents are supposed to view the last possible part of a message,
 343 as that is supposed to be the richest.  However, users may prefer other
 344 types instead, and this list says what types are most unwanted.  If,
 345 for instance, text/html parts are very unwanted, and text/richtext are
 346 somewhat unwanted, then the value of this variable should be set
 347 to:
 348
 349  (\"text/html\" \"text/richtext\")
 350
 351 Adding \"image/.*\" might also be useful.  Spammers use it as the
 352 prefered part of multipart/alternative messages.  See also
 353 `gnus-buttonized-mime-types', to which adding \"multipart/alternative\"
 354 enables you to choose manually one of two types those mails include."
 355   :type '(repeat regexp) ;; See `mm-preferred-alternative-precedence'.
 356   :group 'mime-display)
 357
 358 (defcustom mm-tmp-directory
 359   (if (fboundp 'temp-directory)
 360       (temp-directory)
 361     (if (boundp 'temporary-file-directory)
 362         temporary-file-directory
 363       "/tmp/"))
 364   "Where mm will store its temporary files."
 365   :type 'directory
 366   :group 'mime-display)
 367
 368 (defcustom mm-inline-large-images nil
 369   "If t, then all images fit in the buffer.
 370 If 'resize, try to resize the images so they fit."
 371   :type '(radio
 372           (const :tag "Inline large images as they are." t)
 373           (const :tag "Resize large images." resize)
 374           (const :tag "Do not inline large images." nil))
 375   :group 'mime-display)
 376
 377 (defcustom mm-file-name-rewrite-functions
 378   '(mm-file-name-delete-control mm-file-name-delete-gotchas)
 379   "List of functions used for rewriting file names of MIME parts.
 380 Each function takes a file name as input and returns a file name.
 381
 382 Ready-made functions include `mm-file-name-delete-control',
 383 `mm-file-name-delete-gotchas' (you should not remove these two
 384 functions), `mm-file-name-delete-whitespace',
 385 `mm-file-name-trim-whitespace', `mm-file-name-collapse-whitespace',
 386 `mm-file-name-replace-whitespace', `capitalize', `downcase',
 387 `upcase', and `upcase-initials'."
 388   :type '(list (set :inline t
 389                     (const mm-file-name-delete-control)
 390                     (const mm-file-name-delete-gotchas)
 391                     (const mm-file-name-delete-whitespace)
 392                     (const mm-file-name-trim-whitespace)
 393                     (const mm-file-name-collapse-whitespace)
 394                     (const mm-file-name-replace-whitespace)
 395                     (const capitalize)
 396                     (const downcase)
 397                     (const upcase)
 398                     (const upcase-initials)
 399                (repeat :inline t
 400                        :tag "Function"
 401                        function)))
 402   :version "23.1" ;; No Gnus
 403   :group 'mime-display)
 404
 405
 406 (defvar mm-path-name-rewrite-functions nil
 407   "*List of functions for rewriting the full file names of MIME parts.
 408 This is used when viewing parts externally, and is meant for
 409 transforming the absolute name so that non-compliant programs can find
 410 the file where it's saved.
 411
 412 Each function takes a file name as input and returns a file name.")
 413
 414 (defvar mm-file-name-replace-whitespace nil
 415   "String used for replacing whitespace characters; default is `\"_\"'.")
 416
 417 (defcustom mm-default-directory nil
 418   "The default directory where mm will save files.
 419 If not set, `default-directory' will be used."
 420   :type '(choice directory (const :tag "Default" nil))
 421   :group 'mime-display)
 422
 423 (defcustom mm-attachment-file-modes 384
 424   "Set the mode bits of saved attachments to this integer."
 425   :version "22.1"
 426   :type 'integer
 427   :group 'mime-display)
 428
 429 (defcustom mm-external-terminal-program "xterm"
 430   "The program to start an external terminal."
 431   :version "22.1"
 432   :type 'string
 433   :group 'mime-display)
 434
 435 ;;; Internal variables.
 436
 437 (defvar mm-last-shell-command "")
 438 (defvar mm-content-id-alist nil)
 439 (defvar mm-postponed-undisplay-list nil)
 440
 441 ;; According to RFC2046, in particular, in a digest, the default
 442 ;; Content-Type value for a body part is changed from "text/plain" to
 443 ;; "message/rfc822".
 444 (defvar mm-dissect-default-type "text/plain")
 445
 446 (autoload 'mml2015-verify "mml2015")
 447 (autoload 'mml2015-verify-test "mml2015")
 448 (autoload 'mml-smime-verify "mml-smime")
 449 (autoload 'mml-smime-verify-test "mml-smime")
 450
 451 (defvar mm-verify-function-alist
 452   '(("application/pgp-signature" mml2015-verify "PGP" mml2015-verify-test)
 453     ("application/x-gnus-pgp-signature" mm-uu-pgp-signed-extract-1 "PGP"
 454      mm-uu-pgp-signed-test)
 455     ("application/pkcs7-signature" mml-smime-verify "S/MIME"
 456      mml-smime-verify-test)
 457     ("application/x-pkcs7-signature" mml-smime-verify "S/MIME"
 458      mml-smime-verify-test)))
 459
 460 (defcustom mm-verify-option 'never
 461   "Option of verifying signed parts.
 462 `never', not verify; `always', always verify;
 463 `known', only verify known protocols.  Otherwise, ask user.
 464
 465 When set to `always' or `known', you should add
 466 \"multipart/signed\" to `gnus-buttonized-mime-types' to see
 467 result of the verification."
 468   :version "22.1"
 469   :type '(choice (item always)
 470                  (item never)
 471                  (item :tag "only known protocols" known)
 472                  (item :tag "ask" nil))
 473   :group 'mime-security)
 474
 475 (autoload 'mml2015-decrypt "mml2015")
 476 (autoload 'mml2015-decrypt-test "mml2015")
 477
 478 (defvar mm-decrypt-function-alist
 479   '(("application/pgp-encrypted" mml2015-decrypt "PGP" mml2015-decrypt-test)
 480     ("application/x-gnus-pgp-encrypted" mm-uu-pgp-encrypted-extract-1 "PGP"
 481      mm-uu-pgp-encrypted-test)))
 482
 483 (defcustom mm-decrypt-option nil
 484   "Option of decrypting encrypted parts.
 485 `never', not decrypt; `always', always decrypt;
 486 `known', only decrypt known protocols.  Otherwise, ask user."
 487   :version "22.1"
 488   :type '(choice (item always)
 489                  (item never)
 490                  (item :tag "only known protocols" known)
 491                  (item :tag "ask" nil))
 492   :group 'mime-security)
 493
 494 (defvar mm-viewer-completion-map
 495   (let ((map (make-sparse-keymap 'mm-viewer-completion-map)))
 496     (set-keymap-parent map minibuffer-local-completion-map)
 497     ;; Should we bind other key to minibuffer-complete-word?
 498     (define-key map " " 'self-insert-command)
 499     map)
 500   "Keymap for input viewer with completion.")
 501
 502 (defvar mm-viewer-completion-map
 503   (let ((map (make-sparse-keymap 'mm-viewer-completion-map)))
 504     (set-keymap-parent map minibuffer-local-completion-map)
 505     ;; Should we bind other key to minibuffer-complete-word?
 506     (define-key map " " 'self-insert-command)
 507     map)
 508   "Keymap for input viewer with completion.")
 509
 510 ;;; The functions.
 511
 512 (defun mm-alist-to-plist (alist)
 513   "Convert association list ALIST into the equivalent property-list form.
 514 The plist is returned.  This converts from
 515
 516 \((a . 1) (b . 2) (c . 3))
 517
 518 into
 519
 520 \(a 1 b 2 c 3)
 521
 522 The original alist is not modified.  See also `destructive-alist-to-plist'."
 523   (let (plist)
 524     (while alist
 525       (let ((el (car alist)))
 526         (setq plist (cons (cdr el) (cons (car el) plist))))
 527       (setq alist (cdr alist)))
 528     (nreverse plist)))
 529
 530 (defun mm-keep-viewer-alive-p (handle)
 531   "Say whether external viewer for HANDLE should stay alive."
 532   (let ((types mm-keep-viewer-alive-types)
 533         (type (mm-handle-media-type handle))
 534         ty)
 535     (catch 'found
 536       (while (setq ty (pop types))
 537         (when (string-match ty type)
 538           (throw 'found t))))))
 539
 540 (defun mm-handle-set-external-undisplayer (handle function)
 541   "Set the undisplayer for HANDLE to FUNCTION.
 542 Postpone undisplaying of viewers for types in
 543 `mm-keep-viewer-alive-types'."
 544   (if (mm-keep-viewer-alive-p handle)
 545       (let ((new-handle (copy-sequence handle)))
 546         (mm-handle-set-undisplayer new-handle function)
 547         (mm-handle-set-undisplayer handle nil)
 548         (push new-handle mm-postponed-undisplay-list))
 549     (mm-handle-set-undisplayer handle function)))
 550
 551 (defun mm-destroy-postponed-undisplay-list ()
 552   (when mm-postponed-undisplay-list
 553     (message "Destroying external MIME viewers")
 554     (mm-destroy-parts mm-postponed-undisplay-list)))
 555
 556 (autoload 'message-fetch-field "message")
 557
 558 (defun mm-dissect-buffer (&optional no-strict-mime loose-mime from)
 559   "Dissect the current buffer and return a list of MIME handles."
 560   (save-excursion
 561     (let (ct ctl type subtype cte cd description id result)
 562       (save-restriction
 563         (mail-narrow-to-head)
 564         (when (or no-strict-mime
 565                   loose-mime
 566                   (mail-fetch-field "mime-version"))
 567           (setq ct (mail-fetch-field "content-type")
 568                 ctl (and ct (mail-header-parse-content-type ct))
 569                 cte (mail-fetch-field "content-transfer-encoding")
 570                 cd (mail-fetch-field "content-disposition")
 571                 ;; Newlines in description should be stripped so as
 572                 ;; not to break the MIME tag into two or more lines.
 573                 description (message-fetch-field "content-description")
 574                 id (mail-fetch-field "content-id"))
 575           (unless from
 576             (setq from (mail-fetch-field "from")))
 577           ;; FIXME: In some circumstances, this code is running within
 578           ;; an unibyte macro.  mail-extract-address-components
 579           ;; creates unibyte buffers. This `if', though not a perfect
 580           ;; solution, avoids most of them.
 581           (if from
 582               (setq from (cadr (mail-extract-address-components from))))
 583           (if description
 584               (setq description (mail-decode-encoded-word-string
 585                                  description)))))
 586       (if (or (not ctl)
 587               (not (string-match "/" (car ctl))))
 588           (mm-dissect-singlepart
 589            (list mm-dissect-default-type)
 590            (and cte (intern (downcase (mail-header-strip cte))))
 591            no-strict-mime
 592            (and cd (mail-header-parse-content-disposition cd))
 593            description)
 594         (setq type (split-string (car ctl) "/"))
 595         (setq subtype (cadr type)
 596               type (car type))
 597         (setq
 598          result
 599          (cond
 600           ((equal type "multipart")
 601            (let ((mm-dissect-default-type (if (equal subtype "digest")
 602                                               "message/rfc822"
 603                                             "text/plain"))
 604                  (start (cdr (assq 'start (cdr ctl)))))
 605              (add-text-properties 0 (length (car ctl))
 606                                   (mm-alist-to-plist (cdr ctl)) (car ctl))
 607
 608              ;; what really needs to be done here is a way to link a
 609              ;; MIME handle back to it's parent MIME handle (in a multilevel
 610              ;; MIME article).  That would probably require changing
 611              ;; the mm-handle API so we simply store the multipart buffer
 612              ;; name as a text property of the "multipart/whatever" string.
 613              (add-text-properties 0 (length (car ctl))
 614                                   (list 'buffer (mm-copy-to-buffer)
 615                                         'from from
 616                                         'start start)
 617                                   (car ctl))
 618              (cons (car ctl) (mm-dissect-multipart ctl from))))
 619           (t
 620            (mm-possibly-verify-or-decrypt
 621             (mm-dissect-singlepart
 622              ctl
 623              (and cte (intern (downcase (mail-header-strip cte))))
 624              no-strict-mime
 625              (and cd (mail-header-parse-content-disposition cd))
 626              description id)
 627             ctl))))
 628         (when id
 629           (when (string-match " *<\\(.*\\)> *" id)
 630             (setq id (match-string 1 id)))
 631           (push (cons id result) mm-content-id-alist))
 632         result))))
 633
 634 (defun mm-dissect-singlepart (ctl cte &optional force cdl description id)
 635   (when (or force
 636             (if (equal "text/plain" (car ctl))
 637                 (assoc 'format ctl)
 638               t))
 639     (mm-make-handle
 640      (mm-copy-to-buffer) ctl cte nil cdl description nil id)))
 641
 642 (defun mm-dissect-multipart (ctl from)
 643   (goto-char (point-min))
 644   (let* ((boundary (concat "\n--" (mail-content-type-get ctl 'boundary)))
 645          (close-delimiter (concat (regexp-quote boundary) "--[ \t]*$"))
 646          start parts
 647          (end (save-excursion
 648                 (goto-char (point-max))
 649                 (if (re-search-backward close-delimiter nil t)
 650                     (match-beginning 0)
 651                   (point-max)))))
 652     (setq boundary (concat (regexp-quote boundary) "[ \t]*$"))
 653     (while (and (< (point) end) (re-search-forward boundary end t))
 654       (goto-char (match-beginning 0))
 655       (when start
 656         (save-excursion
 657           (save-restriction
 658             (narrow-to-region start (point))
 659             (setq parts (nconc (list (mm-dissect-buffer t nil from)) parts)))))
 660       (end-of-line 2)
 661       (or (looking-at boundary)
 662           (forward-line 1))
 663       (setq start (point)))
 664     (when (and start (< start end))
 665       (save-excursion
 666         (save-restriction
 667           (narrow-to-region start end)
 668           (setq parts (nconc (list (mm-dissect-buffer t nil from)) parts)))))
 669     (mm-possibly-verify-or-decrypt (nreverse parts) ctl)))
 670
 671 (defun mm-copy-to-buffer ()
 672   "Copy the contents of the current buffer to a fresh buffer."
 673   (let ((obuf (current-buffer))
 674         (mb (mm-multibyte-p))
 675         beg)
 676     (goto-char (point-min))
 677     (search-forward-regexp "^\n" nil t)
 678     (setq beg (point))
 679     (with-current-buffer
 680           (generate-new-buffer " *mm*")
 681       ;; Preserve the data's unibyteness (for url-insert-file-contents).
 682       (mm-set-buffer-multibyte mb)
 683       (insert-buffer-substring obuf beg)
 684       (current-buffer))))
 685
 686 (defun mm-display-parts (handle &optional no-default)
 687   (if (stringp (car handle))
 688       (mapcar 'mm-display-parts (cdr handle))
 689     (if (bufferp (car handle))
 690         (save-restriction
 691           (narrow-to-region (point) (point))
 692           (mm-display-part handle)
 693           (goto-char (point-max)))
 694       (mapcar 'mm-display-parts handle))))
 695
 696 (autoload 'mailcap-parse-mailcaps "mailcap")
 697 (autoload 'mailcap-mime-info "mailcap")
 698
 699 (defun mm-display-part (handle &optional no-default force)
 700   "Display the MIME part represented by HANDLE.
 701 Returns nil if the part is removed; inline if displayed inline;
 702 external if displayed external."
 703   (save-excursion
 704     (mailcap-parse-mailcaps)
 705     (if (and (not force)
 706              (mm-handle-displayed-p handle))
 707         (mm-remove-part handle)
 708       (let* ((ehandle (if (equal (mm-handle-media-type handle)
 709                                  "message/external-body")
 710                           (progn
 711                             (unless (mm-handle-cache handle)
 712                               (mm-extern-cache-contents handle))
 713                             (mm-handle-cache handle))
 714                         handle))
 715              (type (mm-handle-media-type ehandle))
 716              (method (mailcap-mime-info type))
 717              (filename (or (mail-content-type-get
 718                             (mm-handle-disposition handle) 'filename)
 719                            (mail-content-type-get
 720                             (mm-handle-type handle) 'name)
 721                            "<file>"))
 722              (external mm-enable-external))
 723         (if (and (mm-inlinable-p ehandle)
 724                  (mm-inlined-p ehandle))
 725             (progn
 726               (forward-line 1)
 727               (mm-display-inline handle)
 728               'inline)
 729           (when (or method
 730                     (not no-default))
 731             (if (and (not method)
 732                      (equal "text" (car (split-string type "/"))))
 733                 (progn
 734                   (forward-line 1)
 735                   (mm-insert-inline handle (mm-get-part handle))
 736                   'inline)
 737               (setq external
 738                     (and method ;; If nil, we always use "save".
 739                        (stringp method) ;; 'mailcap-save-binary-file
 740                        (or (eq mm-enable-external t)
 741                            (and (eq mm-enable-external 'ask)
 742                                 (y-or-n-p
 743                                  (concat
 744                                   "Display part (" type
 745                                   ") using external program"
 746                                   ;; Can non-string method ever happen?
 747                                   (if (stringp method)
 748                                       (concat
 749                                        " \"" (format method filename) "\"")
 750                                     "")
 751                                     "? "))))))
 752               (if external
 753                   (mm-display-external
 754                    handle (or method 'mailcap-save-binary-file))
 755                 (mm-display-external
 756                  handle 'mailcap-save-binary-file)))))))))
 757
 758 (declare-function gnus-configure-windows "gnus-win" (setting &optional force))
 759 (defvar mailcap-mime-extensions)        ; mailcap-mime-info autoloads
 760
 761 (defun mm-display-external (handle method)
 762   "Display HANDLE using METHOD."
 763   (let ((outbuf (current-buffer)))
 764     (mm-with-unibyte-buffer
 765       (if (functionp method)
 766           (let ((cur (current-buffer)))
 767             (if (eq method 'mailcap-save-binary-file)
 768                 (progn
 769                   (set-buffer (generate-new-buffer " *mm*"))
 770                   (setq method nil))
 771               (mm-insert-part handle)
 772               (mm-add-meta-html-tag handle)
 773               (let ((win (get-buffer-window cur t)))
 774                 (when win
 775                   (select-window win)))
 776               (switch-to-buffer (generate-new-buffer " *mm*")))
 777             (buffer-disable-undo)
 778             (mm-set-buffer-file-coding-system mm-binary-coding-system)
 779             (insert-buffer-substring cur)
 780             (goto-char (point-min))
 781             (when method
 782               (message "Viewing with %s" method))
 783             (let ((mm (current-buffer))
 784                   (non-viewer (assq 'non-viewer
 785                                     (mailcap-mime-info
 786                                      (mm-handle-media-type handle) t))))
 787               (unwind-protect
 788                   (if method
 789                       (funcall method)
 790                     (mm-save-part handle))
 791                 (when (and (not non-viewer)
 792                            method)
 793                   (mm-handle-set-undisplayer handle mm)))))
 794         ;; The function is a string to be executed.
 795         (mm-insert-part handle)
 796         (mm-add-meta-html-tag handle)
 797         (let* ((dir (mm-make-temp-file
 798                      (expand-file-name "emm." mm-tmp-directory) 'dir))
 799                (filename (or
 800                           (mail-content-type-get
 801                            (mm-handle-disposition handle) 'filename)
 802                           (mail-content-type-get
 803                            (mm-handle-type handle) 'name)))
 804                (mime-info (mailcap-mime-info
 805                            (mm-handle-media-type handle) t))
 806                (needsterm (or (assoc "needsterm" mime-info)
 807                               (assoc "needsterminal" mime-info)))
 808                (copiousoutput (assoc "copiousoutput" mime-info))
 809                file buffer)
 810           ;; We create a private sub-directory where we store our files.
 811           (set-file-modes dir #o700)
 812           (if filename
 813               (setq file (expand-file-name
 814                           (gnus-map-function mm-file-name-rewrite-functions
 815                                              (file-name-nondirectory filename))
 816                           dir))
 817             ;; Use nametemplate (defined in RFC1524) if it is specified
 818             ;; in mailcap.
 819             (let ((suffix (cdr (assoc "nametemplate" mime-info))))
 820               (if (and suffix
 821                        (string-match "\\`%s\\(\\..+\\)\\'" suffix))
 822                   (setq suffix (match-string 1 suffix))
 823                 ;; Otherwise, use a suffix according to
 824                 ;; `mailcap-mime-extensions'.
 825                 (setq suffix (car (rassoc (mm-handle-media-type handle)
 826                                           mailcap-mime-extensions))))
 827               (setq file (mm-make-temp-file (expand-file-name "mm." dir)
 828                                             nil suffix))))
 829           (let ((coding-system-for-write mm-binary-coding-system))
 830             (write-region (point-min) (point-max) file nil 'nomesg))
 831           ;; The file is deleted after the viewer exists.  If the users edits
 832           ;; the file, changes will be lost.  Set file to read-only to make it
 833           ;; clear.
 834           (set-file-modes file #o400)
 835           (message "Viewing with %s" method)
 836           (cond
 837            (needsterm
 838             (let ((command (mm-mailcap-command
 839                             method file (mm-handle-type handle))))
 840               (unwind-protect
 841                   (if window-system
 842                       (start-process "*display*" nil
 843                                      mm-external-terminal-program
 844                                      "-e" shell-file-name
 845                                      shell-command-switch command)
 846                     (require 'term)
 847                     (require 'gnus-win)
 848                     (set-buffer
 849                      (setq buffer
 850                            (make-term "display"
 851                                       shell-file-name
 852                                       nil
 853                                       shell-command-switch command)))
 854                     (term-mode)
 855                     (term-char-mode)
 856                     (set-process-sentinel
 857                      (get-buffer-process buffer)
 858                      `(lambda (process state)
 859                         (if (eq 'exit (process-status process))
 860                             (gnus-configure-windows
 861                              ',gnus-current-window-configuration))))
 862                     (gnus-configure-windows 'display-term))
 863                 (mm-handle-set-external-undisplayer handle (cons file buffer)))
 864               (message "Displaying %s..." command))
 865             'external)
 866            (copiousoutput
 867             (with-current-buffer outbuf
 868               (forward-line 1)
 869               (mm-insert-inline
 870                handle
 871                (unwind-protect
 872                    (progn
 873                      (call-process shell-file-name nil
 874                                    (setq buffer
 875                                          (generate-new-buffer " *mm*"))
 876                                    nil
 877                                    shell-command-switch
 878                                    (mm-mailcap-command
 879                                     method file (mm-handle-type handle)))
 880                      (if (buffer-live-p buffer)
 881                          (with-current-buffer buffer
 882                            (buffer-string))))
 883                  (progn
 884                    (ignore-errors (delete-file file))
 885                    (ignore-errors (delete-directory
 886                                    (file-name-directory file)))
 887                    (ignore-errors (kill-buffer buffer))))))
 888             'inline)
 889            (t
 890             ;; Deleting the temp file should be postponed for some wrappers,
 891             ;; shell scripts, and so on, which might exit right after having
 892             ;; started a viewer command as a background job.
 893             (let ((command (mm-mailcap-command
 894                             method file (mm-handle-type handle))))
 895               (unwind-protect
 896                   (progn
 897                     (start-process "*display*"
 898                                    (setq buffer
 899                                          (generate-new-buffer " *mm*"))
 900                                    shell-file-name
 901                                    shell-command-switch command)
 902                     (set-process-sentinel
 903                      (get-buffer-process buffer)
 904                      (lexical-let ;; Don't use `let'.
 905                          ;; Function used to remove temp file and directory.
 906                          ((fn `(lambda nil
 907                                  ;; Don't use `ignore-errors'.
 908                                  (condition-case nil
 909                                      (delete-file ,file)
 910                                    (error))
 911                                  (condition-case nil
 912                                      (delete-directory
 913                                       ,(file-name-directory file))
 914                                    (error))))
 915                           ;; Form uses to kill the process buffer and
 916                           ;; remove the undisplayer.
 917                           (fm `(progn
 918                                  (kill-buffer ,buffer)
 919                                  ,(macroexpand
 920                                    (list 'mm-handle-set-undisplayer
 921                                          (list 'quote handle)
 922                                          nil))))
 923                           ;; Message to be issued when the process exits.
 924                           (done (format "Displaying %s...done" command))
 925                           ;; In particular, the timer object (which is
 926                           ;; a vector in Emacs but is a list in XEmacs)
 927                           ;; requires that it is lexically scoped.
 928                           (timer (run-at-time 2.0 nil 'ignore)))
 929                        (if (featurep 'xemacs)
 930                            (lambda (process state)
 931                              (when (eq 'exit (process-status process))
 932                                (if (memq timer itimer-list)
 933                                    (set-itimer-function timer fn)
 934                                  (funcall fn))
 935                                (ignore-errors (eval fm))
 936                                (message "%s" done)))
 937                          (lambda (process state)
 938                            (when (eq 'exit (process-status process))
 939                              (if (memq timer timer-list)
 940                                  (timer-set-function timer fn)
 941                                (funcall fn))
 942                              (ignore-errors (eval fm))
 943                              (message "%s" done)))))))
 944                 (mm-handle-set-external-undisplayer
 945                  handle (cons file buffer)))
 946               (message "Displaying %s..." command))
 947             'external)))))))
 948
 949 (defun mm-mailcap-command (method file type-list)
 950   (let ((ctl (cdr type-list))
 951         (beg 0)
 952         (uses-stdin t)
 953         out sub total)
 954     (while (string-match "%{\\([^}]+\\)}\\|'%s'\\|\"%s\"\\|%s\\|%t\\|%%"
 955                          method beg)
 956       (push (substring method beg (match-beginning 0)) out)
 957       (setq beg (match-end 0)
 958             total (match-string 0 method)
 959             sub (match-string 1 method))
 960       (cond
 961        ((string= total "%%")
 962         (push "%" out))
 963        ((or (string= total "%s")
 964             ;; We do our own quoting.
 965             (string= total "'%s'")
 966             (string= total "\"%s\""))
 967         (setq uses-stdin nil)
 968         (push (shell-quote-argument
 969                (gnus-map-function mm-path-name-rewrite-functions file)) out))
 970        ((string= total "%t")
 971         (push (shell-quote-argument (car type-list)) out))
 972        (t
 973         (push (shell-quote-argument (or (cdr (assq (intern sub) ctl)) "")) out))))
 974     (push (substring method beg (length method)) out)
 975     (when uses-stdin
 976       (push "<" out)
 977       (push (shell-quote-argument
 978              (gnus-map-function mm-path-name-rewrite-functions file))
 979             out))
 980     (mapconcat 'identity (nreverse out) "")))
 981
 982 (defun mm-remove-parts (handles)
 983   "Remove the displayed MIME parts represented by HANDLES."
 984   (if (and (listp handles)
 985            (bufferp (car handles)))
 986       (mm-remove-part handles)
 987     (let (handle)
 988       (while (setq handle (pop handles))
 989         (cond
 990          ((stringp handle)
 991           (when (buffer-live-p (get-text-property 0 'buffer handle))
 992             (kill-buffer (get-text-property 0 'buffer handle))))
 993          ((and (listp handle)
 994                (stringp (car handle)))
 995           (mm-remove-parts (cdr handle)))
 996          (t
 997           (mm-remove-part handle)))))))
 998
 999 (defun mm-destroy-parts (handles)
1000   "Remove the displayed MIME parts represented by HANDLES."
1001   (if (and (listp handles)
1002            (bufferp (car handles)))
1003       (mm-destroy-part handles)
1004     (let (handle)
1005       (while (setq handle (pop handles))
1006         (cond
1007          ((stringp handle)
1008           (when (buffer-live-p (get-text-property 0 'buffer handle))
1009             (kill-buffer (get-text-property 0 'buffer handle))))
1010          ((and (listp handle)
1011                (stringp (car handle)))
1012           (mm-destroy-parts handle))
1013          (t
1014           (mm-destroy-part handle)))))))
1015
1016 (defun mm-remove-part (handle)
1017   "Remove the displayed MIME part represented by HANDLE."
1018   (when (listp handle)
1019     (let ((object (mm-handle-undisplayer handle)))
1020       (ignore-errors
1021         (cond
1022          ;; Internally displayed part.
1023          ((mm-annotationp object)
1024           (if (featurep 'xemacs)
1025               (delete-annotation object)))
1026          ((or (functionp object)
1027               (and (listp object)
1028                    (eq (car object) 'lambda)))
1029           (funcall object))
1030          ;; Externally displayed part.
1031          ((consp object)
1032           (condition-case ()
1033               (while (get-buffer-process (cdr object))
1034                 (interrupt-process (get-buffer-process (cdr object)))
1035                 (message "Waiting for external displayer to die...")
1036                 (sit-for 1))
1037             (quit)
1038             (error))
1039           (ignore-errors (and (cdr object) (kill-buffer (cdr object))))
1040           (message "Waiting for external displayer to die...done")
1041           (ignore-errors (delete-file (car object)))
1042           (ignore-errors (delete-directory (file-name-directory
1043                                             (car object)))))
1044          ((bufferp object)
1045           (when (buffer-live-p object)
1046             (kill-buffer object)))))
1047       (mm-handle-set-undisplayer handle nil))))
1048
1049 (defun mm-display-inline (handle)
1050   (let* ((type (mm-handle-media-type handle))
1051          (function (cadr (mm-assoc-string-match mm-inline-media-tests type))))
1052     (funcall function handle)
1053     (goto-char (point-min))))
1054
1055 (defun mm-assoc-string-match (alist type)
1056   (dolist (elem alist)
1057     (when (string-match (car elem) type)
1058       (return elem))))
1059
1060 (defun mm-automatic-display-p (handle)
1061   "Say whether the user wants HANDLE to be displayed automatically."
1062   (let ((methods mm-automatic-display)
1063         (type (mm-handle-media-type handle))
1064         method result)
1065     (while (setq method (pop methods))
1066       (when (and (not (mm-inline-override-p handle))
1067                  (string-match method type))
1068         (setq result t
1069               methods nil)))
1070     result))
1071
1072 (defun mm-inlinable-p (handle &optional type)
1073   "Say whether HANDLE can be displayed inline.
1074 TYPE is the mime-type of the object; it defaults to the one given
1075 in HANDLE."
1076   (unless type (setq type (mm-handle-media-type handle)))
1077   (let ((alist mm-inline-media-tests)
1078         test)
1079     (while alist
1080       (when (string-match (caar alist) type)
1081         (setq test (caddar alist)
1082               alist nil)
1083         (setq test (funcall test handle)))
1084       (pop alist))
1085     test))
1086
1087 (defun mm-inlined-p (handle)
1088   "Say whether the user wants HANDLE to be displayed inline."
1089   (let ((methods mm-inlined-types)
1090         (type (mm-handle-media-type handle))
1091         method result)
1092     (while (setq method (pop methods))
1093       (when (and (not (mm-inline-override-p handle))
1094                  (string-match method type))
1095         (setq result t
1096               methods nil)))
1097     result))
1098
1099 (defun mm-attachment-override-p (handle)
1100   "Say whether HANDLE should have attachment behavior overridden."
1101   (let ((types mm-attachment-override-types)
1102         (type (mm-handle-media-type handle))
1103         ty)
1104     (catch 'found
1105       (while (setq ty (pop types))
1106         (when (and (string-match ty type)
1107                    (mm-inlinable-p handle))
1108           (throw 'found t))))))
1109
1110 (defun mm-inline-override-p (handle)
1111   "Say whether HANDLE should have inline behavior overridden."
1112   (let ((types mm-inline-override-types)
1113         (type (mm-handle-media-type handle))
1114         ty)
1115     (catch 'found
1116       (while (setq ty (pop types))
1117         (when (string-match ty type)
1118           (throw 'found t))))))
1119
1120 (defun mm-automatic-external-display-p (type)
1121   "Return the user-defined method for TYPE."
1122   (let ((methods mm-automatic-external-display)
1123         method result)
1124     (while (setq method (pop methods))
1125       (when (string-match method type)
1126         (setq result t
1127               methods nil)))
1128     result))
1129
1130 (defun mm-destroy-part (handle)
1131   "Destroy the data structures connected to HANDLE."
1132   (when (listp handle)
1133     (mm-remove-part handle)
1134     (when (buffer-live-p (mm-handle-buffer handle))
1135       (kill-buffer (mm-handle-buffer handle)))))
1136
1137 (defun mm-handle-displayed-p (handle)
1138   "Say whether HANDLE is displayed or not."
1139   (mm-handle-undisplayer handle))
1140
1141 ;;;
1142 ;;; Functions for outputting parts
1143 ;;;
1144
1145 (defmacro mm-with-part (handle &rest forms)
1146   "Run FORMS in the temp buffer containing the contents of HANDLE."
1147   ;; The handle-buffer's content is a sequence of bytes, not a sequence of
1148   ;; chars, so the buffer should be unibyte.  It may happen that the
1149   ;; handle-buffer is multibyte for some reason, in which case now is a good
1150   ;; time to adjust it, since we know at this point that it should
1151   ;; be unibyte.
1152   `(let* ((handle ,handle))
1153      (when (and (mm-handle-buffer handle)
1154                 (buffer-name (mm-handle-buffer handle)))
1155        (with-temp-buffer
1156          (mm-disable-multibyte)
1157          (insert-buffer-substring (mm-handle-buffer handle))
1158          (mm-decode-content-transfer-encoding
1159           (mm-handle-encoding handle)
1160           (mm-handle-media-type handle))
1161          ,@forms))))
1162 (put 'mm-with-part 'lisp-indent-function 1)
1163 (put 'mm-with-part 'edebug-form-spec '(body))
1164
1165 (defun mm-get-part (handle &optional no-cache)
1166   "Return the contents of HANDLE as a string.
1167 If NO-CACHE is non-nil, cached contents of a message/external-body part
1168 are ignored."
1169   (if (and (not no-cache)
1170            (equal (mm-handle-media-type handle) "message/external-body"))
1171       (progn
1172         (unless (mm-handle-cache handle)
1173           (mm-extern-cache-contents handle))
1174         (with-current-buffer (mm-handle-buffer (mm-handle-cache handle))
1175           (buffer-string)))
1176     (mm-with-part handle
1177       (buffer-string))))
1178
1179 (defun mm-insert-part (handle &optional no-cache)
1180   "Insert the contents of HANDLE in the current buffer.
1181 If NO-CACHE is non-nil, cached contents of a message/external-body part
1182 are ignored."
1183   (let ((text (cond ((eq (mail-content-type-get (mm-handle-type handle)
1184                                                 'charset)
1185                          'gnus-decoded)
1186                      (with-current-buffer (mm-handle-buffer handle)
1187                        (buffer-string)))
1188                     ((mm-multibyte-p)
1189                      (mm-string-to-multibyte (mm-get-part handle no-cache)))
1190                     (t
1191                      (mm-get-part handle no-cache)))))
1192     (save-restriction
1193       (widen)
1194       (goto-char
1195        (prog1
1196            (point)
1197          (if (and (eq (get-char-property (max (point-min) (1- (point))) 'face)
1198                       'mm-uu-extract)
1199                   (eq (get-char-property 0 'face text) 'mm-uu-extract))
1200              ;; Separate the extracted parts that have the same faces.
1201              (insert "\n" text)
1202            (insert text)))))))
1203
1204 (defun mm-file-name-delete-whitespace (file-name)
1205   "Remove all whitespace characters from FILE-NAME."
1206   (while (string-match "\\s-+" file-name)
1207     (setq file-name (replace-match "" t t file-name)))
1208   file-name)
1209
1210 (defun mm-file-name-trim-whitespace (file-name)
1211   "Remove leading and trailing whitespace characters from FILE-NAME."
1212   (when (string-match "\\`\\s-+" file-name)
1213     (setq file-name (substring file-name (match-end 0))))
1214   (when (string-match "\\s-+\\'" file-name)
1215     (setq file-name (substring file-name 0 (match-beginning 0))))
1216   file-name)
1217
1218 (defun mm-file-name-collapse-whitespace (file-name)
1219   "Collapse multiple whitespace characters in FILE-NAME."
1220   (while (string-match "\\s-\\s-+" file-name)
1221     (setq file-name (replace-match " " t t file-name)))
1222   file-name)
1223
1224 (defun mm-file-name-replace-whitespace (file-name)
1225   "Replace whitespace characters in FILE-NAME with underscores.
1226 Set the option `mm-file-name-replace-whitespace' to any other
1227 string if you do not like underscores."
1228   (let ((s (or mm-file-name-replace-whitespace "_")))
1229     (while (string-match "\\s-" file-name)
1230       (setq file-name (replace-match s t t file-name))))
1231   file-name)
1232
1233 (defun mm-file-name-delete-control (filename)
1234   "Delete control characters from FILENAME."
1235   (gnus-replace-in-string filename "[\x00-\x1f\x7f]" ""))
1236
1237 (defun mm-file-name-delete-gotchas (filename)
1238   "Delete shell gotchas from FILENAME."
1239   (setq filename (gnus-replace-in-string filename "[<>|]" ""))
1240   (gnus-replace-in-string filename "^[.-]+" ""))
1241
1242 (defun mm-save-part (handle &optional prompt)
1243   "Write HANDLE to a file.
1244 PROMPT overrides the default one used to ask user for a file name."
1245   (let ((filename (or (mail-content-type-get
1246                        (mm-handle-disposition handle) 'filename)
1247                       (mail-content-type-get
1248                        (mm-handle-type handle) 'name)))
1249         file)
1250     (when filename
1251       (setq filename (gnus-map-function mm-file-name-rewrite-functions
1252                                         (file-name-nondirectory filename))))
1253     (setq file
1254           (read-file-name (or prompt
1255                               (format "Save MIME part to (default %s): "
1256                                       (or filename "")))
1257                           (or mm-default-directory default-directory)
1258                           (or filename "")))
1259     (if (file-directory-p file)
1260         (setq file (expand-file-name filename file))
1261       (setq file (expand-file-name
1262                   file (or mm-default-directory default-directory))))
1263     (setq mm-default-directory (file-name-directory file))
1264     (and (or (not (file-exists-p file))
1265              (yes-or-no-p (format "File %s already exists; overwrite? "
1266                                   file)))
1267          (progn
1268            (mm-save-part-to-file handle file)
1269            file))))
1270
1271 (defun mm-add-meta-html-tag (handle &optional charset force-charset)
1272   "Add meta html tag to specify CHARSET of HANDLE in the current buffer.
1273 CHARSET defaults to the one HANDLE specifies.  Existing meta tag that
1274 specifies charset will not be modified unless FORCE-CHARSET is non-nil.
1275 Return t if meta tag is added or replaced."
1276   (when (equal (mm-handle-media-type handle) "text/html")
1277     (when (or charset
1278               (setq charset (mail-content-type-get (mm-handle-type handle)
1279                                                    'charset)))
1280       (setq charset (format "\
1281 <meta http-equiv=\"Content-Type\" content=\"text/html; charset=%s\">" charset))
1282       (let ((case-fold-search t))
1283         (goto-char (point-min))
1284         (if (re-search-forward "\
1285 <meta\\s-+http-equiv=[\"']?content-type[\"']?\\s-+content=[\"']\
1286 text/\\(\\sw+\\)\\(?:\;\\s-*charset=\\(.+\\)\\)?[\"'][^>]*>" nil t)
1287             (if (and (not force-charset)
1288                      (match-beginning 2)
1289                      (string-match "\\`html\\'" (match-string 1)))
1290                 ;; Don't modify existing meta tag.
1291                 nil
1292               ;; Replace it with the one specifying charset.
1293               (replace-match charset)
1294               t)
1295           (if (re-search-forward "<head>\\s-*" nil t)
1296               (insert charset "\n")
1297             (re-search-forward "<html\\(?:\\s-+[^>]+\\|\\s-*\\)>\\s-*" nil t)
1298             (insert "<head>\n" charset "\n</head>\n"))
1299           t)))))
1300
1301 (defun mm-save-part-to-file (handle file)
1302   (mm-with-unibyte-buffer
1303     (mm-insert-part handle)
1304     (mm-add-meta-html-tag handle)
1305     (let ((current-file-modes (default-file-modes)))
1306       (set-default-file-modes mm-attachment-file-modes)
1307       (unwind-protect
1308           ;; Don't re-compress .gz & al.  Arguably we should make
1309           ;; `file-name-handler-alist' nil, but that would chop
1310           ;; ange-ftp, which is reasonable to use here.
1311           (mm-write-region (point-min) (point-max) file nil nil nil 'binary t)
1312         (set-default-file-modes current-file-modes)))))
1313
1314 (defun mm-pipe-part (handle &optional cmd)
1315   "Pipe HANDLE to a process.
1316 Use CMD as the process."
1317   (let ((name (mail-content-type-get (mm-handle-type handle) 'name))
1318         (command (or cmd
1319                      (gnus-read-shell-command
1320                       "Shell command on MIME part: " mm-last-shell-command))))
1321     (mm-with-unibyte-buffer
1322       (mm-insert-part handle)
1323       (mm-add-meta-html-tag handle)
1324       (let ((coding-system-for-write 'binary))
1325         (shell-command-on-region (point-min) (point-max) command nil)))))
1326
1327 (autoload 'gnus-completing-read "gnus-util")
1328
1329 (defun mm-interactively-view-part (handle)
1330   "Display HANDLE using METHOD."
1331   (let* ((type (mm-handle-media-type handle))
1332          (methods
1333           (mapcar (lambda (i) (cdr (assoc 'viewer i)))
1334                   (mailcap-mime-info type 'all)))
1335          (method (let ((minibuffer-local-completion-map
1336                         mm-viewer-completion-map))
1337                    (gnus-completing-read "Viewer" methods))))
1338     (when (string= method "")
1339       (error "No method given"))
1340     (if (string-match "^[^% \t]+$" method)
1341         (setq method (concat method " %s")))
1342     (mm-display-external handle method)))
1343
1344 (defun mm-preferred-alternative (handles &optional preferred)
1345   "Say which of HANDLES are preferred."
1346   (let ((prec (if preferred (list preferred)
1347                 (mm-preferred-alternative-precedence handles)))
1348         p h result type handle)
1349     (while (setq p (pop prec))
1350       (setq h handles)
1351       (while h
1352         (setq handle (car h))
1353         (setq type (mm-handle-media-type handle))
1354         (when (and (equal p type)
1355                    (mm-automatic-display-p handle)
1356                    (or (stringp (car handle))
1357                        (not (mm-handle-disposition handle))
1358                        (equal (car (mm-handle-disposition handle))
1359                               "inline")))
1360           (setq result handle
1361                 h nil
1362                 prec nil))
1363         (pop h)))
1364     result))
1365
1366 (defun mm-preferred-alternative-precedence (handles)
1367   "Return the precedence based on HANDLES and `mm-discouraged-alternatives'."
1368   (let ((seq (nreverse (mapcar #'mm-handle-media-type
1369                                handles))))
1370     (dolist (disc (reverse mm-discouraged-alternatives))
1371       (dolist (elem (copy-sequence seq))
1372         (when (string-match disc elem)
1373           (setq seq (nconc (delete elem seq) (list elem))))))
1374     seq))
1375
1376 (defun mm-get-content-id (id)
1377   "Return the handle(s) referred to by ID."
1378   (cdr (assoc id mm-content-id-alist)))
1379
1380 (defconst mm-image-type-regexps
1381   '(("/\\*.*XPM.\\*/" . xpm)
1382     ("P[1-6]" . pbm)
1383     ("GIF8" . gif)
1384     ("\377\330" . jpeg)
1385     ("\211PNG\r\n" . png)
1386     ("#define" . xbm)
1387     ("\\(MM\0\\*\\)\\|\\(II\\*\0\\)" . tiff)
1388     ("%!PS" . postscript))
1389   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
1390 When the first bytes of an image file match REGEXP, it is assumed to
1391 be of image type IMAGE-TYPE.")
1392
1393 ;; Steal from image.el. image-type-from-data suffers multi-line matching bug.
1394 (defun mm-image-type-from-buffer ()
1395   "Determine the image type from data in the current buffer.
1396 Value is a symbol specifying the image type or nil if type cannot
1397 be determined."
1398   (let ((types mm-image-type-regexps)
1399         type)
1400     (goto-char (point-min))
1401     (while (and types (null type))
1402       (let ((regexp (car (car types)))
1403             (image-type (cdr (car types))))
1404         (when (looking-at regexp)
1405           (setq type image-type))
1406         (setq types (cdr types))))
1407     type))
1408
1409 (defun mm-get-image (handle)
1410   "Return an image instance based on HANDLE."
1411   (let ((type (mm-handle-media-subtype handle))
1412         spec)
1413     ;; Allow some common translations.
1414     (setq type
1415           (cond
1416            ((equal type "x-pixmap")
1417             "xpm")
1418            ((equal type "x-xbitmap")
1419             "xbm")
1420            ((equal type "x-portable-bitmap")
1421             "pbm")
1422            (t type)))
1423     (or (mm-handle-cache handle)
1424         (mm-with-unibyte-buffer
1425           (mm-insert-part handle)
1426           (prog1
1427               (setq spec
1428                     (ignore-errors
1429                       ;; Avoid testing `make-glyph' since W3 may define
1430                       ;; a bogus version of it.
1431                       (if (fboundp 'create-image)
1432                           (create-image (buffer-string)
1433                                         (or (mm-image-type-from-buffer)
1434                                             (intern type))
1435                                         'data-p)
1436                         (mm-create-image-xemacs type))))
1437             (mm-handle-set-cache handle spec))))))
1438
1439 (defun mm-create-image-xemacs (type)
1440   (when (featurep 'xemacs)
1441     (cond
1442      ((equal type "xbm")
1443       ;; xbm images require special handling, since
1444       ;; the only way to create glyphs from these
1445       ;; (without a ton of work) is to write them
1446       ;; out to a file, and then create a file
1447       ;; specifier.
1448       (let ((file (mm-make-temp-file
1449                    (expand-file-name "emm" mm-tmp-directory)
1450                    nil ".xbm")))
1451         (unwind-protect
1452             (progn
1453               (write-region (point-min) (point-max) file)
1454               (make-glyph (list (cons 'x file))))
1455           (ignore-errors
1456             (delete-file file)))))
1457      (t
1458       (make-glyph
1459        (vector
1460         (or (mm-image-type-from-buffer)
1461             (intern type))
1462         :data (buffer-string)))))))
1463
1464 (declare-function image-size "image.c" (spec &optional pixels frame))
1465
1466 (defun mm-image-fit-p (handle)
1467   "Say whether the image in HANDLE will fit the current window."
1468   (let ((image (mm-get-image handle)))
1469     (or (not image)
1470         (if (featurep 'xemacs)
1471             ;; XEmacs' glyphs can actually tell us about their width, so
1472             ;; lets be nice and smart about them.
1473             (or mm-inline-large-images
1474                 (and (<= (glyph-width image) (window-pixel-width))
1475                      (<= (glyph-height image) (window-pixel-height))))
1476           (let* ((size (image-size image))
1477                  (w (car size))
1478                  (h (cdr size)))
1479             (or mm-inline-large-images
1480                 (and (<= h (1- (window-height))) ; Don't include mode line.
1481                      (<= w (window-width)))))))))
1482
1483 (defun mm-valid-image-format-p (format)
1484   "Say whether FORMAT can be displayed natively by Emacs."
1485   (cond
1486    ;; Handle XEmacs
1487    ((fboundp 'valid-image-instantiator-format-p)
1488     (valid-image-instantiator-format-p format))
1489    ;; Handle Emacs
1490    ((fboundp 'image-type-available-p)
1491     (and (display-graphic-p)
1492          (image-type-available-p format)))
1493    ;; Nobody else can do images yet.
1494    (t
1495     nil)))
1496
1497 (defun mm-valid-and-fit-image-p (format handle)
1498   "Say whether FORMAT can be displayed natively and HANDLE fits the window."
1499   (and (mm-valid-image-format-p format)
1500        (mm-image-fit-p handle)))
1501
1502 (defun mm-find-part-by-type (handles type &optional notp recursive)
1503   "Search in HANDLES for part with TYPE.
1504 If NOTP, returns first non-matching part.
1505 If RECURSIVE, search recursively."
1506   (let (handle)
1507     (while handles
1508       (if (and recursive (stringp (caar handles)))
1509           (if (setq handle (mm-find-part-by-type (cdar handles) type
1510                                                  notp recursive))
1511               (setq handles nil))
1512         (if (if notp
1513                 (not (equal (mm-handle-media-type (car handles)) type))
1514               (equal (mm-handle-media-type (car handles)) type))
1515             (setq handle (car handles)
1516                   handles nil)))
1517       (setq handles (cdr handles)))
1518     handle))
1519
1520 (defun mm-find-raw-part-by-type (ctl type &optional notp)
1521   (goto-char (point-min))
1522   (let* ((boundary (concat "--" (mm-handle-multipart-ctl-parameter ctl
1523                                                                    'boundary)))
1524          (close-delimiter (concat "^" (regexp-quote boundary) "--[ \t]*$"))
1525          start
1526          (end (save-excursion
1527                 (goto-char (point-max))
1528                 (if (re-search-backward close-delimiter nil t)
1529                     (match-beginning 0)
1530                   (point-max))))
1531          result)
1532     (setq boundary (concat "^" (regexp-quote boundary) "[ \t]*$"))
1533     (while (and (not result)
1534                 (re-search-forward boundary end t))
1535       (goto-char (match-beginning 0))
1536       (when start
1537         (save-excursion
1538           (save-restriction
1539             (narrow-to-region start (1- (point)))
1540             (when (let* ((ct (mail-fetch-field "content-type"))
1541                          (ctl (and ct (mail-header-parse-content-type ct))))
1542                     (if notp
1543                         (not (equal (car ctl) type))
1544                       (equal (car ctl) type)))
1545               (setq result (buffer-string))))))
1546       (forward-line 1)
1547       (setq start (point)))
1548     (when (and (not result) start)
1549       (save-excursion
1550         (save-restriction
1551           (narrow-to-region start end)
1552           (when (let* ((ct (mail-fetch-field "content-type"))
1553                        (ctl (and ct (mail-header-parse-content-type ct))))
1554                   (if notp
1555                       (not (equal (car ctl) type))
1556                     (equal (car ctl) type)))
1557             (setq result (buffer-string))))))
1558     result))
1559
1560 (defvar mm-security-handle nil)
1561
1562 (defsubst mm-set-handle-multipart-parameter (handle parameter value)
1563   ;; HANDLE could be a CTL.
1564   (when handle
1565     (put-text-property 0 (length (car handle)) parameter value
1566                        (car handle))))
1567
1568 (autoload 'mm-view-pkcs7 "mm-view")
1569
1570 (defun mm-possibly-verify-or-decrypt (parts ctl)
1571   (let ((type (car ctl))
1572         (subtype (cadr (split-string (car ctl) "/")))
1573         (mm-security-handle ctl) ;; (car CTL) is the type.
1574         protocol func functest)
1575     (cond
1576      ((or (equal type "application/x-pkcs7-mime")
1577           (equal type "application/pkcs7-mime"))
1578       (with-temp-buffer
1579         (when (and (cond
1580                     ((eq mm-decrypt-option 'never) nil)
1581                     ((eq mm-decrypt-option 'always) t)
1582                     ((eq mm-decrypt-option 'known) t)
1583                     (t (y-or-n-p
1584                         (format "Decrypt (S/MIME) part? "))))
1585                    (mm-view-pkcs7 parts))
1586           (setq parts (mm-dissect-buffer t)))))
1587      ((equal subtype "signed")
1588       (unless (and (setq protocol
1589                          (mm-handle-multipart-ctl-parameter ctl 'protocol))
1590                    (not (equal protocol "multipart/mixed")))
1591         ;; The message is broken or draft-ietf-openpgp-multsig-01.
1592         (let ((protocols mm-verify-function-alist))
1593           (while protocols
1594             (if (and (or (not (setq functest (nth 3 (car protocols))))
1595                          (funcall functest parts ctl))
1596                      (mm-find-part-by-type parts (caar protocols) nil t))
1597                 (setq protocol (caar protocols)
1598                       protocols nil)
1599               (setq protocols (cdr protocols))))))
1600       (setq func (nth 1 (assoc protocol mm-verify-function-alist)))
1601       (when (cond
1602              ((eq mm-verify-option 'never) nil)
1603              ((eq mm-verify-option 'always) t)
1604              ((eq mm-verify-option 'known)
1605               (and func
1606                    (or (not (setq functest
1607                                   (nth 3 (assoc protocol
1608                                                 mm-verify-function-alist))))
1609                        (funcall functest parts ctl))))
1610              (t
1611               (y-or-n-p
1612                (format "Verify signed (%s) part? "
1613                        (or (nth 2 (assoc protocol mm-verify-function-alist))
1614                            (format "protocol=%s" protocol))))))
1615         (save-excursion
1616           (if func
1617               (setq parts (funcall func parts ctl))
1618             (mm-set-handle-multipart-parameter
1619              mm-security-handle 'gnus-details
1620              (format "Unknown sign protocol (%s)" protocol))))))
1621      ((equal subtype "encrypted")
1622       (unless (setq protocol
1623                     (mm-handle-multipart-ctl-parameter ctl 'protocol))
1624         ;; The message is broken.
1625         (let ((parts parts))
1626           (while parts
1627             (if (assoc (mm-handle-media-type (car parts))
1628                        mm-decrypt-function-alist)
1629                 (setq protocol (mm-handle-media-type (car parts))
1630                       parts nil)
1631               (setq parts (cdr parts))))))
1632       (setq func (nth 1 (assoc protocol mm-decrypt-function-alist)))
1633       (when (cond
1634              ((eq mm-decrypt-option 'never) nil)
1635              ((eq mm-decrypt-option 'always) t)
1636              ((eq mm-decrypt-option 'known)
1637               (and func
1638                    (or (not (setq functest
1639                                   (nth 3 (assoc protocol
1640                                                 mm-decrypt-function-alist))))
1641                        (funcall functest parts ctl))))
1642              (t
1643               (y-or-n-p
1644                (format "Decrypt (%s) part? "
1645                        (or (nth 2 (assoc protocol mm-decrypt-function-alist))
1646                            (format "protocol=%s" protocol))))))
1647         (save-excursion
1648           (if func
1649               (setq parts (funcall func parts ctl))
1650             (mm-set-handle-multipart-parameter
1651              mm-security-handle 'gnus-details
1652              (format "Unknown encrypt protocol (%s)" protocol))))))
1653      (t nil))
1654     parts))
1655
1656 (defun mm-multiple-handles (handles)
1657   (and (listp handles)
1658        (> (length handles) 1)
1659        (or (listp (car handles))
1660            (stringp (car handles)))))
1661
1662 (defun mm-complicated-handles (handles)
1663   (and (listp (car handles))
1664        (> (length handles) 1)))
1665
1666 (defun mm-merge-handles (handles1 handles2)
1667   (append
1668    (if (listp (car handles1))
1669        handles1
1670      (list handles1))
1671    (if (listp (car handles2))
1672        handles2
1673      (list handles2))))
1674
1675 (defun mm-readable-p (handle)
1676   "Say whether the content of HANDLE is readable."
1677   (and (< (with-current-buffer (mm-handle-buffer handle)
1678             (buffer-size)) 10000)
1679        (mm-with-unibyte-buffer
1680          (mm-insert-part handle)
1681          (and (eq (mm-body-7-or-8) '7bit)
1682               (not (mm-long-lines-p 76))))))
1683
1684 (declare-function libxml-parse-html-region "xml.c"
1685                   (start end &optional base-url))
1686 (declare-function shr-insert-document "shr" (dom))
1687 (defvar shr-blocked-images)
1688 (autoload 'gnus-blocked-images "gnus-art")
1689
1690 (defun mm-shr (handle)
1691   ;; Require since we bind its variables.
1692   (require 'shr)
1693   (let ((article-buffer (current-buffer))
1694         (shr-blocked-images (if (and (boundp 'gnus-summary-buffer)
1695                                      (buffer-name gnus-summary-buffer))
1696                                 (with-current-buffer gnus-summary-buffer
1697                                   (gnus-blocked-images))
1698                               shr-blocked-images))
1699         (shr-content-function (lambda (id)
1700                                 (let ((handle (mm-get-content-id id)))
1701                                   (when handle
1702                                     (mm-with-part handle
1703                                       (buffer-string))))))
1704         charset)
1705     (unless handle
1706       (setq handle (mm-dissect-buffer t)))
1707     (setq charset (mail-content-type-get (mm-handle-type handle) 'charset))
1708     (save-restriction
1709       (narrow-to-region (point) (point))
1710       (shr-insert-document
1711        (mm-with-part handle
1712          (when (and charset
1713                     (setq charset (mm-charset-to-coding-system charset))
1714                     (not (eq charset 'ascii)))
1715            (insert (prog1
1716                        (mm-decode-coding-string (buffer-string) charset)
1717                      (erase-buffer)
1718                      (mm-enable-multibyte))))
1719          (libxml-parse-html-region (point-min) (point-max))))
1720       (mm-handle-set-undisplayer
1721        handle
1722        `(lambda ()
1723           (let ((inhibit-read-only t))
1724             (delete-region ,(point-min-marker)
1725                            ,(point-max-marker))))))))
1726
1727 (provide 'mm-decode)
1728
1729 ;;; mm-decode.el ends here