cgit.sxemacs.org Git - gnus/blob - lisp/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35
  36 (defgroup shr nil
  37   "Simple HTML Renderer"
  38   :group 'mail)
  39
  40 (defcustom shr-max-image-proportion 0.9
  41   "How big pictures displayed are in relation to the window they're in.
  42 A value of 0.7 means that they are allowed to take up 70% of the
  43 width and height of the window.  If they are larger than this,
  44 and Emacs supports it, then the images will be rescaled down to
  45 fit these criteria."
  46   :version "24.1"
  47   :group 'shr
  48   :type 'float)
  49
  50 (defcustom shr-blocked-images nil
  51   "Images that have URLs matching this regexp will be blocked."
  52   :version "24.1"
  53   :group 'shr
  54   :type 'regexp)
  55
  56 (defcustom shr-table-horizontal-line ?-
  57   "Character used to draw horizontal table lines."
  58   :group 'shr
  59   :type 'character)
  60
  61 (defcustom shr-table-vertical-line ?|
  62   "Character used to draw vertical table lines."
  63   :group 'shr
  64   :type 'character)
  65
  66 (defcustom shr-table-corner ?+
  67   "Character used to draw table corners."
  68   :group 'shr
  69   :type 'character)
  70
  71 (defcustom shr-hr-line ?-
  72   "Character used to draw hr lines."
  73   :group 'shr
  74   :type 'character)
  75
  76 (defcustom shr-width fill-column
  77   "Frame width to use for rendering."
  78   :type 'integer
  79   :group 'shr)
  80
  81 (defvar shr-content-function nil
  82   "If bound, this should be a function that will return the content.
  83 This is used for cid: URLs, and the function is called with the
  84 cid: URL as the argument.")
  85
  86 ;;; Internal variables.
  87
  88 (defvar shr-folding-mode nil)
  89 (defvar shr-state nil)
  90 (defvar shr-start nil)
  91 (defvar shr-indentation 0)
  92 (defvar shr-inhibit-images nil)
  93 (defvar shr-list-mode nil)
  94 (defvar shr-content-cache nil)
  95 (defvar shr-kinsoku-shorten nil)
  96 (defvar shr-table-depth 0)
  97 (defvar shr-stylesheet nil)
  98
  99 (defvar shr-map
 100   (let ((map (make-sparse-keymap)))
 101     (define-key map "a" 'shr-show-alt-text)
 102     (define-key map "i" 'shr-browse-image)
 103     (define-key map "I" 'shr-insert-image)
 104     (define-key map "u" 'shr-copy-url)
 105     (define-key map "v" 'shr-browse-url)
 106     (define-key map "o" 'shr-save-contents)
 107     (define-key map "\r" 'shr-browse-url)
 108     map))
 109
 110 ;; Public functions and commands.
 111
 112 ;;;###autoload
 113 (defun shr-insert-document (dom)
 114   (setq shr-content-cache nil)
 115   (let ((shr-state nil)
 116         (shr-start nil))
 117     (shr-descend (shr-transform-dom dom))))
 118
 119 (defun shr-copy-url ()
 120   "Copy the URL under point to the kill ring.
 121 If called twice, then try to fetch the URL and see whether it
 122 redirects somewhere else."
 123   (interactive)
 124   (let ((url (get-text-property (point) 'shr-url)))
 125     (cond
 126      ((not url)
 127       (message "No URL under point"))
 128      ;; Resolve redirected URLs.
 129      ((equal url (car kill-ring))
 130       (url-retrieve
 131        url
 132        (lambda (a)
 133          (when (and (consp a)
 134                     (eq (car a) :redirect))
 135            (with-temp-buffer
 136              (insert (cadr a))
 137              (goto-char (point-min))
 138              ;; Remove common tracking junk from the URL.
 139              (when (re-search-forward ".utm_.*" nil t)
 140                (replace-match "" t t))
 141              (message "Copied %s" (buffer-string))
 142              (copy-region-as-kill (point-min) (point-max)))))))
 143      ;; Copy the URL to the kill ring.
 144      (t
 145       (with-temp-buffer
 146         (insert url)
 147         (copy-region-as-kill (point-min) (point-max))
 148         (message "Copied %s" url))))))
 149
 150 (defun shr-show-alt-text ()
 151   "Show the ALT text of the image under point."
 152   (interactive)
 153   (let ((text (get-text-property (point) 'shr-alt)))
 154     (if (not text)
 155         (message "No image under point")
 156       (message "%s" text))))
 157
 158 (defun shr-browse-image ()
 159   "Browse the image under point."
 160   (interactive)
 161   (let ((url (get-text-property (point) 'image-url)))
 162     (if (not url)
 163         (message "No image under point")
 164       (message "Browsing %s..." url)
 165       (browse-url url))))
 166
 167 (defun shr-insert-image ()
 168   "Insert the image under point into the buffer."
 169   (interactive)
 170   (let ((url (get-text-property (point) 'image-url)))
 171     (if (not url)
 172         (message "No image under point")
 173       (message "Inserting %s..." url)
 174       (url-retrieve url 'shr-image-fetched
 175                     (list (current-buffer) (1- (point)) (point-marker))
 176                     t))))
 177
 178 ;;; Utility functions.
 179
 180 (defun shr-transform-dom (dom)
 181   (let ((result (list (pop dom))))
 182     (dolist (arg (pop dom))
 183       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 184                   (cdr arg))
 185             result))
 186     (dolist (sub dom)
 187       (if (stringp sub)
 188           (push (cons 'text sub) result)
 189         (push (shr-transform-dom sub) result)))
 190     (nreverse result)))
 191
 192 (defun shr-descend (dom)
 193   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray))
 194         (style (cdr (assq :style (cdr dom))))
 195         (shr-stylesheet shr-stylesheet)
 196         (start (point)))
 197     (when (and style
 198                (string-match "color" style))
 199       (setq shr-stylesheet (nconc (shr-parse-style style)
 200                                   shr-stylesheet)))
 201     (if (fboundp function)
 202         (funcall function (cdr dom))
 203       (shr-generic (cdr dom)))
 204     (let ((color (cdr (assq 'color shr-stylesheet)))
 205           (background (cdr (assq 'background-color
 206                                  shr-stylesheet))))
 207       (when (and shr-stylesheet
 208                  (or color background))
 209         (shr-colorize-region start (point) color background)))))
 210
 211 (defun shr-generic (cont)
 212   (dolist (sub cont)
 213     (cond
 214      ((eq (car sub) 'text)
 215       (shr-insert (cdr sub)))
 216      ((listp (cdr sub))
 217       (shr-descend sub)))))
 218
 219 (defmacro shr-char-breakable-p (char)
 220   "Return non-nil if a line can be broken before and after CHAR."
 221   `(aref fill-find-break-point-function-table ,char))
 222 (defmacro shr-char-nospace-p (char)
 223   "Return non-nil if no space is required before and after CHAR."
 224   `(aref fill-nospace-between-words-table ,char))
 225
 226 ;; KINSOKU is a Japanese word meaning a rule that should not be violated.
 227 ;; In Emacs, it is a term used for characters, e.g. punctuation marks,
 228 ;; parentheses, and so on, that should not be placed in the beginning
 229 ;; of a line or the end of a line.
 230 (defmacro shr-char-kinsoku-bol-p (char)
 231   "Return non-nil if a line ought not to begin with CHAR."
 232   `(aref (char-category-set ,char) ?>))
 233 (defmacro shr-char-kinsoku-eol-p (char)
 234   "Return non-nil if a line ought not to end with CHAR."
 235   `(aref (char-category-set ,char) ?<))
 236 (unless (shr-char-kinsoku-bol-p (make-char 'japanese-jisx0208 33 35))
 237   (load "kinsoku" nil t))
 238
 239 (defun shr-insert (text)
 240   (when (and (eq shr-state 'image)
 241              (not (string-match "\\`[ \t\n]+\\'" text)))
 242     (insert "\n")
 243     (setq shr-state nil))
 244   (cond
 245    ((eq shr-folding-mode 'none)
 246     (insert text))
 247    (t
 248     (when (and (string-match "\\`[ \t\n]" text)
 249                (not (bolp))
 250                (not (eq (char-after (1- (point))) ? )))
 251       (insert " "))
 252     (dolist (elem (split-string text))
 253       (when (and (bolp)
 254                  (> shr-indentation 0))
 255         (shr-indent))
 256       ;; The shr-start is a special variable that is used to pass
 257       ;; upwards the first point in the buffer where the text really
 258       ;; starts.
 259       (unless shr-start
 260         (setq shr-start (point)))
 261       ;; No space is needed behind a wide character categorized as
 262       ;; kinsoku-bol, between characters both categorized as nospace,
 263       ;; or at the beginning of a line.
 264       (let (prev)
 265         (when (and (eq (preceding-char) ? )
 266                    (or (= (line-beginning-position) (1- (point)))
 267                        (and (shr-char-breakable-p
 268                              (setq prev (char-after (- (point) 2))))
 269                             (shr-char-kinsoku-bol-p prev))
 270                        (and (shr-char-nospace-p prev)
 271                             (shr-char-nospace-p (aref elem 0)))))
 272           (delete-char -1)))
 273       (insert elem)
 274       (let (found)
 275         (while (and (> (current-column) shr-width)
 276                     (progn
 277                       (setq found (shr-find-fill-point))
 278                       (not (eolp))))
 279           (when (eq (preceding-char) ? )
 280             (delete-char -1))
 281           (insert "\n")
 282           (unless found
 283             (put-text-property (1- (point)) (point) 'shr-break t)
 284             ;; No space is needed at the beginning of a line.
 285             (when (eq (following-char) ? )
 286               (delete-char 1)))
 287           (when (> shr-indentation 0)
 288             (shr-indent))
 289           (end-of-line))
 290         (insert " ")))
 291     (unless (string-match "[ \t\n]\\'" text)
 292       (delete-char -1)))))
 293
 294 (defun shr-find-fill-point ()
 295   (when (> (move-to-column shr-width) shr-width)
 296     (backward-char 1))
 297   (let ((bp (point))
 298         failed)
 299     (while (not (or (setq failed (= (current-column) shr-indentation))
 300                     (eq (preceding-char) ? )
 301                     (eq (following-char) ? )
 302                     (shr-char-breakable-p (preceding-char))
 303                     (shr-char-breakable-p (following-char))
 304                     (if (eq (preceding-char) ?')
 305                         (not (memq (char-after (- (point) 2))
 306                                    (list nil ?\n ? )))
 307                       ;; There're some kinsoku CJK chars that aren't breakable.
 308                       (and (shr-char-kinsoku-bol-p (preceding-char))
 309                            (not (shr-char-kinsoku-bol-p (following-char)))))
 310                     (shr-char-kinsoku-eol-p (following-char))))
 311       (backward-char 1))
 312     (if (and (not (or failed (eolp)))
 313              (eq (preceding-char) ?'))
 314         (while (not (or (setq failed (eolp))
 315                         (eq (following-char) ? )
 316                         (shr-char-breakable-p (following-char))
 317                         (shr-char-kinsoku-eol-p (following-char))))
 318           (forward-char 1)))
 319     (if failed
 320         ;; There's no breakable point, so we give it up.
 321         (let (found)
 322           (goto-char bp)
 323           (unless shr-kinsoku-shorten
 324             (while (and (setq found (re-search-forward
 325                                      "\\(\\c>\\)\\| \\|\\c<\\|\\c|"
 326                                      (line-end-position) 'move))
 327                         (eq (preceding-char) ?')))
 328             (if (and found (not (match-beginning 1)))
 329                 (goto-char (match-beginning 0)))))
 330       (or
 331        (eolp)
 332        ;; Don't put kinsoku-bol characters at the beginning of a line,
 333        ;; or kinsoku-eol characters at the end of a line.
 334        (cond
 335         (shr-kinsoku-shorten
 336          (while (and (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 337                      (shr-char-kinsoku-eol-p (preceding-char)))
 338            (backward-char 1))
 339          (when (setq failed (= (current-column) shr-indentation))
 340            ;; There's no breakable point that doesn't violate kinsoku,
 341            ;; so we look for the second best position.
 342            (while (and (progn
 343                          (forward-char 1)
 344                          (<= (current-column) shr-width))
 345                        (progn
 346                          (setq bp (point))
 347                          (shr-char-kinsoku-eol-p (following-char)))))
 348            (goto-char bp)))
 349         ((shr-char-kinsoku-eol-p (preceding-char))
 350          (if (shr-char-kinsoku-eol-p (following-char))
 351              ;; There are consecutive kinsoku-eol characters.
 352              (setq failed t)
 353            (let ((count 4))
 354              (while
 355                  (progn
 356                    (backward-char 1)
 357                    (and (> (setq count (1- count)) 0)
 358                         (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 359                         (or (shr-char-kinsoku-eol-p (preceding-char))
 360                             (shr-char-kinsoku-bol-p (following-char)))))))
 361            (if (setq failed (= (current-column) shr-indentation))
 362                ;; There's no breakable point that doesn't violate kinsoku,
 363                ;; so we go to the second best position.
 364                (if (looking-at "\\(\\c<+\\)\\c<")
 365                    (goto-char (match-end 1))
 366                  (forward-char 1)))))
 367         (t
 368          (if (shr-char-kinsoku-bol-p (preceding-char))
 369              ;; There are consecutive kinsoku-bol characters.
 370              (setq failed t)
 371            (let ((count 4))
 372              (while (and (>= (setq count (1- count)) 0)
 373                          (shr-char-kinsoku-bol-p (following-char))
 374                          (shr-char-breakable-p (following-char)))
 375                (forward-char 1))))))
 376        (when (eq (following-char) ? )
 377          (forward-char 1))))
 378     (not failed)))
 379
 380 (defun shr-ensure-newline ()
 381   (unless (zerop (current-column))
 382     (insert "\n")))
 383
 384 (defun shr-ensure-paragraph ()
 385   (unless (bobp)
 386     (if (<= (current-column) shr-indentation)
 387         (unless (save-excursion
 388                   (forward-line -1)
 389                   (looking-at " *$"))
 390           (insert "\n"))
 391       (if (save-excursion
 392             (beginning-of-line)
 393             (looking-at " *$"))
 394           (insert "\n")
 395         (insert "\n\n")))))
 396
 397 (defun shr-indent ()
 398   (when (> shr-indentation 0)
 399     (insert (make-string shr-indentation ? ))))
 400
 401 (defun shr-fontize-cont (cont &rest types)
 402   (let (shr-start)
 403     (shr-generic cont)
 404     (dolist (type types)
 405       (shr-add-font (or shr-start (point)) (point) type))))
 406
 407 ;; Add an overlay in the region, but avoid putting the font properties
 408 ;; on blank text at the start of the line, and the newline at the end,
 409 ;; to avoid ugliness.
 410 (defun shr-add-font (start end type)
 411   (save-excursion
 412     (goto-char start)
 413     (while (< (point) end)
 414       (when (bolp)
 415         (skip-chars-forward " "))
 416       (let ((overlay (make-overlay (point) (min (line-end-position) end))))
 417         (overlay-put overlay 'face type))
 418       (if (< (line-end-position) end)
 419           (forward-line 1)
 420         (goto-char end)))))
 421
 422 (defun shr-browse-url ()
 423   "Browse the URL under point."
 424   (interactive)
 425   (let ((url (get-text-property (point) 'shr-url)))
 426     (cond
 427      ((not url)
 428       (message "No link under point"))
 429      ((string-match "^mailto:" url)
 430       (browse-url-mailto url))
 431      (t
 432       (browse-url url)))))
 433
 434 (defun shr-save-contents (directory)
 435   "Save the contents from URL in a file."
 436   (interactive "DSave contents of URL to directory: ")
 437   (let ((url (get-text-property (point) 'shr-url)))
 438     (if (not url)
 439         (message "No link under point")
 440       (url-retrieve (shr-encode-url url)
 441                     'shr-store-contents (list url directory)))))
 442
 443 (defun shr-store-contents (status url directory)
 444   (unless (plist-get status :error)
 445     (when (or (search-forward "\n\n" nil t)
 446               (search-forward "\r\n\r\n" nil t))
 447       (write-region (point) (point-max)
 448                     (expand-file-name (file-name-nondirectory url)
 449                                       directory)))))
 450
 451 (defun shr-image-fetched (status buffer start end)
 452   (when (and (buffer-name buffer)
 453              (not (plist-get status :error)))
 454     (url-store-in-cache (current-buffer))
 455     (when (or (search-forward "\n\n" nil t)
 456               (search-forward "\r\n\r\n" nil t))
 457       (let ((data (buffer-substring (point) (point-max))))
 458         (with-current-buffer buffer
 459           (let ((alt (buffer-substring start end))
 460                 (inhibit-read-only t))
 461             (delete-region start end)
 462             (goto-char start)
 463             (shr-put-image data alt))))))
 464   (kill-buffer (current-buffer)))
 465
 466 (defun shr-put-image (data alt)
 467   (if (display-graphic-p)
 468       (let ((image (ignore-errors
 469                      (shr-rescale-image data))))
 470         (when image
 471           ;; When inserting big-ish pictures, put them at the
 472           ;; beginning of the line.
 473           (when (and (> (current-column) 0)
 474                      (> (car (image-size image t)) 400))
 475             (insert "\n"))
 476           (insert-image image (or alt "*"))))
 477     (insert alt)))
 478
 479 (defun shr-rescale-image (data)
 480   (if (or (not (fboundp 'imagemagick-types))
 481           (not (get-buffer-window (current-buffer))))
 482       (create-image data nil t)
 483     (let* ((image (create-image data nil t))
 484            (size (image-size image t))
 485            (width (car size))
 486            (height (cdr size))
 487            (edges (window-inside-pixel-edges
 488                    (get-buffer-window (current-buffer))))
 489            (window-width (truncate (* shr-max-image-proportion
 490                                       (- (nth 2 edges) (nth 0 edges)))))
 491            (window-height (truncate (* shr-max-image-proportion
 492                                        (- (nth 3 edges) (nth 1 edges)))))
 493            scaled-image)
 494       (when (> height window-height)
 495         (setq image (or (create-image data 'imagemagick t
 496                                       :height window-height)
 497                         image))
 498         (setq size (image-size image t)))
 499       (when (> (car size) window-width)
 500         (setq image (or
 501                      (create-image data 'imagemagick t
 502                                    :width window-width)
 503                      image)))
 504       image)))
 505
 506 ;; url-cache-extract autoloads url-cache.
 507 (declare-function url-cache-create-filename "url-cache" (url))
 508 (autoload 'mm-disable-multibyte "mm-util")
 509 (autoload 'browse-url-mailto "browse-url")
 510
 511 (defun shr-get-image-data (url)
 512   "Get image data for URL.
 513 Return a string with image data."
 514   (with-temp-buffer
 515     (mm-disable-multibyte)
 516     (when (ignore-errors
 517             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 518             t)
 519       (when (or (search-forward "\n\n" nil t)
 520                 (search-forward "\r\n\r\n" nil t))
 521         (buffer-substring (point) (point-max))))))
 522
 523 (defun shr-image-displayer (content-function)
 524   "Return a function to display an image.
 525 CONTENT-FUNCTION is a function to retrieve an image for a cid url that
 526 is an argument.  The function to be returned takes three arguments URL,
 527 START, and END."
 528   `(lambda (url start end)
 529      (when url
 530        (if (string-match "\\`cid:" url)
 531            ,(when content-function
 532               `(let ((image (funcall ,content-function
 533                                      (substring url (match-end 0)))))
 534                  (when image
 535                    (goto-char start)
 536                    (shr-put-image image
 537                                   (prog1
 538                                       (buffer-substring-no-properties start end)
 539                                     (delete-region start end))))))
 540          (url-retrieve url 'shr-image-fetched
 541                        (list (current-buffer) start end)
 542                        t)))))
 543
 544 (defun shr-heading (cont &rest types)
 545   (shr-ensure-paragraph)
 546   (apply #'shr-fontize-cont cont types)
 547   (shr-ensure-paragraph))
 548
 549 (autoload 'widget-convert-button "wid-edit")
 550
 551 (defun shr-urlify (start url &optional title)
 552   (widget-convert-button
 553    'url-link start (point)
 554    :help-echo (if title (format "%s (%s)" url title) url)
 555    :keymap shr-map
 556    url)
 557   (put-text-property start (point) 'shr-url url))
 558
 559 (defun shr-encode-url (url)
 560   "Encode URL."
 561   (browse-url-url-encode-chars url "[)$ ]"))
 562
 563 (autoload 'shr-color-visible "shr-color")
 564 (autoload 'shr-color->hexadecimal "shr-color")
 565
 566 (defun shr-color-check (fg bg)
 567   "Check that FG is visible on BG.
 568 Returns (fg bg) with corrected values.
 569 Returns nil if the colors that would be used are the default
 570 ones, in case fg and bg are nil."
 571   (when (or fg bg)
 572     (let ((fixed (cond ((null fg) 'fg)
 573                        ((null bg) 'bg))))
 574       ;; Convert colors to hexadecimal, or set them to default.
 575       (let ((fg (or (shr-color->hexadecimal fg)
 576                     (frame-parameter nil 'foreground-color)))
 577             (bg (or (shr-color->hexadecimal bg)
 578                     (frame-parameter nil 'background-color))))
 579         (cond ((eq fixed 'bg)
 580                ;; Only return the new fg
 581                (list nil (cadr (shr-color-visible bg fg t))))
 582               ((eq fixed 'fg)
 583                ;; Invert args and results and return only the new bg
 584                (list (cadr (shr-color-visible fg bg t)) nil))
 585               (t
 586                (shr-color-visible bg fg)))))))
 587
 588 (defun shr-colorize-region (start end fg &optional bg)
 589   (when (or fg bg)
 590     (let ((new-colors (shr-color-check fg bg)))
 591       (when new-colors
 592         (shr-put-color start end :foreground (cadr new-colors))
 593         (when bg
 594           (shr-put-color start end :background (car new-colors)))))))
 595
 596 ;; Put a color in the region, but avoid putting colors on on blank
 597 ;; text at the start of the line, and the newline at the end, to avoid
 598 ;; ugliness.  Also, don't overwrite any existing color information,
 599 ;; since this can be called recursively, and we want the "inner" color
 600 ;; to win.
 601 (defun shr-put-color (start end type color)
 602   (save-excursion
 603     (goto-char start)
 604     (while (< (point) end)
 605       (when (bolp)
 606         (skip-chars-forward " "))
 607       (when (> (line-end-position) (point))
 608         (shr-put-color-1 (point) (min (line-end-position) end) type color))
 609       (if (< (line-end-position) end)
 610           (forward-line 1)
 611         (goto-char end)))))
 612
 613 (defun shr-put-color-1 (start end type color)
 614   (let* ((old-props (get-text-property start 'face))
 615          (do-put (not (memq type old-props)))
 616          change)
 617     (while (< start end)
 618       (setq change (next-single-property-change start 'face nil end))
 619       (when do-put
 620         (put-text-property start change 'face
 621                            (nconc (list type color) old-props)))
 622       (setq old-props (get-text-property change 'face))
 623       (setq do-put (not (memq type old-props)))
 624       (setq start change))
 625     (when (and do-put
 626                (> end start))
 627       (put-text-property start end 'face
 628                          (nconc (list type color old-props))))))
 629
 630 ;;; Tag-specific rendering rules.
 631
 632 (defun shr-tag-body (cont)
 633   (let* ((start (point))
 634          (fgcolor (cdr (assq :fgcolor cont)))
 635          (bgcolor (cdr (assq :bgcolor cont)))
 636          (shr-stylesheet (list (cons 'color fgcolor)
 637                                (cons 'background-color bgcolor))))
 638     (shr-generic cont)))
 639
 640 (defun shr-tag-p (cont)
 641   (shr-ensure-paragraph)
 642   (shr-indent)
 643   (shr-generic cont)
 644   (shr-ensure-paragraph))
 645
 646 (defun shr-tag-div (cont)
 647   (shr-ensure-newline)
 648   (shr-indent)
 649   (shr-generic cont)
 650   (shr-ensure-newline))
 651
 652 (defun shr-tag-b (cont)
 653   (shr-fontize-cont cont 'bold))
 654
 655 (defun shr-tag-i (cont)
 656   (shr-fontize-cont cont 'italic))
 657
 658 (defun shr-tag-em (cont)
 659   (shr-fontize-cont cont 'bold))
 660
 661 (defun shr-tag-strong (cont)
 662   (shr-fontize-cont cont 'bold))
 663
 664 (defun shr-tag-u (cont)
 665   (shr-fontize-cont cont 'underline))
 666
 667 (defun shr-tag-s (cont)
 668   (shr-fontize-cont cont 'strike-through))
 669
 670 (defun shr-parse-style (style)
 671   (when style
 672     (save-match-data
 673       (when (string-match "\n" style)
 674         (setq style (replace-match " " t t style))))
 675     (let ((plist nil))
 676       (dolist (elem (split-string style ";"))
 677         (when elem
 678           (setq elem (split-string elem ":"))
 679           (when (and (car elem)
 680                      (cadr elem))
 681             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 682                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 683               (when (string-match " *!important\\'" value)
 684                 (setq value (substring value 0 (match-beginning 0))))
 685               (push (cons (intern name obarray)
 686                           value)
 687                     plist)))))
 688       plist)))
 689
 690 (defun shr-tag-a (cont)
 691   (let ((url (cdr (assq :href cont)))
 692         (title (cdr (assq :title cont)))
 693         (start (point))
 694         shr-start)
 695     (shr-generic cont)
 696     (shr-urlify (or shr-start start) url title)))
 697
 698 (defun shr-tag-object (cont)
 699   (let ((start (point))
 700         url)
 701     (dolist (elem cont)
 702       (when (eq (car elem) 'embed)
 703         (setq url (or url (cdr (assq :src (cdr elem))))))
 704       (when (and (eq (car elem) 'param)
 705                  (equal (cdr (assq :name (cdr elem))) "movie"))
 706         (setq url (or url (cdr (assq :value (cdr elem)))))))
 707     (when url
 708       (shr-insert " [multimedia] ")
 709       (shr-urlify start url))
 710     (shr-generic cont)))
 711
 712 (defun shr-tag-video (cont)
 713   (let ((image (cdr (assq :poster cont)))
 714         (url (cdr (assq :src cont)))
 715         (start (point)))
 716     (shr-tag-img nil image)
 717     (shr-urlify start url)))
 718
 719 (defun shr-tag-img (cont &optional url)
 720   (when (or url
 721             (and cont
 722                  (cdr (assq :src cont))))
 723     (when (and (> (current-column) 0)
 724                (not (eq shr-state 'image)))
 725       (insert "\n"))
 726     (let ((alt (cdr (assq :alt cont)))
 727           (url (or url (cdr (assq :src cont)))))
 728       (let ((start (point-marker)))
 729         (when (zerop (length alt))
 730           (setq alt "*"))
 731         (cond
 732          ((or (member (cdr (assq :height cont)) '("0" "1"))
 733               (member (cdr (assq :width cont)) '("0" "1")))
 734           ;; Ignore zero-sized or single-pixel images.
 735           )
 736          ((and (not shr-inhibit-images)
 737                (string-match "\\`cid:" url))
 738           (let ((url (substring url (match-end 0)))
 739                 image)
 740             (if (or (not shr-content-function)
 741                     (not (setq image (funcall shr-content-function url))))
 742                 (insert alt)
 743               (shr-put-image image alt))))
 744          ((or shr-inhibit-images
 745               (and shr-blocked-images
 746                    (string-match shr-blocked-images url)))
 747           (setq shr-start (point))
 748           (let ((shr-state 'space))
 749             (if (> (string-width alt) 8)
 750                 (shr-insert (truncate-string-to-width alt 8))
 751               (shr-insert alt))))
 752          ((url-is-cached (shr-encode-url url))
 753           (shr-put-image (shr-get-image-data url) alt))
 754          (t
 755           (insert alt)
 756           (ignore-errors
 757             (url-retrieve (shr-encode-url url) 'shr-image-fetched
 758                           (list (current-buffer) start (point-marker))
 759                           t))))
 760         (put-text-property start (point) 'keymap shr-map)
 761         (put-text-property start (point) 'shr-alt alt)
 762         (put-text-property start (point) 'image-url url)
 763         (put-text-property start (point) 'image-displayer
 764                            (shr-image-displayer shr-content-function))
 765         (put-text-property start (point) 'help-echo alt)
 766         (setq shr-state 'image)))))
 767
 768 (defun shr-tag-pre (cont)
 769   (let ((shr-folding-mode 'none))
 770     (shr-ensure-newline)
 771     (shr-indent)
 772     (shr-generic cont)
 773     (shr-ensure-newline)))
 774
 775 (defun shr-tag-blockquote (cont)
 776   (shr-ensure-paragraph)
 777   (shr-indent)
 778   (let ((shr-indentation (+ shr-indentation 4)))
 779     (shr-generic cont))
 780   (shr-ensure-paragraph))
 781
 782 (defun shr-tag-ul (cont)
 783   (shr-ensure-paragraph)
 784   (let ((shr-list-mode 'ul))
 785     (shr-generic cont))
 786   (shr-ensure-paragraph))
 787
 788 (defun shr-tag-ol (cont)
 789   (shr-ensure-paragraph)
 790   (let ((shr-list-mode 1))
 791     (shr-generic cont))
 792   (shr-ensure-paragraph))
 793
 794 (defun shr-tag-li (cont)
 795   (shr-ensure-paragraph)
 796   (shr-indent)
 797   (let* ((bullet
 798           (if (numberp shr-list-mode)
 799               (prog1
 800                   (format "%d " shr-list-mode)
 801                 (setq shr-list-mode (1+ shr-list-mode)))
 802             "* "))
 803          (shr-indentation (+ shr-indentation (length bullet))))
 804     (insert bullet)
 805     (shr-generic cont)))
 806
 807 (defun shr-tag-br (cont)
 808   (unless (bobp)
 809     (insert "\n")
 810     (shr-indent))
 811   (shr-generic cont))
 812
 813 (defun shr-tag-h1 (cont)
 814   (shr-heading cont 'bold 'underline))
 815
 816 (defun shr-tag-h2 (cont)
 817   (shr-heading cont 'bold))
 818
 819 (defun shr-tag-h3 (cont)
 820   (shr-heading cont 'italic))
 821
 822 (defun shr-tag-h4 (cont)
 823   (shr-heading cont))
 824
 825 (defun shr-tag-h5 (cont)
 826   (shr-heading cont))
 827
 828 (defun shr-tag-h6 (cont)
 829   (shr-heading cont))
 830
 831 (defun shr-tag-hr (cont)
 832   (shr-ensure-newline)
 833   (insert (make-string shr-width shr-hr-line) "\n"))
 834
 835 (defun shr-tag-title (cont)
 836   (shr-heading cont 'bold 'underline))
 837
 838 (defun shr-tag-font (cont)
 839   (let* ((start (point))
 840          (color (cdr (assq :color cont)))
 841          (shr-stylesheet (list (cons 'color color))))
 842     (shr-generic cont)))
 843
 844 ;;; Table rendering algorithm.
 845
 846 ;; Table rendering is the only complicated thing here.  We do this by
 847 ;; first counting how many TDs there are in each TR, and registering
 848 ;; how wide they think they should be ("width=45%", etc).  Then we
 849 ;; render each TD separately (this is done in temporary buffers, so
 850 ;; that we can use all the rendering machinery as if we were in the
 851 ;; main buffer).  Now we know how much space each TD really takes, so
 852 ;; we then render everything again with the new widths, and finally
 853 ;; insert all these boxes into the main buffer.
 854 (defun shr-tag-table-1 (cont)
 855   (setq cont (or (cdr (assq 'tbody cont))
 856                  cont))
 857   (let* ((shr-inhibit-images t)
 858          (shr-table-depth (1+ shr-table-depth))
 859          (shr-kinsoku-shorten t)
 860          ;; Find all suggested widths.
 861          (columns (shr-column-specs cont))
 862          ;; Compute how many characters wide each TD should be.
 863          (suggested-widths (shr-pro-rate-columns columns))
 864          ;; Do a "test rendering" to see how big each TD is (this can
 865          ;; be smaller (if there's little text) or bigger (if there's
 866          ;; unbreakable text).
 867          (sketch (shr-make-table cont suggested-widths))
 868          (sketch-widths (shr-table-widths sketch suggested-widths)))
 869     ;; This probably won't work very well.
 870     (when (> (+ (loop for width across sketch-widths
 871                       summing (1+ width))
 872                 shr-indentation 1)
 873              (frame-width))
 874       (setq truncate-lines t))
 875     ;; Then render the table again with these new "hard" widths.
 876     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
 877   ;; Finally, insert all the images after the table.  The Emacs buffer
 878   ;; model isn't strong enough to allow us to put the images actually
 879   ;; into the tables.
 880   (when (zerop shr-table-depth)
 881     (dolist (elem (shr-find-elements cont 'img))
 882       (shr-tag-img (cdr elem)))))
 883
 884 (defun shr-tag-table (cont)
 885   (shr-ensure-paragraph)
 886   (let* ((caption (cdr (assq 'caption cont)))
 887          (header (cdr (assq 'thead cont)))
 888          (body (or (cdr (assq 'tbody cont)) cont))
 889          (footer (cdr (assq 'tfoot cont)))
 890          (bgcolor (cdr (assq :bgcolor cont)))
 891          (nheader (if header (shr-max-columns header)))
 892          (nbody (if body (shr-max-columns body)))
 893          (nfooter (if footer (shr-max-columns footer))))
 894     (shr-tag-table-1
 895      (nconc
 896       (if caption `((tr (td ,@caption))))
 897       (if header
 898           (if footer
 899               ;; hader + body + footer
 900               (if (= nheader nbody)
 901                   (if (= nbody nfooter)
 902                       `((tr (td (table (tbody ,@header ,@body ,@footer)))))
 903                     (nconc `((tr (td (table (tbody ,@header ,@body)))))
 904                            (if (= nfooter 1)
 905                                footer
 906                              `((tr (td (table (tbody ,@footer))))))))
 907                 (nconc `((tr (td (table (tbody ,@header)))))
 908                        (if (= nbody nfooter)
 909                            `((tr (td (table (tbody ,@body ,@footer)))))
 910                          (nconc `((tr (td (table (tbody ,@body)))))
 911                                 (if (= nfooter 1)
 912                                     footer
 913                                   `((tr (td (table (tbody ,@footer))))))))))
 914             ;; header + body
 915             (if (= nheader nbody)
 916                 `((tr (td (table (tbody ,@header ,@body)))))
 917               (if (= nheader 1)
 918                   `(,@header (tr (td (table (tbody ,@body)))))
 919                 `((tr (td (table (tbody ,@header))))
 920                   (tr (td (table (tbody ,@body))))))))
 921         (if footer
 922             ;; body + footer
 923             (if (= nbody nfooter)
 924                 `((tr (td (table (tbody ,@body ,@footer)))))
 925               (nconc `((tr (td (table (tbody ,@body)))))
 926                      (if (= nfooter 1)
 927                          footer
 928                        `((tr (td (table (tbody ,@footer))))))))
 929           (if caption
 930               `((tr (td (table (tbody ,@body)))))
 931             body)))))))
 932
 933 (defun shr-find-elements (cont type)
 934   (let (result)
 935     (dolist (elem cont)
 936       (cond ((eq (car elem) type)
 937              (push elem result))
 938             ((consp (cdr elem))
 939              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
 940     (nreverse result)))
 941
 942 (defun shr-insert-table (table widths)
 943   (shr-insert-table-ruler widths)
 944   (dolist (row table)
 945     (let ((start (point))
 946           (height (let ((max 0))
 947                     (dolist (column row)
 948                       (setq max (max max (cadr column))))
 949                     max)))
 950       (dotimes (i height)
 951         (shr-indent)
 952         (insert shr-table-vertical-line "\n"))
 953       (dolist (column row)
 954         (goto-char start)
 955         (let ((lines (nth 2 column))
 956               (overlay-lines (nth 3 column))
 957               overlay overlay-line)
 958           (dolist (line lines)
 959             (setq overlay-line (pop overlay-lines))
 960             (end-of-line)
 961             (insert line shr-table-vertical-line)
 962             (dolist (overlay overlay-line)
 963               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
 964                                      (- (point) (nth 1 overlay) 1)))
 965                     (properties (nth 2 overlay)))
 966                 (while properties
 967                   (overlay-put o (pop properties) (pop properties)))))
 968             (forward-line 1))
 969           ;; Add blank lines at padding at the bottom of the TD,
 970           ;; possibly.
 971           (dotimes (i (- height (length lines)))
 972             (end-of-line)
 973             (insert (make-string (string-width (car lines)) ? )
 974                     shr-table-vertical-line)
 975             (forward-line 1)))))
 976     (shr-insert-table-ruler widths)))
 977
 978 (defun shr-insert-table-ruler (widths)
 979   (when (and (bolp)
 980              (> shr-indentation 0))
 981     (shr-indent))
 982   (insert shr-table-corner)
 983   (dotimes (i (length widths))
 984     (insert (make-string (aref widths i) shr-table-horizontal-line)
 985             shr-table-corner))
 986   (insert "\n"))
 987
 988 (defun shr-table-widths (table suggested-widths)
 989   (let* ((length (length suggested-widths))
 990          (widths (make-vector length 0))
 991          (natural-widths (make-vector length 0)))
 992     (dolist (row table)
 993       (let ((i 0))
 994         (dolist (column row)
 995           (aset widths i (max (aref widths i)
 996                               (car column)))
 997           (aset natural-widths i (max (aref natural-widths i)
 998                                       (cadr column)))
 999           (setq i (1+ i)))))
1000     (let ((extra (- (apply '+ (append suggested-widths nil))
1001                     (apply '+ (append widths nil))))
1002           (expanded-columns 0))
1003       (when (> extra 0)
1004         (dotimes (i length)
1005           ;; If the natural width is wider than the rendered width, we
1006           ;; want to allow the column to expand.
1007           (when (> (aref natural-widths i) (aref widths i))
1008             (setq expanded-columns (1+ expanded-columns))))
1009         (dotimes (i length)
1010           (when (> (aref natural-widths i) (aref widths i))
1011             (aset widths i (min
1012                             (1+ (aref natural-widths i))
1013                             (+ (/ extra expanded-columns)
1014                                (aref widths i))))))))
1015     widths))
1016
1017 (defun shr-make-table (cont widths &optional fill)
1018   (let ((trs nil))
1019     (dolist (row cont)
1020       (when (eq (car row) 'tr)
1021         (let ((tds nil)
1022               (columns (cdr row))
1023               (i 0)
1024               column)
1025           (while (< i (length widths))
1026             (setq column (pop columns))
1027             (when (or (memq (car column) '(td th))
1028                       (null column))
1029               (push (shr-render-td (cdr column) (aref widths i) fill)
1030                     tds)
1031               (setq i (1+ i))))
1032           (push (nreverse tds) trs))))
1033     (nreverse trs)))
1034
1035 (defun shr-render-td (cont width fill)
1036   (with-temp-buffer
1037     (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
1038       (if cache
1039           (insert cache)
1040         (let ((shr-width width)
1041               (shr-indentation 0))
1042           (shr-descend (cons 'td cont)))
1043         (delete-region
1044          (point)
1045          (+ (point)
1046             (skip-chars-backward " \t\n")))
1047         (push (cons (cons width cont) (buffer-string))
1048               shr-content-cache)))
1049     (goto-char (point-min))
1050     (let ((max 0))
1051       (while (not (eobp))
1052         (end-of-line)
1053         (setq max (max max (current-column)))
1054         (forward-line 1))
1055       (when fill
1056         (goto-char (point-min))
1057         ;; If the buffer is totally empty, then put a single blank
1058         ;; line here.
1059         (if (zerop (buffer-size))
1060             (insert (make-string width ? ))
1061           ;; Otherwise, fill the buffer.
1062           (while (not (eobp))
1063             (end-of-line)
1064             (when (> (- width (current-column)) 0)
1065               (insert (make-string (- width (current-column)) ? )))
1066             (forward-line 1))))
1067       (if fill
1068           (list max
1069                 (count-lines (point-min) (point-max))
1070                 (split-string (buffer-string) "\n")
1071                 (shr-collect-overlays))
1072         (list max
1073               (shr-natural-width))))))
1074
1075 (defun shr-natural-width ()
1076   (goto-char (point-min))
1077   (let ((current 0)
1078         (max 0))
1079     (while (not (eobp))
1080       (end-of-line)
1081       (setq current (+ current (current-column)))
1082       (unless (get-text-property (point) 'shr-break)
1083         (setq max (max max current)
1084               current 0))
1085       (forward-line 1))
1086     max))
1087
1088 (defun shr-collect-overlays ()
1089   (save-excursion
1090     (goto-char (point-min))
1091     (let ((overlays nil))
1092       (while (not (eobp))
1093         (push (shr-overlays-in-region (point) (line-end-position))
1094               overlays)
1095         (forward-line 1))
1096       (nreverse overlays))))
1097
1098 (defun shr-overlays-in-region (start end)
1099   (let (result)
1100     (dolist (overlay (overlays-in start end))
1101       (push (list (if (> start (overlay-start overlay))
1102                       (- end start)
1103                     (- end (overlay-start overlay)))
1104                   (if (< end (overlay-end overlay))
1105                       0
1106                     (- end (overlay-end overlay)))
1107                   (overlay-properties overlay))
1108             result))
1109     (nreverse result)))
1110
1111 (defun shr-pro-rate-columns (columns)
1112   (let ((total-percentage 0)
1113         (widths (make-vector (length columns) 0)))
1114     (dotimes (i (length columns))
1115       (setq total-percentage (+ total-percentage (aref columns i))))
1116     (setq total-percentage (/ 1.0 total-percentage))
1117     (dotimes (i (length columns))
1118       (aset widths i (max (truncate (* (aref columns i)
1119                                        total-percentage
1120                                        (- shr-width (1+ (length columns)))))
1121                           10)))
1122     widths))
1123
1124 ;; Return a summary of the number and shape of the TDs in the table.
1125 (defun shr-column-specs (cont)
1126   (let ((columns (make-vector (shr-max-columns cont) 1)))
1127     (dolist (row cont)
1128       (when (eq (car row) 'tr)
1129         (let ((i 0))
1130           (dolist (column (cdr row))
1131             (when (memq (car column) '(td th))
1132               (let ((width (cdr (assq :width (cdr column)))))
1133                 (when (and width
1134                            (string-match "\\([0-9]+\\)%" width))
1135                   (aset columns i
1136                         (/ (string-to-number (match-string 1 width))
1137                            100.0))))
1138               (setq i (1+ i)))))))
1139     columns))
1140
1141 (defun shr-count (cont elem)
1142   (let ((i 0))
1143     (dolist (sub cont)
1144       (when (eq (car sub) elem)
1145         (setq i (1+ i))))
1146     i))
1147
1148 (defun shr-max-columns (cont)
1149   (let ((max 0))
1150     (dolist (row cont)
1151       (when (eq (car row) 'tr)
1152         (setq max (max max (+ (shr-count (cdr row) 'td)
1153                               (shr-count (cdr row) 'th))))))
1154     max))
1155
1156 (provide 'shr)
1157
1158 ;;; shr.el ends here