cgit.sxemacs.org Git - gnus/blob - lisp/gnus-picon.el

   1 ;;; gnus-picon.el --- displaying pretty icons in Gnus
   2 ;; Copyright (C) 1996,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Wes Hardaker <hardaker@ece.ucdavis.edu>
   5 ;; Keywords: news xpm annotation glyph faces
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'xpm)
  30 (require 'annotations)
  31 (require 'custom)
  32 (require 'gnus-art)
  33 (require 'gnus-win)
  34
  35 ;;; User variables:
  36
  37 (defgroup picons nil
  38   "Show pictures of people, domains, and newsgroups (XEmacs).
  39 For this to work, you must add gnus-group-display-picons to the
  40 gnus-summary-display-hook or to the gnus-article-display-hook
  41 depending on what gnus-picons-display-where is set to.  You must
  42 also add gnus-article-display-picons to gnus-article-display-hook."
  43   :group 'gnus-visual)
  44
  45 (defcustom gnus-picons-display-where 'picons
  46   "Where to display the group and article icons.
  47 Legal values are `article' and `picons'."
  48   :type '(choice symbol string)
  49   :group 'picons)
  50
  51 (defcustom gnus-picons-has-modeline-p t
  52   "*Whether the picons window should have a modeline.
  53 This is only useful if `gnus-picons-display-where' is `picons'."
  54   :type 'boolean
  55   :group 'picons)
  56
  57 (defcustom gnus-picons-database "/usr/local/faces"
  58   "*Defines the location of the faces database.
  59 For information on obtaining this database of pretty pictures, please
  60 see http://www.cs.indiana.edu/picons/ftp/index.html"
  61   :type 'directory
  62   :group 'picons)
  63
  64 (defcustom gnus-picons-news-directories '("news")
  65   "*List of directories to search for newsgroups faces."
  66   :type '(repeat string)
  67   :group 'picons)
  68 (define-obsolete-variable-alias 'gnus-picons-news-directory
  69   'gnus-picons-news-directories)
  70
  71 (defcustom gnus-picons-user-directories '("local" "users" "usenix" "misc")
  72   "*List of directories to search for user faces."
  73   :type '(repeat string)
  74   :group 'picons)
  75
  76 (defcustom gnus-picons-domain-directories '("domains")
  77   "*List of directories to search for domain faces.
  78 Some people may want to add \"unknown\" to this list."
  79   :type '(repeat string)
  80   :group 'picons)
  81
  82 (defcustom gnus-picons-refresh-before-display nil
  83   "*If non-nil, display the article buffer before computing the picons."
  84   :type 'boolean
  85   :group 'picons)
  86
  87 (defcustom gnus-picons-group-excluded-groups nil
  88   "*If this regexp matches the group name, group picons will be disabled."
  89   :type 'regexp
  90   :group 'picons)
  91
  92 (defcustom gnus-picons-x-face-file-name
  93   (format "/tmp/picon-xface.%s.xbm" (user-login-name))
  94   "*The name of the file in which to store the converted X-face header."
  95   :type 'string
  96   :group 'picons)
  97
  98 (defcustom gnus-picons-convert-x-face (format "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | pbmtoxbm > %s" gnus-picons-x-face-file-name)
  99   "*Command to convert the x-face header into a xbm file."
 100   :type 'string
 101   :group 'picons)
 102
 103 (defcustom gnus-picons-display-as-address t
 104   "*If t display textual email addresses along with pictures."
 105   :type 'boolean
 106   :group 'picons)
 107
 108 (defcustom gnus-picons-file-suffixes
 109   (when (featurep 'x)
 110     (let ((types (list "xbm")))
 111       (when (featurep 'gif)
 112         (push "gif" types))
 113       (when (featurep 'xpm)
 114         (push "xpm" types))
 115       types))
 116   "*List of suffixes on picon file names to try."
 117   :type '(repeat string)
 118   :group 'picons)
 119
 120 (defcustom gnus-picons-display-article-move-p nil
 121   "*Whether to move point to first empty line when displaying picons.
 122 This has only an effect if `gnus-picons-display-where' has value `article'."
 123   :type 'boolean
 124   :group 'picons)
 125
 126 (defcustom gnus-picons-clear-cache-on-shutdown t
 127   "*Whether to clear the picons cache when exiting gnus.
 128 Gnus caches every picons it finds while it is running.  This saves
 129 some time in the search process but eats some memory.  If this
 130 variable is set to nil, Gnus will never clear the cache itself; you
 131 will have to manually call `gnus-picons-clear-cache' to clear it.
 132 Otherwise the cache will be cleared every time you exit Gnus."
 133   :type 'boolean
 134   :group 'picons)
 135
 136 (defcustom gnus-picons-piconsearch-url nil
 137   "*The url to query for picons.  Setting this to nil will disable it.
 138 The only publicly available address currently known is
 139 http://www.cs.indiana.edu:800/piconsearch.  If you know of any other,
 140 please tell me so that we can list it."
 141   :type '(choice (const :tag "Disable" :value nil)
 142                  (const :tag "www.cs.indiana.edu"
 143                         :value "http://www.cs.indiana.edu:800/piconsearch")
 144                  (string))
 145   :group 'picons)
 146
 147 (defface gnus-picons-xbm-face '((t (:foreground "black" :background "white")))
 148   "Face to show xbm picons in."
 149   :group 'picons)
 150
 151 ;;; Internal variables:
 152
 153 (defvar gnus-picons-processes-alist nil
 154   "Picons processes currently running and their environment.")
 155 (defvar gnus-picons-glyph-alist nil
 156   "Picons glyphs cache.
 157 List of pairs (KEY . GLYPH) where KEY is either a filename or an URL.")
 158 (defvar gnus-picons-url-alist nil
 159   "Picons file names cache.
 160 List of pairs (KEY . NAME) where KEY is (USER HOST DBS) and NAME is an URL.")
 161
 162 (defvar gnus-picons-jobs-alist nil
 163   "List of jobs that still need be done.
 164 This is a list of (SYM-ANN TAG ARGS...) where SYM-ANN three annotations list,
 165 TAG is one of `picon' or `search' indicating that the job should query a
 166 picon or do a search for picons file names, and ARGS is some additionnal
 167 arguments necessary for the job.")
 168
 169 (defvar gnus-picons-job-already-running nil
 170   "Lock to ensure only one stream of http requests is running.")
 171
 172 ;;; Functions:
 173
 174 (defun gnus-picons-remove-all ()
 175   "Removes all picons from the Gnus display(s)."
 176   (interactive)
 177   (map-extents (function (lambda (ext unused) (delete-annotation ext) nil))
 178                nil nil nil nil nil 'gnus-picon)
 179   (setq gnus-picons-jobs-alist '())
 180   ;; notify running job that it may have been preempted
 181   (if (and (listp gnus-picons-job-already-running)
 182            gnus-picons-job-already-running)
 183       (setq gnus-picons-job-already-running t)))
 184
 185 (defun gnus-get-buffer-name (variable)
 186   "Returns the buffer name associated with the contents of a variable."
 187   (let ((buf (gnus-get-buffer-create (gnus-window-to-buffer-helper
 188                                  (cdr
 189                                   (assq variable gnus-window-to-buffer))))))
 190     (and buf
 191          (buffer-name buf))))
 192
 193 (defun gnus-picons-buffer-name ()
 194   (cond ((or (stringp gnus-picons-display-where)
 195              (bufferp gnus-picons-display-where))
 196          gnus-picons-display-where)
 197         ((eq gnus-picons-display-where 'picons)
 198          (if gnus-single-article-buffer
 199              "*Picons*"
 200            (concat "*Picons " gnus-newsgroup-name "*")))
 201         (t
 202          (gnus-get-buffer-name gnus-picons-display-where))))
 203
 204 (defun gnus-picons-kill-buffer ()
 205   (let ((buf (get-buffer (gnus-picons-buffer-name))))
 206     (if (buffer-live-p buf)
 207         (kill-buffer buf))))
 208
 209 (defun gnus-picons-setup-buffer ()
 210   (let ((name (gnus-picons-buffer-name)))
 211     (save-excursion
 212       (if (get-buffer name)
 213           (set-buffer name)
 214         (set-buffer (gnus-get-buffer-create name))
 215         (buffer-disable-undo)
 216         (setq buffer-read-only t)
 217         (add-hook 'gnus-summary-prepare-exit-hook 'gnus-picons-kill-buffer))
 218       (current-buffer))))
 219
 220 (defun gnus-picons-set-buffer ()
 221   (set-buffer (gnus-picons-setup-buffer))
 222   (goto-char (point-min))
 223   (if (and (eq gnus-picons-display-where 'article)
 224            gnus-picons-display-article-move-p)
 225       (if (search-forward "\n\n" nil t)
 226           (forward-line -1)
 227         (goto-char (point-max)))
 228     (setq buffer-read-only t)
 229     (unless gnus-picons-has-modeline-p
 230       (set-specifier has-modeline-p
 231                      (list (list (current-buffer)
 232                                  (cons nil gnus-picons-has-modeline-p)))))))
 233
 234 (defun gnus-picons-prepare-for-annotations ()
 235   "Prepare picons buffer for putting annotations."
 236   ;; let drawing catch up
 237   (when gnus-picons-refresh-before-display
 238     (sit-for 0))
 239   (gnus-picons-set-buffer)
 240   (gnus-picons-remove-all))
 241
 242 (defun gnus-picons-make-annotation (&rest args)
 243   (let ((annot (apply 'make-annotation args)))
 244     (set-extent-property annot 'gnus-picon t)
 245     (set-extent-property annot 'duplicable t)
 246     annot))
 247
 248 (defun gnus-picons-article-display-x-face ()
 249   "Display the x-face header bitmap in the 'gnus-picons-display-where buffer."
 250   (let ((gnus-article-x-face-command 'gnus-picons-display-x-face))
 251     (gnus-article-display-x-face)))
 252
 253 (defun gnus-picons-x-face-sentinel (process event)
 254   (when (memq process gnus-picons-processes-alist)
 255     (setq gnus-picons-processes-alist
 256           (delq process gnus-picons-processes-alist))
 257     (gnus-picons-set-buffer)
 258     (gnus-picons-make-annotation (make-glyph gnus-picons-x-face-file-name)
 259                                  nil 'text)
 260     (when (file-exists-p gnus-picons-x-face-file-name)
 261       (delete-file gnus-picons-x-face-file-name))))
 262
 263 (defun gnus-picons-display-x-face (beg end)
 264   "Function to display the x-face header in the picons window.
 265 To use:  (setq gnus-article-x-face-command 'gnus-picons-display-x-face)"
 266   (interactive)
 267   (if (featurep 'xface)
 268       ;; Use builtin support
 269       (save-excursion
 270         ;; Don't remove this binding, it is really needed: when
 271         ;; `gnus-picons-set-buffer' changes buffer (like when it is
 272         ;; set to display picons outside of the article buffer), BEG
 273         ;; and END still refer the buffer current now !
 274         (let ((buf (current-buffer)))
 275           (gnus-picons-set-buffer)
 276           (gnus-picons-make-annotation
 277            (vector 'xface
 278                    :data (concat "X-Face: " (buffer-substring beg end buf)))
 279            nil 'text nil nil nil t)))
 280     ;; convert the x-face header to a .xbm file
 281     (let* ((process-connection-type nil)
 282            (process (start-process-shell-command "gnus-x-face" nil
 283                                                  gnus-picons-convert-x-face)))
 284       (push process gnus-picons-processes-alist)
 285       (process-kill-without-query process)
 286       (set-process-sentinel process 'gnus-picons-x-face-sentinel)
 287       (process-send-region process beg end)
 288       (process-send-eof process))))
 289
 290 (defun gnus-article-display-picons ()
 291   "Display faces for an author and her domain in gnus-picons-display-where."
 292   (interactive)
 293   (let (from at-idx)
 294     (when (and (featurep 'xpm)
 295                (or (not (fboundp 'device-type)) (equal (device-type) 'x))
 296                (setq from (mail-fetch-field "from"))
 297                (setq from (downcase (or (cadr (mail-extract-address-components
 298                                                from))
 299                                         "")))
 300                (or (setq at-idx (string-match "@" from))
 301                    (setq at-idx (length from))))
 302       (save-excursion
 303         (let ((username (downcase (substring from 0 at-idx)))
 304               (addrs (if (eq at-idx (length from))
 305                          (if gnus-local-domain
 306                              (message-tokenize-header gnus-local-domain "."))
 307                        (message-tokenize-header (substring from (1+ at-idx))
 308                                                 "."))))
 309           (gnus-picons-prepare-for-annotations)
 310           (gnus-group-display-picons)
 311           (unless gnus-picons-display-article-move-p
 312             (save-restriction
 313               (let ((buffer-read-only nil))
 314                 (when (re-search-forward "^From: " nil t)
 315                   (narrow-to-region (point) (gnus-point-at-eol))
 316                   (when (search-forward from nil t)
 317                     (gnus-put-text-property
 318                      (match-beginning 0) (match-end 0)
 319                      'invisible t))))))
 320           (if (null gnus-picons-piconsearch-url)
 321               (progn
 322                 (gnus-picons-display-pairs (gnus-picons-lookup-pairs
 323                                             addrs
 324                                             gnus-picons-domain-directories)
 325                                            gnus-picons-display-as-address
 326                                            "." t)
 327                 (if (and gnus-picons-display-as-address addrs)
 328                     (gnus-picons-make-annotation
 329                      [string :data "@"] nil 'text nil nil nil t))
 330                 (gnus-picons-display-picon-or-name
 331                  (gnus-picons-lookup-user username addrs)
 332                  username t))
 333             (push (list 'gnus-article-annotations 'search username addrs
 334                         gnus-picons-domain-directories t)
 335                   gnus-picons-jobs-alist)
 336             (gnus-picons-next-job)))))))
 337
 338 (defun gnus-group-display-picons ()
 339   "Display icons for the group in the `gnus-picons-display-where' buffer."
 340   (interactive)
 341   (when (and (featurep 'xpm)
 342              (or (not (fboundp 'device-type)) (equal (device-type) 'x))
 343              (or (null gnus-picons-group-excluded-groups)
 344                  (not (string-match gnus-picons-group-excluded-groups
 345                                     gnus-newsgroup-name))))
 346     (let* ((newsgroups (mail-fetch-field "newsgroups"))
 347            (groups
 348             (if (or gnus-picons-display-article-move-p
 349                     (not newsgroups))(mail-fetch-field "newsgroups")
 350                 (list (gnus-group-real-name gnus-newsgroup-name))
 351               (split-string newsgroups ",")))
 352            group)
 353       (save-excursion
 354         (gnus-picons-prepare-for-annotations)
 355         (while (setq group (pop groups))
 356           (unless gnus-picons-display-article-move-p
 357             (save-restriction
 358               (let ((buffer-read-only nil))
 359                 (goto-char (point-min))
 360                 (when (re-search-forward "^Newsgroups:" nil t)
 361                   (narrow-to-region (point) (gnus-point-at-eol))
 362                   (when (search-forward group nil t)
 363                     (gnus-put-text-property
 364                      (match-beginning 0) (match-end 0)
 365                      'invisible t))))))
 366           (if (null gnus-picons-piconsearch-url)
 367               (gnus-picons-display-pairs
 368                (gnus-picons-lookup-pairs
 369                 (reverse (split-string group "\\."))
 370                 gnus-picons-news-directories)
 371                t ".")
 372             (push (list 'gnus-group-annotations 'search nil
 373                         (split-string group "\\.")
 374                         (if (listp gnus-picons-news-directories)
 375                             gnus-picons-news-directories
 376                           (list gnus-picons-news-directories))
 377                         nil)
 378                   gnus-picons-jobs-alist)
 379             (gnus-picons-next-job))
 380
 381           (add-hook 'gnus-summary-exit-hook 'gnus-picons-remove-all))))))
 382
 383 (defun gnus-picons-lookup-internal (addrs dir)
 384   (setq dir (expand-file-name dir gnus-picons-database))
 385   (gnus-picons-try-face (dolist (part (reverse addrs) dir)
 386                           (setq dir (expand-file-name part dir)))))
 387
 388 (defun gnus-picons-lookup (addrs dirs)
 389   "Lookup the picon for ADDRS in databases DIRS.
 390 Returns the picon filename or NIL if none found."
 391   (let (result)
 392     (while (and dirs (null result))
 393       (setq result (gnus-picons-lookup-internal addrs (pop dirs))))
 394     result))
 395
 396 (defun gnus-picons-lookup-user-internal (user domains)
 397   (let ((dirs gnus-picons-user-directories)
 398         domains-tmp dir picon)
 399     (while (and dirs (null picon))
 400       (setq domains-tmp domains
 401             dir (pop dirs))
 402       (while (and domains-tmp
 403                   (null (setq picon (gnus-picons-lookup-internal
 404                                      (cons user domains-tmp) dir))))
 405         (pop domains-tmp))
 406       ;; Also make a try in MISC subdir
 407       (unless picon
 408         (setq picon (gnus-picons-lookup-internal (list user "MISC") dir))))
 409     picon))
 410
 411 (defun gnus-picons-lookup-user (user domains)
 412   "Lookup the picon for USER at DOMAINS.
 413 USER is a string containing a name.
 414 DOMAINS is a list of strings from the fully qualified domain name."
 415   (or (gnus-picons-lookup-user-internal user domains)
 416       (gnus-picons-lookup-user-internal "unknown" domains)))
 417
 418 (defun gnus-picons-lookup-pairs (domains directories)
 419   "Lookup picons for DOMAINS and all its parents in DIRECTORIES.
 420 Returns a list of PAIRS whose CAR is the picon filename or NIL if
 421 none, and whose CDR is the corresponding element of DOMAINS."
 422   (let (picons)
 423     (setq directories (if (listp directories)
 424                           directories
 425                         (list directories)))
 426     (while domains
 427       (push (list (gnus-picons-lookup (cons "unknown" domains) directories)
 428                   (pop domains))
 429             picons))
 430     picons))
 431
 432 (defun gnus-picons-display-picon-or-name (picon name &optional right-p)
 433   (cond (picon (gnus-picons-display-glyph picon name right-p))
 434         (gnus-picons-display-as-address (list (gnus-picons-make-annotation
 435                                                (vector 'string :data name)
 436                                                nil 'text
 437                                                nil nil nil right-p)))))
 438
 439 (defun gnus-picons-display-pairs (pairs &optional bar-p dot-p right-p)
 440   "Display picons in list PAIRS."
 441   (let ((domain-p (and gnus-picons-display-as-address dot-p))
 442         pair picons)
 443     (when (and bar-p domain-p right-p
 444                gnus-picons-display-article-move-p)
 445       (setq picons (gnus-picons-display-glyph
 446                     (let ((gnus-picons-file-suffixes '("xbm")))
 447                       (gnus-picons-try-face
 448                        gnus-xmas-glyph-directory "bar."))
 449                     nil right-p)))
 450     (while (setq pair (pop pairs))
 451       (setq picons (nconc picons
 452                           (gnus-picons-display-picon-or-name
 453                            (car pair) (cadr pair) right-p)
 454                           (if (and domain-p pairs)
 455                               (list (gnus-picons-make-annotation
 456                                      (vector 'string :data dot-p)
 457                                      nil 'text nil nil nil right-p))))))
 458     picons))
 459
 460 (defun gnus-picons-try-face (dir &optional filebase)
 461   (let* ((dir (file-name-as-directory dir))
 462          (filebase (or filebase "face."))
 463          (key (concat dir filebase))
 464          (glyph (cdr (assoc key gnus-picons-glyph-alist)))
 465          (suffixes gnus-picons-file-suffixes)
 466          f suf)
 467     (while (setq suf (pop suffixes))
 468       (when (file-exists-p (setq f (expand-file-name
 469                                     (concat filebase suf)
 470                                     dir)))
 471         (setq suffixes nil
 472               glyph (make-glyph f))
 473         (when (equal suf "xbm")
 474           (set-glyph-face glyph 'gnus-picons-xbm-face))
 475         (push (cons key glyph) gnus-picons-glyph-alist)))
 476     glyph))
 477
 478 (defun gnus-picons-display-glyph (glyph &optional part rightp)
 479   (set-glyph-baseline glyph 70)
 480   (let ((new (gnus-picons-make-annotation
 481               glyph (point) 'text nil nil nil rightp)))
 482     (when (and part gnus-picons-display-as-address)
 483       (set-annotation-data
 484        new (cons new (make-glyph (vector 'string :data part))))
 485       (set-annotation-action new 'gnus-picons-action-toggle))
 486     (nconc
 487      (list new)
 488      (if (and (eq major-mode 'gnus-article-mode)
 489               (not gnus-picons-display-as-address)
 490               (not part))
 491          (list (gnus-picons-make-annotation [string :data " "] (point)
 492                                             'text nil nil nil rightp))))))
 493
 494 (defun gnus-picons-action-toggle (data)
 495   "Toggle annotation."
 496   (interactive "e")
 497   (let* ((annot (car data))
 498          (glyph (annotation-glyph annot)))
 499     (set-annotation-glyph annot (cdr data))
 500     (set-annotation-data annot (cons annot glyph))))
 501
 502 (defun gnus-picons-clear-cache ()
 503   "Clear the picons cache."
 504   (interactive)
 505   (setq gnus-picons-glyph-alist nil
 506         gnus-picons-url-alist nil))
 507
 508 (gnus-add-shutdown 'gnus-picons-close 'gnus)
 509
 510 (defun gnus-picons-close ()
 511   "Shut down the picons."
 512   (if gnus-picons-clear-cache-on-shutdown
 513       (gnus-picons-clear-cache)))
 514
 515 ;;; Query a remote DB.  This requires some stuff from w3 !
 516
 517 (eval-and-compile
 518   (ignore-errors
 519     (require 'url)
 520     (require 'w3-forms)))
 521
 522 (defun gnus-picons-url-retrieve (url fn arg)
 523   (let ((old-asynch (default-value 'url-be-asynchronous))
 524         (url-working-buffer (generate-new-buffer " *picons*"))
 525         (url-package-name "Gnus")
 526         (url-package-version gnus-version-number)
 527         url-request-method)
 528     (setq-default url-be-asynchronous t)
 529     (save-excursion
 530       (set-buffer url-working-buffer)
 531       (setq url-be-asynchronous t
 532             url-current-callback-data arg
 533             url-current-callback-func fn)
 534       (url-retrieve url t))
 535     (setq-default url-be-asynchronous old-asynch)))
 536
 537 (defun gnus-picons-make-glyph (type)
 538   "Make a TYPE glyph using current buffer as data.  Handles xbm nicely."
 539   (cond ((null type) nil)
 540         ((eq type 'xbm) (let ((fname (make-temp-name "/tmp/picon")))
 541                           (write-region (point-min) (point-max) fname
 542                                         nil 'quiet)
 543                           (prog1 (make-glyph (vector 'xbm :file fname))
 544                             (delete-file fname))))
 545         (t (make-glyph (vector type :data (buffer-string))))))
 546
 547 ;;; Parsing of piconsearch result page.
 548
 549 ;; Assumes:
 550 ;; 1 - each value field has the form: "<strong>key</strong> = <kbd>value</kbd>"
 551 ;; 2 - a "<p>" separates the keywords from the results
 552 ;; 3 - every results begins by the path within the database at the beginning
 553 ;;     of the line in raw text.
 554 ;; 3b - and the href following it is the preferred image type.
 555
 556 ;; if 1 or 2 is not met, it will probably cause an error.  The other
 557 ;; will go undetected
 558
 559 (defun gnus-picons-parse-value (name)
 560   (goto-char (point-min))
 561   (re-search-forward (concat "<strong>"
 562                              (regexp-quote name)
 563                              "</strong> *= *<kbd> *\\([^ <][^<]*\\) *</kbd>"))
 564   (buffer-substring (match-beginning 1) (match-end 1)))
 565
 566 (defun gnus-picons-parse-filenames ()
 567   ;; returns an alist of ((USER ADDRS DB) . URL)
 568   (let* ((case-fold-search t)
 569          (user (gnus-picons-parse-value "user"))
 570          (host (gnus-picons-parse-value "host"))
 571          (dbs (message-tokenize-header (gnus-picons-parse-value "db") " "))
 572          (start-re
 573           (concat
 574            ;; dbs
 575            "^\\(" (mapconcat 'identity dbs "\\|") "\\)/"
 576            ;; host
 577            "\\(\\(" (replace-in-string host "\\." "/\\|" t) "/\\|MISC/\\)*\\)"
 578            ;; user
 579            "\\(" (regexp-quote user) "\\|unknown\\)/"
 580            "face\\."))
 581          cur-db cur-host cur-user types res)
 582     ;; now point will be somewhere in the header.  Find beginning of
 583     ;; entries
 584     (re-search-forward "<p>[ \t\n]*")
 585     (while (re-search-forward start-re nil t)
 586       (setq cur-db (buffer-substring (match-beginning 1) (match-end 1))
 587             cur-host (buffer-substring (match-beginning 2) (match-end 2))
 588             cur-user (buffer-substring (match-beginning 4) (match-end 4))
 589             cur-host (nreverse (message-tokenize-header cur-host "/")))
 590       ;; XXX - KLUDGE: there is a blank picon in news/MISC/unknown
 591       (unless (and (string-equal cur-db "news")
 592                    (string-equal cur-user "unknown")
 593                    (equal cur-host '("MISC")))
 594         ;; ok now we have found an entry (USER HOST DB), find the
 595         ;; corresponding picon URL
 596         (save-restriction
 597           ;; restrict region to this entry
 598           (narrow-to-region (point) (search-forward "<br>"))
 599           (goto-char (point-min))
 600           (setq types gnus-picons-file-suffixes)
 601           (while (and types
 602                       (not (re-search-forward
 603                             (concat "<a[ \t\n]+href=\"\\([^\"]*\\."
 604                                     (regexp-quote (car types)) "\\)\"")
 605                             nil t)))
 606             (pop types))
 607           (push (cons (list cur-user cur-host cur-db)
 608                       (buffer-substring (match-beginning 1) (match-end 1)))
 609                 res))))
 610     (nreverse res)))
 611
 612 ;;; picon network display functions :
 613
 614 (defun gnus-picons-network-display-internal (sym-ann glyph part right-p)
 615   (gnus-picons-set-buffer)
 616   (gnus-picons-display-picon-or-name glyph part right-p)
 617   (gnus-picons-next-job-internal))
 618
 619 (defun gnus-picons-network-display-callback (url part sym-ann right-p)
 620   (let ((glyph (gnus-picons-make-glyph (cdr (assoc url-current-mime-type
 621                                                    w3-image-mappings)))))
 622     (kill-buffer (current-buffer))
 623     (push (cons url glyph) gnus-picons-glyph-alist)
 624     ;; only do the job if it has not been preempted.
 625     (if (equal gnus-picons-job-already-running
 626                (list sym-ann 'picon url part right-p))
 627         (gnus-picons-network-display-internal sym-ann glyph part right-p)
 628       (gnus-picons-next-job-internal))))
 629
 630 (defun gnus-picons-network-display (url part sym-ann right-p)
 631   (let ((cache (assoc url gnus-picons-glyph-alist)))
 632     (if (or cache (null url))
 633         (gnus-picons-network-display-internal sym-ann (cdr cache) part right-p)
 634       (gnus-picons-url-retrieve url 'gnus-picons-network-display-callback
 635                                 (list url part sym-ann right-p)))))
 636
 637 ;;; search job functions
 638
 639 (defun gnus-picons-network-search-internal (user addrs dbs sym-ann right-p
 640                                                  &optional fnames)
 641   (let (curkey dom pfx url dbs-tmp cache new-jobs)
 642     ;; First do the domain search
 643     (dolist (part (if right-p
 644                       (reverse addrs)
 645                     addrs))
 646       (setq pfx (nconc (list part) pfx)
 647             dom (cond ((and dom right-p) (concat part "." dom))
 648                       (dom (concat dom "." part))
 649                       (t part))
 650             curkey (list "unknown" dom dbs))
 651       (when (null (setq cache (assoc curkey gnus-picons-url-alist)))
 652         ;; This one is not yet in the cache, create a new entry
 653         ;; Search for an entry
 654         (setq dbs-tmp dbs
 655               url nil)
 656         (while (and dbs-tmp (null url))
 657           (setq url (or (cdr (assoc (list "unknown" pfx (car dbs-tmp)) fnames))
 658                         (and (eq dom part)
 659                              ;; This is the first component.  Try the
 660                              ;; catch-all MISC component
 661                              (cdr (assoc (list "unknown"
 662                                                '("MISC")
 663                                                (car dbs-tmp))
 664                                          fnames)))))
 665           (pop dbs-tmp))
 666         (push (setq cache (cons curkey url)) gnus-picons-url-alist))
 667       ;; Put this glyph in the job list
 668       (if (and (not (eq dom part)) gnus-picons-display-as-address)
 669           (push (list sym-ann "." right-p) new-jobs))
 670       (push (list sym-ann 'picon (cdr cache) part right-p) new-jobs))
 671     ;; next, the user search
 672     (when user
 673       (setq curkey (list user dom gnus-picons-user-directories))
 674       (if (null (setq cache (assoc curkey gnus-picons-url-alist)))
 675           (let ((users (list user "unknown"))
 676                 dirs usr domains-tmp dir picon)
 677             (while (and users (null picon))
 678               (setq dirs gnus-picons-user-directories
 679                     usr (pop users))
 680               (while (and dirs (null picon))
 681                 (setq domains-tmp addrs
 682                       dir (pop dirs))
 683                 (while (and domains-tmp
 684                             (null (setq picon (assoc (list usr domains-tmp dir)
 685                                                      fnames))))
 686                   (pop domains-tmp))
 687                 (unless picon
 688                   (setq picon (assoc (list usr '("MISC") dir) fnames)))))
 689             (push (setq cache (cons curkey (cdr picon)))
 690                   gnus-picons-url-alist)))
 691       (if (and gnus-picons-display-as-address new-jobs)
 692           (push (list sym-ann "@" right-p) new-jobs))
 693       (push (list sym-ann 'picon (cdr cache) user right-p) new-jobs))
 694     (if (and gnus-picons-display-as-address (not right-p))
 695         (push (list sym-ann 'bar right-p) new-jobs))
 696     ;; only put the jobs in the queue if this job has not been preempted.
 697     (if (equal gnus-picons-job-already-running
 698                (list sym-ann 'search user addrs dbs right-p))
 699         (setq gnus-picons-jobs-alist
 700               (nconc (if (and gnus-picons-display-as-address right-p)
 701                          (list (list sym-ann 'bar right-p)))
 702                      (nreverse new-jobs)
 703                      gnus-picons-jobs-alist)))
 704     (gnus-picons-next-job-internal)))
 705
 706 (defun gnus-picons-network-search-callback (user addrs dbs sym-ann right-p)
 707   (gnus-picons-network-search-internal user addrs dbs sym-ann right-p
 708                                        (prog1 (gnus-picons-parse-filenames)
 709                                          (kill-buffer (current-buffer)))))
 710
 711 ;; Initiate a query on the picon database
 712 (defun gnus-picons-network-search (user addrs dbs sym-ann right-p)
 713   (let* ((host (mapconcat 'identity addrs "."))
 714          (key (list (or user "unknown") host (if user
 715                                                   gnus-picons-user-directories
 716                                                 dbs)))
 717          (cache (assoc key gnus-picons-url-alist)))
 718     (if (null cache)
 719         (gnus-picons-url-retrieve
 720          (concat gnus-picons-piconsearch-url
 721                  "?user=" (w3-form-encode-xwfu (or user "unknown"))
 722                  "&host=" (w3-form-encode-xwfu host)
 723                  "&db=" (mapconcat 'w3-form-encode-xwfu
 724                                    (if user
 725                                        (append dbs
 726                                                gnus-picons-user-directories)
 727                                      dbs)
 728                                    "+"))
 729          'gnus-picons-network-search-callback
 730          (list user addrs dbs sym-ann right-p))
 731       (gnus-picons-network-search-internal user addrs dbs sym-ann right-p))))
 732
 733 ;;; Main jobs dispatcher function
 734
 735 (defun gnus-picons-next-job-internal ()
 736   (when (setq gnus-picons-job-already-running (pop gnus-picons-jobs-alist))
 737     (let* ((job gnus-picons-job-already-running)
 738            (sym-ann (pop job))
 739            (tag (pop job)))
 740       (when tag
 741         (cond
 742          ((stringp tag);; (SYM-ANN "..." RIGHT-P)
 743           (gnus-picons-network-display-internal
 744            sym-ann nil tag (pop job)))
 745          ((eq 'bar tag)
 746           (gnus-picons-network-display-internal
 747            sym-ann
 748            (let ((gnus-picons-file-suffixes '("xbm")))
 749              (gnus-picons-try-face
 750               gnus-xmas-glyph-directory "bar."))
 751            nil (pop job)))
 752          ((eq 'search tag);; (SYM-ANN 'search USER ADDRS DBS RIGHT-P)
 753           (gnus-picons-network-search
 754            (pop job) (pop job) (pop job) sym-ann (pop job)))
 755          ((eq 'picon tag);; (SYM-ANN 'picon URL PART RIGHT-P)
 756           (gnus-picons-network-display
 757            (pop job) (pop job) sym-ann (pop job)))
 758          (t
 759           (setq gnus-picons-job-already-running nil)
 760           (error "Unknown picon job tag %s" tag)))))))
 761
 762 (defun gnus-picons-next-job ()
 763   "Start processing the job queue if it is not in progress."
 764   (unless gnus-picons-job-already-running
 765     (gnus-picons-next-job-internal)))
 766
 767 (provide 'gnus-picon)
 768
 769 ;;; gnus-picon.el ends here