cgit.sxemacs.org Git - gnus/blob - lisp/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35 (unless (aref (char-category-set (make-char 'japanese-jisx0208 33 35)) ?>)
  36   (load "kinsoku" nil t))
  37
  38 (defgroup shr nil
  39   "Simple HTML Renderer"
  40   :group 'mail)
  41
  42 (defcustom shr-max-image-proportion 0.9
  43   "How big pictures displayed are in relation to the window they're in.
  44 A value of 0.7 means that they are allowed to take up 70% of the
  45 width and height of the window.  If they are larger than this,
  46 and Emacs supports it, then the images will be rescaled down to
  47 fit these criteria."
  48   :version "24.1"
  49   :group 'shr
  50   :type 'float)
  51
  52 (defcustom shr-blocked-images nil
  53   "Images that have URLs matching this regexp will be blocked."
  54   :version "24.1"
  55   :group 'shr
  56   :type 'regexp)
  57
  58 (defcustom shr-table-line ?-
  59   "Character used to draw table line."
  60   :group 'shr
  61   :type 'character)
  62
  63 (defcustom shr-table-corner ?+
  64   "Character used to draw table corner."
  65   :group 'shr
  66   :type 'character)
  67
  68 (defcustom shr-hr-line ?-
  69   "Character used to draw hr line."
  70   :group 'shr
  71   :type 'character)
  72
  73 (defcustom shr-width fill-column
  74   "Frame width to use for rendering."
  75   :type 'integer
  76   :group 'shr)
  77
  78 (defvar shr-content-function nil
  79   "If bound, this should be a function that will return the content.
  80 This is used for cid: URLs, and the function is called with the
  81 cid: URL as the argument.")
  82
  83 ;;; Internal variables.
  84
  85 (defvar shr-folding-mode nil)
  86 (defvar shr-state nil)
  87 (defvar shr-start nil)
  88 (defvar shr-indentation 0)
  89 (defvar shr-inhibit-images nil)
  90 (defvar shr-list-mode nil)
  91 (defvar shr-content-cache nil)
  92 (defvar shr-kinsoku-shorten nil)
  93
  94 (defvar shr-map
  95   (let ((map (make-sparse-keymap)))
  96     (define-key map "a" 'shr-show-alt-text)
  97     (define-key map "i" 'shr-browse-image)
  98     (define-key map "I" 'shr-insert-image)
  99     (define-key map "u" 'shr-copy-url)
 100     (define-key map "v" 'shr-browse-url)
 101     (define-key map "o" 'shr-save-contents)
 102     (define-key map "\r" 'shr-browse-url)
 103     map))
 104
 105 ;; Public functions and commands.
 106
 107 ;;;###autoload
 108 (defun shr-insert-document (dom)
 109   (setq shr-content-cache nil)
 110   (let ((shr-state nil)
 111         (shr-start nil))
 112     (shr-descend (shr-transform-dom dom))))
 113
 114 (defun shr-copy-url ()
 115   "Copy the URL under point to the kill ring.
 116 If called twice, then try to fetch the URL and see whether it
 117 redirects somewhere else."
 118   (interactive)
 119   (let ((url (get-text-property (point) 'shr-url)))
 120     (cond
 121      ((not url)
 122       (message "No URL under point"))
 123      ;; Resolve redirected URLs.
 124      ((equal url (car kill-ring))
 125       (url-retrieve
 126        url
 127        (lambda (a)
 128          (when (and (consp a)
 129                     (eq (car a) :redirect))
 130            (with-temp-buffer
 131              (insert (cadr a))
 132              (goto-char (point-min))
 133              ;; Remove common tracking junk from the URL.
 134              (when (re-search-forward ".utm_.*" nil t)
 135                (replace-match "" t t))
 136              (message "Copied %s" (buffer-string))
 137              (copy-region-as-kill (point-min) (point-max)))))))
 138      ;; Copy the URL to the kill ring.
 139      (t
 140       (with-temp-buffer
 141         (insert url)
 142         (copy-region-as-kill (point-min) (point-max))
 143         (message "Copied %s" url))))))
 144
 145 (defun shr-show-alt-text ()
 146   "Show the ALT text of the image under point."
 147   (interactive)
 148   (let ((text (get-text-property (point) 'shr-alt)))
 149     (if (not text)
 150         (message "No image under point")
 151       (message "%s" text))))
 152
 153 (defun shr-browse-image ()
 154   "Browse the image under point."
 155   (interactive)
 156   (let ((url (get-text-property (point) 'shr-image)))
 157     (if (not url)
 158         (message "No image under point")
 159       (message "Browsing %s..." url)
 160       (browse-url url))))
 161
 162 (defun shr-insert-image ()
 163   "Insert the image under point into the buffer."
 164   (interactive)
 165   (let ((url (get-text-property (point) 'shr-image)))
 166     (if (not url)
 167         (message "No image under point")
 168       (message "Inserting %s..." url)
 169       (url-retrieve url 'shr-image-fetched
 170                     (list (current-buffer) (1- (point)) (point-marker))
 171                     t))))
 172
 173 ;;; Utility functions.
 174
 175 (defun shr-transform-dom (dom)
 176   (let ((result (list (pop dom))))
 177     (dolist (arg (pop dom))
 178       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 179                   (cdr arg))
 180             result))
 181     (dolist (sub dom)
 182       (if (stringp sub)
 183           (push (cons :text sub) result)
 184         (push (shr-transform-dom sub) result)))
 185     (nreverse result)))
 186
 187 (defun shr-descend (dom)
 188   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray)))
 189     (if (fboundp function)
 190         (funcall function (cdr dom))
 191       (shr-generic (cdr dom)))))
 192
 193 (defun shr-generic (cont)
 194   (dolist (sub cont)
 195     (cond
 196      ((eq (car sub) :text)
 197       (shr-insert (cdr sub)))
 198      ((listp (cdr sub))
 199       (shr-descend sub)))))
 200
 201 (defun shr-insert (text)
 202   (when (and (eq shr-state 'image)
 203              (not (string-match "\\`[ \t\n]+\\'" text)))
 204     (insert "\n")
 205     (setq shr-state nil))
 206   (cond
 207    ((eq shr-folding-mode 'none)
 208     (insert text))
 209    (t
 210     (when (and (string-match "\\`[ \t\n]" text)
 211                (not (bolp))
 212                (not (eq (char-after (1- (point))) ? )))
 213       (insert " "))
 214     (dolist (elem (split-string text))
 215       (when (and (bolp)
 216                  (> shr-indentation 0))
 217         (shr-indent))
 218       ;; The shr-start is a special variable that is used to pass
 219       ;; upwards the first point in the buffer where the text really
 220       ;; starts.
 221       (unless shr-start
 222         (setq shr-start (point)))
 223       ;; No space is needed behind a wide character categorized as
 224       ;; kinsoku-bol, between characters both categorized as nospace,
 225       ;; or at the beginning of a line.
 226       (let (prev)
 227         (when (and (eq (preceding-char) ? )
 228                    (or (= (line-beginning-position) (1- (point)))
 229                        (and (aref fill-find-break-point-function-table
 230                                   (setq prev (char-after (- (point) 2))))
 231                             (aref (char-category-set prev) ?>))
 232                        (and (aref fill-nospace-between-words-table prev)
 233                             (aref fill-nospace-between-words-table
 234                                   (aref elem 0)))))
 235           (delete-char -1)))
 236       (insert elem)
 237       (while (> (current-column) shr-width)
 238         (unless (prog1
 239                     (shr-find-fill-point)
 240                   (when (eq (preceding-char) ? )
 241                     (delete-char -1))
 242                   (insert "\n"))
 243           (put-text-property (1- (point)) (point) 'shr-break t)
 244           ;; No space is needed at the beginning of a line.
 245           (when (eq (following-char) ? )
 246             (delete-char 1)))
 247         (when (> shr-indentation 0)
 248           (shr-indent))
 249         (end-of-line))
 250       (insert " "))
 251     (unless (string-match "[ \t\n]\\'" text)
 252       (delete-char -1)))))
 253
 254 (defun shr-find-fill-point ()
 255   (when (> (move-to-column shr-width) shr-width)
 256     (backward-char 1))
 257   (let (failed)
 258     (while (not
 259             (or (setq failed (= (current-column) shr-indentation))
 260                 (eq (preceding-char) ? )
 261                 (eq (following-char) ? )
 262                 (aref fill-find-break-point-function-table (preceding-char))))
 263       (backward-char 1))
 264     (if failed
 265         ;; There's no breakable point, so we give it up.
 266         (progn
 267           (end-of-line)
 268           (while (aref fill-find-break-point-function-table (preceding-char))
 269             (backward-char 1))
 270           nil)
 271       (or (eolp)
 272           ;; Don't put kinsoku-bol characters at the beginning of a line,
 273           ;; or kinsoku-eol characters at the end of a line,
 274           (let ((count 4))
 275             (if (or shr-kinsoku-shorten
 276                     (and (aref (char-category-set (preceding-char)) ?<)
 277                          (progn
 278                            (setq count (1- count))
 279                            (backward-char 1)
 280                            t)))
 281                 (while (and
 282                         (>= (setq count (1- count)) 0)
 283                         (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 284                         (or (aref (char-category-set (preceding-char)) ?<)
 285                             (aref (char-category-set (following-char)) ?>)))
 286                   (backward-char 1))
 287               (while (and (>= (setq count (1- count)) 0)
 288                           (aref (char-category-set (following-char)) ?>))
 289                 (forward-char 1)))
 290             (when (eq (following-char) ? )
 291               (forward-char 1))
 292             t)))))
 293
 294 (defun shr-ensure-newline ()
 295   (unless (zerop (current-column))
 296     (insert "\n")))
 297
 298 (defun shr-ensure-paragraph ()
 299   (unless (bobp)
 300     (if (<= (current-column) shr-indentation)
 301         (unless (save-excursion
 302                   (forward-line -1)
 303                   (looking-at " *$"))
 304           (insert "\n"))
 305       (if (save-excursion
 306             (beginning-of-line)
 307             (looking-at " *$"))
 308           (insert "\n")
 309         (insert "\n\n")))))
 310
 311 (defun shr-indent ()
 312   (when (> shr-indentation 0)
 313     (insert (make-string shr-indentation ? ))))
 314
 315 (defun shr-fontize-cont (cont &rest types)
 316   (let (shr-start)
 317     (shr-generic cont)
 318     (dolist (type types)
 319       (shr-add-font (or shr-start (point)) (point) type))))
 320
 321 ;; Add an overlay in the region, but avoid putting the font properties
 322 ;; on blank text at the start of the line, and the newline at the end,
 323 ;; to avoid ugliness.
 324 (defun shr-add-font (start end type)
 325   (save-excursion
 326     (goto-char start)
 327     (while (< (point) end)
 328       (when (bolp)
 329         (skip-chars-forward " "))
 330       (let ((overlay (make-overlay (point) (min (line-end-position) end))))
 331         (overlay-put overlay 'face type))
 332       (if (< (line-end-position) end)
 333           (forward-line 1)
 334         (goto-char end)))))
 335
 336 (defun shr-browse-url ()
 337   "Browse the URL under point."
 338   (interactive)
 339   (let ((url (get-text-property (point) 'shr-url)))
 340     (if (not url)
 341         (message "No link under point")
 342       (browse-url url))))
 343
 344 (defun shr-save-contents (directory)
 345   "Save the contents from URL in a file."
 346   (interactive "DSave contents of URL to directory: ")
 347   (let ((url (get-text-property (point) 'shr-url)))
 348     (if (not url)
 349         (message "No link under point")
 350       (url-retrieve (shr-encode-url url)
 351                     'shr-store-contents (list url directory)))))
 352
 353 (defun shr-store-contents (status url directory)
 354   (unless (plist-get status :error)
 355     (when (or (search-forward "\n\n" nil t)
 356               (search-forward "\r\n\r\n" nil t))
 357       (write-region (point) (point-max)
 358                     (expand-file-name (file-name-nondirectory url)
 359                                       directory)))))
 360
 361 (defun shr-image-fetched (status buffer start end)
 362   (when (and (buffer-name buffer)
 363              (not (plist-get status :error)))
 364     (url-store-in-cache (current-buffer))
 365     (when (or (search-forward "\n\n" nil t)
 366               (search-forward "\r\n\r\n" nil t))
 367       (let ((data (buffer-substring (point) (point-max))))
 368         (with-current-buffer buffer
 369           (let ((alt (buffer-substring start end))
 370                 (inhibit-read-only t))
 371             (delete-region start end)
 372             (shr-put-image data start alt))))))
 373   (kill-buffer (current-buffer)))
 374
 375 (defun shr-put-image (data point alt)
 376   (if (not (display-graphic-p))
 377       (insert alt)
 378     (let ((image (ignore-errors
 379                    (shr-rescale-image data))))
 380       (when image
 381         (put-image image point alt)))))
 382
 383 (defun shr-rescale-image (data)
 384   (if (or (not (fboundp 'imagemagick-types))
 385           (not (get-buffer-window (current-buffer))))
 386       (create-image data nil t)
 387     (let* ((image (create-image data nil t))
 388            (size (image-size image t))
 389            (width (car size))
 390            (height (cdr size))
 391            (edges (window-inside-pixel-edges
 392                    (get-buffer-window (current-buffer))))
 393            (window-width (truncate (* shr-max-image-proportion
 394                                       (- (nth 2 edges) (nth 0 edges)))))
 395            (window-height (truncate (* shr-max-image-proportion
 396                                        (- (nth 3 edges) (nth 1 edges)))))
 397            scaled-image)
 398       (when (> height window-height)
 399         (setq image (or (create-image data 'imagemagick t
 400                                       :height window-height)
 401                         image))
 402         (setq size (image-size image t)))
 403       (when (> (car size) window-width)
 404         (setq image (or
 405                      (create-image data 'imagemagick t
 406                                    :width window-width)
 407                      image)))
 408       image)))
 409
 410 (defun shr-get-image-data (url)
 411   "Get image data for URL.
 412 Return a string with image data."
 413   (with-temp-buffer
 414     (mm-disable-multibyte)
 415     (when (ignore-errors
 416             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 417             t)
 418       (when (or (search-forward "\n\n" nil t)
 419                 (search-forward "\r\n\r\n" nil t))
 420         (buffer-substring (point) (point-max))))))
 421
 422 (defun shr-heading (cont &rest types)
 423   (shr-ensure-paragraph)
 424   (apply #'shr-fontize-cont cont types)
 425   (shr-ensure-paragraph))
 426
 427 (defun shr-urlify (start url)
 428   (widget-convert-button
 429    'url-link start (point)
 430    :help-echo url
 431    :keymap shr-map
 432    url)
 433   (put-text-property start (point) 'shr-url url))
 434
 435 (defun shr-encode-url (url)
 436   "Encode URL."
 437   (browse-url-url-encode-chars url "[)$ ]"))
 438
 439 ;;; Tag-specific rendering rules.
 440
 441 (defun shr-tag-p (cont)
 442   (shr-ensure-paragraph)
 443   (shr-indent)
 444   (shr-generic cont)
 445   (shr-ensure-paragraph))
 446
 447 (defun shr-tag-b (cont)
 448   (shr-fontize-cont cont 'bold))
 449
 450 (defun shr-tag-i (cont)
 451   (shr-fontize-cont cont 'italic))
 452
 453 (defun shr-tag-em (cont)
 454   (shr-fontize-cont cont 'bold))
 455
 456 (defun shr-tag-strong (cont)
 457   (shr-fontize-cont cont 'bold))
 458
 459 (defun shr-tag-u (cont)
 460   (shr-fontize-cont cont 'underline))
 461
 462 (defun shr-tag-s (cont)
 463   (shr-fontize-cont cont 'strike-through))
 464
 465 (defun shr-tag-span (cont)
 466   (let ((start (point))
 467         (color (cdr (assq 'color (shr-parse-style (cdr (assq :style cont)))))))
 468     (shr-generic cont)
 469     (when color
 470       (let ((overlay (make-overlay start (point))))
 471         (overlay-put overlay 'face (cons 'foreground-color color))))))
 472
 473 (defun shr-parse-style (style)
 474   (when style
 475     (let ((plist nil))
 476       (dolist (elem (split-string style ";"))
 477         (when elem
 478           (setq elem (split-string elem ":"))
 479           (when (and (car elem)
 480                      (cadr elem))
 481             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 482                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 483               (push (cons (intern name obarray)
 484                           value)
 485                     plist)))))
 486       plist)))
 487
 488 (defun shr-tag-a (cont)
 489   (let ((url (cdr (assq :href cont)))
 490         (start (point))
 491         shr-start)
 492     (shr-generic cont)
 493     (shr-urlify (or shr-start start) url)))
 494
 495 (defun shr-tag-object (cont)
 496   (let ((url (cdr (assq :src (cdr (assq 'embed cont)))))
 497         (start (point)))
 498     (when url
 499       (shr-insert " [multimedia] ")
 500       (shr-urlify start url))))
 501
 502 (defun shr-tag-img (cont)
 503   (when (and cont
 504              (cdr (assq :src cont)))
 505     (when (and (> (current-column) 0)
 506                (not (eq shr-state 'image)))
 507       (insert "\n"))
 508     (let ((alt (cdr (assq :alt cont)))
 509           (url (cdr (assq :src cont))))
 510       (let ((start (point-marker)))
 511         (when (zerop (length alt))
 512           (setq alt "[img]"))
 513         (cond
 514          ((and (not shr-inhibit-images)
 515                (string-match "\\`cid:" url))
 516           (let ((url (substring url (match-end 0)))
 517                 image)
 518             (if (or (not shr-content-function)
 519                     (not (setq image (funcall shr-content-function url))))
 520                 (insert alt)
 521               (shr-put-image image (point) alt))))
 522          ((or shr-inhibit-images
 523               (and shr-blocked-images
 524                    (string-match shr-blocked-images url)))
 525           (setq shr-start (point))
 526           (let ((shr-state 'space))
 527             (if (> (length alt) 8)
 528                 (shr-insert (substring alt 0 8))
 529               (shr-insert alt))))
 530          ((url-is-cached (shr-encode-url url))
 531           (shr-put-image (shr-get-image-data url) (point) alt))
 532          (t
 533           (insert alt)
 534           (ignore-errors
 535             (url-retrieve (shr-encode-url url) 'shr-image-fetched
 536                           (list (current-buffer) start (point-marker))
 537                           t))))
 538         (insert " ")
 539         (put-text-property start (point) 'keymap shr-map)
 540         (put-text-property start (point) 'shr-alt alt)
 541         (put-text-property start (point) 'shr-image url)
 542         (setq shr-state 'image)))))
 543
 544 (defun shr-tag-pre (cont)
 545   (let ((shr-folding-mode 'none))
 546     (shr-ensure-newline)
 547     (shr-indent)
 548     (shr-generic cont)
 549     (shr-ensure-newline)))
 550
 551 (defun shr-tag-blockquote (cont)
 552   (shr-ensure-paragraph)
 553   (shr-indent)
 554   (let ((shr-indentation (+ shr-indentation 4)))
 555     (shr-generic cont))
 556   (shr-ensure-paragraph))
 557
 558 (defun shr-tag-ul (cont)
 559   (shr-ensure-paragraph)
 560   (let ((shr-list-mode 'ul))
 561     (shr-generic cont))
 562   (shr-ensure-paragraph))
 563
 564 (defun shr-tag-ol (cont)
 565   (shr-ensure-paragraph)
 566   (let ((shr-list-mode 1))
 567     (shr-generic cont))
 568   (shr-ensure-paragraph))
 569
 570 (defun shr-tag-li (cont)
 571   (shr-ensure-paragraph)
 572   (shr-indent)
 573   (let* ((bullet
 574           (if (numberp shr-list-mode)
 575               (prog1
 576                   (format "%d " shr-list-mode)
 577                 (setq shr-list-mode (1+ shr-list-mode)))
 578             "* "))
 579          (shr-indentation (+ shr-indentation (length bullet))))
 580     (insert bullet)
 581     (shr-generic cont)))
 582
 583 (defun shr-tag-br (cont)
 584   (unless (bobp)
 585     (insert "\n")
 586     (shr-indent))
 587   (shr-generic cont))
 588
 589 (defun shr-tag-h1 (cont)
 590   (shr-heading cont 'bold 'underline))
 591
 592 (defun shr-tag-h2 (cont)
 593   (shr-heading cont 'bold))
 594
 595 (defun shr-tag-h3 (cont)
 596   (shr-heading cont 'italic))
 597
 598 (defun shr-tag-h4 (cont)
 599   (shr-heading cont))
 600
 601 (defun shr-tag-h5 (cont)
 602   (shr-heading cont))
 603
 604 (defun shr-tag-h6 (cont)
 605   (shr-heading cont))
 606
 607 (defun shr-tag-hr (cont)
 608   (shr-ensure-newline)
 609   (insert (make-string shr-width shr-hr-line) "\n"))
 610
 611 ;;; Table rendering algorithm.
 612
 613 ;; Table rendering is the only complicated thing here.  We do this by
 614 ;; first counting how many TDs there are in each TR, and registering
 615 ;; how wide they think they should be ("width=45%", etc).  Then we
 616 ;; render each TD separately (this is done in temporary buffers, so
 617 ;; that we can use all the rendering machinery as if we were in the
 618 ;; main buffer).  Now we know how much space each TD really takes, so
 619 ;; we then render everything again with the new widths, and finally
 620 ;; insert all these boxes into the main buffer.
 621 (defun shr-tag-table-1 (cont)
 622   (setq cont (or (cdr (assq 'tbody cont))
 623                  cont))
 624   (let* ((shr-inhibit-images t)
 625          (shr-kinsoku-shorten t)
 626          ;; Find all suggested widths.
 627          (columns (shr-column-specs cont))
 628          ;; Compute how many characters wide each TD should be.
 629          (suggested-widths (shr-pro-rate-columns columns))
 630          ;; Do a "test rendering" to see how big each TD is (this can
 631          ;; be smaller (if there's little text) or bigger (if there's
 632          ;; unbreakable text).
 633          (sketch (shr-make-table cont suggested-widths))
 634          (sketch-widths (shr-table-widths sketch suggested-widths)))
 635     ;; This probably won't work very well.
 636     (when (> (+ (loop for width across sketch-widths
 637                       summing (1+ width))
 638                 shr-indentation 1)
 639              (frame-width))
 640       (setq truncate-lines t))
 641     ;; Then render the table again with these new "hard" widths.
 642     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
 643   ;; Finally, insert all the images after the table.  The Emacs buffer
 644   ;; model isn't strong enough to allow us to put the images actually
 645   ;; into the tables.
 646   (dolist (elem (shr-find-elements cont 'img))
 647     (shr-tag-img (cdr elem))))
 648
 649 (defun shr-tag-table (cont)
 650   (shr-ensure-paragraph)
 651   (let* ((caption (cdr (assq 'caption cont)))
 652          (header (cdr (assq 'thead cont)))
 653          (body (or (cdr (assq 'tbody cont)) cont))
 654          (footer (cdr (assq 'tfoot cont)))
 655          (nheader (if header (shr-max-columns header)))
 656          (nbody (if body (shr-max-columns body)))
 657          (nfooter (if footer (shr-max-columns footer))))
 658     (shr-tag-table-1
 659      (nconc
 660       (if caption `((tr (td ,@caption))))
 661       (if header
 662           (if footer
 663               ;; hader + body + footer
 664               (if (= nheader nbody)
 665                   (if (= nbody nfooter)
 666                       `((tr (td (table (tbody ,@header ,@body ,@footer)))))
 667                     (nconc `((tr (td (table (tbody ,@header ,@body)))))
 668                            (if (= nfooter 1)
 669                                footer
 670                              `((tr (td (table (tbody ,@footer))))))))
 671                 (nconc `((tr (td (table (tbody ,@header)))))
 672                        (if (= nbody nfooter)
 673                            `((tr (td (table (tbody ,@body ,@footer)))))
 674                          (nconc `((tr (td (table (tbody ,@body)))))
 675                                 (if (= nfooter 1)
 676                                     footer
 677                                   `((tr (td (table (tbody ,@footer))))))))))
 678             ;; header + body
 679             (if (= nheader nbody)
 680                 `((tr (td (table (tbody ,@header ,@body)))))
 681               (if (= nheader 1)
 682                   `(,@header (tr (td (table (tbody ,@body)))))
 683                 `((tr (td (table (tbody ,@header))))
 684                   (tr (td (table (tbody ,@body))))))))
 685         (if footer
 686             ;; body + footer
 687             (if (= nbody nfooter)
 688                 `((tr (td (table (tbody ,@body ,@footer)))))
 689               (nconc `((tr (td (table (tbody ,@body)))))
 690                      (if (= nfooter 1)
 691                          footer
 692                        `((tr (td (table (tbody ,@footer))))))))
 693           (if caption
 694               `((tr (td (table (tbody ,@body)))))
 695             body)))))))
 696
 697 (defun shr-find-elements (cont type)
 698   (let (result)
 699     (dolist (elem cont)
 700       (cond ((eq (car elem) type)
 701              (push elem result))
 702             ((consp (cdr elem))
 703              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
 704     (nreverse result)))
 705
 706 (defun shr-insert-table (table widths)
 707   (shr-insert-table-ruler widths)
 708   (dolist (row table)
 709     (let ((start (point))
 710           (height (let ((max 0))
 711                     (dolist (column row)
 712                       (setq max (max max (cadr column))))
 713                     max)))
 714       (dotimes (i height)
 715         (shr-indent)
 716         (insert "|\n"))
 717       (dolist (column row)
 718         (goto-char start)
 719         (let ((lines (nth 2 column))
 720               (overlay-lines (nth 3 column))
 721               overlay overlay-line)
 722           (dolist (line lines)
 723             (setq overlay-line (pop overlay-lines))
 724             (end-of-line)
 725             (insert line "|")
 726             (dolist (overlay overlay-line)
 727               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
 728                                      (- (point) (nth 1 overlay) 1)))
 729                     (properties (nth 2 overlay)))
 730                 (while properties
 731                   (overlay-put o (pop properties) (pop properties)))))
 732             (forward-line 1))
 733           ;; Add blank lines at padding at the bottom of the TD,
 734           ;; possibly.
 735           (dotimes (i (- height (length lines)))
 736             (end-of-line)
 737             (insert (make-string (string-width (car lines)) ? ) "|")
 738             (forward-line 1)))))
 739     (shr-insert-table-ruler widths)))
 740
 741 (defun shr-insert-table-ruler (widths)
 742   (when (and (bolp)
 743              (> shr-indentation 0))
 744     (shr-indent))
 745   (insert shr-table-corner)
 746   (dotimes (i (length widths))
 747     (insert (make-string (aref widths i) shr-table-line) shr-table-corner))
 748   (insert "\n"))
 749
 750 (defun shr-table-widths (table suggested-widths)
 751   (let* ((length (length suggested-widths))
 752          (widths (make-vector length 0))
 753          (natural-widths (make-vector length 0)))
 754     (dolist (row table)
 755       (let ((i 0))
 756         (dolist (column row)
 757           (aset widths i (max (aref widths i)
 758                               (car column)))
 759           (aset natural-widths i (max (aref natural-widths i)
 760                                       (cadr column)))
 761           (setq i (1+ i)))))
 762     (let ((extra (- (apply '+ (append suggested-widths nil))
 763                     (apply '+ (append widths nil))))
 764           (expanded-columns 0))
 765       (when (> extra 0)
 766         (dotimes (i length)
 767           ;; If the natural width is wider than the rendered width, we
 768           ;; want to allow the column to expand.
 769           (when (> (aref natural-widths i) (aref widths i))
 770             (setq expanded-columns (1+ expanded-columns))))
 771         (dotimes (i length)
 772           (when (> (aref natural-widths i) (aref widths i))
 773             (aset widths i (min
 774                             (1+ (aref natural-widths i))
 775                             (+ (/ extra expanded-columns)
 776                                (aref widths i))))))))
 777     widths))
 778
 779 (defun shr-make-table (cont widths &optional fill)
 780   (let ((trs nil))
 781     (dolist (row cont)
 782       (when (eq (car row) 'tr)
 783         (let ((tds nil)
 784               (columns (cdr row))
 785               (i 0)
 786               column)
 787           (while (< i (length widths))
 788             (setq column (pop columns))
 789             (when (or (memq (car column) '(td th))
 790                       (null column))
 791               (push (shr-render-td (cdr column) (aref widths i) fill)
 792                     tds)
 793               (setq i (1+ i))))
 794           (push (nreverse tds) trs))))
 795     (nreverse trs)))
 796
 797 (defun shr-render-td (cont width fill)
 798   (with-temp-buffer
 799     (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
 800       (if cache
 801           (insert cache)
 802         (let ((shr-width width)
 803               (shr-indentation 0))
 804           (shr-generic cont))
 805         (delete-region
 806          (point)
 807          (+ (point)
 808             (skip-chars-backward " \t\n")))
 809         (push (cons (cons width cont) (buffer-string))
 810               shr-content-cache)))
 811     (goto-char (point-min))
 812     (let ((max 0))
 813       (while (not (eobp))
 814         (end-of-line)
 815         (setq max (max max (current-column)))
 816         (forward-line 1))
 817       (when fill
 818         (goto-char (point-min))
 819         ;; If the buffer is totally empty, then put a single blank
 820         ;; line here.
 821         (if (zerop (buffer-size))
 822             (insert (make-string width ? ))
 823           ;; Otherwise, fill the buffer.
 824           (while (not (eobp))
 825             (end-of-line)
 826             (when (> (- width (current-column)) 0)
 827               (insert (make-string (- width (current-column)) ? )))
 828             (forward-line 1))))
 829       (if fill
 830           (list max
 831                 (count-lines (point-min) (point-max))
 832                 (split-string (buffer-string) "\n")
 833                 (shr-collect-overlays))
 834         (list max
 835               (shr-natural-width))))))
 836
 837 (defun shr-natural-width ()
 838   (goto-char (point-min))
 839   (let ((current 0)
 840         (max 0))
 841     (while (not (eobp))
 842       (end-of-line)
 843       (setq current (+ current (current-column)))
 844       (unless (get-text-property (point) 'shr-break)
 845         (setq max (max max current)
 846               current 0))
 847       (forward-line 1))
 848     max))
 849
 850 (defun shr-collect-overlays ()
 851   (save-excursion
 852     (goto-char (point-min))
 853     (let ((overlays nil))
 854       (while (not (eobp))
 855         (push (shr-overlays-in-region (point) (line-end-position))
 856               overlays)
 857         (forward-line 1))
 858       (nreverse overlays))))
 859
 860 (defun shr-overlays-in-region (start end)
 861   (let (result)
 862     (dolist (overlay (overlays-in start end))
 863       (push (list (if (> start (overlay-start overlay))
 864                       (- end start)
 865                     (- end (overlay-start overlay)))
 866                   (if (< end (overlay-end overlay))
 867                       0
 868                     (- end (overlay-end overlay)))
 869                   (overlay-properties overlay))
 870             result))
 871     (nreverse result)))
 872
 873 (defun shr-pro-rate-columns (columns)
 874   (let ((total-percentage 0)
 875         (widths (make-vector (length columns) 0)))
 876     (dotimes (i (length columns))
 877       (setq total-percentage (+ total-percentage (aref columns i))))
 878     (setq total-percentage (/ 1.0 total-percentage))
 879     (dotimes (i (length columns))
 880       (aset widths i (max (truncate (* (aref columns i)
 881                                        total-percentage
 882                                        (- shr-width (1+ (length columns)))))
 883                           10)))
 884     widths))
 885
 886 ;; Return a summary of the number and shape of the TDs in the table.
 887 (defun shr-column-specs (cont)
 888   (let ((columns (make-vector (shr-max-columns cont) 1)))
 889     (dolist (row cont)
 890       (when (eq (car row) 'tr)
 891         (let ((i 0))
 892           (dolist (column (cdr row))
 893             (when (memq (car column) '(td th))
 894               (let ((width (cdr (assq :width (cdr column)))))
 895                 (when (and width
 896                            (string-match "\\([0-9]+\\)%" width))
 897                   (aset columns i
 898                         (/ (string-to-number (match-string 1 width))
 899                            100.0))))
 900               (setq i (1+ i)))))))
 901     columns))
 902
 903 (defun shr-count (cont elem)
 904   (let ((i 0))
 905     (dolist (sub cont)
 906       (when (eq (car sub) elem)
 907         (setq i (1+ i))))
 908     i))
 909
 910 (defun shr-max-columns (cont)
 911   (let ((max 0))
 912     (dolist (row cont)
 913       (when (eq (car row) 'tr)
 914         (setq max (max max (+ (shr-count (cdr row) 'td)
 915                               (shr-count (cdr row) 'th))))))
 916     max))
 917
 918 (provide 'shr)
 919
 920 ;;; shr.el ends here