cgit.sxemacs.org Git - gnus/blob - lisp/rfc2047.el

   1 ;;; rfc2047.el --- functions for encoding and decoding rfc2047 messages
   2 ;; Copyright (C) 1998, 1999, 2000, 2002, 2003 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; RFC 2047 is "MIME (Multipurpose Internet Mail Extensions) Part
  26 ;; Three:  Message Header Extensions for Non-ASCII Text".
  27
  28 ;;; Code:
  29
  30 (eval-when-compile
  31   (require 'cl)
  32   (defvar message-posting-charset)
  33   (unless (fboundp 'with-syntax-table)  ; not in Emacs 20
  34     (defmacro with-syntax-table (table &rest body)
  35       "Evaluate BODY with syntax table of current buffer set to TABLE.
  36 The syntax table of the current buffer is saved, BODY is evaluated, and the
  37 saved table is restored, even in case of an abnormal exit.
  38 Value is what BODY returns."
  39       (let ((old-table (make-symbol "table"))
  40             (old-buffer (make-symbol "buffer")))
  41         `(let ((,old-table (syntax-table))
  42                (,old-buffer (current-buffer)))
  43            (unwind-protect
  44                (progn
  45                  (set-syntax-table ,table)
  46                  ,@body)
  47              (save-current-buffer
  48                (set-buffer ,old-buffer)
  49                (set-syntax-table ,old-table))))))))
  50
  51 (require 'qp)
  52 (require 'mm-util)
  53 ;; Fixme: Avoid this (used for mail-parse-charset) mm dependence on gnus.
  54 (require 'mail-prsvr)
  55 (require 'base64)
  56 (autoload 'mm-body-7-or-8 "mm-bodies")
  57
  58 (eval-and-compile
  59   ;; Avoid gnus-util for mm- code.
  60   (defalias 'rfc2047-point-at-bol
  61     (if (fboundp 'point-at-bol)
  62         'point-at-bol
  63       'line-beginning-position))
  64
  65   (defalias 'rfc2047-point-at-eol
  66     (if (fboundp 'point-at-eol)
  67         'point-at-eol
  68       'line-end-position)))
  69
  70 (defvar rfc2047-header-encoding-alist
  71   '(("Newsgroups" . nil)
  72     ("Followup-To" . nil)
  73     ("Message-ID" . nil)
  74     ("\\(Resent-\\)?\\(From\\|Cc\\|To\\|Bcc\\|Reply-To\\|Sender\\)" .
  75      address-mime)
  76     (t . mime))
  77   "*Header/encoding method alist.
  78 The list is traversed sequentially.  The keys can either be
  79 header regexps or t.
  80
  81 The values can be:
  82
  83 1) nil, in which case no encoding is done;
  84 2) `mime', in which case the header will be encoded according to RFC2047;
  85 3) `address-mime', like `mime', but takes account of the rules for address
  86    fields (where quoted strings and comments must be treated separately);
  87 4) a charset, in which case it will be encoded as that charset;
  88 5) `default', in which case the field will be encoded as the rest
  89    of the article.")
  90
  91 (defvar rfc2047-charset-encoding-alist
  92   '((us-ascii . nil)
  93     (iso-8859-1 . Q)
  94     (iso-8859-2 . Q)
  95     (iso-8859-3 . Q)
  96     (iso-8859-4 . Q)
  97     (iso-8859-5 . B)
  98     (koi8-r . B)
  99     (iso-8859-7 . B)
 100     (iso-8859-8 . B)
 101     (iso-8859-9 . Q)
 102     (iso-8859-14 . Q)
 103     (iso-8859-15 . Q)
 104     (iso-2022-jp . B)
 105     (iso-2022-kr . B)
 106     (gb2312 . B)
 107     (big5 . B)
 108     (cn-big5 . B)
 109     (cn-gb . B)
 110     (cn-gb-2312 . B)
 111     (euc-kr . B)
 112     (iso-2022-jp-2 . B)
 113     (iso-2022-int-1 . B))
 114   "Alist of MIME charsets to RFC2047 encodings.
 115 Valid encodings are nil, `Q' and `B'.  These indicate binary (no) encoding,
 116 quoted-printable and base64 respectively.")
 117
 118 (defvar rfc2047-encoding-function-alist
 119   '((Q . rfc2047-q-encode-region)
 120     (B . rfc2047-b-encode-region)
 121     (nil . ignore))
 122   "Alist of RFC2047 encodings to encoding functions.")
 123
 124 ;;;
 125 ;;; Functions for encoding RFC2047 messages
 126 ;;;
 127
 128 (defun rfc2047-narrow-to-field ()
 129   "Narrow the buffer to the header on the current line."
 130   (beginning-of-line)
 131   (narrow-to-region
 132    (point)
 133    (progn
 134      (forward-line 1)
 135      (if (re-search-forward "^[^ \n\t]" nil t)
 136          (progn
 137            (beginning-of-line)
 138            (point))
 139        (point-max))))
 140   (goto-char (point-min)))
 141
 142 (defun rfc2047-field-value ()
 143   "Return the value of the field at point."
 144   (save-excursion
 145     (save-restriction
 146       (rfc2047-narrow-to-field)
 147       (re-search-forward ":[ \t\n]*" nil t)
 148       (buffer-substring (point) (point-max)))))
 149
 150 (defvar rfc2047-encoding-type 'address-mime
 151   "The type of encoding done by `rfc2047-encode-region'.
 152 This should be dynamically bound around calls to
 153 `rfc2047-encode-region' to either `mime' or `address-mime'.  See
 154 `rfc2047-header-encoding-alist', for definitions.")
 155
 156 (defun rfc2047-encode-message-header ()
 157   "Encode the message header according to `rfc2047-header-encoding-alist'.
 158 Should be called narrowed to the head of the message."
 159   (interactive "*")
 160   (save-excursion
 161     (goto-char (point-min))
 162     (let (alist elem method)
 163       (while (not (eobp))
 164         (save-restriction
 165           (rfc2047-narrow-to-field)
 166           (if (not (rfc2047-encodable-p))
 167               (prog1
 168                 (if (and (eq (mm-body-7-or-8) '8bit)
 169                          (mm-multibyte-p)
 170                          (mm-coding-system-p
 171                           (car message-posting-charset)))
 172                     ;; 8 bit must be decoded.
 173                     (mm-encode-coding-region
 174                      (point-min) (point-max)
 175                      (mm-charset-to-coding-system
 176                       (car message-posting-charset))))
 177                 ;; No encoding necessary, but folding is nice
 178                 (rfc2047-fold-region
 179                  (save-excursion
 180                    (goto-char (point-min))
 181                    (skip-chars-forward "^:")
 182                    (when (looking-at ": ")
 183                      (forward-char 2))
 184                    (point))
 185                  (point-max)))
 186             ;; We found something that may perhaps be encoded.
 187             (setq method nil
 188                   alist rfc2047-header-encoding-alist)
 189             (while (setq elem (pop alist))
 190               (when (or (and (stringp (car elem))
 191                              (looking-at (car elem)))
 192                         (eq (car elem) t))
 193                 (setq alist nil
 194                       method (cdr elem))))
 195             (goto-char (point-min))
 196             (re-search-forward "^[^:]+: *" nil t)
 197             (cond
 198              ((eq method 'address-mime)
 199               (rfc2047-encode-region (point) (point-max)))
 200              ((eq method 'mime)
 201               (let ((rfc2047-encoding-type 'mime))
 202                 (rfc2047-encode-region (point) (point-max))))
 203              ((eq method 'default)
 204               (if (and (featurep 'mule)
 205                        (if (boundp 'default-enable-multibyte-characters)
 206                            default-enable-multibyte-characters)
 207                        mail-parse-charset)
 208                   (mm-encode-coding-region (point) (point-max)
 209                                            mail-parse-charset)))
 210              ;; We get this when CC'ing messsages to newsgroups with
 211              ;; 8-bit names.  The group name mail copy just got
 212              ;; unconditionally encoded.  Previously, it would ask
 213              ;; whether to encode, which was quite confusing for the
 214              ;; user.  If the new behaviour is wrong, tell me. I have
 215              ;; left the old code commented out below.
 216              ;; -- Per Abrahamsen <abraham@dina.kvl.dk> Date: 2001-10-07.
 217              ;; Modified by Dave Love, with the commented-out code changed
 218              ;; in accordance with changes elsewhere.
 219              ((null method)
 220               (rfc2047-encode-region (point) (point-max)))
 221 ;;;          ((null method)
 222 ;;;           (if (or (message-options-get
 223 ;;;                    'rfc2047-encode-message-header-encode-any)
 224 ;;;                   (message-options-set
 225 ;;;                    'rfc2047-encode-message-header-encode-any
 226 ;;;                    (y-or-n-p
 227 ;;;                     "Some texts are not encoded. Encode anyway?")))
 228 ;;;               (rfc2047-encode-region (point-min) (point-max))
 229 ;;;             (error "Cannot send unencoded text")))
 230              ((mm-coding-system-p method)
 231               (if (and (featurep 'mule)
 232                        (if (boundp 'default-enable-multibyte-characters)
 233                            default-enable-multibyte-characters))
 234                   (mm-encode-coding-region (point) (point-max) method)))
 235              ;; Hm.
 236              (t)))
 237           (goto-char (point-max)))))))
 238
 239 ;; Fixme: This, and the require below may not be the Right Thing, but
 240 ;; should be safe just before release.  -- fx 2001-02-08
 241 (eval-when-compile (defvar message-posting-charset))
 242
 243 (defun rfc2047-encodable-p ()
 244   "Return non-nil if any characters in current buffer need encoding in headers.
 245 The buffer may be narrowed."
 246   (require 'message)                    ; for message-posting-charset
 247   (let ((charsets
 248          (mm-find-mime-charset-region (point-min) (point-max))))
 249     (and charsets
 250          (not (equal charsets (list (car message-posting-charset)))))))
 251
 252 ;; Use this syntax table when parsing into regions that may need
 253 ;; encoding.  Double quotes are string delimiters, backslash is
 254 ;; character quoting, and all other RFC 2822 special characters are
 255 ;; treated as punctuation so we can use forward-sexp/forward-word to
 256 ;; skip to the end of regions appropriately.  Nb. ietf-drums does
 257 ;; things differently.
 258 (defconst rfc2047-syntax-table
 259   ;; (make-char-table 'syntax-table '(2)) only works in Emacs.
 260   (let ((table (make-syntax-table)))
 261     ;; The following is done to work for setting all elements of the table
 262     ;; in Emacs 21 and 22 and XEmacs; it appears to be the cleanest way.
 263     ;; Play safe and don't assume the form of the word syntax entry --
 264     ;; copy it from ?a.
 265     (if (fboundp 'set-char-table-range) ; Emacs
 266         (funcall (intern "set-char-table-range")
 267                  table t (aref (standard-syntax-table) ?a))
 268       (if (fboundp 'put-char-table)
 269           (if (fboundp 'get-char-table) ; warning avoidance
 270               (put-char-table t (get-char-table ?a (standard-syntax-table))
 271                               table))))
 272     (modify-syntax-entry ?\\ "\\" table)
 273     (modify-syntax-entry ?\" "\"" table)
 274     (modify-syntax-entry ?\( "." table)
 275     (modify-syntax-entry ?\) "." table)
 276     (modify-syntax-entry ?\< "." table)
 277     (modify-syntax-entry ?\> "." table)
 278     (modify-syntax-entry ?\[ "." table)
 279     (modify-syntax-entry ?\] "." table)
 280     (modify-syntax-entry ?: "." table)
 281     (modify-syntax-entry ?\; "." table)
 282     (modify-syntax-entry ?, "." table)
 283     (modify-syntax-entry ?@ "." table)
 284     table))
 285
 286 (defun rfc2047-encode-region (b e)
 287   "Encode words in region B to E that need encoding.
 288 By default, the region is treated as containing RFC2822 addresses.
 289 Dynamically bind `rfc2047-encoding-type' to change that."
 290   (save-restriction
 291     (narrow-to-region b e)
 292     (if (eq 'mime rfc2047-encoding-type)
 293         ;; Simple case.  Treat as single word after any initial ASCII
 294         ;; part and before any tailing ASCII part.  The leading ASCII
 295         ;; is relevant for instance in Subject headers with `Re:' for
 296         ;; interoperability with non-MIME clients, and we might as
 297         ;; well avoid the tail too.
 298         (progn
 299           (goto-char (point-min))
 300           ;; Does it need encoding?
 301           (skip-chars-forward "\000-\177")
 302           (unless (eobp)
 303             (skip-chars-backward "^ \n") ; beginning of space-delimited word
 304             (rfc2047-encode (point) (progn
 305                                       (goto-char e)
 306                                       (skip-chars-backward "\000-\177")
 307                                       (skip-chars-forward "^ \n")
 308                                       ;; end of space-delimited word
 309                                       (point)))))
 310       ;; `address-mime' case -- take care of quoted words, comments.
 311       (with-syntax-table rfc2047-syntax-table
 312         (let ((start)                   ; start of current token
 313               end                       ; end of current token
 314               ;; Whether there's an encoded word before the current
 315               ;; token, either immediately or separated by space.
 316               last-encoded)
 317           (goto-char (point-min))
 318           (condition-case nil           ; in case of unbalanced quotes
 319               ;; Look for rfc2822-style: sequences of atoms, quoted
 320               ;; strings, specials, whitespace.  (Specials mustn't be
 321               ;; encoded.)
 322               (while (not (eobp))
 323                 (setq start (point))
 324                 ;; Skip whitespace.
 325                 (unless (= 0 (skip-chars-forward " \t\n"))
 326                   (setq start (point)))
 327                 (cond
 328                  ((not (char-after)))   ; eob
 329                  ;; else token start
 330                  ((eq ?\" (char-syntax (char-after)))
 331                   ;; Quoted word.
 332                   (forward-sexp)
 333                   (setq end (point))
 334                   ;; Does it need encoding?
 335                   (goto-char start)
 336                   (skip-chars-forward "\000-\177" end)
 337                   (if (= end (point))
 338                       (setq last-encoded  nil)
 339                     ;; It needs encoding.  Strip the quotes first,
 340                     ;; since encoded words can't occur in quotes.
 341                     (goto-char end)
 342                     (delete-backward-char 1)
 343                     (goto-char start)
 344                     (delete-char 1)
 345                     (when last-encoded
 346                       ;; There was a preceding quoted word.  We need
 347                       ;; to include any separating whitespace in this
 348                       ;; word to avoid it getting lost.
 349                       (skip-chars-backward " \t")
 350                       ;; A space is needed between the encoded words.
 351                       (insert ? )
 352                       (setq start (point)
 353                             end (1+ end)))
 354                     ;; Adjust the end position for the deleted quotes.
 355                     (rfc2047-encode start (- end 2))
 356                     (setq last-encoded t))) ; record that it was encoded
 357                  ((eq ?. (char-syntax (char-after)))
 358                   ;; Skip other delimiters, but record that they've
 359                   ;; potentially separated quoted words.
 360                   (forward-char)
 361                   (setq last-encoded nil))
 362                  (t                 ; normal token/whitespace sequence
 363                   ;; Find the end.
 364                   (forward-word 1)
 365                   (skip-chars-backward " \t")
 366                   (setq end (point))
 367                   ;; Deal with encoding and leading space as for
 368                   ;; quoted words.
 369                   (goto-char start)
 370                   (skip-chars-forward "\000-\177" end)
 371                   (if (= end (point))
 372                       (setq last-encoded  nil)
 373                     (when last-encoded
 374                       (goto-char start)
 375                       (skip-chars-backward " \t")
 376                       (insert ? )
 377                       (setq start (point)
 378                             end (1+ end)))
 379                     (rfc2047-encode start end)
 380                     (setq last-encoded t)))))
 381             (error (error "Invalid data for rfc2047 encoding: %s"
 382                           (buffer-substring b e)))))))
 383     (rfc2047-fold-region b (point))))
 384
 385 (defun rfc2047-encode-string (string)
 386   "Encode words in STRING.
 387 By default, the string is treated as containing addresses (see
 388 `rfc2047-encoding-type')."
 389   (with-temp-buffer
 390     (insert string)
 391     (rfc2047-encode-region (point-min) (point-max))
 392     (buffer-string)))
 393
 394 (defun rfc2047-encode (b e)
 395   "Encode the word(s) in the region B to E.
 396 By default, the region is treated as containing addresses (see
 397 `rfc2047-encoding-type')."
 398   (let* ((mime-charset (mm-find-mime-charset-region b e))
 399          (cs (if (> (length mime-charset) 1)
 400                  ;; Fixme: Instead of this, try to break region into
 401                  ;; parts that can be encoded separately.
 402                  (error "Can't rfc2047-encode `%s'"
 403                         (buffer-substring b e))
 404                (setq mime-charset (car mime-charset))
 405                (mm-charset-to-coding-system mime-charset)))
 406          ;; Fixme: Better, calculate the number of non-ASCII
 407          ;; characters, at least for 8-bit charsets.
 408          (encoding (if (assq mime-charset
 409                              rfc2047-charset-encoding-alist)
 410                        (cdr (assq mime-charset
 411                                   rfc2047-charset-encoding-alist))
 412                      'B))
 413          (start (concat
 414                  "=?" (downcase (symbol-name mime-charset)) "?"
 415                  (downcase (symbol-name encoding)) "?"))
 416          (first t))
 417     (if mime-charset
 418         (save-restriction
 419           (narrow-to-region b e)
 420           (when (eq encoding 'B)
 421             ;; break into lines before encoding
 422             (goto-char (point-min))
 423             (while (not (eobp))
 424               (goto-char (min (point-max) (+ 15 (point))))
 425               (unless (eobp)
 426                 (insert ?\n))))
 427           (if (and (mm-multibyte-p)
 428                    (mm-coding-system-p cs))
 429               (mm-encode-coding-region (point-min) (point-max) cs))
 430           (funcall (cdr (assq encoding rfc2047-encoding-function-alist))
 431                    (point-min) (point-max))
 432           (goto-char (point-min))
 433           (while (not (eobp))
 434             (unless first
 435               (insert ? ))
 436             (setq first nil)
 437             (insert start)
 438             (end-of-line)
 439             (insert "?=")
 440             (forward-line 1))))))
 441
 442 (defun rfc2047-fold-field ()
 443   "Fold the current header field."
 444   (save-excursion
 445     (save-restriction
 446       (rfc2047-narrow-to-field)
 447       (rfc2047-fold-region (point-min) (point-max)))))
 448
 449 (defun rfc2047-fold-region (b e)
 450   "Fold long lines in region B to E."
 451   (save-restriction
 452     (narrow-to-region b e)
 453     (goto-char (point-min))
 454     (let ((break nil)
 455           (qword-break nil)
 456           (first t)
 457           (bol (save-restriction
 458                  (widen)
 459                  (rfc2047-point-at-bol))))
 460       (while (not (eobp))
 461         (when (and (or break qword-break)
 462                    (> (- (point) bol) 76))
 463           (goto-char (or break qword-break))
 464           (setq break nil
 465                 qword-break nil)
 466           (if (looking-at "[ \t]")
 467               (insert ?\n)
 468             (insert "\n "))
 469           (setq bol (1- (point)))
 470           ;; Don't break before the first non-LWSP characters.
 471           (skip-chars-forward " \t")
 472           (unless (eobp)
 473             (forward-char 1)))
 474         (cond
 475          ((eq (char-after) ?\n)
 476           (forward-char 1)
 477           (setq bol (point)
 478                 break nil
 479                 qword-break nil)
 480           (skip-chars-forward " \t")
 481           (unless (or (eobp) (eq (char-after) ?\n))
 482             (forward-char 1)))
 483          ((eq (char-after) ?\r)
 484           (forward-char 1))
 485          ((memq (char-after) '(?  ?\t))
 486           (skip-chars-forward " \t")
 487           (if first
 488               ;; Don't break just after the header name.
 489               (setq first nil)
 490             (setq break (1- (point)))))
 491          ((not break)
 492           (if (not (looking-at "=\\?[^=]"))
 493               (if (eq (char-after) ?=)
 494                   (forward-char 1)
 495                 (skip-chars-forward "^ \t\n\r="))
 496             (setq qword-break (point))
 497             (skip-chars-forward "^ \t\n\r")))
 498          (t
 499           (skip-chars-forward "^ \t\n\r"))))
 500       (when (and (or break qword-break)
 501                  (> (- (point) bol) 76))
 502         (goto-char (or break qword-break))
 503         (setq break nil
 504               qword-break nil)
 505           (if (looking-at "[ \t]")
 506               (insert ?\n)
 507             (insert "\n "))
 508         (setq bol (1- (point)))
 509         ;; Don't break before the first non-LWSP characters.
 510         (skip-chars-forward " \t")
 511         (unless (eobp)
 512           (forward-char 1))))))
 513
 514 (defun rfc2047-unfold-field ()
 515   "Fold the current line."
 516   (save-excursion
 517     (save-restriction
 518       (rfc2047-narrow-to-field)
 519       (rfc2047-unfold-region (point-min) (point-max)))))
 520
 521 (defun rfc2047-unfold-region (b e)
 522   "Unfold lines in region B to E."
 523   (save-restriction
 524     (narrow-to-region b e)
 525     (goto-char (point-min))
 526     (let ((bol (save-restriction
 527                  (widen)
 528                  (rfc2047-point-at-bol)))
 529           (eol (rfc2047-point-at-eol)))
 530       (forward-line 1)
 531       (while (not (eobp))
 532         (if (and (looking-at "[ \t]")
 533                  (< (- (rfc2047-point-at-eol) bol) 76))
 534             (delete-region eol (progn
 535                                  (goto-char eol)
 536                                  (skip-chars-forward "\r\n")
 537                                  (point)))
 538           (setq bol (rfc2047-point-at-bol)))
 539         (setq eol (rfc2047-point-at-eol))
 540         (forward-line 1)))))
 541
 542 (defun rfc2047-b-encode-region (b e)
 543   "Base64-encode the header contained in region B to E."
 544   (save-restriction
 545     (narrow-to-region (goto-char b) e)
 546     (while (not (eobp))
 547       (base64-encode-region (point) (progn (end-of-line) (point)) t)
 548       (if (and (bolp) (eolp))
 549           (delete-backward-char 1))
 550       (forward-line))))
 551
 552 (defun rfc2047-q-encode-region (b e)
 553   "Quoted-printable-encode the header in region B to E."
 554   (save-excursion
 555     (save-restriction
 556       (narrow-to-region (goto-char b) e)
 557       (let ((bol (save-restriction
 558                    (widen)
 559                    (rfc2047-point-at-bol))))
 560         (quoted-printable-encode-region
 561          b e nil
 562          ;; = (\075), _ (\137), ? (\077) are used in the encoded word.
 563          ;; Avoid using 8bit characters.
 564          ;; Equivalent to "^\000-\007\011\013\015-\037\200-\377=_?"
 565          "\010\012\014\040-\074\076\100-\136\140-\177")
 566         (subst-char-in-region (point-min) (point-max) ?  ?_)
 567         ;; The size of QP encapsulation is about 20, so set limit to
 568         ;; 56=76-20.
 569         (unless (< (- (point-max) (point-min)) 56)
 570           ;; Don't break if it could fit in one line.
 571           ;; Let rfc2047-encode-region break it later.
 572           (goto-char (1+ (point-min)))
 573           (while (and (not (bobp)) (not (eobp)))
 574             (goto-char (min (point-max) (+ 56 bol)))
 575             (search-backward "=" (- (point) 2) t)
 576             (unless (or (bobp) (eobp))
 577               (insert ?\n)
 578               (setq bol (point)))))))))
 579
 580 ;;;
 581 ;;; Functions for decoding RFC2047 messages
 582 ;;;
 583
 584 (eval-and-compile
 585   (defconst rfc2047-encoded-word-regexp
 586     "=\\?\\([^][\000-\040()<>@,\;:\\\"/?.=]+\\)\\?\\(B\\|Q\\)\
 587 \\?\\([!->@-~ +]*\\)\\?="))
 588
 589 ;; Fixme: This should decode in place, not cons intermediate strings.
 590 ;; Also check whether it needs to worry about delimiting fields like
 591 ;; encoding.
 592
 593 ;; In fact it's reported that (invalid) encoding of mailboxes in
 594 ;; addr-specs is in use, so delimiting fields might help.  Probably
 595 ;; not decoding a word which isn't properly delimited is good enough
 596 ;; and worthwhile (is it more correct or not?), e.g. something like
 597 ;; `=?iso-8859-1?q?foo?=@'.
 598
 599 (defun rfc2047-decode-region (start end)
 600   "Decode MIME-encoded words in region between START and END."
 601   (interactive "r")
 602   (let ((case-fold-search t)
 603         b e)
 604     (save-excursion
 605       (save-restriction
 606         (narrow-to-region start end)
 607         (goto-char (point-min))
 608         ;; Remove whitespace between encoded words.
 609         (while (re-search-forward
 610                 (eval-when-compile
 611                   (concat "\\(" rfc2047-encoded-word-regexp "\\)"
 612                           "\\(\n?[ \t]\\)+"
 613                           "\\(" rfc2047-encoded-word-regexp "\\)"))
 614                 nil t)
 615           (delete-region (goto-char (match-end 1)) (match-beginning 6)))
 616         ;; Decode the encoded words.
 617         (setq b (goto-char (point-min)))
 618         (while (re-search-forward rfc2047-encoded-word-regexp nil t)
 619           (setq e (match-beginning 0))
 620           (insert (rfc2047-parse-and-decode
 621                    (prog1
 622                        (match-string 0)
 623                      (delete-region (match-beginning 0) (match-end 0)))))
 624           ;; Remove newlines between decoded words, though such things
 625           ;; essentially must not be there.
 626           (save-restriction
 627             (narrow-to-region e (point))
 628             (goto-char e)
 629             (while (re-search-forward "[\n\r]+" nil t)
 630               (replace-match " "))
 631             (goto-char (point-max)))
 632           (when (and (mm-multibyte-p)
 633                      mail-parse-charset
 634                      (not (eq mail-parse-charset 'us-ascii))
 635                      (not (eq mail-parse-charset 'gnus-decoded)))
 636             (mm-decode-coding-region b e mail-parse-charset))
 637           (setq b (point)))
 638         (when (and (mm-multibyte-p)
 639                    mail-parse-charset
 640                    (not (eq mail-parse-charset 'us-ascii))
 641                    (not (eq mail-parse-charset 'gnus-decoded)))
 642           (mm-decode-coding-region b (point-max) mail-parse-charset))))))
 643
 644 (defun rfc2047-decode-string (string)
 645   "Decode the quoted-printable-encoded STRING and return the results."
 646   (let ((m (mm-multibyte-p)))
 647     (if (string-match "=\\?" string)
 648         (with-temp-buffer
 649           ;; Fixme: This logic is wrong, but seems to be required by
 650           ;; Gnus summary buffer generation.  The value of `m' depends
 651           ;; on the current buffer, not global multibyteness or that
 652           ;; of the string.  Also the string returned should always be
 653           ;; multibyte in a multibyte session, i.e. the buffer should
 654           ;; be multibyte before `buffer-string' is called.
 655           (when m
 656             (mm-enable-multibyte))
 657           (insert string)
 658           (inline
 659             (rfc2047-decode-region (point-min) (point-max)))
 660           (buffer-string))
 661       ;; Fixme: As above, `m' here is inappropriate.
 662       (if (and m
 663                mail-parse-charset
 664                (not (eq mail-parse-charset 'us-ascii))
 665                (not (eq mail-parse-charset 'gnus-decoded)))
 666           (mm-decode-coding-string string mail-parse-charset)
 667         (mm-string-as-multibyte string)))))
 668
 669 (defun rfc2047-parse-and-decode (word)
 670   "Decode WORD and return it if it is an encoded word.
 671 Return WORD if it is not not an encoded word or if the charset isn't
 672 decodable."
 673   (if (not (string-match rfc2047-encoded-word-regexp word))
 674       word
 675     (or
 676      (condition-case nil
 677          (rfc2047-decode
 678           (match-string 1 word)
 679           (upcase (match-string 2 word))
 680           (match-string 3 word))
 681        (error word))
 682      word)))                            ; un-decodable
 683
 684 (defun rfc2047-pad-base64 (string)
 685   "Pad STRING to quartets."
 686   ;; Be more liberal to accept buggy base64 strings. If
 687   ;; base64-decode-string accepts buggy strings, this function could
 688   ;; be aliased to identity.
 689   (case (mod (length string) 4)
 690     (0 string)
 691     (1 string) ;; Error, don't pad it.
 692     (2 (concat string "=="))
 693     (3 (concat string "="))))
 694
 695 (defun rfc2047-decode (charset encoding string)
 696   "Decode STRING from the given MIME CHARSET in the given ENCODING.
 697 Valid ENCODINGs are \"B\" and \"Q\".
 698 If your Emacs implementation can't decode CHARSET, return nil."
 699   (if (stringp charset)
 700       (setq charset (intern (downcase charset))))
 701   (if (or (not charset)
 702           (eq 'gnus-all mail-parse-ignored-charsets)
 703           (memq 'gnus-all mail-parse-ignored-charsets)
 704           (memq charset mail-parse-ignored-charsets))
 705       (setq charset mail-parse-charset))
 706   (let ((cs (mm-charset-to-coding-system charset)))
 707     (if (and (not cs) charset
 708              (listp mail-parse-ignored-charsets)
 709              (memq 'gnus-unknown mail-parse-ignored-charsets))
 710         (setq cs (mm-charset-to-coding-system mail-parse-charset)))
 711     (when cs
 712       (when (and (eq cs 'ascii)
 713                  mail-parse-charset)
 714         (setq cs mail-parse-charset))
 715       (mm-decode-coding-string
 716        (cond
 717         ((equal "B" encoding)
 718          (base64-decode-string
 719           (rfc2047-pad-base64 string)))
 720         ((equal "Q" encoding)
 721          (quoted-printable-decode-string
 722           (mm-replace-chars-in-string string ?_ ? )))
 723         (t (error "Invalid encoding: %s" encoding)))
 724        cs))))
 725
 726 (provide 'rfc2047)
 727
 728 ;;; rfc2047.el ends here