cgit.sxemacs.org Git - gnus/blob - lisp/auth-source.el

   1 ;;; auth-source.el --- authentication sources for Gnus and Emacs
   2
   3 ;; Copyright (C) 2008-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Ted Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This is the auth-source.el package.  It lets users tell Gnus how to
  26 ;; authenticate in a single place.  Simplicity is the goal.  Instead
  27 ;; of providing 5000 options, we'll stick to simple, easy to
  28 ;; understand options.
  29
  30 ;; See the auth.info Info documentation for details.
  31
  32 ;; TODO:
  33
  34 ;; - never decode the backend file unless it's necessary
  35 ;; - a more generic way to match backends and search backend contents
  36 ;; - absorb netrc.el and simplify it
  37 ;; - protect passwords better
  38 ;; - allow creating and changing netrc lines (not files) e.g. change a password
  39
  40 ;;; Code:
  41
  42 (require 'password-cache)
  43 (require 'mm-util)
  44 (require 'gnus-util)
  45 (require 'netrc)
  46 (require 'assoc)
  47 (eval-when-compile (require 'cl))
  48 (eval-and-compile
  49   (or (ignore-errors (require 'eieio))
  50       ;; gnus-fallback-lib/ from gnus/lisp/gnus-fallback-lib
  51       (ignore-errors
  52         (let ((load-path (cons (expand-file-name
  53                                 "gnus-fallback-lib/eieio"
  54                                 (file-name-directory (locate-library "gnus")))
  55                                load-path)))
  56           (require 'eieio)))
  57       (error
  58        "eieio not found in `load-path' or gnus-fallback-lib/ directory.")))
  59
  60 (autoload 'secrets-create-item "secrets")
  61 (autoload 'secrets-delete-item "secrets")
  62 (autoload 'secrets-get-alias "secrets")
  63 (autoload 'secrets-get-attributes "secrets")
  64 (autoload 'secrets-get-secret "secrets")
  65 (autoload 'secrets-list-collections "secrets")
  66 (autoload 'secrets-search-items "secrets")
  67
  68 (defvar secrets-enabled)
  69
  70 (defgroup auth-source nil
  71   "Authentication sources."
  72   :version "23.1" ;; No Gnus
  73   :group 'gnus)
  74
  75 ;;;###autoload
  76 (defcustom auth-source-cache-expiry 7200
  77   "How many seconds passwords are cached, or nil to disable
  78 expiring.  Overrides `password-cache-expiry' through a
  79 let-binding."
  80   :group 'auth-source
  81   :type '(choice (const :tag "Never" nil)
  82                  (const :tag "All Day" 86400)
  83                  (const :tag "2 Hours" 7200)
  84                  (const :tag "30 Minutes" 1800)
  85                  (integer :tag "Seconds")))
  86
  87 (defclass auth-source-backend ()
  88   ((type :initarg :type
  89          :initform 'netrc
  90          :type symbol
  91          :custom symbol
  92          :documentation "The backend type.")
  93    (source :initarg :source
  94            :type string
  95            :custom string
  96            :documentation "The backend source.")
  97    (host :initarg :host
  98          :initform t
  99          :type t
 100          :custom string
 101          :documentation "The backend host.")
 102    (user :initarg :user
 103          :initform t
 104          :type t
 105          :custom string
 106          :documentation "The backend user.")
 107    (port :initarg :port
 108          :initform t
 109          :type t
 110          :custom string
 111          :documentation "The backend protocol.")
 112    (create-function :initarg :create-function
 113                     :initform ignore
 114                     :type function
 115                     :custom function
 116                     :documentation "The create function.")
 117    (search-function :initarg :search-function
 118                     :initform ignore
 119                     :type function
 120                     :custom function
 121                     :documentation "The search function.")))
 122
 123 (defcustom auth-source-protocols '((imap "imap" "imaps" "143" "993")
 124                                    (pop3 "pop3" "pop" "pop3s" "110" "995")
 125                                    (ssh  "ssh" "22")
 126                                    (sftp "sftp" "115")
 127                                    (smtp "smtp" "25"))
 128   "List of authentication protocols and their names"
 129
 130   :group 'auth-source
 131   :version "23.2" ;; No Gnus
 132   :type '(repeat :tag "Authentication Protocols"
 133                  (cons :tag "Protocol Entry"
 134                        (symbol :tag "Protocol")
 135                        (repeat :tag "Names"
 136                                (string :tag "Name")))))
 137
 138 ;;; generate all the protocols in a format Customize can use
 139 ;;; TODO: generate on the fly from auth-source-protocols
 140 (defconst auth-source-protocols-customize
 141   (mapcar (lambda (a)
 142             (let ((p (car-safe a)))
 143               (list 'const
 144                     :tag (upcase (symbol-name p))
 145                     p)))
 146           auth-source-protocols))
 147
 148 (defvar auth-source-creation-defaults nil
 149   "Defaults for creating token values.  Usually let-bound.")
 150
 151 (make-obsolete 'auth-source-hide-passwords nil "Emacs 24.1")
 152
 153 (defvar auth-source-magic "auth-source-magic ")
 154
 155 (defcustom auth-source-do-cache t
 156   "Whether auth-source should cache information with `password-cache'."
 157   :group 'auth-source
 158   :version "23.2" ;; No Gnus
 159   :type `boolean)
 160
 161 (defcustom auth-source-debug nil
 162   "Whether auth-source should log debug messages.
 163
 164 If the value is nil, debug messages are not logged.
 165
 166 If the value is t, debug messages are logged with `message'.  In
 167 that case, your authentication data will be in the clear (except
 168 for passwords).
 169
 170 If the value is a function, debug messages are logged by calling
 171  that function using the same arguments as `message'."
 172   :group 'auth-source
 173   :version "23.2" ;; No Gnus
 174   :type `(choice
 175           :tag "auth-source debugging mode"
 176           (const :tag "Log using `message' to the *Messages* buffer" t)
 177           (function :tag "Function that takes arguments like `message'")
 178           (const :tag "Don't log anything" nil)))
 179
 180 (defcustom auth-sources '("~/.authinfo.gpg" "~/.authinfo")
 181   "List of authentication sources.
 182
 183 The default will get login and password information from
 184 \"~/.authinfo.gpg\", which you should set up with the EPA/EPG
 185 packages to be encrypted.  If that file doesn't exist, it will
 186 try the unencrypted version \"~/.authinfo\".
 187
 188 See the auth.info manual for details.
 189
 190 Each entry is the authentication type with optional properties.
 191
 192 It's best to customize this with `M-x customize-variable' because the choices
 193 can get pretty complex."
 194   :group 'auth-source
 195   :version "24.1" ;; No Gnus
 196   :type `(repeat :tag "Authentication Sources"
 197                  (choice
 198                   (string :tag "Just a file")
 199                   (const :tag "Default Secrets API Collection" 'default)
 200                   (const :tag "Login Secrets API Collection" "secrets:Login")
 201                   (const :tag "Temp Secrets API Collection" "secrets:session")
 202                   (list :tag "Source definition"
 203                         (const :format "" :value :source)
 204                         (choice :tag "Authentication backend choice"
 205                                 (string :tag "Authentication Source (file)")
 206                                 (list
 207                                  :tag "Secret Service API/KWallet/GNOME Keyring"
 208                                  (const :format "" :value :secrets)
 209                                  (choice :tag "Collection to use"
 210                                          (string :tag "Collection name")
 211                                          (const :tag "Default" 'default)
 212                                          (const :tag "Login" "Login")
 213                                          (const
 214                                           :tag "Temporary" "session"))))
 215                         (repeat :tag "Extra Parameters" :inline t
 216                                 (choice :tag "Extra parameter"
 217                                         (list
 218                                          :tag "Host"
 219                                          (const :format "" :value :host)
 220                                          (choice :tag "Host (machine) choice"
 221                                                  (const :tag "Any" t)
 222                                                  (regexp
 223                                                   :tag "Regular expression")))
 224                                         (list
 225                                          :tag "Protocol"
 226                                          (const :format "" :value :port)
 227                                          (choice
 228                                           :tag "Protocol"
 229                                           (const :tag "Any" t)
 230                                           ,@auth-source-protocols-customize))
 231                                         (list :tag "User" :inline t
 232                                               (const :format "" :value :user)
 233                                               (choice :tag "Personality/Username"
 234                                                       (const :tag "Any" t)
 235                                                       (string :tag "Name")))))))))
 236
 237 (defcustom auth-source-gpg-encrypt-to t
 238   "List of recipient keys that `authinfo.gpg' encrypted to.
 239 If the value is not a list, symmetric encryption will be used."
 240   :group 'auth-source
 241   :version "24.1" ;; No Gnus
 242   :type '(choice (const :tag "Symmetric encryption" t)
 243                  (repeat :tag "Recipient public keys"
 244                          (string :tag "Recipient public key"))))
 245
 246 ;; temp for debugging
 247 ;; (unintern 'auth-source-protocols)
 248 ;; (unintern 'auth-sources)
 249 ;; (customize-variable 'auth-sources)
 250 ;; (setq auth-sources nil)
 251 ;; (format "%S" auth-sources)
 252 ;; (customize-variable 'auth-source-protocols)
 253 ;; (setq auth-source-protocols nil)
 254 ;; (format "%S" auth-source-protocols)
 255 ;; (auth-source-pick nil :host "a" :port 'imap)
 256 ;; (auth-source-user-or-password "login" "imap.myhost.com" 'imap)
 257 ;; (auth-source-user-or-password "password" "imap.myhost.com" 'imap)
 258 ;; (auth-source-user-or-password-imap "login" "imap.myhost.com")
 259 ;; (auth-source-user-or-password-imap "password" "imap.myhost.com")
 260 ;; (auth-source-protocol-defaults 'imap)
 261
 262 ;; (let ((auth-source-debug 'debug)) (auth-source-do-debug "hello"))
 263 ;; (let ((auth-source-debug t)) (auth-source-do-debug "hello"))
 264 ;; (let ((auth-source-debug nil)) (auth-source-do-debug "hello"))
 265 (defun auth-source-do-debug (&rest msg)
 266   (when auth-source-debug
 267     (apply 'auth-source-do-warn msg)))
 268
 269 (defun auth-source-do-warn (&rest msg)
 270   (apply
 271     ;; set logger to either the function in auth-source-debug or 'message
 272     ;; note that it will be 'message if auth-source-debug is nil
 273    (if (functionp auth-source-debug)
 274        auth-source-debug
 275      'message)
 276    msg))
 277
 278
 279 ;; (auth-source-pick nil :host "any" :port 'imap :user "joe")
 280 ;; (auth-source-pick t :host "any" :port 'imap :user "joe")
 281 ;; (setq auth-sources '((:source (:secrets default) :host t :port t :user "joe")
 282 ;;                   (:source (:secrets "session") :host t :port t :user "joe")
 283 ;;                   (:source (:secrets "Login") :host t :port t)
 284 ;;                   (:source "~/.authinfo.gpg" :host t :port t)))
 285
 286 ;; (setq auth-sources '((:source (:secrets default) :host t :port t :user "joe")
 287 ;;                   (:source (:secrets "session") :host t :port t :user "joe")
 288 ;;                   (:source (:secrets "Login") :host t :port t)
 289 ;;                   ))
 290
 291 ;; (setq auth-sources '((:source "~/.authinfo.gpg" :host t :port t)))
 292
 293 ;; (auth-source-backend-parse "myfile.gpg")
 294 ;; (auth-source-backend-parse 'default)
 295 ;; (auth-source-backend-parse "secrets:Login")
 296
 297 (defun auth-source-backend-parse (entry)
 298   "Creates an auth-source-backend from an ENTRY in `auth-sources'."
 299   (auth-source-backend-parse-parameters
 300    entry
 301    (cond
 302     ;; take 'default and recurse to get it as a Secrets API default collection
 303     ;; matching any user, host, and protocol
 304     ((eq entry 'default)
 305      (auth-source-backend-parse '(:source (:secrets default))))
 306     ;; take secrets:XYZ and recurse to get it as Secrets API collection "XYZ"
 307     ;; matching any user, host, and protocol
 308     ((and (stringp entry) (string-match "^secrets:\\(.+\\)" entry))
 309      (auth-source-backend-parse `(:source (:secrets ,(match-string 1 entry)))))
 310     ;; take just a file name and recurse to get it as a netrc file
 311     ;; matching any user, host, and protocol
 312     ((stringp entry)
 313      (auth-source-backend-parse `(:source ,entry)))
 314
 315     ;; a file name with parameters
 316     ((stringp (plist-get entry :source))
 317      (auth-source-backend
 318       (plist-get entry :source)
 319       :source (plist-get entry :source)
 320       :type 'netrc
 321       :search-function 'auth-source-netrc-search
 322       :create-function 'auth-source-netrc-create))
 323
 324     ;; the Secrets API.  We require the package, in order to have a
 325     ;; defined value for `secrets-enabled'.
 326     ((and
 327       (not (null (plist-get entry :source))) ; the source must not be nil
 328       (listp (plist-get entry :source))      ; and it must be a list
 329       (require 'secrets nil t)               ; and we must load the Secrets API
 330       secrets-enabled)                       ; and that API must be enabled
 331
 332      ;; the source is either the :secrets key in ENTRY or
 333      ;; if that's missing or nil, it's "session"
 334      (let ((source (or (plist-get (plist-get entry :source) :secrets)
 335                        "session")))
 336
 337        ;; if the source is a symbol, we look for the alias named so,
 338        ;; and if that alias is missing, we use "Login"
 339        (when (symbolp source)
 340          (setq source (or (secrets-get-alias (symbol-name source))
 341                           "Login")))
 342
 343        (if (featurep 'secrets)
 344            (auth-source-backend
 345             (format "Secrets API (%s)" source)
 346             :source source
 347             :type 'secrets
 348             :search-function 'auth-source-secrets-search
 349             :create-function 'auth-source-secrets-create)
 350          (auth-source-do-warn
 351           "auth-source-backend-parse: no Secrets API, ignoring spec: %S" entry)
 352          (auth-source-backend
 353           (format "Ignored Secrets API (%s)" source)
 354           :source ""
 355           :type 'ignore))))
 356
 357     ;; none of them
 358     (t
 359      (auth-source-do-warn
 360       "auth-source-backend-parse: invalid backend spec: %S" entry)
 361      (auth-source-backend
 362       "Empty"
 363       :source ""
 364       :type 'ignore)))))
 365
 366 (defun auth-source-backend-parse-parameters (entry backend)
 367   "Fills in the extra auth-source-backend parameters of ENTRY.
 368 Using the plist ENTRY, get the :host, :port, and :user search
 369 parameters."
 370   (let ((entry (if (stringp entry)
 371                    nil
 372                  entry))
 373         val)
 374     (when (setq val (plist-get entry :host))
 375       (oset backend host val))
 376     (when (setq val (plist-get entry :user))
 377       (oset backend user val))
 378     (when (setq val (plist-get entry :port))
 379       (oset backend port val)))
 380   backend)
 381
 382 ;; (mapcar 'auth-source-backend-parse auth-sources)
 383
 384 (defun* auth-source-search (&rest spec
 385                                   &key type max host user port secret
 386                                   create delete
 387                                   &allow-other-keys)
 388   "Search or modify authentication backends according to SPEC.
 389
 390 This function parses `auth-sources' for matches of the SPEC
 391 plist.  It can optionally create or update an authentication
 392 token if requested.  A token is just a standard Emacs property
 393 list with a :secret property that can be a function; all the
 394 other properties will always hold scalar values.
 395
 396 Typically the :secret property, if present, contains a password.
 397
 398 Common search keys are :max, :host, :port, and :user.  In
 399 addition, :create specifies how tokens will be or created.
 400 Finally, :type can specify which backend types you want to check.
 401
 402 A string value is always matched literally.  A symbol is matched
 403 as its string value, literally.  All the SPEC values can be
 404 single values (symbol or string) or lists thereof (in which case
 405 any of the search terms matches).
 406
 407 :create t means to create a token if possible.
 408
 409 A new token will be created if no matching tokens were found.
 410 The new token will have only the keys the backend requires.  For
 411 the netrc backend, for instance, that's the user, host, and
 412 port keys.
 413
 414 Here's an example:
 415
 416 \(let ((auth-source-creation-defaults '((user . \"defaultUser\")
 417                                         (A    . \"default A\"))))
 418   (auth-source-search :host \"mine\" :type 'netrc :max 1
 419                       :P \"pppp\" :Q \"qqqq\"
 420                       :create t))
 421
 422 which says:
 423
 424 \"Search for any entry matching host 'mine' in backends of type
 425  'netrc', maximum one result.
 426
 427  Create a new entry if you found none.  The netrc backend will
 428  automatically require host, user, and port.  The host will be
 429  'mine'.  We prompt for the user with default 'defaultUser' and
 430  for the port without a default.  We will not prompt for A, Q,
 431  or P.  The resulting token will only have keys user, host, and
 432  port.\"
 433
 434 :create '(A B C) also means to create a token if possible.
 435
 436 The behavior is like :create t but if the list contains any
 437 parameter, that parameter will be required in the resulting
 438 token.  The value for that parameter will be obtained from the
 439 search parameters or from user input.  If any queries are needed,
 440 the alist `auth-source-creation-defaults' will be checked for the
 441 default prompt.
 442
 443 Here's an example:
 444
 445 \(let ((auth-source-creation-defaults '((user . \"defaultUser\")
 446                                         (A    . \"default A\"))))
 447   (auth-source-search :host '(\"nonesuch\" \"twosuch\") :type 'netrc :max 1
 448                       :P \"pppp\" :Q \"qqqq\"
 449                       :create '(A B Q)))
 450
 451 which says:
 452
 453 \"Search for any entry matching host 'nonesuch'
 454  or 'twosuch' in backends of type 'netrc', maximum one result.
 455
 456  Create a new entry if you found none.  The netrc backend will
 457  automatically require host, user, and port.  The host will be
 458  'nonesuch' and Q will be 'qqqq'.  We prompt for A with default
 459  'default A', for B and port with default nil, and for the
 460  user with default 'defaultUser'.  We will not prompt for Q.  The
 461  resulting token will have keys user, host, port, A, B, and Q.
 462  It will not have P with any value, even though P is used in the
 463  search to find only entries that have P set to 'pppp'.\"
 464
 465 When multiple values are specified in the search parameter, the
 466 user is prompted for which one.  So :host (X Y Z) would ask the
 467 user to choose between X, Y, and Z.
 468
 469 This creation can fail if the search was not specific enough to
 470 create a new token (it's up to the backend to decide that).  You
 471 should `catch' the backend-specific error as usual.  Some
 472 backends (netrc, at least) will prompt the user rather than throw
 473 an error.
 474
 475 :delete t means to delete any found entries.  nil by default.
 476 Use `auth-source-delete' in ELisp code instead of calling
 477 `auth-source-search' directly with this parameter.
 478
 479 :type (X Y Z) will check only those backend types.  'netrc and
 480 'secrets are the only ones supported right now.
 481
 482 :max N means to try to return at most N items (defaults to 1).
 483 When 0 the function will return just t or nil to indicate if any
 484 matches were found.  More than N items may be returned, depending
 485 on the search and the backend.
 486
 487 :host (X Y Z) means to match only hosts X, Y, or Z according to
 488 the match rules above.  Defaults to t.
 489
 490 :user (X Y Z) means to match only users X, Y, or Z according to
 491 the match rules above.  Defaults to t.
 492
 493 :port (P Q R) means to match only protocols P, Q, or R.
 494 Defaults to t.
 495
 496 :K (V1 V2 V3) for any other key K will match values V1, V2, or
 497 V3 (note the match rules above).
 498
 499 The return value is a list with at most :max tokens.  Each token
 500 is a plist with keys :backend :host :port :user, plus any other
 501 keys provided by the backend (notably :secret).  But note the
 502 exception for :max 0, which see above.
 503
 504 The token's :secret key can hold a function.  In that case you
 505 must call it to obtain the actual value."
 506   (let* ((backends (mapcar 'auth-source-backend-parse auth-sources))
 507          (max (or max 1))
 508          (ignored-keys '(:create :delete :max))
 509          (keys (loop for i below (length spec) by 2
 510                      unless (memq (nth i spec) ignored-keys)
 511                      collect (nth i spec)))
 512          (found (auth-source-recall spec))
 513          filtered-backends accessor-key found-here goal matches)
 514
 515     (if (and found auth-source-do-cache)
 516         (auth-source-do-debug
 517          "auth-source-search: found %d CACHED results matching %S"
 518          (length found) spec)
 519
 520       (assert
 521        (or (eq t create) (listp create)) t
 522        "Invalid auth-source :create parameter (must be nil, t, or a list): %s %s")
 523
 524       (setq filtered-backends (copy-sequence backends))
 525       (dolist (backend backends)
 526         (dolist (key keys)
 527           ;; ignore invalid slots
 528           (condition-case signal
 529               (unless (eval `(auth-source-search-collection
 530                               (plist-get spec key)
 531                               (oref backend ,key)))
 532                 (setq filtered-backends (delq backend filtered-backends))
 533                 (return))
 534             (invalid-slot-name))))
 535
 536       (auth-source-do-debug
 537        "auth-source-search: found %d backends matching %S"
 538        (length filtered-backends) spec)
 539
 540       ;; (debug spec "filtered" filtered-backends)
 541       (setq goal max)
 542       ;; First go through all the backends without :create, so we can
 543       ;; query them all.
 544       (let ((uspec (copy-sequence spec)))
 545         (plist-put uspec :create nil)
 546         (dolist (backend filtered-backends)
 547           (let ((match (apply
 548                         (slot-value backend 'search-function)
 549                         :backend backend
 550                         uspec)))
 551             (when match
 552               (push (list backend match) matches)))))
 553       ;; If we didn't find anything, then we allow the backend(s) to
 554       ;; create the entries.
 555       (when (and create
 556                  (not matches))
 557         (dolist (backend filtered-backends)
 558           (let ((match (apply
 559                         (slot-value backend 'search-function)
 560                         :backend backend
 561                         :create create
 562                         :delete delete
 563                         spec)))
 564             (when match
 565               (push (list backend match) matches)))))
 566
 567       (setq backend (caar matches)
 568             found-here (cadar matches))
 569
 570       (block nil
 571         ;; if max is 0, as soon as we find something, return it
 572         (when (and (zerop max) (> 0 (length found-here)))
 573           (return t))
 574
 575         ;; decrement the goal by the number of new results
 576         (decf goal (length found-here))
 577         ;; and append the new results to the full list
 578         (setq found (append found found-here))
 579
 580         (auth-source-do-debug
 581          "auth-source-search: found %d results (max %d/%d) in %S matching %S"
 582          (length found-here) max goal backend spec)
 583
 584         ;; return full list if the goal is 0 or negative
 585         (when (zerop (max 0 goal))
 586           (return found))
 587
 588         ;; change the :max parameter in the spec to the goal
 589         (setq spec (plist-put spec :max goal))
 590
 591         (when (and found auth-source-do-cache)
 592           (auth-source-remember spec found))))
 593
 594     found))
 595
 596 ;;; (auth-source-search :max 1)
 597 ;;; (funcall (plist-get (nth 0 (auth-source-search :max 1)) :secret))
 598 ;;; (auth-source-search :host "nonesuch" :type 'netrc :K 1)
 599 ;;; (auth-source-search :host "nonesuch" :type 'secrets)
 600
 601 (defun* auth-source-delete (&rest spec
 602                                   &key delete
 603                                   &allow-other-keys)
 604   "Delete entries from the authentication backends according to SPEC.
 605 Calls `auth-source-search' with the :delete property in SPEC set to t.
 606 The backend may not actually delete the entries.
 607
 608 Returns the deleted entries."
 609   (auth-source-search (plist-put spec :delete t)))
 610
 611 (defun auth-source-search-collection (collection value)
 612   "Returns t is VALUE is t or COLLECTION is t or contains VALUE."
 613   (when (and (atom collection) (not (eq t collection)))
 614     (setq collection (list collection)))
 615
 616   ;; (debug :collection collection :value value)
 617   (or (eq collection t)
 618       (eq value t)
 619       (equal collection value)
 620       (member value collection)))
 621
 622 (defun auth-source-forget-all-cached ()
 623   "Forget all cached auth-source data."
 624   (interactive)
 625   (loop for sym being the symbols of password-data
 626         ;; when the symbol name starts with auth-source-magic
 627         when (string-match (concat "^" auth-source-magic)
 628                            (symbol-name sym))
 629         ;; remove that key
 630         do (password-cache-remove (symbol-name sym))))
 631
 632 (defun auth-source-remember (spec found)
 633   "Remember FOUND search results for SPEC."
 634   (let ((password-cache-expiry auth-source-cache-expiry))
 635     (password-cache-add
 636      (concat auth-source-magic (format "%S" spec)) found)))
 637
 638 (defun auth-source-recall (spec)
 639   "Recall FOUND search results for SPEC."
 640   (password-read-from-cache
 641    (concat auth-source-magic (format "%S" spec))))
 642
 643 (defun auth-source-forget (spec)
 644   "Forget any cached data matching SPEC exactly.
 645
 646 This is the same SPEC you passed to `auth-source-search'.
 647 Returns t or nil for forgotten or not found."
 648   (password-cache-remove (concat auth-source-magic (format "%S" spec))))
 649
 650 ;;; (loop for sym being the symbols of password-data when (string-match (concat "^" auth-source-magic) (symbol-name sym)) collect (symbol-name sym))
 651
 652 ;;; (auth-source-remember '(:host "wedd") '(4 5 6))
 653 ;;; (auth-source-remember '(:host "xedd") '(1 2 3))
 654 ;;; (auth-source-recall '(:host "xedd"))
 655 ;;; (auth-source-recall '(:host t))
 656 ;;; (auth-source-forget+ :host t)
 657
 658 (defun* auth-source-forget+ (&rest spec &allow-other-keys)
 659   "Forget any cached data matching SPEC.  Returns forgotten count.
 660
 661 This is not a full `auth-source-search' spec but works similarly.
 662 For instance, \(:host \"myhost\" \"yourhost\") would find all the
 663 cached data that was found with a search for those two hosts,
 664 while \(:host t) would find all host entries."
 665   (let ((count 0)
 666         sname)
 667     (loop for sym being the symbols of password-data
 668           ;; when the symbol name matches with auth-source-magic
 669           when (and (setq sname (symbol-name sym))
 670                     (string-match (concat "^" auth-source-magic "\\(.+\\)")
 671                                   sname)
 672                     ;; and the spec matches what was stored in the cache
 673                     (auth-source-specmatchp spec (read (match-string 1 sname))))
 674           ;; remove that key
 675           do (progn
 676                (password-cache-remove sname)
 677                (incf count)))
 678     count))
 679
 680 (defun auth-source-specmatchp (spec stored)
 681   (let ((keys (loop for i below (length spec) by 2
 682                    collect (nth i spec))))
 683     (not (eq
 684           (dolist (key keys)
 685             (unless (auth-source-search-collection (plist-get stored key)
 686                                                    (plist-get spec key))
 687               (return 'no)))
 688           'no))))
 689
 690 ;;; Backend specific parsing: netrc/authinfo backend
 691
 692 ;;; (auth-source-netrc-parse "~/.authinfo.gpg")
 693 (defun* auth-source-netrc-parse (&rest
 694                                  spec
 695                                  &key file max host user port delete
 696                                  &allow-other-keys)
 697   "Parse FILE and return a list of all entries in the file.
 698 Note that the MAX parameter is used so we can exit the parse early."
 699   (if (listp file)
 700       ;; We got already parsed contents; just return it.
 701       file
 702     (when (file-exists-p file)
 703       (with-temp-buffer
 704         (let ((tokens '("machine" "host" "default" "login" "user"
 705                         "password" "account" "macdef" "force"
 706                         "port" "protocol"))
 707               (max (or max 5000))       ; sanity check: default to stop at 5K
 708               (modified 0)
 709               alist elem result pair)
 710           (insert-file-contents file)
 711           (goto-char (point-min))
 712           ;; Go through the file, line by line.
 713           (while (and (not (eobp))
 714                       (> max 0))
 715
 716             (narrow-to-region (point) (point-at-eol))
 717             ;; For each line, get the tokens and values.
 718             (while (not (eobp))
 719               (skip-chars-forward "\t ")
 720               ;; Skip lines that begin with a "#".
 721               (if (eq (char-after) ?#)
 722                   (goto-char (point-max))
 723                 (unless (eobp)
 724                   (setq elem
 725                         (if (= (following-char) ?\")
 726                             (read (current-buffer))
 727                           (buffer-substring
 728                            (point) (progn (skip-chars-forward "^\t ")
 729                                           (point)))))
 730                   (cond
 731                    ((equal elem "macdef")
 732                     ;; We skip past the macro definition.
 733                     (widen)
 734                     (while (and (zerop (forward-line 1))
 735                                 (looking-at "$")))
 736                     (narrow-to-region (point) (point)))
 737                    ((member elem tokens)
 738                     ;; Tokens that don't have a following value are ignored,
 739                     ;; except "default".
 740                     (when (and pair (or (cdr pair)
 741                                         (equal (car pair) "default")))
 742                       (push pair alist))
 743                     (setq pair (list elem)))
 744                    (t
 745                     ;; Values that haven't got a preceding token are ignored.
 746                     (when pair
 747                       (setcdr pair elem)
 748                       (push pair alist)
 749                       (setq pair nil)))))))
 750
 751             (when (and alist
 752                        (> max 0)
 753                        (auth-source-search-collection
 754                         host
 755                         (or
 756                          (aget alist "machine")
 757                          (aget alist "host")
 758                          t))
 759                        (auth-source-search-collection
 760                         user
 761                         (or
 762                          (aget alist "login")
 763                          (aget alist "account")
 764                          (aget alist "user")
 765                          t))
 766                        (auth-source-search-collection
 767                         port
 768                         (or
 769                          (aget alist "port")
 770                          (aget alist "protocol")
 771                          t)))
 772               (decf max)
 773               (push (nreverse alist) result)
 774               ;; to delete a line, we just comment it out
 775               (when delete
 776                 (goto-char (point-min))
 777                 (insert "#")
 778                 (incf modified)))
 779             (setq alist nil
 780                   pair nil)
 781             (widen)
 782             (forward-line 1))
 783
 784           (when (< 0 modified)
 785             (when auth-source-gpg-encrypt-to
 786               ;; (see bug#7487) making `epa-file-encrypt-to' local to
 787               ;; this buffer lets epa-file skip the key selection query
 788               ;; (see the `local-variable-p' check in
 789               ;; `epa-file-write-region').
 790               (unless (local-variable-p 'epa-file-encrypt-to (current-buffer))
 791                 (make-local-variable 'epa-file-encrypt-to))
 792               (if (listp auth-source-gpg-encrypt-to)
 793                   (setq epa-file-encrypt-to auth-source-gpg-encrypt-to)))
 794
 795             ;; ask AFTER we've successfully opened the file
 796             (when (y-or-n-p (format "Save file %s? (%d modifications)"
 797                                     file modified))
 798               (write-region (point-min) (point-max) file nil 'silent)
 799               (auth-source-do-debug
 800                "auth-source-netrc-parse: modified %d lines in %s"
 801                modified file)))
 802
 803           (nreverse result))))))
 804
 805 (defun auth-source-netrc-normalize (alist)
 806   (mapcar (lambda (entry)
 807             (let (ret item)
 808               (while (setq item (pop entry))
 809                 (let ((k (car item))
 810                       (v (cdr item)))
 811
 812                   ;; apply key aliases
 813                   (setq k (cond ((member k '("machine")) "host")
 814                                 ((member k '("login" "account")) "user")
 815                                 ((member k '("protocol")) "port")
 816                                 ((member k '("password")) "secret")
 817                                 (t k)))
 818
 819                   ;; send back the secret in a function (lexical binding)
 820                   (when (equal k "secret")
 821                     (setq v (lexical-let ((v v))
 822                               (lambda () v))))
 823
 824                   (setq ret (plist-put ret
 825                                        (intern (concat ":" k))
 826                                        v))
 827                   ))
 828               ret))
 829           alist))
 830
 831 ;;; (setq secret (plist-get (nth 0 (auth-source-search :host t :type 'netrc :K 1 :max 1)) :secret))
 832 ;;; (funcall secret)
 833
 834 (defun* auth-source-netrc-search (&rest
 835                                   spec
 836                                   &key backend create delete
 837                                   type max host user port
 838                                   &allow-other-keys)
 839 "Given a property list SPEC, return search matches from the :backend.
 840 See `auth-source-search' for details on SPEC."
 841   ;; just in case, check that the type is correct (null or same as the backend)
 842   (assert (or (null type) (eq type (oref backend type)))
 843           t "Invalid netrc search: %s %s")
 844
 845   (let ((results (auth-source-netrc-normalize
 846                   (auth-source-netrc-parse
 847                    :max max
 848                    :delete delete
 849                    :file (oref backend source)
 850                    :host (or host t)
 851                    :user (or user t)
 852                    :port (or port t)))))
 853
 854     ;; if we need to create an entry AND none were found to match
 855     (when (and create
 856                (= 0 (length results)))
 857
 858       ;; create based on the spec and record the value
 859       (setq results (or
 860                      ;; if the user did not want to create the entry
 861                      ;; in the file, it will be returned
 862                      (apply (slot-value backend 'create-function) spec)
 863                      ;; if not, we do the search again without :create
 864                      ;; to get the updated data.
 865
 866                      ;; the result will be returned, even if the search fails
 867                      (apply 'auth-source-netrc-search
 868                             (plist-put spec :create nil)))))
 869     results))
 870
 871 ;;; (auth-source-search :host "nonesuch" :type 'netrc :max 1 :create t)
 872 ;;; (auth-source-search :host "nonesuch" :type 'netrc :max 1 :create t :create-extra-keys '((A "default A") (B)))
 873
 874 (defun* auth-source-netrc-create (&rest spec
 875                                         &key backend
 876                                         secret host user port create
 877                                         &allow-other-keys)
 878   (let* ((base-required '(host user port secret))
 879          ;; we know (because of an assertion in auth-source-search) that the
 880          ;; :create parameter is either t or a list (which includes nil)
 881          (create-extra (if (eq t create) nil create))
 882          (required (append base-required create-extra))
 883          (file (oref backend source))
 884          (add "")
 885          (show "")
 886          ;; `valist' is an alist
 887          valist
 888          ;; `artificial' will be returned if no creation is needed
 889          artificial)
 890
 891     ;; only for base required elements (defined as function parameters):
 892     ;; fill in the valist with whatever data we may have from the search
 893     ;; we complete the first value if it's a list and use the value otherwise
 894     (dolist (br base-required)
 895       (when (symbol-value br)
 896         (let ((br-choice (cond
 897                           ;; all-accepting choice (predicate is t)
 898                           ((eq t (symbol-value br)) nil)
 899                           ;; just the value otherwise
 900                           (t (symbol-value br)))))
 901           (when br-choice
 902             (aput 'valist br br-choice)))))
 903
 904     ;; for extra required elements, see if the spec includes a value for them
 905     (dolist (er create-extra)
 906       (let ((name (concat ":" (symbol-name er)))
 907             (keys (loop for i below (length spec) by 2
 908                         collect (nth i spec))))
 909         (dolist (k keys)
 910           (when (equal (symbol-name k) name)
 911             (aput 'valist er (plist-get spec k))))))
 912
 913     ;; for each required element
 914     (dolist (r required)
 915       (let* ((data (aget valist r))
 916              (given-default (aget auth-source-creation-defaults r))
 917              ;; the defaults are simple
 918              (default (cond
 919                        ((and (not given-default) (eq r 'user))
 920                         (user-login-name))
 921                        ;; note we need this empty string
 922                        ((and (not given-default) (eq r 'port))
 923                         "")
 924                        (t given-default)))
 925              ;; the prompt's default string depends on the data so far
 926              (default-string (if (and default (< 0 (length default)))
 927                                  (format " (default %s)" default)
 928                                " (no default)"))
 929              ;; the prompt should also show what's entered so far
 930              (user-value (aget valist 'user))
 931              (host-value (aget valist 'host))
 932              (port-value (aget valist 'port))
 933              ;; note this handles lists by just printing them
 934              ;; later we allow the user to use completing-read to pick
 935              (info-so-far (concat (if user-value
 936                                       (format "%s@" user-value)
 937                                     "[USER?]")
 938                                   (if host-value
 939                                       (format "%s" host-value)
 940                                     "[HOST?]")
 941                                   (if port-value
 942                                       ;; this distinguishes protocol between
 943                                       (if (zerop (length port-value))
 944                                           "" ; 'entered as "no default"' vs.
 945                                         (format ":%s" port-value)) ; given
 946                                     ;; and this is when the protocol is unknown
 947                                     "[PORT?]"))))
 948
 949         ;; now prompt if the search SPEC did not include a required key;
 950         ;; take the result and put it in `data' AND store it in `valist'
 951         (aput 'valist r
 952               (setq data
 953                     (cond
 954                      ((and (null data) (eq r 'secret))
 955                       ;; special case prompt for passwords
 956                       (read-passwd (format "Password for %s: " info-so-far)))
 957                      ((null data)
 958                       (read-string
 959                        (format "Enter %s for %s%s: "
 960                                r info-so-far default-string)
 961                        nil nil default))
 962                      ((listp data)
 963                       (completing-read
 964                        (format "Enter %s for %s (TAB to see the choices): "
 965                                r info-so-far)
 966                        data
 967                        nil              ; no predicate
 968                        t                ; require a match
 969                        ;; note the default is nil, but if the user
 970                        ;; hits RET we'll get "", which is handled OK later
 971                        nil))
 972                      (t data))))
 973
 974         (when data
 975           (setq artificial (plist-put artificial
 976                                       (intern (concat ":" (symbol-name r)))
 977                                       (if (eq r 'secret)
 978                                           (lexical-let ((data data))
 979                                             (lambda () data))
 980                                         data))))
 981
 982         ;; when r is not an empty string...
 983         (when (and (stringp data)
 984                    (< 0 (length data)))
 985           (let ((printer (lambda (hide)
 986                            ;; append the key (the symbol name of r)
 987                            ;; and the value in r
 988                            (format "%s%s %S"
 989                                    ;; prepend a space
 990                                    (if (zerop (length add)) "" " ")
 991                                    ;; remap auth-source tokens to netrc
 992                                    (case r
 993                                      ('user "login")
 994                                      ('host "machine")
 995                                      ('secret "password")
 996                                      ('port "port") ; redundant but clearer
 997                                      (t (symbol-name r)))
 998                                    ;; the value will be printed in %S format
 999                                    (if (and hide (eq r 'secret))
1000                                        "HIDDEN_SECRET"
1001                                      data)))))
1002             (setq add (concat add (funcall printer nil)))
1003             (setq show (concat show (funcall printer t)))))))
1004
1005     (with-temp-buffer
1006       (when (file-exists-p file)
1007         (insert-file-contents file))
1008       (when auth-source-gpg-encrypt-to
1009         ;; (see bug#7487) making `epa-file-encrypt-to' local to
1010         ;; this buffer lets epa-file skip the key selection query
1011         ;; (see the `local-variable-p' check in
1012         ;; `epa-file-write-region').
1013         (unless (local-variable-p 'epa-file-encrypt-to (current-buffer))
1014           (make-local-variable 'epa-file-encrypt-to))
1015         (if (listp auth-source-gpg-encrypt-to)
1016             (setq epa-file-encrypt-to auth-source-gpg-encrypt-to)))
1017       (goto-char (point-max))
1018
1019       ;; ask AFTER we've successfully opened the file
1020       (if (y-or-n-p (format "Add to file %s: line [%s]" file show))
1021           (progn
1022             (unless (bolp)
1023               (insert "\n"))
1024             (insert add "\n")
1025             (write-region (point-min) (point-max) file nil 'silent)
1026             (auth-source-do-debug
1027              "auth-source-netrc-create: wrote 1 new line to %s"
1028              file)
1029             nil)
1030         (list artificial)))))
1031
1032 ;;; Backend specific parsing: Secrets API backend
1033
1034 ;;; (let ((auth-sources '(default))) (auth-source-search :max 1 :create t))
1035 ;;; (let ((auth-sources '(default))) (auth-source-search :max 1 :delete t))
1036 ;;; (let ((auth-sources '(default))) (auth-source-search :max 1))
1037 ;;; (let ((auth-sources '(default))) (auth-source-search))
1038 ;;; (let ((auth-sources '("secrets:Login"))) (auth-source-search :max 1))
1039 ;;; (let ((auth-sources '("secrets:Login"))) (auth-source-search :max 1 :signon_realm "https://git.gnus.org/Git"))
1040
1041 (defun* auth-source-secrets-search (&rest
1042                                     spec
1043                                     &key backend create delete label
1044                                     type max host user port
1045                                     &allow-other-keys)
1046   "Search the Secrets API; spec is like `auth-source'.
1047
1048 The :label key specifies the item's label.  It is the only key
1049 that can specify a substring.  Any :label value besides a string
1050 will allow any label.
1051
1052 All other search keys must match exactly.  If you need substring
1053 matching, do a wider search and narrow it down yourself.
1054
1055 You'll get back all the properties of the token as a plist.
1056
1057 Here's an example that looks for the first item in the 'Login'
1058 Secrets collection:
1059
1060  \(let ((auth-sources '(\"secrets:Login\")))
1061     (auth-source-search :max 1)
1062
1063 Here's another that looks for the first item in the 'Login'
1064 Secrets collection whose label contains 'gnus':
1065
1066  \(let ((auth-sources '(\"secrets:Login\")))
1067     (auth-source-search :max 1 :label \"gnus\")
1068
1069 And this one looks for the first item in the 'Login' Secrets
1070 collection that's a Google Chrome entry for the git.gnus.org site
1071 authentication tokens:
1072
1073  \(let ((auth-sources '(\"secrets:Login\")))
1074     (auth-source-search :max 1 :signon_realm \"https://git.gnus.org/Git\"))
1075 "
1076
1077   ;; TODO
1078   (assert (not create) nil
1079           "The Secrets API auth-source backend doesn't support creation yet")
1080   ;; TODO
1081   ;; (secrets-delete-item coll elt)
1082   (assert (not delete) nil
1083           "The Secrets API auth-source backend doesn't support deletion yet")
1084
1085   (let* ((coll (oref backend source))
1086          (max (or max 5000))     ; sanity check: default to stop at 5K
1087          (ignored-keys '(:create :delete :max :backend :label))
1088          (search-keys (loop for i below (length spec) by 2
1089                             unless (memq (nth i spec) ignored-keys)
1090                             collect (nth i spec)))
1091          ;; build a search spec without the ignored keys
1092          ;; if a search key is nil or t (match anything), we skip it
1093          (search-spec (apply 'append (mapcar
1094                                       (lambda (k)
1095                                         (if (or (null (plist-get spec k))
1096                                                 (eq t (plist-get spec k)))
1097                                             nil
1098                                           (list k (plist-get spec k))))
1099                               search-keys)))
1100          ;; needed keys (always including host, login, port, and secret)
1101          (returned-keys (mm-delete-duplicates (append
1102                                                '(:host :login :port :secret)
1103                                                search-keys)))
1104          (items (loop for item in (apply 'secrets-search-items coll search-spec)
1105                       unless (and (stringp label)
1106                                   (not (string-match label item)))
1107                       collect item))
1108          ;; TODO: respect max in `secrets-search-items', not after the fact
1109          (items (butlast items (- (length items) max)))
1110          ;; convert the item name to a full plist
1111          (items (mapcar (lambda (item)
1112                           (append
1113                            ;; make an entry for the secret (password) element
1114                            (list
1115                             :secret
1116                             (lexical-let ((v (secrets-get-secret coll item)))
1117                               (lambda () v)))
1118                            ;; rewrite the entry from ((k1 v1) (k2 v2)) to plist
1119                            (apply 'append
1120                                   (mapcar (lambda (entry)
1121                                             (list (car entry) (cdr entry)))
1122                                           (secrets-get-attributes coll item)))))
1123                         items))
1124          ;; ensure each item has each key in `returned-keys'
1125          (items (mapcar (lambda (plist)
1126                           (append
1127                            (apply 'append
1128                                   (mapcar (lambda (req)
1129                                             (if (plist-get plist req)
1130                                                 nil
1131                                               (list req nil)))
1132                                           returned-keys))
1133                            plist))
1134                         items)))
1135     items))
1136
1137 (defun* auth-source-secrets-create (&rest
1138                                     spec
1139                                     &key backend type max host user port
1140                                     &allow-other-keys)
1141   ;; TODO
1142   ;; (apply 'secrets-create-item (auth-get-source entry) name passwd spec)
1143   (debug spec))
1144
1145 ;;; older API
1146
1147 ;;; (auth-source-user-or-password '("login" "password") "imap.myhost.com" t "tzz")
1148
1149 ;; deprecate the old interface
1150 (make-obsolete 'auth-source-user-or-password
1151                'auth-source-search "Emacs 24.1")
1152 (make-obsolete 'auth-source-forget-user-or-password
1153                'auth-source-forget "Emacs 24.1")
1154
1155 (defun auth-source-user-or-password
1156   (mode host port &optional username create-missing delete-existing)
1157   "Find MODE (string or list of strings) matching HOST and PORT.
1158
1159 DEPRECATED in favor of `auth-source-search'!
1160
1161 USERNAME is optional and will be used as \"login\" in a search
1162 across the Secret Service API (see secrets.el) if the resulting
1163 items don't have a username.  This means that if you search for
1164 username \"joe\" and it matches an item but the item doesn't have
1165 a :user attribute, the username \"joe\" will be returned.
1166
1167 A non nil DELETE-EXISTING means deleting any matching password
1168 entry in the respective sources.  This is useful only when
1169 CREATE-MISSING is non nil as well; the intended use case is to
1170 remove wrong password entries.
1171
1172 If no matching entry is found, and CREATE-MISSING is non nil,
1173 the password will be retrieved interactively, and it will be
1174 stored in the password database which matches best (see
1175 `auth-sources').
1176
1177 MODE can be \"login\" or \"password\"."
1178   (auth-source-do-debug
1179    "auth-source-user-or-password: DEPRECATED get %s for %s (%s) + user=%s"
1180    mode host port username)
1181
1182   (let* ((listy (listp mode))
1183          (mode (if listy mode (list mode)))
1184          (cname (if username
1185                     (format "%s %s:%s %s" mode host port username)
1186                   (format "%s %s:%s" mode host port)))
1187          (search (list :host host :port port))
1188          (search (if username (append search (list :user username)) search))
1189          (search (if create-missing
1190                      (append search (list :create t))
1191                    search))
1192          (search (if delete-existing
1193                      (append search (list :delete t))
1194                    search))
1195          ;; (found (if (not delete-existing)
1196          ;;            (gethash cname auth-source-cache)
1197          ;;          (remhash cname auth-source-cache)
1198          ;;          nil)))
1199          (found nil))
1200     (if found
1201         (progn
1202           (auth-source-do-debug
1203            "auth-source-user-or-password: DEPRECATED cached %s=%s for %s (%s) + %s"
1204            mode
1205            ;; don't show the password
1206            (if (and (member "password" mode) t)
1207                "SECRET"
1208              found)
1209            host port username)
1210           found)                        ; return the found data
1211       ;; else, if not found, search with a max of 1
1212       (let ((choice (nth 0 (apply 'auth-source-search
1213                                   (append '(:max 1) search)))))
1214         (when choice
1215           (dolist (m mode)
1216             (cond
1217              ((equal "password" m)
1218               (push (if (plist-get choice :secret)
1219                       (funcall (plist-get choice :secret))
1220                     nil) found))
1221              ((equal "login" m)
1222               (push (plist-get choice :user) found)))))
1223         (setq found (nreverse found))
1224         (setq found (if listy found (car-safe found)))))
1225
1226         found))
1227
1228 (provide 'auth-source)
1229
1230 ;;; auth-source.el ends here