cgit.sxemacs.org Git - gnus/blob - lisp/nnml.el

   1 ;;; nnml.el --- mail spool access for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'nnoo)
  36 (require 'cl)
  37
  38 (nnoo-declare nnml)
  39
  40 (defvoo nnml-directory message-directory
  41   "Mail spool directory.")
  42
  43 (defvoo nnml-active-file
  44   (concat (file-name-as-directory nnml-directory) "active")
  45   "Mail active file.")
  46
  47 (defvoo nnml-newsgroups-file
  48   (concat (file-name-as-directory nnml-directory) "newsgroups")
  49   "Mail newsgroups description file.")
  50
  51 (defvoo nnml-get-new-mail t
  52   "If non-nil, nnml will check the incoming mail file and split the mail.")
  53
  54 (defvoo nnml-nov-is-evil nil
  55   "If non-nil, Gnus will never generate and use nov databases for mail groups.
  56 Using nov databases will speed up header fetching considerably.
  57 This variable shouldn't be flipped much.  If you have, for some reason,
  58 set this to t, and want to set it to nil again, you should always run
  59 the `nnml-generate-nov-databases' command.  The function will go
  60 through all nnml directories and generate nov databases for them
  61 all.  This may very well take some time.")
  62
  63 (defvoo nnml-prepare-save-mail-hook nil
  64   "Hook run narrowed to an article before saving.")
  65
  66 (defvoo nnml-inhibit-expiry nil
  67   "If non-nil, inhibit expiry.")
  68
  69
  70 \f
  71
  72 (defconst nnml-version "nnml 1.0"
  73   "nnml version.")
  74
  75 (defvoo nnml-nov-file-name ".overview")
  76
  77 (defvoo nnml-current-directory nil)
  78 (defvoo nnml-current-group nil)
  79 (defvoo nnml-status-string "")
  80 (defvoo nnml-nov-buffer-alist nil)
  81 (defvoo nnml-group-alist nil)
  82 (defvoo nnml-active-timestamp nil)
  83 (defvoo nnml-article-file-alist nil)
  84
  85 (defvoo nnml-generate-active-function 'nnml-generate-active-info)
  86
  87 \f
  88
  89 ;;; Interface functions.
  90
  91 (nnoo-define-basics nnml)
  92
  93 (deffoo nnml-retrieve-headers (sequence &optional group server fetch-old)
  94   (when (nnml-possibly-change-directory group server)
  95     (save-excursion
  96       (set-buffer nntp-server-buffer)
  97       (erase-buffer)
  98       (let ((file nil)
  99             (number (length sequence))
 100             (count 0)
 101             beg article)
 102         (if (stringp (car sequence))
 103             'headers
 104           (unless nnml-article-file-alist
 105             (setq nnml-article-file-alist
 106                   (nnheader-article-to-file-alist nnml-current-directory)))
 107           (if (nnml-retrieve-headers-with-nov sequence fetch-old)
 108               'nov
 109             (while sequence
 110               (setq article (car sequence))
 111               (setq file
 112                     (concat nnml-current-directory
 113                             (or (cdr (assq article nnml-article-file-alist))
 114                                 "")))
 115               (when (and (file-exists-p file)
 116                          (not (file-directory-p file)))
 117                 (insert (format "221 %d Article retrieved.\n" article))
 118                 (setq beg (point))
 119                 (nnheader-insert-head file)
 120                 (goto-char beg)
 121                 (if (search-forward "\n\n" nil t)
 122                     (forward-char -1)
 123                   (goto-char (point-max))
 124                   (insert "\n\n"))
 125                 (insert ".\n")
 126                 (delete-region (point) (point-max)))
 127               (setq sequence (cdr sequence))
 128               (setq count (1+ count))
 129               (and (numberp nnmail-large-newsgroup)
 130                    (> number nnmail-large-newsgroup)
 131                    (zerop (% count 20))
 132                    (nnheader-message 6 "nnml: Receiving headers... %d%%"
 133                                      (/ (* count 100) number))))
 134
 135             (and (numberp nnmail-large-newsgroup)
 136                  (> number nnmail-large-newsgroup)
 137                  (nnheader-message 6 "nnml: Receiving headers...done"))
 138
 139             (nnheader-fold-continuation-lines)
 140             'headers))))))
 141
 142 (deffoo nnml-open-server (server &optional defs)
 143   (nnoo-change-server 'nnml server defs)
 144   (when (not (file-exists-p nnml-directory))
 145     (condition-case ()
 146         (make-directory nnml-directory t)
 147       (error)))
 148   (cond
 149    ((not (file-exists-p nnml-directory))
 150     (nnml-close-server)
 151     (nnheader-report 'nnml "Couldn't create directory: %s" nnml-directory))
 152    ((not (file-directory-p (file-truename nnml-directory)))
 153     (nnml-close-server)
 154     (nnheader-report 'nnml "Not a directory: %s" nnml-directory))
 155    (t
 156     (nnheader-report 'nnml "Opened server %s using directory %s"
 157                      server nnml-directory)
 158     t)))
 159
 160 (defun nnml-request-regenerate (server)
 161   (nnml-possibly-change-directory nil server)
 162   (nnml-generate-nov-databases))
 163
 164 (deffoo nnml-request-article (id &optional group server buffer)
 165   (nnml-possibly-change-directory group server)
 166   (let* ((nntp-server-buffer (or buffer nntp-server-buffer))
 167          path gpath group-num)
 168     (if (stringp id)
 169         (when (and (setq group-num (nnml-find-group-number id))
 170                    (cdr
 171                     (assq (cdr group-num)
 172                           (nnheader-article-to-file-alist
 173                            (setq gpath
 174                                  (nnmail-group-pathname
 175                                   (car group-num)
 176                                   nnml-directory))))))
 177           (setq path (concat gpath (int-to-string (cdr group-num)))))
 178       (setq path (nnml-article-to-file id)))
 179     (cond
 180      ((not path)
 181       (nnheader-report 'nnml "No such article: %s" id))
 182      ((not (file-exists-p path))
 183       (nnheader-report 'nnml "No such file: %s" path))
 184      ((file-directory-p path)
 185       (nnheader-report 'nnml "File is a directory: %s" path))
 186      ((not (save-excursion (nnmail-find-file path)))
 187       (nnheader-report 'nnml "Couldn't read file: %s" path))
 188      (t
 189       (nnheader-report 'nnml "Article %s retrieved" id)
 190       ;; We return the article number.
 191       (cons (if group-num (car group-num) group)
 192             (string-to-int (file-name-nondirectory path)))))))
 193
 194 (deffoo nnml-request-group (group &optional server dont-check)
 195   (cond
 196    ((not (nnml-possibly-change-directory group server))
 197     (nnheader-report 'nnml "Invalid group (no such directory)"))
 198    ((not (file-exists-p nnml-current-directory))
 199     (nnheader-report 'nnml "Directory %s does not exist"
 200                      nnml-current-directory))
 201    ((not (file-directory-p nnml-current-directory))
 202     (nnheader-report 'nnml "%s is not a directory" nnml-current-directory))
 203    (dont-check
 204     (nnheader-report 'nnml "Group %s selected" group)
 205     t)
 206    (t
 207     (nnheader-re-read-dir nnml-current-directory)
 208     (nnmail-activate 'nnml)
 209     (let ((active (nth 1 (assoc group nnml-group-alist))))
 210       (if (not active)
 211           (nnheader-report 'nnml "No such group: %s" group)
 212         (nnheader-report 'nnml "Selected group %s" group)
 213         (nnheader-insert "211 %d %d %d %s\n"
 214                          (max (1+ (- (cdr active) (car active))) 0)
 215                          (car active) (cdr active) group))))))
 216
 217 (deffoo nnml-request-scan (&optional group server)
 218   (setq nnml-article-file-alist nil)
 219   (nnml-possibly-change-directory group server)
 220   (nnmail-get-new-mail 'nnml 'nnml-save-nov nnml-directory group))
 221
 222 (deffoo nnml-close-group (group &optional server)
 223   (setq nnml-article-file-alist nil)
 224   t)
 225
 226 (deffoo nnml-request-create-group (group &optional server args)
 227   (nnmail-activate 'nnml)
 228   (unless (assoc group nnml-group-alist)
 229     (let (active)
 230       (push (list group (setq active (cons 1 0)))
 231             nnml-group-alist)
 232       (nnml-possibly-create-directory group)
 233       (nnml-possibly-change-directory group server)
 234       (let ((articles (nnheader-directory-articles nnml-current-directory)))
 235         (when articles
 236           (setcar active (apply 'min articles))
 237           (setcdr active (apply 'max articles))))
 238       (nnmail-save-active nnml-group-alist nnml-active-file)))
 239   t)
 240
 241 (deffoo nnml-request-list (&optional server)
 242   (save-excursion
 243     (nnmail-find-file nnml-active-file)
 244     (setq nnml-group-alist (nnmail-get-active))
 245     t))
 246
 247 (deffoo nnml-request-newgroups (date &optional server)
 248   (nnml-request-list server))
 249
 250 (deffoo nnml-request-list-newsgroups (&optional server)
 251   (save-excursion
 252     (nnmail-find-file nnml-newsgroups-file)))
 253
 254 (deffoo nnml-request-expire-articles (articles group
 255                                                &optional server force)
 256   (nnml-possibly-change-directory group server)
 257   (let* ((active-articles
 258           (nnheader-directory-articles nnml-current-directory))
 259          (is-old t)
 260          article rest mod-time number)
 261     (nnmail-activate 'nnml)
 262
 263     (unless nnml-article-file-alist
 264       (setq nnml-article-file-alist
 265             (nnheader-article-to-file-alist nnml-current-directory)))
 266
 267     (while (and articles is-old)
 268       (when (setq article
 269                   (assq (setq number (pop articles))
 270                         nnml-article-file-alist))
 271         (setq article (concat nnml-current-directory (cdr article)))
 272         (when (setq mod-time (nth 5 (file-attributes article)))
 273           (if (and (nnml-deletable-article-p group number)
 274                    (setq is-old
 275                          (nnmail-expired-article-p group mod-time force
 276                                                    nnml-inhibit-expiry)))
 277               (progn
 278                 (nnheader-message 5 "Deleting article %s in %s"
 279                                   article group)
 280                 (condition-case ()
 281                     (funcall nnmail-delete-file-function article)
 282                   (file-error
 283                    (push number rest)))
 284                 (setq active-articles (delq number active-articles))
 285                 (nnml-nov-delete-article group number))
 286             (push number rest)))))
 287     (let ((active (nth 1 (assoc group nnml-group-alist))))
 288       (when active
 289         (setcar active (or (and active-articles
 290                                 (apply 'min active-articles))
 291                            (1+ (cdr active)))))
 292       (nnmail-save-active nnml-group-alist nnml-active-file))
 293     (nnml-save-nov)
 294     (nconc rest articles)))
 295
 296 (deffoo nnml-request-move-article
 297   (article group server accept-form &optional last)
 298   (let ((buf (get-buffer-create " *nnml move*"))
 299         result)
 300     (nnml-possibly-change-directory group server)
 301     (unless nnml-article-file-alist
 302       (setq nnml-article-file-alist
 303             (nnheader-article-to-file-alist nnml-current-directory)))
 304     (and
 305      (nnml-deletable-article-p group article)
 306      (nnml-request-article article group server)
 307      (save-excursion
 308        (set-buffer buf)
 309        (insert-buffer-substring nntp-server-buffer)
 310        (setq result (eval accept-form))
 311        (kill-buffer (current-buffer))
 312        result)
 313      (progn
 314        (nnml-possibly-change-directory group server)
 315        (condition-case ()
 316            (funcall nnmail-delete-file-function
 317                     (concat nnml-current-directory
 318                             (int-to-string article)))
 319          (file-error nil))
 320        (nnml-nov-delete-article group article)
 321        (and last (nnml-save-nov))))
 322     result))
 323
 324 (deffoo nnml-request-accept-article (group &optional server last)
 325   (nnml-possibly-change-directory group server)
 326   (nnmail-check-syntax)
 327   (let (result)
 328     (if (stringp group)
 329         (and
 330          (nnmail-activate 'nnml)
 331          (setq result (car (nnml-save-mail
 332                             (list (cons group (nnml-active-number group))))))
 333          (progn
 334            (nnmail-save-active nnml-group-alist nnml-active-file)
 335            (and last (nnml-save-nov))))
 336       (and
 337        (nnmail-activate 'nnml)
 338        (setq result (car (nnml-save-mail
 339                           (nnmail-article-group 'nnml-active-number))))
 340        (progn
 341          (nnmail-save-active nnml-group-alist nnml-active-file)
 342          (and last (nnml-save-nov)))))
 343     result))
 344
 345 (deffoo nnml-request-replace-article (article group buffer)
 346   (nnml-possibly-change-directory group)
 347   (save-excursion
 348     (set-buffer buffer)
 349     (nnml-possibly-create-directory group)
 350     (let ((chars (nnmail-insert-lines))
 351           (art (concat (int-to-string article) "\t"))
 352           headers)
 353       (when (condition-case ()
 354                 (progn
 355                   (nnmail-write-region
 356                    (point-min) (point-max)
 357                    (concat nnml-current-directory
 358                            (int-to-string article))
 359                    nil (if (nnheader-be-verbose 5) nil 'nomesg))
 360                   t)
 361               (error nil))
 362         (setq headers (nnml-parse-head chars article))
 363         ;; Replace the NOV line in the NOV file.
 364         (save-excursion
 365           (set-buffer (nnml-open-nov group))
 366           (goto-char (point-min))
 367           (if (or (looking-at art)
 368                   (search-forward (concat "\n" art) nil t))
 369               ;; Delete the old NOV line.
 370               (delete-region (progn (beginning-of-line) (point))
 371                              (progn (forward-line 1) (point)))
 372             ;; The line isn't here, so we have to find out where
 373             ;; we should insert it.  (This situation should never
 374             ;; occur, but one likes to make sure...)
 375             (while (and (looking-at "[0-9]+\t")
 376                         (< (string-to-int
 377                             (buffer-substring
 378                              (match-beginning 0) (match-end 0)))
 379                            article)
 380                         (zerop (forward-line 1)))))
 381           (beginning-of-line)
 382           (nnheader-insert-nov headers)
 383           (nnml-save-nov)
 384           t)))))
 385
 386 (deffoo nnml-request-delete-group (group &optional force server)
 387   (nnml-possibly-change-directory group server)
 388   (when force
 389     ;; Delete all articles in GROUP.
 390     (let ((articles
 391            (directory-files
 392             nnml-current-directory t
 393             (concat nnheader-numerical-short-files
 394                     "\\|" (regexp-quote nnml-nov-file-name) "$")))
 395           article)
 396       (while articles
 397         (setq article (pop articles))
 398         (when (file-writable-p article)
 399           (nnheader-message 5 "Deleting article %s in %s..." article group)
 400           (funcall nnmail-delete-file-function article))))
 401     ;; Try to delete the directory itself.
 402     (condition-case ()
 403         (delete-directory nnml-current-directory)
 404       (error nil)))
 405   ;; Remove the group from all structures.
 406   (setq nnml-group-alist
 407         (delq (assoc group nnml-group-alist) nnml-group-alist)
 408         nnml-current-group nil
 409         nnml-current-directory nil)
 410   ;; Save the active file.
 411   (nnmail-save-active nnml-group-alist nnml-active-file)
 412   t)
 413
 414 (deffoo nnml-request-rename-group (group new-name &optional server)
 415   (nnml-possibly-change-directory group server)
 416   (let ((new-dir (nnmail-group-pathname new-name nnml-directory))
 417         (old-dir (nnmail-group-pathname group nnml-directory)))
 418     (when (condition-case ()
 419               (progn
 420                 (make-directory new-dir t)
 421                 t)
 422             (error nil))
 423       ;; We move the articles file by file instead of renaming
 424       ;; the directory -- there may be subgroups in this group.
 425       ;; One might be more clever, I guess.
 426       (let ((files (nnheader-article-to-file-alist old-dir)))
 427         (while files
 428           (rename-file
 429            (concat old-dir (cdar files))
 430            (concat new-dir (cdar files)))
 431           (pop files)))
 432       ;; Move .overview file.
 433       (let ((overview (concat old-dir nnml-nov-file-name)))
 434         (when (file-exists-p overview)
 435           (rename-file overview (concat new-dir nnml-nov-file-name))))
 436       (when (<= (length (directory-files old-dir)) 2)
 437         (condition-case ()
 438             (delete-directory old-dir)
 439           (error nil)))
 440       ;; That went ok, so we change the internal structures.
 441       (let ((entry (assoc group nnml-group-alist)))
 442         (when entry
 443           (setcar entry new-name))
 444         (setq nnml-current-directory nil
 445               nnml-current-group nil)
 446         ;; Save the new group alist.
 447         (nnmail-save-active nnml-group-alist nnml-active-file)
 448         t))))
 449
 450 (deffoo nnml-set-status (article name value &optional group server)
 451   (nnml-possibly-change-directory group server)
 452   (let ((file (nnml-article-to-file article)))
 453     (cond
 454      ((not (file-exists-p file))
 455       (nnheader-report 'nnml "File %s does not exist" file))
 456      (t
 457       (nnheader-temp-write file
 458         (nnheader-insert-file-contents file)
 459         (nnmail-replace-status name value))
 460       t))))
 461
 462 \f
 463 ;;; Internal functions.
 464
 465 (defun nnml-article-to-file (article)
 466   (unless nnml-article-file-alist
 467     (setq nnml-article-file-alist
 468           (nnheader-article-to-file-alist nnml-current-directory)))
 469   (let (file)
 470     (when (setq file (cdr (assq article nnml-article-file-alist)))
 471       (concat nnml-current-directory file))))
 472
 473 (defun nnml-deletable-article-p (group article)
 474   "Say whether ARTICLE in GROUP can be deleted."
 475   (let (file path)
 476     (when (setq file (cdr (assq article nnml-article-file-alist)))
 477       (setq path (concat nnml-current-directory file))
 478       (when (file-writable-p path)
 479         (or (not nnmail-keep-last-article)
 480             (not (eq (cdr (nth 1 (assoc group nnml-group-alist)))
 481                      article)))))))
 482
 483 ;; Find an article number in the current group given the Message-ID.
 484 (defun nnml-find-group-number (id)
 485   (save-excursion
 486     (set-buffer (get-buffer-create " *nnml id*"))
 487     (buffer-disable-undo (current-buffer))
 488     (let ((alist nnml-group-alist)
 489           number)
 490       ;; We want to look through all .overview files, but we want to
 491       ;; start with the one in the current directory.  It seems most
 492       ;; likely that the article we are looking for is in that group.
 493       (if (setq number (nnml-find-id nnml-current-group id))
 494           (cons nnml-current-group number)
 495         ;; It wasn't there, so we look through the other groups as well.
 496         (while (and (not number)
 497                     alist)
 498           (or (string= (caar alist) nnml-current-group)
 499               (setq number (nnml-find-id (caar alist) id)))
 500           (or number
 501               (setq alist (cdr alist))))
 502         (and number
 503              (cons (caar alist) number))))))
 504
 505 (defun nnml-find-id (group id)
 506   (erase-buffer)
 507   (let ((nov (concat (nnmail-group-pathname group nnml-directory)
 508                      nnml-nov-file-name))
 509         number found)
 510     (when (file-exists-p nov)
 511       (nnheader-insert-file-contents nov)
 512       (while (and (not found)
 513                   (search-forward id nil t)) ; We find the ID.
 514         ;; And the id is in the fourth field.
 515         (if (not (and (search-backward "\t" nil t 4)
 516                       (not (search-backward"\t" (gnus-point-at-bol) t))))
 517             (forward-line 1)
 518           (beginning-of-line)
 519           (setq found t)
 520           ;; We return the article number.
 521           (setq number
 522                 (condition-case ()
 523                     (read (current-buffer))
 524                   (error nil)))))
 525       number)))
 526
 527 (defun nnml-retrieve-headers-with-nov (articles &optional fetch-old)
 528   (if (or gnus-nov-is-evil nnml-nov-is-evil)
 529       nil
 530     (let ((nov (concat nnml-current-directory nnml-nov-file-name)))
 531       (when (file-exists-p nov)
 532         (save-excursion
 533           (set-buffer nntp-server-buffer)
 534           (erase-buffer)
 535           (nnheader-insert-file-contents nov)
 536           (if (and fetch-old
 537                    (not (numberp fetch-old)))
 538               t                         ; Don't remove anything.
 539             (nnheader-nov-delete-outside-range
 540              (if fetch-old (max 1 (- (car articles) fetch-old))
 541                (car articles))
 542              (car (last articles)))
 543             t))))))
 544
 545 (defun nnml-possibly-change-directory (group &optional server)
 546   (when (and server
 547              (not (nnml-server-opened server)))
 548     (nnml-open-server server))
 549   (if (not group)
 550       t
 551     (let ((pathname (nnmail-group-pathname group nnml-directory)))
 552       (when (not (equal pathname nnml-current-directory))
 553         (setq nnml-current-directory pathname
 554               nnml-current-group group
 555               nnml-article-file-alist nil))
 556       (file-exists-p nnml-current-directory))))
 557
 558 (defun nnml-possibly-create-directory (group)
 559   (let (dir dirs)
 560     (setq dir (nnmail-group-pathname group nnml-directory))
 561     (while (not (file-directory-p dir))
 562       (push dir dirs)
 563       (setq dir (file-name-directory (directory-file-name dir))))
 564     (while dirs
 565       (make-directory (directory-file-name (car dirs)))
 566       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 567       (setq dirs (cdr dirs)))))
 568
 569 (defun nnml-save-mail (group-art)
 570   "Called narrowed to an article."
 571   (let (chars headers)
 572     (setq chars (nnmail-insert-lines))
 573     (nnmail-insert-xref group-art)
 574     (run-hooks 'nnmail-prepare-save-mail-hook)
 575     (run-hooks 'nnml-prepare-save-mail-hook)
 576     (goto-char (point-min))
 577     (while (looking-at "From ")
 578       (replace-match "X-From-Line: ")
 579       (forward-line 1))
 580     ;; We save the article in all the groups it belongs in.
 581     (let ((ga group-art)
 582           first)
 583       (while ga
 584         (nnml-possibly-create-directory (caar ga))
 585         (let ((file (concat (nnmail-group-pathname
 586                              (caar ga) nnml-directory)
 587                             (int-to-string (cdar ga)))))
 588           (if first
 589               ;; It was already saved, so we just make a hard link.
 590               (funcall nnmail-crosspost-link-function first file t)
 591             ;; Save the article.
 592             (nnmail-write-region (point-min) (point-max) file nil
 593                                  (if (nnheader-be-verbose 5) nil 'nomesg))
 594             (setq first file)))
 595         (setq ga (cdr ga))))
 596     ;; Generate a nov line for this article.  We generate the nov
 597     ;; line after saving, because nov generation destroys the
 598     ;; header.
 599     (setq headers (nnml-parse-head chars))
 600     ;; Output the nov line to all nov databases that should have it.
 601     (let ((ga group-art))
 602       (while ga
 603         (nnml-add-nov (caar ga) (cdar ga) headers)
 604         (setq ga (cdr ga))))
 605     group-art))
 606
 607 (defun nnml-active-number (group)
 608   "Compute the next article number in GROUP."
 609   (let ((active (cadr (assoc group nnml-group-alist))))
 610     ;; The group wasn't known to nnml, so we just create an active
 611     ;; entry for it.
 612     (unless active
 613       ;; Perhaps the active file was corrupt?  See whether
 614       ;; there are any articles in this group.
 615       (nnml-possibly-create-directory group)
 616       (nnml-possibly-change-directory group)
 617       (unless nnml-article-file-alist
 618         (setq nnml-article-file-alist
 619               (sort
 620                (nnheader-article-to-file-alist nnml-current-directory)
 621                (lambda (a1 a2) (< (car a1) (car a2))))))
 622       (setq active
 623             (if nnml-article-file-alist
 624                 (cons (caar nnml-article-file-alist)
 625                       (caar (last nnml-article-file-alist)))
 626               (cons 1 0)))
 627       (push (list group active) nnml-group-alist))
 628     (setcdr active (1+ (cdr active)))
 629     (while (file-exists-p
 630             (concat (nnmail-group-pathname group nnml-directory)
 631                     (int-to-string (cdr active))))
 632       (setcdr active (1+ (cdr active))))
 633     (cdr active)))
 634
 635 (defun nnml-add-nov (group article headers)
 636   "Add a nov line for the GROUP base."
 637   (save-excursion
 638     (set-buffer (nnml-open-nov group))
 639     (goto-char (point-max))
 640     (mail-header-set-number headers article)
 641     (nnheader-insert-nov headers)))
 642
 643 (defsubst nnml-header-value ()
 644   (buffer-substring (match-end 0) (progn (end-of-line) (point))))
 645
 646 (defun nnml-parse-head (chars &optional number)
 647   "Parse the head of the current buffer."
 648   (save-excursion
 649     (save-restriction
 650       (goto-char (point-min))
 651       (narrow-to-region
 652        (point)
 653        (1- (or (search-forward "\n\n" nil t) (point-max))))
 654       ;; Fold continuation lines.
 655       (goto-char (point-min))
 656       (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 657         (replace-match " " t t))
 658       ;; Remove any tabs; they are too confusing.
 659       (subst-char-in-region (point-min) (point-max) ?\t ? )
 660       (let ((headers (nnheader-parse-head t)))
 661         (mail-header-set-chars headers chars)
 662         (mail-header-set-number headers number)
 663         headers))))
 664
 665 (defun nnml-open-nov (group)
 666   (or (cdr (assoc group nnml-nov-buffer-alist))
 667       (let ((buffer (nnheader-find-file-noselect
 668                      (concat (nnmail-group-pathname group nnml-directory)
 669                              nnml-nov-file-name))))
 670         (save-excursion
 671           (set-buffer buffer)
 672           (buffer-disable-undo (current-buffer)))
 673         (push (cons group buffer) nnml-nov-buffer-alist)
 674         buffer)))
 675
 676 (defun nnml-save-nov ()
 677   (save-excursion
 678     (while nnml-nov-buffer-alist
 679       (when (buffer-name (cdar nnml-nov-buffer-alist))
 680         (set-buffer (cdar nnml-nov-buffer-alist))
 681         (when (buffer-modified-p)
 682           (nnmail-write-region 1 (point-max) (buffer-file-name) nil 'nomesg))
 683         (set-buffer-modified-p nil)
 684         (kill-buffer (current-buffer)))
 685       (setq nnml-nov-buffer-alist (cdr nnml-nov-buffer-alist)))))
 686
 687 ;;;###autoload
 688 (defun nnml-generate-nov-databases ()
 689   "Generate nov databases in all nnml directories."
 690   (interactive)
 691   ;; Read the active file to make sure we don't re-use articles
 692   ;; numbers in empty groups.
 693   (nnmail-activate 'nnml)
 694   (nnml-open-server (or (nnoo-current-server 'nnml) ""))
 695   (setq nnml-directory (expand-file-name nnml-directory))
 696   ;; Recurse down the directories.
 697   (nnml-generate-nov-databases-1 nnml-directory)
 698   ;; Save the active file.
 699   (nnmail-save-active nnml-group-alist nnml-active-file))
 700
 701 (defun nnml-generate-nov-databases-1 (dir &optional seen)
 702   (setq dir (file-name-as-directory dir))
 703   ;; Only scan this sub-tree if we haven't been here yet.
 704   (unless (member (file-truename dir) seen)
 705     (push (file-truename dir) seen)
 706     ;; We descend recursively
 707     (let ((dirs (directory-files dir t nil t))
 708           dir)
 709       (while (setq dir (pop dirs))
 710         (when (and (not (member (file-name-nondirectory dir) '("." "..")))
 711                    (file-directory-p dir))
 712           (nnml-generate-nov-databases-1 dir seen))))
 713     ;; Do this directory.
 714     (let ((files (sort (nnheader-article-to-file-alist dir)
 715                        (lambda (a b) (< (car a) (car b))))))
 716       (when files
 717         (funcall nnml-generate-active-function dir)
 718         ;; Generate the nov file.
 719         (nnml-generate-nov-file dir files)))))
 720
 721 (defvar files)
 722 (defun nnml-generate-active-info (dir)
 723   ;; Update the active info for this group.
 724   (let ((group (nnheader-file-to-group
 725                 (directory-file-name dir) nnml-directory)))
 726     (setq nnml-group-alist
 727           (delq (assoc group nnml-group-alist) nnml-group-alist))
 728     (push (list group
 729                 (cons (caar files)
 730                       (let ((f files))
 731                         (while (cdr f) (setq f (cdr f)))
 732                         (caar f))))
 733           nnml-group-alist)))
 734
 735 (defun nnml-generate-nov-file (dir files)
 736   (let* ((dir (file-name-as-directory dir))
 737          (nov (concat dir nnml-nov-file-name))
 738          (nov-buffer (get-buffer-create " *nov*"))
 739          chars file headers)
 740     (save-excursion
 741       ;; Init the nov buffer.
 742       (set-buffer nov-buffer)
 743       (buffer-disable-undo (current-buffer))
 744       (erase-buffer)
 745       (set-buffer nntp-server-buffer)
 746       ;; Delete the old NOV file.
 747       (when (file-exists-p nov)
 748         (funcall nnmail-delete-file-function nov))
 749       (while files
 750         (unless (file-directory-p (setq file (concat dir (cdar files))))
 751           (erase-buffer)
 752           (nnheader-insert-file-contents file)
 753           (narrow-to-region
 754            (goto-char (point-min))
 755            (progn
 756              (search-forward "\n\n" nil t)
 757              (setq chars (- (point-max) (point)))
 758              (max 1 (1- (point)))))
 759           (when (and (not (= 0 chars))  ; none of them empty files...
 760                      (not (= (point-min) (point-max))))
 761             (goto-char (point-min))
 762             (setq headers (nnml-parse-head chars (caar files)))
 763             (save-excursion
 764               (set-buffer nov-buffer)
 765               (goto-char (point-max))
 766               (nnheader-insert-nov headers)))
 767           (widen))
 768         (setq files (cdr files)))
 769       (save-excursion
 770         (set-buffer nov-buffer)
 771         (nnmail-write-region 1 (point-max) nov nil 'nomesg)
 772         (kill-buffer (current-buffer))))))
 773
 774 (defun nnml-nov-delete-article (group article)
 775   (save-excursion
 776     (set-buffer (nnml-open-nov group))
 777     (goto-char (point-min))
 778     (when (re-search-forward (concat "^" (int-to-string article) "\t") nil t)
 779       (delete-region (match-beginning 0) (progn (forward-line 1) (point))))
 780     t))
 781
 782 (provide 'nnml)
 783
 784 ;;; nnml.el ends here