cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-ems)
  33 (require 'message)
  34 (require 'gnus-art)
  35 (require 'gnus-util)
  36
  37 (defcustom gnus-post-method 'current
  38   "*Preferred method for posting USENET news.
  39
  40 If this variable is `current' (which is the default), Gnus will use
  41 the \"current\" select method when posting.  If it is `native', Gnus
  42 will use the native select method when posting.
  43
  44 This method will not be used in mail groups and the like, only in
  45 \"real\" newsgroups.
  46
  47 If not `native' nor `current', the value must be a valid method as discussed
  48 in the documentation of `gnus-select-method'.  It can also be a list of
  49 methods.  If that is the case, the user will be queried for what select
  50 method to use when posting."
  51   :group 'gnus-group-foreign
  52   :link '(custom-manual "(gnus)Posting Server")
  53   :type `(choice (const native)
  54                  (const current)
  55                  (sexp :tag "Methods" ,gnus-select-method)))
  56
  57 (defcustom gnus-outgoing-message-group nil
  58   "*All outgoing messages will be put in this group.
  59 If you want to store all your outgoing mail and articles in the group
  60 \"nnml:archive\", you set this variable to that value.  This variable
  61 can also be a list of group names.
  62
  63 If you want to have greater control over what group to put each
  64 message in, you can set this variable to a function that checks the
  65 current newsgroup name and then returns a suitable group name (or list
  66 of names)."
  67   :group 'gnus-message
  68   :type '(choice (const nil)
  69                  (function)
  70                  (string :tag "Group")
  71                  (repeat :tag "List of groups" (string :tag "Group"))))
  72
  73 (defcustom gnus-mailing-list-groups nil
  74   "*If non-nil a regexp matching groups that are really mailing lists.
  75 This is useful when you're reading a mailing list that has been
  76 gatewayed to a newsgroup, and you want to followup to an article in
  77 the group."
  78   :group 'gnus-message
  79   :type '(choice (regexp)
  80                  (const nil)))
  81
  82 (defcustom gnus-add-to-list nil
  83   "*If non-nil, add a `to-list' parameter automatically."
  84   :group 'gnus-message
  85   :type 'boolean)
  86
  87 (defcustom gnus-crosspost-complaint
  88   "Hi,
  89
  90 You posted the article below with the following Newsgroups header:
  91
  92 Newsgroups: %s
  93
  94 The %s group, at least, was an inappropriate recipient
  95 of this message.  Please trim your Newsgroups header to exclude this
  96 group before posting in the future.
  97
  98 Thank you.
  99
 100 "
 101   "Format string to be inserted when complaining about crossposts.
 102 The first %s will be replaced by the Newsgroups header;
 103 the second with the current group name."
 104   :group 'gnus-message
 105   :type 'string)
 106
 107 (defcustom gnus-message-setup-hook nil
 108   "Hook run after setting up a message buffer."
 109   :group 'gnus-message
 110   :options '(message-remove-blank-cited-lines)
 111   :type 'hook)
 112
 113 (defcustom gnus-bug-create-help-buffer t
 114   "*Should we create the *Gnus Help Bug* buffer?"
 115   :group 'gnus-message
 116   :type 'boolean)
 117
 118 (defcustom gnus-posting-styles nil
 119   "*Alist of styles to use when posting.
 120 See Info node `(gnus)Posting Styles'."
 121   :group 'gnus-message
 122   :link '(custom-manual "(gnus)Posting Styles")
 123   :type '(repeat (cons (choice (regexp)
 124                                (variable)
 125                                (list (const header)
 126                                      (string :tag "Header")
 127                                      (regexp :tag "Regexp"))
 128                                (function)
 129                                (sexp))
 130                        (repeat (list
 131                                 (choice (const signature)
 132                                         (const signature-file)
 133                                         (const organization)
 134                                         (const address)
 135                                         (const x-face-file)
 136                                         (const name)
 137                                         (const body)
 138                                         (symbol)
 139                                         (string :tag "Header"))
 140                                 (choice (string)
 141                                         (function)
 142                                         (variable)
 143                                         (sexp)))))))
 144
 145 (defcustom gnus-gcc-mark-as-read nil
 146   "If non-nil, automatically mark Gcc articles as read."
 147   :version "22.1"
 148   :group 'gnus-message
 149   :type 'boolean)
 150
 151 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 152                         'gnus-gcc-mark-as-read "Emacs 22.1")
 153
 154 (defcustom gnus-gcc-externalize-attachments nil
 155   "Should local-file attachments be included as external parts in Gcc copies?
 156 If it is `all', attach files as external parts;
 157 if a regexp and matches the Gcc group name, attach files as external parts;
 158 if nil, attach files as normal parts."
 159   :version "22.1"
 160   :group 'gnus-message
 161   :type '(choice (const nil :tag "None")
 162                  (const all :tag "Any")
 163                  (string :tag "Regexp")))
 164
 165 (gnus-define-group-parameter
 166  posting-charset-alist
 167  :type list
 168  :function-document
 169  "Return the permitted unencoded charsets for posting of GROUP."
 170  :variable gnus-group-posting-charset-alist
 171  :variable-default
 172   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 173     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 174     (message-this-is-mail nil nil)
 175     (message-this-is-news nil t))
 176  :variable-document
 177   "Alist of regexps and permitted unencoded charsets for posting.
 178 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 179 TEST is either a regular expression matching the newsgroup header or a
 180 variable to query,
 181 HEADER is the charset which may be left unencoded in the header (nil
 182 means encode all charsets),
 183 BODY-LIST is a list of charsets which may be encoded using 8bit
 184 content-transfer encoding in the body, or one of the special values
 185 nil (always encode using quoted-printable) or t (always use 8bit).
 186
 187 Note that any value other than nil for HEADER infringes some RFCs, so
 188 use this option with care."
 189  :variable-group gnus-charset
 190  :variable-type
 191  '(repeat (list :tag "Permitted unencoded charsets"
 192                 (choice :tag "Where"
 193                         (regexp :tag "Group")
 194                         (const :tag "Mail message" :value message-this-is-mail)
 195                         (const :tag "News article" :value message-this-is-news))
 196                 (choice :tag "Header"
 197                         (const :tag "None" nil)
 198                         (symbol :tag "Charset"))
 199                 (choice :tag "Body"
 200                         (const :tag "Any" :value t)
 201                         (const :tag "None" :value nil)
 202                         (repeat :tag "Charsets"
 203                                 (symbol :tag "Charset")))))
 204  :parameter-type '(choice :tag "Permitted unencoded charsets"
 205                           :value nil
 206                           (repeat (symbol)))
 207  :parameter-document       "\
 208 List of charsets that are permitted to be unencoded.")
 209
 210 (defcustom gnus-debug-files
 211   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 212     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 213     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 214     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 215     "mm-util.el" "mm-decode.el" "nnmail.el" "message.el")
 216   "Files whose variables will be reported in `gnus-bug'."
 217   :version "22.1"
 218   :group 'gnus-message
 219   :type '(repeat (string :tag "File")))
 220
 221 (defcustom gnus-debug-exclude-variables
 222   '(mm-mime-mule-charset-alist
 223     nnmail-split-fancy message-minibuffer-local-map)
 224   "Variables that should not be reported in `gnus-bug'."
 225   :version "22.1"
 226   :group 'gnus-message
 227   :type '(repeat (symbol :tag "Variable")))
 228
 229 (defcustom gnus-discouraged-post-methods
 230   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 231   "A list of back ends that are not used in \"real\" newsgroups.
 232 This variable is used only when `gnus-post-method' is `current'."
 233   :version "22.1"
 234   :group 'gnus-group-foreign
 235   :type '(repeat (symbol :tag "Back end")))
 236
 237 (defcustom gnus-message-replysign
 238   nil
 239   "Automatically sign replies to signed messages.
 240 See also the `mml-default-sign-method' variable."
 241   :group 'gnus-message
 242   :type 'boolean)
 243
 244 (defcustom gnus-message-replyencrypt
 245   nil
 246   "Automatically encrypt replies to encrypted messages.
 247 See also the `mml-default-encrypt-method' variable."
 248   :group 'gnus-message
 249   :type 'boolean)
 250
 251 (defcustom gnus-message-replysignencrypted
 252   t
 253   "Setting this causes automatically encrypted messages to also be signed."
 254   :group 'gnus-message
 255   :type 'boolean)
 256
 257 (defcustom gnus-confirm-mail-reply-to-news (and gnus-novice-user
 258                                                 (not gnus-expert-user))
 259   "If non-nil, Gnus requests confirmation when replying to news.
 260 This is done because new users often reply by mistake when reading
 261 news.
 262 This can also be a function receiving the group name as the only
 263 parameter, which should return non-nil if a confirmation is needed; or
 264 a regexp, in which case a confirmation is asked for if the group name
 265 matches the regexp."
 266   :version "23.1" ;; No Gnus (default changed)
 267   :group 'gnus-message
 268   :type '(choice (const :tag "No" nil)
 269                  (const :tag "Yes" t)
 270                  (regexp :tag "If group matches regexp")
 271                  (function :tag "If function evaluates to non-nil")))
 272
 273 (defcustom gnus-confirm-treat-mail-like-news
 274   nil
 275   "If non-nil, Gnus will treat mail like news with regard to confirmation
 276 when replying by mail.  See the `gnus-confirm-mail-reply-to-news' variable
 277 for fine-tuning this.
 278 If nil, Gnus will never ask for confirmation if replying to mail."
 279   :version "22.1"
 280   :group 'gnus-message
 281   :type 'boolean)
 282
 283 (defcustom gnus-summary-resend-default-address t
 284   "If non-nil, Gnus tries to suggest a default address to resend to.
 285 If nil, the address field will always be empty after invoking
 286 `gnus-summary-resend-message'."
 287   :version "22.1"
 288   :group 'gnus-message
 289   :type 'boolean)
 290
 291 (defcustom gnus-message-highlight-citation
 292   t ;; gnus-treat-highlight-citation ;; gnus-cite dependency
 293   "Enable highlighting of different citation levels in message-mode."
 294   :version "23.1" ;; No Gnus
 295   :group 'gnus-cite
 296   :group 'gnus-message
 297   :type 'boolean)
 298
 299 (autoload 'gnus-message-citation-mode "gnus-cite" nil t)
 300
 301 ;;; Internal variables.
 302
 303 (defvar gnus-inhibit-posting-styles nil
 304   "Inhibit the use of posting styles.")
 305
 306 (defvar gnus-article-yanked-articles nil)
 307 (defvar gnus-message-buffer "*Mail Gnus*")
 308 (defvar gnus-article-copy nil)
 309 (defvar gnus-check-before-posting nil)
 310 (defvar gnus-last-posting-server nil)
 311 (defvar gnus-message-group-art nil)
 312
 313 (defvar gnus-msg-force-broken-reply-to nil)
 314
 315 (defconst gnus-bug-message
 316   "Sending a bug report to the Gnus Towers.
 317 ========================================
 318
 319 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 320 be sent to the Gnus Bug Exterminators.
 321
 322 The thing near the bottom of the buffer is how the environment
 323 settings will be included in the mail.  Please do not delete that.
 324 They will tell the Bug People what your environment is, so that it
 325 will be easier to locate the bugs.
 326
 327 If you have found a bug that makes Emacs go \"beep\", set
 328 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 329 and include the backtrace in your bug report.
 330
 331 Please describe the bug in annoying, painstaking detail.
 332
 333 Thank you for your help in stamping out bugs.
 334 ")
 335
 336 (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 337
 338 \f
 339 ;;;
 340 ;;; Gnus Posting Functions
 341 ;;;
 342
 343 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 344   "p" gnus-summary-post-news
 345   "i" gnus-summary-news-other-window
 346   "f" gnus-summary-followup
 347   "F" gnus-summary-followup-with-original
 348   "c" gnus-summary-cancel-article
 349   "s" gnus-summary-supersede-article
 350   "r" gnus-summary-reply
 351   "y" gnus-summary-yank-message
 352   "R" gnus-summary-reply-with-original
 353   "w" gnus-summary-wide-reply
 354   "W" gnus-summary-wide-reply-with-original
 355   "v" gnus-summary-very-wide-reply
 356   "V" gnus-summary-very-wide-reply-with-original
 357   "n" gnus-summary-followup-to-mail
 358   "N" gnus-summary-followup-to-mail-with-original
 359   "m" gnus-summary-mail-other-window
 360   "u" gnus-uu-post-news
 361   "\M-c" gnus-summary-mail-crosspost-complaint
 362   "Br" gnus-summary-reply-broken-reply-to
 363   "BR" gnus-summary-reply-broken-reply-to-with-original
 364   "om" gnus-summary-mail-forward
 365   "op" gnus-summary-post-forward
 366   "Om" gnus-uu-digest-mail-forward
 367   "Op" gnus-uu-digest-post-forward)
 368
 369 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 370   "b" gnus-summary-resend-bounced-mail
 371   ;; "c" gnus-summary-send-draft
 372   "r" gnus-summary-resend-message
 373   "e" gnus-summary-resend-message-edit)
 374
 375 ;;; Internal functions.
 376
 377 (defun gnus-inews-make-draft (articles)
 378   `(lambda ()
 379      (gnus-inews-make-draft-meta-information
 380       ,(gnus-group-decoded-name gnus-newsgroup-name) ',articles)))
 381
 382 (defvar gnus-article-reply nil)
 383 (defmacro gnus-setup-message (config &rest forms)
 384   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 385         (buffer (make-symbol "gnus-setup-message-buffer"))
 386         (article (make-symbol "gnus-setup-message-article"))
 387         (yanked (make-symbol "gnus-setup-yanked-articles"))
 388         (group (make-symbol "gnus-setup-message-group")))
 389     `(let ((,winconf (current-window-configuration))
 390            (,buffer (buffer-name (current-buffer)))
 391            (,article gnus-article-reply)
 392            (,yanked gnus-article-yanked-articles)
 393            (,group gnus-newsgroup-name)
 394            (message-header-setup-hook
 395             (copy-sequence message-header-setup-hook))
 396            (mbl mml-buffer-list)
 397            (message-mode-hook (copy-sequence message-mode-hook)))
 398        (setq mml-buffer-list nil)
 399        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 400        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 401        ;; message-newsreader and message-mailer were formerly set in
 402        ;; gnus-inews-add-send-actions, but this is too late when
 403        ;; message-generate-headers-first is used. --ansel
 404        (add-hook 'message-mode-hook
 405                  (lambda nil
 406                    (setq message-newsreader
 407                          (setq message-mailer (gnus-extended-version)))))
 408        ;; #### FIXME: for a reason that I did not manage to identify yet,
 409        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 410        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 411        ;; After evaluation of @forms below, it gets the value we actually want
 412        ;; to override, and the posting styles are used. For that reason, I've
 413        ;; added an optional argument to `gnus-configure-posting-styles' to
 414        ;; make sure that the correct value for the group name is used. -- drv
 415        (add-hook 'message-mode-hook
 416                  (if (memq ,config '(reply-yank reply))
 417                      (lambda ()
 418                        (gnus-configure-posting-styles ,group))
 419                    (lambda ()
 420                      ;; There may be an old " *gnus article copy*" buffer.
 421                      (let (gnus-article-copy)
 422                        (gnus-configure-posting-styles ,group)))))
 423        (gnus-alist-pull ',(intern gnus-draft-meta-information-header)
 424                   message-required-headers)
 425        (when (and ,group
 426                   (not (string= ,group "")))
 427          (push (cons
 428                 (intern gnus-draft-meta-information-header)
 429                 (gnus-inews-make-draft (or ,yanked ,article)))
 430                message-required-headers))
 431        (unwind-protect
 432            (progn
 433              ,@forms)
 434          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 435                                       ,yanked)
 436          (setq gnus-message-buffer (current-buffer))
 437          (set (make-local-variable 'gnus-message-group-art)
 438               (cons ,group ,article))
 439          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 440          ;; Enable highlighting of different citation levels
 441          (when gnus-message-highlight-citation
 442            (gnus-message-citation-mode 1))
 443          (gnus-run-hooks 'gnus-message-setup-hook)
 444          (if (eq major-mode 'message-mode)
 445              (let ((mbl1 mml-buffer-list))
 446                (setq mml-buffer-list mbl)  ;; Global value
 447                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 448                (gnus-make-local-hook 'kill-buffer-hook)
 449                (gnus-make-local-hook 'change-major-mode-hook)
 450                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 451                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 452            (mml-destroy-buffers)
 453            (setq mml-buffer-list mbl)))
 454        (message-hide-headers)
 455        (gnus-add-buffer)
 456        (gnus-configure-windows ,config t)
 457        (run-hooks 'post-command-hook)
 458        (set-buffer-modified-p nil))))
 459
 460 (defun gnus-inews-make-draft-meta-information (group articles)
 461   (when (numberp articles)
 462     (setq articles (list articles)))
 463   (concat "(\"" group "\""
 464           (if articles
 465               (concat " "
 466                       (mapconcat
 467                        (lambda (elem)
 468                          (number-to-string
 469                           (if (consp elem)
 470                               (car elem)
 471                             elem)))
 472                        articles " "))
 473             "")
 474           ")"))
 475
 476 ;;;###autoload
 477 (defun gnus-msg-mail (&optional to subject other-headers continue
 478                                 switch-action yank-action send-actions)
 479   "Start editing a mail message to be sent.
 480 Like `message-mail', but with Gnus paraphernalia, particularly the
 481 Gcc: header for archiving purposes."
 482   (interactive)
 483   (let ((buf (current-buffer))
 484         mail-buf)
 485     (gnus-setup-message 'message
 486       (message-mail to subject other-headers continue
 487                     nil yank-action send-actions))
 488     (when switch-action
 489       (setq mail-buf (current-buffer))
 490       (switch-to-buffer buf)
 491       (apply switch-action mail-buf nil)))
 492   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 493   t)
 494
 495 ;;;###autoload
 496 (defun gnus-button-mailto (address)
 497   "Mail to ADDRESS."
 498   (set-buffer (gnus-copy-article-buffer))
 499   (gnus-setup-message 'message
 500     (message-reply address)))
 501
 502 ;;;###autoload
 503 (defun gnus-button-reply (&optional to-address wide)
 504   "Like `message-reply'."
 505   (interactive)
 506   (gnus-setup-message 'message
 507     (message-reply to-address wide)))
 508
 509 ;;;###autoload
 510 (define-mail-user-agent 'gnus-user-agent
 511   'gnus-msg-mail 'message-send-and-exit
 512   'message-kill-buffer 'message-send-hook)
 513
 514 (defun gnus-setup-posting-charset (group)
 515   (let ((alist gnus-group-posting-charset-alist)
 516         (group (or group ""))
 517         elem)
 518     (when group
 519       (catch 'found
 520         (while (setq elem (pop alist))
 521           (when (or (and (stringp (car elem))
 522                          (string-match (car elem) group))
 523                     (and (functionp (car elem))
 524                          (funcall (car elem) group))
 525                     (and (symbolp (car elem))
 526                          (symbol-value (car elem))))
 527             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 528
 529 (defun gnus-inews-add-send-actions (winconf buffer article
 530                                             &optional config yanked)
 531   (gnus-make-local-hook 'message-sent-hook)
 532   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 533                                  'gnus-inews-do-gcc) nil t)
 534   (when gnus-agent
 535     (gnus-make-local-hook 'message-header-hook)
 536     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 537   (setq message-post-method
 538         `(lambda (&optional arg)
 539            (gnus-post-method arg ,gnus-newsgroup-name)))
 540   (message-add-action
 541    `(when (gnus-buffer-exists-p ,buffer)
 542       (set-window-configuration ,winconf))
 543    'exit 'postpone 'kill)
 544   (let ((to-be-marked (cond
 545                        (yanked
 546                         (mapcar
 547                          (lambda (x) (if (listp x) (car x) x)) yanked))
 548                        (article (if (listp article) article (list article)))
 549                        (t nil))))
 550     (message-add-action
 551      `(when (gnus-buffer-exists-p ,buffer)
 552         (with-current-buffer ,buffer
 553           ,(when to-be-marked
 554              (if (eq config 'forward)
 555                  `(gnus-summary-mark-article-as-forwarded ',to-be-marked)
 556                `(gnus-summary-mark-article-as-replied ',to-be-marked)))))
 557      'send)))
 558
 559 (put 'gnus-setup-message 'lisp-indent-function 1)
 560 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 561
 562 ;;; Post news commands of Gnus group mode and summary mode
 563
 564 (defun gnus-group-mail (&optional arg)
 565   "Start composing a mail.
 566 If ARG, use the group under the point to find a posting style.
 567 If ARG is 1, prompt for a group name to find the posting style."
 568   (interactive "P")
 569   ;; We can't `let' gnus-newsgroup-name here, since that leads
 570   ;; to local variables leaking.
 571   (let ((group gnus-newsgroup-name)
 572         ;; make sure last viewed article doesn't affect posting styles:
 573         (gnus-article-copy)
 574         (buffer (current-buffer)))
 575     (unwind-protect
 576         (progn
 577           (setq gnus-newsgroup-name
 578                 (if arg
 579                     (if (= 1 (prefix-numeric-value arg))
 580                         (gnus-group-completing-read
 581                          "Use posting style of group"
 582                          nil (gnus-read-active-file-p))
 583                       (gnus-group-group-name))
 584                   ""))
 585           ;; #### see comment in gnus-setup-message -- drv
 586           (gnus-setup-message 'message (message-mail)))
 587       (with-current-buffer buffer
 588         (setq gnus-newsgroup-name group)))))
 589
 590 (defun gnus-group-news (&optional arg)
 591   "Start composing a news.
 592 If ARG, post to group under point.
 593 If ARG is 1, prompt for group name to post to.
 594
 595 This function prepares a news even when using mail groups.  This is useful
 596 for posting messages to mail groups without actually sending them over the
 597 network.  The corresponding back end must have a 'request-post method."
 598   (interactive "P")
 599   ;; We can't `let' gnus-newsgroup-name here, since that leads
 600   ;; to local variables leaking.
 601   (let ((group gnus-newsgroup-name)
 602         ;; make sure last viewed article doesn't affect posting styles:
 603         (gnus-article-copy)
 604         (buffer (current-buffer)))
 605     (unwind-protect
 606         (progn
 607           (setq gnus-newsgroup-name
 608                 (if arg
 609                     (if (= 1 (prefix-numeric-value arg))
 610                         (gnus-group-completing-read "Use group"
 611                                                     nil
 612                                                     (gnus-read-active-file-p))
 613                       (gnus-group-group-name))
 614                   ""))
 615           ;; #### see comment in gnus-setup-message -- drv
 616           (gnus-setup-message 'message
 617             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 618       (with-current-buffer buffer
 619         (setq gnus-newsgroup-name group)))))
 620
 621 (defun gnus-group-post-news (&optional arg)
 622   "Start composing a message (a news by default).
 623 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 624 Depending on the selected group, the message might be either a mail or
 625 a news."
 626   (interactive "P")
 627   ;; Bind this variable here to make message mode hooks work ok.
 628   (let ((gnus-newsgroup-name
 629          (if arg
 630              (if (= 1 (prefix-numeric-value arg))
 631                  (gnus-group-completing-read "Newsgroup" nil
 632                                              (gnus-read-active-file-p))
 633                (gnus-group-group-name))
 634            ""))
 635         ;; make sure last viewed article doesn't affect posting styles:
 636         (gnus-article-copy))
 637     (gnus-post-news 'post gnus-newsgroup-name nil nil nil nil
 638                     (string= gnus-newsgroup-name ""))))
 639
 640 (defun gnus-summary-mail-other-window (&optional arg)
 641   "Start composing a mail in another window.
 642 Use the posting of the current group by default.
 643 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 644 posting style."
 645   (interactive "P")
 646   ;; We can't `let' gnus-newsgroup-name here, since that leads
 647   ;; to local variables leaking.
 648   (let ((group gnus-newsgroup-name)
 649         ;; make sure last viewed article doesn't affect posting styles:
 650         (gnus-article-copy)
 651         (buffer (current-buffer)))
 652     (unwind-protect
 653         (progn
 654           (setq gnus-newsgroup-name
 655                 (if arg
 656                     (if (= 1 (prefix-numeric-value arg))
 657                         (gnus-group-completing-read "Use group"
 658                                                     nil
 659                                                     (gnus-read-active-file-p))
 660                       "")
 661                   gnus-newsgroup-name))
 662           ;; #### see comment in gnus-setup-message -- drv
 663           (gnus-setup-message 'message (message-mail)))
 664       (with-current-buffer buffer
 665         (setq gnus-newsgroup-name group)))))
 666
 667 (defun gnus-summary-news-other-window (&optional arg)
 668   "Start composing a news in another window.
 669 Post to the current group by default.
 670 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 671
 672 This function prepares a news even when using mail groups.  This is useful
 673 for posting messages to mail groups without actually sending them over the
 674 network.  The corresponding back end must have a 'request-post method."
 675   (interactive "P")
 676   ;; We can't `let' gnus-newsgroup-name here, since that leads
 677   ;; to local variables leaking.
 678   (let ((group gnus-newsgroup-name)
 679         ;; make sure last viewed article doesn't affect posting styles:
 680         (gnus-article-copy)
 681         (buffer (current-buffer)))
 682     (unwind-protect
 683         (progn
 684           (setq gnus-newsgroup-name
 685                 (if arg
 686                     (if (= 1 (prefix-numeric-value arg))
 687                         (gnus-group-completing-read "Use group"
 688                                                     nil
 689                                                     (gnus-read-active-file-p))
 690                       "")
 691                   gnus-newsgroup-name))
 692           ;; #### see comment in gnus-setup-message -- drv
 693           (gnus-setup-message 'message
 694             (progn
 695               (message-news (gnus-group-real-name gnus-newsgroup-name))
 696               (set (make-local-variable 'gnus-discouraged-post-methods)
 697                    (remove
 698                     (car (gnus-find-method-for-group gnus-newsgroup-name))
 699                     gnus-discouraged-post-methods)))))
 700       (with-current-buffer buffer
 701         (setq gnus-newsgroup-name group)))))
 702
 703 (defun gnus-summary-post-news (&optional arg)
 704   "Start composing a message.  Post to the current group by default.
 705 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 706 Depending on the selected group, the message might be either a mail or
 707 a news."
 708   (interactive "P")
 709   ;; Bind this variable here to make message mode hooks work ok.
 710   (let ((gnus-newsgroup-name
 711          (if arg
 712              (if (= 1 (prefix-numeric-value arg))
 713                  (gnus-group-completing-read "Newsgroup" nil
 714                                              (gnus-read-active-file-p))
 715                "")
 716            gnus-newsgroup-name))
 717         ;; make sure last viewed article doesn't affect posting styles:
 718         (gnus-article-copy))
 719     (gnus-post-news 'post gnus-newsgroup-name)))
 720
 721
 722 (defun gnus-summary-followup (yank &optional force-news)
 723   "Compose a followup to an article.
 724 If prefix argument YANK is non-nil, the original article is yanked
 725 automatically.
 726 YANK is a list of elements, where the car of each element is the
 727 article number, and the cdr is the string to be yanked."
 728   (interactive
 729    (list (and current-prefix-arg
 730               (gnus-summary-work-articles 1))))
 731   (when yank
 732     (gnus-summary-goto-subject
 733      (if (listp (car yank))
 734          (caar yank)
 735        (car yank))))
 736   (save-window-excursion
 737     (gnus-summary-select-article))
 738   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 739         (gnus-newsgroup-name gnus-newsgroup-name))
 740     ;; Send a followup.
 741     (gnus-post-news nil gnus-newsgroup-name
 742                     headers gnus-article-buffer
 743                     yank nil force-news)
 744     (gnus-summary-handle-replysign)))
 745
 746 (defun gnus-summary-followup-with-original (n &optional force-news)
 747   "Compose a followup to an article and include the original article.
 748 The text in the region will be yanked.  If the region isn't
 749 active, the entire article will be yanked."
 750   (interactive "P")
 751   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 752
 753 (defun gnus-summary-followup-to-mail (&optional arg)
 754   "Followup to the current mail message via news."
 755   (interactive
 756    (list (and current-prefix-arg
 757               (gnus-summary-work-articles 1))))
 758   (gnus-summary-followup arg t))
 759
 760 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 761   "Followup to the current mail message via news."
 762   (interactive "P")
 763   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 764
 765 (defun gnus-inews-yank-articles (articles)
 766   (let (beg article yank-string)
 767     (message-goto-body)
 768     (while (setq article (pop articles))
 769       (when (listp article)
 770         (setq yank-string (nth 1 article)
 771               article (nth 0 article)))
 772       (save-window-excursion
 773         (set-buffer gnus-summary-buffer)
 774         (gnus-summary-select-article nil nil nil article)
 775         (gnus-summary-remove-process-mark article))
 776       (gnus-copy-article-buffer nil yank-string)
 777       (let ((message-reply-buffer gnus-article-copy)
 778             (message-reply-headers
 779              ;; The headers are decoded.
 780              (with-current-buffer gnus-article-copy
 781                (save-restriction
 782                  (nnheader-narrow-to-headers)
 783                  (nnheader-parse-naked-head)))))
 784         (message-yank-original)
 785         (message-exchange-point-and-mark)
 786         (setq beg (or beg (mark t))))
 787       (when articles
 788         (insert "\n")))
 789     (push-mark)
 790     (goto-char beg)))
 791
 792 (defun gnus-summary-cancel-article (&optional n symp)
 793   "Cancel an article you posted.
 794 Uses the process-prefix convention.  If given the symbolic
 795 prefix `a', cancel using the standard posting method; if not
 796 post using the current select method."
 797   (interactive (gnus-interactive "P\ny"))
 798   (let ((message-post-method
 799          `(lambda (arg)
 800             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name))))
 801     (dolist (article (gnus-summary-work-articles n))
 802       (when (gnus-summary-select-article t nil nil article)
 803         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 804                 (message-cancel-news))
 805           (gnus-summary-mark-as-read article gnus-canceled-mark)
 806           (gnus-cache-remove-article 1))
 807         (gnus-article-hide-headers-if-wanted))
 808       (gnus-summary-remove-process-mark article))))
 809
 810 (defun gnus-summary-supersede-article ()
 811   "Compose an article that will supersede a previous article.
 812 This is done simply by taking the old article and adding a Supersedes
 813 header line with the old Message-ID."
 814   (interactive)
 815   (let ((article (gnus-summary-article-number))
 816         (mail-parse-charset gnus-newsgroup-charset))
 817     (gnus-setup-message 'reply-yank
 818       (gnus-summary-select-article t)
 819       (set-buffer gnus-original-article-buffer)
 820       (message-supersede)
 821       (push
 822        `((lambda ()
 823            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 824              (with-current-buffer ,gnus-summary-buffer
 825                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 826                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 827        message-send-actions)
 828       ;; Add Gcc header.
 829       (gnus-inews-insert-archive-gcc)
 830       (gnus-inews-insert-gcc))))
 831
 832 \f
 833
 834 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 835   ;; make a copy of the article buffer with all text properties removed
 836   ;; this copy is in the buffer gnus-article-copy.
 837   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 838   ;; this buffer should be passed to all mail/news reply/post routines.
 839   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 840   (with-current-buffer gnus-article-copy
 841     (mm-enable-multibyte))
 842   (let ((article-buffer (or article-buffer gnus-article-buffer))
 843         end beg)
 844     (if (not (and (get-buffer article-buffer)
 845                   (gnus-buffer-exists-p article-buffer)))
 846         (error "Can't find any article buffer")
 847       (with-current-buffer article-buffer
 848         (let ((gnus-newsgroup-charset (or gnus-article-charset
 849                                           gnus-newsgroup-charset))
 850               (gnus-newsgroup-ignored-charsets
 851                (or gnus-article-ignored-charsets
 852                    gnus-newsgroup-ignored-charsets)))
 853           (save-restriction
 854             ;; Copy over the (displayed) article buffer, delete
 855             ;; hidden text and remove text properties.
 856             (widen)
 857             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 858             (set-buffer gnus-article-copy)
 859             (when yank-string
 860               (message-goto-body)
 861               (delete-region (point) (point-max))
 862               (insert yank-string))
 863             (gnus-article-delete-text-of-type 'annotation)
 864             (gnus-article-delete-text-of-type 'multipart)
 865             (gnus-remove-text-with-property 'gnus-prev)
 866             (gnus-remove-text-with-property 'gnus-next)
 867             (gnus-remove-text-with-property 'gnus-decoration)
 868             (insert
 869              (prog1
 870                  (buffer-substring-no-properties (point-min) (point-max))
 871                (erase-buffer)))
 872             ;; Find the original headers.
 873             (set-buffer gnus-original-article-buffer)
 874             (goto-char (point-min))
 875             (while (looking-at message-unix-mail-delimiter)
 876               (forward-line 1))
 877             (let ((mail-header-separator ""))
 878               (setq beg (point)
 879                     end (or (message-goto-body)
 880                             ;; There may be just a header.
 881                             (point-max))))
 882             ;; Delete the headers from the displayed articles.
 883             (set-buffer gnus-article-copy)
 884             (let ((mail-header-separator ""))
 885               (delete-region (goto-char (point-min))
 886                              (or (message-goto-body) (point-max))))
 887             ;; Insert the original article headers.
 888             (insert-buffer-substring gnus-original-article-buffer beg end)
 889             ;; Decode charsets.
 890             (let ((gnus-article-decode-hook
 891                    (delq 'article-decode-charset
 892                          (copy-sequence gnus-article-decode-hook)))
 893                   (rfc2047-quote-decoded-words-containing-tspecials t))
 894               (run-hooks 'gnus-article-decode-hook)))))
 895       gnus-article-copy)))
 896
 897 (defun gnus-post-news (post &optional group header article-buffer yank subject
 898                             force-news)
 899   (when article-buffer
 900     (gnus-copy-article-buffer))
 901   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 902         (gnus-article-yanked-articles yank)
 903         (add-to-list gnus-add-to-list))
 904     (gnus-setup-message (cond (yank 'reply-yank)
 905                               (article-buffer 'reply)
 906                               (t 'message))
 907       (let* ((group (or group gnus-newsgroup-name))
 908              (charset (gnus-group-name-charset nil group))
 909              (pgroup group)
 910              to-address to-group mailing-list to-list
 911              newsgroup-p)
 912         (when group
 913           (setq to-address (gnus-parameter-to-address group)
 914                 to-group (gnus-group-find-parameter group 'to-group)
 915                 to-list (gnus-parameter-to-list group)
 916                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 917                 mailing-list (when gnus-mailing-list-groups
 918                                (string-match gnus-mailing-list-groups group))
 919                 group (gnus-group-name-decode (gnus-group-real-name group)
 920                                               charset)))
 921         (if (or (and to-group
 922                      (gnus-news-group-p to-group))
 923                 newsgroup-p
 924                 force-news
 925                 (and (gnus-news-group-p
 926                       (or pgroup gnus-newsgroup-name)
 927                       (or header gnus-current-article))
 928                      (not mailing-list)
 929                      (not to-list)
 930                      (not to-address)))
 931             ;; This is news.
 932             (if post
 933                 (message-news
 934                  (or to-group
 935                      (and (not (gnus-virtual-group-p pgroup)) group)))
 936               (set-buffer gnus-article-copy)
 937               (gnus-msg-treat-broken-reply-to)
 938               (message-followup (if (or newsgroup-p force-news)
 939                                     (if (save-restriction
 940                                           (article-narrow-to-head)
 941                                           (message-fetch-field "newsgroups"))
 942                                         nil
 943                                       "")
 944                                   to-group)))
 945           ;; The is mail.
 946           (if post
 947               (progn
 948                 (message-mail (or to-address to-list))
 949                 ;; Arrange for mail groups that have no `to-address' to
 950                 ;; get that when the user sends off the mail.
 951                 (when (and (not to-list)
 952                            (not to-address)
 953                            add-to-list)
 954                   (push (list 'gnus-inews-add-to-address pgroup)
 955                         message-send-actions)))
 956             (set-buffer gnus-article-copy)
 957             (gnus-msg-treat-broken-reply-to)
 958             (message-wide-reply to-address)))
 959         (when yank
 960           (gnus-inews-yank-articles yank))))))
 961
 962 (defun gnus-msg-treat-broken-reply-to (&optional force)
 963   "Remove the Reply-to header if broken-reply-to."
 964   (when (or force
 965             (gnus-group-find-parameter
 966              gnus-newsgroup-name 'broken-reply-to))
 967     (save-restriction
 968       (message-narrow-to-head)
 969       (message-remove-header "reply-to"))))
 970
 971 (defun gnus-post-method (arg group &optional silent)
 972   "Return the posting method based on GROUP and ARG.
 973 If SILENT, don't prompt the user."
 974   (let ((gnus-post-method (or (gnus-parameter-post-method group)
 975                               gnus-post-method))
 976         (group-method (gnus-find-method-for-group group)))
 977     (cond
 978      ;; If the group-method is nil (which shouldn't happen) we use
 979      ;; the default method.
 980      ((null group-method)
 981       (or (and (listp gnus-post-method) ;If not current/native/nil
 982                (not (listp (car gnus-post-method))) ; and not a list of methods
 983                gnus-post-method)        ;then use it.
 984           gnus-select-method
 985           message-post-method))
 986      ;; We want the inverse of the default
 987      ((and arg (not (eq arg 0)))
 988       (if (eq gnus-post-method 'current)
 989           gnus-select-method
 990         group-method))
 991      ;; We query the user for a post method.
 992      ((or arg
 993           (and (listp gnus-post-method)
 994                (listp (car gnus-post-method))))
 995       (let* ((methods
 996               ;; Collect all methods we know about.
 997               (append
 998                (when (listp gnus-post-method)
 999                  (if (listp (car gnus-post-method))
1000                      gnus-post-method
1001                    (list gnus-post-method)))
1002                gnus-secondary-select-methods
1003                (mapcar 'cdr gnus-server-alist)
1004                (mapcar 'car gnus-opened-servers)
1005                (list gnus-select-method)
1006                (list group-method)))
1007              method-alist post-methods method)
1008         ;; Weed out all mail methods.
1009         (while methods
1010           (setq method (gnus-server-get-method "" (pop methods)))
1011           (when (and (or (gnus-method-option-p method 'post)
1012                          (gnus-method-option-p method 'post-mail))
1013                      (not (member method post-methods)))
1014             (push method post-methods)))
1015         ;; Create a name-method alist.
1016         (setq method-alist
1017               (mapcar
1018                (lambda (m)
1019                  (if (equal (cadr m) "")
1020                      (list (symbol-name (car m)) m)
1021                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
1022                post-methods))
1023         ;; Query the user.
1024         (cadr
1025          (assoc
1026           (setq gnus-last-posting-server
1027                 (if (and silent
1028                          gnus-last-posting-server)
1029                     ;; Just use the last value.
1030                     gnus-last-posting-server
1031                   (gnus-completing-read
1032                    "Posting method" (mapcar 'car method-alist) t
1033                    (cons (or gnus-last-posting-server "") 0))))
1034           method-alist))))
1035      ;; Override normal method.
1036      ((and (eq gnus-post-method 'current)
1037            (not (memq (car group-method) gnus-discouraged-post-methods))
1038            (gnus-get-function group-method 'request-post t))
1039       (assert (not arg))
1040       group-method)
1041      ;; Use gnus-post-method.
1042      ((listp gnus-post-method)          ;A method...
1043       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
1044       gnus-post-method)
1045      ;; Use the normal select method (nil or native).
1046      (t gnus-select-method))))
1047
1048 \f
1049
1050 (defun gnus-extended-version ()
1051   "Stringified Gnus version and Emacs version.
1052 See the variable `gnus-user-agent'."
1053   (interactive)
1054   (if (stringp gnus-user-agent)
1055       gnus-user-agent
1056     ;; `gnus-user-agent' is a list:
1057     (let* ((float-output-format nil)
1058            (gnus-v
1059             (when (memq 'gnus gnus-user-agent)
1060               (concat "Gnus/"
1061                       (prin1-to-string (gnus-continuum-version gnus-version) t)
1062                       " (" gnus-version ")")))
1063            (emacs-v (gnus-emacs-version)))
1064       (concat gnus-v (when (and gnus-v emacs-v) " ")
1065               emacs-v))))
1066
1067 \f
1068 ;;;
1069 ;;; Gnus Mail Functions
1070 ;;;
1071
1072 ;;; Mail reply commands of Gnus summary mode
1073
1074 (defun gnus-summary-reply (&optional yank wide very-wide)
1075   "Start composing a mail reply to the current message.
1076 If prefix argument YANK is non-nil, the original article is yanked
1077 automatically.
1078 If WIDE, make a wide reply.
1079 If VERY-WIDE, make a very wide reply."
1080   (interactive
1081    (list (and current-prefix-arg
1082               (gnus-summary-work-articles 1))))
1083   ;; Allow user to require confirmation before replying by mail to the
1084   ;; author of a news article (or mail message).
1085   (when (or
1086             (not (or (gnus-news-group-p gnus-newsgroup-name)
1087                      gnus-confirm-treat-mail-like-news))
1088             (not (cond ((stringp gnus-confirm-mail-reply-to-news)
1089                         (string-match gnus-confirm-mail-reply-to-news
1090                                       gnus-newsgroup-name))
1091                        ((functionp gnus-confirm-mail-reply-to-news)
1092                         (funcall gnus-confirm-mail-reply-to-news gnus-newsgroup-name))
1093                        (t gnus-confirm-mail-reply-to-news)))
1094             (if (or wide very-wide)
1095                 t ;; Ignore gnus-confirm-mail-reply-to-news for wide and very
1096                   ;; wide replies.
1097               (y-or-n-p "Really reply by mail to article author? ")))
1098     (let* ((article
1099             (if (listp (car yank))
1100                 (caar yank)
1101               (car yank)))
1102            (gnus-article-reply (or article (gnus-summary-article-number)))
1103            (gnus-article-yanked-articles yank)
1104            (headers ""))
1105       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1106       (when yank
1107         (gnus-summary-goto-subject article))
1108       (gnus-setup-message (if yank 'reply-yank 'reply)
1109         (if (not very-wide)
1110             (gnus-summary-select-article)
1111           (dolist (article very-wide)
1112             (gnus-summary-select-article nil nil nil article)
1113             (with-current-buffer (gnus-copy-article-buffer)
1114               (gnus-msg-treat-broken-reply-to)
1115               (save-restriction
1116                 (message-narrow-to-head)
1117                 (setq headers (concat headers (buffer-string)))))))
1118         (set-buffer (gnus-copy-article-buffer))
1119         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1120         (save-restriction
1121           (message-narrow-to-head)
1122           (when very-wide
1123             (erase-buffer)
1124             (insert headers))
1125           (goto-char (point-max)))
1126         (mml-quote-region (point) (point-max))
1127         (message-reply nil wide)
1128         (when yank
1129           (gnus-inews-yank-articles yank))
1130         (gnus-summary-handle-replysign)))))
1131
1132 (defun gnus-summary-handle-replysign ()
1133   "Check the various replysign variables and take action accordingly."
1134   (when (or gnus-message-replysign gnus-message-replyencrypt)
1135     (let (signed encrypted)
1136       (with-current-buffer gnus-article-buffer
1137         (setq signed (memq 'signed gnus-article-wash-types))
1138         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1139       (cond ((and gnus-message-replyencrypt encrypted)
1140              (mml-secure-message mml-default-encrypt-method
1141                                  (if gnus-message-replysignencrypted
1142                                      'signencrypt
1143                                    'encrypt)))
1144             ((and gnus-message-replysign signed)
1145              (mml-secure-message mml-default-sign-method 'sign))))))
1146
1147 (defun gnus-summary-reply-with-original (n &optional wide)
1148   "Start composing a reply mail to the current message.
1149 The original article will be yanked."
1150   (interactive "P")
1151   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1152
1153 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1154   "Like `gnus-summary-reply' except removing reply-to field.
1155 If prefix argument YANK is non-nil, the original article is yanked
1156 automatically.
1157 If WIDE, make a wide reply.
1158 If VERY-WIDE, make a very wide reply."
1159   (interactive
1160    (list (and current-prefix-arg
1161               (gnus-summary-work-articles 1))))
1162   (let ((gnus-msg-force-broken-reply-to t))
1163     (gnus-summary-reply yank wide very-wide)))
1164
1165 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1166   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1167 The original article will be yanked."
1168   (interactive "P")
1169   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1170
1171 (defun gnus-summary-wide-reply (&optional yank)
1172   "Start composing a wide reply mail to the current message.
1173 If prefix argument YANK is non-nil, the original article is yanked
1174 automatically."
1175   (interactive
1176    (list (and current-prefix-arg
1177               (gnus-summary-work-articles 1))))
1178   (gnus-summary-reply yank t))
1179
1180 (defun gnus-summary-wide-reply-with-original (n)
1181   "Start composing a wide reply mail to the current message.
1182 The original article will be yanked.
1183 Uses the process/prefix convention."
1184   (interactive "P")
1185   (gnus-summary-reply-with-original n t))
1186
1187 (defun gnus-summary-very-wide-reply (&optional yank)
1188   "Start composing a very wide reply mail to the current message.
1189 If prefix argument YANK is non-nil, the original article is yanked
1190 automatically."
1191   (interactive
1192    (list (and current-prefix-arg
1193               (gnus-summary-work-articles 1))))
1194   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1195
1196 (defun gnus-summary-very-wide-reply-with-original (n)
1197   "Start composing a very wide reply mail to the current message.
1198 The original article will be yanked."
1199   (interactive "P")
1200   (gnus-summary-reply
1201    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1202
1203 (defun gnus-summary-mail-forward (&optional arg post)
1204   "Forward the current message(s) to another user.
1205 If process marks exist, forward all marked messages;
1206 if ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
1207 if ARG is 1, decode the message and forward directly inline;
1208 if ARG is 2, forward message as an rfc822 MIME section;
1209 if ARG is 3, decode message and forward as an rfc822 MIME section;
1210 if ARG is 4, forward message directly inline;
1211 otherwise, use flipped `message-forward-as-mime'.
1212 If POST, post instead of mail.
1213 For the `inline' alternatives, also see the variable
1214 `message-forward-ignored-headers'."
1215   (interactive "P")
1216   (if (cdr (gnus-summary-work-articles nil))
1217       ;; Process marks are given.
1218       (gnus-uu-digest-mail-forward arg post)
1219     ;; No process marks.
1220     (let ((message-forward-as-mime message-forward-as-mime)
1221           (message-forward-show-mml message-forward-show-mml))
1222       (cond
1223        ((null arg))
1224        ((eq arg 1)
1225         (setq message-forward-as-mime nil
1226               message-forward-show-mml t))
1227        ((eq arg 2)
1228         (setq message-forward-as-mime t
1229               message-forward-show-mml nil))
1230        ((eq arg 3)
1231         (setq message-forward-as-mime t
1232               message-forward-show-mml t))
1233        ((eq arg 4)
1234         (setq message-forward-as-mime nil
1235               message-forward-show-mml nil))
1236        (t
1237         (setq message-forward-as-mime (not message-forward-as-mime))))
1238       (let* ((gnus-article-reply (gnus-summary-article-number))
1239              (gnus-article-yanked-articles (list gnus-article-reply)))
1240         (gnus-setup-message 'forward
1241           (gnus-summary-select-article)
1242           (let ((mail-parse-charset
1243                  (or (and (gnus-buffer-live-p gnus-article-buffer)
1244                           (with-current-buffer gnus-article-buffer
1245                             gnus-article-charset))
1246                      gnus-newsgroup-charset))
1247                 (mail-parse-ignored-charsets
1248                  gnus-newsgroup-ignored-charsets))
1249             (set-buffer gnus-original-article-buffer)
1250             (message-forward post)))))))
1251
1252 (defun gnus-summary-resend-message (address n)
1253   "Resend the current article to ADDRESS."
1254   (interactive
1255    (list (message-read-from-minibuffer
1256           "Resend message(s) to: "
1257           (when (and gnus-summary-resend-default-address
1258                      (gnus-buffer-live-p gnus-original-article-buffer))
1259             ;; If some other article is currently selected, the
1260             ;; initial-contents is wrong. Whatever, it is just the
1261             ;; initial-contents.
1262             (with-current-buffer gnus-original-article-buffer
1263               (nnmail-fetch-field "to"))))
1264          current-prefix-arg))
1265   (dolist (article (gnus-summary-work-articles n))
1266     (gnus-summary-select-article nil nil nil article)
1267     (with-current-buffer gnus-original-article-buffer
1268       (let ((gnus-gcc-externalize-attachments nil))
1269         (message-resend address)))
1270     (gnus-summary-mark-article-as-forwarded article)))
1271
1272 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1273 (defun gnus-summary-resend-message-edit ()
1274   "Resend an article that has already been sent.
1275 A new buffer will be created to allow the user to modify body and
1276 contents of the message, and then, everything will happen as when
1277 composing a new message."
1278   (interactive)
1279   (let ((mail-parse-charset gnus-newsgroup-charset))
1280     (gnus-setup-message 'reply-yank
1281       (gnus-summary-select-article t)
1282       (set-buffer gnus-original-article-buffer)
1283       (let ((cur (current-buffer))
1284             (to (message-fetch-field "to")))
1285         ;; Get a normal message buffer.
1286         (message-pop-to-buffer (message-buffer-name "Resend" to))
1287         (insert-buffer-substring cur)
1288         (mime-to-mml)
1289         (message-narrow-to-head-1)
1290         ;; Gnus will generate a new one when sending.
1291         (message-remove-header "Message-ID")
1292         ;; Remove unwanted headers.
1293         (message-remove-header message-ignored-resent-headers t)
1294         (goto-char (point-max))
1295         (insert mail-header-separator)
1296         ;; Add Gcc header.
1297         (gnus-inews-insert-archive-gcc)
1298         (gnus-inews-insert-gcc)
1299         (goto-char (point-min))
1300         (when (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1301           (forward-char 1))
1302         (widen)))))
1303
1304 (defun gnus-summary-post-forward (&optional arg)
1305   "Forward the current article to a newsgroup.
1306 See `gnus-summary-mail-forward' for ARG."
1307   (interactive "P")
1308   (gnus-summary-mail-forward arg t))
1309
1310 (defun gnus-summary-mail-crosspost-complaint (n)
1311   "Send a complaint about crossposting to the current article(s)."
1312   (interactive "P")
1313   (dolist (article (gnus-summary-work-articles n))
1314     (set-buffer gnus-summary-buffer)
1315     (gnus-summary-goto-subject article)
1316     (let ((group (gnus-group-real-name gnus-newsgroup-name))
1317           newsgroups followup-to)
1318       (gnus-summary-select-article)
1319       (set-buffer gnus-original-article-buffer)
1320       (if (and (<= (length (message-tokenize-header
1321                             (setq newsgroups
1322                                   (mail-fetch-field "newsgroups"))
1323                             ", "))
1324                    1)
1325                (or (not (setq followup-to (mail-fetch-field "followup-to")))
1326                    (not (member group (message-tokenize-header
1327                                        followup-to ", ")))))
1328           (if followup-to
1329               (gnus-message 1 "Followup-to restricted")
1330             (gnus-message 1 "Not a crossposted article"))
1331         (set-buffer gnus-summary-buffer)
1332         (gnus-summary-reply-with-original 1)
1333         (set-buffer gnus-message-buffer)
1334         (message-goto-body)
1335         (insert (format gnus-crosspost-complaint newsgroups group))
1336         (message-goto-subject)
1337         (re-search-forward " *$")
1338         (replace-match " (crosspost notification)" t t)
1339         (gnus-deactivate-mark)
1340         (when (gnus-y-or-n-p "Send this complaint? ")
1341           (message-send-and-exit))))))
1342
1343 (defun gnus-mail-parse-comma-list ()
1344   (let (accumulated
1345         beg)
1346     (skip-chars-forward " ")
1347     (while (not (eobp))
1348       (setq beg (point))
1349       (skip-chars-forward "^,")
1350       (while (zerop
1351               (save-excursion
1352                 (save-restriction
1353                   (let ((i 0))
1354                     (narrow-to-region beg (point))
1355                     (goto-char beg)
1356                     (logand (progn
1357                               (while (search-forward "\"" nil t)
1358                                 (incf i))
1359                               (if (zerop i) 2 i))
1360                             2)))))
1361         (skip-chars-forward ",")
1362         (skip-chars-forward "^,"))
1363       (skip-chars-backward " ")
1364       (push (buffer-substring beg (point))
1365             accumulated)
1366       (skip-chars-forward "^,")
1367       (skip-chars-forward ", "))
1368     accumulated))
1369
1370 (defun gnus-inews-add-to-address (group)
1371   (let ((to-address (mail-fetch-field "to")))
1372     (when (and to-address
1373                (gnus-alive-p))
1374       ;; This mail group doesn't have a `to-list', so we add one
1375       ;; here.  Magic!
1376       (when (gnus-y-or-n-p
1377              (format "Do you want to add this as `to-list': %s? " to-address))
1378         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1379
1380 (defun gnus-put-message ()
1381   "Put the current message in some group and return to Gnus."
1382   (interactive)
1383   (let ((reply gnus-article-reply)
1384         (winconf gnus-prev-winconf)
1385         (group gnus-newsgroup-name))
1386     (unless (and group
1387                  (not (gnus-group-read-only-p group)))
1388       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1389
1390     (when (gnus-group-entry group)
1391       (error "No such group: %s" group))
1392     (save-excursion
1393       (save-restriction
1394         (widen)
1395         (message-narrow-to-headers)
1396         (let ((gnus-deletable-headers nil))
1397           (message-generate-headers
1398            (if (message-news-p)
1399                message-required-news-headers
1400              message-required-mail-headers)))
1401         (goto-char (point-max))
1402         (if (string-match " " group)
1403             (insert "Gcc: \"" group "\"\n")
1404           (insert "Gcc: " group "\n"))
1405         (widen)))
1406     (gnus-inews-do-gcc)
1407     (when (and (get-buffer gnus-group-buffer)
1408                (gnus-buffer-exists-p (car-safe reply))
1409                (cdr reply))
1410       (set-buffer (car reply))
1411       (gnus-summary-mark-article-as-replied (cdr reply)))
1412     (when winconf
1413       (set-window-configuration winconf))))
1414
1415 (defun gnus-article-mail (yank)
1416   "Send a reply to the address near point.
1417 If YANK is non-nil, include the original article."
1418   (interactive "P")
1419   (let ((address
1420          (buffer-substring
1421           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1422           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1423     (when address
1424       (gnus-msg-mail address)
1425       (when yank
1426         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1427
1428 (defvar nntp-server-type)
1429 (defun gnus-bug ()
1430   "Send a bug report to the Gnus maintainers."
1431   (interactive)
1432   (unless (gnus-alive-p)
1433     (error "Gnus has been shut down"))
1434   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1435     (unless (message-mail-user-agent)
1436       (delete-other-windows)
1437       (when gnus-bug-create-help-buffer
1438         (switch-to-buffer "*Gnus Help Bug*")
1439         (erase-buffer)
1440         (insert gnus-bug-message)
1441         (goto-char (point-min)))
1442       (message-pop-to-buffer "*Gnus Bug*"))
1443     (let ((message-this-is-mail t))
1444       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1445     (when gnus-bug-create-help-buffer
1446       (push `(gnus-bug-kill-buffer) message-send-actions))
1447     (goto-char (point-min))
1448     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1449     (forward-line 1)
1450     (insert (gnus-version) "\n"
1451             (emacs-version) "\n")
1452     (when (and (boundp 'nntp-server-type)
1453                (stringp nntp-server-type))
1454       (insert nntp-server-type))
1455     (insert "\n\n\n\n\n")
1456     (let (text)
1457       (with-current-buffer (gnus-get-buffer-create " *gnus environment info*")
1458         (erase-buffer)
1459         (gnus-debug)
1460         (setq text (buffer-string)))
1461       (insert "<#part type=application/emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
1462     (goto-char (point-min))
1463     (search-forward "Subject: " nil t)
1464     (message "")))
1465
1466 (defun gnus-bug-kill-buffer ()
1467   (when (get-buffer "*Gnus Help Bug*")
1468     (kill-buffer "*Gnus Help Bug*")))
1469
1470 (defun gnus-summary-yank-message (buffer n)
1471   "Yank the current article into a composed message."
1472   (interactive
1473    (list (gnus-completing-read "Buffer" (message-buffers) t)
1474          current-prefix-arg))
1475   (gnus-summary-iterate n
1476     (let ((gnus-inhibit-treatment t))
1477       (gnus-summary-select-article))
1478     (with-current-buffer buffer
1479       (message-yank-buffer gnus-article-buffer))))
1480
1481 (defun gnus-debug ()
1482   "Attempts to go through the Gnus source file and report what variables have been changed.
1483 The source file has to be in the Emacs load path."
1484   (interactive)
1485   (let ((files gnus-debug-files)
1486         (point (point))
1487         file expr olist sym)
1488     (gnus-message 4 "Please wait while we snoop your variables...")
1489     (sit-for 0)
1490     ;; Go through all the files looking for non-default values for variables.
1491     (with-current-buffer (gnus-get-buffer-create " *gnus bug info*")
1492       (while files
1493         (erase-buffer)
1494         (when (and (setq file (locate-library (pop files)))
1495                    (file-exists-p file))
1496           (insert-file-contents file)
1497           (goto-char (point-min))
1498           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1499               (gnus-message 4 "Malformed sources in file %s" file)
1500             (narrow-to-region (point-min) (point))
1501             (goto-char (point-min))
1502             (while (setq expr (ignore-errors (read (current-buffer))))
1503               (ignore-errors
1504                 (and (or (eq (car expr) 'defvar)
1505                          (eq (car expr) 'defcustom))
1506                      (stringp (nth 3 expr))
1507                      (not (memq (nth 1 expr) gnus-debug-exclude-variables))
1508                      (or (not (boundp (nth 1 expr)))
1509                          (not (equal (eval (nth 2 expr))
1510                                      (symbol-value (nth 1 expr)))))
1511                      (push (nth 1 expr) olist)))))))
1512       (kill-buffer (current-buffer)))
1513     (when (setq olist (nreverse olist))
1514       (insert "------------------ Environment follows ------------------\n\n"))
1515     (while olist
1516       (if (boundp (car olist))
1517           (ignore-errors
1518            (gnus-pp
1519             `(setq ,(car olist)
1520                    ,(if (or (consp (setq sym (symbol-value (car olist))))
1521                             (and (symbolp sym)
1522                                  (not (or (eq sym nil)
1523                                           (eq sym t)))))
1524                         (list 'quote (symbol-value (car olist)))
1525                       (symbol-value (car olist))))))
1526         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1527       (setq olist (cdr olist)))
1528     (insert "\n\n")
1529     ;; Remove any control chars - they seem to cause trouble for some
1530     ;; mailers.  (Byte-compiled output from the stuff above.)
1531     (goto-char point)
1532     (while (re-search-forward (mm-string-to-multibyte
1533                                "[\000-\010\013-\037\200-\237]") nil t)
1534       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1535                      t t))))
1536
1537 ;;; Treatment of rejected articles.
1538 ;;; Bounced mail.
1539
1540 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1541   "Re-mail the current message.
1542 This only makes sense if the current message is a bounce message that
1543 contains some mail you have written which has been bounced back to
1544 you.
1545 If FETCH, try to fetch the article that this is a reply to, if indeed
1546 this is a reply."
1547   (interactive "P")
1548   (gnus-summary-select-article t)
1549   (let (summary-buffer parent)
1550     (if fetch
1551         (progn
1552           (setq summary-buffer (current-buffer))
1553           (set-buffer gnus-original-article-buffer)
1554           (article-goto-body)
1555           (when (re-search-forward "^References:\n?" nil t)
1556             (while (memq (char-after) '(?\t ? ))
1557               (forward-line 1))
1558             (skip-chars-backward "\t\n ")
1559             (setq parent
1560                   (gnus-parent-id (buffer-substring (match-end 0) (point))))))
1561       (set-buffer gnus-original-article-buffer))
1562     (gnus-setup-message 'compose-bounce
1563       (message-bounce)
1564       ;; Add Gcc header.
1565       (gnus-inews-insert-archive-gcc)
1566       (gnus-inews-insert-gcc)
1567       ;; If there are references, we fetch the article we answered to.
1568       (when parent
1569         (with-current-buffer summary-buffer
1570           (gnus-summary-refer-article parent)
1571           (gnus-summary-show-all-headers))))))
1572
1573 ;;; Gcc handling.
1574
1575 (defun gnus-inews-group-method (group)
1576   (cond
1577    ;; If the group doesn't exist, we assume
1578    ;; it's an archive group...
1579    ((and (null (gnus-get-info group))
1580          (eq (car (gnus-server-to-method gnus-message-archive-method))
1581              (car (gnus-server-to-method (gnus-group-method group)))))
1582     gnus-message-archive-method)
1583    ;; Use the method.
1584    ((gnus-info-method (gnus-get-info group))
1585     (gnus-info-method (gnus-get-info group)))
1586    ;; Find the method.
1587    (t (gnus-server-to-method (gnus-group-method group)))))
1588
1589 ;; Do Gcc handling, which copied the message over to some group.
1590 (defun gnus-inews-do-gcc (&optional gcc)
1591   (interactive)
1592   (save-excursion
1593     (save-restriction
1594       (message-narrow-to-headers)
1595       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1596             (cur (current-buffer))
1597             groups group method group-art
1598             mml-externalize-attachments)
1599         (when gcc
1600           (message-remove-header "gcc")
1601           (widen)
1602           (setq groups (message-unquote-tokens
1603                         (message-tokenize-header gcc " ,")))
1604           ;; Copy the article over to some group(s).
1605           (while (setq group (pop groups))
1606             (setq method (gnus-inews-group-method group)
1607                   group (mm-encode-coding-string
1608                          group
1609                          (gnus-group-name-charset method group)))
1610             (unless (gnus-check-server method)
1611               (error "Can't open server %s" (if (stringp method) method
1612                                               (car method))))
1613             (unless (gnus-request-group group t method)
1614               (gnus-request-create-group group method))
1615             (setq mml-externalize-attachments
1616                   (if (stringp gnus-gcc-externalize-attachments)
1617                       (string-match gnus-gcc-externalize-attachments group)
1618                     gnus-gcc-externalize-attachments))
1619             (save-excursion
1620               (nnheader-set-temp-buffer " *acc*")
1621               (insert-buffer-substring cur)
1622               (message-encode-message-body)
1623               (save-restriction
1624                 (message-narrow-to-headers)
1625                 (let* ((mail-parse-charset message-default-charset)
1626                        (newsgroups-field (save-restriction
1627                                            (message-narrow-to-headers-or-head)
1628                                            (message-fetch-field "Newsgroups")))
1629                        (followup-field (save-restriction
1630                                          (message-narrow-to-headers-or-head)
1631                                          (message-fetch-field "Followup-To")))
1632                        ;; BUG: We really need to get the charset for
1633                        ;; each name in the Newsgroups and Followup-To
1634                        ;; lines to allow crossposting between group
1635                        ;; namess with incompatible character sets.
1636                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1637                        (group-field-charset
1638                         (gnus-group-name-charset
1639                          method (or newsgroups-field "")))
1640                        (followup-field-charset
1641                         (gnus-group-name-charset
1642                          method (or followup-field "")))
1643                        (rfc2047-header-encoding-alist
1644                         (append
1645                          (when group-field-charset
1646                            (list (cons "Newsgroups" group-field-charset)))
1647                          (when followup-field-charset
1648                            (list (cons "Followup-To" followup-field-charset)))
1649                          rfc2047-header-encoding-alist)))
1650                   (mail-encode-encoded-word-buffer)))
1651               (goto-char (point-min))
1652               (when (re-search-forward
1653                      (concat "^" (regexp-quote mail-header-separator) "$")
1654                      nil t)
1655                 (replace-match "" t t ))
1656               (when (or (not (gnus-check-backend-function
1657                               'request-accept-article group))
1658                         (not (setq group-art
1659                                    (gnus-request-accept-article
1660                                     group method t t))))
1661                 (gnus-message 1 "Couldn't store article in group %s: %s"
1662                               group (gnus-status-message method)))
1663               (when (stringp method)
1664                 (setq method (gnus-server-to-method method)))
1665               (when (and (listp method)
1666                          (gnus-native-method-p method))
1667                 (setq group (gnus-group-short-name group)))
1668               (when (and group-art
1669                          ;; FIXME: Should gcc-mark-as-read work when
1670                          ;; Gnus is not running?
1671                          (gnus-alive-p)
1672                          (or gnus-gcc-mark-as-read
1673                              (and
1674                               (boundp 'gnus-inews-mark-gcc-as-read)
1675                               (symbol-value 'gnus-inews-mark-gcc-as-read))))
1676                 (gnus-group-mark-article-read group (cdr group-art)))
1677               (kill-buffer (current-buffer)))))))))
1678
1679 (defun gnus-inews-insert-gcc ()
1680   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1681   (save-excursion
1682     (save-restriction
1683       (message-narrow-to-headers)
1684       (let* ((group gnus-outgoing-message-group)
1685              (gcc (cond
1686                    ((functionp group)
1687                     (funcall group))
1688                    ((or (stringp group) (listp group))
1689                     group))))
1690         (when gcc
1691           (insert "Gcc: "
1692                   (if (stringp gcc)
1693                       (if (string-match " " gcc)
1694                           (concat "\"" gcc "\"")
1695                         gcc)
1696                     (mapconcat (lambda (group)
1697                                  (if (string-match " " group)
1698                                      (concat "\"" group "\"")
1699                                    group))
1700                                gcc " "))
1701                   "\n"))))))
1702
1703 (defun gnus-inews-insert-archive-gcc (&optional group)
1704   "Insert the Gcc to say where the article is to be archived."
1705   (setq group (cond (group
1706                      (gnus-group-decoded-name group))
1707                     (gnus-newsgroup-name
1708                      (gnus-group-decoded-name gnus-newsgroup-name))
1709                     (t
1710                      "")))
1711   (let* ((var gnus-message-archive-group)
1712          (gcc-self-val
1713           (and gnus-newsgroup-name
1714                (not (equal gnus-newsgroup-name ""))
1715                (gnus-group-find-parameter
1716                 gnus-newsgroup-name 'gcc-self)))
1717          result
1718          (groups
1719           (cond
1720            ((null gnus-message-archive-method)
1721             ;; Ignore.
1722             nil)
1723            ((stringp var)
1724             ;; Just a single group.
1725             (list var))
1726            ((null var)
1727             ;; We don't want this.
1728             nil)
1729            ((and (listp var) (stringp (car var)))
1730             ;; A list of groups.
1731             var)
1732            ((functionp var)
1733             ;; A function.
1734             (funcall var group))
1735            (t
1736             ;; An alist of regexps/functions/forms.
1737             (while (and var
1738                         (not
1739                          (setq result
1740                                (cond
1741                                 ((stringp (caar var))
1742                                  ;; Regexp.
1743                                  (when (string-match (caar var) group)
1744                                    (cdar var)))
1745                                 ((functionp (car var))
1746                                  ;; Function.
1747                                  (funcall (car var) group))
1748                                 (t
1749                                  (eval (car var)))))))
1750               (setq var (cdr var)))
1751             result)))
1752          name)
1753     (when (or groups gcc-self-val)
1754       (when (stringp groups)
1755         (setq groups (list groups)))
1756       (save-excursion
1757         (save-restriction
1758           (message-narrow-to-headers)
1759           (goto-char (point-max))
1760           (insert "Gcc: ")
1761           (if gcc-self-val
1762               ;; Use the `gcc-self' param value instead.
1763               (progn
1764                 (insert
1765                  (if (stringp gcc-self-val)
1766                      (if (string-match " " gcc-self-val)
1767                          (concat "\"" gcc-self-val "\"")
1768                        gcc-self-val)
1769                    ;; In nndoc groups, we use the parent group name
1770                    ;; instead of the current group.
1771                    (let ((group (or (gnus-group-find-parameter
1772                                      gnus-newsgroup-name 'parent-group)
1773                                     group)))
1774                      (if (string-match " " group)
1775                          (concat "\"" group "\"")
1776                        group))))
1777                 (if (not (eq gcc-self-val 'none))
1778                     (insert "\n")
1779                   (gnus-delete-line)))
1780             ;; Use the list of groups.
1781             (while (setq name (pop groups))
1782               (let ((str (if (string-match ":" name)
1783                              name
1784                            (gnus-group-prefixed-name
1785                             name gnus-message-archive-method))))
1786                 (insert (if (string-match " " str)
1787                             (concat "\"" str "\"")
1788                           str)))
1789               (when groups
1790                 (insert " ")))
1791             (insert "\n")))))))
1792
1793 (defun gnus-mailing-list-followup-to ()
1794   "Look at the headers in the current buffer and return a Mail-Followup-To address."
1795   (let ((x-been-there (gnus-fetch-original-field "x-beenthere"))
1796         (list-post (gnus-fetch-original-field "list-post")))
1797     (when (and list-post
1798                (string-match "mailto:\\([^>]+\\)" list-post))
1799       (setq list-post (match-string 1 list-post)))
1800     (or list-post
1801         x-been-there)))
1802
1803 ;;; Posting styles.
1804
1805 (defun gnus-configure-posting-styles (&optional group-name)
1806   "Configure posting styles according to `gnus-posting-styles'."
1807   (unless gnus-inhibit-posting-styles
1808     (let ((group (or group-name gnus-newsgroup-name ""))
1809           (styles gnus-posting-styles)
1810           style match attribute value v results
1811           filep name address element)
1812       ;; If the group has a posting-style parameter, add it at the end with a
1813       ;; regexp matching everything, to be sure it takes precedence over all
1814       ;; the others.
1815       (when gnus-newsgroup-name
1816         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1817           (when tmp-style
1818             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1819       ;; Go through all styles and look for matches.
1820       (dolist (style styles)
1821         (setq match (pop style))
1822         (goto-char (point-min))
1823         (when (cond
1824                ((stringp match)
1825                 ;; Regexp string match on the group name.
1826                 (string-match match group))
1827                ((eq match 'header)
1828                 ;; Obsolete format of header match.
1829                 (and (gnus-buffer-live-p gnus-article-copy)
1830                      (with-current-buffer gnus-article-copy
1831                        (save-restriction
1832                          (nnheader-narrow-to-headers)
1833                          (let ((header (message-fetch-field (pop style))))
1834                            (and header
1835                                 (string-match (pop style) header)))))))
1836                ((or (symbolp match)
1837                     (functionp match))
1838                 (cond
1839                  ((functionp match)
1840                   ;; Function to be called.
1841                   (funcall match))
1842                  ((boundp match)
1843                   ;; Variable to be checked.
1844                   (symbol-value match))))
1845                ((listp match)
1846                 (cond
1847                  ((eq (car match) 'header)
1848                   ;; New format of header match.
1849                   (and (gnus-buffer-live-p gnus-article-copy)
1850                        (with-current-buffer gnus-article-copy
1851                          (save-restriction
1852                            (nnheader-narrow-to-headers)
1853                            (let ((header (message-fetch-field (nth 1 match))))
1854                              (and header
1855                                   (string-match (nth 2 match) header)))))))
1856                  (t
1857                   ;; This is a form to be evaled.
1858                   (eval match)))))
1859           ;; We have a match, so we set the variables.
1860           (dolist (attribute style)
1861             (setq element (pop attribute)
1862                   filep nil)
1863             (setq value
1864                   (cond
1865                    ((eq (car attribute) :file)
1866                     (setq filep t)
1867                     (cadr attribute))
1868                    ((eq (car attribute) :value)
1869                     (cadr attribute))
1870                    (t
1871                     (car attribute))))
1872             ;; We get the value.
1873             (setq v
1874                   (cond
1875                    ((stringp value)
1876                     (if (and (stringp match)
1877                              (gnus-string-match-p "\\\\[&[:digit:]]" value)
1878                              (match-beginning 1))
1879                         (gnus-match-substitute-replacement value nil nil group)
1880                       value))
1881                    ((or (symbolp value)
1882                         (functionp value))
1883                     (cond ((functionp value)
1884                            (funcall value))
1885                           ((boundp value)
1886                            (symbol-value value))))
1887                    ((listp value)
1888                     (eval value))))
1889             ;; Translate obsolescent value.
1890             (cond
1891              ((eq element 'signature-file)
1892               (setq element 'signature
1893                     filep t))
1894              ((eq element 'x-face-file)
1895               (setq element 'x-face
1896                     filep t)))
1897             ;; Post-processing for the signature posting-style:
1898             (and (eq element 'signature) filep
1899                  message-signature-directory
1900                  ;; don't actually use the signature directory
1901                  ;; if message-signature-file contains a path.
1902                  (not (file-name-directory v))
1903                  (setq v (nnheader-concat message-signature-directory v)))
1904             ;; Get the contents of file elems.
1905             (when (and filep v)
1906               (setq v (with-temp-buffer
1907                         (insert-file-contents v)
1908                         (buffer-substring
1909                          (point-min)
1910                          (progn
1911                            (goto-char (point-max))
1912                            (if (zerop (skip-chars-backward "\n"))
1913                                (point)
1914                              (1+ (point))))))))
1915             (setq results (delq (assoc element results) results))
1916             (push (cons element v) results))))
1917       ;; Now we have all the styles, so we insert them.
1918       (setq name (assq 'name results)
1919             address (assq 'address results))
1920       (setq results (delq name (delq address results)))
1921       (gnus-make-local-hook 'message-setup-hook)
1922       (setq results (sort results (lambda (x y)
1923                                     (string-lessp (car x) (car y)))))
1924       (dolist (result results)
1925         (add-hook 'message-setup-hook
1926                   (cond
1927                    ((eq 'eval (car result))
1928                     'ignore)
1929                    ((eq 'body (car result))
1930                     `(lambda ()
1931                        (save-excursion
1932                          (message-goto-body)
1933                          (insert ,(cdr result)))))
1934                    ((eq 'signature (car result))
1935                     (set (make-local-variable 'message-signature) nil)
1936                     (set (make-local-variable 'message-signature-file) nil)
1937                     (if (not (cdr result))
1938                         'ignore
1939                       `(lambda ()
1940                          (save-excursion
1941                            (let ((message-signature ,(cdr result)))
1942                              (when message-signature
1943                                (message-insert-signature)))))))
1944                    (t
1945                     (let ((header
1946                            (if (symbolp (car result))
1947                                (capitalize (symbol-name (car result)))
1948                              (car result))))
1949                       `(lambda ()
1950                          (save-excursion
1951                            (message-remove-header ,header)
1952                            (let ((value ,(cdr result)))
1953                              (when value
1954                                (message-goto-eoh)
1955                                (insert ,header ": " value)
1956                                (unless (bolp)
1957                                  (insert "\n")))))))))
1958                   nil 'local))
1959       (when (or name address)
1960         (add-hook 'message-setup-hook
1961                   `(lambda ()
1962                      (set (make-local-variable 'user-mail-address)
1963                           ,(or (cdr address) user-mail-address))
1964                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1965                            (user-mail-address
1966                             ,(or (cdr address) user-mail-address)))
1967                        (save-excursion
1968                          (message-remove-header "From")
1969                          (message-goto-eoh)
1970                          (insert "From: " (message-make-from) "\n"))))
1971                   nil 'local)))))
1972
1973 ;;; Allow redefinition of functions.
1974
1975 (gnus-ems-redefine)
1976
1977 (provide 'gnus-msg)
1978
1979 ;;; gnus-msg.el ends here