cgit.sxemacs.org Git - gnus/blob - lisp/binhex.el

   1 ;;; binhex.el --- elisp native binhex decode
   2 ;; Copyright (c) 1998, 1999, 2000, 2001, 2002, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Shenghuo Zhu <zsh@cs.rochester.edu>
   6 ;; Keywords: binhex news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (eval-and-compile
  32   (defalias 'binhex-char-int
  33     (if (fboundp 'char-int)
  34         'char-int
  35       'identity)))
  36
  37 (defcustom binhex-decoder-program "hexbin"
  38   "*Non-nil value should be a string that names a binhex decoder.
  39 The program should expect to read binhex data on its standard
  40 input and write the converted data to its standard output."
  41   :type 'string
  42   :group 'gnus-extract)
  43
  44 (defcustom binhex-decoder-switches '("-d")
  45   "*List of command line flags passed to the command `binhex-decoder-program'."
  46   :group 'gnus-extract
  47   :type '(repeat string))
  48
  49 (defcustom binhex-use-external
  50   (executable-find binhex-decoder-program)
  51   "*Use external binhex program."
  52   :version "21.4"
  53   :group 'gnus-extract
  54   :type 'boolean)
  55
  56 (defconst binhex-alphabet-decoding-alist
  57   '(( ?\! . 0) ( ?\" . 1) ( ?\# . 2) ( ?\$ . 3) ( ?\% . 4) ( ?\& . 5)
  58     ( ?\' . 6) ( ?\( . 7) ( ?\) . 8) ( ?\* . 9) ( ?\+ . 10) ( ?\, . 11)
  59     ( ?\- . 12) ( ?0 . 13) ( ?1 . 14) ( ?2 . 15) ( ?3 . 16) ( ?4 . 17)
  60     ( ?5 . 18) ( ?6 . 19) ( ?8 . 20) ( ?9 . 21) ( ?@ . 22) ( ?A . 23)
  61     ( ?B . 24) ( ?C . 25) ( ?D . 26) ( ?E . 27) ( ?F . 28) ( ?G . 29)
  62     ( ?H . 30) ( ?I . 31) ( ?J . 32) ( ?K . 33) ( ?L . 34) ( ?M . 35)
  63     ( ?N . 36) ( ?P . 37) ( ?Q . 38) ( ?R . 39) ( ?S . 40) ( ?T . 41)
  64     ( ?U . 42) ( ?V . 43) ( ?X . 44) ( ?Y . 45) ( ?Z . 46) ( ?\[ . 47)
  65     ( ?\` . 48) ( ?a . 49) ( ?b . 50) ( ?c . 51) ( ?d . 52) ( ?e . 53)
  66     ( ?f . 54) ( ?h . 55) ( ?i . 56) ( ?j . 57) ( ?k . 58) ( ?l . 59)
  67     ( ?m . 60) ( ?p . 61) ( ?q . 62) ( ?r . 63)))
  68
  69 (defun binhex-char-map (char)
  70   (cdr (assq char binhex-alphabet-decoding-alist)))
  71
  72 ;;;###autoload
  73 (defconst binhex-begin-line
  74   "^:...............................................................$")
  75 (defconst binhex-body-line
  76   "^[^:]...............................................................$")
  77 (defconst binhex-end-line ":$")
  78
  79 (defvar binhex-temporary-file-directory
  80   (cond ((fboundp 'temp-directory) (temp-directory))
  81         ((boundp 'temporary-file-directory) temporary-file-directory)
  82         ("/tmp/")))
  83
  84 (eval-and-compile
  85   (defalias 'binhex-insert-char
  86     (if (featurep 'xemacs)
  87         'insert-char
  88       (lambda (char &optional count ignored buffer)
  89         "Insert COUNT copies of CHARACTER into BUFFER."
  90         (if (or (null buffer) (eq buffer (current-buffer)))
  91             (insert-char char count)
  92           (with-current-buffer buffer
  93             (insert-char char count)))))))
  94
  95 (defvar binhex-crc-table
  96   [0  4129  8258  12387  16516  20645  24774  28903
  97       33032  37161  41290  45419  49548  53677  57806  61935
  98       4657  528  12915  8786  21173  17044  29431  25302
  99       37689  33560  45947  41818  54205  50076  62463  58334
 100       9314  13379  1056  5121  25830  29895  17572  21637
 101       42346  46411  34088  38153  58862  62927  50604  54669
 102       13907  9842  5649  1584  30423  26358  22165  18100
 103       46939  42874  38681  34616  63455  59390  55197  51132
 104       18628  22757  26758  30887  2112  6241  10242  14371
 105       51660  55789  59790  63919  35144  39273  43274  47403
 106       23285  19156  31415  27286  6769  2640  14899  10770
 107       56317  52188  64447  60318  39801  35672  47931  43802
 108       27814  31879  19684  23749  11298  15363  3168  7233
 109       60846  64911  52716  56781  44330  48395  36200  40265
 110       32407  28342  24277  20212  15891  11826  7761  3696
 111       65439  61374  57309  53244  48923  44858  40793  36728
 112       37256  33193  45514  41451  53516  49453  61774  57711
 113       4224  161  12482  8419  20484  16421  28742  24679
 114       33721  37784  41979  46042  49981  54044  58239  62302
 115       689  4752  8947  13010  16949  21012  25207  29270
 116       46570  42443  38312  34185  62830  58703  54572  50445
 117       13538  9411  5280  1153  29798  25671  21540  17413
 118       42971  47098  34713  38840  59231  63358  50973  55100
 119       9939  14066  1681  5808  26199  30326  17941  22068
 120       55628  51565  63758  59695  39368  35305  47498  43435
 121       22596  18533  30726  26663  6336  2273  14466  10403
 122       52093  56156  60223  64286  35833  39896  43963  48026
 123       19061  23124  27191  31254  2801  6864  10931  14994
 124       64814  60687  56684  52557  48554  44427  40424  36297
 125       31782  27655  23652  19525  15522  11395  7392  3265
 126       61215  65342  53085  57212  44955  49082  36825  40952
 127       28183  32310  20053  24180  11923  16050  3793  7920])
 128
 129 (defun binhex-update-crc (crc char &optional count)
 130   (if (null count) (setq count 1))
 131   (while (> count 0)
 132     (setq crc (logxor (logand (lsh crc 8) 65280)
 133                       (aref binhex-crc-table
 134                             (logxor (logand (lsh crc -8) 255)
 135                                     char)))
 136           count (1- count)))
 137   crc)
 138
 139 (defun binhex-verify-crc (buffer start end)
 140   (with-current-buffer buffer
 141     (let ((pos start) (crc 0) (last (- end 2)))
 142       (while (< pos last)
 143         (setq crc (binhex-update-crc crc (char-after pos))
 144               pos (1+ pos)))
 145       (if (= crc (binhex-string-big-endian (buffer-substring last end)))
 146           nil
 147         (error "CRC error")))))
 148
 149 (defun binhex-string-big-endian (string)
 150   (let ((ret 0) (i 0) (len (length string)))
 151     (while (< i len)
 152       (setq ret (+ (lsh ret 8) (binhex-char-int (aref string i)))
 153             i (1+ i)))
 154     ret))
 155
 156 (defun binhex-string-little-endian (string)
 157   (let ((ret 0) (i 0) (shift 0) (len (length string)))
 158     (while (< i len)
 159       (setq ret (+ ret (lsh (binhex-char-int (aref string i)) shift))
 160             i (1+ i)
 161             shift (+ shift 8)))
 162     ret))
 163
 164 (defun binhex-header (buffer)
 165   (with-current-buffer buffer
 166     (let ((pos (point-min)) len)
 167       (vector
 168        (prog1
 169            (setq len (binhex-char-int (char-after pos)))
 170          (setq pos (1+ pos)))
 171        (buffer-substring pos (setq pos (+ pos len)))
 172        (prog1
 173            (setq len (binhex-char-int (char-after pos)))
 174          (setq pos (1+ pos)))
 175        (buffer-substring pos (setq pos (+ pos 4)))
 176        (buffer-substring pos (setq pos (+ pos 4)))
 177        (binhex-string-big-endian
 178         (buffer-substring pos (setq pos (+ pos 2))))
 179        (binhex-string-big-endian
 180         (buffer-substring pos (setq pos (+ pos 4))))
 181        (binhex-string-big-endian
 182         (buffer-substring pos (setq pos (+ pos 4))))))))
 183
 184 (defvar binhex-last-char)
 185 (defvar binhex-repeat)
 186
 187 (defun binhex-push-char (char &optional count ignored buffer)
 188   (cond
 189    (binhex-repeat
 190     (if (eq char 0)
 191         (binhex-insert-char (setq binhex-last-char 144) 1
 192                             ignored buffer)
 193       (binhex-insert-char binhex-last-char (- char 1)
 194                           ignored buffer)
 195       (setq binhex-last-char nil))
 196     (setq binhex-repeat nil))
 197    ((= char 144)
 198     (setq binhex-repeat t))
 199    (t
 200     (binhex-insert-char (setq binhex-last-char char) 1 ignored buffer))))
 201
 202 ;;;###autoload
 203 (defun binhex-decode-region-internal (start end &optional header-only)
 204   "Binhex decode region between START and END without using an external program.
 205 If HEADER-ONLY is non-nil only decode header and return filename."
 206   (interactive "r")
 207   (let ((work-buffer nil)
 208         (counter 0)
 209         (bits 0) (tmp t)
 210         (lim 0) inputpos
 211         (non-data-chars " \t\n\r:")
 212         file-name-length data-fork-start
 213         header
 214         binhex-last-char binhex-repeat)
 215     (unwind-protect
 216         (save-excursion
 217           (goto-char start)
 218           (when (re-search-forward binhex-begin-line end t)
 219             (let (default-enable-multibyte-characters)
 220               (setq work-buffer (generate-new-buffer " *binhex-work*")))
 221             (beginning-of-line)
 222             (setq bits 0 counter 0)
 223             (while tmp
 224               (skip-chars-forward non-data-chars end)
 225               (setq inputpos (point))
 226               (end-of-line)
 227               (setq lim (point))
 228               (while (and (< inputpos lim)
 229                           (setq tmp (binhex-char-map (char-after inputpos))))
 230                 (setq bits (+ bits tmp)
 231                       counter (1+ counter)
 232                       inputpos (1+ inputpos))
 233                 (cond ((= counter 4)
 234                        (binhex-push-char (lsh bits -16) 1 nil work-buffer)
 235                        (binhex-push-char (logand (lsh bits -8) 255) 1 nil
 236                                          work-buffer)
 237                        (binhex-push-char (logand bits 255) 1 nil
 238                                          work-buffer)
 239                        (setq bits 0 counter 0))
 240                       (t (setq bits (lsh bits 6)))))
 241               (if (null file-name-length)
 242                   (with-current-buffer work-buffer
 243                     (setq file-name-length (char-after (point-min))
 244                           data-fork-start (+ (point-min)
 245                                              file-name-length 22))))
 246               (when (and (null header)
 247                          (with-current-buffer work-buffer
 248                            (>= (buffer-size) data-fork-start)))
 249                 (binhex-verify-crc work-buffer
 250                                    (point-min) data-fork-start)
 251                 (setq header (binhex-header work-buffer))
 252                 (when header-only (setq tmp nil counter 0)))
 253               (setq tmp (and tmp (not (eq inputpos end)))))
 254             (cond
 255              ((= counter 3)
 256               (binhex-push-char (logand (lsh bits -16) 255) 1 nil
 257                                 work-buffer)
 258               (binhex-push-char (logand (lsh bits -8) 255) 1 nil
 259                                 work-buffer))
 260              ((= counter 2)
 261               (binhex-push-char (logand (lsh bits -10) 255) 1 nil
 262                                 work-buffer))))
 263           (if header-only nil
 264             (binhex-verify-crc work-buffer
 265                                data-fork-start
 266                                (+ data-fork-start (aref header 6) 2))
 267             (or (markerp end) (setq end (set-marker (make-marker) end)))
 268             (goto-char start)
 269             (insert-buffer-substring work-buffer
 270                                      data-fork-start (+ data-fork-start
 271                                                         (aref header 6)))
 272             (delete-region (point) end)))
 273       (and work-buffer (kill-buffer work-buffer)))
 274     (if header (aref header 1))))
 275
 276 ;;;###autoload
 277 (defun binhex-decode-region-external (start end)
 278   "Binhex decode region between START and END using external decoder."
 279   (interactive "r")
 280   (let ((cbuf (current-buffer)) firstline work-buffer status
 281         (file-name (expand-file-name
 282                     (concat (binhex-decode-region-internal start end t)
 283                             ".data")
 284                     binhex-temporary-file-directory)))
 285     (save-excursion
 286       (goto-char start)
 287       (when (re-search-forward binhex-begin-line nil t)
 288         (let ((cdir default-directory) default-process-coding-system)
 289           (unwind-protect
 290               (progn
 291                 (set-buffer (setq work-buffer
 292                                   (generate-new-buffer " *binhex-work*")))
 293                 (buffer-disable-undo work-buffer)
 294                 (insert-buffer-substring cbuf firstline end)
 295                 (cd binhex-temporary-file-directory)
 296                 (apply 'call-process-region
 297                        (point-min)
 298                        (point-max)
 299                        binhex-decoder-program
 300                        nil
 301                        nil
 302                        nil
 303                        binhex-decoder-switches))
 304             (cd cdir) (set-buffer cbuf)))
 305         (if (and file-name (file-exists-p file-name))
 306             (progn
 307               (goto-char start)
 308               (delete-region start end)
 309               (let (format-alist)
 310                 (insert-file-contents-literally file-name)))
 311           (error "Can not binhex")))
 312       (and work-buffer (kill-buffer work-buffer))
 313       (ignore-errors
 314         (if file-name (delete-file file-name))))))
 315
 316 ;;;###autoload
 317 (defun binhex-decode-region (start end)
 318   "Binhex decode region between START and END."
 319   (interactive "r")
 320   (if binhex-use-external
 321       (binhex-decode-region-external start end)
 322     (binhex-decode-region-internal start end)))
 323
 324 (provide 'binhex)
 325
 326 ;;; arch-tag: 8476badd-1e76-4f1d-a640-f9a38c72eed8
 327 ;;; binhex.el ends here