cgit.sxemacs.org Git - gnus/blob - lisp/flow-fill.el

   1 ;;; flow-fill.el --- interprete RFC2646 "flowed" text
   2
   3 ;; Copyright (C) 2000, 2001, 2002 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   6 ;; Keywords: mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This implement decoding of RFC2646 formatted text, including the
  28 ;; quoted-depth wins rules.
  29
  30 ;; Theory of operation: search for lines ending with SPC, save quote
  31 ;; length of line, remove SPC and concatenate line with the following
  32 ;; line if quote length of following line matches current line.
  33
  34 ;; When no further concatenations are possible, we've found a
  35 ;; paragraph and we let `fill-region' fill the long line into several
  36 ;; lines with the quote prefix as `fill-prefix'.
  37
  38 ;; Todo: implement basic `fill-region' (Emacs and XEmacs
  39 ;;       implementations differ..)
  40
  41 ;;; History:
  42
  43 ;; 2000-02-17  posted on ding mailing list
  44 ;; 2000-02-19  use `point-at-{b,e}ol' in XEmacs
  45 ;; 2000-03-11  no compile warnings for point-at-bol stuff
  46 ;; 2000-03-26  committed to gnus cvs
  47 ;; 2000-10-23  don't flow "-- " lines, make "quote-depth wins" rule
  48 ;;             work when first line is at level 0.
  49 ;; 2002-01-12  probably incomplete encoding support
  50
  51 ;;; Code:
  52
  53 (eval-when-compile (require 'cl))
  54
  55 (defcustom fill-flowed-display-column 'fill-column
  56   "Column beyond which format=flowed lines are wrapped, when displayed.
  57 This can be a lisp expression or an integer."
  58   :type '(choice (const :tag "Standard `fill-column'" fill-column)
  59                  (const :tag "Fit Window" (- (window-width) 5))
  60                  (sexp)
  61                  (integer)))
  62
  63 (defcustom fill-flowed-encode-column 66
  64   "Column beyond which format=flowed lines are wrapped, in outgoing messages.
  65 This can be a lisp expression or an integer.
  66 RFC 2646 suggests 66 characters for readability."
  67   :type '(choice (const :tag "Standard fill-column" fill-column)
  68                  (const :tag "RFC 2646 default (66)" 66)
  69                  (sexp)
  70                  (integer)))
  71
  72 (eval-and-compile
  73   (defalias 'fill-flowed-point-at-bol
  74         (if (fboundp 'point-at-bol)
  75             'point-at-bol
  76           'line-beginning-position))
  77
  78    (defalias 'fill-flowed-point-at-eol
  79         (if (fboundp 'point-at-eol)
  80             'point-at-eol
  81           'line-end-position)))
  82
  83 (defun fill-flowed-encode (&optional buffer)
  84   (with-current-buffer (or buffer (current-buffer))
  85     ;; No point in doing this unless hard newlines is used.
  86     (when use-hard-newlines
  87       (let ((start (point-min)) end)
  88         ;; Go through each paragraph, filling it and adding SPC
  89         ;; as the last character on each line.
  90         (while (setq end (text-property-any start (point-max) 'hard 't))
  91           (let ((fill-column (eval fill-flowed-encode-column)))
  92             (fill-region start end t 'nosqueeze 'to-eop))
  93           (goto-char start)
  94           ;; `fill-region' probably distorted end.
  95           (setq end (text-property-any start (point-max) 'hard 't))
  96           (while (and (< (point) end)
  97                       (re-search-forward "$" (1- end) t))
  98             (insert " ")
  99             (setq end (1+ end))
 100             (forward-char))
 101           (goto-char (setq start (1+ end)))))
 102       t)))
 103
 104 (defun fill-flowed (&optional buffer)
 105   (save-excursion
 106     (set-buffer (or (current-buffer) buffer))
 107     (goto-char (point-min))
 108     (while (re-search-forward " $" nil t)
 109       (when (save-excursion
 110               (beginning-of-line)
 111               (looking-at "^\\(>*\\)\\( ?\\)"))
 112         (let ((quote (match-string 1))
 113               sig)
 114           (if (string= quote "")
 115               (setq quote nil))
 116           (when (and quote (string= (match-string 2) ""))
 117             (save-excursion
 118               ;; insert SP after quote for pleasant reading of quoted lines
 119               (beginning-of-line)
 120               (when (> (skip-chars-forward ">") 0)
 121                 (insert " "))))
 122           ;; XXX slightly buggy handling of "-- "
 123           (while (and (save-excursion
 124                         (ignore-errors (backward-char 3))
 125                         (setq sig (looking-at "-- "))
 126                         (looking-at "[^-][^-] "))
 127                       (save-excursion
 128                         (unless (eobp)
 129                           (forward-char 1)
 130                           (looking-at (format "^\\(%s\\)\\([^>]\\)"
 131                                               (or quote " ?"))))))
 132             (save-excursion
 133               (replace-match (if (string= (match-string 2) " ")
 134                                  "" "\\2")))
 135             (backward-delete-char -1)
 136             (end-of-line))
 137           (unless sig
 138             (condition-case nil
 139                 (let ((fill-prefix (when quote (concat quote " ")))
 140                       (fill-column (eval fill-flowed-display-column))
 141                       filladapt-mode)
 142                   (fill-region (fill-flowed-point-at-bol)
 143                                (min (1+ (fill-flowed-point-at-eol))
 144                                     (point-max))
 145                                'left 'nosqueeze))
 146               (error
 147                (forward-line 1)
 148                nil))))))))
 149
 150 (provide 'flow-fill)
 151
 152 ;;; flow-fill.el ends here