cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'gnus)
  34 (require 'gnus-ems)
  35 (require 'message)
  36 (require 'gnus-art)
  37 (require 'gnus-util)
  38
  39 (defcustom gnus-post-method 'current
  40   "*Preferred method for posting USENET news.
  41
  42 If this variable is `current' (which is the default), Gnus will use
  43 the \"current\" select method when posting.  If it is `native', Gnus
  44 will use the native select method when posting.
  45
  46 This method will not be used in mail groups and the like, only in
  47 \"real\" newsgroups.
  48
  49 If not `native' nor `current', the value must be a valid method as discussed
  50 in the documentation of `gnus-select-method'.  It can also be a list of
  51 methods.  If that is the case, the user will be queried for what select
  52 method to use when posting."
  53   :group 'gnus-group-foreign
  54   :link '(custom-manual "(gnus)Posting Server")
  55   :type `(choice (const native)
  56                  (const current)
  57                  (sexp :tag "Methods" ,gnus-select-method)))
  58
  59 (defcustom gnus-outgoing-message-group nil
  60   "*All outgoing messages will be put in this group.
  61 If you want to store all your outgoing mail and articles in the group
  62 \"nnml:archive\", you set this variable to that value.  This variable
  63 can also be a list of group names.
  64
  65 If you want to have greater control over what group to put each
  66 message in, you can set this variable to a function that checks the
  67 current newsgroup name and then returns a suitable group name (or list
  68 of names)."
  69   :group 'gnus-message
  70   :type '(choice (const nil)
  71                  (function)
  72                  (string :tag "Group")
  73                  (repeat :tag "List of groups" (string :tag "Group"))))
  74
  75 (defcustom gnus-mailing-list-groups nil
  76   "*If non-nil a regexp matching groups that are really mailing lists.
  77 This is useful when you're reading a mailing list that has been
  78 gatewayed to a newsgroup, and you want to followup to an article in
  79 the group."
  80   :group 'gnus-message
  81   :type '(choice (regexp)
  82                  (const nil)))
  83
  84 (defcustom gnus-add-to-list nil
  85   "*If non-nil, add a `to-list' parameter automatically."
  86   :group 'gnus-message
  87   :type 'boolean)
  88
  89 (defcustom gnus-crosspost-complaint
  90   "Hi,
  91
  92 You posted the article below with the following Newsgroups header:
  93
  94 Newsgroups: %s
  95
  96 The %s group, at least, was an inappropriate recipient
  97 of this message.  Please trim your Newsgroups header to exclude this
  98 group before posting in the future.
  99
 100 Thank you.
 101
 102 "
 103   "Format string to be inserted when complaining about crossposts.
 104 The first %s will be replaced by the Newsgroups header;
 105 the second with the current group name."
 106   :group 'gnus-message
 107   :type 'string)
 108
 109 (defcustom gnus-message-setup-hook nil
 110   "Hook run after setting up a message buffer."
 111   :group 'gnus-message
 112   :type 'hook)
 113
 114 (defcustom gnus-bug-create-help-buffer t
 115   "*Should we create the *Gnus Help Bug* buffer?"
 116   :group 'gnus-message
 117   :type 'boolean)
 118
 119 (defcustom gnus-posting-styles nil
 120   "*Alist of styles to use when posting.
 121 See Info node `(gnus)Posting Styles'."
 122   :group 'gnus-message
 123   :link '(custom-manual "(gnus)Posting Styles")
 124   :type '(repeat (cons (choice (regexp)
 125                                (variable)
 126                                (list (const header)
 127                                      (string :tag "Header")
 128                                      (regexp :tag "Regexp"))
 129                                (function)
 130                                (sexp))
 131                        (repeat (list
 132                                 (choice (const signature)
 133                                         (const signature-file)
 134                                         (const organization)
 135                                         (const address)
 136                                         (const x-face-file)
 137                                         (const name)
 138                                         (const body)
 139                                         (symbol)
 140                                         (string :tag "Header"))
 141                                 (choice (string)
 142                                         (function)
 143                                         (variable)
 144                                         (sexp)))))))
 145
 146 (defcustom gnus-gcc-mark-as-read nil
 147   "If non-nil, automatically mark Gcc articles as read."
 148   :version "22.1"
 149   :group 'gnus-message
 150   :type 'boolean)
 151
 152 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 153                         'gnus-gcc-mark-as-read)
 154
 155 (defcustom gnus-gcc-externalize-attachments nil
 156   "Should local-file attachments be included as external parts in Gcc copies?
 157 If it is `all', attach files as external parts;
 158 if a regexp and matches the Gcc group name, attach files as external parts;
 159 if nil, attach files as normal parts."
 160   :version "22.1"
 161   :group 'gnus-message
 162   :type '(choice (const nil :tag "None")
 163                  (const all :tag "Any")
 164                  (string :tag "Regexp")))
 165
 166 (gnus-define-group-parameter
 167  posting-charset-alist
 168  :type list
 169  :function-document
 170  "Return the permitted unencoded charsets for posting of GROUP."
 171  :variable gnus-group-posting-charset-alist
 172  :variable-default
 173   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 174     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 175     (message-this-is-mail nil nil)
 176     (message-this-is-news nil t))
 177  :variable-document
 178   "Alist of regexps and permitted unencoded charsets for posting.
 179 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 180 TEST is either a regular expression matching the newsgroup header or a
 181 variable to query,
 182 HEADER is the charset which may be left unencoded in the header (nil
 183 means encode all charsets),
 184 BODY-LIST is a list of charsets which may be encoded using 8bit
 185 content-transfer encoding in the body, or one of the special values
 186 nil (always encode using quoted-printable) or t (always use 8bit).
 187
 188 Note that any value other than nil for HEADER infringes some RFCs, so
 189 use this option with care."
 190  :variable-group gnus-charset
 191  :variable-type
 192  '(repeat (list :tag "Permitted unencoded charsets"
 193                 (choice :tag "Where"
 194                         (regexp :tag "Group")
 195                         (const :tag "Mail message" :value message-this-is-mail)
 196                         (const :tag "News article" :value message-this-is-news))
 197                 (choice :tag "Header"
 198                         (const :tag "None" nil)
 199                         (symbol :tag "Charset"))
 200                 (choice :tag "Body"
 201                         (const :tag "Any" :value t)
 202                         (const :tag "None" :value nil)
 203                         (repeat :tag "Charsets"
 204                                 (symbol :tag "Charset")))))
 205  :parameter-type '(choice :tag "Permitted unencoded charsets"
 206                           :value nil
 207                           (repeat (symbol)))
 208  :parameter-document       "\
 209 List of charsets that are permitted to be unencoded.")
 210
 211 (defcustom gnus-debug-files
 212   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 213     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 214     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 215     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 216     "mm-util.el" "mm-decode.el" "nnmail.el" "message.el")
 217   "Files whose variables will be reported in `gnus-bug'."
 218   :version "22.1"
 219   :group 'gnus-message
 220   :type '(repeat (string :tag "File")))
 221
 222 (defcustom gnus-debug-exclude-variables
 223   '(mm-mime-mule-charset-alist
 224     nnmail-split-fancy message-minibuffer-local-map)
 225   "Variables that should not be reported in `gnus-bug'."
 226   :version "22.1"
 227   :group 'gnus-message
 228   :type '(repeat (symbol :tag "Variable")))
 229
 230 (defcustom gnus-discouraged-post-methods
 231   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 232   "A list of back ends that are not used in \"real\" newsgroups.
 233 This variable is used only when `gnus-post-method' is `current'."
 234   :version "22.1"
 235   :group 'gnus-group-foreign
 236   :type '(repeat (symbol :tag "Back end")))
 237
 238 (defcustom gnus-message-replysign
 239   nil
 240   "Automatically sign replies to signed messages.
 241 See also the `mml-default-sign-method' variable."
 242   :group 'gnus-message
 243   :type 'boolean)
 244
 245 (defcustom gnus-message-replyencrypt
 246   nil
 247   "Automatically encrypt replies to encrypted messages.
 248 See also the `mml-default-encrypt-method' variable."
 249   :group 'gnus-message
 250   :type 'boolean)
 251
 252 (defcustom gnus-message-replysignencrypted
 253   t
 254   "Setting this causes automatically encrypted messages to also be signed."
 255   :group 'gnus-message
 256   :type 'boolean)
 257
 258 (defcustom gnus-confirm-mail-reply-to-news (and gnus-novice-user
 259                                                 (not gnus-expert-user))
 260   "If non-nil, Gnus requests confirmation when replying to news.
 261 This is done because new users often reply by mistake when reading
 262 news.
 263 This can also be a function receiving the group name as the only
 264 parameter which should return non-nil iff a confirmation is needed, or
 265 a regexp, in which case a confirmation is asked for iff the group name
 266 matches the regexp."
 267   :version "22.1"
 268   :group 'gnus-message
 269   :type '(choice (const :tag "No" nil)
 270                  (const :tag "Yes" t)
 271                  (regexp :tag "Iff group matches regexp")
 272                  (function :tag "Iff function evaluates to non-nil")))
 273
 274 (defcustom gnus-confirm-treat-mail-like-news
 275   nil
 276   "If non-nil, Gnus will treat mail like news with regard to confirmation
 277 when replying by mail.  See the `gnus-confirm-mail-reply-to-news' variable
 278 for fine-tuning this.
 279 If nil, Gnus will never ask for confirmation if replying to mail."
 280   :version "22.1"
 281   :group 'gnus-message
 282   :type 'boolean)
 283
 284 (defcustom gnus-summary-resend-default-address t
 285   "If non-nil, Gnus tries to suggest a default address to resend to.
 286 If nil, the address field will always be empty after invoking
 287 `gnus-summary-resend-message'."
 288   :version "22.1"
 289   :group 'gnus-message
 290   :type 'boolean)
 291
 292 ;;; Internal variables.
 293
 294 (defvar gnus-inhibit-posting-styles nil
 295   "Inhibit the use of posting styles.")
 296
 297 (defvar gnus-article-yanked-articles nil)
 298 (defvar gnus-message-buffer "*Mail Gnus*")
 299 (defvar gnus-article-copy nil)
 300 (defvar gnus-check-before-posting nil)
 301 (defvar gnus-last-posting-server nil)
 302 (defvar gnus-message-group-art nil)
 303
 304 (defvar gnus-msg-force-broken-reply-to nil)
 305
 306 (defconst gnus-bug-message
 307   "Sending a bug report to the Gnus Towers.
 308 ========================================
 309
 310 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 311 be sent to the Gnus Bug Exterminators.
 312
 313 The thing near the bottom of the buffer is how the environment
 314 settings will be included in the mail.  Please do not delete that.
 315 They will tell the Bug People what your environment is, so that it
 316 will be easier to locate the bugs.
 317
 318 If you have found a bug that makes Emacs go \"beep\", set
 319 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 320 and include the backtrace in your bug report.
 321
 322 Please describe the bug in annoying, painstaking detail.
 323
 324 Thank you for your help in stamping out bugs.
 325 ")
 326
 327 (eval-and-compile
 328   (autoload 'gnus-uu-post-news "gnus-uu" nil t))
 329
 330 \f
 331 ;;;
 332 ;;; Gnus Posting Functions
 333 ;;;
 334
 335 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 336   "p" gnus-summary-post-news
 337   "i" gnus-summary-news-other-window
 338   "f" gnus-summary-followup
 339   "F" gnus-summary-followup-with-original
 340   "c" gnus-summary-cancel-article
 341   "s" gnus-summary-supersede-article
 342   "r" gnus-summary-reply
 343   "y" gnus-summary-yank-message
 344   "R" gnus-summary-reply-with-original
 345   "w" gnus-summary-wide-reply
 346   "W" gnus-summary-wide-reply-with-original
 347   "v" gnus-summary-very-wide-reply
 348   "V" gnus-summary-very-wide-reply-with-original
 349   "n" gnus-summary-followup-to-mail
 350   "N" gnus-summary-followup-to-mail-with-original
 351   "m" gnus-summary-mail-other-window
 352   "u" gnus-uu-post-news
 353   "\M-c" gnus-summary-mail-crosspost-complaint
 354   "Br" gnus-summary-reply-broken-reply-to
 355   "BR" gnus-summary-reply-broken-reply-to-with-original
 356   "om" gnus-summary-mail-forward
 357   "op" gnus-summary-post-forward
 358   "Om" gnus-uu-digest-mail-forward
 359   "Op" gnus-uu-digest-post-forward)
 360
 361 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 362   "b" gnus-summary-resend-bounced-mail
 363   ;; "c" gnus-summary-send-draft
 364   "r" gnus-summary-resend-message
 365   "e" gnus-summary-resend-message-edit)
 366
 367 ;;; Internal functions.
 368
 369 (defun gnus-inews-make-draft (articles)
 370   `(lambda ()
 371      (gnus-inews-make-draft-meta-information
 372       ,gnus-newsgroup-name ',articles)))
 373
 374 (defvar gnus-article-reply nil)
 375 (defmacro gnus-setup-message (config &rest forms)
 376   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 377         (buffer (make-symbol "gnus-setup-message-buffer"))
 378         (article (make-symbol "gnus-setup-message-article"))
 379         (yanked (make-symbol "gnus-setup-yanked-articles"))
 380         (group (make-symbol "gnus-setup-message-group")))
 381     `(let ((,winconf (current-window-configuration))
 382            (,buffer (buffer-name (current-buffer)))
 383            (,article gnus-article-reply)
 384            (,yanked gnus-article-yanked-articles)
 385            (,group gnus-newsgroup-name)
 386            (message-header-setup-hook
 387             (copy-sequence message-header-setup-hook))
 388            (mbl mml-buffer-list)
 389            (message-mode-hook (copy-sequence message-mode-hook)))
 390        (setq mml-buffer-list nil)
 391        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 392        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 393        ;; #### FIXME: for a reason that I did not manage to identify yet,
 394        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 395        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 396        ;; After evaluation of @forms below, it gets the value we actually want
 397        ;; to override, and the posting styles are used. For that reason, I've
 398        ;; added an optional argument to `gnus-configure-posting-styles' to
 399        ;; make sure that the correct value for the group name is used. -- drv
 400        (add-hook 'message-mode-hook
 401                  (if (memq ,config '(reply-yank reply))
 402                      (lambda ()
 403                        (gnus-configure-posting-styles ,group))
 404                    (lambda ()
 405                      ;; There may be an old " *gnus article copy*" buffer.
 406                      (let (gnus-article-copy)
 407                        (gnus-configure-posting-styles ,group)))))
 408        (gnus-pull ',(intern gnus-draft-meta-information-header)
 409                   message-required-headers)
 410        (when (and ,group
 411                   (not (string= ,group "")))
 412          (push (cons
 413                 (intern gnus-draft-meta-information-header)
 414                 (gnus-inews-make-draft (or ,yanked ,article)))
 415                message-required-headers))
 416        (unwind-protect
 417            (progn
 418              ,@forms)
 419          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 420                                       ,yanked)
 421          (setq gnus-message-buffer (current-buffer))
 422          (set (make-local-variable 'gnus-message-group-art)
 423               (cons ,group ,article))
 424          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 425          (gnus-run-hooks 'gnus-message-setup-hook)
 426          (if (eq major-mode 'message-mode)
 427              (let ((mbl1 mml-buffer-list))
 428                (setq mml-buffer-list mbl)  ;; Global value
 429                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 430                (gnus-make-local-hook 'kill-buffer-hook)
 431                (gnus-make-local-hook 'change-major-mode-hook)
 432                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 433                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 434            (mml-destroy-buffers)
 435            (setq mml-buffer-list mbl)))
 436        (message-hide-headers)
 437        (gnus-add-buffer)
 438        (gnus-configure-windows ,config t)
 439        (run-hooks 'post-command-hook)
 440        (set-buffer-modified-p nil))))
 441
 442 (defun gnus-inews-make-draft-meta-information (group articles)
 443   (when (numberp articles)
 444     (setq articles (list articles)))
 445   (concat "(\"" group "\""
 446           (if articles
 447               (concat " "
 448                       (mapconcat
 449                        (lambda (elem)
 450                          (number-to-string
 451                           (if (consp elem)
 452                               (car elem)
 453                             elem)))
 454                        articles " "))
 455             "")
 456           ")"))
 457
 458 ;;;###autoload
 459 (defun gnus-msg-mail (&optional to subject other-headers continue
 460                                 switch-action yank-action send-actions)
 461   "Start editing a mail message to be sent.
 462 Like `message-mail', but with Gnus paraphernalia, particularly the
 463 Gcc: header for archiving purposes."
 464   (interactive)
 465   (let ((buf (current-buffer))
 466         mail-buf)
 467     (gnus-setup-message 'message
 468       (message-mail to subject other-headers continue
 469                     nil yank-action send-actions))
 470     (when switch-action
 471       (setq mail-buf (current-buffer))
 472       (switch-to-buffer buf)
 473       (apply switch-action mail-buf nil)))
 474   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 475   t)
 476
 477 ;;;###autoload
 478 (defun gnus-button-mailto (address)
 479   "Mail to ADDRESS."
 480   (set-buffer (gnus-copy-article-buffer))
 481   (gnus-setup-message 'message
 482     (message-reply address)))
 483
 484 ;;;###autoload
 485 (defun gnus-button-reply (&optional to-address wide)
 486   "Like `message-reply'."
 487   (interactive)
 488   (gnus-setup-message 'message
 489     (message-reply to-address wide)))
 490
 491 ;;;###autoload
 492 (define-mail-user-agent 'gnus-user-agent
 493   'gnus-msg-mail 'message-send-and-exit
 494   'message-kill-buffer 'message-send-hook)
 495
 496 (defun gnus-setup-posting-charset (group)
 497   (let ((alist gnus-group-posting-charset-alist)
 498         (group (or group ""))
 499         elem)
 500     (when group
 501       (catch 'found
 502         (while (setq elem (pop alist))
 503           (when (or (and (stringp (car elem))
 504                          (string-match (car elem) group))
 505                     (and (functionp (car elem))
 506                          (funcall (car elem) group))
 507                     (and (symbolp (car elem))
 508                          (symbol-value (car elem))))
 509             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 510
 511 (defun gnus-inews-add-send-actions (winconf buffer article
 512                                             &optional config yanked)
 513   (gnus-make-local-hook 'message-sent-hook)
 514   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 515                                  'gnus-inews-do-gcc) nil t)
 516   (when gnus-agent
 517     (gnus-make-local-hook 'message-header-hook)
 518     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 519   (setq message-post-method
 520         `(lambda (&optional arg)
 521            (gnus-post-method arg ,gnus-newsgroup-name)))
 522   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 523   (message-add-action
 524    `(when (gnus-buffer-exists-p ,buffer)
 525       (set-window-configuration ,winconf))
 526    'exit 'postpone 'kill)
 527   (let ((to-be-marked (cond
 528                        (yanked
 529                         (mapcar
 530                          (lambda (x) (if (listp x) (car x) x)) yanked))
 531                        (article (if (listp article) article (list article)))
 532                        (t nil))))
 533     (message-add-action
 534      `(when (gnus-buffer-exists-p ,buffer)
 535         (save-excursion
 536           (set-buffer ,buffer)
 537           ,(when to-be-marked
 538              (if (eq config 'forward)
 539                  `(gnus-summary-mark-article-as-forwarded ',to-be-marked)
 540                `(gnus-summary-mark-article-as-replied ',to-be-marked)))))
 541      'send)))
 542
 543 (put 'gnus-setup-message 'lisp-indent-function 1)
 544 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 545
 546 ;;; Post news commands of Gnus group mode and summary mode
 547
 548 (defun gnus-group-mail (&optional arg)
 549   "Start composing a mail.
 550 If ARG, use the group under the point to find a posting style.
 551 If ARG is 1, prompt for a group name to find the posting style."
 552   (interactive "P")
 553   ;; We can't `let' gnus-newsgroup-name here, since that leads
 554   ;; to local variables leaking.
 555   (let ((group gnus-newsgroup-name)
 556         ;; make sure last viewed article doesn't affect posting styles:
 557         (gnus-article-copy)
 558         (buffer (current-buffer)))
 559     (unwind-protect
 560         (progn
 561           (setq gnus-newsgroup-name
 562                 (if arg
 563                     (if (= 1 (prefix-numeric-value arg))
 564                         (completing-read "Use posting style of group: "
 565                                          gnus-active-hashtb nil
 566                                          (gnus-read-active-file-p))
 567                       (gnus-group-group-name))
 568                   ""))
 569           ;; #### see comment in gnus-setup-message -- drv
 570           (gnus-setup-message 'message (message-mail)))
 571       (save-excursion
 572         (set-buffer buffer)
 573         (setq gnus-newsgroup-name group)))))
 574
 575 (defun gnus-group-news (&optional arg)
 576   "Start composing a news.
 577 If ARG, post to group under point.
 578 If ARG is 1, prompt for group name to post to.
 579
 580 This function prepares a news even when using mail groups.  This is useful
 581 for posting messages to mail groups without actually sending them over the
 582 network.  The corresponding back end must have a 'request-post method."
 583   (interactive "P")
 584   ;; We can't `let' gnus-newsgroup-name here, since that leads
 585   ;; to local variables leaking.
 586   (let ((group gnus-newsgroup-name)
 587         ;; make sure last viewed article doesn't affect posting styles:
 588         (gnus-article-copy)
 589         (buffer (current-buffer)))
 590     (unwind-protect
 591         (progn
 592           (setq gnus-newsgroup-name
 593                 (if arg
 594                     (if (= 1 (prefix-numeric-value arg))
 595                         (completing-read "Use group: "
 596                                          gnus-active-hashtb nil
 597                                          (gnus-read-active-file-p))
 598                       (gnus-group-group-name))
 599                   ""))
 600           ;; #### see comment in gnus-setup-message -- drv
 601           (gnus-setup-message 'message
 602             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 603       (save-excursion
 604         (set-buffer buffer)
 605         (setq gnus-newsgroup-name group)))))
 606
 607 (defun gnus-group-post-news (&optional arg)
 608   "Start composing a message (a news by default).
 609 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 610 Depending on the selected group, the message might be either a mail or
 611 a news."
 612   (interactive "P")
 613   ;; Bind this variable here to make message mode hooks work ok.
 614   (let ((gnus-newsgroup-name
 615          (if arg
 616              (if (= 1 (prefix-numeric-value arg))
 617                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 618                                   (gnus-read-active-file-p))
 619                (gnus-group-group-name))
 620            ""))
 621         ;; make sure last viewed article doesn't affect posting styles:
 622         (gnus-article-copy))
 623     (gnus-post-news 'post gnus-newsgroup-name nil nil nil nil
 624                     (string= gnus-newsgroup-name ""))))
 625
 626 (defun gnus-summary-mail-other-window (&optional arg)
 627   "Start composing a mail in another window.
 628 Use the posting of the current group by default.
 629 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 630 posting style."
 631   (interactive "P")
 632   ;; We can't `let' gnus-newsgroup-name here, since that leads
 633   ;; to local variables leaking.
 634   (let ((group gnus-newsgroup-name)
 635         ;; make sure last viewed article doesn't affect posting styles:
 636         (gnus-article-copy)
 637         (buffer (current-buffer)))
 638     (unwind-protect
 639         (progn
 640           (setq gnus-newsgroup-name
 641                 (if arg
 642                     (if (= 1 (prefix-numeric-value arg))
 643                         (completing-read "Use group: "
 644                                          gnus-active-hashtb nil
 645                                          (gnus-read-active-file-p))
 646                       "")
 647                   gnus-newsgroup-name))
 648           ;; #### see comment in gnus-setup-message -- drv
 649           (gnus-setup-message 'message (message-mail)))
 650       (save-excursion
 651         (set-buffer buffer)
 652         (setq gnus-newsgroup-name group)))))
 653
 654 (defun gnus-summary-news-other-window (&optional arg)
 655   "Start composing a news in another window.
 656 Post to the current group by default.
 657 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 658
 659 This function prepares a news even when using mail groups.  This is useful
 660 for posting messages to mail groups without actually sending them over the
 661 network.  The corresponding back end must have a 'request-post method."
 662   (interactive "P")
 663   ;; We can't `let' gnus-newsgroup-name here, since that leads
 664   ;; to local variables leaking.
 665   (let ((group gnus-newsgroup-name)
 666         ;; make sure last viewed article doesn't affect posting styles:
 667         (gnus-article-copy)
 668         (buffer (current-buffer)))
 669     (unwind-protect
 670         (progn
 671           (setq gnus-newsgroup-name
 672                 (if arg
 673                     (if (= 1 (prefix-numeric-value arg))
 674                         (completing-read "Use group: "
 675                                          gnus-active-hashtb nil
 676                                          (gnus-read-active-file-p))
 677                       "")
 678                   gnus-newsgroup-name))
 679           ;; #### see comment in gnus-setup-message -- drv
 680           (gnus-setup-message 'message
 681             (progn
 682               (message-news (gnus-group-real-name gnus-newsgroup-name))
 683               (set (make-local-variable 'gnus-discouraged-post-methods)
 684                    (remove
 685                     (car (gnus-find-method-for-group gnus-newsgroup-name))
 686                     gnus-discouraged-post-methods)))))
 687       (save-excursion
 688         (set-buffer buffer)
 689         (setq gnus-newsgroup-name group)))))
 690
 691 (defun gnus-summary-post-news (&optional arg)
 692   "Start composing a message.  Post to the current group by default.
 693 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 694 Depending on the selected group, the message might be either a mail or
 695 a news."
 696   (interactive "P")
 697   ;; Bind this variable here to make message mode hooks work ok.
 698   (let ((gnus-newsgroup-name
 699          (if arg
 700              (if (= 1 (prefix-numeric-value arg))
 701                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 702                                   (gnus-read-active-file-p))
 703                "")
 704            gnus-newsgroup-name))
 705         ;; make sure last viewed article doesn't affect posting styles:
 706         (gnus-article-copy))
 707     (gnus-post-news 'post gnus-newsgroup-name)))
 708
 709
 710 (defun gnus-summary-followup (yank &optional force-news)
 711   "Compose a followup to an article.
 712 If prefix argument YANK is non-nil, the original article is yanked
 713 automatically.
 714 YANK is a list of elements, where the car of each element is the
 715 article number, and the cdr is the string to be yanked."
 716   (interactive
 717    (list (and current-prefix-arg
 718               (gnus-summary-work-articles 1))))
 719   (when yank
 720     (gnus-summary-goto-subject
 721      (if (listp (car yank))
 722          (caar yank)
 723        (car yank))))
 724   (save-window-excursion
 725     (gnus-summary-select-article))
 726   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 727         (gnus-newsgroup-name gnus-newsgroup-name))
 728     ;; Send a followup.
 729     (gnus-post-news nil gnus-newsgroup-name
 730                     headers gnus-article-buffer
 731                     yank nil force-news)
 732     (gnus-summary-handle-replysign)))
 733
 734 (defun gnus-summary-followup-with-original (n &optional force-news)
 735   "Compose a followup to an article and include the original article.
 736 The text in the region will be yanked.  If the region isn't
 737 active, the entire article will be yanked."
 738   (interactive "P")
 739   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 740
 741 (defun gnus-summary-followup-to-mail (&optional arg)
 742   "Followup to the current mail message via news."
 743   (interactive
 744    (list (and current-prefix-arg
 745               (gnus-summary-work-articles 1))))
 746   (gnus-summary-followup arg t))
 747
 748 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 749   "Followup to the current mail message via news."
 750   (interactive "P")
 751   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 752
 753 (defun gnus-inews-yank-articles (articles)
 754   (let (beg article yank-string)
 755     (message-goto-body)
 756     (while (setq article (pop articles))
 757       (when (listp article)
 758         (setq yank-string (nth 1 article)
 759               article (nth 0 article)))
 760       (save-window-excursion
 761         (set-buffer gnus-summary-buffer)
 762         (gnus-summary-select-article nil nil nil article)
 763         (gnus-summary-remove-process-mark article))
 764       (gnus-copy-article-buffer nil yank-string)
 765       (let ((message-reply-buffer gnus-article-copy)
 766             (message-reply-headers
 767              ;; The headers are decoded.
 768              (with-current-buffer gnus-article-copy
 769                (save-restriction
 770                  (nnheader-narrow-to-headers)
 771                  (nnheader-parse-naked-head)))))
 772         (message-yank-original)
 773         (setq beg (or beg (mark t))))
 774       (when articles
 775         (insert "\n")))
 776     (push-mark)
 777     (goto-char beg)))
 778
 779 (defun gnus-summary-cancel-article (&optional n symp)
 780   "Cancel an article you posted.
 781 Uses the process-prefix convention.  If given the symbolic
 782 prefix `a', cancel using the standard posting method; if not
 783 post using the current select method."
 784   (interactive (gnus-interactive "P\ny"))
 785   (let ((message-post-method
 786          `(lambda (arg)
 787             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name))))
 788     (dolist (article (gnus-summary-work-articles n))
 789       (when (gnus-summary-select-article t nil nil article)
 790         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 791                 (message-cancel-news))
 792           (gnus-summary-mark-as-read article gnus-canceled-mark)
 793           (gnus-cache-remove-article 1))
 794         (gnus-article-hide-headers-if-wanted))
 795       (gnus-summary-remove-process-mark article))))
 796
 797 (defun gnus-summary-supersede-article ()
 798   "Compose an article that will supersede a previous article.
 799 This is done simply by taking the old article and adding a Supersedes
 800 header line with the old Message-ID."
 801   (interactive)
 802   (let ((article (gnus-summary-article-number)))
 803     (gnus-setup-message 'reply-yank
 804       (gnus-summary-select-article t)
 805       (set-buffer gnus-original-article-buffer)
 806       (message-supersede)
 807       (push
 808        `((lambda ()
 809            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 810              (save-excursion
 811                (set-buffer ,gnus-summary-buffer)
 812                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 813                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 814        message-send-actions))))
 815
 816 \f
 817
 818 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 819   ;; make a copy of the article buffer with all text properties removed
 820   ;; this copy is in the buffer gnus-article-copy.
 821   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 822   ;; this buffer should be passed to all mail/news reply/post routines.
 823   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 824   (save-excursion
 825     (set-buffer gnus-article-copy)
 826     (mm-enable-multibyte))
 827   (let ((article-buffer (or article-buffer gnus-article-buffer))
 828         end beg)
 829     (if (not (and (get-buffer article-buffer)
 830                   (gnus-buffer-exists-p article-buffer)))
 831         (error "Can't find any article buffer")
 832       (save-excursion
 833         (set-buffer article-buffer)
 834         (let ((gnus-newsgroup-charset (or gnus-article-charset
 835                                           gnus-newsgroup-charset))
 836               (gnus-newsgroup-ignored-charsets
 837                (or gnus-article-ignored-charsets
 838                    gnus-newsgroup-ignored-charsets)))
 839           (save-restriction
 840             ;; Copy over the (displayed) article buffer, delete
 841             ;; hidden text and remove text properties.
 842             (widen)
 843             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 844             (set-buffer gnus-article-copy)
 845             (when yank-string
 846               (message-goto-body)
 847               (delete-region (point) (point-max))
 848               (insert yank-string))
 849             (gnus-article-delete-text-of-type 'annotation)
 850             (gnus-article-delete-text-of-type 'multipart)
 851             (gnus-remove-text-with-property 'gnus-prev)
 852             (gnus-remove-text-with-property 'gnus-next)
 853             (gnus-remove-text-with-property 'gnus-decoration)
 854             (insert
 855              (prog1
 856                  (buffer-substring-no-properties (point-min) (point-max))
 857                (erase-buffer)))
 858             ;; Find the original headers.
 859             (set-buffer gnus-original-article-buffer)
 860             (goto-char (point-min))
 861             (while (looking-at message-unix-mail-delimiter)
 862               (forward-line 1))
 863             (let ((mail-header-separator ""))
 864               (setq beg (point)
 865                     end (or (message-goto-body)
 866                             ;; There may be just a header.
 867                             (point-max))))
 868             ;; Delete the headers from the displayed articles.
 869             (set-buffer gnus-article-copy)
 870             (let ((mail-header-separator ""))
 871               (delete-region (goto-char (point-min))
 872                              (or (message-goto-body) (point-max))))
 873             ;; Insert the original article headers.
 874             (insert-buffer-substring gnus-original-article-buffer beg end)
 875             ;; Decode charsets.
 876             (let ((gnus-article-decode-hook
 877                    (delq 'article-decode-charset
 878                          (copy-sequence gnus-article-decode-hook)))
 879                   (rfc2047-quote-decoded-words-containing-tspecials t))
 880               (run-hooks 'gnus-article-decode-hook)))))
 881       gnus-article-copy)))
 882
 883 (defun gnus-post-news (post &optional group header article-buffer yank subject
 884                             force-news)
 885   (when article-buffer
 886     (gnus-copy-article-buffer))
 887   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 888         (gnus-article-yanked-articles yank)
 889         (add-to-list gnus-add-to-list))
 890     (gnus-setup-message (cond (yank 'reply-yank)
 891                               (article-buffer 'reply)
 892                               (t 'message))
 893       (let* ((group (or group gnus-newsgroup-name))
 894              (charset (gnus-group-name-charset nil group))
 895              (pgroup group)
 896              to-address to-group mailing-list to-list
 897              newsgroup-p)
 898         (when group
 899           (setq to-address (gnus-parameter-to-address group)
 900                 to-group (gnus-group-find-parameter group 'to-group)
 901                 to-list (gnus-parameter-to-list group)
 902                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 903                 mailing-list (when gnus-mailing-list-groups
 904                                (string-match gnus-mailing-list-groups group))
 905                 group (gnus-group-name-decode (gnus-group-real-name group)
 906                                               charset)))
 907         (if (or (and to-group
 908                      (gnus-news-group-p to-group))
 909                 newsgroup-p
 910                 force-news
 911                 (and (gnus-news-group-p
 912                       (or pgroup gnus-newsgroup-name)
 913                       (or header gnus-current-article))
 914                      (not mailing-list)
 915                      (not to-list)
 916                      (not to-address)))
 917             ;; This is news.
 918             (if post
 919                 (message-news
 920                  (or to-group
 921                      (and (not (gnus-virtual-group-p pgroup)) group)))
 922               (set-buffer gnus-article-copy)
 923               (gnus-msg-treat-broken-reply-to)
 924               (message-followup (if (or newsgroup-p force-news)
 925                                     (if (save-restriction
 926                                           (article-narrow-to-head)
 927                                           (message-fetch-field "newsgroups"))
 928                                         nil
 929                                       "")
 930                                   to-group)))
 931           ;; The is mail.
 932           (if post
 933               (progn
 934                 (message-mail (or to-address to-list))
 935                 ;; Arrange for mail groups that have no `to-address' to
 936                 ;; get that when the user sends off the mail.
 937                 (when (and (not to-list)
 938                            (not to-address)
 939                            add-to-list)
 940                   (push (list 'gnus-inews-add-to-address pgroup)
 941                         message-send-actions)))
 942             (set-buffer gnus-article-copy)
 943             (gnus-msg-treat-broken-reply-to)
 944             (message-wide-reply to-address)))
 945         (when yank
 946           (gnus-inews-yank-articles yank))))))
 947
 948 (defun gnus-msg-treat-broken-reply-to (&optional force)
 949   "Remove the Reply-to header if broken-reply-to."
 950   (when (or force
 951             (gnus-group-find-parameter
 952              gnus-newsgroup-name 'broken-reply-to))
 953     (save-restriction
 954       (message-narrow-to-head)
 955       (message-remove-header "reply-to"))))
 956
 957 (defun gnus-post-method (arg group &optional silent)
 958   "Return the posting method based on GROUP and ARG.
 959 If SILENT, don't prompt the user."
 960   (let ((gnus-post-method (or (gnus-parameter-post-method group)
 961                               gnus-post-method))
 962         (group-method (gnus-find-method-for-group group)))
 963     (cond
 964      ;; If the group-method is nil (which shouldn't happen) we use
 965      ;; the default method.
 966      ((null group-method)
 967       (or (and (listp gnus-post-method) ;If not current/native/nil
 968                (not (listp (car gnus-post-method))) ; and not a list of methods
 969                gnus-post-method)        ;then use it.
 970           gnus-select-method
 971           message-post-method))
 972      ;; We want the inverse of the default
 973      ((and arg (not (eq arg 0)))
 974       (if (eq gnus-post-method 'current)
 975           gnus-select-method
 976         group-method))
 977      ;; We query the user for a post method.
 978      ((or arg
 979           (and (listp gnus-post-method)
 980                (listp (car gnus-post-method))))
 981       (let* ((methods
 982               ;; Collect all methods we know about.
 983               (append
 984                (when (listp gnus-post-method)
 985                  (if (listp (car gnus-post-method))
 986                      gnus-post-method
 987                    (list gnus-post-method)))
 988                gnus-secondary-select-methods
 989                (mapcar 'cdr gnus-server-alist)
 990                (mapcar 'car gnus-opened-servers)
 991                (list gnus-select-method)
 992                (list group-method)))
 993              method-alist post-methods method)
 994         ;; Weed out all mail methods.
 995         (while methods
 996           (setq method (gnus-server-get-method "" (pop methods)))
 997           (when (and (or (gnus-method-option-p method 'post)
 998                          (gnus-method-option-p method 'post-mail))
 999                      (not (member method post-methods)))
1000             (push method post-methods)))
1001         ;; Create a name-method alist.
1002         (setq method-alist
1003               (mapcar
1004                (lambda (m)
1005                  (if (equal (cadr m) "")
1006                      (list (symbol-name (car m)) m)
1007                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
1008                post-methods))
1009         ;; Query the user.
1010         (cadr
1011          (assoc
1012           (setq gnus-last-posting-server
1013                 (if (and silent
1014                          gnus-last-posting-server)
1015                     ;; Just use the last value.
1016                     gnus-last-posting-server
1017                   (completing-read
1018                    "Posting method: " method-alist nil t
1019                    (cons (or gnus-last-posting-server "") 0))))
1020           method-alist))))
1021      ;; Override normal method.
1022      ((and (eq gnus-post-method 'current)
1023            (not (memq (car group-method) gnus-discouraged-post-methods))
1024            (gnus-get-function group-method 'request-post t))
1025       (assert (not arg))
1026       group-method)
1027      ;; Use gnus-post-method.
1028      ((listp gnus-post-method)          ;A method...
1029       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
1030       gnus-post-method)
1031      ;; Use the normal select method (nil or native).
1032      (t gnus-select-method))))
1033
1034 \f
1035
1036 (defun gnus-extended-version ()
1037   "Stringified Gnus version and Emacs version.
1038 See the variable `gnus-user-agent'."
1039   (interactive)
1040   (if (stringp gnus-user-agent)
1041       gnus-user-agent
1042     ;; `gnus-user-agent' is a list:
1043     (let* ((float-output-format nil)
1044            (gnus-v
1045             (when (memq 'gnus gnus-user-agent)
1046               (concat "Gnus/"
1047                       (prin1-to-string (gnus-continuum-version gnus-version) t)
1048                       " (" gnus-version ")")))
1049            (emacs-v (gnus-emacs-version)))
1050       (concat gnus-v (when (and gnus-v emacs-v) " ")
1051               emacs-v))))
1052
1053 \f
1054 ;;;
1055 ;;; Gnus Mail Functions
1056 ;;;
1057
1058 ;;; Mail reply commands of Gnus summary mode
1059
1060 (defun gnus-summary-reply (&optional yank wide very-wide)
1061   "Start composing a mail reply to the current message.
1062 If prefix argument YANK is non-nil, the original article is yanked
1063 automatically.
1064 If WIDE, make a wide reply.
1065 If VERY-WIDE, make a very wide reply."
1066   (interactive
1067    (list (and current-prefix-arg
1068               (gnus-summary-work-articles 1))))
1069   ;; Allow user to require confirmation before replying by mail to the
1070   ;; author of a news article (or mail message).
1071   (when (or
1072             (not (or (gnus-news-group-p gnus-newsgroup-name)
1073                      gnus-confirm-treat-mail-like-news))
1074             (not (cond ((stringp gnus-confirm-mail-reply-to-news)
1075                         (string-match gnus-confirm-mail-reply-to-news
1076                                       gnus-newsgroup-name))
1077                        ((functionp gnus-confirm-mail-reply-to-news)
1078                         (funcall gnus-confirm-mail-reply-to-news gnus-newsgroup-name))
1079                        (t gnus-confirm-mail-reply-to-news)))
1080             (y-or-n-p "Really reply by mail to article author? "))
1081     (let* ((article
1082             (if (listp (car yank))
1083                 (caar yank)
1084               (car yank)))
1085            (gnus-article-reply (or article (gnus-summary-article-number)))
1086            (gnus-article-yanked-articles yank)
1087            (headers ""))
1088       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1089       (when yank
1090         (gnus-summary-goto-subject article))
1091       (gnus-setup-message (if yank 'reply-yank 'reply)
1092         (if (not very-wide)
1093             (gnus-summary-select-article)
1094           (dolist (article very-wide)
1095             (gnus-summary-select-article nil nil nil article)
1096             (save-excursion
1097               (set-buffer (gnus-copy-article-buffer))
1098               (gnus-msg-treat-broken-reply-to)
1099               (save-restriction
1100                 (message-narrow-to-head)
1101                 (setq headers (concat headers (buffer-string)))))))
1102         (set-buffer (gnus-copy-article-buffer))
1103         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1104         (save-restriction
1105           (message-narrow-to-head)
1106           (when very-wide
1107             (erase-buffer)
1108             (insert headers))
1109           (goto-char (point-max)))
1110         (mml-quote-region (point) (point-max))
1111         (message-reply nil wide)
1112         (when yank
1113           (gnus-inews-yank-articles yank))
1114         (gnus-summary-handle-replysign)))))
1115
1116 (defun gnus-summary-handle-replysign ()
1117   "Check the various replysign variables and take action accordingly."
1118   (when (or gnus-message-replysign gnus-message-replyencrypt)
1119     (let (signed encrypted)
1120       (save-excursion
1121         (set-buffer gnus-article-buffer)
1122         (setq signed (memq 'signed gnus-article-wash-types))
1123         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1124       (cond ((and gnus-message-replyencrypt encrypted)
1125              (mml-secure-message mml-default-encrypt-method
1126                                  (if gnus-message-replysignencrypted
1127                                      'signencrypt
1128                                    'encrypt)))
1129             ((and gnus-message-replysign signed)
1130              (mml-secure-message mml-default-sign-method 'sign))))))
1131
1132 (defun gnus-summary-reply-with-original (n &optional wide)
1133   "Start composing a reply mail to the current message.
1134 The original article will be yanked."
1135   (interactive "P")
1136   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1137
1138 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1139   "Like `gnus-summary-reply' except removing reply-to field.
1140 If prefix argument YANK is non-nil, the original article is yanked
1141 automatically.
1142 If WIDE, make a wide reply.
1143 If VERY-WIDE, make a very wide reply."
1144   (interactive
1145    (list (and current-prefix-arg
1146               (gnus-summary-work-articles 1))))
1147   (let ((gnus-msg-force-broken-reply-to t))
1148     (gnus-summary-reply yank wide very-wide)))
1149
1150 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1151   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1152 The original article will be yanked."
1153   (interactive "P")
1154   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1155
1156 (defun gnus-summary-wide-reply (&optional yank)
1157   "Start composing a wide reply mail to the current message.
1158 If prefix argument YANK is non-nil, the original article is yanked
1159 automatically."
1160   (interactive
1161    (list (and current-prefix-arg
1162               (gnus-summary-work-articles 1))))
1163   (gnus-summary-reply yank t))
1164
1165 (defun gnus-summary-wide-reply-with-original (n)
1166   "Start composing a wide reply mail to the current message.
1167 The original article will be yanked.
1168 Uses the process/prefix convention."
1169   (interactive "P")
1170   (gnus-summary-reply-with-original n t))
1171
1172 (defun gnus-summary-very-wide-reply (&optional yank)
1173   "Start composing a very wide reply mail to the current message.
1174 If prefix argument YANK is non-nil, the original article is yanked
1175 automatically."
1176   (interactive
1177    (list (and current-prefix-arg
1178               (gnus-summary-work-articles 1))))
1179   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1180
1181 (defun gnus-summary-very-wide-reply-with-original (n)
1182   "Start composing a very wide reply mail to the current message.
1183 The original article will be yanked."
1184   (interactive "P")
1185   (gnus-summary-reply
1186    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1187
1188 (defun gnus-summary-mail-forward (&optional arg post)
1189   "Forward the current message(s) to another user.
1190 If process marks exist, forward all marked messages;
1191 if ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
1192 if ARG is 1, decode the message and forward directly inline;
1193 if ARG is 2, forward message as an rfc822 MIME section;
1194 if ARG is 3, decode message and forward as an rfc822 MIME section;
1195 if ARG is 4, forward message directly inline;
1196 otherwise, use flipped `message-forward-as-mime'.
1197 If POST, post instead of mail.
1198 For the `inline' alternatives, also see the variable
1199 `message-forward-ignored-headers'."
1200   (interactive "P")
1201   (if (cdr (gnus-summary-work-articles nil))
1202       ;; Process marks are given.
1203       (gnus-uu-digest-mail-forward arg post)
1204     ;; No process marks.
1205     (let ((message-forward-as-mime message-forward-as-mime)
1206           (message-forward-show-mml message-forward-show-mml))
1207       (cond
1208        ((null arg))
1209        ((eq arg 1)
1210         (setq message-forward-as-mime nil
1211               message-forward-show-mml t))
1212        ((eq arg 2)
1213         (setq message-forward-as-mime t
1214               message-forward-show-mml nil))
1215        ((eq arg 3)
1216         (setq message-forward-as-mime t
1217               message-forward-show-mml t))
1218        ((eq arg 4)
1219         (setq message-forward-as-mime nil
1220               message-forward-show-mml nil))
1221        (t
1222         (setq message-forward-as-mime (not message-forward-as-mime))))
1223       (let* ((gnus-article-reply (gnus-summary-article-number))
1224              (gnus-article-yanked-articles (list gnus-article-reply)))
1225         (gnus-setup-message 'forward
1226           (gnus-summary-select-article)
1227           (let ((mail-parse-charset
1228                  (or (and (gnus-buffer-live-p gnus-article-buffer)
1229                           (with-current-buffer gnus-article-buffer
1230                             gnus-article-charset))
1231                      gnus-newsgroup-charset))
1232                 (mail-parse-ignored-charsets
1233                  gnus-newsgroup-ignored-charsets))
1234             (set-buffer gnus-original-article-buffer)
1235             (message-forward post)))))))
1236
1237 (defun gnus-summary-resend-message (address n)
1238   "Resend the current article to ADDRESS."
1239   (interactive
1240    (list (message-read-from-minibuffer
1241           "Resend message(s) to: "
1242           (when (and gnus-summary-resend-default-address
1243                      (gnus-buffer-live-p gnus-original-article-buffer))
1244             ;; If some other article is currently selected, the
1245             ;; initial-contents is wrong. Whatever, it is just the
1246             ;; initial-contents.
1247             (with-current-buffer gnus-original-article-buffer
1248               (nnmail-fetch-field "to"))))
1249          current-prefix-arg))
1250   (dolist (article (gnus-summary-work-articles n))
1251     (gnus-summary-select-article nil nil nil article)
1252     (save-excursion
1253       (set-buffer gnus-original-article-buffer)
1254       (message-resend address))
1255     (gnus-summary-mark-article-as-forwarded article)))
1256
1257 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1258 (defun gnus-summary-resend-message-edit ()
1259   "Resend an article that has already been sent.
1260 A new buffer will be created to allow the user to modify body and
1261 contents of the message, and then, everything will happen as when
1262 composing a new message."
1263   (interactive)
1264   (let ((article (gnus-summary-article-number)))
1265     (gnus-setup-message 'reply-yank
1266       (gnus-summary-select-article t)
1267       (set-buffer gnus-original-article-buffer)
1268       (let ((cur (current-buffer))
1269             (to (message-fetch-field "to")))
1270         ;; Get a normal message buffer.
1271         (message-pop-to-buffer (message-buffer-name "Resend" to))
1272         (insert-buffer-substring cur)
1273         (mime-to-mml)
1274         (message-narrow-to-head-1)
1275         ;; Gnus will generate a new one when sending.
1276         (message-remove-header "Message-ID")
1277         (message-remove-header message-ignored-resent-headers t)
1278         ;; Remove unwanted headers.
1279         (goto-char (point-max))
1280         (insert mail-header-separator)
1281         (goto-char (point-min))
1282         (when (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1283           (forward-char 1))
1284         (widen)))))
1285
1286 (defun gnus-summary-post-forward (&optional arg)
1287   "Forward the current article to a newsgroup.
1288 See `gnus-summary-mail-forward' for ARG."
1289   (interactive "P")
1290   (gnus-summary-mail-forward arg t))
1291
1292 (defvar gnus-nastygram-message
1293   "The following article was inappropriately posted to %s.\n\n"
1294   "Format string to insert in nastygrams.
1295 The current group name will be inserted at \"%s\".")
1296
1297 (defun gnus-summary-mail-nastygram (n)
1298   "Send a nastygram to the author of the current article."
1299   (interactive "P")
1300   (when (or gnus-expert-user
1301             (gnus-y-or-n-p
1302              "Really send a nastygram to the author of the current article? "))
1303     (let ((group gnus-newsgroup-name))
1304       (gnus-summary-reply-with-original n)
1305       (set-buffer gnus-message-buffer)
1306       (message-goto-body)
1307       (insert (format gnus-nastygram-message group))
1308       (message-send-and-exit))))
1309
1310 (defun gnus-summary-mail-crosspost-complaint (n)
1311   "Send a complaint about crossposting to the current article(s)."
1312   (interactive "P")
1313   (dolist (article (gnus-summary-work-articles n))
1314     (set-buffer gnus-summary-buffer)
1315     (gnus-summary-goto-subject article)
1316     (let ((group (gnus-group-real-name gnus-newsgroup-name))
1317           newsgroups followup-to)
1318       (gnus-summary-select-article)
1319       (set-buffer gnus-original-article-buffer)
1320       (if (and (<= (length (message-tokenize-header
1321                             (setq newsgroups
1322                                   (mail-fetch-field "newsgroups"))
1323                             ", "))
1324                    1)
1325                (or (not (setq followup-to (mail-fetch-field "followup-to")))
1326                    (not (member group (message-tokenize-header
1327                                        followup-to ", ")))))
1328           (if followup-to
1329               (gnus-message 1 "Followup-to restricted")
1330             (gnus-message 1 "Not a crossposted article"))
1331         (set-buffer gnus-summary-buffer)
1332         (gnus-summary-reply-with-original 1)
1333         (set-buffer gnus-message-buffer)
1334         (message-goto-body)
1335         (insert (format gnus-crosspost-complaint newsgroups group))
1336         (message-goto-subject)
1337         (re-search-forward " *$")
1338         (replace-match " (crosspost notification)" t t)
1339         (gnus-deactivate-mark)
1340         (when (gnus-y-or-n-p "Send this complaint? ")
1341           (message-send-and-exit))))))
1342
1343 (defun gnus-mail-parse-comma-list ()
1344   (let (accumulated
1345         beg)
1346     (skip-chars-forward " ")
1347     (while (not (eobp))
1348       (setq beg (point))
1349       (skip-chars-forward "^,")
1350       (while (zerop
1351               (save-excursion
1352                 (save-restriction
1353                   (let ((i 0))
1354                     (narrow-to-region beg (point))
1355                     (goto-char beg)
1356                     (logand (progn
1357                               (while (search-forward "\"" nil t)
1358                                 (incf i))
1359                               (if (zerop i) 2 i))
1360                             2)))))
1361         (skip-chars-forward ",")
1362         (skip-chars-forward "^,"))
1363       (skip-chars-backward " ")
1364       (push (buffer-substring beg (point))
1365             accumulated)
1366       (skip-chars-forward "^,")
1367       (skip-chars-forward ", "))
1368     accumulated))
1369
1370 (defun gnus-inews-add-to-address (group)
1371   (let ((to-address (mail-fetch-field "to")))
1372     (when (and to-address
1373                (gnus-alive-p))
1374       ;; This mail group doesn't have a `to-list', so we add one
1375       ;; here.  Magic!
1376       (when (gnus-y-or-n-p
1377              (format "Do you want to add this as `to-list': %s? " to-address))
1378         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1379
1380 (defun gnus-put-message ()
1381   "Put the current message in some group and return to Gnus."
1382   (interactive)
1383   (let ((reply gnus-article-reply)
1384         (winconf gnus-prev-winconf)
1385         (group gnus-newsgroup-name))
1386     (unless (and group
1387                  (not (gnus-group-read-only-p group)))
1388       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1389
1390     (when (gnus-group-entry group)
1391       (error "No such group: %s" group))
1392     (save-excursion
1393       (save-restriction
1394         (widen)
1395         (message-narrow-to-headers)
1396         (let ((gnus-deletable-headers nil))
1397           (message-generate-headers
1398            (if (message-news-p)
1399                message-required-news-headers
1400              message-required-mail-headers)))
1401         (goto-char (point-max))
1402         (if (string-match " " group)
1403             (insert "Gcc: \"" group "\"\n")
1404           (insert "Gcc: " group "\n"))
1405         (widen)))
1406     (gnus-inews-do-gcc)
1407     (when (and (get-buffer gnus-group-buffer)
1408                (gnus-buffer-exists-p (car-safe reply))
1409                (cdr reply))
1410       (set-buffer (car reply))
1411       (gnus-summary-mark-article-as-replied (cdr reply)))
1412     (when winconf
1413       (set-window-configuration winconf))))
1414
1415 (defun gnus-article-mail (yank)
1416   "Send a reply to the address near point.
1417 If YANK is non-nil, include the original article."
1418   (interactive "P")
1419   (let ((address
1420          (buffer-substring
1421           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1422           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1423     (when address
1424       (gnus-msg-mail address)
1425       (when yank
1426         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1427
1428 (defvar nntp-server-type)
1429 (defun gnus-bug ()
1430   "Send a bug report to the Gnus maintainers."
1431   (interactive)
1432   (unless (gnus-alive-p)
1433     (error "Gnus has been shut down"))
1434   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1435     (unless (message-mail-user-agent)
1436       (delete-other-windows)
1437       (when gnus-bug-create-help-buffer
1438         (switch-to-buffer "*Gnus Help Bug*")
1439         (erase-buffer)
1440         (insert gnus-bug-message)
1441         (goto-char (point-min)))
1442       (message-pop-to-buffer "*Gnus Bug*"))
1443     (let ((message-this-is-mail t))
1444       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1445     (when gnus-bug-create-help-buffer
1446       (push `(gnus-bug-kill-buffer) message-send-actions))
1447     (goto-char (point-min))
1448     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1449     (forward-line 1)
1450     (insert (gnus-version) "\n"
1451             (emacs-version) "\n")
1452     (when (and (boundp 'nntp-server-type)
1453                (stringp nntp-server-type))
1454       (insert nntp-server-type))
1455     (insert "\n\n\n\n\n")
1456     (let (text)
1457       (save-excursion
1458         (set-buffer (gnus-get-buffer-create " *gnus environment info*"))
1459         (erase-buffer)
1460         (gnus-debug)
1461         (setq text (buffer-string)))
1462       (insert "<#part type=application/emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
1463     (goto-char (point-min))
1464     (search-forward "Subject: " nil t)
1465     (message "")))
1466
1467 (defun gnus-bug-kill-buffer ()
1468   (when (get-buffer "*Gnus Help Bug*")
1469     (kill-buffer "*Gnus Help Bug*")))
1470
1471 (defun gnus-summary-yank-message (buffer n)
1472   "Yank the current article into a composed message."
1473   (interactive
1474    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
1475          current-prefix-arg))
1476   (gnus-summary-iterate n
1477     (let ((gnus-inhibit-treatment t))
1478       (gnus-summary-select-article))
1479     (save-excursion
1480       (set-buffer buffer)
1481       (message-yank-buffer gnus-article-buffer))))
1482
1483 (defun gnus-debug ()
1484   "Attempts to go through the Gnus source file and report what variables have been changed.
1485 The source file has to be in the Emacs load path."
1486   (interactive)
1487   (let ((files gnus-debug-files)
1488         (point (point))
1489         file expr olist sym)
1490     (gnus-message 4 "Please wait while we snoop your variables...")
1491     (sit-for 0)
1492     ;; Go through all the files looking for non-default values for variables.
1493     (save-excursion
1494       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
1495       (while files
1496         (erase-buffer)
1497         (when (and (setq file (locate-library (pop files)))
1498                    (file-exists-p file))
1499           (insert-file-contents file)
1500           (goto-char (point-min))
1501           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1502               (gnus-message 4 "Malformed sources in file %s" file)
1503             (narrow-to-region (point-min) (point))
1504             (goto-char (point-min))
1505             (while (setq expr (ignore-errors (read (current-buffer))))
1506               (ignore-errors
1507                 (and (or (eq (car expr) 'defvar)
1508                          (eq (car expr) 'defcustom))
1509                      (stringp (nth 3 expr))
1510                      (not (memq (nth 1 expr) gnus-debug-exclude-variables))
1511                      (or (not (boundp (nth 1 expr)))
1512                          (not (equal (eval (nth 2 expr))
1513                                      (symbol-value (nth 1 expr)))))
1514                      (push (nth 1 expr) olist)))))))
1515       (kill-buffer (current-buffer)))
1516     (when (setq olist (nreverse olist))
1517       (insert "------------------ Environment follows ------------------\n\n"))
1518     (while olist
1519       (if (boundp (car olist))
1520           (ignore-errors
1521            (gnus-pp
1522             `(setq ,(car olist)
1523                    ,(if (or (consp (setq sym (symbol-value (car olist))))
1524                             (and (symbolp sym)
1525                                  (not (or (eq sym nil)
1526                                           (eq sym t)))))
1527                         (list 'quote (symbol-value (car olist)))
1528                       (symbol-value (car olist))))))
1529         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1530       (setq olist (cdr olist)))
1531     (insert "\n\n")
1532     ;; Remove any control chars - they seem to cause trouble for some
1533     ;; mailers.  (Byte-compiled output from the stuff above.)
1534     (goto-char point)
1535     (while (re-search-forward (mm-string-as-multibyte
1536                                "[\000-\010\013-\037\200-\237]") nil t)
1537       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1538                      t t))))
1539
1540 ;;; Treatment of rejected articles.
1541 ;;; Bounced mail.
1542
1543 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1544   "Re-mail the current message.
1545 This only makes sense if the current message is a bounce message that
1546 contains some mail you have written which has been bounced back to
1547 you.
1548 If FETCH, try to fetch the article that this is a reply to, if indeed
1549 this is a reply."
1550   (interactive "P")
1551   (gnus-summary-select-article t)
1552   (set-buffer gnus-original-article-buffer)
1553   (gnus-setup-message 'compose-bounce
1554     (let* ((references (mail-fetch-field "references"))
1555            (parent (and references (gnus-parent-id references))))
1556       (message-bounce)
1557       ;; If there are references, we fetch the article we answered to.
1558       (and fetch parent
1559            (gnus-summary-refer-article parent)
1560            (gnus-summary-show-all-headers)))))
1561
1562 ;;; Gcc handling.
1563
1564 (defun gnus-inews-group-method (group)
1565   (cond
1566    ;; If the group doesn't exist, we assume
1567    ;; it's an archive group...
1568    ((and (null (gnus-get-info group))
1569          (eq (car (gnus-server-to-method gnus-message-archive-method))
1570              (car (gnus-server-to-method (gnus-group-method group)))))
1571     gnus-message-archive-method)
1572    ;; Use the method.
1573    ((gnus-info-method (gnus-get-info group))
1574     (gnus-info-method (gnus-get-info group)))
1575    ;; Find the method.
1576    (t (gnus-server-to-method (gnus-group-method group)))))
1577
1578 ;; Do Gcc handling, which copied the message over to some group.
1579 (defun gnus-inews-do-gcc (&optional gcc)
1580   (interactive)
1581   (save-excursion
1582     (save-restriction
1583       (message-narrow-to-headers)
1584       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1585             (cur (current-buffer))
1586             groups group method group-art
1587             mml-externalize-attachments)
1588         (when gcc
1589           (message-remove-header "gcc")
1590           (widen)
1591           (setq groups (message-unquote-tokens
1592                         (message-tokenize-header gcc " ,")))
1593           ;; Copy the article over to some group(s).
1594           (while (setq group (pop groups))
1595             (unless (gnus-check-server
1596                      (setq method (gnus-inews-group-method group)))
1597               (error "Can't open server %s" (if (stringp method) method
1598                                               (car method))))
1599             (unless (gnus-request-group group nil method)
1600               (gnus-request-create-group group method))
1601             (setq mml-externalize-attachments
1602                   (if (stringp gnus-gcc-externalize-attachments)
1603                       (string-match gnus-gcc-externalize-attachments group)
1604                     gnus-gcc-externalize-attachments))
1605             (save-excursion
1606               (nnheader-set-temp-buffer " *acc*")
1607               (insert-buffer-substring cur)
1608               (message-encode-message-body)
1609               (save-restriction
1610                 (message-narrow-to-headers)
1611                 (let* ((mail-parse-charset message-default-charset)
1612                        (newsgroups-field (save-restriction
1613                                            (message-narrow-to-headers-or-head)
1614                                            (message-fetch-field "Newsgroups")))
1615                        (followup-field (save-restriction
1616                                          (message-narrow-to-headers-or-head)
1617                                          (message-fetch-field "Followup-To")))
1618                        ;; BUG: We really need to get the charset for
1619                        ;; each name in the Newsgroups and Followup-To
1620                        ;; lines to allow crossposting between group
1621                        ;; namess with incompatible character sets.
1622                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1623                        (group-field-charset
1624                         (gnus-group-name-charset
1625                          method (or newsgroups-field "")))
1626                        (followup-field-charset
1627                         (gnus-group-name-charset
1628                          method (or followup-field "")))
1629                        (rfc2047-header-encoding-alist
1630                         (append
1631                          (when group-field-charset
1632                            (list (cons "Newsgroups" group-field-charset)))
1633                          (when followup-field-charset
1634                            (list (cons "Followup-To" followup-field-charset)))
1635                          rfc2047-header-encoding-alist)))
1636                   (mail-encode-encoded-word-buffer)))
1637               (goto-char (point-min))
1638               (when (re-search-forward
1639                      (concat "^" (regexp-quote mail-header-separator) "$")
1640                      nil t)
1641                 (replace-match "" t t ))
1642               (when (or (not (gnus-check-backend-function
1643                               'request-accept-article group))
1644                         (not (setq group-art
1645                                    (gnus-request-accept-article
1646                                     group method t t))))
1647                 (gnus-message 1 "Couldn't store article in group %s: %s"
1648                               group (gnus-status-message method)))
1649               (when (and group-art
1650                          ;; FIXME: Should gcc-mark-as-read work when
1651                          ;; Gnus is not running?
1652                          (gnus-alive-p)
1653                          (or gnus-gcc-mark-as-read
1654                              (and
1655                               (boundp 'gnus-inews-mark-gcc-as-read)
1656                               (symbol-value 'gnus-inews-mark-gcc-as-read))))
1657                 (gnus-group-mark-article-read group (cdr group-art)))
1658               (kill-buffer (current-buffer)))))))))
1659
1660 (defun gnus-inews-insert-gcc ()
1661   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1662   (save-excursion
1663     (save-restriction
1664       (message-narrow-to-headers)
1665       (let* ((group gnus-outgoing-message-group)
1666              (gcc (cond
1667                    ((functionp group)
1668                     (funcall group))
1669                    ((or (stringp group) (listp group))
1670                     group))))
1671         (when gcc
1672           (insert "Gcc: "
1673                   (if (stringp gcc)
1674                       (if (string-match " " gcc)
1675                           (concat "\"" gcc "\"")
1676                         gcc)
1677                     (mapconcat (lambda (group)
1678                                  (if (string-match " " group)
1679                                      (concat "\"" group "\"")
1680                                    group))
1681                                gcc " "))
1682                   "\n"))))))
1683
1684 (defun gnus-inews-insert-archive-gcc (&optional group)
1685   "Insert the Gcc to say where the article is to be archived."
1686   (let* ((var gnus-message-archive-group)
1687          (group (or group gnus-newsgroup-name ""))
1688          (gcc-self-val
1689           (and gnus-newsgroup-name
1690                (not (equal gnus-newsgroup-name ""))
1691                (gnus-group-find-parameter
1692                 gnus-newsgroup-name 'gcc-self)))
1693          result
1694          (groups
1695           (cond
1696            ((null gnus-message-archive-method)
1697             ;; Ignore.
1698             nil)
1699            ((stringp var)
1700             ;; Just a single group.
1701             (list var))
1702            ((null var)
1703             ;; We don't want this.
1704             nil)
1705            ((and (listp var) (stringp (car var)))
1706             ;; A list of groups.
1707             var)
1708            ((functionp var)
1709             ;; A function.
1710             (funcall var group))
1711            (t
1712             ;; An alist of regexps/functions/forms.
1713             (while (and var
1714                         (not
1715                          (setq result
1716                                (cond
1717                                 ((stringp (caar var))
1718                                  ;; Regexp.
1719                                  (when (string-match (caar var) group)
1720                                    (cdar var)))
1721                                 ((functionp (car var))
1722                                  ;; Function.
1723                                  (funcall (car var) group))
1724                                 (t
1725                                  (eval (car var)))))))
1726               (setq var (cdr var)))
1727             result)))
1728          name)
1729     (when (or groups gcc-self-val)
1730       (when (stringp groups)
1731         (setq groups (list groups)))
1732       (save-excursion
1733         (save-restriction
1734           (message-narrow-to-headers)
1735           (goto-char (point-max))
1736           (insert "Gcc: ")
1737           (if gcc-self-val
1738               ;; Use the `gcc-self' param value instead.
1739               (progn
1740                 (insert
1741                  (if (stringp gcc-self-val)
1742                      (if (string-match " " gcc-self-val)
1743                          (concat "\"" gcc-self-val "\"")
1744                        gcc-self-val)
1745                    ;; In nndoc groups, we use the parent group name
1746                    ;; instead of the current group.
1747                    (let ((group (or (gnus-group-find-parameter
1748                                      gnus-newsgroup-name 'parent-group)
1749                                     group)))
1750                      (if (string-match " " group)
1751                          (concat "\"" group "\"")
1752                        group))))
1753                 (if (not (eq gcc-self-val 'none))
1754                     (insert "\n")
1755                   (gnus-delete-line)))
1756             ;; Use the list of groups.
1757             (while (setq name (pop groups))
1758               (let ((str (if (string-match ":" name)
1759                              name
1760                            (gnus-group-prefixed-name
1761                             name gnus-message-archive-method))))
1762                 (insert (if (string-match " " str)
1763                             (concat "\"" str "\"")
1764                           str)))
1765               (when groups
1766                 (insert " ")))
1767             (insert "\n")))))))
1768
1769 (defun gnus-mailing-list-followup-to ()
1770   "Look at the headers in the current buffer and return a Mail-Followup-To address."
1771   (let ((x-been-there (gnus-fetch-original-field "x-beenthere"))
1772         (list-post (gnus-fetch-original-field "list-post")))
1773     (when (and list-post
1774                (string-match "mailto:\\([^>]+\\)" list-post))
1775       (setq list-post (match-string 1 list-post)))
1776     (or list-post
1777         x-been-there)))
1778
1779 ;;; Posting styles.
1780
1781 (defun gnus-configure-posting-styles (&optional group-name)
1782   "Configure posting styles according to `gnus-posting-styles'."
1783   (unless gnus-inhibit-posting-styles
1784     (let ((group (or group-name gnus-newsgroup-name ""))
1785           (styles gnus-posting-styles)
1786           style match attribute value v results
1787           filep name address element)
1788       ;; If the group has a posting-style parameter, add it at the end with a
1789       ;; regexp matching everything, to be sure it takes precedence over all
1790       ;; the others.
1791       (when gnus-newsgroup-name
1792         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1793           (when tmp-style
1794             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1795       ;; Go through all styles and look for matches.
1796       (dolist (style styles)
1797         (setq match (pop style))
1798         (goto-char (point-min))
1799         (when (cond
1800                ((stringp match)
1801                 ;; Regexp string match on the group name.
1802                 (string-match match group))
1803                ((eq match 'header)
1804                 ;; Obsolete format of header match.
1805                 (and (gnus-buffer-live-p gnus-article-copy)
1806                      (with-current-buffer gnus-article-copy
1807                        (save-restriction
1808                          (nnheader-narrow-to-headers)
1809                          (let ((header (message-fetch-field (pop style))))
1810                            (and header
1811                                 (string-match (pop style) header)))))))
1812                ((or (symbolp match)
1813                     (functionp match))
1814                 (cond
1815                  ((functionp match)
1816                   ;; Function to be called.
1817                   (funcall match))
1818                  ((boundp match)
1819                   ;; Variable to be checked.
1820                   (symbol-value match))))
1821                ((listp match)
1822                 (cond
1823                  ((eq (car match) 'header)
1824                   ;; New format of header match.
1825                   (and (gnus-buffer-live-p gnus-article-copy)
1826                        (with-current-buffer gnus-article-copy
1827                          (save-restriction
1828                            (nnheader-narrow-to-headers)
1829                            (let ((header (message-fetch-field (nth 1 match))))
1830                              (and header
1831                                   (string-match (nth 2 match) header)))))))
1832                  (t
1833                   ;; This is a form to be evaled.
1834                   (eval match)))))
1835           ;; We have a match, so we set the variables.
1836           (dolist (attribute style)
1837             (setq element (pop attribute)
1838                   filep nil)
1839             (setq value
1840                   (cond
1841                    ((eq (car attribute) :file)
1842                     (setq filep t)
1843                     (cadr attribute))
1844                    ((eq (car attribute) :value)
1845                     (cadr attribute))
1846                    (t
1847                     (car attribute))))
1848             ;; We get the value.
1849             (setq v
1850                   (cond
1851                    ((stringp value)
1852                     value)
1853                    ((or (symbolp value)
1854                         (functionp value))
1855                     (cond ((functionp value)
1856                            (funcall value))
1857                           ((boundp value)
1858                            (symbol-value value))))
1859                    ((listp value)
1860                     (eval value))))
1861             ;; Translate obsolescent value.
1862             (cond
1863              ((eq element 'signature-file)
1864               (setq element 'signature
1865                     filep t))
1866              ((eq element 'x-face-file)
1867               (setq element 'x-face
1868                     filep t)))
1869             ;; Get the contents of file elems.
1870             (when (and filep v)
1871               (setq v (with-temp-buffer
1872                         (insert-file-contents v)
1873                         (buffer-substring
1874                          (point-min)
1875                          (progn
1876                            (goto-char (point-max))
1877                            (if (zerop (skip-chars-backward "\n"))
1878                                (point)
1879                              (1+ (point))))))))
1880             (setq results (delq (assoc element results) results))
1881             (push (cons element v) results))))
1882       ;; Now we have all the styles, so we insert them.
1883       (setq name (assq 'name results)
1884             address (assq 'address results))
1885       (setq results (delq name (delq address results)))
1886       (gnus-make-local-hook 'message-setup-hook)
1887       (setq results (sort results (lambda (x y)
1888                                     (string-lessp (car x) (car y)))))
1889       (dolist (result results)
1890         (add-hook 'message-setup-hook
1891                   (cond
1892                    ((eq 'eval (car result))
1893                     'ignore)
1894                    ((eq 'body (car result))
1895                     `(lambda ()
1896                        (save-excursion
1897                          (message-goto-body)
1898                          (insert ,(cdr result)))))
1899                    ((eq 'signature (car result))
1900                     (set (make-local-variable 'message-signature) nil)
1901                     (set (make-local-variable 'message-signature-file) nil)
1902                     (if (not (cdr result))
1903                         'ignore
1904                       `(lambda ()
1905                          (save-excursion
1906                            (let ((message-signature ,(cdr result)))
1907                              (when message-signature
1908                                (message-insert-signature)))))))
1909                    (t
1910                     (let ((header
1911                            (if (symbolp (car result))
1912                                (capitalize (symbol-name (car result)))
1913                              (car result))))
1914                       `(lambda ()
1915                          (save-excursion
1916                            (message-remove-header ,header)
1917                            (let ((value ,(cdr result)))
1918                              (when value
1919                                (message-goto-eoh)
1920                                (insert ,header ": " value)
1921                                (unless (bolp)
1922                                  (insert "\n")))))))))
1923                   nil 'local))
1924       (when (or name address)
1925         (add-hook 'message-setup-hook
1926                   `(lambda ()
1927                      (set (make-local-variable 'user-mail-address)
1928                           ,(or (cdr address) user-mail-address))
1929                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1930                            (user-mail-address
1931                             ,(or (cdr address) user-mail-address)))
1932                        (save-excursion
1933                          (message-remove-header "From")
1934                          (message-goto-eoh)
1935                          (insert "From: " (message-make-from) "\n"))))
1936                   nil 'local)))))
1937
1938 ;;; Allow redefinition of functions.
1939
1940 (gnus-ems-redefine)
1941
1942 (provide 'gnus-msg)
1943
1944 ;;; arch-tag: 9f22b2f5-1c0a-49de-916e-4c88e984852b
1945 ;;; gnus-msg.el ends here