cgit.sxemacs.org Git - gnus/blob - lisp/gnus-picon.el

   1 ;;; gnus-picon.el --- displaying pretty icons in Gnus
   2 ;; Copyright (C) 1996,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Wes Hardaker <hardaker@ece.ucdavis.edu>
   5 ;; Keywords: news xpm annotation glyph faces
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'xpm)
  30 (require 'annotations)
  31 (require 'custom)
  32 (require 'gnus-art)
  33 (require 'gnus-win)
  34
  35 ;;; User variables:
  36
  37 (defgroup picons nil
  38   "Show pictures of people, domains, and newsgroups (XEmacs).
  39 For this to work, you must add gnus-group-display-picons to the
  40 gnus-summary-display-hook or to the gnus-article-display-hook
  41 depending on what gnus-picons-display-where is set to.  You must
  42 also add gnus-article-display-picons to gnus-article-display-hook."
  43   :group 'gnus-visual)
  44
  45 (defcustom gnus-picons-display-where 'picons
  46   "Where to display the group and article icons.
  47 Legal values are `article' and `picons'."
  48   :type '(choice symbol string)
  49   :group 'picons)
  50
  51 (defcustom gnus-picons-has-modeline-p t
  52   "*Whether the picons window should have a modeline.
  53 This is only useful if `gnus-picons-display-where' is `picons'."
  54   :type 'boolean
  55   :group 'picons)
  56
  57 (defcustom gnus-picons-database "/usr/local/faces"
  58   "*Defines the location of the faces database.
  59 For information on obtaining this database of pretty pictures, please
  60 see http://www.cs.indiana.edu/picons/ftp/index.html"
  61   :type 'directory
  62   :group 'picons)
  63
  64 (defcustom gnus-picons-news-directories '("news")
  65   "*List of directories to search for newsgroups faces."
  66   :type '(repeat string)
  67   :group 'picons)
  68 (define-obsolete-variable-alias 'gnus-picons-news-directory
  69   'gnus-picons-news-directories)
  70
  71 (defcustom gnus-picons-user-directories '("local" "users" "usenix" "misc")
  72   "*List of directories to search for user faces."
  73   :type '(repeat string)
  74   :group 'picons)
  75
  76 (defcustom gnus-picons-domain-directories '("domains")
  77   "*List of directories to search for domain faces.
  78 Some people may want to add \"unknown\" to this list."
  79   :type '(repeat string)
  80   :group 'picons)
  81
  82 (defcustom gnus-picons-refresh-before-display nil
  83   "*If non-nil, display the article buffer before computing the picons."
  84   :type 'boolean
  85   :group 'picons)
  86
  87 (defcustom gnus-picons-group-excluded-groups nil
  88   "*If this regexp matches the group name, group picons will be disabled."
  89   :type 'regexp
  90   :group 'picons)
  91
  92 (defcustom gnus-picons-x-face-file-name
  93   (format "/tmp/picon-xface.%s.xbm" (user-login-name))
  94   "*The name of the file in which to store the converted X-face header."
  95   :type 'string
  96   :group 'picons)
  97
  98 (defcustom gnus-picons-convert-x-face (format "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | pbmtoxbm > %s" gnus-picons-x-face-file-name)
  99   "*Command to convert the x-face header into a xbm file."
 100   :type 'string
 101   :group 'picons)
 102
 103 (defcustom gnus-picons-display-as-address t
 104   "*If t display textual email addresses along with pictures."
 105   :type 'boolean
 106   :group 'picons)
 107
 108 (defcustom gnus-picons-file-suffixes
 109   (when (featurep 'x)
 110     (let ((types (list "xbm")))
 111       (when (featurep 'gif)
 112         (push "gif" types))
 113       (when (featurep 'xpm)
 114         (push "xpm" types))
 115       types))
 116   "*List of suffixes on picon file names to try."
 117   :type '(repeat string)
 118   :group 'picons)
 119
 120 (defcustom gnus-picons-display-article-move-p t
 121   "*Whether to move point to first empty line when displaying picons.
 122 This has only an effect if `gnus-picons-display-where' has value `article'."
 123   :type 'boolean
 124   :group 'picons)
 125
 126 (defcustom gnus-picons-clear-cache-on-shutdown t
 127   "*Whether to clear the picons cache when exiting gnus.
 128 Gnus caches every picons it finds while it is running.  This saves
 129 some time in the search process but eats some memory.  If this
 130 variable is set to nil, Gnus will never clear the cache itself; you
 131 will have to manually call `gnus-picons-clear-cache' to clear it.
 132 Otherwise the cache will be cleared every time you exit Gnus."
 133   :type 'boolean
 134   :group 'picons)
 135
 136 (defcustom gnus-picons-piconsearch-url nil
 137   "*The url to query for picons.  Setting this to nil will disable it.
 138 The only publicly available address currently known is
 139 http://www.cs.indiana.edu:800/piconsearch.  If you know of any other,
 140 please tell me so that we can list it."
 141   :type '(choice (const :tag "Disable" :value nil)
 142                  (const :tag "www.cs.indiana.edu"
 143                         :value "http://www.cs.indiana.edu:800/piconsearch")
 144                  (string))
 145   :group 'picons)
 146
 147 (defface gnus-picons-xbm-face '((t (:foreground "black" :background "white")))
 148   "Face to show X face"
 149   :group 'picons)
 150
 151 ;;; Internal variables:
 152
 153 (defvar gnus-picons-processes-alist nil
 154   "Picons processes currently running and their environment.")
 155 (defvar gnus-picons-glyph-alist nil
 156   "Picons glyphs cache.
 157 List of pairs (KEY . GLYPH) where KEY is either a filename or an URL.")
 158 (defvar gnus-picons-url-alist nil
 159   "Picons file names cache.
 160 List of pairs (KEY . NAME) where KEY is (USER HOST DBS) and NAME is an URL.")
 161
 162 (defvar gnus-picons-jobs-alist nil
 163   "List of jobs that still need be done.
 164 This is a list of (SYM-ANN TAG ARGS...) where SYM-ANN three annotations list,
 165 TAG is one of `picon' or `search' indicating that the job should query a
 166 picon or do a search for picons file names, and ARGS is some additionnal
 167 arguments necessary for the job.")
 168
 169 (defvar gnus-picons-job-already-running nil
 170   "Lock to ensure only one stream of http requests is running.")
 171
 172 ;;; Functions:
 173
 174 (defun gnus-picons-remove-all ()
 175   "Removes all picons from the Gnus display(s)."
 176   (interactive)
 177   (map-extents (function (lambda (ext unused) (delete-annotation ext) nil))
 178                nil nil nil nil nil 'gnus-picon)
 179   (setq gnus-picons-jobs-alist '())
 180   ;; notify running job that it may have been preempted
 181   (if (and (listp gnus-picons-job-already-running)
 182            gnus-picons-job-already-running)
 183       (setq gnus-picons-job-already-running t)))
 184
 185 (defun gnus-get-buffer-name (variable)
 186   "Returns the buffer name associated with the contents of a variable."
 187   (let ((buf (get-buffer (gnus-window-to-buffer-helper
 188                             (cdr (assq variable gnus-window-to-buffer))))))
 189     (and buf
 190          (buffer-name buf))))
 191
 192 (defun gnus-picons-buffer-name ()
 193   (cond ((or (stringp gnus-picons-display-where)
 194              (bufferp gnus-picons-display-where))
 195          gnus-picons-display-where)
 196         ((eq gnus-picons-display-where 'picons)
 197          (if gnus-single-article-buffer
 198              "*Picons*"
 199            (concat "*Picons " gnus-newsgroup-name "*")))
 200         (t
 201          (gnus-get-buffer-name gnus-picons-display-where))))
 202
 203 (defun gnus-picons-kill-buffer ()
 204   (let ((buf (get-buffer (gnus-picons-buffer-name))))
 205     (if (buffer-live-p buf)
 206         (kill-buffer buf))))
 207
 208 (defun gnus-picons-setup-buffer ()
 209   (let ((name (gnus-picons-buffer-name)))
 210     (save-excursion
 211       (if (get-buffer name)
 212           (set-buffer name)
 213         (set-buffer (get-buffer-create name))
 214         (buffer-disable-undo)
 215         (setq buffer-read-only t)
 216         (gnus-add-current-to-buffer-list)
 217         (add-hook 'gnus-summary-prepare-exit-hook 'gnus-picons-kill-buffer))
 218       (current-buffer))))
 219
 220 (defun gnus-picons-set-buffer ()
 221   (set-buffer (gnus-picons-setup-buffer))
 222   (goto-char (point-min))
 223   (if (and (eq gnus-picons-display-where 'article)
 224            gnus-picons-display-article-move-p)
 225       (if (search-forward "\n\n" nil t)
 226           (forward-line -1)
 227         (goto-char (point-max)))
 228     (setq buffer-read-only t)
 229     (unless gnus-picons-has-modeline-p
 230       (set-specifier has-modeline-p
 231                      (list (list (current-buffer)
 232                                  (cons nil gnus-picons-has-modeline-p)))))))
 233
 234 (defun gnus-picons-prepare-for-annotations ()
 235   "Prepare picons buffer for putting annotations."
 236   ;; let drawing catch up
 237   (when gnus-picons-refresh-before-display
 238     (sit-for 0))
 239   (gnus-picons-set-buffer)
 240   (gnus-picons-remove-all))
 241
 242 (defun gnus-picons-make-annotation (&rest args)
 243   (let ((annot (apply 'make-annotation args)))
 244     (set-extent-property annot 'gnus-picon t)
 245     (set-extent-property annot 'duplicable t)
 246     annot))
 247
 248 (defun gnus-picons-article-display-x-face ()
 249   "Display the x-face header bitmap in the 'gnus-picons-display-where buffer."
 250   (let ((gnus-article-x-face-command 'gnus-picons-display-x-face))
 251     (gnus-article-display-x-face)))
 252
 253 (defun gnus-picons-x-face-sentinel (process event)
 254   (when (memq process gnus-picons-processes-alist)
 255     (setq gnus-picons-processes-alist
 256           (delq process gnus-picons-processes-alist))
 257     (gnus-picons-set-buffer)
 258     (gnus-picons-make-annotation (make-glyph gnus-picons-x-face-file-name)
 259                                  nil 'text)
 260     (when (file-exists-p gnus-picons-x-face-file-name)
 261       (delete-file gnus-picons-x-face-file-name))))
 262
 263 (defun gnus-picons-display-x-face (beg end)
 264   "Function to display the x-face header in the picons window.
 265 To use:  (setq gnus-article-x-face-command 'gnus-picons-display-x-face)"
 266   (interactive)
 267   (if (featurep 'xface)
 268       ;; Use builtin support
 269       (save-excursion
 270         ;; Don't remove this binding, it is really needed: when
 271         ;; `gnus-picons-set-buffer' changes buffer (like when it is
 272         ;; set to display picons outside of the article buffer), BEG
 273         ;; and END still refer the buffer current now !
 274         (let ((buf (current-buffer)))
 275           (gnus-picons-set-buffer)
 276           (gnus-picons-make-annotation
 277            (vector 'xface
 278                    :data (concat "X-Face: " (buffer-substring beg end buf)))
 279            nil 'text nil nil nil t)))
 280     ;; convert the x-face header to a .xbm file
 281     (let* ((process-connection-type nil)
 282            (process (start-process-shell-command "gnus-x-face" nil
 283                                                  gnus-picons-convert-x-face)))
 284       (push process gnus-picons-processes-alist)
 285       (process-kill-without-query process)
 286       (set-process-sentinel process 'gnus-picons-x-face-sentinel)
 287       (process-send-region process beg end)
 288       (process-send-eof process))))
 289
 290 (defun gnus-article-display-picons ()
 291   "Display faces for an author and her domain in gnus-picons-display-where."
 292   (interactive)
 293   (let (from at-idx)
 294     (when (and (featurep 'xpm)
 295                (or (not (fboundp 'device-type)) (equal (device-type) 'x))
 296                (setq from (mail-fetch-field "from"))
 297                (setq from (downcase (or (cadr (mail-extract-address-components
 298                                                from))
 299                                         "")))
 300                (or (setq at-idx (string-match "@" from))
 301                    (setq at-idx (length from))))
 302       (save-excursion
 303         (let ((username (downcase (substring from 0 at-idx)))
 304               (addrs (if (eq at-idx (length from))
 305                          (if gnus-local-domain
 306                              (message-tokenize-header gnus-local-domain "."))
 307                        (message-tokenize-header (substring from (1+ at-idx))
 308                                                 "."))))
 309           (gnus-picons-prepare-for-annotations)
 310           (gnus-group-display-picons)
 311           (if (null gnus-picons-piconsearch-url)
 312               (progn
 313                 (gnus-picons-display-pairs (gnus-picons-lookup-pairs
 314                                             addrs
 315                                             gnus-picons-domain-directories)
 316                                            gnus-picons-display-as-address
 317                                            "." t)
 318                 (if (and gnus-picons-display-as-address addrs)
 319                     (gnus-picons-make-annotation
 320                      [string :data "@"] nil 'text nil nil nil t))
 321                 (gnus-picons-display-picon-or-name
 322                  (gnus-picons-lookup-user username addrs)
 323                  username t))
 324             (push (list 'gnus-article-annotations 'search username addrs
 325                         gnus-picons-domain-directories t)
 326                   gnus-picons-jobs-alist)
 327             (gnus-picons-next-job)))))))
 328
 329 (defun gnus-group-display-picons ()
 330   "Display icons for the group in the `gnus-picons-display-where' buffer."
 331   (interactive)
 332   (when (and (featurep 'xpm)
 333              (or (not (fboundp 'device-type)) (equal (device-type) 'x))
 334              (or (null gnus-picons-group-excluded-groups)
 335                  (not (string-match gnus-picons-group-excluded-groups
 336                                     gnus-newsgroup-name))))
 337     (save-excursion
 338       (gnus-picons-prepare-for-annotations)
 339       (if (null gnus-picons-piconsearch-url)
 340           (gnus-picons-display-pairs
 341                  (gnus-picons-lookup-pairs
 342                   (reverse (message-tokenize-header
 343                             (gnus-group-real-name gnus-newsgroup-name)
 344                             "."))
 345                   gnus-picons-news-directories)
 346                  t ".")
 347         (push (list 'gnus-group-annotations 'search nil
 348                     (message-tokenize-header
 349                      (gnus-group-real-name gnus-newsgroup-name) ".")
 350                     (if (listp gnus-picons-news-directories)
 351                         gnus-picons-news-directories
 352                       (list gnus-picons-news-directories))
 353                     nil)
 354               gnus-picons-jobs-alist)
 355         (gnus-picons-next-job))
 356
 357       (add-hook 'gnus-summary-exit-hook 'gnus-picons-remove-all))))
 358
 359 (defun gnus-picons-lookup-internal (addrs dir)
 360   (setq dir (expand-file-name dir gnus-picons-database))
 361   (gnus-picons-try-face (dolist (part (reverse addrs) dir)
 362                           (setq dir (expand-file-name part dir)))))
 363
 364 (defun gnus-picons-lookup (addrs dirs)
 365   "Lookup the picon for ADDRS in databases DIRS.
 366 Returns the picon filename or NIL if none found."
 367   (let (result)
 368     (while (and dirs (null result))
 369       (setq result (gnus-picons-lookup-internal addrs (pop dirs))))
 370     result))
 371
 372 (defun gnus-picons-lookup-user-internal (user domains)
 373   (let ((dirs gnus-picons-user-directories)
 374         domains-tmp dir picon)
 375     (while (and dirs (null picon))
 376       (setq domains-tmp domains
 377             dir (pop dirs))
 378       (while (and domains-tmp
 379                   (null (setq picon (gnus-picons-lookup-internal
 380                                      (cons user domains-tmp) dir))))
 381         (pop domains-tmp))
 382       ;; Also make a try in MISC subdir
 383       (unless picon
 384         (setq picon (gnus-picons-lookup-internal (list user "MISC") dir))))
 385     picon))
 386
 387 (defun gnus-picons-lookup-user (user domains)
 388   "Lookup the picon for USER at DOMAINS.
 389 USER is a string containing a name.
 390 DOMAINS is a list of strings from the fully qualified domain name."
 391   (or (gnus-picons-lookup-user-internal user domains)
 392       (gnus-picons-lookup-user-internal "unknown" domains)))
 393
 394 (defun gnus-picons-lookup-pairs (domains directories)
 395   "Lookup picons for DOMAINS and all its parents in DIRECTORIES.
 396 Returns a list of PAIRS whose CAR is the picon filename or NIL if
 397 none, and whose CDR is the corresponding element of DOMAINS."
 398   (let (picons)
 399     (setq directories (if (listp directories)
 400                           directories
 401                         (list directories)))
 402     (while domains
 403       (push (list (gnus-picons-lookup (cons "unknown" domains) directories)
 404                   (pop domains))
 405             picons))
 406     picons))
 407
 408 (defun gnus-picons-display-picon-or-name (picon name &optional right-p)
 409   (cond (picon (gnus-picons-display-glyph picon name right-p))
 410         (gnus-picons-display-as-address (list (gnus-picons-make-annotation
 411                                                (vector 'string :data name)
 412                                                nil 'text
 413                                                nil nil nil right-p)))))
 414
 415 (defun gnus-picons-display-pairs (pairs &optional bar-p dot-p right-p)
 416   "Display picons in list PAIRS."
 417   (let ((domain-p (and gnus-picons-display-as-address dot-p))
 418         pair picons)
 419     (when (and bar-p domain-p right-p)
 420       (setq picons (gnus-picons-display-glyph
 421                     (let ((gnus-picons-file-suffixes '("xbm")))
 422                       (gnus-picons-try-face
 423                        gnus-xmas-glyph-directory "bar."))
 424                     nil right-p)))
 425     (while (setq pair (pop pairs))
 426       (setq picons (nconc picons
 427                           (gnus-picons-display-picon-or-name
 428                            (car pair) (cadr pair) right-p)
 429                           (if (and domain-p pairs)
 430                               (list (gnus-picons-make-annotation
 431                                      (vector 'string :data dot-p)
 432                                      nil 'text nil nil nil right-p))))))
 433     picons))
 434
 435 (defun gnus-picons-try-face (dir &optional filebase)
 436   (let* ((dir (file-name-as-directory dir))
 437          (filebase (or filebase "face."))
 438          (key (concat dir filebase))
 439          (glyph (cdr (assoc key gnus-picons-glyph-alist)))
 440          (suffixes gnus-picons-file-suffixes)
 441          f suf)
 442     (while (setq suf (pop suffixes))
 443       (when (file-exists-p (setq f (expand-file-name
 444                                     (concat filebase suf)
 445                                     dir)))
 446         (setq suffixes nil
 447               glyph (make-glyph f))
 448         (when (equal suf "xbm")
 449           (set-glyph-face glyph 'gnus-picons-xbm-face))
 450         (push (cons key glyph) gnus-picons-glyph-alist)))
 451     glyph))
 452
 453 (defun gnus-picons-display-glyph (glyph &optional part rightp)
 454   (let ((new (gnus-picons-make-annotation
 455               glyph (point) 'text nil nil nil rightp)))
 456     (when (and part gnus-picons-display-as-address)
 457       (set-annotation-data
 458        new (cons new (make-glyph (vector 'string :data part))))
 459       (set-annotation-action new 'gnus-picons-action-toggle))
 460     (nconc
 461      (list new)
 462      (if (and (eq major-mode 'gnus-article-mode)
 463               (not gnus-picons-display-as-address)
 464               (not part))
 465          (list (gnus-picons-make-annotation [string :data " "] (point)
 466                                             'text nil nil nil rightp))))))
 467
 468 (defun gnus-picons-action-toggle (data)
 469   "Toggle annotation"
 470   (interactive "e")
 471   (let* ((annot (car data))
 472          (glyph (annotation-glyph annot)))
 473     (set-annotation-glyph annot (cdr data))
 474     (set-annotation-data annot (cons annot glyph))))
 475
 476 (defun gnus-picons-clear-cache ()
 477   "Clear the picons cache"
 478   (interactive)
 479   (setq gnus-picons-glyph-alist nil
 480         gnus-picons-url-alist nil))
 481
 482 (gnus-add-shutdown 'gnus-picons-close 'gnus)
 483
 484 (defun gnus-picons-close ()
 485   "Shut down the picons."
 486   (if gnus-picons-clear-cache-on-shutdown
 487       (gnus-picons-clear-cache)))
 488
 489 ;;; Query a remote DB.  This requires some stuff from w3 !
 490
 491 (require 'url)
 492 (require 'w3-forms)
 493
 494 (defun gnus-picons-url-retrieve (url fn arg)
 495   (let ((old-asynch (default-value 'url-be-asynchronous))
 496         (url-working-buffer (generate-new-buffer " *picons*"))
 497         (url-package-name "Gnus")
 498         (url-package-version gnus-version-number)
 499         url-request-method)
 500     (setq-default url-be-asynchronous t)
 501     (save-excursion
 502       (set-buffer url-working-buffer)
 503       (setq url-be-asynchronous t
 504             url-current-callback-data arg
 505             url-current-callback-func fn)
 506       (url-retrieve url t))
 507     (setq-default url-be-asynchronous old-asynch)))
 508
 509 (defun gnus-picons-make-glyph (type)
 510   "Make a TYPE glyph using current buffer as data.  Handles xbm nicely."
 511   (cond ((null type) nil)
 512         ((eq type 'xbm) (let ((fname (make-temp-name "/tmp/picon")))
 513                           (write-region (point-min) (point-max) fname
 514                                         nil 'quiet)
 515                           (prog1 (make-glyph (vector 'xbm :file fname))
 516                             (delete-file fname))))
 517         (t (make-glyph (vector type :data (buffer-string))))))
 518
 519 ;;; Parsing of piconsearch result page.
 520
 521 ;; Assumes:
 522 ;; 1 - each value field has the form: "<strong>key</strong> = <kbd>value</kbd>"
 523 ;; 2 - a "<p>" separates the keywords from the results
 524 ;; 3 - every results begins by the path within the database at the beginning
 525 ;;     of the line in raw text.
 526 ;; 3b - and the href following it is the preferred image type.
 527
 528 ;; if 1 or 2 is not met, it will probably cause an error.  The other
 529 ;; will go undetected
 530
 531 (defun gnus-picons-parse-value (name)
 532   (goto-char (point-min))
 533   (re-search-forward (concat "<strong>"
 534                              (regexp-quote name)
 535                              "</strong> *= *<kbd> *\\([^ <][^<]*\\) *</kbd>"))
 536   (buffer-substring (match-beginning 1) (match-end 1)))
 537
 538 (defun gnus-picons-parse-filenames ()
 539   ;; returns an alist of ((USER ADDRS DB) . URL)
 540   (let* ((case-fold-search t)
 541          (user (gnus-picons-parse-value "user"))
 542          (host (gnus-picons-parse-value "host"))
 543          (dbs (message-tokenize-header (gnus-picons-parse-value "db") " "))
 544          (start-re
 545           (concat
 546            ;; dbs
 547            "^\\(" (mapconcat 'identity dbs "\\|") "\\)/"
 548            ;; host
 549            "\\(\\(" (replace-in-string host "\\." "/\\|" t) "/\\|MISC/\\)*\\)"
 550            ;; user
 551            "\\(" (regexp-quote user) "\\|unknown\\)/"
 552            "face\\."))
 553          cur-db cur-host cur-user types res)
 554     ;; now point will be somewhere in the header.  Find beginning of
 555     ;; entries
 556     (re-search-forward "<p>[ \t\n]*")
 557     (while (re-search-forward start-re nil t)
 558       (setq cur-db (buffer-substring (match-beginning 1) (match-end 1))
 559             cur-host (buffer-substring (match-beginning 2) (match-end 2))
 560             cur-user (buffer-substring (match-beginning 4) (match-end 4))
 561             cur-host (nreverse (message-tokenize-header cur-host "/")))
 562       ;; XXX - KLUDGE: there is a blank picon in news/MISC/unknown
 563       (unless (and (string-equal cur-db "news")
 564                    (string-equal cur-user "unknown")
 565                    (equal cur-host '("MISC")))
 566         ;; ok now we have found an entry (USER HOST DB), find the
 567         ;; corresponding picon URL
 568         (save-restriction
 569           ;; restrict region to this entry
 570           (narrow-to-region (point) (search-forward "<br>"))
 571           (goto-char (point-min))
 572           (setq types gnus-picons-file-suffixes)
 573           (while (and types
 574                       (not (re-search-forward
 575                             (concat "<a[ \t\n]+href=\"\\([^\"]*\\."
 576                                     (regexp-quote (car types)) "\\)\"")
 577                             nil t)))
 578             (pop types))
 579           (push (cons (list cur-user cur-host cur-db)
 580                       (buffer-substring (match-beginning 1) (match-end 1)))
 581                 res))))
 582     (nreverse res)))
 583
 584 ;;; picon network display functions :
 585
 586 (defun gnus-picons-network-display-internal (sym-ann glyph part right-p)
 587   (gnus-picons-set-buffer)
 588   (gnus-picons-display-picon-or-name glyph part right-p)
 589   (gnus-picons-next-job-internal))
 590
 591 (defun gnus-picons-network-display-callback (url part sym-ann right-p)
 592   (let ((glyph (gnus-picons-make-glyph (cdr (assoc url-current-mime-type
 593                                                    w3-image-mappings)))))
 594     (kill-buffer (current-buffer))
 595     (push (cons url glyph) gnus-picons-glyph-alist)
 596     ;; only do the job if it has not been preempted.
 597     (if (equal gnus-picons-job-already-running
 598                (list sym-ann 'picon url part right-p))
 599         (gnus-picons-network-display-internal sym-ann glyph part right-p)
 600       (gnus-picons-next-job-internal))))
 601
 602 (defun gnus-picons-network-display (url part sym-ann right-p)
 603   (let ((cache (assoc url gnus-picons-glyph-alist)))
 604     (if (or cache (null url))
 605         (gnus-picons-network-display-internal sym-ann (cdr cache) part right-p)
 606       (gnus-picons-url-retrieve url 'gnus-picons-network-display-callback
 607                                 (list url part sym-ann right-p)))))
 608
 609 ;;; search job functions
 610
 611 (defun gnus-picons-network-search-internal (user addrs dbs sym-ann right-p
 612                                                  &optional fnames)
 613   (let (curkey dom pfx url dbs-tmp cache new-jobs)
 614     ;; First do the domain search
 615     (dolist (part (if right-p
 616                       (reverse addrs)
 617                     addrs))
 618       (setq pfx (nconc (list part) pfx)
 619             dom (cond ((and dom right-p) (concat part "." dom))
 620                       (dom (concat dom "." part))
 621                       (t part))
 622             curkey (list "unknown" dom dbs))
 623       (when (null (setq cache (assoc curkey gnus-picons-url-alist)))
 624         ;; This one is not yet in the cache, create a new entry
 625         ;; Search for an entry
 626         (setq dbs-tmp dbs
 627               url nil)
 628         (while (and dbs-tmp (null url))
 629           (setq url (or (cdr (assoc (list "unknown" pfx (car dbs-tmp)) fnames))
 630                         (and (eq dom part)
 631                              ;; This is the first component.  Try the
 632                              ;; catch-all MISC component
 633                              (cdr (assoc (list "unknown"
 634                                                '("MISC")
 635                                                (car dbs-tmp))
 636                                          fnames)))))
 637           (pop dbs-tmp))
 638         (push (setq cache (cons curkey url)) gnus-picons-url-alist))
 639       ;; Put this glyph in the job list
 640       (if (and (not (eq dom part)) gnus-picons-display-as-address)
 641           (push (list sym-ann "." right-p) new-jobs))
 642       (push (list sym-ann 'picon (cdr cache) part right-p) new-jobs))
 643     ;; next, the user search
 644     (when user
 645       (setq curkey (list user dom gnus-picons-user-directories))
 646       (if (null (setq cache (assoc curkey gnus-picons-url-alist)))
 647           (let ((users (list user "unknown"))
 648                 dirs usr domains-tmp dir picon)
 649             (while (and users (null picon))
 650               (setq dirs gnus-picons-user-directories
 651                     usr (pop users))
 652               (while (and dirs (null picon))
 653                 (setq domains-tmp addrs
 654                       dir (pop dirs))
 655                 (while (and domains-tmp
 656                             (null (setq picon (assoc (list usr domains-tmp dir)
 657                                                      fnames))))
 658                   (pop domains-tmp))
 659                 (unless picon
 660                   (setq picon (assoc (list usr '("MISC") dir) fnames)))))
 661             (push (setq cache (cons curkey (cdr picon)))
 662                   gnus-picons-url-alist)))
 663       (if (and gnus-picons-display-as-address new-jobs)
 664           (push (list sym-ann "@" right-p) new-jobs))
 665       (push (list sym-ann 'picon (cdr cache) user right-p) new-jobs))
 666     (if (and gnus-picons-display-as-address (not right-p))
 667         (push (list sym-ann 'bar right-p) new-jobs))
 668     ;; only put the jobs in the queue if this job has not been preempted.
 669     (if (equal gnus-picons-job-already-running
 670                (list sym-ann 'search user addrs dbs right-p))
 671         (setq gnus-picons-jobs-alist
 672               (nconc (if (and gnus-picons-display-as-address right-p)
 673                          (list (list sym-ann 'bar right-p)))
 674                      (nreverse new-jobs)
 675                      gnus-picons-jobs-alist)))
 676     (gnus-picons-next-job-internal)))
 677
 678 (defun gnus-picons-network-search-callback (user addrs dbs sym-ann right-p)
 679   (gnus-picons-network-search-internal user addrs dbs sym-ann right-p
 680                                        (prog1 (gnus-picons-parse-filenames)
 681                                          (kill-buffer (current-buffer)))))
 682
 683 ;; Initiate a query on the picon database
 684 (defun gnus-picons-network-search (user addrs dbs sym-ann right-p)
 685   (let* ((host (mapconcat 'identity addrs "."))
 686          (key (list (or user "unknown") host (if user
 687                                                   gnus-picons-user-directories
 688                                                 dbs)))
 689          (cache (assoc key gnus-picons-url-alist)))
 690     (if (null cache)
 691         (gnus-picons-url-retrieve
 692          (concat gnus-picons-piconsearch-url
 693                  "?user=" (w3-form-encode-xwfu (or user "unknown"))
 694                  "&host=" (w3-form-encode-xwfu host)
 695                  "&db=" (mapconcat 'w3-form-encode-xwfu
 696                                    (if user
 697                                        (append dbs
 698                                                gnus-picons-user-directories)
 699                                      dbs)
 700                                    "+"))
 701          'gnus-picons-network-search-callback
 702          (list user addrs dbs sym-ann right-p))
 703       (gnus-picons-network-search-internal user addrs dbs sym-ann right-p))))
 704
 705 ;;; Main jobs dispatcher function
 706
 707 (defun gnus-picons-next-job-internal ()
 708   (if (setq gnus-picons-job-already-running (pop gnus-picons-jobs-alist))
 709       (let* ((job gnus-picons-job-already-running)
 710              (sym-ann (pop job))
 711              (tag (pop job)))
 712         (if tag
 713             (cond ((stringp tag);; (SYM-ANN "..." RIGHT-P)
 714                    (gnus-picons-network-display-internal sym-ann nil tag
 715                                                          (pop job)))
 716                   ((eq 'bar tag)
 717                    (gnus-picons-network-display-internal
 718                     sym-ann
 719                     (let ((gnus-picons-file-suffixes '("xbm")))
 720                       (gnus-picons-try-face
 721                        gnus-xmas-glyph-directory "bar."))
 722                     nil (pop job)))
 723                   ((eq 'search tag);; (SYM-ANN 'search USER ADDRS DBS RIGHT-P)
 724                    (gnus-picons-network-search
 725                     (pop job) (pop job) (pop job) sym-ann (pop job)))
 726                   ((eq 'picon tag);; (SYM-ANN 'picon URL PART RIGHT-P)
 727                    (gnus-picons-network-display
 728                     (pop job) (pop job) sym-ann (pop job)))
 729                   (t (setq gnus-picons-job-already-running nil)
 730                      (error "Unknown picon job tag %s" tag)))))))
 731
 732 (defun gnus-picons-next-job ()
 733   "Start processing the job queue if it is not in progress"
 734   (unless gnus-picons-job-already-running
 735     (gnus-picons-next-job-internal)))
 736
 737 (provide 'gnus-picon)
 738
 739 ;;; gnus-picon.el ends here