e5a3ec7737d465538c2e1b7fdf5148f0c19e530b
[gnus] / lisp / gnus-start.el
1 ;;; gnus-start.el --- startup functions for Gnus
2
3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
4 ;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
5
6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
7 ;; Keywords: news
8
9 ;; This file is part of GNU Emacs.
10
11 ;; GNU Emacs is free software: you can redistribute it and/or modify
12 ;; it under the terms of the GNU General Public License as published by
13 ;; the Free Software Foundation, either version 3 of the License, or
14 ;; (at your option) any later version.
15
16 ;; GNU Emacs is distributed in the hope that it will be useful,
17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
19 ;; GNU General Public License for more details.
20
21 ;; You should have received a copy of the GNU General Public License
22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
23
24 ;;; Commentary:
25
26 ;;; Code:
27
28 (require 'gnus)
29 (require 'gnus-win)
30 (require 'gnus-int)
31 (require 'gnus-spec)
32 (require 'gnus-range)
33 (require 'gnus-util)
34 (autoload 'message-make-date "message")
35 (autoload 'gnus-agent-read-servers-validate "gnus-agent")
36 (autoload 'gnus-agent-save-local "gnus-agent")
37 (autoload 'gnus-agent-possibly-alter-active "gnus-agent")
38
39 (eval-when-compile
40   (require 'cl))
41
42 (defvar gnus-agent-covered-methods)
43 (defvar gnus-agent-file-loading-local)
44 (defvar gnus-agent-file-loading-cache)
45
46 (defcustom gnus-startup-file (nnheader-concat gnus-home-directory ".newsrc")
47   "Your `.newsrc' file.
48 `.newsrc-SERVER' will be used instead if that exists."
49   :group 'gnus-start
50   :type 'file)
51
52 (defcustom gnus-backup-startup-file 'never
53   "Control use of version numbers for backups of `gnus-startup-file'.
54 This variable takes the same values as the `version-control'
55 variable."
56   :version "22.1"
57   :group 'gnus-start
58   :type '(choice (const :tag "Never" never)
59                  (const :tag "If existing" nil)
60                  (other :tag "Always" t)))
61
62 (defcustom gnus-save-startup-file-via-temp-buffer t
63   "Whether to write the startup file contents to a buffer then save
64 the buffer or write directly to the file.  The buffer is faster
65 because all of the contents are written at once.  The direct write
66 uses considerably less memory."
67   :version "22.1"
68   :group 'gnus-start
69   :type '(choice (const :tag "Write via buffer" t)
70                  (const :tag "Write directly to file" nil)))
71
72 (defcustom gnus-init-file (nnheader-concat gnus-home-directory ".gnus")
73   "Your Gnus Emacs-Lisp startup file name.
74 If a file with the `.el' or `.elc' suffixes exists, it will be read instead."
75   :group 'gnus-start
76   :type 'file)
77
78 (defcustom gnus-site-init-file
79   (condition-case nil
80       (concat (file-name-directory
81                (directory-file-name installation-directory))
82               "site-lisp/gnus-init")
83     (error nil))
84   "The site-wide Gnus Emacs-Lisp startup file name, or nil if none.
85 If a file with the `.el' or `.elc' suffixes exists, it will be read instead."
86   :group 'gnus-start
87   :type '(choice file (const nil)))
88
89 (defcustom gnus-default-subscribed-newsgroups nil
90   "List of newsgroups to subscribe, when a user runs Gnus the first time.
91 The value should be a list of strings.
92 If it is t, Gnus will not do anything special the first time it is
93 started; it'll just use the normal newsgroups subscription methods."
94   :group 'gnus-start
95   :type '(choice (repeat string) (const :tag "Nothing special" t)))
96
97 (defcustom gnus-use-dribble-file t
98   "*Non-nil means that Gnus will use a dribble file to store user updates.
99 If Emacs should crash without saving the .newsrc files, complete
100 information can be restored from the dribble file."
101   :group 'gnus-dribble-file
102   :type 'boolean)
103
104 (defcustom gnus-dribble-directory nil
105   "*The directory where dribble files will be saved.
106 If this variable is nil, the directory where the .newsrc files are
107 saved will be used."
108   :group 'gnus-dribble-file
109   :type '(choice directory (const nil)))
110
111 (defcustom gnus-check-new-newsgroups 'ask-server
112   "*Non-nil means that Gnus will run `gnus-find-new-newsgroups' at startup.
113 This normally finds new newsgroups by comparing the active groups the
114 servers have already reported with those Gnus already knows, either alive
115 or killed.
116
117 When any of the following are true, `gnus-find-new-newsgroups' will instead
118 ask the servers (primary, secondary, and archive servers) to list new
119 groups since the last time it checked:
120   1. This variable is `ask-server'.
121   2. This variable is a list of select methods (see below).
122   3. `gnus-read-active-file' is nil or `some'.
123   4. A prefix argument is given to `gnus-find-new-newsgroups' interactively.
124
125 Thus, if this variable is `ask-server' or a list of select methods or
126 `gnus-read-active-file' is nil or `some', then the killed list is no
127 longer necessary, so you could safely set `gnus-save-killed-list' to nil.
128
129 This variable can be a list of select methods which Gnus will query with
130 the `ask-server' method in addition to the primary, secondary, and archive
131 servers.
132
133 Eg.
134   (setq gnus-check-new-newsgroups
135         '((nntp \"some.server\") (nntp \"other.server\")))
136
137 If this variable is nil, then you have to tell Gnus explicitly to
138 check for new newsgroups with \\<gnus-group-mode-map>\\[gnus-find-new-newsgroups]."
139   :group 'gnus-start
140   :type '(choice (const :tag "no" nil)
141                  (const :tag "by brute force" t)
142                  (const :tag "ask servers" ask-server)
143                  (repeat :menu-tag "ask additional servers"
144                          :tag "ask additional servers"
145                          :value ((nntp ""))
146                          (sexp :format "%v"))))
147
148 (defcustom gnus-check-bogus-newsgroups nil
149   "*Non-nil means that Gnus will check and remove bogus newsgroup at startup.
150 If this variable is nil, then you have to tell Gnus explicitly to
151 check for bogus newsgroups with \\<gnus-group-mode-map>\\[gnus-group-check-bogus-groups]."
152   :group 'gnus-start-server
153   :type 'boolean)
154
155 (defcustom gnus-read-active-file 'some
156   "*Non-nil means that Gnus will read the entire active file at startup.
157 If this variable is nil, Gnus will only know about the groups in your
158 `.newsrc' file.
159
160 If this variable is `some', Gnus will try to only read the relevant
161 parts of the active file from the server.  Not all servers support
162 this, and it might be quite slow with other servers, but this should
163 generally be faster than both the t and nil value.
164
165 If you set this variable to nil or `some', you probably still want to
166 be told about new newsgroups that arrive.  To do that, set
167 `gnus-check-new-newsgroups' to `ask-server'.  This may not work
168 properly with all servers."
169   :group 'gnus-start-server
170   :type '(choice (const nil)
171                  (const some)
172                  (const t)))
173
174 (defconst gnus-level-subscribed 5
175   "Groups with levels less than or equal to this variable are subscribed.")
176
177 (defconst gnus-level-unsubscribed 7
178   "Groups with levels less than or equal to this variable are unsubscribed.
179
180 Groups with levels less than `gnus-level-subscribed', which
181 should be less than this variable, are subscribed.  Groups with
182 levels from `gnus-level-subscribed' (exclusive) upto this
183 variable (inclusive) are unsubscribed.  See also
184 `gnus-level-zombie', `gnus-level-killed' and the Info node `(gnus)Group
185 Levels' for details.")
186
187 (defconst gnus-level-zombie 8
188   "Groups with this level are zombie groups.")
189
190 (defconst gnus-level-killed 9
191   "Groups with this level are killed.")
192
193 (defcustom gnus-level-default-subscribed 3
194   "*New subscribed groups will be subscribed at this level."
195   :group 'gnus-group-levels
196   :type 'integer)
197
198 (defcustom gnus-level-default-unsubscribed 6
199   "*New unsubscribed groups will be unsubscribed at this level."
200   :group 'gnus-group-levels
201   :type 'integer)
202
203 (defcustom gnus-activate-level (1+ gnus-level-subscribed)
204   "*Groups higher than this level won't be activated on startup.
205 Setting this variable to something low might save lots of time when
206 you have many groups that you aren't interested in."
207   :group 'gnus-group-levels
208   :type 'integer)
209
210 (defcustom gnus-activate-foreign-newsgroups 4
211   "*If nil, Gnus will not check foreign newsgroups at startup.
212 If it is non-nil, it should be a number between one and nine.  Foreign
213 newsgroups that have a level lower or equal to this number will be
214 activated on startup.  For instance, if you want to active all
215 subscribed newsgroups, but not the rest, you'd set this variable to
216 `gnus-level-subscribed'.
217
218 If you subscribe to lots of newsgroups from different servers, startup
219 might take a while.  By setting this variable to nil, you'll save time,
220 but you won't be told how many unread articles there are in the
221 groups."
222   :group 'gnus-group-levels
223   :type '(choice integer
224                  (const :tag "none" nil)))
225
226 (defcustom gnus-read-newsrc-file t
227   "*Non-nil means that Gnus will read the `.newsrc' file.
228 Gnus always reads its own startup file, which is called
229 \".newsrc.eld\".  The file called \".newsrc\" is in a format that can
230 be readily understood by other newsreaders.  If you don't plan on
231 using other newsreaders, set this variable to nil to save some time on
232 entry."
233   :version "21.1"
234   :group 'gnus-newsrc
235   :type 'boolean)
236
237 (defcustom gnus-save-newsrc-file t
238   "*Non-nil means that Gnus will save the `.newsrc' file.
239 Gnus always saves its own startup file, which is called
240 \".newsrc.eld\".  The file called \".newsrc\" is in a format that can
241 be readily understood by other newsreaders.  If you don't plan on
242 using other newsreaders, set this variable to nil to save some time on
243 exit."
244   :group 'gnus-newsrc
245   :type 'boolean)
246
247 (defcustom gnus-save-killed-list t
248   "*If non-nil, save the list of killed groups to the startup file.
249 If you set this variable to nil, you'll save both time (when starting
250 and quitting) and space (both memory and disk), but it will also mean
251 that Gnus has no record of which groups are new and which are old, so
252 the automatic new newsgroups subscription methods become meaningless.
253
254 You should always set `gnus-check-new-newsgroups' to `ask-server' or
255 nil if you set this variable to nil.
256
257 This variable can also be a regexp.  In that case, all groups that do
258 not match this regexp will be removed before saving the list."
259   :group 'gnus-newsrc
260   :type '(radio (sexp :format "Non-nil\n"
261                       :match (lambda (widget value)
262                                (and value (not (stringp value))))
263                       :value t)
264                 (const nil)
265                 regexp))
266
267 (defcustom gnus-ignored-newsgroups
268   (mapconcat 'identity
269              '("^to\\."                 ; not "real" groups
270                "^[0-9. \t]+\\( \\|$\\)" ; all digits in name
271                "^[\"][\"#'()]"  ; bogus characters
272                )
273              "\\|")
274   "*A regexp to match uninteresting newsgroups in the active file.
275 Any lines in the active file matching this regular expression are
276 removed from the newsgroup list before anything else is done to it,
277 thus making them effectively non-existent."
278   :group 'gnus-group-new
279   :type 'regexp)
280
281 (defcustom gnus-subscribe-newsgroup-method 'gnus-subscribe-zombies
282   "*Function(s) called with a group name when new group is detected.
283 A few pre-made functions are supplied: `gnus-subscribe-randomly'
284 inserts new groups at the beginning of the list of groups;
285 `gnus-subscribe-alphabetically' inserts new groups in strict
286 alphabetic order; `gnus-subscribe-hierarchically' inserts new groups
287 in hierarchical newsgroup order; `gnus-subscribe-interactively' asks
288 for your decision; `gnus-subscribe-killed' kills all new groups;
289 `gnus-subscribe-zombies' will make all new groups into zombies;
290 `gnus-subscribe-topics' will enter groups into the topics that
291 claim them."
292   :group 'gnus-group-new
293   :type '(radio (function-item gnus-subscribe-randomly)
294                 (function-item gnus-subscribe-alphabetically)
295                 (function-item gnus-subscribe-hierarchically)
296                 (function-item gnus-subscribe-interactively)
297                 (function-item gnus-subscribe-killed)
298                 (function-item gnus-subscribe-zombies)
299                 (function-item gnus-subscribe-topics)
300                 function
301                 (repeat function)))
302
303 (defcustom gnus-subscribe-newsgroup-hooks nil
304   "*Hooks run after you subscribe to a new group.
305 The hooks will be called with new group's name as argument."
306   :version "22.1"
307   :group 'gnus-group-new
308   :type 'hook)
309
310 (defcustom gnus-subscribe-options-newsgroup-method
311   'gnus-subscribe-alphabetically
312   "*Function(s) called to subscribe newsgroups mentioned on \"options -n\" lines.
313 If, for instance, you want to subscribe to all newsgroups in the
314 \"no\" and \"alt\" hierarchies, you'd put the following in your
315 .newsrc file:
316
317 options -n no.all alt.all
318
319 Gnus will then subscribe all new newsgroups in these hierarchies
320 with the subscription method in this variable."
321   :group 'gnus-group-new
322   :type '(radio (function-item gnus-subscribe-randomly)
323                 (function-item gnus-subscribe-alphabetically)
324                 (function-item gnus-subscribe-hierarchically)
325                 (function-item gnus-subscribe-interactively)
326                 (function-item gnus-subscribe-killed)
327                 (function-item gnus-subscribe-zombies)
328                 (function-item gnus-subscribe-topics)
329                 function
330                 (repeat function)))
331
332 (defcustom gnus-subscribe-hierarchical-interactive nil
333   "*If non-nil, Gnus will offer to subscribe hierarchically.
334 When a new hierarchy appears, Gnus will ask the user:
335
336 'alt.binaries': Do you want to subscribe to this hierarchy? ([d]ys):
337
338 If the user pressed `d', Gnus will descend the hierarchy, `y' will
339 subscribe to all newsgroups in the hierarchy and `s' will skip this
340 hierarchy in its entirety."
341   :group 'gnus-group-new
342   :type 'boolean)
343
344 (defcustom gnus-auto-subscribed-groups
345   "^nnml\\|^nnfolder\\|^nnmbox\\|^nnmh\\|^nnbabyl\\|^nnmaildir"
346   "*All new groups that match this regexp will be subscribed automatically.
347 Note that this variable only deals with new groups.  It has no effect
348 whatsoever on old groups.
349
350 New groups that match this regexp will not be handled by
351 `gnus-subscribe-newsgroup-method'.  Instead, they will
352 be subscribed using `gnus-subscribe-options-newsgroup-method'."
353   :group 'gnus-group-new
354   :type 'regexp)
355
356 (defcustom gnus-options-subscribe nil
357   "*All new groups matching this regexp will be subscribed unconditionally.
358 Note that this variable deals only with new newsgroups.  This variable
359 does not affect old newsgroups.
360
361 New groups that match this regexp will not be handled by
362 `gnus-subscribe-newsgroup-method'.  Instead, they will
363 be subscribed using `gnus-subscribe-options-newsgroup-method'."
364   :group 'gnus-group-new
365   :type '(choice regexp
366                  (const :tag "none" nil)))
367
368 (defcustom gnus-options-not-subscribe nil
369   "*All new groups matching this regexp will be ignored.
370 Note that this variable deals only with new newsgroups.  This variable
371 does not affect old (already subscribed) newsgroups."
372   :group 'gnus-group-new
373   :type '(choice regexp
374                  (const :tag "none" nil)))
375
376 (defcustom gnus-modtime-botch nil
377   "*Non-nil means .newsrc should be deleted prior to save.
378 Its use is due to the bogus appearance that .newsrc was modified on
379 disc."
380   :group 'gnus-newsrc
381   :type 'boolean)
382
383 (defcustom gnus-use-backend-marks nil
384   "If non-nil, Gnus will store and retrieve marks from the backends.
385 This means that marks will be stored both in .newsrc.eld and in
386 the backend, and will slow operation down somewhat."
387   :group 'gnus-newsrc
388   :type 'boolean)
389
390 (defcustom gnus-check-bogus-groups-hook nil
391   "A hook run after removing bogus groups."
392   :group 'gnus-start-server
393   :type 'hook)
394
395 (defcustom gnus-startup-hook nil
396   "A hook called at startup.
397 This hook is called after Gnus is connected to the NNTP server."
398   :group 'gnus-start
399   :type 'hook)
400
401 (defcustom gnus-before-startup-hook nil
402   "A hook called before startup.
403 This hook is called as the first thing when Gnus is started."
404   :group 'gnus-start
405   :type 'hook)
406
407 (defcustom gnus-started-hook nil
408   "A hook called as the last thing after startup."
409   :group 'gnus-start
410   :type 'hook)
411
412 (defcustom gnus-setup-news-hook nil
413   "A hook after reading the .newsrc file, but before generating the buffer."
414   :group 'gnus-start
415   :type 'hook)
416
417 (defcustom gnus-get-top-new-news-hook nil
418   "A hook run just before Gnus checks for new news globally."
419   :version "22.1"
420   :group 'gnus-group-new
421   :type 'hook)
422
423 (defcustom gnus-get-new-news-hook nil
424   "A hook run just before Gnus checks for new news."
425   :group 'gnus-group-new
426   :type 'hook)
427
428 (defcustom gnus-after-getting-new-news-hook
429   '(gnus-display-time-event-handler)
430   "*A hook run after Gnus checks for new news when Gnus is already running."
431   :version "24.1"
432   :group 'gnus-group-new
433   :type 'hook)
434
435 (defcustom gnus-read-newsrc-el-hook nil
436   "A hook called after reading the newsrc.eld? file."
437   :group 'gnus-newsrc
438   :type 'hook)
439
440 (defcustom gnus-save-newsrc-hook nil
441   "A hook called before saving any of the newsrc files."
442   :group 'gnus-newsrc
443   :type 'hook)
444
445 (defcustom gnus-save-quick-newsrc-hook nil
446   "A hook called just before saving the quick newsrc file.
447 Can be used to turn version control on or off."
448   :group 'gnus-newsrc
449   :type 'hook)
450
451 (defcustom gnus-save-standard-newsrc-hook nil
452   "A hook called just before saving the standard newsrc file.
453 Can be used to turn version control on or off."
454   :group 'gnus-newsrc
455   :type 'hook)
456
457 (defcustom gnus-group-mode-hook nil
458   "Hook for Gnus group mode."
459   :group 'gnus-group-various
460   :options '(gnus-topic-mode)
461   :type 'hook)
462
463 (defcustom gnus-always-read-dribble-file nil
464   "Unconditionally read the dribble file."
465   :group 'gnus-newsrc
466   :type 'boolean)
467
468 ;;; Internal variables
469
470 ;; Fixme: deal with old emacs-mule when mm-universal-coding-system is
471 ;; utf-8-emacs.
472 (defvar gnus-ding-file-coding-system mm-universal-coding-system
473   "Coding system for ding file.")
474
475 (defvar gnus-newsrc-file-version nil)
476 (defvar gnus-override-subscribe-method nil)
477 (defvar gnus-dribble-buffer nil)
478 (defvar gnus-newsrc-options nil
479   "Options line in the .newsrc file.")
480
481 (defvar gnus-newsrc-options-n nil
482   "List of regexps representing groups to be subscribed/ignored unconditionally.")
483
484 (defvar gnus-newsrc-last-checked-date nil
485   "Date Gnus last asked server for new newsgroups.")
486
487 (defvar gnus-current-startup-file nil
488   "Startup file for the current host.")
489
490 ;; Byte-compiler warning.
491 (defvar gnus-group-line-format)
492
493 ;; Suggested by Brian Edmonds <edmonds@cs.ubc.ca>.
494 (defvar gnus-init-inhibit nil)
495 (defun gnus-read-init-file (&optional inhibit-next)
496   ;; Don't load .gnus if the -q option was used.
497   (when init-file-user
498     (if gnus-init-inhibit
499         (setq gnus-init-inhibit nil)
500       (setq gnus-init-inhibit inhibit-next)
501       (dolist (file (list gnus-site-init-file gnus-init-file))
502         (when (and file
503                    (locate-library file))
504           (if (or debug-on-error debug-on-quit)
505               (load file nil t)
506             (condition-case var
507                 (load file nil t)
508               (error
509                (error "Error in %s: %s" file (cadr var))))))))))
510
511 ;; For subscribing new newsgroup
512
513 (defun gnus-subscribe-hierarchical-interactive (groups)
514   (let ((groups (sort groups 'string<))
515         prefixes prefix start ans group starts real-group)
516     (while groups
517       (setq prefixes (list "^"))
518       (while (and groups prefixes)
519         (while (not (string-match (car prefixes)
520                                   (gnus-group-real-name (car groups))))
521           (setq prefixes (cdr prefixes)))
522         (setq prefix (car prefixes))
523         (setq start (1- (length prefix)))
524         (if (and (string-match "[^\\.]\\." (gnus-group-real-name (car groups))
525                                start)
526                  (cdr groups)
527                  (setq prefix
528                        (concat "^" (substring
529                                     (gnus-group-real-name (car groups))
530                                     0 (match-end 0))))
531                  (string-match prefix (gnus-group-real-name (cadr groups))))
532             (progn
533               (push prefix prefixes)
534               (message "Descend hierarchy %s? ([y]nsq): "
535                        (substring prefix 1 (1- (length prefix))))
536               (while (not (memq (setq ans (read-char-exclusive))
537                                 '(?y ?\n ?\r ?n ?s ?q)))
538                 (ding)
539                 (message "Descend hierarchy %s? ([y]nsq): "
540                          (substring prefix 1 (1- (length prefix)))))
541               (cond ((= ans ?n)
542                      (while (and groups
543                                  (setq group (car groups)
544                                        real-group (gnus-group-real-name group))
545                                  (string-match prefix real-group))
546                        (push group gnus-killed-list)
547                        (gnus-sethash group group gnus-killed-hashtb)
548                        (setq groups (cdr groups)))
549                      (setq starts (cdr starts)))
550                     ((= ans ?s)
551                      (while (and groups
552                                  (setq group (car groups)
553                                        real-group (gnus-group-real-name group))
554                                  (string-match prefix real-group))
555                        (gnus-sethash group group gnus-killed-hashtb)
556                        (gnus-subscribe-alphabetically (car groups))
557                        (setq groups (cdr groups)))
558                      (setq starts (cdr starts)))
559                     ((= ans ?q)
560                      (while groups
561                        (setq group (car groups))
562                        (push group gnus-killed-list)
563                        (gnus-sethash group group gnus-killed-hashtb)
564                        (setq groups (cdr groups))))
565                     (t nil)))
566           (message "Subscribe %s? ([n]yq)" (car groups))
567           (while (not (memq (setq ans (read-char-exclusive))
568                             '(?y ?\n ?\r ?q ?n)))
569             (ding)
570             (message "Subscribe %s? ([n]yq)" (car groups)))
571           (setq group (car groups))
572           (cond ((= ans ?y)
573                  (gnus-subscribe-alphabetically (car groups))
574                  (gnus-sethash group group gnus-killed-hashtb))
575                 ((= ans ?q)
576                  (while groups
577                    (setq group (car groups))
578                    (push group gnus-killed-list)
579                    (gnus-sethash group group gnus-killed-hashtb)
580                    (setq groups (cdr groups))))
581                 (t
582                  (push group gnus-killed-list)
583                  (gnus-sethash group group gnus-killed-hashtb)))
584           (setq groups (cdr groups)))))))
585
586 (defun gnus-subscribe-randomly (newsgroup)
587   "Subscribe new NEWSGROUP by making it the first newsgroup."
588   (gnus-subscribe-newsgroup newsgroup))
589
590 (defun gnus-subscribe-alphabetically (newgroup)
591   "Subscribe new NEWGROUP and insert it in alphabetical order."
592   (let ((groups (cdr gnus-newsrc-alist))
593         before)
594     (while (and (not before) groups)
595       (if (string< newgroup (caar groups))
596           (setq before (caar groups))
597         (setq groups (cdr groups))))
598     (gnus-subscribe-newsgroup newgroup before)))
599
600 (defun gnus-subscribe-hierarchically (newgroup)
601   "Subscribe new NEWGROUP and insert it in hierarchical newsgroup order."
602   ;; Basic ideas by mike-w@cs.aukuni.ac.nz (Mike Williams)
603   (with-current-buffer (nnheader-find-file-noselect gnus-current-startup-file)
604     (prog1
605         (let ((groupkey newgroup) before)
606           (while (and (not before) groupkey)
607             (goto-char (point-min))
608             (let ((groupkey-re
609                    (concat "^\\(" (regexp-quote groupkey) ".*\\)[!:]")))
610               (while (and (re-search-forward groupkey-re nil t)
611                           (progn
612                             (setq before (match-string 1))
613                             (string< before newgroup)))))
614             ;; Remove tail of newsgroup name (eg. a.b.c -> a.b)
615             (setq groupkey
616                   (when (string-match "^\\(.*\\)\\.[^.]+$" groupkey)
617                     (substring groupkey (match-beginning 1) (match-end 1)))))
618           (gnus-subscribe-newsgroup newgroup before))
619       (kill-buffer (current-buffer)))))
620
621 (defun gnus-subscribe-interactively (group)
622   "Subscribe the new GROUP interactively.
623 It is inserted in hierarchical newsgroup order if subscribed.  If not,
624 it is killed."
625   (if (gnus-y-or-n-p (format "Subscribe new newsgroup %s? " group))
626       (gnus-subscribe-hierarchically group)
627     (push group gnus-killed-list)))
628
629 (defun gnus-subscribe-zombies (group)
630   "Make the new GROUP into a zombie group."
631   (push group gnus-zombie-list))
632
633 (defun gnus-subscribe-killed (group)
634   "Make the new GROUP a killed group."
635   (push group gnus-killed-list))
636
637 (defun gnus-subscribe-newsgroup (newsgroup &optional next)
638   "Subscribe new NEWSGROUP.
639 If NEXT is non-nil, it is inserted before NEXT.  Otherwise it is made
640 the first newsgroup."
641   (save-excursion
642     (goto-char (point-min))
643     ;; We subscribe the group by changing its level to `subscribed'.
644     (gnus-group-change-level
645      newsgroup gnus-level-default-subscribed
646      gnus-level-killed (gnus-group-entry (or next "dummy.group")))
647     (gnus-message 5 "Subscribe newsgroup: %s" newsgroup)
648     (run-hook-with-args 'gnus-subscribe-newsgroup-hooks newsgroup)
649     t))
650
651 (defun gnus-read-active-file-p ()
652   "Say whether the active file has been read from `gnus-select-method'."
653   (memq gnus-select-method gnus-have-read-active-file))
654
655 ;;; General various misc type functions.
656
657 ;; Silence byte-compiler.
658 (defvar gnus-current-headers)
659 (defvar gnus-thread-indent-array)
660 (defvar gnus-newsgroup-name)
661 (defvar gnus-newsgroup-headers)
662 (defvar gnus-group-list-mode)
663 (defvar gnus-group-mark-positions)
664 (defvar gnus-newsgroup-data)
665 (defvar gnus-newsgroup-unreads)
666 (defvar nnoo-state-alist)
667 (defvar gnus-current-select-method)
668 (defvar mail-sources)
669 (defvar nnmail-scan-directory-mail-source-once)
670 (defvar nnmail-split-history)
671 (defvar nnmail-spool-file)
672
673 (defun gnus-close-all-servers ()
674   "Close all servers."
675   (interactive)
676   (dolist (server gnus-opened-servers)
677     (gnus-close-server (car server))))
678
679 (defun gnus-clear-system ()
680   "Clear all variables and buffers."
681   ;; Clear Gnus variables.
682   (let ((variables (remove 'gnus-format-specs gnus-variable-list)))
683     (while variables
684       (set (car variables) nil)
685       (setq variables (cdr variables))))
686   ;; Clear other internal variables.
687   (setq gnus-list-of-killed-groups nil
688         gnus-have-read-active-file nil
689         gnus-agent-covered-methods nil
690         gnus-agent-file-loading-local nil
691         gnus-agent-file-loading-cache nil
692         gnus-server-method-cache nil
693         gnus-newsrc-alist nil
694         gnus-newsrc-hashtb nil
695         gnus-killed-list nil
696         gnus-zombie-list nil
697         gnus-killed-hashtb nil
698         gnus-active-hashtb nil
699         gnus-moderated-hashtb nil
700         gnus-description-hashtb nil
701         gnus-current-headers nil
702         gnus-thread-indent-array nil
703         gnus-newsgroup-headers nil
704         gnus-newsgroup-name nil
705         gnus-server-alist nil
706         gnus-group-list-mode nil
707         gnus-opened-servers nil
708         gnus-group-mark-positions nil
709         gnus-newsgroup-data nil
710         gnus-newsgroup-unreads nil
711         nnoo-state-alist nil
712         gnus-current-select-method nil
713         nnmail-split-history nil
714         gnus-extended-servers nil
715         gnus-ephemeral-servers nil)
716   (gnus-shutdown 'gnus)
717   ;; Kill the startup file.
718   (and gnus-current-startup-file
719        (get-file-buffer gnus-current-startup-file)
720        (kill-buffer (get-file-buffer gnus-current-startup-file)))
721   ;; Clear the dribble buffer.
722   (gnus-dribble-clear)
723   ;; Kill global KILL file buffer.
724   (when (get-file-buffer (gnus-newsgroup-kill-file nil))
725     (kill-buffer (get-file-buffer (gnus-newsgroup-kill-file nil))))
726   (gnus-kill-buffer nntp-server-buffer)
727   ;; Kill Gnus buffers.
728   (dolist (buffer (gnus-buffers))
729     (gnus-kill-buffer buffer))
730   ;; Remove Gnus frames.
731   (gnus-kill-gnus-frames))
732
733 (defun gnus-no-server-1 (&optional arg slave)
734   "Read network news.
735 If ARG is a positive number, Gnus will use that as the startup
736 level.  If ARG is nil, Gnus will be started at level 2
737 \(`gnus-level-default-subscribed' minus one).  If ARG is non-nil
738 and not a positive number, Gnus will prompt the user for the name
739 of an NNTP server to use.  As opposed to \\[gnus], this command
740 will not connect to the local server."
741   (interactive "P")
742   (let ((val (or arg (1- gnus-level-default-subscribed))))
743     (gnus val t slave)
744     (make-local-variable 'gnus-group-use-permanent-levels)
745     (setq gnus-group-use-permanent-levels val)))
746
747 (defun gnus-1 (&optional arg dont-connect slave)
748   "Read network news.
749 If ARG is non-nil and a positive number, Gnus will use that as the
750 startup level.  If ARG is non-nil and not a positive number, Gnus will
751 prompt the user for the name of an NNTP server to use."
752   (interactive "P")
753
754   (if (gnus-alive-p)
755       (progn
756         (switch-to-buffer gnus-group-buffer)
757         (gnus-group-get-new-news
758          (and (numberp arg)
759               (> arg 0)
760               (max (car gnus-group-list-mode) arg))))
761
762     (gnus-clear-system)
763     (gnus-splash)
764     (gnus-run-hooks 'gnus-before-startup-hook)
765     (nnheader-init-server-buffer)
766     (setq gnus-slave slave)
767     (gnus-read-init-file)
768
769     ;; Add "native" to gnus-predefined-server-alist just to have a
770     ;; name for the native select method.
771     (when gnus-select-method
772       (push (cons "native" gnus-select-method)
773             gnus-predefined-server-alist))
774
775     (if gnus-agent
776         (gnus-agentize))
777
778     (when gnus-simple-splash
779       (setq gnus-simple-splash nil)
780       (cond
781        ((featurep 'xemacs)
782         (gnus-xmas-splash))
783        (window-system
784         (gnus-x-splash))))
785
786     (let ((level (and (numberp arg) (> arg 0) arg))
787           did-connect)
788       (unwind-protect
789           (progn
790             (unless dont-connect
791               (setq did-connect
792                     (gnus-start-news-server (and arg (not level))))))
793         (if (and (not dont-connect)
794                  (not did-connect))
795             (gnus-group-quit)
796           (gnus-run-hooks 'gnus-startup-hook)
797           ;; NNTP server is successfully open.
798
799           ;; Find the current startup file name.
800           (setq gnus-current-startup-file
801                 (gnus-make-newsrc-file gnus-startup-file))
802
803           ;; Read the dribble file.
804           (when (or gnus-slave gnus-use-dribble-file)
805             (gnus-dribble-read-file))
806
807           ;; Do the actual startup.
808           (if gnus-agent
809               (gnus-request-create-group "queue" '(nndraft "")))
810           (gnus-request-create-group "drafts" '(nndraft ""))
811           (gnus-setup-news nil level dont-connect)
812           (gnus-run-hooks 'gnus-setup-news-hook)
813           (gnus-start-draft-setup)
814           ;; Generate the group buffer.
815           (gnus-group-list-groups level)
816           (gnus-group-first-unread-group)
817           (gnus-configure-windows 'group)
818           (gnus-group-set-mode-line)
819           (gnus-run-hooks 'gnus-started-hook))))))
820
821 (defun gnus-start-draft-setup ()
822   "Make sure the draft group exists."
823   (interactive)
824   (gnus-request-create-group "drafts" '(nndraft ""))
825   (unless (gnus-group-entry "nndraft:drafts")
826     (let ((gnus-level-default-subscribed 1))
827       (gnus-subscribe-group "nndraft:drafts" nil '(nndraft ""))))
828   (unless (equal (gnus-group-get-parameter "nndraft:drafts" 'gnus-dummy t)
829                  '((gnus-draft-mode)))
830     (gnus-message 3 "Setting up drafts group")
831     (gnus-group-set-parameter
832      "nndraft:drafts" 'gnus-dummy '((gnus-draft-mode)))))
833
834 \f
835 ;;;
836 ;;; Dribble file
837 ;;;
838
839 (defvar gnus-dribble-ignore nil)
840 (defvar gnus-dribble-eval-file nil)
841
842 (defun gnus-dribble-file-name ()
843   "Return the dribble file for the current .newsrc."
844   (concat
845    (if gnus-dribble-directory
846        (concat (file-name-as-directory gnus-dribble-directory)
847                (file-name-nondirectory gnus-current-startup-file))
848      gnus-current-startup-file)
849    "-dribble"))
850
851 (defun gnus-dribble-enter (string)
852   "Enter STRING into the dribble buffer."
853   (when (and (not gnus-dribble-ignore)
854              gnus-dribble-buffer
855              (buffer-name gnus-dribble-buffer))
856     (let ((obuf (current-buffer)))
857       (set-buffer gnus-dribble-buffer)
858       (goto-char (point-max))
859       (insert string "\n")
860       ;; This has been commented by Josh Huber <huber@alum.wpi.edu>
861       ;; It causes problems with both XEmacs and Emacs 21, and doesn't
862       ;; seem to be of much value. (FIXME: remove this after we make sure
863       ;; it's not needed).
864       ;; (set-window-point (get-buffer-window (current-buffer)) (point-max))
865       (bury-buffer gnus-dribble-buffer)
866       (with-current-buffer gnus-group-buffer
867         (gnus-group-set-mode-line))
868       (set-buffer obuf))))
869
870 (defun gnus-dribble-touch ()
871   "Touch the dribble buffer."
872   (gnus-dribble-enter ""))
873
874 (defun gnus-dribble-read-file ()
875   "Read the dribble file from disk."
876   (let ((dribble-file (gnus-dribble-file-name)))
877     (unless (file-exists-p (file-name-directory dribble-file))
878       (make-directory (file-name-directory dribble-file) t))
879     (with-current-buffer (setq gnus-dribble-buffer
880                                (gnus-get-buffer-create
881                                 (file-name-nondirectory dribble-file)))
882       (set (make-local-variable 'file-precious-flag) t)
883       (erase-buffer)
884       (setq buffer-file-name dribble-file)
885       (auto-save-mode t)
886       (buffer-disable-undo)
887       (bury-buffer (current-buffer))
888       (set-buffer-modified-p nil)
889       (let ((auto (make-auto-save-file-name))
890             (gnus-dribble-ignore t)
891             (purpose nil)
892             modes)
893         (when (or (file-exists-p auto) (file-exists-p dribble-file))
894           ;; Load whichever file is newest -- the auto save file
895           ;; or the "real" file.
896           (if (file-newer-than-file-p auto dribble-file)
897               (nnheader-insert-file-contents auto)
898             (nnheader-insert-file-contents dribble-file))
899           (unless (zerop (buffer-size))
900             (set-buffer-modified-p t))
901           ;; Set the file modes to reflect the .newsrc file modes.
902           (save-buffer)
903           (when (and (file-exists-p gnus-current-startup-file)
904                      (file-exists-p dribble-file)
905                      (setq modes (file-modes gnus-current-startup-file)))
906             (gnus-set-file-modes dribble-file modes))
907           (goto-char (point-min))
908           (when (search-forward "Gnus was exited on purpose" nil t)
909             (setq purpose t))
910           ;; Possibly eval the file later.
911           (when (or gnus-always-read-dribble-file
912                     (gnus-y-or-n-p
913                      (if purpose
914                          "Gnus exited on purpose without saving; read auto-save file anyway? "
915                      "Gnus auto-save file exists.  Do you want to read it? ")))
916             (setq gnus-dribble-eval-file t)))))))
917
918 (defun gnus-dribble-eval-file ()
919   (when gnus-dribble-eval-file
920     (setq gnus-dribble-eval-file nil)
921     (save-excursion
922       (let ((gnus-dribble-ignore t))
923         (set-buffer gnus-dribble-buffer)
924         (eval-buffer (current-buffer))))))
925
926 (defun gnus-dribble-delete-file ()
927   (when (file-exists-p (gnus-dribble-file-name))
928     (delete-file (gnus-dribble-file-name)))
929   (when gnus-dribble-buffer
930     (with-current-buffer gnus-dribble-buffer
931       (let ((auto (make-auto-save-file-name)))
932         (when (file-exists-p auto)
933           (delete-file auto))
934         (erase-buffer)
935         (set-buffer-modified-p nil)))))
936
937 (defun gnus-dribble-save ()
938   (when (and gnus-dribble-buffer
939              (buffer-name gnus-dribble-buffer))
940     (with-current-buffer gnus-dribble-buffer
941       (save-buffer))))
942
943 (defun gnus-dribble-clear ()
944   (when (gnus-buffer-exists-p gnus-dribble-buffer)
945     (with-current-buffer gnus-dribble-buffer
946       (erase-buffer)
947       (set-buffer-modified-p nil)
948       (setq buffer-saved-size (buffer-size)))))
949
950 \f
951 ;;;
952 ;;; Active & Newsrc File Handling
953 ;;;
954
955 (defun gnus-setup-news (&optional rawfile level dont-connect)
956   "Setup news information.
957 If RAWFILE is non-nil, the .newsrc file will also be read.
958 If LEVEL is non-nil, the news will be set up at level LEVEL."
959   (require 'nnmail)
960   (let ((init (not (and gnus-newsrc-alist gnus-active-hashtb (not rawfile))))
961         ;; Binding this variable will inhibit multiple fetchings
962         ;; of the same mail source.
963         (nnmail-fetched-sources (list t)))
964
965     (when init
966       ;; Clear some variables to re-initialize news information.
967       (setq gnus-newsrc-alist nil
968             gnus-active-hashtb nil)
969       ;; Read the newsrc file and create `gnus-newsrc-hashtb'.
970       (gnus-read-newsrc-file rawfile))
971
972     ;; Make sure the archive server is available to all and sundry.
973     (let ((method (or (and (stringp gnus-message-archive-method)
974                            (gnus-server-to-method
975                             gnus-message-archive-method))
976                       gnus-message-archive-method)))
977       ;; Check whether the archive method is writable.
978       (unless (or (not method)
979                   (stringp method)
980                   (memq 'respool (assoc (format "%s" (car method))
981                                         gnus-valid-select-methods)))
982         (setq method "archive")) ;; The default.
983       (when (stringp method)
984         (setq method `(nnfolder
985                        ,method
986                        (nnfolder-directory
987                         ,(nnheader-concat message-directory method))
988                        (nnfolder-active-file
989                         ,(nnheader-concat message-directory
990                                           (concat method "/active")))
991                        (nnfolder-get-new-mail nil)
992                        (nnfolder-inhibit-expiry t))))
993       (if (assoc "archive" gnus-server-alist)
994           (when gnus-update-message-archive-method
995             (if method
996                 (setcdr (assoc "archive" gnus-server-alist) method)
997               (setq gnus-server-alist (delq (assoc "archive" gnus-server-alist)
998                                             gnus-server-alist))))
999         (when method
1000           (push (cons "archive" method) gnus-server-alist))))
1001
1002     ;; If we don't read the complete active file, we fill in the
1003     ;; hashtb here.
1004     (when (or (null gnus-read-active-file)
1005               (eq gnus-read-active-file 'some))
1006       (gnus-update-active-hashtb-from-killed))
1007
1008     ;; Validate agent covered methods now that gnus-server-alist has
1009     ;; been initialized.
1010     ;; NOTE: This is here for one purpose only.  By validating the
1011     ;; agentized server's, it converts the old 5.10.3, and earlier,
1012     ;; format to the current format.  That enables the agent code
1013     ;; within gnus-read-active-file to function correctly.
1014     (if gnus-agent
1015         (gnus-agent-read-servers-validate))
1016
1017     ;; Read the active file and create `gnus-active-hashtb'.
1018     ;; If `gnus-read-active-file' is nil, then we just create an empty
1019     ;; hash table.  The partial filling out of the hash table will be
1020     ;; done in `gnus-get-unread-articles'.
1021     (and gnus-read-active-file
1022          (not level)
1023          (gnus-read-active-file nil dont-connect))
1024
1025     (unless gnus-active-hashtb
1026       (setq gnus-active-hashtb (gnus-make-hashtable 4096)))
1027
1028     ;; Initialize the cache.
1029     (when gnus-use-cache
1030       (gnus-cache-open))
1031
1032     ;; Possibly eval the dribble file.
1033     (and init
1034          (or gnus-use-dribble-file gnus-slave)
1035          (gnus-dribble-eval-file))
1036
1037     ;; Slave Gnusii should then clear the dribble buffer.
1038     (when (and init gnus-slave)
1039       (gnus-dribble-clear))
1040
1041     (gnus-update-format-specifications)
1042
1043     ;; See whether we need to read the description file.
1044     (when (and (boundp 'gnus-group-line-format)
1045                (stringp gnus-group-line-format)
1046                (let ((case-fold-search nil))
1047                  (string-match "%[-,0-9]*D" gnus-group-line-format))
1048                (not gnus-description-hashtb)
1049                (not dont-connect)
1050                gnus-read-active-file)
1051       (gnus-read-all-descriptions-files))
1052
1053     ;; Find new newsgroups and treat them.
1054     (when (and init gnus-check-new-newsgroups (not level)
1055                (gnus-check-server gnus-select-method)
1056                (not gnus-slave)
1057                gnus-plugged)
1058       (gnus-find-new-newsgroups))
1059
1060     ;; Check and remove bogus newsgroups.
1061     (when (and init gnus-check-bogus-newsgroups
1062                gnus-read-active-file (not level)
1063                (gnus-server-opened gnus-select-method))
1064       (gnus-check-bogus-newsgroups))
1065
1066     ;; Read any slave files.
1067     (gnus-master-read-slave-newsrc)
1068
1069     ;; Find the number of unread articles in each non-dead group.
1070     (let ((gnus-read-active-file (and (not level) gnus-read-active-file)))
1071       (gnus-get-unread-articles level))))
1072
1073 (defun gnus-call-subscribe-functions (method group)
1074   "Call METHOD to subscribe GROUP.
1075 If no function returns `non-nil', call `gnus-subscribe-zombies'."
1076   (unless (cond
1077            ((functionp method)
1078             (funcall method group))
1079            ((listp method)
1080             (catch 'found
1081               (dolist (func method)
1082                 (if (funcall func group)
1083                     (throw 'found t)))
1084               nil))
1085            (t nil))
1086     (gnus-subscribe-zombies group)))
1087
1088 (defun gnus-find-new-newsgroups (&optional arg)
1089   "Search for new newsgroups and add them.
1090 Each new newsgroup will be treated with `gnus-subscribe-newsgroup-method'.
1091 The `-n' option line from .newsrc is respected.
1092
1093 With 1 C-u, use the `ask-server' method to query the server for new
1094 groups.
1095 With 2 C-u's, use most complete method possible to query the server
1096 for new groups, and subscribe the new groups as zombies."
1097   (interactive "p")
1098   (let* ((gnus-subscribe-newsgroup-method
1099           gnus-subscribe-newsgroup-method)
1100          (check (cond
1101                  ((or (and (= (or arg 1) 4)
1102                            (not (listp gnus-check-new-newsgroups)))
1103                       (null gnus-read-active-file)
1104                       (eq gnus-read-active-file 'some))
1105                   'ask-server)
1106                  ((= (or arg 1) 16)
1107                   (setq gnus-subscribe-newsgroup-method
1108                         'gnus-subscribe-zombies)
1109                   t)
1110                  (t gnus-check-new-newsgroups))))
1111     (unless (gnus-check-first-time-used)
1112       (if (or (consp check)
1113               (eq check 'ask-server))
1114           ;; Ask the server for new groups.
1115           (gnus-ask-server-for-new-groups)
1116         ;; Go through the active hashtb and look for new groups.
1117         (let ((groups 0)
1118               group new-newsgroups)
1119           (gnus-message 5 "Looking for new newsgroups...")
1120           (unless gnus-have-read-active-file
1121             (gnus-read-active-file))
1122           (setq gnus-newsrc-last-checked-date (message-make-date))
1123           (unless gnus-killed-hashtb
1124             (gnus-make-hashtable-from-killed))
1125           ;; Go though every newsgroup in `gnus-active-hashtb' and compare
1126           ;; with `gnus-newsrc-hashtb' and `gnus-killed-hashtb'.
1127           (mapatoms
1128            (lambda (sym)
1129              (if (or (null (setq group (symbol-name sym)))
1130                      (not (boundp sym))
1131                      (null (symbol-value sym))
1132                      (gnus-gethash group gnus-killed-hashtb)
1133                      (gnus-gethash group gnus-newsrc-hashtb))
1134                  ()
1135                (let ((do-sub (gnus-matches-options-n group)))
1136                  (cond
1137                   ((eq do-sub 'subscribe)
1138                    (setq groups (1+ groups))
1139                    (gnus-sethash group group gnus-killed-hashtb)
1140                    (gnus-call-subscribe-functions
1141                     gnus-subscribe-options-newsgroup-method group))
1142                   ((eq do-sub 'ignore)
1143                    nil)
1144                   (t
1145                    (setq groups (1+ groups))
1146                    (gnus-sethash group group gnus-killed-hashtb)
1147                    (if gnus-subscribe-hierarchical-interactive
1148                        (push group new-newsgroups)
1149                      (gnus-call-subscribe-functions
1150                       gnus-subscribe-newsgroup-method group)))))))
1151            gnus-active-hashtb)
1152           (when new-newsgroups
1153             (gnus-subscribe-hierarchical-interactive new-newsgroups))
1154           (if (> groups 0)
1155               (gnus-message 5 "%d new newsgroup%s arrived."
1156                             groups (if (> groups 1) "s have" " has"))
1157             (gnus-message 5 "No new newsgroups.")))))))
1158
1159 (defun gnus-matches-options-n (group)
1160   ;; Returns `subscribe' if the group is to be unconditionally
1161   ;; subscribed, `ignore' if it is to be ignored, and nil if there is
1162   ;; no match for the group.
1163
1164   ;; First we check the two user variables.
1165   (cond
1166    ((and gnus-options-subscribe
1167          (string-match gnus-options-subscribe group))
1168     'subscribe)
1169    ((and gnus-auto-subscribed-groups
1170          (string-match gnus-auto-subscribed-groups group))
1171     'subscribe)
1172    ((and gnus-options-not-subscribe
1173          (string-match gnus-options-not-subscribe group))
1174     'ignore)
1175    ;; Then we go through the list that was retrieved from the .newsrc
1176    ;; file.  This list has elements on the form
1177    ;; `(REGEXP . {ignore,subscribe})'.  The first match found (the list
1178    ;; is in the reverse order of the options line) is returned.
1179    (t
1180     (let ((regs gnus-newsrc-options-n))
1181       (while (and regs
1182                   (not (string-match (caar regs) group)))
1183         (setq regs (cdr regs)))
1184       (and regs (cdar regs))))))
1185
1186 (defun gnus-ask-server-for-new-groups ()
1187   (let* ((new-date (message-make-date))
1188          (date (or gnus-newsrc-last-checked-date new-date))
1189          (methods (cons gnus-select-method
1190                         (nconc
1191                          (when (gnus-archive-server-wanted-p)
1192                            (list "archive"))
1193                          (append
1194                           (and (consp gnus-check-new-newsgroups)
1195                                gnus-check-new-newsgroups)
1196                           gnus-secondary-select-methods))))
1197          (groups 0)
1198          group new-newsgroups got-new method hashtb
1199          gnus-override-subscribe-method)
1200     (unless gnus-killed-hashtb
1201       (gnus-make-hashtable-from-killed))
1202     ;; Go through both primary and secondary select methods and
1203     ;; request new newsgroups.
1204     (while (setq method (gnus-server-get-method nil (pop methods)))
1205       (setq new-newsgroups nil
1206             gnus-override-subscribe-method method)
1207       (when (and (gnus-check-server method)
1208                  (gnus-request-newgroups date method))
1209         (save-excursion
1210           (setq got-new t
1211                 hashtb (gnus-make-hashtable 100))
1212           (set-buffer nntp-server-buffer)
1213           ;; Enter all the new groups into a hashtable.
1214           (gnus-active-to-gnus-format method hashtb 'ignore))
1215         ;; Now all new groups from `method' are in `hashtb'.
1216         (mapatoms
1217          (lambda (group-sym)
1218            (if (or (null (setq group (symbol-name group-sym)))
1219                    (not (boundp group-sym))
1220                    (null (symbol-value group-sym))
1221                    (gnus-gethash group gnus-newsrc-hashtb)
1222                    (member group gnus-zombie-list)
1223                    (member group gnus-killed-list))
1224                ;; The group is already known.
1225                ()
1226              ;; Make this group active.
1227              (when (symbol-value group-sym)
1228                (gnus-set-active group (symbol-value group-sym)))
1229              ;; Check whether we want it or not.
1230              (let ((do-sub (gnus-matches-options-n group)))
1231                (cond
1232                 ((eq do-sub 'subscribe)
1233                  (incf groups)
1234                  (gnus-sethash group group gnus-killed-hashtb)
1235                  (gnus-call-subscribe-functions
1236                   gnus-subscribe-options-newsgroup-method group))
1237                 ((eq do-sub 'ignore)
1238                  nil)
1239                 (t
1240                  (incf groups)
1241                  (gnus-sethash group group gnus-killed-hashtb)
1242                  (if gnus-subscribe-hierarchical-interactive
1243                      (push group new-newsgroups)
1244                    (gnus-call-subscribe-functions
1245                     gnus-subscribe-newsgroup-method group)))))))
1246          hashtb))
1247       (when new-newsgroups
1248         (gnus-subscribe-hierarchical-interactive new-newsgroups)))
1249     (if (> groups 0)
1250         (gnus-message 5 "%d new newsgroup%s arrived"
1251                       groups (if (> groups 1) "s have" " has"))
1252       (gnus-message 5 "No new newsgroups"))
1253     (when got-new
1254       (setq gnus-newsrc-last-checked-date new-date))
1255     got-new))
1256
1257 (defun gnus-check-first-time-used ()
1258   (catch 'ended
1259     ;; First check if any of the following files exist.  If they do,
1260     ;; it's not the first time the user has used Gnus.
1261     (dolist (file (list (concat gnus-current-startup-file ".el")
1262                         (concat gnus-current-startup-file ".eld")
1263                         (concat gnus-startup-file ".el")
1264                         (concat gnus-startup-file ".eld")))
1265       (when (file-exists-p file)
1266         (throw 'ended nil)))
1267     (gnus-message 6 "First time user; subscribing you to default groups")
1268     (unless (gnus-read-active-file-p)
1269       (let ((gnus-read-active-file t))
1270         (gnus-read-active-file)))
1271     (setq gnus-newsrc-last-checked-date (message-make-date))
1272     ;; Subscribe to the default newsgroups.
1273     (let ((groups (or gnus-default-subscribed-newsgroups
1274                       gnus-backup-default-subscribed-newsgroups))
1275           group)
1276       (if (eq groups t)
1277           ;; If t, we subscribe (or not) all groups as if they were new.
1278           (mapatoms
1279            (lambda (sym)
1280              (when (setq group (symbol-name sym))
1281                (let ((do-sub (gnus-matches-options-n group)))
1282                  (cond
1283                   ((eq do-sub 'subscribe)
1284                    (gnus-sethash group group gnus-killed-hashtb)
1285                    (gnus-call-subscribe-functions
1286                     gnus-subscribe-options-newsgroup-method group))
1287                   ((eq do-sub 'ignore)
1288                    nil)
1289                   (t
1290                    (push group gnus-killed-list))))))
1291            gnus-active-hashtb)
1292         (dolist (group groups)
1293           ;; Only subscribe the default groups that are activated.
1294           (when (gnus-active group)
1295             (gnus-group-change-level
1296              group gnus-level-default-subscribed gnus-level-killed)))
1297         (with-current-buffer gnus-group-buffer
1298           ;; Don't error if the group already exists. This happens when a
1299           ;; first-time user types 'F'. -- didier
1300           (gnus-group-make-help-group t))
1301         (when gnus-novice-user
1302           (gnus-message 7 "`A k' to list killed groups"))))))
1303
1304 (defun gnus-subscribe-group (group &optional previous method)
1305   "Subscribe GROUP and put it after PREVIOUS."
1306   (gnus-group-change-level
1307    (if method
1308        (list t group gnus-level-default-subscribed nil nil method)
1309      group)
1310    gnus-level-default-subscribed gnus-level-killed previous t)
1311   t)
1312
1313 ;; `gnus-group-change-level' is the fundamental function for changing
1314 ;; subscription levels of newsgroups.  This might mean just changing
1315 ;; from level 1 to 2, which is pretty trivial, from 2 to 6 or back
1316 ;; again, which subscribes/unsubscribes a group, which is equally
1317 ;; trivial.  Changing from 1-7 to 8-9 means that you kill a group, and
1318 ;; from 8-9 to 1-7 means that you remove the group from the list of
1319 ;; killed (or zombie) groups and add them to the (kinda) subscribed
1320 ;; groups.  And last but not least, moving from 8 to 9 and 9 to 8,
1321 ;; which is trivial.
1322 ;; ENTRY can either be a string (newsgroup name) or a list (if
1323 ;; FROMKILLED is t, it's a list on the format (NUM INFO-LIST),
1324 ;; otherwise it's a list in the format of the `gnus-newsrc-hashtb'
1325 ;; entries.
1326 ;; LEVEL is the new level of the group, OLDLEVEL is the old level and
1327 ;; PREVIOUS is the group (in hashtb entry format) to insert this group
1328 ;; after.
1329 (defun gnus-group-change-level (entry level &optional oldlevel
1330                                       previous fromkilled)
1331   (let (group info active num)
1332     ;; Glean what info we can from the arguments
1333     (if (consp entry)
1334         (if fromkilled (setq group (nth 1 entry))
1335           (setq group (car (nth 2 entry))))
1336       (setq group entry))
1337     (when (and (stringp entry)
1338                oldlevel
1339                (< oldlevel gnus-level-zombie))
1340       (setq entry (gnus-group-entry entry)))
1341     (if (and (not oldlevel)
1342              (consp entry))
1343         (setq oldlevel (gnus-info-level (nth 2 entry)))
1344       (setq oldlevel (or oldlevel gnus-level-killed)))
1345     (when (stringp previous)
1346       (setq previous (gnus-group-entry previous)))
1347
1348     (if (and (>= oldlevel gnus-level-zombie)
1349              (gnus-group-entry group))
1350         ;; We are trying to subscribe a group that is already
1351         ;; subscribed.
1352         ()                              ; Do nothing.
1353
1354       (unless (gnus-ephemeral-group-p group)
1355         (gnus-dribble-enter
1356          (format "(gnus-group-change-level %S %S %S %S %S)"
1357                  group level oldlevel (car (nth 2 previous)) fromkilled)))
1358
1359       ;; Then we remove the newgroup from any old structures, if needed.
1360       ;; If the group was killed, we remove it from the killed or zombie
1361       ;; list.  If not, and it is in fact going to be killed, we remove
1362       ;; it from the newsrc hash table and assoc.
1363       (cond
1364        ((>= oldlevel gnus-level-zombie)
1365         ;; oldlevel could be wrong.
1366         (setq gnus-zombie-list (delete group gnus-zombie-list))
1367         (setq gnus-killed-list (delete group gnus-killed-list)))
1368        (t
1369         (when (and (>= level gnus-level-zombie)
1370                    entry)
1371           (gnus-sethash (car (nth 2 entry)) nil gnus-newsrc-hashtb)
1372           (when (nth 3 entry)
1373             (setcdr (gnus-group-entry (car (nth 3 entry)))
1374                     (cdr entry)))
1375           (setcdr (cdr entry) (cdddr entry)))))
1376
1377       ;; Finally we enter (if needed) the list where it is supposed to
1378       ;; go, and change the subscription level.  If it is to be killed,
1379       ;; we enter it into the killed or zombie list.
1380       (cond
1381        ((>= level gnus-level-zombie)
1382         ;; Remove from the hash table.
1383         (gnus-sethash group nil gnus-newsrc-hashtb)
1384         ;; We do not enter foreign groups into the list of dead
1385         ;; groups.
1386         (unless (gnus-group-foreign-p group)
1387           (if (= level gnus-level-zombie)
1388               (push group gnus-zombie-list)
1389             (if (= oldlevel gnus-level-killed)
1390                 ;; Remove from active hashtb.
1391                 (unintern group gnus-active-hashtb)
1392               ;; Don't add it into killed-list if it was killed.
1393               (push group gnus-killed-list)))))
1394        (t
1395         ;; If the list is to be entered into the newsrc assoc, and
1396         ;; it was killed, we have to create an entry in the newsrc
1397         ;; hashtb format and fix the pointers in the newsrc assoc.
1398         (if (< oldlevel gnus-level-zombie)
1399             ;; It was alive, and it is going to stay alive, so we
1400             ;; just change the level and don't change any pointers or
1401             ;; hash table entries.
1402             (setcar (cdaddr entry) level)
1403           (if (listp entry)
1404               (setq info (cdr entry)
1405                     num (car entry))
1406             (setq active (gnus-active group))
1407             (setq num
1408                   (if active (- (1+ (cdr active)) (car active)) t))
1409             ;; Shorten the select method if possible, if we need to
1410             ;; store it at all (native groups).
1411             (let ((method (gnus-method-simplify
1412                            (or gnus-override-subscribe-method
1413                                (gnus-group-method group)))))
1414               (if method
1415                   (setq info (list group level nil nil method))
1416                 (setq info (list group level nil)))))
1417           (unless previous
1418             (setq previous
1419                   (let ((p gnus-newsrc-alist))
1420                     (while (cddr p)
1421                       (setq p (cdr p)))
1422                     p)))
1423           (setq entry (cons info (cddr previous)))
1424           (if (cdr previous)
1425               (progn
1426                 (setcdr (cdr previous) entry)
1427                 (gnus-sethash group (cons num (cdr previous))
1428                               gnus-newsrc-hashtb))
1429             (setcdr previous entry)
1430             (gnus-sethash group (cons num previous)
1431                           gnus-newsrc-hashtb))
1432           (when (cdr entry)
1433             (setcdr (gnus-group-entry (caadr entry)) entry))
1434           (gnus-dribble-enter
1435            (format
1436             "(gnus-group-set-info '%S)" info)))))
1437       (when gnus-group-change-level-function
1438         (funcall gnus-group-change-level-function
1439                  group level oldlevel previous)))))
1440
1441 (defun gnus-kill-newsgroup (newsgroup)
1442   "Obsolete function.  Kills a newsgroup."
1443   (gnus-group-change-level
1444    (gnus-group-entry newsgroup) gnus-level-killed))
1445
1446 (defun gnus-check-bogus-newsgroups (&optional confirm)
1447   "Remove bogus newsgroups.
1448 If CONFIRM is non-nil, the user has to confirm the deletion of every
1449 newsgroup."
1450   (let ((newsrc (cdr gnus-newsrc-alist))
1451         bogus group entry info)
1452     (gnus-message 5 "Checking bogus newsgroups...")
1453     (unless (gnus-read-active-file-p)
1454       (gnus-read-active-file t))
1455     (when (gnus-read-active-file-p)
1456       ;; Find all bogus newsgroup that are subscribed.
1457       (while newsrc
1458         (setq info (pop newsrc)
1459               group (gnus-info-group info))
1460         (unless (or (gnus-active group) ; Active
1461                     (and (gnus-info-method info)
1462                          (not (gnus-secondary-method-p
1463                                (gnus-info-method info))))) ; Foreign
1464           ;; Found a bogus newsgroup.
1465           (push group bogus)))
1466       (if confirm
1467           (map-y-or-n-p
1468            (format "Remove bogus group %%s (of %d groups)? " (length bogus))
1469            (lambda (group)
1470              ;; Remove all bogus subscribed groups by first killing them, and
1471              ;; then removing them from the list of killed groups.
1472              (when (setq entry (gnus-group-entry group))
1473                (gnus-group-change-level entry gnus-level-killed)
1474                (setq gnus-killed-list (delete group gnus-killed-list))))
1475            bogus '("group" "groups" "remove"))
1476         (while (setq group (pop bogus))
1477           ;; Remove all bogus subscribed groups by first killing them, and
1478           ;; then removing them from the list of killed groups.
1479           (when (setq entry (gnus-group-entry group))
1480             (gnus-group-change-level entry gnus-level-killed)
1481             (setq gnus-killed-list (delete group gnus-killed-list)))))
1482       ;; Then we remove all bogus groups from the list of killed and
1483       ;; zombie groups.  They are removed without confirmation.
1484       (let ((dead-lists '(gnus-killed-list gnus-zombie-list))
1485             killed)
1486         (while dead-lists
1487           (setq killed (symbol-value (car dead-lists)))
1488           (while killed
1489             (unless (gnus-active (setq group (pop killed)))
1490               ;; The group is bogus.
1491               ;; !!!Slow as hell.
1492               (set (car dead-lists)
1493                    (delete group (symbol-value (car dead-lists))))))
1494           (setq dead-lists (cdr dead-lists))))
1495       (gnus-run-hooks 'gnus-check-bogus-groups-hook)
1496       (gnus-message 5 "Checking bogus newsgroups...done"))))
1497
1498 (defun gnus-check-duplicate-killed-groups ()
1499   "Remove duplicates from the list of killed groups."
1500   (interactive)
1501   (let ((killed gnus-killed-list))
1502     (while killed
1503       (gnus-message 9 "%d" (length killed))
1504       (setcdr killed (delete (car killed) (cdr killed)))
1505       (setq killed (cdr killed)))))
1506
1507 ;; We want to inline a function from gnus-cache, so we cheat here:
1508 (defvar gnus-cache-active-hashtb)
1509 (eval-when-compile
1510   (defun gnus-cache-possibly-alter-active (group active)
1511     "Alter the ACTIVE info for GROUP to reflect the articles in the cache."
1512     (when gnus-cache-active-hashtb
1513       (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
1514         (when cache-active
1515           (when (< (car cache-active) (car active))
1516             (setcar active (car cache-active)))
1517           (when (> (cdr cache-active) (cdr active))
1518             (setcdr active (cdr cache-active))))))))
1519
1520 (defun gnus-activate-group (group &optional scan dont-check method
1521                                   dont-sub-check)
1522   "Check whether a group has been activated or not.
1523 If SCAN, request a scan of that group as well."
1524   (let ((method (or method (inline (gnus-find-method-for-group group))))
1525         active)
1526     (and (inline (gnus-check-server method))
1527          ;; We escape all bugs and quit here to make it possible to
1528          ;; continue if a group is so out-there that it reports bugs
1529          ;; and stuff.
1530          (progn
1531            (and scan
1532                 (gnus-check-backend-function 'request-scan (car method))
1533                 (gnus-request-scan group method))
1534            t)
1535          (if (or debug-on-error debug-on-quit)
1536              (inline (gnus-request-group group (or dont-sub-check dont-check)
1537                                          method
1538                                          (gnus-get-info group)))
1539            (condition-case nil
1540                (inline (gnus-request-group group (or dont-sub-check dont-check)
1541                                            method
1542                                            (gnus-get-info group)))
1543              ;;(error nil)
1544              (quit
1545               (message "Quit activating %s" group)
1546               nil)))
1547          (unless dont-check
1548            (setq active (gnus-parse-active))
1549            ;; If there are no articles in the group, the GROUP
1550            ;; command may have responded with the `(0 . 0)'.  We
1551            ;; ignore this if we already have an active entry
1552            ;; for the group.
1553            (if (and (zerop (or (car active) 0))
1554                     (zerop (or (cdr active) 0))
1555                     (gnus-active group))
1556                (gnus-active group)
1557
1558              ;; If a cache is present, we may have to alter the active info.
1559              (when gnus-use-cache
1560                (inline (gnus-cache-possibly-alter-active
1561                         group active)))
1562
1563              ;; If the agent is enabled, we may have to alter the active info.
1564              (when gnus-agent
1565                (gnus-agent-possibly-alter-active group active))
1566
1567              (gnus-set-active group active)
1568              ;; Return the new active info.
1569              active)))))
1570
1571 (defun gnus-get-unread-articles-in-group (info active &optional update)
1572   (when (and info active)
1573     ;; Allow the backend to update the info in the group.
1574     (when (and update
1575                (gnus-request-update-info
1576                 info (inline (gnus-find-method-for-group
1577                               (gnus-info-group info)))))
1578       (gnus-activate-group (gnus-info-group info) nil t))
1579
1580     ;; Allow backends to update marks, 
1581     (when gnus-use-backend-marks
1582       (let ((method (inline (gnus-find-method-for-group
1583                              (gnus-info-group info)))))
1584         (when (gnus-check-backend-function 'request-marks (car method))
1585           (gnus-request-marks info method))))
1586
1587     (let* ((range (gnus-info-read info))
1588            (num 0))
1589
1590       ;; These checks are present in gnus-activate-group but skipped
1591       ;; due to setting dont-check in the preceeding call.
1592
1593       ;; If a cache is present, we may have to alter the active info.
1594       (when (and gnus-use-cache info)
1595         (inline (gnus-cache-possibly-alter-active
1596                  (gnus-info-group info) active)))
1597
1598       ;; If the agent is enabled, we may have to alter the active info.
1599       (when (and gnus-agent info)
1600         (gnus-agent-possibly-alter-active (gnus-info-group info) active info))
1601
1602       ;; Modify the list of read articles according to what articles
1603       ;; are available; then tally the unread articles and add the
1604       ;; number to the group hash table entry.
1605       (cond
1606        ((zerop (cdr active))
1607         (setq num 0))
1608        ((not range)
1609         (setq num (- (1+ (cdr active)) (car active))))
1610        ((not (listp (cdr range)))
1611         ;; Fix a single (num . num) range according to the
1612         ;; active hash table.
1613         ;; Fix by Carsten Bormann <cabo@Informatik.Uni-Bremen.DE>.
1614         (and (< (cdr range) (car active)) (setcdr range (1- (car active))))
1615         (and (> (cdr range) (cdr active)) (setcdr range (cdr active)))
1616         ;; Compute number of unread articles.
1617         (setq num (max 0 (- (cdr active) (- (1+ (cdr range)) (car range))))))
1618        (t
1619         ;; The read list is a list of ranges.  Fix them according to
1620         ;; the active hash table.
1621         ;; First peel off any elements that are below the lower
1622         ;; active limit.
1623         (while (and (cdr range)
1624                     (>= (car active)
1625                         (or (and (atom (cadr range)) (cadr range))
1626                             (caadr range))))
1627           (if (numberp (car range))
1628               (setcar range
1629                       (cons (car range)
1630                             (or (and (numberp (cadr range))
1631                                      (cadr range))
1632                                 (cdadr range))))
1633             (setcdr (car range)
1634                     (or (and (numberp (nth 1 range)) (nth 1 range))
1635                         (cdadr range))))
1636           (setcdr range (cddr range)))
1637         ;; Adjust the first element to be the same as the lower limit.
1638         (when (and (not (atom (car range)))
1639                    (< (cdar range) (car active)))
1640           (setcdr (car range) (1- (car active))))
1641         ;; Then we want to peel off any elements that are higher
1642         ;; than the upper active limit.
1643         (let ((srange range))
1644           ;; Go past all valid elements.
1645           (while (and (cdr srange)
1646                       (<= (or (and (atom (cadr srange))
1647                                    (cadr srange))
1648                               (caadr srange))
1649                           (cdr active)))
1650             (setq srange (cdr srange)))
1651           (when (cdr srange)
1652             ;; Nuke all remaining invalid elements.
1653             (setcdr srange nil))
1654
1655           ;; Adjust the final element.
1656           (when (and (not (atom (car srange)))
1657                      (> (cdar srange) (cdr active)))
1658             (setcdr (car srange) (cdr active))))
1659         ;; Compute the number of unread articles.
1660         (while range
1661           (setq num (+ num (- (1+ (or (and (atom (car range)) (car range))
1662                                       (cdar range)))
1663                               (or (and (atom (car range)) (car range))
1664                                   (caar range)))))
1665           (setq range (cdr range)))
1666         (setq num (max 0 (- (cdr active) num)))))
1667       ;; Set the number of unread articles.
1668       (when (and info
1669                  (gnus-group-entry (gnus-info-group info)))
1670         (setcar (gnus-group-entry (gnus-info-group info)) num))
1671       num)))
1672
1673 ;; Go though `gnus-newsrc-alist' and compare with `gnus-active-hashtb'
1674 ;; and compute how many unread articles there are in each group.
1675 (defun gnus-get-unread-articles (&optional level)
1676   (setq gnus-server-method-cache nil)
1677   (let* ((newsrc (cdr gnus-newsrc-alist))
1678          (alevel (or level gnus-activate-level (1+ gnus-level-subscribed)))
1679          (foreign-level
1680           (or
1681            level
1682            (min
1683             (cond ((and gnus-activate-foreign-newsgroups
1684                         (not (numberp gnus-activate-foreign-newsgroups)))
1685                    (1+ gnus-level-subscribed))
1686                   ((numberp gnus-activate-foreign-newsgroups)
1687                    gnus-activate-foreign-newsgroups)
1688                   (t 0))
1689             alevel)))
1690          (methods-cache nil)
1691          (type-cache nil)
1692          (gnus-agent-article-local-times 0)
1693          (archive-method (gnus-server-to-method "archive"))
1694          infos info group active method cmethod
1695          method-type method-group-list entry)
1696     (gnus-message 6 "Checking new news...")
1697
1698     (while newsrc
1699       (setq active (gnus-active (setq group (gnus-info-group
1700                                              (setq info (pop newsrc))))))
1701       ;; First go through all the groups, see what select methods they
1702       ;; belong to, and then collect them into lists per unique select
1703       ;; method.
1704       (if (not (setq method (gnus-info-method info)))
1705           (setq method gnus-select-method)
1706         ;; There may be several similar methods.  Possibly extend the
1707         ;; method.
1708         (if (setq cmethod (assoc method methods-cache))
1709             (setq method (cdr cmethod))
1710           (setq cmethod (if (stringp method)
1711                             (gnus-server-to-method method)
1712                           (inline (gnus-find-method-for-group
1713                                    (gnus-info-group info) info))))
1714           (push (cons method cmethod) methods-cache)
1715           (setq method cmethod)))
1716       (setq method-group-list (assoc method type-cache))
1717       (unless method-group-list
1718         (setq method-type
1719               (cond
1720                ((or (gnus-secondary-method-p method)
1721                     (and (gnus-archive-server-wanted-p)
1722                          (gnus-methods-equal-p archive-method method)))
1723                 'secondary)
1724                ((inline (gnus-server-equal gnus-select-method method))
1725                 'primary)
1726                (t
1727                 'foreign)))
1728         (push (setq method-group-list (list method method-type nil nil))
1729               type-cache))
1730       ;; Only add groups that need updating.
1731       (if (<= (gnus-info-level info)
1732               (if (eq (cadr method-group-list) 'foreign)
1733                   foreign-level
1734                 alevel))
1735           (setcar (nthcdr 2 method-group-list)
1736                   (cons info (nth 2 method-group-list)))
1737         ;; The group is inactive, so we nix out the number of unread articles.
1738         ;; It leads `(gnus-group-unread group)' to return t.  See also
1739         ;; `gnus-group-prepare-flat'.
1740         (unless active
1741           (when (setq entry (gnus-group-entry group))
1742             (setcar entry t)))))
1743
1744     ;; Sort the methods based so that the primary and secondary
1745     ;; methods come first.  This is done for legacy reasons to try to
1746     ;; ensure that side-effect behaviour doesn't change from previous
1747     ;; Gnus versions.
1748     (setq type-cache
1749           (sort (nreverse type-cache)
1750                 (lambda (c1 c2)
1751                   (< (gnus-method-rank (cadr c1) (car c1))
1752                      (gnus-method-rank (cadr c2) (car c2))))))
1753
1754     ;; Start early async retrieval of data.
1755     (dolist (elem type-cache)
1756       (destructuring-bind (method method-type infos dummy) elem
1757         (when (and method infos
1758                    (not (gnus-method-denied-p method)))
1759           (unless (gnus-server-opened method)
1760             (gnus-open-server method))
1761           (when (and
1762                  (gnus-server-opened method)
1763                  (gnus-check-backend-function
1764                   'retrieve-group-data-early (car method)))
1765             (when (gnus-check-backend-function 'request-scan (car method))
1766               (gnus-request-scan nil method))
1767             (setcar (nthcdr 3 elem)
1768                     (gnus-retrieve-group-data-early method infos))))))
1769
1770     ;; Do the rest of the retrieval.
1771     (dolist (elem type-cache)
1772       (destructuring-bind (method method-type infos early-data) elem
1773         (when (and method infos)
1774           (let ((updatep (gnus-check-backend-function
1775                           'request-update-info (car method))))
1776             ;; See if any of the groups from this method require updating.
1777             (gnus-read-active-for-groups method infos early-data)
1778             (dolist (info infos)
1779               (inline (gnus-get-unread-articles-in-group
1780                        info (gnus-active (gnus-info-group info))
1781                        updatep)))))))
1782     (gnus-message 6 "Checking new news...done")))
1783
1784 (defun gnus-method-rank (type method)
1785   (cond
1786    ;; Get info for virtual groups last.
1787    ((eq (car method) 'nnvirtual)
1788     200)
1789    ((eq type 'primary)
1790     1)
1791    ;; Compute the rank of the secondary methods based on where they
1792    ;; are in the secondary select list.
1793    ((eq type 'secondary)
1794     (let ((i 2))
1795       (block nil
1796         (dolist (smethod gnus-secondary-select-methods)
1797           (when (equal method smethod)
1798             (return i))
1799           (incf i))
1800         i)))
1801    ;; Just say that all foreign groups have the same rank.
1802    (t
1803     100)))
1804
1805 (defun gnus-read-active-for-groups (method infos early-data)
1806   (with-current-buffer nntp-server-buffer
1807     (cond
1808      ((and
1809        (gnus-check-backend-function 'finish-retrieve-group-infos (car method))
1810        (or (not (gnus-agent-method-p method))
1811            (gnus-online method)))
1812       (gnus-finish-retrieve-group-infos method infos early-data)
1813       (gnus-agent-save-active method))
1814      ((gnus-check-backend-function 'retrieve-groups (car method))
1815       (when (gnus-check-backend-function 'request-scan (car method))
1816         (gnus-request-scan nil method))
1817       (let (groups)
1818         (gnus-read-active-file-2
1819          (dolist (info infos (nreverse groups))
1820            (push (gnus-group-real-name (gnus-info-group info)) groups))
1821          method)))
1822      ((gnus-check-backend-function 'request-list (car method))
1823       (gnus-read-active-file-1 method nil infos))
1824      (t
1825       (dolist (info infos)
1826         (gnus-activate-group (gnus-info-group info) nil nil method t))))))
1827
1828 ;; Create a hash table out of the newsrc alist.  The `car's of the
1829 ;; alist elements are used as keys.
1830 (defun gnus-make-hashtable-from-newsrc-alist ()
1831   (let ((alist gnus-newsrc-alist)
1832         (ohashtb gnus-newsrc-hashtb)
1833         prev info method rest methods)
1834     (setq gnus-newsrc-hashtb (gnus-make-hashtable (length alist)))
1835     (setq alist
1836           (setq prev (setq gnus-newsrc-alist
1837                            (if (equal (caar gnus-newsrc-alist)
1838                                       "dummy.group")
1839                                gnus-newsrc-alist
1840                              (cons (list "dummy.group" 0 nil) alist)))))
1841     (while alist
1842       (setq info (car alist))
1843       ;; Make the same select-methods identical Lisp objects.
1844       (when (setq method (gnus-info-method info))
1845         (if (setq rest (member method methods))
1846             (gnus-info-set-method info (car rest))
1847           (push method methods)))
1848       ;; Check for duplicates.
1849       (if (gnus-gethash (car info) gnus-newsrc-hashtb)
1850           ;; Remove this entry from the alist.
1851           (setcdr prev (cddr prev))
1852         (gnus-sethash
1853          (car info)
1854          ;; Preserve number of unread articles in groups.
1855          (cons (and ohashtb (car (gnus-gethash (car info) ohashtb)))
1856                prev)
1857          gnus-newsrc-hashtb)
1858         (setq prev alist))
1859       (setq alist (cdr alist)))
1860     ;; Make the same select-methods in `gnus-server-alist' identical
1861     ;; as well.
1862     (while methods
1863       (setq method (pop methods))
1864       (when (setq rest (rassoc method gnus-server-alist))
1865         (setcdr rest method)))))
1866
1867 (defun gnus-make-hashtable-from-killed ()
1868   "Create a hash table from the killed and zombie lists."
1869   (let ((lists '(gnus-killed-list gnus-zombie-list))
1870         list)
1871     (setq gnus-killed-hashtb
1872           (gnus-make-hashtable
1873            (+ (length gnus-killed-list) (length gnus-zombie-list))))
1874     (while lists
1875       (setq list (symbol-value (pop lists)))
1876       (while list
1877         (gnus-sethash (car list) (pop list) gnus-killed-hashtb)))))
1878
1879 (defun gnus-parse-active ()
1880   "Parse active info in the nntp server buffer."
1881   (with-current-buffer nntp-server-buffer
1882     (goto-char (point-min))
1883     ;; Parse the result we got from `gnus-request-group'.
1884     (when (looking-at "[0-9]+ [0-9]+ \\([0-9]+\\) [0-9]+")
1885       (goto-char (match-beginning 1))
1886       (cons (read (current-buffer))
1887             (read (current-buffer))))))
1888
1889 (defun gnus-make-articles-unread (group articles)
1890   "Mark ARTICLES in GROUP as unread."
1891   (let* ((info (nth 2 (or (gnus-group-entry group)
1892                           (gnus-group-entry
1893                            (gnus-group-real-name group)))))
1894          (ranges (gnus-info-read info))
1895          news article)
1896     (while articles
1897       (when (gnus-member-of-range
1898              (setq article (pop articles)) ranges)
1899         (push article news)))
1900     (when news
1901       ;; Enter this list into the group info.
1902       (gnus-info-set-read
1903        info (gnus-remove-from-range (gnus-info-read info) (nreverse news)))
1904
1905       ;; Set the number of unread articles in gnus-newsrc-hashtb.
1906       (gnus-get-unread-articles-in-group info (gnus-active group))
1907
1908       ;; Insert the change into the group buffer and the dribble file.
1909       (gnus-group-update-group group t))))
1910
1911 (defun gnus-make-ascending-articles-unread (group articles)
1912   "Mark ascending ARTICLES in GROUP as unread."
1913   (let* ((entry (or (gnus-group-entry group)
1914                     (gnus-group-entry (gnus-group-real-name group))))
1915          (info (nth 2 entry))
1916          (ranges (gnus-info-read info))
1917          (r ranges)
1918          modified)
1919
1920     (while articles
1921       (let ((article (pop articles))) ; get the next article to remove from ranges
1922         (while (let ((range (car ranges))) ; note the current range
1923                  (if (atom range)       ; single value range
1924                      (cond ((not range)
1925                             ;; the articles extend past the end of the ranges
1926                             ;; OK - I'm done
1927                             (setq articles nil))
1928                            ((< range article)
1929                             ;; this range preceeds the article. Leave the range unmodified.
1930                             (pop ranges)
1931                             ranges)
1932                            ((= range article)
1933                             ;; this range exactly matches the article; REMOVE THE RANGE.
1934                             ;; NOTE: When the range being removed is the last range, the list is corrupted by inserting null at its end.
1935                             (setcar ranges (cadr ranges))
1936                             (setcdr ranges (cddr ranges))
1937                             (setq modified (if (car ranges) t 'remove-null))
1938                             nil))
1939                    (let ((min (car range))
1940                          (max (cdr range)))
1941                      ;; I have a min/max range to consider
1942                      (cond ((> min max) ; invalid range introduced by splitter
1943                             (setcar ranges (cadr ranges))
1944                             (setcdr ranges (cddr ranges))
1945                             (setq modified (if (car ranges) t 'remove-null))
1946                             ranges)
1947                            ((= min max)
1948                             ;; replace min/max range with a single-value range
1949                             (setcar ranges min)
1950                             ranges)
1951                            ((< max article)
1952                             ;; this range preceeds the article. Leave the range unmodified.
1953                             (pop ranges)
1954                             ranges)
1955                            ((< article min)
1956                             ;; this article preceeds the range.  Return null to move to the
1957                             ;; next article
1958                             nil)
1959                            (t
1960                             ;; this article splits the range into two parts
1961                             (setcdr ranges (cons (cons (1+ article) max) (cdr ranges)))
1962                             (setcdr range (1- article))
1963                             (setq modified t)
1964                             ranges))))))))
1965
1966     (when modified
1967       (when (eq modified 'remove-null)
1968         (setq r (delq nil r)))
1969       ;; Enter this list into the group info.
1970       (gnus-info-set-read info r)
1971
1972       ;; Set the number of unread articles in gnus-newsrc-hashtb.
1973       (gnus-get-unread-articles-in-group info (gnus-active group))
1974
1975       ;; Insert the change into the group buffer and the dribble file.
1976       (gnus-group-update-group group t))))
1977
1978 ;; Enter all dead groups into the hashtb.
1979 (defun gnus-update-active-hashtb-from-killed ()
1980   (let ((hashtb (setq gnus-active-hashtb (gnus-make-hashtable 4096)))
1981         (lists (list gnus-killed-list gnus-zombie-list))
1982         killed)
1983     (while lists
1984       (setq killed (car lists))
1985       (while killed
1986         (gnus-sethash (mm-string-as-unibyte (car killed)) nil hashtb)
1987         (setq killed (cdr killed)))
1988       (setq lists (cdr lists)))))
1989
1990 (defun gnus-get-killed-groups ()
1991   "Go through the active hashtb and mark all unknown groups as killed."
1992   ;; First make sure active file has been read.
1993   (unless (gnus-read-active-file-p)
1994     (let ((gnus-read-active-file t))
1995       (gnus-read-active-file)))
1996   (unless gnus-killed-hashtb
1997     (gnus-make-hashtable-from-killed))
1998   ;; Go through all newsgroups that are known to Gnus - enlarge kill list.
1999   (mapatoms
2000    (lambda (sym)
2001      (let ((groups 0)
2002            (group (symbol-name sym)))
2003        (if (or (null group)
2004                (gnus-gethash group gnus-killed-hashtb)
2005                (gnus-gethash group gnus-newsrc-hashtb))
2006            ()
2007          (let ((do-sub (gnus-matches-options-n group)))
2008            (if (or (eq do-sub 'subscribe) (eq do-sub 'ignore))
2009                ()
2010              (setq groups (1+ groups))
2011              (push group gnus-killed-list)
2012              (gnus-sethash group group gnus-killed-hashtb))))))
2013    gnus-active-hashtb)
2014   (gnus-dribble-touch))
2015
2016 ;; Get the active file(s) from the backend(s).
2017 (defun gnus-read-active-file (&optional force not-native)
2018   (gnus-group-set-mode-line)
2019   (let ((methods
2020          (mapcar
2021           (lambda (m) (if (stringp m) (gnus-server-get-method nil m) m))
2022           (append
2023            (if (and (not not-native)
2024                     (gnus-check-server gnus-select-method))
2025                ;; The native server is available.
2026                (cons gnus-select-method gnus-secondary-select-methods)
2027              ;; The native server is down, so we just do the
2028              ;; secondary ones.
2029              gnus-secondary-select-methods)
2030            ;; Also read from the archive server.
2031            (when (gnus-archive-server-wanted-p)
2032              (list "archive")))))
2033         method)
2034     (setq gnus-have-read-active-file nil)
2035     (with-current-buffer nntp-server-buffer
2036       (while (setq method (pop methods))
2037         ;; Only do each method once, in case the methods appear more
2038         ;; than once in this list.
2039         (unless (member method methods)
2040           (if (or debug-on-error debug-on-quit)
2041               (gnus-read-active-file-1 method force)
2042             (condition-case ()
2043                 (gnus-read-active-file-1 method force)
2044               ;; We catch C-g so that we can continue past servers
2045               ;; that do not respond.
2046               (quit
2047                (message "Quit reading the active file")
2048                nil))))))))
2049
2050 (defun gnus-read-active-file-1 (method force &optional infos)
2051   (let (where mesg)
2052     (setq where (nth 1 method)
2053           mesg (format "Reading active file%s via %s..."
2054                        (if (and where (not (zerop (length where))))
2055                            (concat " from " where) "")
2056                        (car method)))
2057     (gnus-message 5 "%s" mesg)
2058     (when (gnus-check-server method)
2059       ;; Request that the backend scan its incoming messages.
2060       (when (and (or (and gnus-agent
2061                           (gnus-online method))
2062                      (not gnus-agent))
2063                  (gnus-check-backend-function 'request-scan (car method)))
2064         (gnus-request-scan nil method))
2065       (cond
2066        ((and (eq gnus-read-active-file 'some)
2067              (gnus-check-backend-function 'retrieve-groups (car method))
2068              (not force))
2069         (let ((newsrc (cdr gnus-newsrc-alist))
2070               (gmethod (gnus-server-get-method nil method))
2071               groups info)
2072           (while (setq info (pop newsrc))
2073             (when (inline
2074                     (gnus-server-equal
2075                           (inline
2076                             (gnus-find-method-for-group
2077                                   (gnus-info-group info) info))
2078                           gmethod))
2079               (push (gnus-group-real-name (gnus-info-group info))
2080                     groups)))
2081           (gnus-read-active-file-2 groups method)))
2082        ((null method)
2083         t)
2084        (t
2085         (if (not (gnus-request-list method))
2086             (unless (equal method gnus-message-archive-method)
2087               (gnus-error 1 "Cannot read active file from %s server"
2088                           (car method)))
2089           (gnus-message 5 "%s" mesg)
2090           (gnus-active-to-gnus-format method gnus-active-hashtb nil t)
2091           ;; We mark this active file as read.
2092           (push method gnus-have-read-active-file)
2093           (gnus-message 5 "%sdone" mesg)))))))
2094
2095 (defun gnus-read-active-file-2 (groups method)
2096   "Read an active file for GROUPS in METHOD using `gnus-retrieve-groups'."
2097   (when groups
2098     (with-current-buffer nntp-server-buffer
2099       (gnus-check-server method)
2100       (let ((list-type (gnus-retrieve-groups groups method)))
2101         (cond ((not list-type)
2102                (gnus-error
2103                 1.2 "Cannot read partial active file from %s server."
2104                 (car method)))
2105               ((eq list-type 'active)
2106                (gnus-active-to-gnus-format method gnus-active-hashtb nil t))
2107               (t
2108                (gnus-groups-to-gnus-format method gnus-active-hashtb t)))))))
2109
2110 ;; Read an active file and place the results in `gnus-active-hashtb'.
2111 (defun gnus-active-to-gnus-format (&optional method hashtb ignore-errors
2112                                              real-active)
2113   (unless method
2114     (setq method gnus-select-method))
2115   (let ((cur (current-buffer))
2116         (hashtb (or hashtb
2117                     (if (and gnus-active-hashtb
2118                              (not (equal method gnus-select-method)))
2119                         gnus-active-hashtb
2120                       (setq gnus-active-hashtb
2121                             (if (equal method gnus-select-method)
2122                                 (gnus-make-hashtable
2123                                  (count-lines (point-min) (point-max)))
2124                               (gnus-make-hashtable 4096))))))
2125         group max min)
2126     ;; Delete unnecessary lines.
2127     (goto-char (point-min))
2128     (cond
2129      ((string= gnus-ignored-newsgroups "")
2130       (delete-matching-lines "^to\\."))
2131      (t
2132       (delete-matching-lines (concat "^to\\.\\|" gnus-ignored-newsgroups))))
2133
2134     (goto-char (point-min))
2135     (unless (re-search-forward "[\\\"]" nil t)
2136       ;; Make the group names readable as a lisp expression even if they
2137       ;; contain special characters.
2138       (goto-char (point-max))
2139       (while (re-search-backward "[][';?()#]" nil t)
2140         (insert ?\\)))
2141
2142     ;; Let the Gnus agent save the active file.
2143     (when (and gnus-agent real-active (gnus-online method))
2144       (gnus-agent-save-active method))
2145
2146     ;; If these are groups from a foreign select method, we insert the
2147     ;; group prefix in front of the group names.
2148     (when (not (gnus-server-equal
2149                 (gnus-server-get-method nil method)
2150                 (gnus-server-get-method nil gnus-select-method)))
2151       (let ((prefix (gnus-group-prefixed-name "" method)))
2152         (goto-char (point-min))
2153         (while (and (not (eobp))
2154                     (progn
2155                       (when (= (following-char) ?\")
2156                         (forward-char 1))
2157                       (insert prefix)
2158                       (zerop (forward-line 1)))))))
2159     ;; Store the active file in a hash table.
2160     ;; Use a unibyte buffer in order to make `read' read non-ASCII
2161     ;; group names (which have been encoded) as unibyte strings.
2162     (mm-with-unibyte-buffer
2163       (insert-buffer-substring cur)
2164       (setq cur (current-buffer))
2165       (goto-char (point-min))
2166       (while (not (eobp))
2167         (condition-case ()
2168             (progn
2169               (narrow-to-region (point) (point-at-eol))
2170               ;; group gets set to a symbol interned in the hash table
2171               ;; (what a hack!!) - jwz
2172               (setq group (let ((obarray hashtb)) (read cur)))
2173               ;; ### The extended group name scheme makes
2174               ;; the previous optimization strategy sort of pointless...
2175               (when (stringp group)
2176                 (setq group (intern group hashtb)))
2177               (if (and (numberp (setq max (read cur)))
2178                        (numberp (setq min (read cur)))
2179                        (progn
2180                          (skip-chars-forward " \t")
2181                          (not
2182                           (or (eq (char-after) ?=)
2183                               (eq (char-after) ?x)
2184                               (eq (char-after) ?j)))))
2185                   (progn
2186                     (set group (cons min max))
2187                     ;; if group is moderated, stick in moderation table
2188                     (when (eq (char-after) ?m)
2189                       (unless gnus-moderated-hashtb
2190                         (setq gnus-moderated-hashtb (gnus-make-hashtable)))
2191                       (gnus-sethash (symbol-name group) t
2192                                     gnus-moderated-hashtb)))
2193                 (set group nil)))
2194           (error
2195            (and group
2196                 (symbolp group)
2197                 (set group nil))
2198            (unless ignore-errors
2199              (gnus-message 3 "Warning - invalid active: %s"
2200                            (buffer-substring
2201                             (point-at-bol) (point-at-eol))))))
2202         (widen)
2203         (forward-line 1)))))
2204
2205 (defun gnus-groups-to-gnus-format (method &optional hashtb real-active)
2206   ;; Parse a "groups" active file.
2207   (let ((cur (current-buffer))
2208         (hashtb (or hashtb
2209                     (if (and method gnus-active-hashtb)
2210                         gnus-active-hashtb
2211                       (setq gnus-active-hashtb
2212                             (gnus-make-hashtable
2213                              (count-lines (point-min) (point-max)))))))
2214         (prefix (and method
2215                      (not (gnus-server-equal
2216                            (gnus-server-get-method nil method)
2217                            (gnus-server-get-method nil gnus-select-method)))
2218                      (gnus-group-prefixed-name "" method))))
2219
2220     ;; Let the Gnus agent save the active file.
2221     (if (and gnus-agent
2222              real-active
2223              (gnus-online method)
2224              (gnus-agent-method-p method))
2225         (progn
2226           (gnus-agent-save-active method)
2227           (gnus-active-to-gnus-format method hashtb nil real-active))
2228
2229       (goto-char (point-min))
2230       ;; We split this into to separate loops, one with the prefix
2231       ;; and one without to speed the reading up somewhat.
2232       (if prefix
2233           (let (min max opoint group)
2234             (while (not (eobp))
2235               (condition-case ()
2236                   (progn
2237                     (read cur) (read cur)
2238                     (setq min (read cur)
2239                           max (read cur)
2240                           opoint (point))
2241                     (skip-chars-forward " \t")
2242                     (insert prefix)
2243                     (goto-char opoint)
2244                     (set (let ((obarray hashtb)) (read cur))
2245                          (cons min max)))
2246                 (error (and group (symbolp group) (set group nil))))
2247               (forward-line 1)))
2248         (let (min max group)
2249           (while (not (eobp))
2250             (condition-case ()
2251                 (when (eq (char-after) ?2)
2252                   (read cur) (read cur)
2253                   (setq min (read cur)
2254                         max (read cur))
2255                   (set (setq group (let ((obarray hashtb)) (read cur)))
2256                        (cons min max)))
2257               (error (and group (symbolp group) (set group nil))))
2258             (forward-line 1)))))))
2259
2260 (defun gnus-read-newsrc-file (&optional force)
2261   "Read startup file.
2262 If FORCE is non-nil, the .newsrc file is read."
2263   ;; Reset variables that might be defined in the .newsrc.eld file.
2264   (let ((variables (remove 'gnus-format-specs gnus-variable-list)))
2265     (while variables
2266       (set (car variables) nil)
2267       (setq variables (cdr variables))))
2268   (let* ((newsrc-file gnus-current-startup-file)
2269          (quick-file (concat newsrc-file ".el")))
2270     (save-excursion
2271       ;; We always load the .newsrc.eld file.  If always contains
2272       ;; much information that can not be gotten from the .newsrc
2273       ;; file (ticked articles, killed groups, foreign methods, etc.)
2274       (gnus-read-newsrc-el-file quick-file)
2275
2276       (when (and gnus-read-newsrc-file
2277                  (file-exists-p gnus-current-startup-file)
2278                  (or force
2279                      (and (file-newer-than-file-p newsrc-file quick-file)
2280                           (file-newer-than-file-p newsrc-file
2281                                                   (concat quick-file "d")))
2282                      (not gnus-newsrc-alist)))
2283         ;; We read the .newsrc file.  Note that if there if a
2284         ;; .newsrc.eld file exists, it has already been read, and
2285         ;; the `gnus-newsrc-hashtb' has been created.  While reading
2286         ;; the .newsrc file, Gnus will only use the information it
2287         ;; can find there for changing the data already read -
2288         ;; i. e., reading the .newsrc file will not trash the data
2289         ;; already read (except for read articles).
2290         (save-excursion
2291           (gnus-message 5 "Reading %s..." newsrc-file)
2292           (set-buffer (nnheader-find-file-noselect newsrc-file))
2293           (buffer-disable-undo)
2294           (gnus-newsrc-to-gnus-format)
2295           (kill-buffer (current-buffer))
2296           (gnus-message 5 "Reading %s...done" newsrc-file)))
2297
2298       ;; Convert old to new.
2299       (gnus-convert-old-newsrc))))
2300
2301 (defun gnus-convert-old-newsrc ()
2302   "Convert old newsrc formats into the current format, if needed."
2303   (let ((fcv (and gnus-newsrc-file-version
2304                   (gnus-continuum-version gnus-newsrc-file-version)))
2305         (gcv (gnus-continuum-version)))
2306     (when fcv
2307       ;; A newsrc file was loaded.
2308       (let (prompt-displayed
2309             (converters
2310              (sort
2311               (mapcar (lambda (date-func)
2312                         (cons (gnus-continuum-version (car date-func))
2313                               date-func))
2314                       ;; This is a list of converters that must be run
2315                       ;; to bring the newsrc file up to the current
2316                       ;; version.  If you create an incompatibility
2317                       ;; with older versions, you should create an
2318                       ;; entry here.  The entry should consist of the
2319                       ;; current gnus version (hardcoded so that it
2320                       ;; doesn't change with each release) and the
2321                       ;; function that must be applied to convert the
2322                       ;; previous version into the current version.
2323                       '(("September Gnus v0.1" nil
2324                          gnus-convert-old-ticks)
2325                         ("Oort Gnus v0.08"     "legacy-gnus-agent"
2326                          gnus-agent-convert-to-compressed-agentview)
2327                         ("Gnus v5.10.7"        "legacy-gnus-agent"
2328                          gnus-agent-unlist-expire-days)
2329                         ("Gnus v5.10.7"        "legacy-gnus-agent"
2330                          gnus-agent-unhook-expire-days)))
2331               #'car-less-than-car)))
2332         ;; Skip converters older than the file version
2333         (while (and converters (>= fcv (caar converters)))
2334           (pop converters))
2335
2336         ;; Perform converters to bring older version up to date.
2337         (when (and converters (< fcv (caar converters)))
2338           (while (and converters (< fcv (caar converters))
2339                       (<= (caar converters) gcv))
2340             (let* ((converter-spec  (pop converters))
2341                    (convert-to      (nth 1 converter-spec))
2342                    (load-from       (nth 2 converter-spec))
2343                    (func            (nth 3 converter-spec)))
2344               (when (and load-from
2345                          (not (fboundp func)))
2346                 (load load-from t))
2347               (or prompt-displayed
2348                   (not (gnus-convert-converter-needs-prompt func))
2349                   (while (let (c
2350                                (cursor-in-echo-area t)
2351                                (echo-keystrokes 0))
2352                            (message "Convert gnus from version '%s' to '%s'? (n/y/?)"
2353                                     gnus-newsrc-file-version gnus-version)
2354                            (setq c (read-char-exclusive))
2355
2356                            (cond ((or (eq c ?n) (eq c ?N))
2357                                   (error "Can not start gnus without converting"))
2358                                  ((or (eq c ?y) (eq c ?Y))
2359                                   (setq prompt-displayed t)
2360                                   nil)
2361                                  ((eq c ?\?)
2362                                   (message "This conversion is irreversible. \
2363  To be safe, you should backup your files before proceeding.")
2364                                   (sit-for 5)
2365                                   t)
2366                                  (t
2367                                   (gnus-message 3 "Ignoring unexpected input")
2368                                   (sit-for 3)
2369                                   t)))))
2370
2371               (funcall func convert-to)))
2372           (gnus-dribble-enter
2373            (format ";Converted gnus from version '%s' to '%s'."
2374                    gnus-newsrc-file-version gnus-version)))))))
2375
2376 (defun gnus-convert-mark-converter-prompt (converter no-prompt)
2377   "Indicate whether CONVERTER requires gnus-convert-old-newsrc to
2378   display the conversion prompt.  NO-PROMPT may be nil (prompt),
2379   t (no prompt), or any form that can be called as a function.
2380   The form should return either t or nil."
2381   (put converter 'gnus-convert-no-prompt no-prompt))
2382
2383 (defun gnus-convert-converter-needs-prompt (converter)
2384   (let ((no-prompt (get converter 'gnus-convert-no-prompt)))
2385     (not (if (memq no-prompt '(t nil))
2386              no-prompt
2387            (funcall no-prompt)))))
2388
2389 (defun gnus-convert-old-ticks (converting-to)
2390   (let ((newsrc (cdr gnus-newsrc-alist))
2391         marks info dormant ticked)
2392     (while (setq info (pop newsrc))
2393       (when (setq marks (gnus-info-marks info))
2394         (setq dormant (cdr (assq 'dormant marks))
2395               ticked (cdr (assq 'tick marks)))
2396         (when (or dormant ticked)
2397           (gnus-info-set-read
2398            info
2399            (gnus-add-to-range
2400             (gnus-info-read info)
2401             (nconc (gnus-uncompress-range dormant)
2402                    (gnus-uncompress-range ticked)))))))))
2403
2404 (defun gnus-load (file)
2405   "Load FILE, but in such a way that read errors can be reported."
2406   (with-temp-buffer
2407     (insert-file-contents file)
2408     (while (not (eobp))
2409       (condition-case type
2410           (let ((form (read (current-buffer))))
2411             (eval form))
2412         (error
2413          (unless (eq (car type) 'end-of-file)
2414            (let ((errmsg (format "Error in %s line %d" file
2415                                  (count-lines (point-min) (point)))))
2416              (ding)
2417              (unless (gnus-yes-or-no-p (concat errmsg "; continue? "))
2418                (error "%s" errmsg)))))))))
2419
2420 (defun gnus-read-newsrc-el-file (file)
2421   (let ((ding-file (concat file "d")))
2422     (when (file-exists-p ding-file)
2423       ;; We always, always read the .eld file.
2424       (gnus-message 5 "Reading %s..." ding-file)
2425       (let (gnus-newsrc-assoc)
2426         (gnus-load ding-file)
2427         ;; Older versions of `gnus-format-specs' are no longer valid
2428         ;; in Oort Gnus 0.01.
2429         (let ((version
2430                (and gnus-newsrc-file-version
2431                     (gnus-continuum-version gnus-newsrc-file-version))))
2432           (when (or (not version)
2433                     (< version 5.090009))
2434             (setq gnus-format-specs gnus-default-format-specs)))
2435         (when gnus-newsrc-assoc
2436           (setq gnus-newsrc-alist gnus-newsrc-assoc))))
2437     (dolist (elem gnus-newsrc-alist)
2438       (setcar elem (mm-string-as-unibyte (car elem))))
2439     (gnus-make-hashtable-from-newsrc-alist)
2440     (when (file-newer-than-file-p file ding-file)
2441       ;; Old format quick file
2442       (gnus-message 5 "Reading %s..." file)
2443       ;; The .el file is newer than the .eld file, so we read that one
2444       ;; as well.
2445       (gnus-read-old-newsrc-el-file file)))
2446   (gnus-run-hooks 'gnus-read-newsrc-el-hook))
2447
2448 ;; Parse the old-style quick startup file
2449 (defun gnus-read-old-newsrc-el-file (file)
2450   (let (newsrc killed marked group m info)
2451     (prog1
2452         (let ((gnus-killed-assoc nil)
2453               gnus-marked-assoc gnus-newsrc-alist gnus-newsrc-assoc)
2454           (prog1
2455               (ignore-errors
2456                 (load file t t t))
2457             (setq newsrc gnus-newsrc-assoc
2458                   killed gnus-killed-assoc
2459                   marked gnus-marked-assoc)))
2460       (setq gnus-newsrc-alist nil)
2461       (while (setq group (pop newsrc))
2462         (if (setq info (gnus-get-info (car group)))
2463             (progn
2464               (gnus-info-set-read info (cddr group))
2465               (gnus-info-set-level
2466                info (if (nth 1 group) gnus-level-default-subscribed
2467                       gnus-level-default-unsubscribed))
2468               (push info gnus-newsrc-alist))
2469           (push (setq info
2470                       (list (car group)
2471                             (if (nth 1 group) gnus-level-default-subscribed
2472                               gnus-level-default-unsubscribed)
2473                             (cddr group)))
2474                 gnus-newsrc-alist))
2475         ;; Copy marks into info.
2476         (when (setq m (assoc (car group) marked))
2477           (unless (nthcdr 3 info)
2478             (nconc info (list nil)))
2479           (gnus-info-set-marks
2480            info (list (cons 'tick (gnus-compress-sequence
2481                                    (sort (cdr m) '<) t))))))
2482       (setq newsrc killed)
2483       (while newsrc
2484         (setcar newsrc (caar newsrc))
2485         (setq newsrc (cdr newsrc)))
2486       (setq gnus-killed-list killed))
2487     ;; The .el file version of this variable does not begin with
2488     ;; "options", while the .eld version does, so we just add it if it
2489     ;; isn't there.
2490     (when
2491         gnus-newsrc-options
2492       (when (not (string-match "^ *options" gnus-newsrc-options))
2493         (setq gnus-newsrc-options (concat "options " gnus-newsrc-options)))
2494       (when (not (string-match "\n$" gnus-newsrc-options))
2495         (setq gnus-newsrc-options (concat gnus-newsrc-options "\n")))
2496       ;; Finally, if we read some options lines, we parse them.
2497       (unless (string= gnus-newsrc-options "")
2498         (gnus-newsrc-parse-options gnus-newsrc-options)))
2499
2500     (setq gnus-newsrc-alist (nreverse gnus-newsrc-alist))
2501     (gnus-make-hashtable-from-newsrc-alist)))
2502
2503 (defun gnus-make-newsrc-file (file)
2504   "Make server dependent file name by catenating FILE and server host name."
2505   (let* ((file (expand-file-name file nil))
2506          (real-file (concat file "-" (nth 1 gnus-select-method))))
2507     (if (or (file-exists-p real-file)
2508             (file-exists-p (concat real-file ".el"))
2509             (file-exists-p (concat real-file ".eld")))
2510         real-file
2511       file)))
2512
2513 (defun gnus-newsrc-to-gnus-format ()
2514   (setq gnus-newsrc-options "")
2515   (setq gnus-newsrc-options-n nil)
2516
2517   (unless gnus-active-hashtb
2518     (setq gnus-active-hashtb (gnus-make-hashtable 4096)))
2519   (let ((buf (current-buffer))
2520         (already-read (> (length gnus-newsrc-alist) 1))
2521         group subscribed options-symbol newsrc Options-symbol
2522         symbol reads num1)
2523     (goto-char (point-min))
2524     ;; We intern the symbol `options' in the active hashtb so that we
2525     ;; can `eq' against it later.
2526     (set (setq options-symbol (intern "options" gnus-active-hashtb)) nil)
2527     (set (setq Options-symbol (intern "Options" gnus-active-hashtb)) nil)
2528
2529     (while (not (eobp))
2530       ;; We first read the first word on the line by narrowing and
2531       ;; then reading into `gnus-active-hashtb'.  Most groups will
2532       ;; already exist in that hashtb, so this will save some string
2533       ;; space.
2534       (narrow-to-region
2535        (point)
2536        (progn (skip-chars-forward "^ \t!:\n") (point)))
2537       (goto-char (point-min))
2538       (setq symbol
2539             (and (/= (point-min) (point-max))
2540                  (let ((obarray gnus-active-hashtb)) (read buf))))
2541       (widen)
2542       ;; Now, the symbol we have read is either `options' or a group
2543       ;; name.  If it is an options line, we just add it to a string.
2544       (cond
2545        ((or (eq symbol options-symbol)
2546             (eq symbol Options-symbol))
2547         (setq gnus-newsrc-options
2548               ;; This concating is quite inefficient, but since our
2549               ;; thorough studies show that approx 99.37% of all
2550               ;; .newsrc files only contain a single options line, we
2551               ;; don't give a damn, frankly, my dear.
2552               (concat gnus-newsrc-options
2553                       (buffer-substring
2554                        (point-at-bol)
2555                        ;; Options may continue on the next line.
2556                        (or (and (re-search-forward "^[^ \t]" nil 'move)
2557                                 (point-at-bol))
2558                            (point)))))
2559         (forward-line -1))
2560        (symbol
2561         ;; Group names can be just numbers.
2562         (when (numberp symbol)
2563           (setq symbol (intern (int-to-string symbol) gnus-active-hashtb)))
2564         (unless (boundp symbol)
2565           (set symbol nil))
2566         ;; It was a group name.
2567         (setq subscribed (eq (char-after) ?:)
2568               group (symbol-name symbol)
2569               reads nil)
2570         (if (eolp)
2571             ;; If the line ends here, this is clearly a buggy line, so
2572             ;; we put point a the beginning of line and let the cond
2573             ;; below do the error handling.
2574             (beginning-of-line)
2575           ;; We skip to the beginning of the ranges.
2576           (skip-chars-forward "!: \t"))
2577         ;; We are now at the beginning of the list of read articles.
2578         ;; We read them range by range.
2579         (while
2580             (cond
2581              ((looking-at "[0-9]+")
2582               ;; We narrow and read a number instead of buffer-substring/
2583               ;; string-to-number because it's faster.  narrow/widen is
2584               ;; faster than save-restriction/narrow, and save-restriction
2585               ;; produces a garbage object.
2586               (setq num1 (progn
2587                            (narrow-to-region (match-beginning 0) (match-end 0))
2588                            (read buf)))
2589               (widen)
2590               ;; If the next character is a dash, then this is a range.
2591               (if (eq (char-after) ?-)
2592                   (progn
2593                     ;; We read the upper bound of the range.
2594                     (forward-char 1)
2595                     (if (not (looking-at "[0-9]+"))
2596                         ;; This is a buggy line, by we pretend that
2597                         ;; it's kinda OK.  Perhaps the user should be
2598                         ;; dinged?
2599                         (push num1 reads)
2600                       (push
2601                        (cons num1
2602                              (progn
2603                                (narrow-to-region (match-beginning 0)
2604                                                  (match-end 0))
2605                                (read buf)))
2606                        reads)
2607                       (widen)))
2608                 ;; It was just a simple number, so we add it to the
2609                 ;; list of ranges.
2610                 (push num1 reads))
2611               ;; If the next char in ?\n, then we have reached the end
2612               ;; of the line and return nil.
2613               (not (eq (char-after) ?\n)))
2614              ((eq (char-after) ?\n)
2615               ;; End of line, so we end.
2616               nil)
2617              (t
2618               ;; Not numbers and not eol, so this might be a buggy
2619               ;; line...
2620               (unless (eobp)
2621                 ;; If it was eob instead of ?\n, we allow it.
2622                 ;; The line was buggy.
2623                 (setq group nil)
2624                 (gnus-error 3.1 "Mangled line: %s"
2625                             (buffer-substring (point-at-bol)
2626                                               (point-at-eol))))
2627               nil))
2628           ;; Skip past ", ".  Spaces are invalid in these ranges, but
2629           ;; we allow them, because it's a common mistake to put a
2630           ;; space after the comma.
2631           (skip-chars-forward ", "))
2632
2633         ;; We have already read .newsrc.eld, so we gently update the
2634         ;; data in the hash table with the information we have just
2635         ;; read.
2636         (when group
2637           (let ((info (gnus-get-info group))
2638                 level)
2639             (if info
2640                 ;; There is an entry for this file in the alist.
2641                 (progn
2642                   (gnus-info-set-read info (nreverse reads))
2643                   ;; We update the level very gently.  In fact, we
2644                   ;; only change it if there's been a status change
2645                   ;; from subscribed to unsubscribed, or vice versa.
2646                   (setq level (gnus-info-level info))
2647                   (cond ((and (<= level gnus-level-subscribed)
2648                               (not subscribed))
2649                          (setq level (if reads
2650                                          gnus-level-default-unsubscribed
2651                                        (1+ gnus-level-default-unsubscribed))))
2652                         ((and (> level gnus-level-subscribed) subscribed)
2653                          (setq level gnus-level-default-subscribed)))
2654                   (gnus-info-set-level info level))
2655               ;; This is a new group.
2656               (setq info (list group
2657                                (if subscribed
2658                                    gnus-level-default-subscribed
2659                                  (if reads
2660                                      (1+ gnus-level-subscribed)
2661                                    gnus-level-default-unsubscribed))
2662                                (nreverse reads))))
2663             (push info newsrc)))))
2664       (forward-line 1))
2665
2666     (setq newsrc (nreverse newsrc))
2667
2668     (if (not already-read)
2669         ()
2670       ;; We now have two newsrc lists - `newsrc', which is what we
2671       ;; have read from .newsrc, and `gnus-newsrc-alist', which is
2672       ;; what we've read from .newsrc.eld.  We have to merge these
2673       ;; lists.  We do this by "attaching" any (foreign) groups in the
2674       ;; gnus-newsrc-alist to the (native) group that precedes them.
2675       (let ((rc (cdr gnus-newsrc-alist))
2676             (prev gnus-newsrc-alist)
2677             entry mentry)
2678         (while rc
2679           (or (null (nth 4 (car rc)))   ; It's a native group.
2680               (assoc (caar rc) newsrc)  ; It's already in the alist.
2681               (if (setq entry (assoc (caar prev) newsrc))
2682                   (setcdr (setq mentry (memq entry newsrc))
2683                           (cons (car rc) (cdr mentry)))
2684                 (push (car rc) newsrc)))
2685           (setq prev rc
2686                 rc (cdr rc)))))
2687
2688     (setq gnus-newsrc-alist newsrc)
2689     ;; We make the newsrc hashtb.
2690     (gnus-make-hashtable-from-newsrc-alist)
2691
2692     ;; Finally, if we read some options lines, we parse them.
2693     (unless (string= gnus-newsrc-options "")
2694       (gnus-newsrc-parse-options gnus-newsrc-options))))
2695
2696 ;; Parse options lines to find "options -n !all rec.all" and stuff.
2697 ;; The return value will be a list on the form
2698 ;; ((regexp1 . ignore)
2699 ;;  (regexp2 . subscribe)...)
2700 ;; When handling new newsgroups, groups that match a `ignore' regexp
2701 ;; will be ignored, and groups that match a `subscribe' regexp will be
2702 ;; subscribed.  A line like
2703 ;; options -n !all rec.all
2704 ;; will lead to a list that looks like
2705 ;; (("^rec\\..+" . subscribe)
2706 ;;  ("^.+" . ignore))
2707 ;; So all "rec.*" groups will be subscribed, while all the other
2708 ;; groups will be ignored.  Note that "options -n !all rec.all" is very
2709 ;; different from "options -n rec.all !all".
2710 (defun gnus-newsrc-parse-options (options)
2711   (let (out eol)
2712     (save-excursion
2713       (gnus-set-work-buffer)
2714       (insert (regexp-quote options))
2715       ;; First we treat all continuation lines.
2716       (goto-char (point-min))
2717       (while (re-search-forward "\n[ \t]+" nil t)
2718         (replace-match " " t t))
2719       ;; Then we transform all "all"s into ".+"s.
2720       (goto-char (point-min))
2721       (while (re-search-forward "\\ball\\b" nil t)
2722         (replace-match ".+" t t))
2723       (goto-char (point-min))
2724       ;; We remove all other options than the "-n" ones.
2725       (while (re-search-forward "[ \t]-[^n][^-]*" nil t)
2726         (replace-match " ")
2727         (forward-char -1))
2728       (goto-char (point-min))
2729
2730       ;; We are only interested in "options -n" lines - we
2731       ;; ignore the other option lines.
2732       (while (re-search-forward "[ \t]-n" nil t)
2733         (setq eol
2734               (or (save-excursion
2735                     (and (re-search-forward "[ \t]-n" (point-at-eol) t)
2736                          (- (point) 2)))
2737                   (point-at-eol)))
2738         ;; Search for all "words"...
2739         (while (re-search-forward "[^ \t,\n]+" eol t)
2740           (if (eq (char-after (match-beginning 0)) ?!)
2741               ;; If the word begins with a bang (!), this is a "not"
2742               ;; spec.  We put this spec (minus the bang) and the
2743               ;; symbol `ignore' into the list.
2744               (push (cons (concat
2745                            "^" (buffer-substring
2746                                 (1+ (match-beginning 0))
2747                                 (match-end 0))
2748                            "\\($\\|\\.\\)")
2749                           'ignore)
2750                     out)
2751             ;; There was no bang, so this is a "yes" spec.
2752             (push (cons (concat "^" (match-string 0) "\\($\\|\\.\\)")
2753                         'subscribe)
2754                   out))))
2755
2756       (setq gnus-newsrc-options-n out))))
2757
2758 (eval-and-compile
2759   (defalias 'gnus-long-file-names
2760     (if (fboundp 'msdos-long-file-names)
2761       'msdos-long-file-names
2762       (lambda () t))))
2763
2764 (defun gnus-save-newsrc-file (&optional force)
2765   "Save .newsrc file."
2766   ;; Note: We cannot save .newsrc file if all newsgroups are removed
2767   ;; from the variable gnus-newsrc-alist.
2768   (when (and (or gnus-newsrc-alist gnus-killed-list)
2769              gnus-current-startup-file)
2770     ;; Save agent range limits for the currently active method.
2771     (when gnus-agent
2772       (gnus-agent-save-local force))
2773
2774     (save-excursion
2775       (if (and (or gnus-use-dribble-file gnus-slave)
2776                (not force)
2777                (or (not gnus-dribble-buffer)
2778                    (not (buffer-name gnus-dribble-buffer))
2779                    (zerop (with-current-buffer gnus-dribble-buffer
2780                             (buffer-size)))))
2781           (gnus-message 4 "(No changes need to be saved)")
2782         (gnus-run-hooks 'gnus-save-newsrc-hook)
2783         (if gnus-slave
2784             (gnus-slave-save-newsrc)
2785           ;; Save .newsrc.
2786           (when gnus-save-newsrc-file
2787             (gnus-message 8 "Saving %s..." gnus-current-startup-file)
2788             (gnus-gnus-to-newsrc-format)
2789             (gnus-message 8 "Saving %s...done" gnus-current-startup-file))
2790
2791           ;; Save .newsrc.eld.
2792           (set-buffer (gnus-get-buffer-create " *Gnus-newsrc*"))
2793           (make-local-variable 'version-control)
2794           (setq version-control gnus-backup-startup-file)
2795           (setq buffer-file-name
2796                 (concat gnus-current-startup-file ".eld"))
2797           (setq default-directory (file-name-directory buffer-file-name))
2798           (buffer-disable-undo)
2799           (erase-buffer)
2800           (gnus-message 5 "Saving %s.eld..." gnus-current-startup-file)
2801
2802           (if gnus-save-startup-file-via-temp-buffer
2803               (let ((coding-system-for-write gnus-ding-file-coding-system)
2804                     (standard-output (current-buffer)))
2805                 (gnus-gnus-to-quick-newsrc-format)
2806                 (gnus-run-hooks 'gnus-save-quick-newsrc-hook)
2807                 (save-buffer))
2808             (let ((coding-system-for-write gnus-ding-file-coding-system)
2809                   (version-control gnus-backup-startup-file)
2810                   (startup-file (concat gnus-current-startup-file ".eld"))
2811                   (working-dir (file-name-directory gnus-current-startup-file))
2812                   working-file
2813                   (i -1))
2814               ;; Generate the name of a non-existent file.
2815               (while (progn (setq working-file
2816                                   (format
2817                                    (if (and (eq system-type 'ms-dos)
2818                                             (not (gnus-long-file-names)))
2819                                        "%s#%d.tm#" ; MSDOS limits files to 8+3
2820                                      "%s#tmp#%d")
2821                                    working-dir (setq i (1+ i))))
2822                             (file-exists-p working-file)))
2823
2824               (unwind-protect
2825                   (progn
2826                     (gnus-with-output-to-file working-file
2827                       (gnus-gnus-to-quick-newsrc-format)
2828                       (gnus-run-hooks 'gnus-save-quick-newsrc-hook))
2829
2830                     ;; These bindings will mislead the current buffer
2831                     ;; into thinking that it is visiting the startup
2832                     ;; file.
2833                     (let ((buffer-backed-up nil)
2834                           (buffer-file-name startup-file)
2835                           (file-precious-flag t)
2836                           (setmodes (file-modes startup-file)))
2837                       ;; Backup the current version of the startup file.
2838                       (backup-buffer)
2839
2840                       ;; Replace the existing startup file with the temp file.
2841                       (rename-file working-file startup-file t)
2842                       (gnus-set-file-modes startup-file setmodes)))
2843                 (condition-case nil
2844                     (delete-file working-file)
2845                   (file-error nil)))))
2846
2847           (gnus-kill-buffer (current-buffer))
2848           (gnus-message
2849            5 "Saving %s.eld...done" gnus-current-startup-file))
2850         (gnus-dribble-delete-file)
2851         (gnus-group-set-mode-line)))))
2852
2853 (defun gnus-gnus-to-quick-newsrc-format (&optional minimal name &rest specific-variables)
2854   "Print Gnus variables such as `gnus-newsrc-alist' in Lisp format."
2855     (princ (format ";; -*- mode:emacs-lisp; coding: %s; -*-\n"
2856                    gnus-ding-file-coding-system))
2857     (if name
2858         (princ (format ";; %s\n" name))
2859       (princ ";; Gnus startup file.\n"))
2860
2861     (unless minimal
2862       (princ "\
2863 ;; Never delete this file -- if you want to force Gnus to read the
2864 ;; .newsrc file (if you have one), touch .newsrc instead.\n")
2865       (princ "(setq gnus-newsrc-file-version ")
2866       (princ (gnus-prin1-to-string gnus-version))
2867       (princ ")\n"))
2868
2869     (let* ((print-quoted t)
2870            (print-readably t)
2871            (print-escape-multibyte nil)
2872            (print-escape-nonascii t)
2873            (print-length nil)
2874            (print-level nil)
2875            (print-circle nil)
2876            (print-escape-newlines t)
2877            (gnus-killed-list
2878             (if (and gnus-save-killed-list
2879                      (stringp gnus-save-killed-list))
2880                 (gnus-strip-killed-list)
2881               gnus-killed-list))
2882            (variables
2883             (or specific-variables
2884                 (if gnus-save-killed-list gnus-variable-list
2885                   ;; Remove the `gnus-killed-list' from the list of variables
2886                   ;; to be saved, if required.
2887                   (delq 'gnus-killed-list (copy-sequence gnus-variable-list)))))
2888            ;; Peel off the "dummy" group.
2889            (gnus-newsrc-alist (cdr gnus-newsrc-alist))
2890            variable)
2891       ;; Insert the variables into the file.
2892       (while variables
2893         (when (and (boundp (setq variable (pop variables)))
2894                    (symbol-value variable))
2895           (princ "\n(setq ")
2896           (princ (symbol-name variable))
2897           (princ " '")
2898           (prin1 (symbol-value variable))
2899           (princ ")\n")))))
2900
2901 (defun gnus-strip-killed-list ()
2902   "Return the killed list minus the groups that match `gnus-save-killed-list'."
2903   (let ((list gnus-killed-list)
2904         olist)
2905     (while list
2906       (when (string-match gnus-save-killed-list (car list))
2907         (push (car list) olist))
2908       (pop list))
2909     (nreverse olist)))
2910
2911 (defun gnus-gnus-to-newsrc-format ()
2912   ;; Generate and save the .newsrc file.
2913   (with-current-buffer (create-file-buffer gnus-current-startup-file)
2914     (let ((newsrc (cdr gnus-newsrc-alist))
2915           (standard-output (current-buffer))
2916           info ranges range method)
2917       (setq buffer-file-name gnus-current-startup-file)
2918       (setq default-directory (file-name-directory buffer-file-name))
2919       (buffer-disable-undo)
2920       (erase-buffer)
2921       ;; Use a unibyte buffer since group names are unibyte strings;
2922       ;; in particular, non-ASCII group names are the ones encoded by
2923       ;; a certain coding system.
2924       (mm-disable-multibyte)
2925       ;; Write options.
2926       (when gnus-newsrc-options
2927         (insert gnus-newsrc-options))
2928       ;; Write subscribed and unsubscribed.
2929       (while (setq info (pop newsrc))
2930         ;; Don't write foreign groups to .newsrc.
2931         (when (or (null (setq method (gnus-info-method info)))
2932                   (equal method "native")
2933                   (inline (gnus-server-equal method gnus-select-method)))
2934           (insert (gnus-info-group info)
2935                   (if (> (gnus-info-level info) gnus-level-subscribed)
2936                       "!" ":"))
2937           (when (setq ranges (gnus-info-read info))
2938             (insert " ")
2939             (if (not (listp (cdr ranges)))
2940                 (if (= (car ranges) (cdr ranges))
2941                     (princ (car ranges))
2942                   (princ (car ranges))
2943                   (insert "-")
2944                   (princ (cdr ranges)))
2945               (while (setq range (pop ranges))
2946                 (if (or (atom range) (= (car range) (cdr range)))
2947                     (princ (or (and (atom range) range) (car range)))
2948                   (princ (car range))
2949                   (insert "-")
2950                   (princ (cdr range)))
2951                 (when ranges
2952                   (insert ",")))))
2953           (insert "\n")))
2954       (make-local-variable 'version-control)
2955       (setq version-control 'never)
2956       ;; It has been reported that sometime the modtime on the .newsrc
2957       ;; file seems to be off.  We really do want to overwrite it, so
2958       ;; we clear the modtime here before saving.  It's a bit odd,
2959       ;; though...
2960       ;; sometimes the modtime clear isn't sufficient.  most brute force:
2961       ;; delete the silly thing entirely first.  but this fails to provide
2962       ;; such niceties as .newsrc~ creation.
2963       (if gnus-modtime-botch
2964           (delete-file gnus-startup-file)
2965         (clear-visited-file-modtime))
2966       (gnus-run-hooks 'gnus-save-standard-newsrc-hook)
2967       (let ((coding-system-for-write 'raw-text))
2968         (save-buffer))
2969       (kill-buffer (current-buffer)))))
2970
2971 \f
2972 ;;;
2973 ;;; Slave functions.
2974 ;;;
2975
2976 (defvar gnus-slave-mode nil)
2977
2978 (defun gnus-slave-mode ()
2979   "Minor mode for slave Gnusae."
2980   ;; FIXME: gnus-slave-mode appears to never be set (i.e. it'll always be nil):
2981   ;; Remove, or fix and use define-minor-mode.
2982   (add-minor-mode 'gnus-slave-mode " Slave" (make-sparse-keymap))
2983   (gnus-run-hooks 'gnus-slave-mode-hook))
2984
2985 (defun gnus-slave-save-newsrc ()
2986   (with-current-buffer gnus-dribble-buffer
2987     (let ((slave-name
2988            (mm-make-temp-file (concat gnus-current-startup-file "-slave-")))
2989           (modes (ignore-errors
2990                    (file-modes (concat gnus-current-startup-file ".eld")))))
2991       (let ((coding-system-for-write gnus-ding-file-coding-system))
2992         (gnus-write-buffer slave-name))
2993       (when modes
2994         (gnus-set-file-modes slave-name modes)))))
2995
2996 (defun gnus-master-read-slave-newsrc ()
2997   (let ((slave-files
2998          (directory-files
2999           (file-name-directory gnus-current-startup-file)
3000           t (concat
3001              "^" (regexp-quote
3002                   (concat
3003                    (file-name-nondirectory gnus-current-startup-file)
3004                    "-slave-")))
3005           t))
3006         file)
3007     (if (not slave-files)
3008         ()                              ; There are no slave files to read.
3009       (gnus-message 7 "Reading slave newsrcs...")
3010       (with-current-buffer (gnus-get-buffer-create " *gnus slave*")
3011         (setq slave-files
3012               (sort (mapcar (lambda (file)
3013                               (list (nth 5 (file-attributes file)) file))
3014                             slave-files)
3015                     (lambda (f1 f2)
3016                       (or (< (caar f1) (caar f2))
3017                           (< (nth 1 (car f1)) (nth 1 (car f2)))))))
3018         (while slave-files
3019           (erase-buffer)
3020           (setq file (nth 1 (car slave-files)))
3021           (nnheader-insert-file-contents file)
3022           (when (condition-case ()
3023                     (progn
3024                       (eval-buffer (current-buffer))
3025                       t)
3026                   (error
3027                    (gnus-error 3.2 "Possible error in %s" file)
3028                    nil))
3029             (unless gnus-slave          ; Slaves shouldn't delete these files.
3030               (ignore-errors
3031                 (delete-file file))))
3032           (setq slave-files (cdr slave-files))))
3033       (gnus-dribble-touch)
3034       (gnus-message 7 "Reading slave newsrcs...done"))))
3035
3036 \f
3037 ;;;
3038 ;;; Group description.
3039 ;;;
3040
3041 (defun gnus-read-all-descriptions-files ()
3042   (let ((methods (cons gnus-select-method
3043                        (nconc
3044                         (when (gnus-archive-server-wanted-p)
3045                           (list "archive"))
3046                         gnus-secondary-select-methods))))
3047     (while methods
3048       (gnus-read-descriptions-file (car methods))
3049       (setq methods (cdr methods)))
3050     t))
3051
3052 (defun gnus-read-descriptions-file (&optional method)
3053   (let ((method (or method gnus-select-method))
3054         group)
3055     (when (stringp method)
3056       (setq method (gnus-server-to-method method)))
3057     ;; We create the hashtable whether we manage to read the desc file
3058     ;; to avoid trying to re-read after a failed read.
3059     (unless gnus-description-hashtb
3060       (setq gnus-description-hashtb
3061             (gnus-make-hashtable (length gnus-active-hashtb))))
3062     ;; Mark this method's desc file as read.
3063     (gnus-sethash (gnus-group-prefixed-name "" method) "Has read"
3064                   gnus-description-hashtb)
3065
3066     (gnus-message 5 "Reading descriptions file via %s..." (car method))
3067     (cond
3068      ((null (gnus-get-function method 'request-list-newsgroups t))
3069       t)
3070      ((not (gnus-check-server method))
3071       (gnus-message 1 "Couldn't open server")
3072       nil)
3073      ((not (gnus-request-list-newsgroups method))
3074       (gnus-message 1 "Couldn't read newsgroups descriptions")
3075       nil)
3076      (t
3077       (save-excursion
3078         ;; FIXME: Shouldn't save-restriction be done after set-buffer?
3079         (save-restriction
3080           (set-buffer nntp-server-buffer)
3081           (goto-char (point-min))
3082           (when (or (search-forward "\n.\n" nil t)
3083                     (goto-char (point-max)))
3084             (beginning-of-line)
3085             (narrow-to-region (point-min) (point)))
3086           ;; If these are groups from a foreign select method, we insert the
3087           ;; group prefix in front of the group names.
3088           (and method (not (inline
3089                              (gnus-server-equal
3090                               (gnus-server-get-method nil method)
3091                               (gnus-server-get-method
3092                                nil gnus-select-method))))
3093                (let ((prefix (gnus-group-prefixed-name "" method)))
3094                  (goto-char (point-min))
3095                  (while (and (not (eobp))
3096                              (progn (insert prefix)
3097                                     (zerop (forward-line 1)))))))
3098           (goto-char (point-min))
3099           (while (not (eobp))
3100             ;; If we get an error, we set group to 0, which is not a
3101             ;; symbol...
3102             (setq group
3103                   (condition-case ()
3104                       (let ((obarray gnus-description-hashtb))
3105                         ;; Group is set to a symbol interned in this
3106                         ;; hash table.
3107                         (read nntp-server-buffer))
3108                     (error 0)))
3109             (skip-chars-forward " \t")
3110             ;; ...  which leads to this line being effectively ignored.
3111             (when (symbolp group)
3112               (let* ((str (buffer-substring
3113                            (point) (progn (end-of-line) (point))))
3114                      (name (symbol-name group))
3115                      (charset
3116                       (or (gnus-group-name-charset method name)
3117                           (gnus-parameter-charset name)
3118                           gnus-default-charset)))
3119                 ;; Fixme: Don't decode in unibyte mode.
3120                 (when (and str charset (featurep 'mule))
3121                   (setq str (mm-decode-coding-string str charset)))
3122                 (set group str)))
3123             (forward-line 1))))
3124       (gnus-message 5 "Reading descriptions file...done")
3125       t))))
3126
3127 (defun gnus-group-get-description (group)
3128   "Get the description of a group by sending XGTITLE to the server."
3129   (when (gnus-request-group-description group)
3130     (with-current-buffer nntp-server-buffer
3131       (goto-char (point-min))
3132       (when (looking-at "[^ \t]+[ \t]+\\(.*\\)")
3133         (match-string 1)))))
3134
3135 ;;;###autoload
3136 (defun gnus-declare-backend (name &rest abilities)
3137   "Declare back end NAME with ABILITIES as a Gnus back end."
3138   (setq gnus-valid-select-methods
3139         (nconc gnus-valid-select-methods
3140                (list (apply 'list name abilities))))
3141   (gnus-redefine-select-method-widget))
3142
3143 (defun gnus-set-default-directory ()
3144   "Set the default directory in the current buffer to `gnus-default-directory'.
3145 If this variable is nil, don't do anything."
3146   (setq default-directory
3147         (if (and gnus-default-directory
3148                  (file-exists-p gnus-default-directory))
3149             (file-name-as-directory (expand-file-name gnus-default-directory))
3150           default-directory)))
3151
3152 (defun gnus-display-time-event-handler ()
3153   (if (and (fboundp 'display-time-event-handler)
3154            (gnus-boundp 'display-time-timer))
3155       (display-time-event-handler)))
3156
3157 (defun gnus-check-reasonable-setup ()
3158   ;; Check whether nnml and nnfolder share a directory.
3159   (let ((display-warn
3160          (if (fboundp 'display-warning)
3161              'display-warning
3162            (lambda (type message)
3163              (if noninteractive
3164                  (message "Warning (%s): %s" type message)
3165                (let (window)
3166                  (with-current-buffer (get-buffer-create "*Warnings*")
3167                    (goto-char (point-max))
3168                    (unless (bolp)
3169                      (insert "\n"))
3170                    (insert (format "Warning (%s): %s\n" type message))
3171                    (setq window (display-buffer (current-buffer)))
3172                    (set-window-start
3173                     window
3174                     (prog2
3175                         (forward-line (- 1 (window-height window)))
3176                         (point)
3177                       (goto-char (point-max))))))))))
3178         method active actives match)
3179     (dolist (server gnus-server-alist)
3180       (setq method (gnus-server-to-method server)
3181             active (intern (format "%s-active-file" (car method))))
3182       (when (and (member (car method) '(nnml nnfolder))
3183                  (gnus-server-opened method)
3184                  (boundp active))
3185         (when (setq match (assoc (symbol-value active) actives))
3186           (funcall display-warn 'gnus-server
3187                    (format "%s and %s share the same active file %s"
3188                            (car method)
3189                            (cadr match)
3190                            (car match))))
3191         (push (list (symbol-value active) method) actives)))))
3192
3193 (provide 'gnus-start)
3194
3195 ;;; gnus-start.el ends here