cgit.sxemacs.org Git - gnus/blob - lisp/gnus-html.el

   1 ;;; gnus-html.el --- Render HTML in a buffer.
   2
   3 ;; Copyright (C) 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html, web
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; The idea is to provide a simple, fast and pretty minimal way to
  26 ;; render HTML (including links and images) in a buffer, based on an
  27 ;; external HTML renderer (i.e., w3m).
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'gnus-art)
  34 (eval-when-compile (require 'mm-decode))
  35
  36 (require 'mm-url)
  37 (require 'url)
  38 (require 'url-cache)
  39 (require 'xml)
  40 (require 'browse-url)
  41 (eval-and-compile (unless (featurep 'xemacs) (require 'help-fns)))
  42
  43 (defcustom gnus-html-image-cache-ttl (days-to-time 7)
  44   "Time used to determine if we should use images from the cache."
  45   :version "24.1"
  46   :group 'gnus-art
  47   :type 'integer)
  48
  49 (defcustom gnus-html-image-automatic-caching t
  50   "Whether automatically cache retrieve images."
  51   :version "24.1"
  52   :group 'gnus-art
  53   :type 'boolean)
  54
  55 (defcustom gnus-html-frame-width 70
  56   "What width to use when rendering HTML."
  57   :version "24.1"
  58   :group 'gnus-art
  59   :type 'integer)
  60
  61 (defcustom gnus-max-image-proportion 0.9
  62   "How big pictures displayed are in relation to the window they're in.
  63 A value of 0.7 means that they are allowed to take up 70% of the
  64 width and height of the window.  If they are larger than this,
  65 and Emacs supports it, then the images will be rescaled down to
  66 fit these criteria."
  67   :version "24.1"
  68   :group 'gnus-art
  69   :type 'float)
  70
  71 (defvar gnus-html-image-map
  72   (let ((map (make-sparse-keymap)))
  73     (define-key map "u" 'gnus-article-copy-string)
  74     (define-key map "i" 'gnus-html-insert-image)
  75     (define-key map "v" 'gnus-html-browse-url)
  76     map))
  77
  78 (defvar gnus-html-displayed-image-map
  79   (let ((map (make-sparse-keymap)))
  80     (define-key map "a" 'gnus-html-show-alt-text)
  81     (define-key map "i" 'gnus-html-browse-image)
  82     (define-key map "\r" 'gnus-html-browse-url)
  83     (define-key map "u" 'gnus-article-copy-string)
  84     (define-key map [tab] 'widget-forward)
  85     map))
  86
  87 (eval-and-compile
  88   (defalias 'gnus-html-encode-url-chars
  89     (if (fboundp 'browse-url-url-encode-chars)
  90         'browse-url-url-encode-chars
  91       (lambda (text chars)
  92         "URL-encode the chars in TEXT that match CHARS.
  93 CHARS is a regexp-like character alternative (e.g., \"[)$]\")."
  94         (let ((encoded-text (copy-sequence text))
  95               (s 0))
  96           (while (setq s (string-match chars encoded-text s))
  97             (setq encoded-text
  98                   (replace-match (format "%%%x"
  99                                          (string-to-char
 100                                           (match-string 0 encoded-text)))
 101                                  t t encoded-text)
 102                   s (1+ s)))
 103           encoded-text)))))
 104
 105 (defun gnus-html-encode-url (url)
 106   "Encode URL."
 107   (gnus-html-encode-url-chars url "[)$ ]"))
 108
 109 (defun gnus-html-cache-expired (url ttl)
 110   "Check if URL is cached for more than TTL."
 111   (cond (url-standalone-mode
 112          (not (file-exists-p (url-cache-create-filename url))))
 113         (t (let ((cache-time (url-is-cached url)))
 114              (if cache-time
 115                  (time-less-p
 116                   (time-add
 117                    cache-time
 118                    ttl)
 119                   (current-time))
 120                t)))))
 121
 122 ;;;###autoload
 123 (defun gnus-article-html (&optional handle)
 124   (let ((article-buffer (current-buffer)))
 125     (unless handle
 126       (setq handle (mm-dissect-buffer t)))
 127     (save-restriction
 128       (narrow-to-region (point) (point))
 129       (save-excursion
 130         (mm-with-part handle
 131           (let* ((coding-system-for-read 'utf-8)
 132                  (coding-system-for-write 'utf-8)
 133                  (default-process-coding-system
 134                    (cons coding-system-for-read coding-system-for-write))
 135                  (charset (mail-content-type-get (mm-handle-type handle)
 136                                                  'charset)))
 137             (when (and charset
 138                        (setq charset (mm-charset-to-coding-system charset))
 139                        (not (eq charset 'ascii)))
 140               (insert (prog1
 141                           (mm-decode-coding-string (buffer-string) charset)
 142                         (erase-buffer)
 143                         (mm-enable-multibyte))))
 144             (call-process-region (point-min) (point-max)
 145                                  "w3m"
 146                                  nil article-buffer nil
 147                                  "-halfdump"
 148                                  "-no-cookie"
 149                                  "-I" "UTF-8"
 150                                  "-O" "UTF-8"
 151                                  "-o" "ext_halfdump=1"
 152                                  "-o" "display_ins_del=2"
 153                                  "-o" "pre_conv=1"
 154                                  "-t" (format "%s" tab-width)
 155                                  "-cols" (format "%s" gnus-html-frame-width)
 156                                  "-o" "display_image=on"
 157                                  "-T" "text/html"))))
 158       (gnus-html-wash-tags))))
 159
 160 (defvar gnus-article-mouse-face)
 161
 162 (defun gnus-html-pre-wash ()
 163   (goto-char (point-min))
 164   (while (re-search-forward " *<pre_int> *</pre_int> *\n" nil t)
 165     (replace-match "" t t))
 166   (goto-char (point-min))
 167   (while (re-search-forward "<a name[^\n>]+>" nil t)
 168     (replace-match "" t t)))
 169
 170 (defun gnus-html-wash-images ()
 171   "Run through current buffer and replace img tags by images."
 172   (let (tag parameters string start end images url)
 173     (goto-char (point-min))
 174     ;; Search for all the images first.
 175     (while (re-search-forward "<img_alt \\([^>]*\\)>" nil t)
 176       (setq parameters (match-string 1)
 177             start (match-beginning 0))
 178       (delete-region start (point))
 179       (when (search-forward "</img_alt>" (line-end-position) t)
 180         (delete-region (match-beginning 0) (match-end 0)))
 181       (setq end (point))
 182       (when (string-match "src=\"\\([^\"]+\\)" parameters)
 183         (setq url (gnus-html-encode-url (match-string 1 parameters)))
 184         (gnus-message 8 "gnus-html-wash-tags: fetching image URL %s" url)
 185         (if (string-match "^cid:\\(.*\\)" url)
 186             ;; URLs with cid: have their content stashed in other
 187             ;; parts of the MIME structure, so just insert them
 188             ;; immediately.
 189             (let* ((handle (mm-get-content-id
 190                             (setq url (match-string 1 url))))
 191                    (image (when handle
 192                             (gnus-create-image
 193                              (mm-with-part handle (buffer-string))
 194                              nil t))))
 195               (when image
 196                 (let ((string (buffer-substring start end)))
 197                   (delete-region start end)
 198                   (gnus-put-image (gnus-rescale-image
 199                                    image (gnus-html-maximum-image-size))
 200                                   (gnus-string-or string "*") 'cid)
 201                   (gnus-add-image 'cid image))))
 202           ;; Normal, external URL.
 203           (let ((alt-text
 204                  (when (string-match "\\(alt\\|title\\)=\"\\([^\"]+\\)"
 205                                      parameters)
 206                    (xml-substitute-special (match-string 2 parameters)))))
 207             (gnus-put-text-property start end 'image-url url)
 208             (gnus-put-text-property
 209              start end 'image-displayer
 210              (lambda (url start end)
 211                (gnus-html-display-image url start end)))
 212             (if (gnus-html-image-url-blocked-p
 213                  url
 214                  (if (buffer-live-p gnus-summary-buffer)
 215                      (with-current-buffer gnus-summary-buffer
 216                        (gnus-blocked-images))
 217                    (gnus-blocked-images)))
 218                 (progn
 219                   (widget-convert-button
 220                    'link start end
 221                    :action 'gnus-html-insert-image
 222                    :help-echo url
 223                    :keymap gnus-html-image-map
 224                    :button-keymap gnus-html-image-map)
 225                   (let ((overlay (gnus-make-overlay start end))
 226                         (spec (list url start end alt-text)))
 227                     (gnus-overlay-put overlay 'local-map gnus-html-image-map)
 228                     (gnus-overlay-put overlay 'gnus-image spec)
 229                     (gnus-put-text-property
 230                      start end
 231                      'gnus-image spec)))
 232               ;; Non-blocked url
 233               (let ((width
 234                      (when (string-match "width=\"?\\([0-9]+\\)" parameters)
 235                        (string-to-number (match-string 1 parameters))))
 236                     (height
 237                      (when (string-match "height=\"?\\([0-9]+\\)" parameters)
 238                        (string-to-number (match-string 1 parameters)))))
 239                 ;; Don't fetch images that are really small.  They're
 240                 ;; probably tracking pictures.
 241                 (when (and (or (null height)
 242                                (> height 4))
 243                            (or (null width)
 244                                (> width 4)))
 245                   (gnus-html-display-image url start end alt-text))))))))))
 246
 247 (defun gnus-html-display-image (url start end &optional alt-text)
 248   "Display image at URL on text from START to END.
 249 Use ALT-TEXT for the image string."
 250   (if (gnus-html-cache-expired url gnus-html-image-cache-ttl)
 251       ;; We don't have it, so schedule it for fetching
 252       ;; asynchronously.
 253       (gnus-html-schedule-image-fetching
 254        (current-buffer)
 255        (list url alt-text))
 256     ;; It's already cached, so just insert it.
 257     (gnus-html-put-image (gnus-html-get-image-data url) url (or alt-text "*"))))
 258
 259 (defun gnus-html-wash-tags ()
 260   (let (tag parameters string start end images url)
 261     (gnus-html-pre-wash)
 262     (gnus-html-wash-images)
 263
 264     (goto-char (point-min))
 265     ;; Then do the other tags.
 266     (while (re-search-forward "<\\([^ />]+\\)\\([^>]*\\)>" nil t)
 267       (setq tag (match-string 1)
 268             parameters (match-string 2)
 269             start (match-beginning 0))
 270       (when (> (length parameters) 0)
 271         (set-text-properties 0 (1- (length parameters)) nil parameters))
 272       (delete-region start (point))
 273       (when (search-forward (concat "</" tag ">") nil t)
 274         (delete-region (match-beginning 0) (match-end 0)))
 275       (setq end (point))
 276       (cond
 277        ;; Fetch and insert a picture.
 278        ((equal tag "img_alt"))
 279        ;; Add a link.
 280        ((or (equal tag "a")
 281             (equal tag "A"))
 282         (when (string-match "href=\"\\([^\"]+\\)" parameters)
 283           (setq url (match-string 1 parameters))
 284           (gnus-message 8 "gnus-html-wash-tags: fetching link URL %s" url)
 285           (gnus-article-add-button start end
 286                                    'browse-url (mm-url-decode-entities-string url)
 287                                    url)
 288           (let ((overlay (gnus-make-overlay start end)))
 289             (gnus-overlay-put overlay 'evaporate t)
 290             (gnus-overlay-put overlay 'gnus-button-url url)
 291             (gnus-put-text-property start end 'gnus-string url)
 292             (when gnus-article-mouse-face
 293               (gnus-overlay-put overlay 'mouse-face gnus-article-mouse-face)))))
 294        ;; The upper-case IMG_ALT is apparently just an artifact that
 295        ;; should be deleted.
 296        ((equal tag "IMG_ALT")
 297         (delete-region start end))
 298        ;; w3m does not normalize the case
 299        ((or (equal tag "b")
 300             (equal tag "B"))
 301         (gnus-overlay-put (gnus-make-overlay start end) 'face 'gnus-emphasis-bold))
 302        ((or (equal tag "u")
 303             (equal tag "U"))
 304         (gnus-overlay-put (gnus-make-overlay start end) 'face 'gnus-emphasis-underline))
 305        ((or (equal tag "i")
 306             (equal tag "I"))
 307         (gnus-overlay-put (gnus-make-overlay start end) 'face 'gnus-emphasis-italic))
 308        ((or (equal tag "s")
 309             (equal tag "S"))
 310         (gnus-overlay-put (gnus-make-overlay start end) 'face 'gnus-emphasis-strikethru))
 311        ((or (equal tag "ins")
 312             (equal tag "INS"))
 313         (gnus-overlay-put (gnus-make-overlay start end) 'face 'gnus-emphasis-underline))
 314        ;; Handle different UL types
 315        ((equal tag "_SYMBOL")
 316         (when (string-match "TYPE=\\(.+\\)" parameters)
 317           (let ((type (string-to-number (match-string 1 parameters))))
 318             (delete-region start end)
 319             (cond ((= type 33) (insert " "))
 320                   ((= type 34) (insert " "))
 321                   ((= type 35) (insert " "))
 322                   ((= type 36) (insert " "))
 323                   ((= type 37) (insert " "))
 324                   ((= type 38) (insert " "))
 325                   ((= type 39) (insert " "))
 326                   ((= type 40) (insert " "))
 327                   ((= type 42) (insert " "))
 328                   ((= type 43) (insert " "))
 329                   (t (insert " "))))))
 330        ;; Whatever.  Just ignore the tag.
 331        (t
 332         ))
 333       (goto-char start))
 334     (goto-char (point-min))
 335     ;; The output from -halfdump isn't totally regular, so strip
 336     ;; off any </pre_int>s that were left over.
 337     (while (re-search-forward "</pre_int>\\|</internal>" nil t)
 338       (replace-match "" t t))
 339     (mm-url-decode-entities)))
 340
 341 (defun gnus-html-insert-image ()
 342   "Fetch and insert the image under point."
 343   (interactive)
 344   (apply 'gnus-html-display-image (get-text-property (point) 'gnus-image)))
 345
 346 (defun gnus-html-show-alt-text ()
 347   "Show the ALT text of the image under point."
 348   (interactive)
 349   (message "%s" (get-text-property (point) 'gnus-alt-text)))
 350
 351 (defun gnus-html-browse-image ()
 352   "Browse the image under point."
 353   (interactive)
 354   (browse-url (get-text-property (point) 'image-url)))
 355
 356 (defun gnus-html-browse-url ()
 357   "Browse the image under point."
 358   (interactive)
 359   (let ((url (get-text-property (point) 'gnus-string)))
 360     (cond
 361      ((not url)
 362       (message "No link under point"))
 363      ((string-match "^mailto:" url)
 364       (gnus-url-mailto url))
 365      (t
 366       (browse-url url)))))
 367
 368 (defun gnus-html-schedule-image-fetching (buffer image)
 369   "Retrieve IMAGE, and place it into BUFFER on arrival."
 370   (gnus-message 8 "gnus-html-schedule-image-fetching: buffer %s, image %s"
 371                 buffer image)
 372   (let ((args (list (car image)
 373                     'gnus-html-image-fetched
 374                     (list buffer image))))
 375     (when (> (length (if (featurep 'xemacs)
 376                          (cdr (split-string (function-arglist 'url-retrieve)))
 377                        (help-function-arglist 'url-retrieve)))
 378              4)
 379       (setq args (nconc args (list t))))
 380     (ignore-errors
 381       (apply #'url-retrieve args))))
 382
 383 (defun gnus-html-image-fetched (status buffer image)
 384   "Callback function called when image has been fetched."
 385   (unless (plist-get status :error)
 386     (when gnus-html-image-automatic-caching
 387       (url-store-in-cache (current-buffer)))
 388     (when (and (or (search-forward "\n\n" nil t)
 389                    (search-forward "\r\n\r\n" nil t))
 390                (buffer-live-p buffer))
 391       (let ((data (buffer-substring (point) (point-max))))
 392         (with-current-buffer buffer
 393           (let ((inhibit-read-only t))
 394             (gnus-html-put-image data (car image) (cadr image)))))))
 395   (kill-buffer (current-buffer)))
 396
 397 (defun gnus-html-get-image-data (url)
 398   "Get image data for URL.
 399 Return a string with image data."
 400   (with-temp-buffer
 401     (mm-disable-multibyte)
 402     (url-cache-extract (url-cache-create-filename url))
 403     (when (or (search-forward "\n\n" nil t)
 404               (search-forward "\r\n\r\n" nil t))
 405       (buffer-substring (point) (point-max)))))
 406
 407 (defun gnus-html-maximum-image-size ()
 408   "Return the maximum size of an image according to `gnus-max-image-proportion'."
 409   (let ((edges (gnus-window-inside-pixel-edges
 410                 (get-buffer-window (current-buffer)))))
 411     ;; (width . height)
 412     (cons
 413      ;; Aimed width
 414      (truncate
 415       (* gnus-max-image-proportion
 416          (- (nth 2 edges) (nth 0 edges))))
 417      ;; Aimed height
 418      (truncate (* gnus-max-image-proportion
 419                   (- (nth 3 edges) (nth 1 edges)))))))
 420
 421 (defun gnus-html-put-image (data url &optional alt-text)
 422   "Put an image with DATA from URL and optional ALT-TEXT."
 423   (when (gnus-graphic-display-p)
 424     (let* ((start (text-property-any (point-min) (point-max)
 425                                      'image-url url))
 426            (end (when start
 427                   (next-single-property-change start 'image-url))))
 428       ;; Image found?
 429       (when start
 430         (let* ((image
 431                 (ignore-errors
 432                   (gnus-create-image data nil t)))
 433                (size (and image
 434                           (if (featurep 'xemacs)
 435                               (cons (glyph-width image) (glyph-height image))
 436                             (image-size image t)))))
 437           (save-excursion
 438             (goto-char start)
 439             (let ((alt-text (or alt-text
 440                                 (buffer-substring-no-properties start end))))
 441               (if (and image
 442                        ;; Kludge to avoid displaying 30x30 gif images, which
 443                        ;; seems to be a signal of a broken image.
 444                        (not (and (if (featurep 'xemacs)
 445                                      (glyphp image)
 446                                    (listp image))
 447                                  (eq (if (featurep 'xemacs)
 448                                          (let ((d (cdadar
 449                                                    (specifier-spec-list
 450                                                     (glyph-image image)))))
 451                                            (and (vectorp d)
 452                                                 (aref d 0)))
 453                                        (plist-get (cdr image) :type))
 454                                      'gif)
 455                                  (= (car size) 30)
 456                                  (= (cdr size) 30))))
 457                   ;; Good image, add it!
 458                   (let ((image (gnus-rescale-image image (gnus-html-maximum-image-size))))
 459                     (delete-region start end)
 460                     (gnus-put-image image alt-text 'external)
 461                     (gnus-put-text-property start (point) 'help-echo alt-text)
 462                     (gnus-overlay-put
 463                      (gnus-make-overlay start (point)) 'local-map
 464                      gnus-html-displayed-image-map)
 465                     (gnus-put-text-property start (point)
 466                                             'gnus-alt-text alt-text)
 467                     (when url
 468                       (gnus-put-text-property start (point)
 469                                               'image-url url))
 470                     (gnus-add-image 'external image)
 471                     t)
 472                 ;; Bad image, try to show something else
 473                 (when (fboundp 'find-image)
 474                   (delete-region start end)
 475                   (setq image (find-image
 476                                '((:type xpm :file "lock-broken.xpm"))))
 477                   (gnus-put-image image alt-text 'internal)
 478                   (gnus-add-image 'internal image))
 479                 nil))))))))
 480
 481 (defun gnus-html-image-url-blocked-p (url blocked-images)
 482   "Find out if URL is blocked by BLOCKED-IMAGES."
 483   (let ((ret (and blocked-images
 484                   (string-match blocked-images url))))
 485     (if ret
 486         (gnus-message 8 "gnus-html-image-url-blocked-p: %s blocked by regex %s"
 487                       url blocked-images)
 488       (gnus-message 9 "gnus-html-image-url-blocked-p: %s passes regex %s"
 489                     url blocked-images))
 490     ret))
 491
 492 ;;;###autoload
 493 (defun gnus-html-prefetch-images (summary)
 494   (when (buffer-live-p summary)
 495     (let ((blocked-images (with-current-buffer summary
 496                             (gnus-blocked-images))))
 497       (save-match-data
 498         (while (re-search-forward "<img[^>]+src=[\"']\\(http[^\"']+\\)" nil t)
 499           (let ((url (gnus-html-encode-url
 500                       (mm-url-decode-entities-string (match-string 1)))))
 501             (unless (gnus-html-image-url-blocked-p url blocked-images)
 502               (when (gnus-html-cache-expired url gnus-html-image-cache-ttl)
 503                 (gnus-html-schedule-image-fetching nil
 504                                                    (list url))))))))))
 505
 506 (provide 'gnus-html)
 507
 508 ;;; gnus-html.el ends here