cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'gnus-start)
  32 (require 'gnus-spec)
  33 (require 'gnus-group)
  34 (require 'gnus-int)
  35 (require 'gnus-range)
  36
  37 (defcustom gnus-server-mode-hook nil
  38   "Hook run in `gnus-server-mode' buffers."
  39   :group 'gnus-server
  40   :type 'hook)
  41
  42 (defcustom gnus-server-exit-hook nil
  43   "Hook run when exiting the server buffer."
  44   :group 'gnus-server
  45   :type 'hook)
  46
  47 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  48   "Format of server lines.
  49 It works along the same lines as a normal formatting string,
  50 with some simple extensions.
  51
  52 The following specs are understood:
  53
  54 %h back end
  55 %n name
  56 %w address
  57 %s status
  58 %a agent covered
  59
  60 General format specifiers can also be used.
  61 See Info node `(gnus)Formatting Variables'."
  62   :link '(custom-manual "(gnus)Formatting Variables")
  63   :group 'gnus-server-visual
  64   :type 'string)
  65
  66 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  67   "The format specification for the server mode line."
  68   :group 'gnus-server-visual
  69   :type 'string)
  70
  71 (defcustom gnus-server-browse-in-group-buffer nil
  72   "Whether server browsing should take place in the group buffer.
  73 If nil, a faster, but more primitive, buffer is used instead."
  74   :version "22.1"
  75   :group 'gnus-server-visual
  76   :type 'boolean)
  77
  78 ;;; Internal variables.
  79
  80 (defvar gnus-inserted-opened-servers nil)
  81
  82 (defvar gnus-server-line-format-alist
  83   `((?h gnus-tmp-how ?s)
  84     (?n gnus-tmp-name ?s)
  85     (?w gnus-tmp-where ?s)
  86     (?s gnus-tmp-status ?s)
  87     (?a gnus-tmp-agent ?s)))
  88
  89 (defvar gnus-server-mode-line-format-alist
  90   `((?S gnus-tmp-news-server ?s)
  91     (?M gnus-tmp-news-method ?s)
  92     (?u gnus-tmp-user-defined ?s)))
  93
  94 (defvar gnus-server-line-format-spec nil)
  95 (defvar gnus-server-mode-line-format-spec nil)
  96 (defvar gnus-server-killed-servers nil)
  97
  98 (defvar gnus-server-mode-map)
  99
 100 (defvar gnus-server-menu-hook nil
 101   "*Hook run after the creation of the server mode menu.")
 102
 103 (defun gnus-server-make-menu-bar ()
 104   (gnus-turn-off-edit-menu 'server)
 105   (unless (boundp 'gnus-server-server-menu)
 106     (easy-menu-define
 107      gnus-server-server-menu gnus-server-mode-map ""
 108      '("Server"
 109        ["Add..." gnus-server-add-server t]
 110        ["Browse" gnus-server-read-server t]
 111        ["Scan" gnus-server-scan-server t]
 112        ["List" gnus-server-list-servers t]
 113        ["Kill" gnus-server-kill-server t]
 114        ["Yank" gnus-server-yank-server t]
 115        ["Copy" gnus-server-copy-server t]
 116        ["Edit" gnus-server-edit-server t]
 117        ["Regenerate" gnus-server-regenerate-server t]
 118        ["Compact" gnus-server-compact-server t]
 119        ["Exit" gnus-server-exit t]))
 120
 121     (easy-menu-define
 122      gnus-server-connections-menu gnus-server-mode-map ""
 123      '("Connections"
 124        ["Open" gnus-server-open-server t]
 125        ["Close" gnus-server-close-server t]
 126        ["Offline" gnus-server-offline-server t]
 127        ["Deny" gnus-server-deny-server t]
 128        "---"
 129        ["Open All" gnus-server-open-all-servers t]
 130        ["Close All" gnus-server-close-all-servers t]
 131        ["Reset All" gnus-server-remove-denials t]))
 132
 133     (gnus-run-hooks 'gnus-server-menu-hook)))
 134
 135 (defvar gnus-server-mode-map nil)
 136 (put 'gnus-server-mode 'mode-class 'special)
 137
 138 (unless gnus-server-mode-map
 139   (setq gnus-server-mode-map (make-sparse-keymap))
 140   (suppress-keymap gnus-server-mode-map)
 141
 142   (gnus-define-keys gnus-server-mode-map
 143     " " gnus-server-read-server-in-server-buffer
 144     "\r" gnus-server-read-server
 145     gnus-mouse-2 gnus-server-pick-server
 146     "q" gnus-server-exit
 147     "l" gnus-server-list-servers
 148     "k" gnus-server-kill-server
 149     "y" gnus-server-yank-server
 150     "c" gnus-server-copy-server
 151     "a" gnus-server-add-server
 152     "e" gnus-server-edit-server
 153     "s" gnus-server-scan-server
 154
 155     "O" gnus-server-open-server
 156     "\M-o" gnus-server-open-all-servers
 157     "C" gnus-server-close-server
 158     "\M-c" gnus-server-close-all-servers
 159     "D" gnus-server-deny-server
 160     "L" gnus-server-offline-server
 161     "R" gnus-server-remove-denials
 162
 163     "n" next-line
 164     "p" previous-line
 165
 166     "g" gnus-server-regenerate-server
 167
 168     "z" gnus-server-compact-server
 169
 170     "\C-c\C-i" gnus-info-find-node
 171     "\C-c\C-b" gnus-bug))
 172
 173 (defface gnus-server-agent
 174   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 175     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 176     (t (:bold t)))
 177   "Face used for displaying AGENTIZED servers"
 178   :group 'gnus-server-visual)
 179 ;; backward-compatibility alias
 180 (put 'gnus-server-agent-face 'face-alias 'gnus-server-agent)
 181 (put 'gnus-server-agent-face 'obsolete-face "22.1")
 182
 183 (defface gnus-server-opened
 184   '((((class color) (background light)) (:foreground "Green3" :bold t))
 185     (((class color) (background dark)) (:foreground "Green1" :bold t))
 186     (t (:bold t)))
 187   "Face used for displaying OPENED servers"
 188   :group 'gnus-server-visual)
 189 ;; backward-compatibility alias
 190 (put 'gnus-server-opened-face 'face-alias 'gnus-server-opened)
 191 (put 'gnus-server-opened-face 'obsolete-face "22.1")
 192
 193 (defface gnus-server-closed
 194   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 195     (((class color) (background dark))
 196      (:foreground "LightBlue" :italic t))
 197     (t (:italic t)))
 198   "Face used for displaying CLOSED servers"
 199   :group 'gnus-server-visual)
 200 ;; backward-compatibility alias
 201 (put 'gnus-server-closed-face 'face-alias 'gnus-server-closed)
 202 (put 'gnus-server-closed-face 'obsolete-face "22.1")
 203
 204 (defface gnus-server-denied
 205   '((((class color) (background light)) (:foreground "Red" :bold t))
 206     (((class color) (background dark)) (:foreground "Pink" :bold t))
 207     (t (:inverse-video t :bold t)))
 208   "Face used for displaying DENIED servers"
 209   :group 'gnus-server-visual)
 210 ;; backward-compatibility alias
 211 (put 'gnus-server-denied-face 'face-alias 'gnus-server-denied)
 212 (put 'gnus-server-denied-face 'obsolete-face "22.1")
 213
 214 (defface gnus-server-offline
 215   '((((class color) (background light)) (:foreground "Orange" :bold t))
 216     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 217     (t (:inverse-video t :bold t)))
 218   "Face used for displaying OFFLINE servers"
 219   :group 'gnus-server-visual)
 220 ;; backward-compatibility alias
 221 (put 'gnus-server-offline-face 'face-alias 'gnus-server-offline)
 222 (put 'gnus-server-offline-face 'obsolete-face "22.1")
 223
 224 (defvar gnus-server-font-lock-keywords
 225   '(("(\\(agent\\))" 1 'gnus-server-agent)
 226     ("(\\(opened\\))" 1 'gnus-server-opened)
 227     ("(\\(closed\\))" 1 'gnus-server-closed)
 228     ("(\\(offline\\))" 1 'gnus-server-offline)
 229     ("(\\(denied\\))" 1 'gnus-server-denied)))
 230
 231 (defun gnus-server-mode ()
 232   "Major mode for listing and editing servers.
 233
 234 All normal editing commands are switched off.
 235 \\<gnus-server-mode-map>
 236 For more in-depth information on this mode, read the manual
 237 \(`\\[gnus-info-find-node]').
 238
 239 The following commands are available:
 240
 241 \\{gnus-server-mode-map}"
 242   (interactive)
 243   (when (gnus-visual-p 'server-menu 'menu)
 244     (gnus-server-make-menu-bar))
 245   (kill-all-local-variables)
 246   (gnus-simplify-mode-line)
 247   (setq major-mode 'gnus-server-mode)
 248   (setq mode-name "Server")
 249   (gnus-set-default-directory)
 250   (setq mode-line-process nil)
 251   (use-local-map gnus-server-mode-map)
 252   (buffer-disable-undo)
 253   (setq truncate-lines t)
 254   (setq buffer-read-only t)
 255   (if (featurep 'xemacs)
 256       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 257     (set (make-local-variable 'font-lock-defaults)
 258          '(gnus-server-font-lock-keywords t)))
 259   (gnus-run-mode-hooks 'gnus-server-mode-hook))
 260
 261 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 262   (let* ((gnus-tmp-how (car method))
 263          (gnus-tmp-where (nth 1 method))
 264          (elem (assoc method gnus-opened-servers))
 265          (gnus-tmp-status
 266           (cond
 267            ((eq (nth 1 elem) 'denied) "(denied)")
 268            ((eq (nth 1 elem) 'offline) "(offline)")
 269            (t
 270             (condition-case nil
 271                 (if (or (gnus-server-opened method)
 272                         (eq (nth 1 elem) 'ok))
 273                     "(opened)"
 274                   "(closed)")
 275               ((error) "(error)")))))
 276          (gnus-tmp-agent (if (and gnus-agent
 277                                   (gnus-agent-method-p method))
 278                              " (agent)"
 279                            "")))
 280     (beginning-of-line)
 281     (gnus-add-text-properties
 282      (point)
 283      (prog1 (1+ (point))
 284        ;; Insert the text.
 285        (eval gnus-server-line-format-spec))
 286      (list 'gnus-server (intern gnus-tmp-name)
 287            'gnus-named-server (intern (gnus-method-to-server method t))))))
 288
 289 (defun gnus-enter-server-buffer ()
 290   "Set up the server buffer."
 291   (gnus-server-setup-buffer)
 292   (gnus-configure-windows 'server)
 293   ;; Usually `gnus-configure-windows' will finish with the
 294   ;; `gnus-server-buffer' selected as the current buffer, but not always (I
 295   ;; bumped into it when starting from a dedicated *Group* frame, and
 296   ;; gnus-configure-windows opened *Server* into its own dedicated frame).
 297   (with-current-buffer (get-buffer gnus-server-buffer)
 298     (gnus-server-prepare)))
 299
 300 (defun gnus-server-setup-buffer ()
 301   "Initialize the server buffer."
 302   (unless (get-buffer gnus-server-buffer)
 303     (with-current-buffer (gnus-get-buffer-create gnus-server-buffer)
 304       (gnus-server-mode))))
 305
 306 (defun gnus-server-prepare ()
 307   (gnus-set-format 'server-mode)
 308   (gnus-set-format 'server t)
 309   (let ((alist gnus-server-alist)
 310         (buffer-read-only nil)
 311         done server op-ser)
 312     (erase-buffer)
 313     (setq gnus-inserted-opened-servers nil)
 314     ;; First we do the real list of servers.
 315     (while alist
 316       (unless (member (cdar alist) done)
 317         (push (cdar alist) done)
 318         (setq server (pop alist))
 319         (when (and server (car server) (cdr server))
 320           (gnus-server-insert-server-line (car server) (cdr server))))
 321       (when (member (cdar alist) done)
 322         (pop alist)))
 323     ;; Then we insert the list of servers that have been opened in
 324     ;; this session.
 325     (dolist (open gnus-opened-servers)
 326       (when (and (not (member (car open) done))
 327                  ;; Just ignore ephemeral servers.
 328                  (not (member (car open) gnus-ephemeral-servers)))
 329         (push (car open) done)
 330         (gnus-server-insert-server-line
 331          (setq op-ser (format "%s:%s" (caar open) (nth 1 (car open))))
 332          (car open))
 333         (push (list op-ser (car open)) gnus-inserted-opened-servers))))
 334   (goto-char (point-min))
 335   (gnus-server-position-point))
 336
 337 (defun gnus-server-server-name ()
 338   (let ((server (get-text-property (point-at-bol) 'gnus-server)))
 339     (and server (symbol-name server))))
 340
 341 (defun gnus-server-named-server ()
 342   "Return a server name that matches one of the names returned by
 343 `gnus-method-to-server'."
 344   (let ((server (get-text-property (point-at-bol) 'gnus-named-server)))
 345     (and server (symbol-name server))))
 346
 347 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 348
 349 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 350
 351 (defun gnus-server-update-server (server)
 352   (with-current-buffer gnus-server-buffer
 353     (let* ((buffer-read-only nil)
 354            (entry (assoc server gnus-server-alist))
 355            (oentry (assoc (gnus-server-to-method server)
 356                           gnus-opened-servers)))
 357       (when entry
 358         (gnus-dribble-enter
 359          (concat "(gnus-server-set-info \"" server "\" '"
 360                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 361       (when (or entry oentry)
 362         ;; Buffer may be narrowed.
 363         (save-restriction
 364           (widen)
 365           (when (gnus-server-goto-server server)
 366             (gnus-delete-line))
 367           (if entry
 368               (gnus-server-insert-server-line (car entry) (cdr entry))
 369             (gnus-server-insert-server-line
 370              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 371              (car oentry)))
 372           (gnus-server-position-point))))))
 373
 374 (defun gnus-server-set-info (server info)
 375   ;; Enter a select method into the virtual server alist.
 376   (when (and server info)
 377     (gnus-dribble-enter
 378      (concat "(gnus-server-set-info \"" server "\" '"
 379              (gnus-prin1-to-string info) ")"))
 380     (let* ((server (nth 1 info))
 381            (entry (assoc server gnus-server-alist))
 382            (cached (assoc server gnus-server-method-cache)))
 383       (if cached
 384           (setq gnus-server-method-cache
 385                 (delq cached gnus-server-method-cache)))
 386       (if entry
 387           (progn
 388             ;; Remove the server from `gnus-opened-servers' since
 389             ;; it has never been opened with the new `info' yet.
 390             (gnus-opened-servers-remove (cdr entry))
 391             ;; Don't make a new Lisp object.
 392             (setcar (cdr entry) (car info))
 393             (setcdr (cdr entry) (cdr info)))
 394         (setq gnus-server-alist
 395               (nconc gnus-server-alist (list (cons server info))))))))
 396
 397 ;;; Interactive server functions.
 398
 399 (defun gnus-server-kill-server (server)
 400   "Kill the server on the current line."
 401   (interactive (list (gnus-server-server-name)))
 402   (unless (gnus-server-goto-server server)
 403     (if server (error "No such server: %s" server)
 404       (error "No server on the current line")))
 405   (unless (assoc server gnus-server-alist)
 406     (error "Read-only server %s" server))
 407   (gnus-dribble-touch)
 408   (let ((buffer-read-only nil))
 409     (gnus-delete-line))
 410   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 411   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 412                                 gnus-server-alist))
 413   (let ((groups (gnus-groups-from-server server)))
 414     (when (and groups
 415                (gnus-yes-or-no-p
 416                 (format "Kill all %s groups from this server? "
 417                         (length groups))))
 418       (dolist (group groups)
 419         (setq gnus-newsrc-alist
 420               (delq (assoc group gnus-newsrc-alist)
 421                     gnus-newsrc-alist))
 422         (when gnus-group-change-level-function
 423           (funcall gnus-group-change-level-function
 424                    group gnus-level-killed 3)))))
 425   (gnus-server-position-point))
 426
 427 (defun gnus-server-yank-server ()
 428   "Yank the previously killed server."
 429   (interactive)
 430   (unless gnus-server-killed-servers
 431     (error "No killed servers to be yanked"))
 432   (let ((alist gnus-server-alist)
 433         (server (gnus-server-server-name))
 434         (killed (car gnus-server-killed-servers)))
 435     (if (not server)
 436         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 437       (if (string= server (caar gnus-server-alist))
 438           (push killed gnus-server-alist)
 439         (while (and (cdr alist)
 440                     (not (string= server (caadr alist))))
 441           (setq alist (cdr alist)))
 442         (if alist
 443             (setcdr alist (cons killed (cdr alist)))
 444           (setq gnus-server-alist (list killed)))))
 445     (gnus-server-update-server (car killed))
 446     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 447     (gnus-server-position-point)))
 448
 449 (defun gnus-server-exit ()
 450   "Return to the group buffer."
 451   (interactive)
 452   (gnus-run-hooks 'gnus-server-exit-hook)
 453   (gnus-kill-buffer (current-buffer))
 454   (gnus-configure-windows 'group t))
 455
 456 (defun gnus-server-list-servers ()
 457   "List all available servers."
 458   (interactive)
 459   (let ((cur (gnus-server-server-name)))
 460     (gnus-server-prepare)
 461     (if cur (gnus-server-goto-server cur)
 462       (goto-char (point-max))
 463       (forward-line -1))
 464     (gnus-server-position-point)))
 465
 466 (defun gnus-server-set-status (method status)
 467   "Make METHOD have STATUS."
 468   (let ((entry (assoc method gnus-opened-servers)))
 469     (if entry
 470         (setcar (cdr entry) status)
 471       (push (list method status) gnus-opened-servers))))
 472
 473 (defun gnus-opened-servers-remove (method)
 474   "Remove METHOD from the list of opened servers."
 475   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 476                                   gnus-opened-servers)))
 477
 478 (defun gnus-server-open-server (server)
 479   "Force an open of SERVER."
 480   (interactive (list (gnus-server-server-name)))
 481   (let ((method (gnus-server-to-method server)))
 482     (unless method
 483       (error "No such server: %s" server))
 484     (gnus-server-set-status method 'ok)
 485     (prog1
 486         (or (gnus-open-server method)
 487             (progn (message "Couldn't open %s" server) nil))
 488       (gnus-server-update-server server)
 489       (gnus-server-position-point))))
 490
 491 (defun gnus-server-open-all-servers ()
 492   "Open all servers."
 493   (interactive)
 494   (dolist (server gnus-inserted-opened-servers)
 495     (gnus-server-open-server (car server))))
 496
 497 (defun gnus-server-close-server (server)
 498   "Close SERVER."
 499   (interactive (list (gnus-server-server-name)))
 500   (let ((method (gnus-server-to-method server)))
 501     (unless method
 502       (error "No such server: %s" server))
 503     (gnus-server-set-status method 'closed)
 504     (prog1
 505         (gnus-close-server method)
 506       (gnus-server-update-server server)
 507       (gnus-server-position-point))))
 508
 509 (defun gnus-server-offline-server (server)
 510   "Set SERVER to offline."
 511   (interactive (list (gnus-server-server-name)))
 512   (let ((method (gnus-server-to-method server)))
 513     (unless method
 514       (error "No such server: %s" server))
 515     (prog1
 516         (gnus-close-server method)
 517       (gnus-server-set-status method 'offline)
 518       (gnus-server-update-server server)
 519       (gnus-server-position-point))))
 520
 521 (defun gnus-server-close-all-servers ()
 522   "Close all servers."
 523   (interactive)
 524   (dolist (server gnus-inserted-opened-servers)
 525     (gnus-server-close-server (car server)))
 526   (dolist (server gnus-server-alist)
 527     (gnus-server-close-server (car server))))
 528
 529 (defun gnus-server-deny-server (server)
 530   "Make sure SERVER will never be attempted opened."
 531   (interactive (list (gnus-server-server-name)))
 532   (let ((method (gnus-server-to-method server)))
 533     (unless method
 534       (error "No such server: %s" server))
 535     (gnus-server-set-status method 'denied))
 536   (gnus-server-update-server server)
 537   (gnus-server-position-point)
 538   t)
 539
 540 (defun gnus-server-remove-denials ()
 541   "Make all denied servers into closed servers."
 542   (interactive)
 543   (dolist (server gnus-opened-servers)
 544     (when (eq (nth 1 server) 'denied)
 545       (setcar (nthcdr 1 server) 'closed)))
 546   (gnus-server-list-servers))
 547
 548 (defun gnus-server-copy-server (from to)
 549   "Copy a server definiton to a new name."
 550   (interactive
 551    (list
 552     (or (gnus-server-server-name)
 553         (error "No server on the current line"))
 554     (read-string "Copy to: ")))
 555   (unless from
 556     (error "No server on current line"))
 557   (unless (and to (not (string= to "")))
 558     (error "No name to copy to"))
 559   (when (assoc to gnus-server-alist)
 560     (error "%s already exists" to))
 561   (unless (gnus-server-to-method from)
 562     (error "%s: no such server" from))
 563   (let ((to-entry (cons from (gnus-copy-sequence
 564                               (gnus-server-to-method from)))))
 565     (setcar to-entry to)
 566     (setcar (nthcdr 2 to-entry) to)
 567     (push to-entry gnus-server-killed-servers)
 568     (gnus-server-yank-server)))
 569
 570 (defun gnus-server-add-server (how where)
 571   (interactive
 572    (list (intern (gnus-completing-read "Server method"
 573                                        (mapcar 'car gnus-valid-select-methods)
 574                                        t))
 575          (read-string "Server name: ")))
 576   (when (assq where gnus-server-alist)
 577     (error "Server with that name already defined"))
 578   (push (list where how where) gnus-server-killed-servers)
 579   (gnus-server-yank-server))
 580
 581 (defun gnus-server-goto-server (server)
 582   "Jump to a server line."
 583   (interactive
 584    (list (gnus-completing-read "Goto server" (mapcar 'car gnus-server-alist) t)))
 585   (let ((to (text-property-any (point-min) (point-max)
 586                                'gnus-server (intern server))))
 587     (when to
 588       (goto-char to)
 589       (gnus-server-position-point))))
 590
 591 (defun gnus-server-edit-server (server)
 592   "Edit the server on the current line."
 593   (interactive (list (gnus-server-server-name)))
 594   (unless server
 595     (error "No server on current line"))
 596   (unless (assoc server gnus-server-alist)
 597     (error "This server can't be edited"))
 598   (let ((info (cdr (assoc server gnus-server-alist))))
 599     (gnus-close-server info)
 600     (gnus-edit-form
 601      info "Editing the server."
 602      `(lambda (form)
 603         (gnus-server-set-info ,server form)
 604         (gnus-server-list-servers)
 605         (gnus-server-position-point))
 606      'edit-server)))
 607
 608 (defun gnus-server-scan-server (server)
 609   "Request a scan from the current server."
 610   (interactive (list (gnus-server-server-name)))
 611   (let ((method (gnus-server-to-method server)))
 612     (if (not (gnus-get-function method 'request-scan))
 613         (error "Server %s can't scan" (car method))
 614       (gnus-message 3 "Scanning %s..." server)
 615       (gnus-request-scan nil method)
 616       (gnus-message 3 "Scanning %s...done" server))))
 617
 618 (defun gnus-server-read-server-in-server-buffer (server)
 619   "Browse a server in server buffer."
 620   (interactive (list (gnus-server-server-name)))
 621   (let (gnus-server-browse-in-group-buffer)
 622     (gnus-server-read-server server)))
 623
 624 (defun gnus-server-read-server (server)
 625   "Browse a server."
 626   (interactive (list (gnus-server-server-name)))
 627   (let ((buf (current-buffer)))
 628     (prog1
 629         (gnus-browse-foreign-server server buf)
 630       (with-current-buffer buf
 631         (gnus-server-update-server (gnus-server-server-name))
 632         (gnus-server-position-point)))))
 633
 634 (defun gnus-server-pick-server (e)
 635   (interactive "e")
 636   (mouse-set-point e)
 637   (gnus-server-read-server (gnus-server-server-name)))
 638
 639 \f
 640 ;;;
 641 ;;; Browse Server Mode
 642 ;;;
 643
 644 (defvar gnus-browse-menu-hook nil
 645   "*Hook run after the creation of the browse mode menu.")
 646
 647 (defcustom gnus-browse-subscribe-newsgroup-method
 648   'gnus-subscribe-alphabetically
 649   "Function(s) called when subscribing groups in the Browse Server Buffer
 650 A few pre-made functions are supplied: `gnus-subscribe-randomly'
 651 inserts new groups at the beginning of the list of groups;
 652 `gnus-subscribe-alphabetically' inserts new groups in strict
 653 alphabetic order; `gnus-subscribe-hierarchically' inserts new groups
 654 in hierarchical newsgroup order; `gnus-subscribe-interactively' asks
 655 for your decision; `gnus-subscribe-killed' kills all new groups;
 656 `gnus-subscribe-zombies' will make all new groups into zombies;
 657 `gnus-subscribe-topics' will enter groups into the topics that
 658 claim them."
 659   :version "24.1"
 660   :group 'gnus-server
 661   :type '(radio (function-item gnus-subscribe-randomly)
 662                 (function-item gnus-subscribe-alphabetically)
 663                 (function-item gnus-subscribe-hierarchically)
 664                 (function-item gnus-subscribe-interactively)
 665                 (function-item gnus-subscribe-killed)
 666                 (function-item gnus-subscribe-zombies)
 667                 (function-item gnus-subscribe-topics)
 668                 function
 669                 (repeat function)))
 670
 671 (defvar gnus-browse-mode-hook nil)
 672 (defvar gnus-browse-mode-map nil)
 673 (put 'gnus-browse-mode 'mode-class 'special)
 674
 675 (unless gnus-browse-mode-map
 676   (setq gnus-browse-mode-map (make-keymap))
 677   (suppress-keymap gnus-browse-mode-map)
 678
 679   (gnus-define-keys
 680       gnus-browse-mode-map
 681     " " gnus-browse-read-group
 682     "=" gnus-browse-select-group
 683     "n" gnus-browse-next-group
 684     "p" gnus-browse-prev-group
 685     "\177" gnus-browse-prev-group
 686     [delete] gnus-browse-prev-group
 687     "N" gnus-browse-next-group
 688     "P" gnus-browse-prev-group
 689     "\M-n" gnus-browse-next-group
 690     "\M-p" gnus-browse-prev-group
 691     "\r" gnus-browse-select-group
 692     "u" gnus-browse-unsubscribe-current-group
 693     "l" gnus-browse-exit
 694     "L" gnus-browse-exit
 695     "q" gnus-browse-exit
 696     "Q" gnus-browse-exit
 697     "d" gnus-browse-describe-group
 698     "\C-c\C-c" gnus-browse-exit
 699     "?" gnus-browse-describe-briefly
 700
 701     "\C-c\C-i" gnus-info-find-node
 702     "\C-c\C-b" gnus-bug))
 703
 704 (defun gnus-browse-make-menu-bar ()
 705   (gnus-turn-off-edit-menu 'browse)
 706   (unless (boundp 'gnus-browse-menu)
 707     (easy-menu-define
 708      gnus-browse-menu gnus-browse-mode-map ""
 709      '("Browse"
 710        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 711        ["Read" gnus-browse-read-group t]
 712        ["Select" gnus-browse-select-group t]
 713        ["Describe" gnus-browse-describe-group t]
 714        ["Next" gnus-browse-next-group t]
 715        ["Prev" gnus-browse-prev-group t]
 716        ["Exit" gnus-browse-exit t]))
 717     (gnus-run-hooks 'gnus-browse-menu-hook)))
 718
 719 (defvar gnus-browse-current-method nil)
 720 (defvar gnus-browse-return-buffer nil)
 721
 722 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 723
 724 (defun gnus-browse-foreign-server (server &optional return-buffer)
 725   "Browse the server SERVER."
 726   (setq gnus-browse-current-method (gnus-server-to-method server))
 727   (setq gnus-browse-return-buffer return-buffer)
 728   (let* ((method gnus-browse-current-method)
 729          (orig-select-method gnus-select-method)
 730          (gnus-select-method method)
 731          groups group)
 732     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 733     (cond
 734      ((not (gnus-check-server method))
 735       (gnus-message
 736        1 "Unable to contact server %s: %s" (nth 1 method)
 737        (gnus-status-message method))
 738       nil)
 739      ((not
 740        (prog2
 741            (gnus-message 6 "Reading active file...")
 742            (gnus-request-list method)
 743          (gnus-message 6 "Reading active file...done")))
 744       (gnus-message
 745        1 "Couldn't request list: %s" (gnus-status-message method))
 746       nil)
 747      (t
 748       (with-current-buffer nntp-server-buffer
 749         (let ((cur (current-buffer)))
 750           (goto-char (point-min))
 751           (unless (string= gnus-ignored-newsgroups "")
 752             (delete-matching-lines gnus-ignored-newsgroups))
 753           ;; We treat NNTP as a special case to avoid problems with
 754           ;; garbage group names like `"foo' that appear in some badly
 755           ;; managed active files. -jh.
 756           (if (eq (car method) 'nntp)
 757               (while (not (eobp))
 758                 (ignore-errors
 759                   (push (cons
 760                          (mm-string-as-unibyte
 761                           (buffer-substring
 762                            (point)
 763                            (progn
 764                              (skip-chars-forward "^ \t")
 765                              (point))))
 766                          (let ((last (read cur)))
 767                            (cons (read cur) last)))
 768                         groups))
 769                 (forward-line))
 770             (while (not (eobp))
 771               (ignore-errors
 772                 (push (cons
 773                        (mm-string-as-unibyte
 774                         (if (eq (char-after) ?\")
 775                             (read cur)
 776                           (let ((p (point)) (name ""))
 777                             (skip-chars-forward "^ \t\\\\")
 778                             (setq name (buffer-substring p (point)))
 779                             (while (eq (char-after) ?\\)
 780                               (setq p (1+ (point)))
 781                               (forward-char 2)
 782                               (skip-chars-forward "^ \t\\\\")
 783                               (setq name (concat name (buffer-substring
 784                                                        p (point)))))
 785                             name)))
 786                        (let ((last (read cur)))
 787                          (cons (read cur) last)))
 788                       groups))
 789               (forward-line)))))
 790       (setq groups (sort groups
 791                          (lambda (l1 l2)
 792                            (string< (car l1) (car l2)))))
 793       (if gnus-server-browse-in-group-buffer
 794           (let* ((gnus-select-method orig-select-method)
 795                  (gnus-group-listed-groups
 796                   (mapcar (lambda (group)
 797                             (let ((name
 798                                    (gnus-group-prefixed-name
 799                                     (car group) method)))
 800                               (gnus-set-active name (cdr group))
 801                               name))
 802                           groups)))
 803             (gnus-configure-windows 'group)
 804             (funcall gnus-group-prepare-function
 805                      gnus-level-killed 'ignore 1 'ignore))
 806         (gnus-get-buffer-create gnus-browse-buffer)
 807         (gnus-configure-windows 'browse)
 808         (buffer-disable-undo)
 809         (let ((buffer-read-only nil))
 810           (erase-buffer))
 811         (gnus-browse-mode)
 812         (setq mode-line-buffer-identification
 813               (list
 814                (format
 815                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 816         (let ((buffer-read-only nil)
 817               name
 818               (prefix (let ((gnus-select-method orig-select-method))
 819                         (gnus-group-prefixed-name "" method))))
 820           (while (setq group (pop groups))
 821             (gnus-add-text-properties
 822              (point)
 823              (prog1 (1+ (point))
 824                (insert
 825                 (format "%c%7d: %s\n"
 826                         (let ((level
 827                                (if (string= prefix "")
 828                                    (gnus-group-level (setq name (car group)))
 829                                  (gnus-group-level
 830                                   (concat prefix (setq name (car group)))))))
 831                           (cond
 832                            ((<= level gnus-level-subscribed) ? )
 833                            ((<= level gnus-level-unsubscribed) ?U)
 834                            ((= level gnus-level-zombie) ?Z)
 835                            (t ?K)))
 836                         (max 0 (- (1+ (cddr group)) (cadr group)))
 837                         ;; Don't decode if name is ASCII
 838                         (if (and (fboundp 'detect-coding-string)
 839                                  (eq (detect-coding-string name t) 'undecided))
 840                             name
 841                           (mm-decode-coding-string
 842                            name
 843                            (inline (gnus-group-name-charset method name)))))))
 844              (list 'gnus-group name)
 845              )))
 846         (switch-to-buffer (current-buffer)))
 847       (goto-char (point-min))
 848       (gnus-group-position-point)
 849       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 850       t))))
 851
 852 (defun gnus-browse-mode ()
 853   "Major mode for browsing a foreign server.
 854
 855 All normal editing commands are switched off.
 856
 857 \\<gnus-browse-mode-map>
 858 The only things you can do in this buffer is
 859
 860 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 861 The group will be inserted into the group buffer upon exit from this
 862 buffer.
 863
 864 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 865
 866 3) `\\[gnus-browse-exit]' to return to the group buffer."
 867   (interactive)
 868   (kill-all-local-variables)
 869   (when (gnus-visual-p 'browse-menu 'menu)
 870     (gnus-browse-make-menu-bar))
 871   (gnus-simplify-mode-line)
 872   (setq major-mode 'gnus-browse-mode)
 873   (setq mode-name "Browse Server")
 874   (setq mode-line-process nil)
 875   (use-local-map gnus-browse-mode-map)
 876   (buffer-disable-undo)
 877   (setq truncate-lines t)
 878   (gnus-set-default-directory)
 879   (setq buffer-read-only t)
 880   (gnus-run-mode-hooks 'gnus-browse-mode-hook))
 881
 882 (defun gnus-browse-read-group (&optional no-article number)
 883   "Enter the group at the current line.
 884 If NUMBER, fetch this number of articles."
 885   (interactive "P")
 886   (let ((group (gnus-browse-group-name)))
 887     (if (or (not (gnus-get-info group))
 888             (gnus-ephemeral-group-p group))
 889         (unless (gnus-group-read-ephemeral-group
 890                  group gnus-browse-current-method nil
 891                  (cons (current-buffer) 'browse)
 892                  nil nil nil number)
 893           (error "Couldn't enter %s" group))
 894       (unless (gnus-group-read-group nil no-article group)
 895         (error "Couldn't enter %s" group)))))
 896
 897 (defun gnus-browse-select-group (&optional number)
 898   "Select the current group.
 899 If NUMBER, fetch this number of articles."
 900   (interactive "P")
 901   (gnus-browse-read-group 'no number))
 902
 903 (defun gnus-browse-next-group (n)
 904   "Go to the next group."
 905   (interactive "p")
 906   (prog1
 907       (forward-line n)
 908     (gnus-group-position-point)))
 909
 910 (defun gnus-browse-prev-group (n)
 911   "Go to the next group."
 912   (interactive "p")
 913   (gnus-browse-next-group (- n)))
 914
 915 (defun gnus-browse-unsubscribe-current-group (arg)
 916   "(Un)subscribe to the next ARG groups.
 917 The variable `gnus-browse-subscribe-newsgroup-method' determines
 918 how new groups will be entered into the group buffer."
 919   (interactive "p")
 920   (when (eobp)
 921     (error "No group at current line"))
 922   (let ((ward (if (< arg 0) -1 1))
 923         (arg (abs arg)))
 924     (while (and (> arg 0)
 925                 (not (eobp))
 926                 (gnus-browse-unsubscribe-group)
 927                 (zerop (gnus-browse-next-group ward)))
 928       (decf arg))
 929     (gnus-group-position-point)
 930     (when (/= 0 arg)
 931       (gnus-message 7 "No more newsgroups"))
 932     arg))
 933
 934 (defun gnus-browse-group-name ()
 935   (save-excursion
 936     (beginning-of-line)
 937     (let ((name (get-text-property (point) 'gnus-group)))
 938       (when (re-search-forward ": \\(.*\\)$" (point-at-eol) t)
 939         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 940                 (or name
 941                     (match-string-no-properties 1)))))))
 942
 943 (defun gnus-browse-describe-group (group)
 944   "Describe the current group."
 945   (interactive (list (gnus-browse-group-name)))
 946   (gnus-group-describe-group nil group))
 947
 948 (defun gnus-browse-unsubscribe-group ()
 949   "Toggle subscription of the current group in the browse buffer."
 950   (let ((sub nil)
 951         (buffer-read-only nil)
 952         group)
 953     (save-excursion
 954       (beginning-of-line)
 955       ;; If this group it killed, then we want to subscribe it.
 956       (unless (eq (char-after) ? )
 957         (setq sub t))
 958       (setq group (gnus-browse-group-name))
 959       (when (gnus-server-equal gnus-browse-current-method "native")
 960         (setq group (gnus-group-real-name group)))
 961       (if sub
 962           (progn
 963             ;; Make sure the group has been properly removed before we
 964             ;; subscribe to it.
 965             (if (gnus-ephemeral-group-p group)
 966                 (gnus-kill-ephemeral-group group))
 967             (let ((entry (gnus-group-entry group)))
 968               (if entry
 969                   ;; Just change the subscription level if it is an
 970                   ;; unsubscribed group.
 971                   (gnus-group-change-level entry
 972                                            gnus-level-default-subscribed)
 973                 ;; If it is a killed group or a zombie, feed it to the
 974                 ;; mechanism for new group subscription.
 975                 (gnus-call-subscribe-functions
 976                  gnus-browse-subscribe-newsgroup-method
 977                  group)))
 978             (delete-char 1)
 979             (insert (let ((lvl (gnus-group-level group)))
 980                       (cond
 981                        ((< lvl gnus-level-unsubscribed) ? )
 982                        ((< lvl gnus-level-zombie) ?U)
 983                        ((< lvl gnus-level-killed) ?Z)
 984                        (t ?K)))))
 985         (gnus-group-change-level
 986          group gnus-level-unsubscribed gnus-level-default-subscribed)
 987         (delete-char 1)
 988         (insert ?U)))
 989     t))
 990
 991 (defun gnus-browse-exit ()
 992   "Quit browsing and return to the group buffer."
 993   (interactive)
 994   (when (eq major-mode 'gnus-browse-mode)
 995     (gnus-kill-buffer (current-buffer)))
 996   ;; Insert the newly subscribed groups in the group buffer.
 997   (with-current-buffer gnus-group-buffer
 998     (gnus-group-list-groups nil))
 999   (if gnus-browse-return-buffer
1000       (gnus-configure-windows 'server 'force)
1001     (gnus-configure-windows 'group 'force)))
1002
1003 (defun gnus-browse-describe-briefly ()
1004   "Give a one line description of the group mode commands."
1005   (interactive)
1006   (gnus-message 6 "%s"
1007                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
1008
1009 (defun gnus-server-regenerate-server ()
1010   "Issue a command to the server to regenerate all its data structures."
1011   (interactive)
1012   (let ((server (gnus-server-server-name)))
1013     (unless server
1014       (error "No server on the current line"))
1015     (condition-case ()
1016         (gnus-get-function (gnus-server-to-method server)
1017                            'request-regenerate)
1018       (error
1019         (error "This back end doesn't support regeneration")))
1020     (gnus-message 5 "Requesting regeneration of %s..." server)
1021     (unless (gnus-open-server server)
1022       (error "Couldn't open server"))
1023     (if (gnus-request-regenerate server)
1024         (gnus-message 5 "Requesting regeneration of %s...done" server)
1025       (gnus-message 5 "Couldn't regenerate %s" server))))
1026
1027
1028 ;;;
1029 ;;; Server compaction. -- dvl
1030 ;;;
1031
1032 ;; #### FIXME: this function currently fails to update the Group buffer's
1033 ;; #### appearance.
1034 (defun gnus-server-compact-server ()
1035   "Issue a command to the server to compact all its groups.
1036
1037 Note: currently only implemented in nnml."
1038   (interactive)
1039   (let ((server (gnus-server-server-name)))
1040     (unless server
1041       (error "No server on the current line"))
1042     (condition-case ()
1043         (gnus-get-function (gnus-server-to-method server)
1044                            'request-compact)
1045       (error
1046        (error "This back end doesn't support compaction")))
1047     (gnus-message 5 "\
1048 Requesting compaction of %s... (this may take a long time)"
1049                   server)
1050     (unless (gnus-open-server server)
1051       (error "Couldn't open server"))
1052     (if (not (gnus-request-compact server))
1053         (gnus-message 5 "Couldn't compact %s" server)
1054       (gnus-message 5 "Requesting compaction of %s...done" server)
1055       ;; Invalidate the original article buffer which might be out of date.
1056       ;; #### NOTE: Yes, this might be a bit rude, but since compaction
1057       ;; #### will not happen very often, I think this is acceptable.
1058       (let ((original (get-buffer gnus-original-article-buffer)))
1059         (and original (gnus-kill-buffer original))))))
1060
1061 (provide 'gnus-srvr)
1062
1063 ;;; gnus-srvr.el ends here