cgit.sxemacs.org Git - gnus/blob - lisp/gnus-picon.el

   1 ;;; gnus-picon.el --- displaying pretty icons in Gnus
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001
   4 ;;      Free Software Foundation, Inc.
   5
   6 ;; Author: Wes Hardaker <hardaker@ece.ucdavis.edu>
   7 ;; Keywords: news xpm annotation glyph faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; There are three picon types relevant to Gnus:
  29 ;;
  30 ;; Persons: person@subdomain.dom
  31 ;;          users/dom/subdomain/person/face.gif
  32 ;;          usenix/dom/subdomain/person/face.gif
  33 ;;          misc/MISC/person/face.gif
  34 ;; Domains: subdomain.dom
  35 ;;          domain/dom/subdomain/unknown/face.gif
  36 ;; Groups:  comp.lang.lisp
  37 ;;          news/comp/lang/lisp/unknown/face.gif
  38
  39 ;;; Code:
  40
  41 (require 'gnus)
  42 (require 'custom)
  43 (require 'gnus-art)
  44 (require 'gnus-win)
  45
  46 ;;; User variables:
  47
  48 (defgroup picon nil
  49   "Show pictures of people, domains, and newsgroups.
  50 For this to work, you must switch on the `gnus-treat-display-picon'
  51 variable."
  52   :group 'gnus-visual)
  53
  54 (defcustom gnus-picon-databases '("/usr/lib/picon" "/usr/local/faces")
  55   "*Defines the location of the faces database.
  56 For information on obtaining this database of pretty pictures, please
  57 see http://www.cs.indiana.edu/picons/ftp/index.html"
  58   :type 'directory
  59   :group 'picon)
  60
  61 (defcustom gnus-picon-news-directories '("news")
  62   "*List of directories to search for newsgroups faces."
  63   :type '(repeat string)
  64   :group 'picon)
  65
  66 (defcustom gnus-picon-user-directories '("users" "usenix" "local" "misc")
  67   "*List of directories to search for user faces."
  68   :type '(repeat string)
  69   :group 'picon)
  70
  71 (defcustom gnus-picon-domain-directories '("domains")
  72   "*List of directories to search for domain faces.
  73 Some people may want to add \"unknown\" to this list."
  74   :type '(repeat string)
  75   :group 'picon)
  76
  77 (defcustom gnus-picon-file-types
  78   (let ((types (list "xbm")))
  79     (when (gnus-image-type-available-p 'gif)
  80       (push "gif" types))
  81     (when (gnus-image-type-available-p 'xpm)
  82       (push "xpm" types))
  83     types)
  84   "*List of suffixes on picon file names to try."
  85   :type '(repeat string)
  86   :group 'picon)
  87
  88 (defface gnus-picon-xbm-face '((t (:foreground "black" :background "white")))
  89   "Face to show xbm picon in."
  90   :group 'picon)
  91
  92 (defface gnus-picon-face '((t (:foreground "black" :background "white")))
  93   "Face to show picon in."
  94   :group 'picon)
  95
  96 ;;; Internal variables:
  97
  98 (defvar gnus-picon-setup-p nil)
  99 (defvar gnus-picon-glyph-alist nil
 100   "Picon glyphs cache.
 101 List of pairs (KEY . GLYPH) where KEY is either a filename or an URL.")
 102
 103 ;;; Functions:
 104
 105 (defsubst gnus-picon-split-address (address)
 106   (setq address (split-string address "@"))
 107   (if (cdr address)
 108       (cons (car address) (split-string (nth 1 address) "\\."))
 109     (split-string (car address) "\\.")))
 110
 111 (defun gnus-picon-find-face (address directories &optional exact)
 112   (let* ((databases gnus-picon-databases)
 113          (address (gnus-picon-split-address address))
 114          (user (pop address))
 115          database directory found instance base)
 116     (while (and (not found)
 117                 (setq database (pop databases)))
 118       (while (and (not found)
 119                   (setq directory (pop directories)))
 120         (setq base (expand-file-name directory database))
 121         ;; Kludge to search misc/MISC for users.
 122         (when (string= directory "misc")
 123           (setq address '("MISC")))
 124         (while (and (not found)
 125                     address)
 126           (setq found (gnus-picon-find-image
 127                        (concat base "/" (mapconcat 'identity
 128                                                    (reverse address)
 129                                                    "/")
 130                                "/" user "/")))
 131           (if exact
 132               (setq address nil)
 133             (pop address)))))
 134     found))
 135
 136 (defun gnus-picon-find-image (directory)
 137   (let ((types gnus-picon-file-types)
 138         found type file)
 139     (while (and (not found)
 140                 (setq type (pop types)))
 141       (setq found (file-exists-p (setq file (concat directory "face." type)))))
 142     (if found
 143         file
 144       nil)))
 145
 146 (defun gnus-picon-insert-glyph (glyph)
 147   "Insert GLYPH into the buffer.
 148 GLYPH can be either a glyph or a string."
 149   (if (stringp glyph)
 150       (insert glyph)
 151     (gnus-put-image glyph)))
 152
 153 (defun gnus-picon-create-glyph (file)
 154   (or (cdr (assoc file gnus-picon-glyph-alist))
 155       (cdar (push (cons file (gnus-create-image file))
 156                   gnus-picon-glyph-alist))))
 157
 158 ;;; Functions that does picon transformations:
 159
 160 (defun gnus-picon-transform-address (header)
 161   (interactive)
 162   (gnus-with-article-headers
 163     (let ((addresses
 164            (mail-header-parse-addresses (mail-fetch-field header)))
 165           first spec file)
 166       (dolist (address addresses)
 167         (setq address (car address)
 168               first t)
 169         (when (stringp address)
 170           (setq spec (gnus-picon-split-address address))
 171           (when (setq file (gnus-picon-find-face
 172                             address gnus-picon-user-directories))
 173             (setcar spec (gnus-picon-create-glyph file)))
 174           (dotimes (i (1- (length spec)))
 175             (when (setq file (gnus-picon-find-face
 176                               (concat "unknown@"
 177                                       (mapconcat
 178                                        'identity (nthcdr (1+ i) spec) "."))
 179                               gnus-picon-domain-directories t))
 180               (setcar (nthcdr (1+ i) spec) (gnus-picon-create-glyph file))))
 181
 182           (gnus-article-goto-header header)
 183           (mail-header-narrow-to-field)
 184           (when (search-forward address nil t)
 185             (delete-region (match-beginning 0) (match-end 0))
 186             (while spec
 187               (gnus-picon-insert-glyph (pop spec))
 188               (when spec
 189                 (if (not first)
 190                     (insert ".")
 191                   (insert "@")
 192                   (setq first nil))))))))))
 193
 194 (defun gnus-picon-transform-newsgroups (header)
 195   (interactive)
 196   (gnus-with-article-headers
 197     (let ((groups
 198            (sort
 199             (message-tokenize-header (mail-fetch-field header))
 200             (lambda (g1 g2) (> (length g1) (length g2)))))
 201           spec file)
 202       (dolist (group groups)
 203         (setq spec (nreverse (split-string group "[.]")))
 204         (dotimes (i (length spec))
 205           (when (setq file (gnus-picon-find-face
 206                             (concat "unknown@"
 207                                     (mapconcat
 208                                      'identity (nthcdr i spec) "."))
 209                             gnus-picon-news-directories t))
 210             (setcar (nthcdr i spec) (gnus-picon-create-glyph file))))
 211
 212         (gnus-article-goto-header header)
 213         (mail-header-narrow-to-field)
 214         (when (search-forward group nil t)
 215           (delete-region (match-beginning 0) (match-end 0))
 216           (setq spec (nreverse spec))
 217           (while spec
 218             (gnus-picon-insert-glyph (pop spec))
 219             (when spec
 220               (insert "."))))))))
 221
 222 ;;; Commands:
 223
 224 (defun gnus-treat-from-picon ()
 225   (interactive)
 226   (gnus-picon-transform-address "from"))
 227
 228 (defun gnus-treat-mail-picon ()
 229   (interactive)
 230   (gnus-picon-transform-address "cc")
 231   (gnus-picon-transform-address "to"))
 232
 233 (defun gnus-treat-newsgroups-picon ()
 234   (interactive)
 235   (gnus-picon-transform-newsgroups "newsgroups")
 236   (gnus-picon-transform-newsgroups "followup-to"))
 237
 238 (provide 'gnus-picon)
 239
 240 ;;; gnus-picon.el ends here