cgit.sxemacs.org Git - gnus/blob - lisp/proto-stream.el

   1 ;;; proto-stream.el --- negotiating TLS, STARTTLS and other connections
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: network
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This library is meant to provide the glue between modules that want
  26 ;; to establish a network connection to a server for protocols such as
  27 ;; IMAP, NNTP, SMTP and POP3.
  28
  29 ;; The main problem is that there's more than a couple of interfaces
  30 ;; towards doing this.  You have normal, plain connections, which are
  31 ;; no trouble at all, but you also have TLS/SSL connections, and you
  32 ;; have STARTTLS.  Negotiating this for each protocol can be rather
  33 ;; tedious, so this library provides a single entry point, and hides
  34 ;; much of the ugliness.
  35
  36 ;; Usage example:
  37
  38 ;; (open-protocol-stream
  39 ;;  "*nnimap*" buffer address port
  40 ;;  :type 'network
  41 ;;  :capability-command "1 CAPABILITY\r\n"
  42 ;;  :success " OK "
  43 ;;  :starttls-function
  44 ;;  (lambda (capabilities)
  45 ;;    (if (not (string-match "STARTTLS" capabilities))
  46 ;;        nil
  47 ;;      "1 STARTTLS\r\n")))
  48
  49 ;;; Code:
  50
  51 (eval-when-compile
  52   (require 'cl))
  53 (require 'tls)
  54 (require 'starttls)
  55 (require 'format-spec)
  56
  57 (defcustom proto-stream-always-use-starttls (fboundp 'open-gnutls-stream)
  58   "If non-nil, always try to upgrade network connections with STARTTLS."
  59   :version "24.1"
  60   :type 'boolean
  61   :group 'comm)
  62
  63 (declare-function gnutls-negotiate "gnutls"
  64                   (proc type &optional priority-string trustfiles keyfiles))
  65
  66 ;;;###autoload
  67 (defun open-protocol-stream (name buffer host service &rest parameters)
  68   "Open a network stream to HOST, upgrading to STARTTLS if possible.
  69 The first four parameters have the same meaning as in
  70 `open-network-stream'.  The function returns a list where the
  71 first element is the stream, the second element is the greeting
  72 the server replied with after connecting, and the third element
  73 is a string representing the capabilities of the server (if any).
  74
  75 The PARAMETERS is a keyword list that can have the following
  76 values:
  77
  78 :type -- either `network', `network-only, `tls', `shell' or
  79 `starttls'.  If omitted, the default is `network'.  `network'
  80 will be opportunistically upgraded to STARTTLS if both the server
  81 and Emacs supports it.  If you don't want STARTTLS upgrades, use
  82 `network-only'.
  83
  84 :end-of-command -- a regexp saying what the end of a command is.
  85 This defaults to \"\\n\".
  86
  87 :success -- a regexp saying whether the STARTTLS command was
  88 successful or not.  For instance, for NNTP this is \"^3\".
  89
  90 :capability-command -- a string representing the command used to
  91 query server for capabilities.  For instance, for IMAP this is
  92 \"1 CAPABILITY\\r\\n\".
  93
  94 :starttls-function -- a function that takes one parameter, which
  95 is the response to the capaibility command.  It should return nil
  96 if it turns out that the server doesn't support STARTTLS, or the
  97 command to switch on STARTTLS otherwise."
  98   (let ((type (or (cadr (memq :type parameters)) 'network)))
  99     (cond
 100      ((eq type 'starttls)
 101       (setq type 'network))
 102      ((eq type 'ssl)
 103       (setq type 'tls)))
 104     (destructuring-bind (stream greeting capabilities)
 105         (funcall (intern (format "proto-stream-open-%s" type) obarray)
 106                  name buffer host service parameters)
 107       (list (and stream
 108                  (memq (process-status stream)
 109                        '(open run))
 110                  stream)
 111             greeting capabilities))))
 112
 113 (defun proto-stream-open-network-only (name buffer host service parameters)
 114   (open-network-stream name buffer host service))
 115
 116 (defun proto-stream-open-network (name buffer host service parameters)
 117   (let* ((start (with-current-buffer buffer (point)))
 118          (stream (open-network-stream name buffer host service))
 119          (capability-command (cadr (memq :capability-command parameters)))
 120          (eoc (proto-stream-eoc parameters))
 121          (type (cadr (memq :type parameters)))
 122          (greeting (proto-stream-get-response stream start eoc))
 123          success)
 124     (if (not capability-command)
 125         (list stream greeting nil)
 126       (let* ((capabilities
 127               (proto-stream-command stream capability-command eoc))
 128              (starttls-command
 129               (funcall (cadr (memq :starttls-function parameters))
 130                        capabilities)))
 131         (cond
 132           ;; If this server doesn't support STARTTLS, but we have
 133           ;; requested it explicitly, then close the connection and
 134           ;; return nil.
 135          ((or (not starttls-command)
 136               (and (not (eq type 'starttls))
 137                    (not proto-stream-always-use-starttls)))
 138           (if (eq type 'starttls)
 139               (progn
 140                 (delete-process stream)
 141                 nil)
 142             ;; Otherwise, just return this plain network connection.
 143             (list stream greeting capabilities)))
 144          ;; We have some kind of STARTTLS support, so we try to
 145          ;; upgrade the connection opportunistically.
 146          ((or (fboundp 'open-gnutls-stream)
 147               (executable-find "gnutls-cli"))
 148           (unless (fboundp 'open-gnutls-stream)
 149             (delete-process stream)
 150             (setq start (with-current-buffer buffer (point-max)))
 151             (let* ((starttls-use-gnutls t)
 152                    (starttls-extra-arguments
 153                     (if (not (eq type 'starttls))
 154                         ;; When doing opportunistic TLS upgrades we
 155                         ;; don't really care about the identity of the
 156                         ;; peer.
 157                         (cons "--insecure" starttls-extra-arguments)
 158                       starttls-extra-arguments)))
 159               (setq stream (starttls-open-stream name buffer host service)))
 160             (proto-stream-get-response stream start eoc))
 161           (if (not
 162                (string-match
 163                 (cadr (memq :success parameters))
 164                 (proto-stream-command stream starttls-command eoc)))
 165               ;; We got an error back from the STARTTLS command.
 166               (progn
 167                 (if (eq type 'starttls)
 168                     (progn
 169                       (delete-process stream)
 170                       nil)
 171                   (list stream greeting capabilities)))
 172             ;; The server said it was OK to start doing STARTTLS negotiations.
 173             (if (fboundp 'open-gnutls-stream)
 174                 (gnutls-negotiate stream nil)
 175               (unless (starttls-negotiate stream)
 176                 (delete-process stream)
 177                 (setq stream nil)))
 178             (when (or (null stream)
 179                       (not (memq (process-status stream)
 180                                  '(open run))))
 181               ;; It didn't successfully negotiate STARTTLS, so we reopen
 182               ;; the connection.
 183               (setq stream (open-network-stream name buffer host service))
 184               (proto-stream-get-response stream start eoc))
 185             ;; Re-get the capabilities, since they may have changed
 186             ;; after switching to TLS.
 187             (list stream greeting
 188                   (proto-stream-command stream capability-command eoc))))
 189          ;; We don't have STARTTLS support available, but the caller
 190          ;; requested a STARTTLS connection, so we give up.
 191          ((eq (cadr (memq :type parameters)) 'starttls)
 192           (delete-process stream)
 193           nil)
 194          ;; Fall back on using a plain network stream.
 195          (t
 196           (list stream greeting capabilities)))))))
 197
 198 (defun proto-stream-command (stream command eoc)
 199   (let ((start (with-current-buffer (process-buffer stream) (point-max))))
 200     (process-send-string stream command)
 201     (proto-stream-get-response stream start eoc)))
 202
 203 (defun proto-stream-get-response (stream start end-of-command)
 204   (with-current-buffer (process-buffer stream)
 205     (save-excursion
 206       (goto-char start)
 207       (while (and (memq (process-status stream)
 208                         '(open run))
 209                   (not (re-search-forward end-of-command nil t)))
 210         (accept-process-output stream 0 50)
 211         (goto-char start))
 212       (if (= start (point))
 213           ;; The process died; return nil.
 214           nil
 215         ;; Return the data we got back.
 216         (buffer-substring start (point))))))
 217
 218 (defun proto-stream-open-tls (name buffer host service parameters)
 219   (with-current-buffer buffer
 220     (let ((start (point-max))
 221           (stream
 222            (funcall (if (fboundp 'open-gnutls-stream)
 223                         'open-gnutls-stream
 224                       'open-tls-stream)
 225                     name buffer host service)))
 226       (if (null stream)
 227           nil
 228         ;; If we're using tls.el, we have to delete the output from
 229         ;; openssl/gnutls-cli.
 230         (unless (fboundp 'open-gnutls-stream)
 231           (proto-stream-get-response
 232            stream start (proto-stream-eoc parameters))
 233           (goto-char (point-min))
 234           (when (re-search-forward (proto-stream-eoc parameters) nil t)
 235             (goto-char (match-beginning 0))
 236             (delete-region (point-min) (line-beginning-position))))
 237         (proto-stream-capability-open start stream parameters)))))
 238
 239 (defun proto-stream-open-shell (name buffer host service parameters)
 240   (proto-stream-capability-open
 241    (with-current-buffer buffer (point))
 242    (let ((process-connection-type nil))
 243      (start-process name buffer shell-file-name
 244                     shell-command-switch
 245                     (format-spec
 246                      (cadr (memq :shell-command parameters))
 247                      (format-spec-make
 248                       ?s host
 249                       ?p service))))
 250    parameters))
 251
 252 (defun proto-stream-capability-open (start stream parameters)
 253   (let ((capability-command (cadr (memq :capability-command parameters)))
 254         (greeting (proto-stream-get-response
 255                    stream start (proto-stream-eoc parameters))))
 256     (list stream greeting
 257           (and capability-command
 258                (proto-stream-command
 259                 stream capability-command (proto-stream-eoc parameters))))))
 260
 261 (defun proto-stream-eoc (parameters)
 262   (or (cadr (memq :end-of-command parameters))
 263       "\r\n"))
 264
 265 (provide 'proto-stream)
 266
 267 ;;; proto-stream.el ends here