cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-ems)
  34 (require 'message)
  35 (require 'gnus-art)
  36 (require 'gnus-util)
  37
  38 (defcustom gnus-post-method 'current
  39   "*Preferred method for posting USENET news.
  40
  41 If this variable is `current' (which is the default), Gnus will use
  42 the \"current\" select method when posting.  If it is `native', Gnus
  43 will use the native select method when posting.
  44
  45 This method will not be used in mail groups and the like, only in
  46 \"real\" newsgroups.
  47
  48 If not `native' nor `current', the value must be a valid method as discussed
  49 in the documentation of `gnus-select-method'.  It can also be a list of
  50 methods.  If that is the case, the user will be queried for what select
  51 method to use when posting."
  52   :group 'gnus-group-foreign
  53   :link '(custom-manual "(gnus)Posting Server")
  54   :type `(choice (const native)
  55                  (const current)
  56                  (sexp :tag "Methods" ,gnus-select-method)))
  57
  58 (defcustom gnus-outgoing-message-group nil
  59   "*All outgoing messages will be put in this group.
  60 If you want to store all your outgoing mail and articles in the group
  61 \"nnml:archive\", you set this variable to that value.  This variable
  62 can also be a list of group names.
  63
  64 If you want to have greater control over what group to put each
  65 message in, you can set this variable to a function that checks the
  66 current newsgroup name and then returns a suitable group name (or list
  67 of names)."
  68   :group 'gnus-message
  69   :type '(choice (string :tag "Group")
  70                  (function)))
  71
  72 (defcustom gnus-mailing-list-groups nil
  73   "*If non-nil a regexp matching groups that are really mailing lists.
  74 This is useful when you're reading a mailing list that has been
  75 gatewayed to a newsgroup, and you want to followup to an article in
  76 the group."
  77   :group 'gnus-message
  78   :type '(choice (regexp)
  79                  (const nil)))
  80
  81 (defcustom gnus-add-to-list nil
  82   "*If non-nil, add a `to-list' parameter automatically."
  83   :group 'gnus-message
  84   :type 'boolean)
  85
  86 (defcustom gnus-crosspost-complaint
  87   "Hi,
  88
  89 You posted the article below with the following Newsgroups header:
  90
  91 Newsgroups: %s
  92
  93 The %s group, at least, was an inappropriate recipient
  94 of this message.  Please trim your Newsgroups header to exclude this
  95 group before posting in the future.
  96
  97 Thank you.
  98
  99 "
 100   "Format string to be inserted when complaining about crossposts.
 101 The first %s will be replaced by the Newsgroups header;
 102 the second with the current group name."
 103   :group 'gnus-message
 104   :type 'string)
 105
 106 (defcustom gnus-message-setup-hook nil
 107   "Hook run after setting up a message buffer."
 108   :group 'gnus-message
 109   :type 'hook)
 110
 111 (defcustom gnus-bug-create-help-buffer t
 112   "*Should we create the *Gnus Help Bug* buffer?"
 113   :group 'gnus-message
 114   :type 'boolean)
 115
 116 (defcustom gnus-posting-styles nil
 117   "*Alist of styles to use when posting.
 118 See Info node `(gnus)Posting Styles'."
 119   :group 'gnus-message
 120   :link '(custom-manual "(gnus)Posting Styles")
 121   :type '(repeat (cons (choice (regexp)
 122                                (variable)
 123                                (list (const header)
 124                                      (string :tag "Header")
 125                                      (regexp :tag "Regexp"))
 126                                (function)
 127                                (sexp))
 128                        (repeat (list
 129                                 (choice (const signature)
 130                                         (const signature-file)
 131                                         (const organization)
 132                                         (const address)
 133                                         (const x-face-file)
 134                                         (const name)
 135                                         (const body)
 136                                         (symbol)
 137                                         (string :tag "Header"))
 138                                 (choice (string)
 139                                         (function)
 140                                         (variable)
 141                                         (sexp)))))))
 142
 143 (defcustom gnus-gcc-mark-as-read nil
 144   "If non-nil, automatically mark Gcc articles as read."
 145   :version "21.4"
 146   :group 'gnus-message
 147   :type 'boolean)
 148
 149 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 150                         'gnus-gcc-mark-as-read)
 151
 152 (defcustom gnus-gcc-externalize-attachments nil
 153   "Should local-file attachments be included as external parts in Gcc copies?
 154 If it is `all', attach files as external parts;
 155 if a regexp and matches the Gcc group name, attach files as external parts;
 156 if nil, attach files as normal parts."
 157   :version "21.4"
 158   :group 'gnus-message
 159   :type '(choice (const nil :tag "None")
 160                  (const all :tag "Any")
 161                  (string :tag "Regexp")))
 162
 163 (gnus-define-group-parameter
 164  posting-charset-alist
 165  :type list
 166  :function-document
 167  "Return the permitted unencoded charsets for posting of GROUP."
 168  :variable gnus-group-posting-charset-alist
 169  :variable-default
 170   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 171     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 172     (message-this-is-mail nil nil)
 173     (message-this-is-news nil t))
 174  :variable-document
 175   "Alist of regexps and permitted unencoded charsets for posting.
 176 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 177 TEST is either a regular expression matching the newsgroup header or a
 178 variable to query,
 179 HEADER is the charset which may be left unencoded in the header (nil
 180 means encode all charsets),
 181 BODY-LIST is a list of charsets which may be encoded using 8bit
 182 content-transfer encoding in the body, or one of the special values
 183 nil (always encode using quoted-printable) or t (always use 8bit).
 184
 185 Note that any value other than nil for HEADER infringes some RFCs, so
 186 use this option with care."
 187  :variable-group gnus-charset
 188  :variable-type
 189  '(repeat (list :tag "Permitted unencoded charsets"
 190                 (choice :tag "Where"
 191                         (regexp :tag "Group")
 192                         (const :tag "Mail message" :value message-this-is-mail)
 193                         (const :tag "News article" :value message-this-is-news))
 194                 (choice :tag "Header"
 195                         (const :tag "None" nil)
 196                         (symbol :tag "Charset"))
 197                 (choice :tag "Body"
 198                         (const :tag "Any" :value t)
 199                         (const :tag "None" :value nil)
 200                         (repeat :tag "Charsets"
 201                                 (symbol :tag "Charset")))))
 202  :parameter-type '(choice :tag "Permitted unencoded charsets"
 203                           :value nil
 204                           (repeat (symbol)))
 205  :parameter-document       "\
 206 List of charsets that are permitted to be unencoded.")
 207
 208 (defcustom gnus-debug-files
 209   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 210     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 211     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 212     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 213     "mm-util.el" "mm-decode.el" "nnmail.el" "message.el")
 214   "Files whose variables will be reported in `gnus-bug'."
 215   :version "21.4"
 216   :group 'gnus-message
 217   :type '(repeat (string :tag "File")))
 218
 219 (defcustom gnus-debug-exclude-variables
 220   '(mm-mime-mule-charset-alist
 221     nnmail-split-fancy message-minibuffer-local-map)
 222   "Variables that should not be reported in `gnus-bug'."
 223   :version "21.4"
 224   :group 'gnus-message
 225   :type '(repeat (symbol :tag "Variable")))
 226
 227 (defcustom gnus-discouraged-post-methods
 228   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 229   "A list of back ends that are not used in \"real\" newsgroups.
 230 This variable is used only when `gnus-post-method' is `current'."
 231   :version "21.4"
 232   :group 'gnus-group-foreign
 233   :type '(repeat (symbol :tag "Back end")))
 234
 235 (defcustom gnus-message-replysign
 236   nil
 237   "Automatically sign replies to signed messages.
 238 See also the `mml-default-sign-method' variable."
 239   :group 'gnus-message
 240   :type 'boolean)
 241
 242 (defcustom gnus-message-replyencrypt
 243   nil
 244   "Automatically encrypt replies to encrypted messages.
 245 See also the `mml-default-encrypt-method' variable."
 246   :group 'gnus-message
 247   :type 'boolean)
 248
 249 (defcustom gnus-message-replysignencrypted
 250   t
 251   "Setting this causes automatically encrypted messages to also be signed."
 252   :group 'gnus-message
 253   :type 'boolean)
 254
 255 (defcustom gnus-confirm-mail-reply-to-news nil
 256   "If non-nil, Gnus requests confirmation when replying to news.
 257 This is done because new users often reply by mistake when reading
 258 news.
 259 This can also be a function receiving the group name as the only
 260 parameter which should return non-nil iff a confirmation is needed, or
 261 a regexp, in which case a confirmation is asked for iff the group name
 262 matches the regexp."
 263   :version "21.4"
 264   :group 'gnus-message
 265   :type '(choice (const :tag "No" nil)
 266                  (const :tag "Yes" t)
 267                  (regexp :tag "Iff group matches regexp")
 268                  (function :tag "Iff function evaluates to non-nil")))
 269
 270 (defcustom gnus-confirm-treat-mail-like-news
 271   nil
 272   "If non-nil, Gnus will treat mail like news with regard to confirmation
 273 when replying by mail.  See the `gnus-confirm-mail-reply-to-news' variable
 274 for fine-tuning this.
 275 If nil, Gnus will never ask for confirmation if replying to mail."
 276   :version "21.4"
 277   :group 'gnus-message
 278   :type 'boolean)
 279
 280 (defcustom gnus-summary-resend-default-address t
 281   "If non-nil, Gnus tries to suggest a default address to resend to.
 282 If nil, the address field will always be empty after invoking
 283 `gnus-summary-resend-message'."
 284   :version "21.4"
 285   :group 'gnus-message
 286   :type 'boolean)
 287
 288 ;;; Internal variables.
 289
 290 (defvar gnus-inhibit-posting-styles nil
 291   "Inhibit the use of posting styles.")
 292
 293 (defvar gnus-article-yanked-articles nil)
 294 (defvar gnus-message-buffer "*Mail Gnus*")
 295 (defvar gnus-article-copy nil)
 296 (defvar gnus-check-before-posting nil)
 297 (defvar gnus-last-posting-server nil)
 298 (defvar gnus-message-group-art nil)
 299
 300 (defvar gnus-msg-force-broken-reply-to nil)
 301
 302 (defconst gnus-bug-message
 303   "Sending a bug report to the Gnus Towers.
 304 ========================================
 305
 306 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 307 be sent to the Gnus Bug Exterminators.
 308
 309 The thing near the bottom of the buffer is how the environment
 310 settings will be included in the mail.  Please do not delete that.
 311 They will tell the Bug People what your environment is, so that it
 312 will be easier to locate the bugs.
 313
 314 If you have found a bug that makes Emacs go \"beep\", set
 315 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 316 and include the backtrace in your bug report.
 317
 318 Please describe the bug in annoying, painstaking detail.
 319
 320 Thank you for your help in stamping out bugs.
 321 ")
 322
 323 (eval-and-compile
 324   (autoload 'gnus-uu-post-news "gnus-uu" nil t))
 325
 326 \f
 327 ;;;
 328 ;;; Gnus Posting Functions
 329 ;;;
 330
 331 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 332   "p" gnus-summary-post-news
 333   "i" gnus-summary-news-other-window
 334   "f" gnus-summary-followup
 335   "F" gnus-summary-followup-with-original
 336   "c" gnus-summary-cancel-article
 337   "s" gnus-summary-supersede-article
 338   "r" gnus-summary-reply
 339   "y" gnus-summary-yank-message
 340   "R" gnus-summary-reply-with-original
 341   "w" gnus-summary-wide-reply
 342   "W" gnus-summary-wide-reply-with-original
 343   "v" gnus-summary-very-wide-reply
 344   "V" gnus-summary-very-wide-reply-with-original
 345   "n" gnus-summary-followup-to-mail
 346   "N" gnus-summary-followup-to-mail-with-original
 347   "m" gnus-summary-mail-other-window
 348   "u" gnus-uu-post-news
 349   "\M-c" gnus-summary-mail-crosspost-complaint
 350   "Br" gnus-summary-reply-broken-reply-to
 351   "BR" gnus-summary-reply-broken-reply-to-with-original
 352   "om" gnus-summary-mail-forward
 353   "op" gnus-summary-post-forward
 354   "Om" gnus-uu-digest-mail-forward
 355   "Op" gnus-uu-digest-post-forward)
 356
 357 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 358   "b" gnus-summary-resend-bounced-mail
 359   ;; "c" gnus-summary-send-draft
 360   "r" gnus-summary-resend-message
 361   "e" gnus-summary-resend-message-edit)
 362
 363 ;;; Internal functions.
 364
 365 (defun gnus-inews-make-draft (articles)
 366   `(lambda ()
 367      (gnus-inews-make-draft-meta-information
 368       ,gnus-newsgroup-name ',articles)))
 369
 370 (defvar gnus-article-reply nil)
 371 (defmacro gnus-setup-message (config &rest forms)
 372   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 373         (buffer (make-symbol "gnus-setup-message-buffer"))
 374         (article (make-symbol "gnus-setup-message-article"))
 375         (yanked (make-symbol "gnus-setup-yanked-articles"))
 376         (group (make-symbol "gnus-setup-message-group")))
 377     `(let ((,winconf (current-window-configuration))
 378            (,buffer (buffer-name (current-buffer)))
 379            (,article gnus-article-reply)
 380            (,yanked gnus-article-yanked-articles)
 381            (,group gnus-newsgroup-name)
 382            (message-header-setup-hook
 383             (copy-sequence message-header-setup-hook))
 384            (mbl mml-buffer-list)
 385            (message-mode-hook (copy-sequence message-mode-hook)))
 386        (setq mml-buffer-list nil)
 387        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 388        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 389        ;; #### FIXME: for a reason that I did not manage to identify yet,
 390        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 391        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 392        ;; After evaluation of @forms below, it gets the value we actually want
 393        ;; to override, and the posting styles are used. For that reason, I've
 394        ;; added an optional argument to `gnus-configure-posting-styles' to
 395        ;; make sure that the correct value for the group name is used. -- drv
 396        (add-hook 'message-mode-hook
 397                  (if (memq ,config '(reply-yank reply))
 398                      (lambda ()
 399                        (gnus-configure-posting-styles ,group))
 400                    (lambda ()
 401                      ;; There may be an old " *gnus article copy*" buffer.
 402                      (let (gnus-article-copy)
 403                        (gnus-configure-posting-styles ,group)))))
 404        (gnus-pull ',(intern gnus-draft-meta-information-header)
 405                   message-required-headers)
 406        (when (and ,group
 407                   (not (string= ,group "")))
 408          (push (cons
 409                 (intern gnus-draft-meta-information-header)
 410                 (gnus-inews-make-draft (or ,yanked ,article)))
 411                message-required-headers))
 412        (unwind-protect
 413            (progn
 414              ,@forms)
 415          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 416                                       ,yanked)
 417          (setq gnus-message-buffer (current-buffer))
 418          (set (make-local-variable 'gnus-message-group-art)
 419               (cons ,group ,article))
 420          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 421          (gnus-run-hooks 'gnus-message-setup-hook)
 422          (if (eq major-mode 'message-mode)
 423              (let ((mbl1 mml-buffer-list))
 424                (setq mml-buffer-list mbl)  ;; Global value
 425                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 426                (gnus-make-local-hook 'kill-buffer-hook)
 427                (gnus-make-local-hook 'change-major-mode-hook)
 428                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 429                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 430            (mml-destroy-buffers)
 431            (setq mml-buffer-list mbl)))
 432        (message-hide-headers)
 433        (gnus-add-buffer)
 434        (gnus-configure-windows ,config t)
 435        (run-hooks 'post-command-hook)
 436        (set-buffer-modified-p nil))))
 437
 438 (defun gnus-inews-make-draft-meta-information (group articles)
 439   (when (numberp articles)
 440     (setq articles (list articles)))
 441   (concat "(\"" group "\""
 442           (if articles
 443               (concat " "
 444                       (mapconcat
 445                        (lambda (elem)
 446                          (number-to-string
 447                           (if (consp elem)
 448                               (car elem)
 449                             elem)))
 450                        articles " "))
 451             "")
 452           ")"))
 453
 454 ;;;###autoload
 455 (defun gnus-msg-mail (&optional to subject other-headers continue
 456                                 switch-action yank-action send-actions)
 457   "Start editing a mail message to be sent.
 458 Like `message-mail', but with Gnus paraphernalia, particularly the
 459 Gcc: header for archiving purposes."
 460   (interactive)
 461   (let ((buf (current-buffer))
 462         mail-buf)
 463     (gnus-setup-message 'message
 464       (message-mail to subject other-headers continue
 465                     nil yank-action send-actions))
 466     (when switch-action
 467       (setq mail-buf (current-buffer))
 468       (switch-to-buffer buf)
 469       (apply switch-action mail-buf nil)))
 470   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 471   t)
 472
 473 (defvar save-selected-window-window)
 474
 475 ;;;###autoload
 476 (defun gnus-button-mailto (address)
 477   "Mail to ADDRESS."
 478   (set-buffer (gnus-copy-article-buffer))
 479   (gnus-setup-message 'message
 480     (message-reply address))
 481   (and (boundp 'save-selected-window-window)
 482        (not (window-live-p save-selected-window-window))
 483        (setq save-selected-window-window (selected-window))))
 484
 485 ;;;###autoload
 486 (defun gnus-button-reply (&optional to-address wide)
 487   "Like `message-reply'."
 488   (interactive)
 489   (gnus-setup-message 'message
 490     (message-reply to-address wide))
 491   (and (boundp 'save-selected-window-window)
 492        (not (window-live-p save-selected-window-window))
 493        (setq save-selected-window-window (selected-window))))
 494
 495 ;;;###autoload
 496 (define-mail-user-agent 'gnus-user-agent
 497   'gnus-msg-mail 'message-send-and-exit
 498   'message-kill-buffer 'message-send-hook)
 499
 500 (defun gnus-setup-posting-charset (group)
 501   (let ((alist gnus-group-posting-charset-alist)
 502         (group (or group ""))
 503         elem)
 504     (when group
 505       (catch 'found
 506         (while (setq elem (pop alist))
 507           (when (or (and (stringp (car elem))
 508                          (string-match (car elem) group))
 509                     (and (functionp (car elem))
 510                          (funcall (car elem) group))
 511                     (and (symbolp (car elem))
 512                          (symbol-value (car elem))))
 513             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 514
 515 (defun gnus-inews-add-send-actions (winconf buffer article
 516                                             &optional config yanked)
 517   (gnus-make-local-hook 'message-sent-hook)
 518   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 519                                  'gnus-inews-do-gcc) nil t)
 520   (when gnus-agent
 521     (gnus-make-local-hook 'message-header-hook)
 522     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 523   (setq message-post-method
 524         `(lambda (arg)
 525            (gnus-post-method arg ,gnus-newsgroup-name)))
 526   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 527   (message-add-action
 528    `(when (gnus-buffer-exists-p ,buffer)
 529       (set-window-configuration ,winconf))
 530    'exit 'postpone 'kill)
 531   (let ((to-be-marked (cond
 532                        (yanked
 533                         (mapcar
 534                          (lambda (x) (if (listp x) (car x) x)) yanked))
 535                        (article (if (listp article) article (list article)))
 536                        (t nil))))
 537     (message-add-action
 538      `(when (gnus-buffer-exists-p ,buffer)
 539         (save-excursion
 540           (set-buffer ,buffer)
 541           ,(when to-be-marked
 542              (if (eq config 'forward)
 543                  `(gnus-summary-mark-article-as-forwarded ',to-be-marked)
 544                `(gnus-summary-mark-article-as-replied ',to-be-marked)))))
 545      'send)))
 546
 547 (put 'gnus-setup-message 'lisp-indent-function 1)
 548 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 549
 550 ;;; Post news commands of Gnus group mode and summary mode
 551
 552 (defun gnus-group-mail (&optional arg)
 553   "Start composing a mail.
 554 If ARG, use the group under the point to find a posting style.
 555 If ARG is 1, prompt for a group name to find the posting style."
 556   (interactive "P")
 557   ;; We can't `let' gnus-newsgroup-name here, since that leads
 558   ;; to local variables leaking.
 559   (let ((group gnus-newsgroup-name)
 560         ;; make sure last viewed article doesn't affect posting styles:
 561         (gnus-article-copy)
 562         (buffer (current-buffer)))
 563     (unwind-protect
 564         (progn
 565           (setq gnus-newsgroup-name
 566                 (if arg
 567                     (if (= 1 (prefix-numeric-value arg))
 568                         (completing-read "Use posting style of group: "
 569                                          gnus-active-hashtb nil
 570                                          (gnus-read-active-file-p))
 571                       (gnus-group-group-name))
 572                   ""))
 573           ;; #### see comment in gnus-setup-message -- drv
 574           (gnus-setup-message 'message (message-mail)))
 575       (save-excursion
 576         (set-buffer buffer)
 577         (setq gnus-newsgroup-name group)))))
 578
 579 (defun gnus-group-news (&optional arg)
 580   "Start composing a news.
 581 If ARG, post to group under point.
 582 If ARG is 1, prompt for group name to post to.
 583
 584 This function prepares a news even when using mail groups.  This is useful
 585 for posting messages to mail groups without actually sending them over the
 586 network.  The corresponding back end must have a 'request-post method."
 587   (interactive "P")
 588   ;; We can't `let' gnus-newsgroup-name here, since that leads
 589   ;; to local variables leaking.
 590   (let ((group gnus-newsgroup-name)
 591         ;; make sure last viewed article doesn't affect posting styles:
 592         (gnus-article-copy)
 593         (buffer (current-buffer)))
 594     (unwind-protect
 595         (progn
 596           (setq gnus-newsgroup-name
 597                 (if arg
 598                     (if (= 1 (prefix-numeric-value arg))
 599                         (completing-read "Use group: "
 600                                          gnus-active-hashtb nil
 601                                          (gnus-read-active-file-p))
 602                       (gnus-group-group-name))
 603                   ""))
 604           ;; #### see comment in gnus-setup-message -- drv
 605           (gnus-setup-message 'message
 606             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 607       (save-excursion
 608         (set-buffer buffer)
 609         (setq gnus-newsgroup-name group)))))
 610
 611 (defun gnus-group-post-news (&optional arg)
 612   "Start composing a message (a news by default).
 613 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 614 Depending on the selected group, the message might be either a mail or
 615 a news."
 616   (interactive "P")
 617   ;; Bind this variable here to make message mode hooks work ok.
 618   (let ((gnus-newsgroup-name
 619          (if arg
 620              (if (= 1 (prefix-numeric-value arg))
 621                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 622                                   (gnus-read-active-file-p))
 623                (gnus-group-group-name))
 624            ""))
 625         ;; make sure last viewed article doesn't affect posting styles:
 626         (gnus-article-copy))
 627     (gnus-post-news 'post gnus-newsgroup-name nil nil nil nil
 628                     (string= gnus-newsgroup-name ""))))
 629
 630 (defun gnus-summary-mail-other-window (&optional arg)
 631   "Start composing a mail in another window.
 632 Use the posting of the current group by default.
 633 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 634 posting style."
 635   (interactive "P")
 636   ;; We can't `let' gnus-newsgroup-name here, since that leads
 637   ;; to local variables leaking.
 638   (let ((group gnus-newsgroup-name)
 639         ;; make sure last viewed article doesn't affect posting styles:
 640         (gnus-article-copy)
 641         (buffer (current-buffer)))
 642     (unwind-protect
 643         (progn
 644           (setq gnus-newsgroup-name
 645                 (if arg
 646                     (if (= 1 (prefix-numeric-value arg))
 647                         (completing-read "Use group: "
 648                                          gnus-active-hashtb nil
 649                                          (gnus-read-active-file-p))
 650                       "")
 651                   gnus-newsgroup-name))
 652           ;; #### see comment in gnus-setup-message -- drv
 653           (gnus-setup-message 'message (message-mail)))
 654       (save-excursion
 655         (set-buffer buffer)
 656         (setq gnus-newsgroup-name group)))))
 657
 658 (defun gnus-summary-news-other-window (&optional arg)
 659   "Start composing a news in another window.
 660 Post to the current group by default.
 661 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 662
 663 This function prepares a news even when using mail groups.  This is useful
 664 for posting messages to mail groups without actually sending them over the
 665 network.  The corresponding back end must have a 'request-post method."
 666   (interactive "P")
 667   ;; We can't `let' gnus-newsgroup-name here, since that leads
 668   ;; to local variables leaking.
 669   (let ((group gnus-newsgroup-name)
 670         ;; make sure last viewed article doesn't affect posting styles:
 671         (gnus-article-copy)
 672         (buffer (current-buffer)))
 673     (unwind-protect
 674         (progn
 675           (setq gnus-newsgroup-name
 676                 (if arg
 677                     (if (= 1 (prefix-numeric-value arg))
 678                         (completing-read "Use group: "
 679                                          gnus-active-hashtb nil
 680                                          (gnus-read-active-file-p))
 681                       "")
 682                   gnus-newsgroup-name))
 683           ;; #### see comment in gnus-setup-message -- drv
 684           (gnus-setup-message 'message
 685             (progn
 686               (message-news (gnus-group-real-name gnus-newsgroup-name))
 687               (set (make-local-variable 'gnus-discouraged-post-methods)
 688                    (remove
 689                     (car (gnus-find-method-for-group gnus-newsgroup-name))
 690                     gnus-discouraged-post-methods)))))
 691       (save-excursion
 692         (set-buffer buffer)
 693         (setq gnus-newsgroup-name group)))))
 694
 695 (defun gnus-summary-post-news (&optional arg)
 696   "Start composing a message.  Post to the current group by default.
 697 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 698 Depending on the selected group, the message might be either a mail or
 699 a news."
 700   (interactive "P")
 701   ;; Bind this variable here to make message mode hooks work ok.
 702   (let ((gnus-newsgroup-name
 703          (if arg
 704              (if (= 1 (prefix-numeric-value arg))
 705                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 706                                   (gnus-read-active-file-p))
 707                "")
 708            gnus-newsgroup-name))
 709         ;; make sure last viewed article doesn't affect posting styles:
 710         (gnus-article-copy))
 711     (gnus-post-news 'post gnus-newsgroup-name)))
 712
 713
 714 (defun gnus-summary-followup (yank &optional force-news)
 715   "Compose a followup to an article.
 716 If prefix argument YANK is non-nil, the original article is yanked
 717 automatically.
 718 YANK is a list of elements, where the car of each element is the
 719 article number, and the cdr is the string to be yanked."
 720   (interactive
 721    (list (and current-prefix-arg
 722               (gnus-summary-work-articles 1))))
 723   (when yank
 724     (gnus-summary-goto-subject
 725      (if (listp (car yank))
 726          (caar yank)
 727        (car yank))))
 728   (save-window-excursion
 729     (gnus-summary-select-article))
 730   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 731         (gnus-newsgroup-name gnus-newsgroup-name))
 732     ;; Send a followup.
 733     (gnus-post-news nil gnus-newsgroup-name
 734                     headers gnus-article-buffer
 735                     yank nil force-news)
 736     (gnus-summary-handle-replysign)))
 737
 738 (defun gnus-summary-followup-with-original (n &optional force-news)
 739   "Compose a followup to an article and include the original article.
 740 The text in the region will be yanked.  If the region isn't
 741 active, the entire article will be yanked."
 742   (interactive "P")
 743   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 744
 745 (defun gnus-summary-followup-to-mail (&optional arg)
 746   "Followup to the current mail message via news."
 747   (interactive
 748    (list (and current-prefix-arg
 749               (gnus-summary-work-articles 1))))
 750   (gnus-summary-followup arg t))
 751
 752 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 753   "Followup to the current mail message via news."
 754   (interactive "P")
 755   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 756
 757 (defun gnus-inews-yank-articles (articles)
 758   (let (beg article yank-string)
 759     (message-goto-body)
 760     (while (setq article (pop articles))
 761       (when (listp article)
 762         (setq yank-string (nth 1 article)
 763               article (nth 0 article)))
 764       (save-window-excursion
 765         (set-buffer gnus-summary-buffer)
 766         (gnus-summary-select-article nil nil nil article)
 767         (gnus-summary-remove-process-mark article))
 768       (gnus-copy-article-buffer nil yank-string)
 769       (let ((message-reply-buffer gnus-article-copy)
 770             (message-reply-headers
 771              ;; The headers are decoded.
 772              (with-current-buffer gnus-article-copy
 773                (save-restriction
 774                  (nnheader-narrow-to-headers)
 775                  (nnheader-parse-naked-head)))))
 776         (message-yank-original)
 777         (setq beg (or beg (mark t))))
 778       (when articles
 779         (insert "\n")))
 780     (push-mark)
 781     (goto-char beg)))
 782
 783 (defun gnus-summary-cancel-article (&optional n symp)
 784   "Cancel an article you posted.
 785 Uses the process-prefix convention.  If given the symbolic
 786 prefix `a', cancel using the standard posting method; if not
 787 post using the current select method."
 788   (interactive (gnus-interactive "P\ny"))
 789   (let ((message-post-method
 790          `(lambda (arg)
 791             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name))))
 792     (dolist (article (gnus-summary-work-articles n))
 793       (when (gnus-summary-select-article t nil nil article)
 794         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 795                 (message-cancel-news))
 796           (gnus-summary-mark-as-read article gnus-canceled-mark)
 797           (gnus-cache-remove-article 1))
 798         (gnus-article-hide-headers-if-wanted))
 799       (gnus-summary-remove-process-mark article))))
 800
 801 (defun gnus-summary-supersede-article ()
 802   "Compose an article that will supersede a previous article.
 803 This is done simply by taking the old article and adding a Supersedes
 804 header line with the old Message-ID."
 805   (interactive)
 806   (let ((article (gnus-summary-article-number)))
 807     (gnus-setup-message 'reply-yank
 808       (gnus-summary-select-article t)
 809       (set-buffer gnus-original-article-buffer)
 810       (message-supersede)
 811       (push
 812        `((lambda ()
 813            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 814              (save-excursion
 815                (set-buffer ,gnus-summary-buffer)
 816                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 817                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 818        message-send-actions))))
 819
 820 \f
 821
 822 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 823   ;; make a copy of the article buffer with all text properties removed
 824   ;; this copy is in the buffer gnus-article-copy.
 825   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 826   ;; this buffer should be passed to all mail/news reply/post routines.
 827   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 828   (save-excursion
 829     (set-buffer gnus-article-copy)
 830     (mm-enable-multibyte))
 831   (let ((article-buffer (or article-buffer gnus-article-buffer))
 832         end beg)
 833     (if (not (and (get-buffer article-buffer)
 834                   (gnus-buffer-exists-p article-buffer)))
 835         (error "Can't find any article buffer")
 836       (save-excursion
 837         (set-buffer article-buffer)
 838         (let ((gnus-newsgroup-charset (or gnus-article-charset
 839                                           gnus-newsgroup-charset))
 840               (gnus-newsgroup-ignored-charsets
 841                (or gnus-article-ignored-charsets
 842                    gnus-newsgroup-ignored-charsets)))
 843           (save-restriction
 844             ;; Copy over the (displayed) article buffer, delete
 845             ;; hidden text and remove text properties.
 846             (widen)
 847             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 848             (set-buffer gnus-article-copy)
 849             (when yank-string
 850               (message-goto-body)
 851               (delete-region (point) (point-max))
 852               (insert yank-string))
 853             (gnus-article-delete-text-of-type 'annotation)
 854             (gnus-remove-text-with-property 'gnus-prev)
 855             (gnus-remove-text-with-property 'gnus-next)
 856             (gnus-remove-text-with-property 'gnus-decoration)
 857             (insert
 858              (prog1
 859                  (buffer-substring-no-properties (point-min) (point-max))
 860                (erase-buffer)))
 861             ;; Find the original headers.
 862             (set-buffer gnus-original-article-buffer)
 863             (goto-char (point-min))
 864             (while (looking-at message-unix-mail-delimiter)
 865               (forward-line 1))
 866             (let ((mail-header-separator ""))
 867               (setq beg (point)
 868                     end (or (message-goto-body)
 869                             ;; There may be just a header.
 870                             (point-max))))
 871             ;; Delete the headers from the displayed articles.
 872             (set-buffer gnus-article-copy)
 873             (let ((mail-header-separator ""))
 874               (delete-region (goto-char (point-min))
 875                              (or (message-goto-body) (point-max))))
 876             ;; Insert the original article headers.
 877             (insert-buffer-substring gnus-original-article-buffer beg end)
 878             ;; Decode charsets.
 879             (let ((gnus-article-decode-hook
 880                    (delq 'article-decode-charset
 881                          (copy-sequence gnus-article-decode-hook))))
 882               (run-hooks 'gnus-article-decode-hook)))))
 883       gnus-article-copy)))
 884
 885 (defun gnus-post-news (post &optional group header article-buffer yank subject
 886                             force-news)
 887   (when article-buffer
 888     (gnus-copy-article-buffer))
 889   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 890         (gnus-article-yanked-articles yank)
 891         (add-to-list gnus-add-to-list))
 892     (gnus-setup-message (cond (yank 'reply-yank)
 893                               (article-buffer 'reply)
 894                               (t 'message))
 895       (let* ((group (or group gnus-newsgroup-name))
 896              (charset (gnus-group-name-charset nil group))
 897              (pgroup group)
 898              to-address to-group mailing-list to-list
 899              newsgroup-p)
 900         (when group
 901           (setq to-address (gnus-parameter-to-address group)
 902                 to-group (gnus-group-find-parameter group 'to-group)
 903                 to-list (gnus-parameter-to-list group)
 904                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 905                 mailing-list (when gnus-mailing-list-groups
 906                                (string-match gnus-mailing-list-groups group))
 907                 group (gnus-group-name-decode (gnus-group-real-name group)
 908                                               charset)))
 909         (if (or (and to-group
 910                      (gnus-news-group-p to-group))
 911                 newsgroup-p
 912                 force-news
 913                 (and (gnus-news-group-p
 914                       (or pgroup gnus-newsgroup-name)
 915                       (or header gnus-current-article))
 916                      (not mailing-list)
 917                      (not to-list)
 918                      (not to-address)))
 919             ;; This is news.
 920             (if post
 921                 (message-news
 922                  (or to-group
 923                      (and (not (gnus-virtual-group-p pgroup)) group)))
 924               (set-buffer gnus-article-copy)
 925               (gnus-msg-treat-broken-reply-to)
 926               (message-followup (if (or newsgroup-p force-news)
 927                                     (if (save-restriction
 928                                           (article-narrow-to-head)
 929                                           (message-fetch-field "newsgroups"))
 930                                         nil
 931                                       "")
 932                                   to-group)))
 933           ;; The is mail.
 934           (if post
 935               (progn
 936                 (message-mail (or to-address to-list))
 937                 ;; Arrange for mail groups that have no `to-address' to
 938                 ;; get that when the user sends off the mail.
 939                 (when (and (not to-list)
 940                            (not to-address)
 941                            add-to-list)
 942                   (push (list 'gnus-inews-add-to-address pgroup)
 943                         message-send-actions)))
 944             (set-buffer gnus-article-copy)
 945             (gnus-msg-treat-broken-reply-to)
 946             (message-wide-reply to-address)))
 947         (when yank
 948           (gnus-inews-yank-articles yank))))))
 949
 950 (defun gnus-msg-treat-broken-reply-to (&optional force)
 951   "Remove the Reply-to header if broken-reply-to."
 952   (when (or force
 953             (gnus-group-find-parameter
 954              gnus-newsgroup-name 'broken-reply-to))
 955     (save-restriction
 956       (message-narrow-to-head)
 957       (message-remove-header "reply-to"))))
 958
 959 (defun gnus-post-method (arg group &optional silent)
 960   "Return the posting method based on GROUP and ARG.
 961 If SILENT, don't prompt the user."
 962   (let ((gnus-post-method (or (gnus-parameter-post-method group)
 963                               gnus-post-method))
 964         (group-method (gnus-find-method-for-group group)))
 965     (cond
 966      ;; If the group-method is nil (which shouldn't happen) we use
 967      ;; the default method.
 968      ((null group-method)
 969       (or (and (listp gnus-post-method) ;If not current/native/nil
 970                (not (listp (car gnus-post-method))) ; and not a list of methods
 971                gnus-post-method)        ;then use it.
 972           gnus-select-method
 973           message-post-method))
 974      ;; We want the inverse of the default
 975      ((and arg (not (eq arg 0)))
 976       (if (eq gnus-post-method 'current)
 977           gnus-select-method
 978         group-method))
 979      ;; We query the user for a post method.
 980      ((or arg
 981           (and (listp gnus-post-method)
 982                (listp (car gnus-post-method))))
 983       (let* ((methods
 984               ;; Collect all methods we know about.
 985               (append
 986                (when (listp gnus-post-method)
 987                  (if (listp (car gnus-post-method))
 988                      gnus-post-method
 989                    (list gnus-post-method)))
 990                gnus-secondary-select-methods
 991                (mapcar 'cdr gnus-server-alist)
 992                (mapcar 'car gnus-opened-servers)
 993                (list gnus-select-method)
 994                (list group-method)))
 995              method-alist post-methods method)
 996         ;; Weed out all mail methods.
 997         (while methods
 998           (setq method (gnus-server-get-method "" (pop methods)))
 999           (when (and (or (gnus-method-option-p method 'post)
1000                          (gnus-method-option-p method 'post-mail))
1001                      (not (member method post-methods)))
1002             (push method post-methods)))
1003         ;; Create a name-method alist.
1004         (setq method-alist
1005               (mapcar
1006                (lambda (m)
1007                  (if (equal (cadr m) "")
1008                      (list (symbol-name (car m)) m)
1009                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
1010                post-methods))
1011         ;; Query the user.
1012         (cadr
1013          (assoc
1014           (setq gnus-last-posting-server
1015                 (if (and silent
1016                          gnus-last-posting-server)
1017                     ;; Just use the last value.
1018                     gnus-last-posting-server
1019                   (completing-read
1020                    "Posting method: " method-alist nil t
1021                    (cons (or gnus-last-posting-server "") 0))))
1022           method-alist))))
1023      ;; Override normal method.
1024      ((and (eq gnus-post-method 'current)
1025            (not (memq (car group-method) gnus-discouraged-post-methods))
1026            (gnus-get-function group-method 'request-post t))
1027       (assert (not arg))
1028       group-method)
1029      ;; Use gnus-post-method.
1030      ((listp gnus-post-method)          ;A method...
1031       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
1032       gnus-post-method)
1033      ;; Use the normal select method (nil or native).
1034      (t gnus-select-method))))
1035
1036 \f
1037
1038 (defun gnus-extended-version ()
1039   "Stringified Gnus version and Emacs version.
1040 See the variable `gnus-user-agent'."
1041   (interactive)
1042   (let* ((float-output-format nil)
1043          (gnus-v
1044           (concat "Gnus/"
1045                   (prin1-to-string (gnus-continuum-version gnus-version) t)
1046                   " (" gnus-version ")"))
1047          (emacs-v (gnus-emacs-version)))
1048     (if (stringp gnus-user-agent)
1049         gnus-user-agent
1050       (concat gnus-v
1051               (when emacs-v
1052                 (concat " " emacs-v))))))
1053
1054 \f
1055 ;;;
1056 ;;; Gnus Mail Functions
1057 ;;;
1058
1059 ;;; Mail reply commands of Gnus summary mode
1060
1061 (defun gnus-summary-reply (&optional yank wide very-wide)
1062   "Start composing a mail reply to the current message.
1063 If prefix argument YANK is non-nil, the original article is yanked
1064 automatically.
1065 If WIDE, make a wide reply.
1066 If VERY-WIDE, make a very wide reply."
1067   (interactive
1068    (list (and current-prefix-arg
1069               (gnus-summary-work-articles 1))))
1070   ;; Allow user to require confirmation before replying by mail to the
1071   ;; author of a news article (or mail message).
1072   (when (or
1073             (not (or (gnus-news-group-p gnus-newsgroup-name)
1074                      gnus-confirm-treat-mail-like-news))
1075             (not (cond ((stringp gnus-confirm-mail-reply-to-news)
1076                         (string-match gnus-confirm-mail-reply-to-news
1077                                       gnus-newsgroup-name))
1078                        ((functionp gnus-confirm-mail-reply-to-news)
1079                         (funcall gnus-confirm-mail-reply-to-news gnus-newsgroup-name))
1080                        (t gnus-confirm-mail-reply-to-news)))
1081             (y-or-n-p "Really reply by mail to article author? "))
1082     (let* ((article
1083             (if (listp (car yank))
1084                 (caar yank)
1085               (car yank)))
1086            (gnus-article-reply (or article (gnus-summary-article-number)))
1087            (gnus-article-yanked-articles yank)
1088            (headers ""))
1089       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1090       (when yank
1091         (gnus-summary-goto-subject article))
1092       (gnus-setup-message (if yank 'reply-yank 'reply)
1093         (if (not very-wide)
1094             (gnus-summary-select-article)
1095           (dolist (article very-wide)
1096             (gnus-summary-select-article nil nil nil article)
1097             (save-excursion
1098               (set-buffer (gnus-copy-article-buffer))
1099               (gnus-msg-treat-broken-reply-to)
1100               (save-restriction
1101                 (message-narrow-to-head)
1102                 (setq headers (concat headers (buffer-string)))))))
1103         (set-buffer (gnus-copy-article-buffer))
1104         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1105         (save-restriction
1106           (message-narrow-to-head)
1107           (when very-wide
1108             (erase-buffer)
1109             (insert headers))
1110           (goto-char (point-max)))
1111         (mml-quote-region (point) (point-max))
1112         (message-reply nil wide)
1113         (when yank
1114           (gnus-inews-yank-articles yank))
1115         (gnus-summary-handle-replysign)))))
1116
1117 (defun gnus-summary-handle-replysign ()
1118   "Check the various replysign variables and take action accordingly."
1119   (when (or gnus-message-replysign gnus-message-replyencrypt)
1120     (let (signed encrypted)
1121       (save-excursion
1122         (set-buffer gnus-article-buffer)
1123         (setq signed (memq 'signed gnus-article-wash-types))
1124         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1125       (cond ((and gnus-message-replyencrypt encrypted)
1126              (mml-secure-message mml-default-encrypt-method
1127                                  (if gnus-message-replysignencrypted
1128                                      'signencrypt
1129                                    'encrypt)))
1130             ((and gnus-message-replysign signed)
1131              (mml-secure-message mml-default-sign-method 'sign))))))
1132
1133 (defun gnus-summary-reply-with-original (n &optional wide)
1134   "Start composing a reply mail to the current message.
1135 The original article will be yanked."
1136   (interactive "P")
1137   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1138
1139 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1140   "Like `gnus-summary-reply' except removing reply-to field.
1141 If prefix argument YANK is non-nil, the original article is yanked
1142 automatically.
1143 If WIDE, make a wide reply.
1144 If VERY-WIDE, make a very wide reply."
1145   (interactive
1146    (list (and current-prefix-arg
1147               (gnus-summary-work-articles 1))))
1148   (let ((gnus-msg-force-broken-reply-to t))
1149     (gnus-summary-reply yank wide very-wide)))
1150
1151 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1152   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1153 The original article will be yanked."
1154   (interactive "P")
1155   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1156
1157 (defun gnus-summary-wide-reply (&optional yank)
1158   "Start composing a wide reply mail to the current message.
1159 If prefix argument YANK is non-nil, the original article is yanked
1160 automatically."
1161   (interactive
1162    (list (and current-prefix-arg
1163               (gnus-summary-work-articles 1))))
1164   (gnus-summary-reply yank t))
1165
1166 (defun gnus-summary-wide-reply-with-original (n)
1167   "Start composing a wide reply mail to the current message.
1168 The original article will be yanked.
1169 Uses the process/prefix convention."
1170   (interactive "P")
1171   (gnus-summary-reply-with-original n t))
1172
1173 (defun gnus-summary-very-wide-reply (&optional yank)
1174   "Start composing a very wide reply mail to the current message.
1175 If prefix argument YANK is non-nil, the original article is yanked
1176 automatically."
1177   (interactive
1178    (list (and current-prefix-arg
1179               (gnus-summary-work-articles 1))))
1180   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1181
1182 (defun gnus-summary-very-wide-reply-with-original (n)
1183   "Start composing a very wide reply mail to the current message.
1184 The original article will be yanked."
1185   (interactive "P")
1186   (gnus-summary-reply
1187    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1188
1189 (defun gnus-summary-mail-forward (&optional arg post)
1190   "Forward the current message(s) to another user.
1191 If process marks exist, forward all marked messages;
1192 if ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
1193 if ARG is 1, decode the message and forward directly inline;
1194 if ARG is 2, forward message as an rfc822 MIME section;
1195 if ARG is 3, decode message and forward as an rfc822 MIME section;
1196 if ARG is 4, forward message directly inline;
1197 otherwise, use flipped `message-forward-as-mime'.
1198 If POST, post instead of mail.
1199 For the `inline' alternatives, also see the variable
1200 `message-forward-ignored-headers'."
1201   (interactive "P")
1202   (if (cdr (gnus-summary-work-articles nil))
1203       ;; Process marks are given.
1204       (gnus-uu-digest-mail-forward arg post)
1205     ;; No process marks.
1206     (let ((message-forward-as-mime message-forward-as-mime)
1207           (message-forward-show-mml message-forward-show-mml))
1208       (cond
1209        ((null arg))
1210        ((eq arg 1)
1211         (setq message-forward-as-mime nil
1212               message-forward-show-mml t))
1213        ((eq arg 2)
1214         (setq message-forward-as-mime t
1215               message-forward-show-mml nil))
1216        ((eq arg 3)
1217         (setq message-forward-as-mime t
1218               message-forward-show-mml t))
1219        ((eq arg 4)
1220         (setq message-forward-as-mime nil
1221               message-forward-show-mml nil))
1222        (t
1223         (setq message-forward-as-mime (not message-forward-as-mime))))
1224       (let* ((gnus-article-reply (gnus-summary-article-number))
1225              (gnus-article-yanked-articles (list gnus-article-reply)))
1226         (gnus-setup-message 'forward
1227           (gnus-summary-select-article)
1228           (let ((mail-parse-charset
1229                  (or (and (gnus-buffer-live-p gnus-article-buffer)
1230                           (with-current-buffer gnus-article-buffer
1231                             gnus-article-charset))
1232                      gnus-newsgroup-charset))
1233                 (mail-parse-ignored-charsets
1234                  gnus-newsgroup-ignored-charsets))
1235             (set-buffer gnus-original-article-buffer)
1236             (message-forward post)))))))
1237
1238 (defun gnus-summary-resend-message (address n)
1239   "Resend the current article to ADDRESS."
1240   (interactive
1241    (list (message-read-from-minibuffer
1242           "Resend message(s) to: "
1243           (when (and gnus-summary-resend-default-address
1244                      (gnus-buffer-live-p gnus-original-article-buffer))
1245             ;; If some other article is currently selected, the
1246             ;; initial-contents is wrong. Whatever, it is just the
1247             ;; initial-contents.
1248             (with-current-buffer gnus-original-article-buffer
1249               (nnmail-fetch-field "to"))))
1250          current-prefix-arg))
1251   (dolist (article (gnus-summary-work-articles n))
1252     (gnus-summary-select-article nil nil nil article)
1253     (save-excursion
1254       (set-buffer gnus-original-article-buffer)
1255       (message-resend address))
1256     (gnus-summary-mark-article-as-forwarded article)))
1257
1258 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1259 (defun gnus-summary-resend-message-edit ()
1260   "Resend an article that has already been sent.
1261 A new buffer will be created to allow the user to modify body and
1262 contents of the message, and then, everything will happen as when
1263 composing a new message."
1264   (interactive)
1265   (let ((article (gnus-summary-article-number)))
1266     (gnus-setup-message 'reply-yank
1267       (gnus-summary-select-article t)
1268       (set-buffer gnus-original-article-buffer)
1269       (let ((cur (current-buffer))
1270             (to (message-fetch-field "to")))
1271         ;; Get a normal message buffer.
1272         (message-pop-to-buffer (message-buffer-name "Resend" to))
1273         (insert-buffer-substring cur)
1274         (mime-to-mml)
1275         (message-narrow-to-head-1)
1276         ;; Gnus will generate a new one when sending.
1277         (message-remove-header "Message-ID")
1278         (message-remove-header message-ignored-resent-headers t)
1279         ;; Remove unwanted headers.
1280         (goto-char (point-max))
1281         (insert mail-header-separator)
1282         (goto-char (point-min))
1283         (when (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1284           (forward-char 1))
1285         (widen)))))
1286
1287 (defun gnus-summary-post-forward (&optional arg)
1288   "Forward the current article to a newsgroup.
1289 See `gnus-summary-mail-forward' for ARG."
1290   (interactive "P")
1291   (gnus-summary-mail-forward arg t))
1292
1293 (defvar gnus-nastygram-message
1294   "The following article was inappropriately posted to %s.\n\n"
1295   "Format string to insert in nastygrams.
1296 The current group name will be inserted at \"%s\".")
1297
1298 (defun gnus-summary-mail-nastygram (n)
1299   "Send a nastygram to the author of the current article."
1300   (interactive "P")
1301   (when (or gnus-expert-user
1302             (gnus-y-or-n-p
1303              "Really send a nastygram to the author of the current article? "))
1304     (let ((group gnus-newsgroup-name))
1305       (gnus-summary-reply-with-original n)
1306       (set-buffer gnus-message-buffer)
1307       (message-goto-body)
1308       (insert (format gnus-nastygram-message group))
1309       (message-send-and-exit))))
1310
1311 (defun gnus-summary-mail-crosspost-complaint (n)
1312   "Send a complaint about crossposting to the current article(s)."
1313   (interactive "P")
1314   (dolist (article (gnus-summary-work-articles n))
1315     (set-buffer gnus-summary-buffer)
1316     (gnus-summary-goto-subject article)
1317     (let ((group (gnus-group-real-name gnus-newsgroup-name))
1318           newsgroups followup-to)
1319       (gnus-summary-select-article)
1320       (set-buffer gnus-original-article-buffer)
1321       (if (and (<= (length (message-tokenize-header
1322                             (setq newsgroups
1323                                   (mail-fetch-field "newsgroups"))
1324                             ", "))
1325                    1)
1326                (or (not (setq followup-to (mail-fetch-field "followup-to")))
1327                    (not (member group (message-tokenize-header
1328                                        followup-to ", ")))))
1329           (if followup-to
1330               (gnus-message 1 "Followup-to restricted")
1331             (gnus-message 1 "Not a crossposted article"))
1332         (set-buffer gnus-summary-buffer)
1333         (gnus-summary-reply-with-original 1)
1334         (set-buffer gnus-message-buffer)
1335         (message-goto-body)
1336         (insert (format gnus-crosspost-complaint newsgroups group))
1337         (message-goto-subject)
1338         (re-search-forward " *$")
1339         (replace-match " (crosspost notification)" t t)
1340         (gnus-deactivate-mark)
1341         (when (gnus-y-or-n-p "Send this complaint? ")
1342           (message-send-and-exit))))))
1343
1344 (defun gnus-mail-parse-comma-list ()
1345   (let (accumulated
1346         beg)
1347     (skip-chars-forward " ")
1348     (while (not (eobp))
1349       (setq beg (point))
1350       (skip-chars-forward "^,")
1351       (while (zerop
1352               (save-excursion
1353                 (save-restriction
1354                   (let ((i 0))
1355                     (narrow-to-region beg (point))
1356                     (goto-char beg)
1357                     (logand (progn
1358                               (while (search-forward "\"" nil t)
1359                                 (incf i))
1360                               (if (zerop i) 2 i))
1361                             2)))))
1362         (skip-chars-forward ",")
1363         (skip-chars-forward "^,"))
1364       (skip-chars-backward " ")
1365       (push (buffer-substring beg (point))
1366             accumulated)
1367       (skip-chars-forward "^,")
1368       (skip-chars-forward ", "))
1369     accumulated))
1370
1371 (defun gnus-inews-add-to-address (group)
1372   (let ((to-address (mail-fetch-field "to")))
1373     (when (and to-address
1374                (gnus-alive-p))
1375       ;; This mail group doesn't have a `to-list', so we add one
1376       ;; here.  Magic!
1377       (when (gnus-y-or-n-p
1378              (format "Do you want to add this as `to-list': %s? " to-address))
1379         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1380
1381 (defun gnus-put-message ()
1382   "Put the current message in some group and return to Gnus."
1383   (interactive)
1384   (let ((reply gnus-article-reply)
1385         (winconf gnus-prev-winconf)
1386         (group gnus-newsgroup-name))
1387     (unless (and group
1388                  (not (gnus-group-read-only-p group)))
1389       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1390
1391     (when (gnus-group-entry group)
1392       (error "No such group: %s" group))
1393     (save-excursion
1394       (save-restriction
1395         (widen)
1396         (message-narrow-to-headers)
1397         (let ((gnus-deletable-headers nil))
1398           (message-generate-headers
1399            (if (message-news-p)
1400                message-required-news-headers
1401              message-required-mail-headers)))
1402         (goto-char (point-max))
1403         (if (string-match " " group)
1404             (insert "Gcc: \"" group "\"\n")
1405           (insert "Gcc: " group "\n"))
1406         (widen)))
1407     (gnus-inews-do-gcc)
1408     (when (and (get-buffer gnus-group-buffer)
1409                (gnus-buffer-exists-p (car-safe reply))
1410                (cdr reply))
1411       (set-buffer (car reply))
1412       (gnus-summary-mark-article-as-replied (cdr reply)))
1413     (when winconf
1414       (set-window-configuration winconf))))
1415
1416 (defun gnus-article-mail (yank)
1417   "Send a reply to the address near point.
1418 If YANK is non-nil, include the original article."
1419   (interactive "P")
1420   (let ((address
1421          (buffer-substring
1422           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1423           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1424     (when address
1425       (gnus-msg-mail address)
1426       (when yank
1427         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1428
1429 (defvar nntp-server-type)
1430 (defun gnus-bug ()
1431   "Send a bug report to the Gnus maintainers."
1432   (interactive)
1433   (unless (gnus-alive-p)
1434     (error "Gnus has been shut down"))
1435   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1436     (unless (message-mail-user-agent)
1437       (delete-other-windows)
1438       (when gnus-bug-create-help-buffer
1439         (switch-to-buffer "*Gnus Help Bug*")
1440         (erase-buffer)
1441         (insert gnus-bug-message)
1442         (goto-char (point-min)))
1443       (message-pop-to-buffer "*Gnus Bug*"))
1444     (let ((message-this-is-mail t))
1445       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1446     (when gnus-bug-create-help-buffer
1447       (push `(gnus-bug-kill-buffer) message-send-actions))
1448     (goto-char (point-min))
1449     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1450     (forward-line 1)
1451     (insert (gnus-version) "\n"
1452             (emacs-version) "\n")
1453     (when (and (boundp 'nntp-server-type)
1454                (stringp nntp-server-type))
1455       (insert nntp-server-type))
1456     (insert "\n\n\n\n\n")
1457     (let (text)
1458       (save-excursion
1459         (set-buffer (gnus-get-buffer-create " *gnus environment info*"))
1460         (erase-buffer)
1461         (gnus-debug)
1462         (setq text (buffer-string)))
1463       (insert "<#part type=application/emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
1464     (goto-char (point-min))
1465     (search-forward "Subject: " nil t)
1466     (message "")))
1467
1468 (defun gnus-bug-kill-buffer ()
1469   (when (get-buffer "*Gnus Help Bug*")
1470     (kill-buffer "*Gnus Help Bug*")))
1471
1472 (defun gnus-summary-yank-message (buffer n)
1473   "Yank the current article into a composed message."
1474   (interactive
1475    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
1476          current-prefix-arg))
1477   (gnus-summary-iterate n
1478     (let ((gnus-inhibit-treatment t))
1479       (gnus-summary-select-article))
1480     (save-excursion
1481       (set-buffer buffer)
1482       (message-yank-buffer gnus-article-buffer))))
1483
1484 (defun gnus-debug ()
1485   "Attempts to go through the Gnus source file and report what variables have been changed.
1486 The source file has to be in the Emacs load path."
1487   (interactive)
1488   (let ((files gnus-debug-files)
1489         (point (point))
1490         file expr olist sym)
1491     (gnus-message 4 "Please wait while we snoop your variables...")
1492     (sit-for 0)
1493     ;; Go through all the files looking for non-default values for variables.
1494     (save-excursion
1495       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
1496       (while files
1497         (erase-buffer)
1498         (when (and (setq file (locate-library (pop files)))
1499                    (file-exists-p file))
1500           (insert-file-contents file)
1501           (goto-char (point-min))
1502           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1503               (gnus-message 4 "Malformed sources in file %s" file)
1504             (narrow-to-region (point-min) (point))
1505             (goto-char (point-min))
1506             (while (setq expr (ignore-errors (read (current-buffer))))
1507               (ignore-errors
1508                 (and (or (eq (car expr) 'defvar)
1509                          (eq (car expr) 'defcustom))
1510                      (stringp (nth 3 expr))
1511                      (not (memq (nth 1 expr) gnus-debug-exclude-variables))
1512                      (or (not (boundp (nth 1 expr)))
1513                          (not (equal (eval (nth 2 expr))
1514                                      (symbol-value (nth 1 expr)))))
1515                      (push (nth 1 expr) olist)))))))
1516       (kill-buffer (current-buffer)))
1517     (when (setq olist (nreverse olist))
1518       (insert "------------------ Environment follows ------------------\n\n"))
1519     (while olist
1520       (if (boundp (car olist))
1521           (ignore-errors
1522            (gnus-pp
1523             `(setq ,(car olist)
1524                    ,(if (or (consp (setq sym (symbol-value (car olist))))
1525                             (and (symbolp sym)
1526                                  (not (or (eq sym nil)
1527                                           (eq sym t)))))
1528                         (list 'quote (symbol-value (car olist)))
1529                       (symbol-value (car olist))))))
1530         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1531       (setq olist (cdr olist)))
1532     (insert "\n\n")
1533     ;; Remove any control chars - they seem to cause trouble for some
1534     ;; mailers.  (Byte-compiled output from the stuff above.)
1535     (goto-char point)
1536     (while (re-search-forward (mm-string-as-multibyte
1537                                "[\000-\010\013-\037\200-\237]") nil t)
1538       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1539                      t t))))
1540
1541 ;;; Treatment of rejected articles.
1542 ;;; Bounced mail.
1543
1544 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1545   "Re-mail the current message.
1546 This only makes sense if the current message is a bounce message that
1547 contains some mail you have written which has been bounced back to
1548 you.
1549 If FETCH, try to fetch the article that this is a reply to, if indeed
1550 this is a reply."
1551   (interactive "P")
1552   (gnus-summary-select-article t)
1553   (set-buffer gnus-original-article-buffer)
1554   (gnus-setup-message 'compose-bounce
1555     (let* ((references (mail-fetch-field "references"))
1556            (parent (and references (gnus-parent-id references))))
1557       (message-bounce)
1558       ;; If there are references, we fetch the article we answered to.
1559       (and fetch parent
1560            (gnus-summary-refer-article parent)
1561            (gnus-summary-show-all-headers)))))
1562
1563 ;;; Gcc handling.
1564
1565 (defun gnus-inews-group-method (group)
1566   (cond
1567    ;; If the group doesn't exist, we assume
1568    ;; it's an archive group...
1569    ((and (null (gnus-get-info group))
1570          (eq (car (gnus-server-to-method gnus-message-archive-method))
1571              (car (gnus-server-to-method (gnus-group-method group)))))
1572     gnus-message-archive-method)
1573    ;; Use the method.
1574    ((gnus-info-method (gnus-get-info group))
1575     (gnus-info-method (gnus-get-info group)))
1576    ;; Find the method.
1577    (t (gnus-server-to-method (gnus-group-method group)))))
1578
1579 ;; Do Gcc handling, which copied the message over to some group.
1580 (defun gnus-inews-do-gcc (&optional gcc)
1581   (interactive)
1582   (save-excursion
1583     (save-restriction
1584       (message-narrow-to-headers)
1585       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1586             (cur (current-buffer))
1587             groups group method group-art
1588             mml-externalize-attachments)
1589         (when gcc
1590           (message-remove-header "gcc")
1591           (widen)
1592           (setq groups (message-unquote-tokens
1593                         (message-tokenize-header gcc " ,")))
1594           ;; Copy the article over to some group(s).
1595           (while (setq group (pop groups))
1596             (unless (gnus-check-server
1597                      (setq method (gnus-inews-group-method group)))
1598               (error "Can't open server %s" (if (stringp method) method
1599                                               (car method))))
1600             (unless (gnus-request-group group nil method)
1601               (gnus-request-create-group group method))
1602             (setq mml-externalize-attachments
1603                   (if (stringp gnus-gcc-externalize-attachments)
1604                       (string-match gnus-gcc-externalize-attachments group)
1605                     gnus-gcc-externalize-attachments))
1606             (save-excursion
1607               (nnheader-set-temp-buffer " *acc*")
1608               (insert-buffer-substring cur)
1609               (message-encode-message-body)
1610               (save-restriction
1611                 (message-narrow-to-headers)
1612                 (let* ((mail-parse-charset message-default-charset)
1613                        (newsgroups-field (save-restriction
1614                                            (message-narrow-to-headers-or-head)
1615                                            (message-fetch-field "Newsgroups")))
1616                        (followup-field (save-restriction
1617                                          (message-narrow-to-headers-or-head)
1618                                          (message-fetch-field "Followup-To")))
1619                        ;; BUG: We really need to get the charset for
1620                        ;; each name in the Newsgroups and Followup-To
1621                        ;; lines to allow crossposting between group
1622                        ;; namess with incompatible character sets.
1623                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1624                        (group-field-charset
1625                         (gnus-group-name-charset
1626                          method (or newsgroups-field "")))
1627                        (followup-field-charset
1628                         (gnus-group-name-charset
1629                          method (or followup-field "")))
1630                        (rfc2047-header-encoding-alist
1631                         (append
1632                          (when group-field-charset
1633                            (list (cons "Newsgroups" group-field-charset)))
1634                          (when followup-field-charset
1635                            (list (cons "Followup-To" followup-field-charset)))
1636                          rfc2047-header-encoding-alist)))
1637                   (mail-encode-encoded-word-buffer)))
1638               (goto-char (point-min))
1639               (when (re-search-forward
1640                      (concat "^" (regexp-quote mail-header-separator) "$")
1641                      nil t)
1642                 (replace-match "" t t ))
1643               (when (or (not (gnus-check-backend-function
1644                               'request-accept-article group))
1645                         (not (setq group-art
1646                                    (gnus-request-accept-article
1647                                     group method t t))))
1648                 (gnus-message 1 "Couldn't store article in group %s: %s"
1649                               group (gnus-status-message method)))
1650               (when (and group-art
1651                          ;; FIXME: Should gcc-mark-as-read work when
1652                          ;; Gnus is not running?
1653                          (gnus-alive-p)
1654                          (or gnus-gcc-mark-as-read
1655                              (and
1656                               (boundp 'gnus-inews-mark-gcc-as-read)
1657                               (symbol-value 'gnus-inews-mark-gcc-as-read))))
1658                 (gnus-group-mark-article-read group (cdr group-art)))
1659               (kill-buffer (current-buffer)))))))))
1660
1661 (defun gnus-inews-insert-gcc ()
1662   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1663   (save-excursion
1664     (save-restriction
1665       (message-narrow-to-headers)
1666       (let* ((group gnus-outgoing-message-group)
1667              (gcc (cond
1668                    ((functionp group)
1669                     (funcall group))
1670                    ((or (stringp group) (list group))
1671                     group))))
1672         (when gcc
1673           (insert "Gcc: "
1674                   (if (stringp gcc)
1675                       (if (string-match " " gcc)
1676                           (concat "\"" gcc "\"")
1677                         gcc)
1678                     (mapconcat (lambda (group)
1679                                  (if (string-match " " group)
1680                                      (concat "\"" group "\"")
1681                                    group))
1682                                gcc " "))
1683                   "\n"))))))
1684
1685 (defun gnus-inews-insert-archive-gcc (&optional group)
1686   "Insert the Gcc to say where the article is to be archived."
1687   (let* ((var gnus-message-archive-group)
1688          (group (or group gnus-newsgroup-name ""))
1689          (gcc-self-val
1690           (and gnus-newsgroup-name
1691                (not (equal gnus-newsgroup-name ""))
1692                (gnus-group-find-parameter
1693                 gnus-newsgroup-name 'gcc-self)))
1694          result
1695          (groups
1696           (cond
1697            ((null gnus-message-archive-method)
1698             ;; Ignore.
1699             nil)
1700            ((stringp var)
1701             ;; Just a single group.
1702             (list var))
1703            ((null var)
1704             ;; We don't want this.
1705             nil)
1706            ((and (listp var) (stringp (car var)))
1707             ;; A list of groups.
1708             var)
1709            ((functionp var)
1710             ;; A function.
1711             (funcall var group))
1712            (t
1713             ;; An alist of regexps/functions/forms.
1714             (while (and var
1715                         (not
1716                          (setq result
1717                                (cond
1718                                 ((stringp (caar var))
1719                                  ;; Regexp.
1720                                  (when (string-match (caar var) group)
1721                                    (cdar var)))
1722                                 ((functionp (car var))
1723                                  ;; Function.
1724                                  (funcall (car var) group))
1725                                 (t
1726                                  (eval (car var)))))))
1727               (setq var (cdr var)))
1728             result)))
1729          name)
1730     (when (or groups gcc-self-val)
1731       (when (stringp groups)
1732         (setq groups (list groups)))
1733       (save-excursion
1734         (save-restriction
1735           (message-narrow-to-headers)
1736           (goto-char (point-max))
1737           (insert "Gcc: ")
1738           (if gcc-self-val
1739               ;; Use the `gcc-self' param value instead.
1740               (progn
1741                 (insert
1742                  (if (stringp gcc-self-val)
1743                      (if (string-match " " gcc-self-val)
1744                          (concat "\"" gcc-self-val "\"")
1745                        gcc-self-val)
1746                    ;; In nndoc groups, we use the parent group name
1747                    ;; instead of the current group.
1748                    (let ((group (or (gnus-group-find-parameter
1749                                      gnus-newsgroup-name 'parent-group)
1750                                     group)))
1751                      (if (string-match " " group)
1752                          (concat "\"" group "\"")
1753                        group))))
1754                 (if (not (eq gcc-self-val 'none))
1755                     (insert "\n")
1756                   (gnus-delete-line)))
1757             ;; Use the list of groups.
1758             (while (setq name (pop groups))
1759               (let ((str (if (string-match ":" name)
1760                              name
1761                            (gnus-group-prefixed-name
1762                             name gnus-message-archive-method))))
1763                 (insert (if (string-match " " str)
1764                             (concat "\"" str "\"")
1765                           str)))
1766               (when groups
1767                 (insert " ")))
1768             (insert "\n")))))))
1769
1770 (defun gnus-mailing-list-followup-to ()
1771   "Look at the headers in the current buffer and return a Mail-Followup-To address."
1772   (let ((x-been-there (gnus-fetch-original-field "x-beenthere"))
1773         (list-post (gnus-fetch-original-field "list-post")))
1774     (when (and list-post
1775                (string-match "mailto:\\([^>]+\\)" list-post))
1776       (setq list-post (match-string 1 list-post)))
1777     (or list-post
1778         x-been-there)))
1779
1780 ;;; Posting styles.
1781
1782 (defun gnus-configure-posting-styles (&optional group-name)
1783   "Configure posting styles according to `gnus-posting-styles'."
1784   (unless gnus-inhibit-posting-styles
1785     (let ((group (or group-name gnus-newsgroup-name ""))
1786           (styles gnus-posting-styles)
1787           style match attribute value v results
1788           filep name address element)
1789       ;; If the group has a posting-style parameter, add it at the end with a
1790       ;; regexp matching everything, to be sure it takes precedence over all
1791       ;; the others.
1792       (when gnus-newsgroup-name
1793         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1794           (when tmp-style
1795             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1796       ;; Go through all styles and look for matches.
1797       (dolist (style styles)
1798         (setq match (pop style))
1799         (goto-char (point-min))
1800         (when (cond
1801                ((stringp match)
1802                 ;; Regexp string match on the group name.
1803                 (string-match match group))
1804                ((eq match 'header)
1805                 ;; Obsolete format of header match.
1806                 (and (gnus-buffer-live-p gnus-article-copy)
1807                      (with-current-buffer gnus-article-copy
1808                        (save-restriction
1809                          (nnheader-narrow-to-headers)
1810                          (let ((header (message-fetch-field (pop style))))
1811                            (and header
1812                                 (string-match (pop style) header)))))))
1813                ((or (symbolp match)
1814                     (functionp match))
1815                 (cond
1816                  ((functionp match)
1817                   ;; Function to be called.
1818                   (funcall match))
1819                  ((boundp match)
1820                   ;; Variable to be checked.
1821                   (symbol-value match))))
1822                ((listp match)
1823                 (cond
1824                  ((eq (car match) 'header)
1825                   ;; New format of header match.
1826                   (and (gnus-buffer-live-p gnus-article-copy)
1827                        (with-current-buffer gnus-article-copy
1828                          (save-restriction
1829                            (nnheader-narrow-to-headers)
1830                            (let ((header (message-fetch-field (nth 1 match))))
1831                              (and header
1832                                   (string-match (nth 2 match) header)))))))
1833                  (t
1834                   ;; This is a form to be evaled.
1835                   (eval match)))))
1836           ;; We have a match, so we set the variables.
1837           (dolist (attribute style)
1838             (setq element (pop attribute)
1839                   filep nil)
1840             (setq value
1841                   (cond
1842                    ((eq (car attribute) :file)
1843                     (setq filep t)
1844                     (cadr attribute))
1845                    ((eq (car attribute) :value)
1846                     (cadr attribute))
1847                    (t
1848                     (car attribute))))
1849             ;; We get the value.
1850             (setq v
1851                   (cond
1852                    ((stringp value)
1853                     value)
1854                    ((or (symbolp value)
1855                         (functionp value))
1856                     (cond ((functionp value)
1857                            (funcall value))
1858                           ((boundp value)
1859                            (symbol-value value))))
1860                    ((listp value)
1861                     (eval value))))
1862             ;; Translate obsolescent value.
1863             (cond
1864              ((eq element 'signature-file)
1865               (setq element 'signature
1866                     filep t))
1867              ((eq element 'x-face-file)
1868               (setq element 'x-face
1869                     filep t)))
1870             ;; Get the contents of file elems.
1871             (when (and filep v)
1872               (setq v (with-temp-buffer
1873                         (insert-file-contents v)
1874                         (goto-char (point-max))
1875                         (skip-chars-backward "\n")
1876                         (delete-region (+ (point) (if (bolp) 0 1))
1877                                        (point-max))
1878                         (buffer-string))))
1879             (setq results (delq (assoc element results) results))
1880             (push (cons element v) results))))
1881       ;; Now we have all the styles, so we insert them.
1882       (setq name (assq 'name results)
1883             address (assq 'address results))
1884       (setq results (delq name (delq address results)))
1885       (gnus-make-local-hook 'message-setup-hook)
1886       (setq results (sort results (lambda (x y)
1887                                     (string-lessp (car x) (car y)))))
1888       (dolist (result results)
1889         (add-hook 'message-setup-hook
1890                   (cond
1891                    ((eq 'eval (car result))
1892                     'ignore)
1893                    ((eq 'body (car result))
1894                     `(lambda ()
1895                        (save-excursion
1896                          (message-goto-body)
1897                          (insert ,(cdr result)))))
1898                    ((eq 'signature (car result))
1899                     (set (make-local-variable 'message-signature) nil)
1900                     (set (make-local-variable 'message-signature-file) nil)
1901                     (if (not (cdr result))
1902                         'ignore
1903                       `(lambda ()
1904                          (save-excursion
1905                            (let ((message-signature ,(cdr result)))
1906                              (when message-signature
1907                                (message-insert-signature)))))))
1908                    (t
1909                     (let ((header
1910                            (if (symbolp (car result))
1911                                (capitalize (symbol-name (car result)))
1912                              (car result))))
1913                       `(lambda ()
1914                          (save-excursion
1915                            (message-remove-header ,header)
1916                            (let ((value ,(cdr result)))
1917                              (when value
1918                                (message-goto-eoh)
1919                                (insert ,header ": " value)
1920                                (unless (bolp)
1921                                  (insert "\n")))))))))
1922                   nil 'local))
1923       (when (or name address)
1924         (add-hook 'message-setup-hook
1925                   `(lambda ()
1926                      (set (make-local-variable 'user-mail-address)
1927                           ,(or (cdr address) user-mail-address))
1928                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1929                            (user-mail-address
1930                             ,(or (cdr address) user-mail-address)))
1931                        (save-excursion
1932                          (message-remove-header "From")
1933                          (message-goto-eoh)
1934                          (insert "From: " (message-make-from) "\n"))))
1935                   nil 'local)))))
1936
1937 ;;; Allow redefinition of functions.
1938
1939 (gnus-ems-redefine)
1940
1941 (provide 'gnus-msg)
1942
1943 ;;; arch-tag: 9f22b2f5-1c0a-49de-916e-4c88e984852b
1944 ;;; gnus-msg.el ends here