Sequences, Arrays, and Vectors
******************************

Recall that the sequence type is the union of five other Lisp types: lists, double-linked lists, vectors, bit vectors, and strings. In other words, any list is a sequence, any dllist is a sequence, any vector is a sequence, any bit vector is a sequence, and any string is a sequence.  The common property that all sequences have is that each is an ordered collection of elements.

An array is a single primitive object that has a slot for each elements.  All the elements are accessible in constant time, but the length of an existing array cannot be changed.  Strings, vectors, and bit vectors are the three types of arrays.

A list (or dllist) is a sequence of elements, but it is not a single primitive object; it is made of cons cells, one cell per element. Finding the Nth element requires looking through N cons cells, so elements farther from the beginning of the list take longer to access.  But it is possible to add elements to the list, or remove elements.

The following diagram shows the relationship between these types:

               ___________________________________
              |                                   |
              |          Sequence                 |
              |  ______   ______________________  |
              | |      | |                      | |
              | | List | |         Array        | |
              | |      | |  ________   _______  | |
              | |______| | |        | |       | | |
              |          | | Vector | | String| | |
              |  ______  | |________| |_______| | |
              | |      | |  __________________  | |
              | | DL-  | | |                  | | |
              | | List | | |    Bit Vector    | | |
              | |______| | |__________________| | |
              |          |______________________| |
              |___________________________________|

The elements of vectors, lists and dllists may be any Lisp objects. The elements of strings are all characters.  The elements of bit vectors are the numbers 0 and 1.

Sequences
=========

In SXEmacs Lisp, a sequence is either a list, a double-linked list, a vector, a bit vector, or a string.  The common property that all sequences have is that each is an ordered collection of elements. This section describes functions that accept any kind of sequence.

 -- Function: sequencep object
     Returns t if OBJECT is a list, dllist, vector, bit vector, or string, nil otherwise.

 -- Function: copy-sequence sequence
     Returns a copy of SEQUENCE.  The copy is the same type of object as the original sequence, and it has the same elements in the same order.

     Storing a new element into the copy does not affect the original SEQUENCE, and vice versa.  However, the elements of the new sequence are not copies; they are identical (eq) to the elements of the original.  Therefore, changes made within these elements, as found via the copied sequence, are also visible in the original sequence.

     If the sequence is a string with extents or text properties, the extents and text properties in the copy are also copied, not shared with the original. (This means that modifying the extents or text properties of the original will not affect the copy.) However, the actual values of the properties are shared.  See Extents, see Text Properties.

     See also append in Building Lists, concat in Creating Strings, vconcat in Vectors, and bvconcat in Bit Vectors, for other ways to copy sequences.

          (setq bar '(1 2))
               => (1 2)

          (setq x (vector 'foo bar))
               => [foo (1 2)]

          (setq y (copy-sequence x))
               => [foo (1 2)]

          (eq x y)
               => nil

          (equal x y)
               => t

          (eq (elt x 1) (elt y 1))
               => t

          ;; Replacing an element of one sequence.
          (aset x 0 'quux)
          x => [quux (1 2)]
          y => [foo (1 2)]

          ;; Modifying the inside of a shared element.
          (setcar (aref x 1) 69)
          x => [quux (69 2)]
          y => [foo (69 2)]

          ;; Creating a bit vector.
          (bit-vector 1 0 1 1 0 1 0 0)
               => #*10110100

 -- Function: length sequence
     Returns the number of elements in SEQUENCE.  If SEQUENCE is a cons cell that is not a list (because the final CDR is not nil), a wrong-type-argument error is signaled.

          (length '(1 2 3))
              => 3

          (length ())
              => 0

          (length (dllist 2 4))
              => 2

          (length "foobar")
              => 6

          (length [1 2 3])
              => 3

          (length #*01101)
              => 5

 -- Function: elt sequence index
     This function returns the element of SEQUENCE indexed by INDEX.  Legitimate values of INDEX are integers ranging from 0 up to one less than the length of SEQUENCE.  If SEQUENCE is a list, then out-of-range values of INDEX return nil; otherwise, they trigger an args-out-of-range error.

          (elt [1 2 3 4] 2)
               => 3

          (elt '(1 2 3 4) 2)
               => 3

          (elt (dllist 1 2 3 4) 2)
               => 3

          (char-to-string (elt "1234" 2))
               => "3"

          (elt #*00010000 3)
               => 1

          (elt [1 2 3 4] 4)
               error-->Args out of range: [1 2 3 4], 4

          (elt [1 2 3 4] -1)
               error-->Args out of range: [1 2 3 4], -1

     This function generalizes aref (see Array Functions) and nth (see List Elements).

Arrays
======

An array object has slots that hold a number of other Lisp objects, called the elements of the array.  Any element of an array may be accessed in constant time.  In contrast, an element of a list requires access time that is proportional to the position of the element in the list.

When you create an array, you must specify how many elements it has. The amount of space allocated depends on the number of elements. Therefore, it is impossible to change the size of an array once it is created; you cannot add or remove elements.  However, you can replace an element with a different value.

SXEmacs defines three types of array, all of which are one-dimensional: strings, vectors, and bit vectors.  A vector is a general array; its elements can be any Lisp objects.  A string is a specialized array; its elements must be characters.  A bit vector is another specialized array; its elements must be bits (an integer, either 0 or 1).  Each type of array has its own read syntax.  See String Type, Vector Type, and Bit Vector Type.

All kinds of array share these characteristics:

  * The first element of an array has index zero, the second element has index 1, and so on.  This is called zero-origin indexing.  For example, an array of four elements has indices 0, 1, 2, and 3.

  * The elements of an array may be referenced or changed with the functions aref and aset, respectively (see Array Functions).

In principle, if you wish to have an array of text characters, you could use either a string or a vector.  In practice, we always choose strings for such applications, for four reasons:

  * They usually occupy one-fourth the space of a vector of the same elements.  (This is one-eighth the space for 64-bit machines such as the DEC Alpha, and may also be different when MULE support is compiled into SXEmacs.)

  * Strings are printed in a way that shows the contents more clearly as characters.

  * Strings can hold extent and text properties.  See Extents, see Text Properties.

  * Many of the specialized editing and I/O facilities of SXEmacs accept only strings.  For example, you cannot insert a vector of characters into a buffer the way you can insert a string.  See Strings and Characters.

By contrast, for an array of keyboard input characters (such as a key sequence), a vector may be necessary, because many keyboard input characters are non-printable and are represented with symbols rather than with characters.  See Key Sequence Input.

Similarly, when representing an array of bits, a bit vector has the following advantages over a regular vector:

  * They occupy 1/32nd the space of a vector of the same elements. (1/64th on 64-bit machines such as the DEC Alpha.)

  * Bit vectors are printed in a way that shows the contents more clearly as bits.

Functions that Operate on Arrays
================================

In this section, we describe the functions that accept strings, vectors, and bit vectors.

 -- Function: arrayp object
     This function returns t if OBJECT is an array (i.e., a string, vector, or bit vector).

          (arrayp "asdf")
          => t
          (arrayp [a])
          => t
          (arrayp #*101)
          => t

 -- Function: aref array index
     This function returns the INDEXth element of ARRAY.  The first element is at index zero.

          (setq primes [2 3 5 7 11 13])
               => [2 3 5 7 11 13]
          (aref primes 4)
               => 11
          (elt primes 4)
               => 11

          (aref "abcdefg" 1)
               => ?b

          (aref #*1101 2)
               => 0

     See also the function elt, in Sequence Functions.

 -- Function: aset array index object
     This function sets the INDEXth element of ARRAY to be OBJECT.  It returns OBJECT.

          (setq w [foo bar baz])
               => [foo bar baz]
          (aset w 0 'fu)
               => fu
          w
               => [fu bar baz]

          (setq x "asdfasfd")
               => "asdfasfd"
          (aset x 3 ?Z)
               => ?Z
          x
               => "asdZasfd"

          (setq bv #*1111)
               => #*1111
          (aset bv 2 0)
               => 0
          bv
               => #*1101

     If ARRAY is a string and OBJECT is not a character, a wrong-type-argument error results.

 -- Function: fillarray array object
     This function fills the array ARRAY with OBJECT, so that each element of ARRAY is OBJECT.  It returns ARRAY.

          (setq a [a b c d e f g])
               => [a b c d e f g]
          (fillarray a 0)
               => [0 0 0 0 0 0 0]
          a
               => [0 0 0 0 0 0 0]

          (setq s "When in the course")
               => "When in the course"
          (fillarray s ?-)
               => "------------------"

          (setq bv #*1101)
               => #*1101
          (fillarray bv 0)
               => #*0000

     If ARRAY is a string and OBJECT is not a character, a wrong-type-argument error results.

The general sequence functions copy-sequence and length are often useful for objects known to be arrays.  See Sequence Functions.

Vectors
=======

Arrays in Lisp, like arrays in most languages, are blocks of memory whose elements can be accessed in constant time.  A vector is a general-purpose array; its elements can be any Lisp objects.  (The other kind of array in SXEmacs Lisp is the string, whose elements must be characters.)  Vectors in SXEmacs serve as obarrays (vectors of symbols), although this is a shortcoming that should be fixed.  They are also used internally as part of the representation of a byte-compiled function; if you print such a function, you will see a vector in it.

In SXEmacs Lisp, the indices of the elements of a vector start from zero and count up from there.

Vectors are printed with square brackets surrounding the elements. Thus, a vector whose elements are the symbols a, b and a is printed as [a b a].  You can write vectors in the same way in Lisp input.

A vector, like a string or a number, is considered a constant for evaluation: the result of evaluating it is the same vector.  This does not evaluate or even examine the elements of the vector. See Self-Evaluating Forms.

Here are examples of these principles:

     (setq avector [1 two '(three) "four" [five]])
          => [1 two (quote (three)) "four" [five]]
     (eval avector)
          => [1 two (quote (three)) "four" [five]]
     (eq avector (eval avector))
          => t

Functions That Operate on Vectors
=================================

Here are some functions that relate to vectors:

 -- Function: vectorp object
     This function returns t if OBJECT is a vector.

          (vectorp [a])
               => t
          (vectorp "asdf")
               => nil

 -- Function: vector &rest objects
     This function creates and returns a vector whose elements are the arguments, OBJECTS.

          (vector 'foo 23 [bar baz] "rats")
               => [foo 23 [bar baz] "rats"]
          (vector)
               => []

 -- Function: make-vector length object
     This function returns a new vector consisting of LENGTH elements, each initialized to OBJECT.

          (setq sleepy (make-vector 9 'Z))
               => [Z Z Z Z Z Z Z Z Z]

 -- Function: vconcat &rest sequences
     This function returns a new vector containing all the elements of the SEQUENCES.  The arguments SEQUENCES may be lists, vectors, or strings.  If no SEQUENCES are given, an empty vector is returned.

     The value is a newly constructed vector that is not eq to any existing vector.

          (setq a (vconcat '(A B C) '(D E F)))
               => [A B C D E F]
          (eq a (vconcat a))
               => nil

          (vconcat)
               => []
          (vconcat [A B C] "aa" '(foo (6 7)))
               => [A B C 97 97 foo (6 7)]

     The vconcat function also allows integers as arguments.  It converts them to strings of digits, making up the decimal print representation of the integer, and then uses the strings instead of the original integers.  Don't use this feature; we plan to eliminate it.  If you already use this feature, change your programs now!  The proper way to convert an integer to a decimal number in this way is with format (see Formatting Strings) or number-to-string (see String Conversion).

     For other concatenation functions, see mapconcat in Mapping Functions, concat in Creating Strings, append in Building Lists, and bvconcat in Bit Vector Functions.

The append function provides a way to convert a vector into a list with the same elements (see Building Lists):

     (setq avector [1 two (quote (three)) "four" [five]])
          => [1 two (quote (three)) "four" [five]]
     (append avector nil)
          => (1 two (quote (three)) "four" [five])

Bit Vectors
===========

Bit vectors are specialized vectors that can only represent arrays of 1's and 0's.  Bit vectors have a very efficient representation and are useful for representing sets of boolean (true or false) values.

There is no limit on the size of a bit vector.  You could, for example, create a bit vector with 100,000 elements if you really wanted to.

Bit vectors have a special printed representation consisting of #* followed by the bits of the vector.  For example, a bit vector whose elements are 0, 1, 1, 0, and 1, respectively, is printed as

     #*01101

Bit vectors are considered constants for evaluation, like vectors, strings, and numbers.  See Self-Evaluating Forms.

Functions That Operate on Bit Vectors
=====================================

Here are some functions that relate to bit vectors:

 -- Function: bit-vector-p object
     This function returns t if OBJECT is a bit vector.

          (bit-vector-p #*01)
               => t
          (bit-vector-p [0 1])
               => nil
          (bit-vector-p "01")
               => nil

 -- Function: bitp object
     This function returns t if OBJECT is either 0 or 1.

 -- Function: bit-vector &rest bits
     This function creates and returns a bit vector whose elements are the arguments BITS.  Each argument must be a bit, i.e. one of the two integers 0 or 1.

          (bit-vector 0 0 0 1 0 0 0 0 1 0)
               => #*0001000010
          (bit-vector)
               => #*

 -- Function: make-bit-vector length bit
     This function creates and returns a bit vector consisting of LENGTH elements, each initialized to BIT, which must be one of the two integers 0 or 1.

          (setq picket-fence (make-bit-vector 9 1))
               => #*111111111

 -- Function: bvconcat &rest sequences
     This function returns a new bit vector containing all the elements of the SEQUENCES.  The arguments SEQUENCES may be lists, vectors, or bit vectors, all of whose elements are the integers 0 or 1. If no SEQUENCES are given, an empty bit vector is returned.

     The value is a newly constructed bit vector that is not eq to any existing bit vector.

          (setq a (bvconcat '(1 1 0) '(0 0 1)))
               => #*110001
          (eq a (bvconcat a))
               => nil

          (bvconcat)
               => #*
          (bvconcat [1 0 0 0 0] #*111 '(0 0 0 0 1))
               => #*1000011100001

     For other concatenation functions, see mapconcat in Mapping Functions, concat in Creating Strings, vconcat in Vector Functions, and append in Building Lists.

The append function provides a way to convert a bit vector into a list with the same elements (see Building Lists):

     (setq bv #*00001110)
          => #*00001110
     (append bv nil)
          => (0 0 0 0 1 1 1 0)