cgit.sxemacs.org Git - gnus/blob - lisp/gnus-picon.el

   1 ;;; gnus-picon.el --- displaying pretty icons in Gnus
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001
   4 ;;      Free Software Foundation, Inc.
   5
   6 ;; Author: Wes Hardaker <hardaker@ece.ucdavis.edu>
   7 ;; Keywords: news xpm annotation glyph faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; There are three picon types relevant to Gnus:
  29 ;;
  30 ;; Persons: person@subdomain.dom
  31 ;;          users/dom/subdomain/person/face.gif
  32 ;;          usenix/dom/subdomain/person/face.gif
  33 ;;          misc/MISC/person/face.gif
  34 ;; Domains: subdomain.dom
  35 ;;          domain/dom/subdomain/unknown/face.gif
  36 ;; Groups:  comp.lang.lisp
  37 ;;          news/comp/lang/lisp/unknown/face.gif
  38
  39 ;;; Code:
  40
  41 (require 'gnus)
  42 (require 'custom)
  43 (require 'gnus-art)
  44 (require 'gnus-win)
  45
  46 ;;; User variables:
  47
  48 (defgroup picon nil
  49   "Show pictures of people, domains, and newsgroups.
  50 For this to work, you must switch on the `gnus-treat-display-picon'
  51 variable."
  52   :group 'gnus-visual)
  53
  54 (defcustom gnus-picon-databases '("/usr/lib/picon" "/usr/local/faces")
  55   "*Defines the location of the faces database.
  56 For information on obtaining this database of pretty pictures, please
  57 see http://www.cs.indiana.edu/picons/ftp/index.html"
  58   :type 'directory
  59   :group 'picon)
  60
  61 (defcustom gnus-picon-news-directories '("news")
  62   "*List of directories to search for newsgroups faces."
  63   :type '(repeat string)
  64   :group 'picon)
  65
  66 (defcustom gnus-picon-user-directories '("users" "usenix" "local" "misc")
  67   "*List of directories to search for user faces."
  68   :type '(repeat string)
  69   :group 'picon)
  70
  71 (defcustom gnus-picon-domain-directories '("domains")
  72   "*List of directories to search for domain faces.
  73 Some people may want to add \"unknown\" to this list."
  74   :type '(repeat string)
  75   :group 'picon)
  76
  77 (defcustom gnus-picon-file-types
  78   (let ((types (list "xbm")))
  79     (when (gnus-image-type-available-p 'gif)
  80       (push "gif" types))
  81     (when (gnus-image-type-available-p 'xpm)
  82       (push "xpm" types))
  83     types)
  84   "*List of suffixes on picon file names to try."
  85   :type '(repeat string)
  86   :group 'picon)
  87
  88 (defface gnus-picon-xbm-face '((t (:foreground "black" :background "white")))
  89   "Face to show xbm picon in."
  90   :group 'picon)
  91
  92 (defface gnus-picon-face '((t (:foreground "black" :background "white")))
  93   "Face to show picon in."
  94   :group 'picon)
  95
  96 ;;; Internal variables:
  97
  98 (defvar gnus-picon-setup-p nil)
  99 (defvar gnus-picon-glyph-alist nil
 100   "Picon glyphs cache.
 101 List of pairs (KEY . GLYPH) where KEY is either a filename or an URL.")
 102
 103 ;;; Functions:
 104
 105 (defun gnus-picon-find-face (address directories &optional exact)
 106   (let* ((databases gnus-picon-databases)
 107          (address (split-string address "[.@]"))
 108          (user (pop address))
 109          database directory found instance base)
 110     (while (and (not found)
 111                 (setq database (pop databases)))
 112       (while (and (not found)
 113                   (setq directory (pop directories)))
 114         (setq base (expand-file-name directory database))
 115         ;; Kludge to search misc/MISC for users.
 116         (when (string= directory "misc")
 117           (setq address '("MISC")))
 118         (while (and (not found)
 119                     address)
 120           (setq found (gnus-picon-find-image
 121                        (concat base "/" (mapconcat 'identity
 122                                                    (reverse address)
 123                                                    "/")
 124                                "/" user "/")))
 125           (if exact
 126               (setq address nil)
 127             (pop address)))))
 128     found))
 129
 130 (defun gnus-picon-find-image (directory)
 131   (let ((types gnus-picon-file-types)
 132         found type file)
 133     (while (and (not found)
 134                 (setq type (pop types)))
 135       (setq found (file-exists-p (setq file (concat directory "face." type)))))
 136     (if found
 137         file
 138       nil)))
 139
 140 (defun gnus-picon-insert-glyph (glyph)
 141   "Insert GLYPH into the buffer.
 142 GLYPH can be either a glyph or a string."
 143   (if (stringp glyph)
 144       (insert glyph)
 145     (gnus-put-image glyph)))
 146
 147 (defun gnus-picon-create-glyph (file)
 148   (or (cdr (assoc file gnus-picon-glyph-alist))
 149       (cdar (push (cons file (gnus-create-image file))
 150                   gnus-picon-glyph-alist))))
 151
 152 ;;; Functions that does picon transformations:
 153
 154 (defun gnus-picon-transform-address (header)
 155   (interactive)
 156   (gnus-with-article-headers
 157     (let ((addresses
 158            (mail-header-parse-addresses (mail-fetch-field header)))
 159           (first t)
 160           spec file)
 161       (dolist (address addresses)
 162         (setq address (car address))
 163         (when (stringp address)
 164           (setq spec (split-string address "[.@]"))
 165           (when (setq file (gnus-picon-find-face
 166                             address gnus-picon-user-directories))
 167             (setcar spec (gnus-picon-create-glyph file)))
 168           (dotimes (i (1- (length spec)))
 169             (when (setq file (gnus-picon-find-face
 170                               (concat "unknown@"
 171                                       (mapconcat
 172                                        'identity (nthcdr (1+ i) spec) "."))
 173                               gnus-picon-domain-directories t))
 174               (setcar (nthcdr (1+ i) spec) (gnus-picon-create-glyph file))))
 175
 176           (gnus-article-goto-header header)
 177           (mail-header-narrow-to-field)
 178           (when (search-forward address nil t)
 179             (delete-region (match-beginning 0) (match-end 0))
 180             (while spec
 181               (gnus-picon-insert-glyph (pop spec))
 182               (when spec
 183                 (if (not first)
 184                     (insert ".")
 185                   (insert "@")
 186                   (setq first nil))))))))))
 187
 188 (defun gnus-picon-transform-newsgroups (header)
 189   (interactive)
 190   (gnus-with-article-headers
 191     (let ((groups
 192            (sort
 193             (message-tokenize-header (mail-fetch-field header))
 194             (lambda (g1 g2) (> (length g1) (length g2)))))
 195           spec file)
 196       (dolist (group groups)
 197         (setq spec (nreverse (split-string group "[.]")))
 198         (dotimes (i (length spec))
 199           (when (setq file (gnus-picon-find-face
 200                             (concat "unknown@"
 201                                     (mapconcat
 202                                      'identity (nthcdr i spec) "."))
 203                             gnus-picon-news-directories t))
 204             (setcar (nthcdr i spec) (gnus-picon-create-glyph file))))
 205
 206         (gnus-article-goto-header header)
 207         (mail-header-narrow-to-field)
 208         (when (search-forward group nil t)
 209           (delete-region (match-beginning 0) (match-end 0))
 210           (setq spec (nreverse spec))
 211           (while spec
 212             (gnus-picon-insert-glyph (pop spec))
 213             (when spec
 214               (insert "."))))))))
 215
 216 ;;; Commands:
 217
 218 (defun gnus-treat-from-picon ()
 219   (interactive)
 220   (gnus-picon-transform-address "from"))
 221
 222 (defun gnus-treat-mail-picon ()
 223   (interactive)
 224   (gnus-picon-transform-address "cc")
 225   (gnus-picon-transform-address "to"))
 226
 227 (defun gnus-treat-newsgroups-picon ()
 228   (interactive)
 229   (gnus-picon-transform-newsgroups "newsgroups")
 230   (gnus-picon-transform-newsgroups "followup-to"))
 231
 232 (provide 'gnus-picon)
 233
 234 ;;; gnus-picon.el ends here