cgit.sxemacs.org Git - gnus/blob - lisp/gnus-picon.el

   1 ;;; gnus-picon.el --- displaying pretty icons in Gnus
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news xpm annotation glyph faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; There are three picon types relevant to Gnus:
  27 ;;
  28 ;; Persons: person@subdomain.dom
  29 ;;          users/dom/subdomain/person/face.gif
  30 ;;          usenix/dom/subdomain/person/face.gif
  31 ;;          misc/MISC/person/face.gif
  32 ;; Domains: subdomain.dom
  33 ;;          domain/dom/subdomain/unknown/face.gif
  34 ;; Groups:  comp.lang.lisp
  35 ;;          news/comp/lang/lisp/unknown/face.gif
  36 ;;
  37 ;; Original implementation by Wes Hardaker <hardaker@ece.ucdavis.edu>.
  38 ;;
  39 ;;; Code:
  40
  41 ;; For Emacs < 22.2.
  42 (eval-and-compile
  43   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  44
  45 (eval-when-compile (require 'cl))
  46
  47 (require 'gnus)
  48 (require 'gnus-art)
  49
  50 ;;; User variables:
  51
  52 (defcustom gnus-picon-news-directories '("news")
  53   "*List of directories to search for newsgroups faces."
  54   :type '(repeat string)
  55   :group 'gnus-picon)
  56
  57 (defcustom gnus-picon-user-directories '("users" "usenix" "local" "misc")
  58   "*List of directories to search for user faces."
  59   :type '(repeat string)
  60   :group 'gnus-picon)
  61
  62 (defcustom gnus-picon-domain-directories '("domains")
  63   "*List of directories to search for domain faces.
  64 Some people may want to add \"unknown\" to this list."
  65   :type '(repeat string)
  66   :group 'gnus-picon)
  67
  68 (defcustom gnus-picon-file-types
  69   (let ((types (list "xbm")))
  70     (when (gnus-image-type-available-p 'gif)
  71       (push "gif" types))
  72     (when (gnus-image-type-available-p 'xpm)
  73       (push "xpm" types))
  74     types)
  75   "*List of suffixes on picon file names to try."
  76   :type '(repeat string)
  77   :group 'gnus-picon)
  78
  79 (defcustom gnus-picon-style 'inline
  80   "How should picons be displayed.
  81 If `inline', the textual representation is replaced.  If `right', picons are
  82 added right to the textual representation."
  83   ;; FIXME: `right' needs improvement for XEmacs.
  84   :type '(choice (const inline)
  85                  (const right))
  86   :group 'gnus-picon)
  87
  88 ;;; Internal variables:
  89
  90 (defvar gnus-picon-glyph-alist nil
  91   "Picon glyphs cache.
  92 List of pairs (KEY . GLYPH) where KEY is either a filename or an URL.")
  93 (defvar gnus-picon-cache nil)
  94
  95 ;;; Functions:
  96
  97 (defsubst gnus-picon-split-address (address)
  98   (setq address (split-string address "@"))
  99   (if (stringp (cadr address))
 100       (cons (car address) (split-string (cadr address) "\\."))
 101     (if (stringp (car address))
 102         (split-string (car address) "\\."))))
 103
 104 (defun gnus-picon-find-face (address directories &optional exact)
 105   (let* ((address (gnus-picon-split-address address))
 106          (user (pop address))
 107          (faddress address)
 108          database directory result instance base)
 109     (catch 'found
 110       (dolist (database gnus-picon-databases)
 111         (dolist (directory directories)
 112           (setq address faddress
 113                 base (expand-file-name directory database))
 114           (while address
 115             (when (setq result (gnus-picon-find-image
 116                                 (concat base "/" (mapconcat 'downcase
 117                                                             (reverse address)
 118                                                             "/")
 119                                         "/" (downcase user) "/")))
 120               (throw 'found result))
 121             (if exact
 122                 (setq address nil)
 123               (pop address)))
 124           ;; Kludge to search MISC as well.  But not in "news".
 125           (unless (string= directory "news")
 126             (when (setq result (gnus-picon-find-image
 127                                 (concat base "/MISC/" user "/")))
 128               (throw 'found result))))))))
 129
 130 (defun gnus-picon-find-image (directory)
 131   (let ((types gnus-picon-file-types)
 132         found type file)
 133     (while (and (not found)
 134                 (setq type (pop types)))
 135       (setq found (file-exists-p (setq file (concat directory "face." type)))))
 136     (if found
 137         file
 138       nil)))
 139
 140 (defun gnus-picon-insert-glyph (glyph category &optional nostring)
 141   "Insert GLYPH into the buffer.
 142 GLYPH can be either a glyph or a string.  When NOSTRING, no textual
 143 replacement is added."
 144   ;; Using NOSTRING prevents wrong BBDB entries with `gnus-picon-style' set to
 145   ;; 'right.
 146   (if (stringp glyph)
 147       (insert glyph)
 148     (gnus-add-wash-type category)
 149     (gnus-add-image category (car glyph))
 150     (gnus-put-image (car glyph) (unless nostring (cdr glyph)) category)))
 151
 152 (defun gnus-picon-create-glyph (file)
 153   (or (cdr (assoc file gnus-picon-glyph-alist))
 154       (cdar (push (cons file (gnus-create-image
 155                               file nil nil
 156                               :color-symbols '(("None" . "white"))))
 157                   gnus-picon-glyph-alist))))
 158
 159 ;;; Functions that does picon transformations:
 160
 161 (declare-function image-size "image.c" (spec &optional pixels frame))
 162
 163 (defun gnus-picon-transform-address (header category)
 164   (gnus-with-article-headers
 165    (let ((addresses
 166           (mail-header-parse-addresses
 167            ;; mail-header-parse-addresses does not work (reliably) on
 168            ;; decoded headers.
 169            (or
 170             (ignore-errors
 171              (mail-encode-encoded-word-string
 172               (or (mail-fetch-field header) "")))
 173             (mail-fetch-field header))))
 174          spec file point cache len)
 175      (dolist (address addresses)
 176        (setq address (car address))
 177        (when (and (stringp address)
 178                   (setq spec (gnus-picon-split-address address)))
 179          (if (setq cache (cdr (assoc address gnus-picon-cache)))
 180              (setq spec cache)
 181            (when (setq file (or (gnus-picon-find-face
 182                                  address gnus-picon-user-directories)
 183                                 (gnus-picon-find-face
 184                                  (concat "unknown@"
 185                                          (mapconcat
 186                                           'identity (cdr spec) "."))
 187                                  gnus-picon-user-directories)))
 188              (setcar spec (cons (gnus-picon-create-glyph file)
 189                                 (car spec))))
 190
 191            (dotimes (i (1- (length spec)))
 192              (when (setq file (gnus-picon-find-face
 193                                (concat "unknown@"
 194                                        (mapconcat
 195                                         'identity (nthcdr (1+ i) spec) "."))
 196                                gnus-picon-domain-directories t))
 197                (setcar (nthcdr (1+ i) spec)
 198                        (cons (gnus-picon-create-glyph file)
 199                              (nth (1+ i) spec)))))
 200            (setq spec (nreverse spec))
 201            (push (cons address spec) gnus-picon-cache))
 202
 203          (gnus-article-goto-header header)
 204          (mail-header-narrow-to-field)
 205          (case gnus-picon-style
 206                (right
 207                 (when (= (length addresses) 1)
 208                   (setq len (apply '+ (mapcar (lambda (x)
 209                                                 (condition-case nil
 210                                                     (car (image-size (car x)))
 211                                                   (error 0))) spec)))
 212                   (when (> len 0)
 213                     (goto-char (point-at-eol))
 214                     (insert (propertize
 215                              " " 'display
 216                              (cons 'space
 217                                    (list :align-to (- (window-width) 1 len))))))
 218                   (goto-char (point-at-eol))
 219                   (setq point (point-at-eol))
 220                   (dolist (image spec)
 221                     (unless (stringp image)
 222                       (goto-char point)
 223                       (gnus-picon-insert-glyph image category 'nostring)))))
 224                (inline
 225                  (when (search-forward address nil t)
 226                    (delete-region (match-beginning 0) (match-end 0))
 227                    (setq point (point))
 228                    (while spec
 229                      (goto-char point)
 230                      (if (> (length spec) 2)
 231                          (insert ".")
 232                        (if (= (length spec) 2)
 233                            (insert "@")))
 234                      (gnus-picon-insert-glyph (pop spec) category))))))))))
 235
 236 (defun gnus-picon-transform-newsgroups (header)
 237   (interactive)
 238   (gnus-with-article-headers
 239    (gnus-article-goto-header header)
 240    (mail-header-narrow-to-field)
 241    (let ((groups (message-tokenize-header (mail-fetch-field header)))
 242          spec file point)
 243      (dolist (group groups)
 244        (unless (setq spec (cdr (assoc group gnus-picon-cache)))
 245          (setq spec (nreverse (split-string group "[.]")))
 246          (dotimes (i (length spec))
 247            (when (setq file (gnus-picon-find-face
 248                              (concat "unknown@"
 249                                      (mapconcat
 250                                       'identity (nthcdr i spec) "."))
 251                              gnus-picon-news-directories t))
 252              (setcar (nthcdr i spec)
 253                      (cons (gnus-picon-create-glyph file)
 254                            (nth i spec)))))
 255          (push (cons group spec) gnus-picon-cache))
 256        (when (search-forward group nil t)
 257          (delete-region (match-beginning 0) (match-end 0))
 258          (save-restriction
 259            (narrow-to-region (point) (point))
 260            (while spec
 261              (goto-char (point-min))
 262              (if (> (length spec) 1)
 263                  (insert "."))
 264              (gnus-picon-insert-glyph (pop spec) 'newsgroups-picon))
 265            (goto-char (point-max))))))))
 266
 267 ;;; Commands:
 268
 269 ;; #### NOTE: the test for buffer-read-only is the same as in
 270 ;; article-display-[x-]face. See the comment up there.
 271
 272 ;;;###autoload
 273 (defun gnus-treat-from-picon ()
 274   "Display picons in the From header.
 275 If picons are already displayed, remove them."
 276   (interactive)
 277   (let ((wash-picon-p buffer-read-only))
 278     (gnus-with-article-buffer
 279      (if (and wash-picon-p (memq 'from-picon gnus-article-wash-types))
 280          (gnus-delete-images 'from-picon)
 281        (gnus-picon-transform-address "from" 'from-picon)))))
 282
 283 ;;;###autoload
 284 (defun gnus-treat-mail-picon ()
 285   "Display picons in the Cc and To headers.
 286 If picons are already displayed, remove them."
 287   (interactive)
 288   (let ((wash-picon-p buffer-read-only))
 289     (gnus-with-article-buffer
 290      (if (and wash-picon-p (memq 'mail-picon gnus-article-wash-types))
 291          (gnus-delete-images 'mail-picon)
 292        (gnus-picon-transform-address "cc" 'mail-picon)
 293        (gnus-picon-transform-address "to" 'mail-picon)))))
 294
 295 ;;;###autoload
 296 (defun gnus-treat-newsgroups-picon ()
 297   "Display picons in the Newsgroups and Followup-To headers.
 298 If picons are already displayed, remove them."
 299   (interactive)
 300   (let ((wash-picon-p buffer-read-only))
 301     (gnus-with-article-buffer
 302      (if (and wash-picon-p (memq 'newsgroups-picon gnus-article-wash-types))
 303          (gnus-delete-images 'newsgroups-picon)
 304        (gnus-picon-transform-newsgroups "newsgroups")
 305        (gnus-picon-transform-newsgroups "followup-to")))))
 306
 307 (provide 'gnus-picon)
 308
 309 ;;; gnus-picon.el ends here