cgit.sxemacs.org Git - gnus/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2 ;; Copyright (C) 1995 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  27 ;; For an overview of what the interface functions do, please see the
  28 ;; Gnus sources.
  29
  30 ;;; Code:
  31
  32 (require 'nnheader)
  33 (require 'rmail)
  34 (require 'nnmail)
  35 (require 'gnus)
  36
  37 (defvar nnmh-directory "~/Mail/"
  38   "*Mail spool directory.")
  39
  40 (defvar nnmh-get-new-mail t
  41   "*If non-nil, nnmh will check the incoming mail file and split the mail.")
  42
  43 (defvar nnmh-prepare-save-mail-hook nil
  44   "*Hook run narrowed to an article before saving.")
  45
  46 (defvar nnmh-be-safe nil
  47   "*If non-nil, nnmh will check all articles to make sure whether they are new or not.")
  48
  49 \f
  50
  51 (defconst nnmh-version "nnmh 1.0"
  52   "nnmh version.")
  53
  54 (defvar nnmh-current-directory nil
  55   "Current news group directory.")
  56
  57 (defvar nnmh-status-string "")
  58 (defvar nnmh-group-alist nil)
  59
  60 \f
  61
  62 (defvar nnmh-current-server nil)
  63 (defvar nnmh-server-alist nil)
  64 (defvar nnmh-server-variables
  65   (list
  66    (list 'nnmh-directory nnmh-directory)
  67    (list 'nnmh-get-new-mail nnmh-get-new-mail)
  68    '(nnmh-current-directory nil)
  69    '(nnmh-status-string "")
  70    '(nnmh-group-alist)))
  71
  72 \f
  73
  74 ;;; Interface functions.
  75
  76 (defun nnmh-retrieve-headers (sequence &optional newsgroup server fetch-old)
  77   (save-excursion
  78     (set-buffer nntp-server-buffer)
  79     (erase-buffer)
  80     (let* ((file nil)
  81            (number (length sequence))
  82            (large (and (numberp nnmail-large-newsgroup)
  83                        (> number nnmail-large-newsgroup)))
  84            (count 0)
  85            beg article)
  86       (nnmh-possibly-change-directory newsgroup)
  87       (if (stringp (car sequence))
  88           'headers
  89         (while sequence
  90           (setq article (car sequence))
  91           (setq file
  92                 (concat nnmh-current-directory (int-to-string article)))
  93           (if (and (file-exists-p file)
  94                    (not (file-directory-p file)))
  95               (progn
  96                 (insert (format "221 %d Article retrieved.\n" article))
  97                 (setq beg (point))
  98                 (nnheader-insert-head file)
  99                 (goto-char beg)
 100                 (if (search-forward "\n\n" nil t)
 101                     (forward-char -1)
 102                   (goto-char (point-max))
 103                   (insert "\n\n"))
 104                 (insert ".\n")
 105                 (delete-region (point) (point-max))))
 106           (setq sequence (cdr sequence))
 107           (setq count (1+ count))
 108
 109           (and large
 110                (zerop (% count 20))
 111                (message "nnmh: Receiving headers... %d%%"
 112                         (/ (* count 100) number))))
 113
 114         (and large (message "nnmh: Receiving headers...done"))
 115
 116         ;; Fold continuation lines.
 117         (goto-char (point-min))
 118         (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 119           (replace-match " " t t))
 120         'headers))))
 121
 122 (defun nnmh-open-server (server &optional defs)
 123   (nnheader-init-server-buffer)
 124   (if (equal server nnmh-current-server)
 125       t
 126     (if nnmh-current-server
 127         (setq nnmh-server-alist
 128               (cons (list nnmh-current-server
 129                           (nnheader-save-variables nnmh-server-variables))
 130                     nnmh-server-alist)))
 131     (let ((state (assoc server nnmh-server-alist)))
 132       (if state
 133           (progn
 134             (nnheader-restore-variables (nth 1 state))
 135             (setq nnmh-server-alist (delq state nnmh-server-alist)))
 136         (nnheader-set-init-variables nnmh-server-variables defs)))
 137     (setq nnmh-current-server server)))
 138
 139 (defun nnmh-close-server (&optional server)
 140   t)
 141
 142 (defun nnmh-server-opened (&optional server)
 143   (and (equal server nnmh-current-server)
 144        nntp-server-buffer
 145        (buffer-name nntp-server-buffer)))
 146
 147 (defun nnmh-status-message (&optional server)
 148   nnmh-status-string)
 149
 150 (defun nnmh-request-article (id &optional newsgroup server buffer)
 151   (nnmh-possibly-change-directory newsgroup)
 152   (let ((file (if (stringp id)
 153                   nil
 154                 (concat nnmh-current-directory (int-to-string id))))
 155         (nntp-server-buffer (or buffer nntp-server-buffer)))
 156     (and (stringp file)
 157          (file-exists-p file)
 158          (not (file-directory-p file))
 159          (save-excursion (nnmail-find-file file))
 160          (string-to-int (file-name-nondirectory file)))))
 161
 162 (defun nnmh-request-group (group &optional server dont-check)
 163   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 164         dir)
 165     (if (file-directory-p pathname)
 166         (progn
 167           (setq nnmh-current-directory pathname)
 168           (and nnmh-get-new-mail
 169                nnmh-be-safe
 170                (nnmh-update-gnus-unreads group))
 171           (or dont-check
 172               (progn
 173                 (setq dir
 174                       (sort
 175                        (mapcar
 176                         (function
 177                          (lambda (name)
 178                            (string-to-int name)))
 179                         (directory-files pathname nil "^[0-9]+$" t))
 180                        '<))
 181                 (save-excursion
 182                   (set-buffer nntp-server-buffer)
 183                   (erase-buffer)
 184                   (if dir
 185                       (insert (format "211 %d %d %d %s\n" (length dir)
 186                                       (car dir)
 187                                       (progn (while (cdr dir)
 188                                                (setq dir (cdr dir)))
 189                                              (car dir))
 190                                       group))
 191                     (insert (format "211 0 1 0 %s\n" group))))))
 192           t)
 193       (setq nnmh-status-string "No such group")
 194       nil)))
 195
 196 (defun nnmh-request-scan (&optional group server)
 197   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 198
 199 (defun nnmh-request-list (&optional server dir)
 200   (or dir
 201       (save-excursion
 202         (set-buffer nntp-server-buffer)
 203         (erase-buffer)
 204         (setq dir (file-truename (file-name-as-directory nnmh-directory)))))
 205   (setq dir (expand-file-name dir))
 206   ;; Recurse down all directories.
 207   (let ((dirs (and (file-readable-p dir)
 208                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 209                    (directory-files dir t nil t))))
 210     (while dirs
 211       (if (and (not (string-match "/\\.\\.?$" (car dirs)))
 212                (file-directory-p (car dirs))
 213                (file-readable-p (car dirs)))
 214           (nnmh-request-list nil (car dirs)))
 215       (setq dirs (cdr dirs))))
 216   ;; For each directory, generate an active file line.
 217   (if (not (string= (expand-file-name nnmh-directory) dir))
 218       (let ((files (mapcar
 219                     (lambda (name) (string-to-int name))
 220                     (directory-files dir nil "^[0-9]+$" t))))
 221         (if (null files)
 222             ()
 223           (save-excursion
 224             (set-buffer nntp-server-buffer)
 225             (goto-char (point-max))
 226             (insert
 227              (format
 228               "%s %d %d y\n"
 229               (progn
 230                 (string-match
 231                  (file-truename (file-name-as-directory
 232                                  (expand-file-name nnmh-directory))) dir)
 233                 (nnmail-replace-chars-in-string
 234                  (substring dir (match-end 0)) ?/ ?.))
 235               (apply (function max) files)
 236               (apply (function min) files)))))))
 237   (setq nnmh-group-alist (nnmail-get-active))
 238   t)
 239
 240 (defun nnmh-request-newgroups (date &optional server)
 241   (nnmh-request-list server))
 242
 243 (defun nnmh-request-post (&optional server)
 244   (mail-send-and-exit nil))
 245
 246 (defun nnmh-request-expire-articles (articles newsgroup &optional server force)
 247   (nnmh-possibly-change-directory newsgroup)
 248   (let* ((days (or (and nnmail-expiry-wait-function
 249                         (funcall nnmail-expiry-wait-function newsgroup))
 250                    nnmail-expiry-wait))
 251          (active-articles
 252           (mapcar
 253            (function
 254             (lambda (name)
 255               (string-to-int name)))
 256            (directory-files nnmh-current-directory nil "^[0-9]+$" t)))
 257          (max-article (and active-articles (apply 'max active-articles)))
 258          (is-old t)
 259          article rest mod-time)
 260     (nnmail-activate 'nnmh)
 261
 262     (while (and articles is-old)
 263       (setq article (concat nnmh-current-directory
 264                             (int-to-string (car articles))))
 265       (if (setq mod-time (nth 5 (file-attributes article)))
 266           (if (and (nnmh-deletable-article-p newsgroup (car articles))
 267                    (or force
 268                        (and (not (equal mod-time '(0 0)))
 269                             (setq is-old
 270                                   (> (nnmail-days-between
 271                                       (current-time-string)
 272                                       (current-time-string mod-time))
 273                                      days)))))
 274               (progn
 275                 (and gnus-verbose-backends
 276                      (message "Deleting article %s in %s..."
 277                               article newsgroup))
 278                 (condition-case ()
 279                     (funcall nnmail-delete-file-function article)
 280                   (file-error
 281                    (setq rest (cons (car articles) rest)))))
 282             (setq rest (cons (car articles) rest))))
 283       (setq articles (cdr articles)))
 284     (message "")
 285     (nconc rest articles)))
 286
 287 (defun nnmh-close-group (group &optional server)
 288   t)
 289
 290 (defun nnmh-request-move-article
 291   (article group server accept-form &optional last)
 292   (let ((buf (get-buffer-create " *nnmh move*"))
 293         result)
 294     (and
 295      (nnmh-deletable-article-p group article)
 296      (nnmh-request-article article group server)
 297      (save-excursion
 298        (set-buffer buf)
 299        (insert-buffer-substring nntp-server-buffer)
 300        (setq result (eval accept-form))
 301        (kill-buffer (current-buffer))
 302        result)
 303      (condition-case ()
 304          (funcall nnmail-delete-file-function
 305                   (concat nnmh-current-directory (int-to-string article)))
 306        (file-error nil)))
 307     result))
 308
 309 (defun nnmh-request-accept-article (group &optional last)
 310   (if (stringp group)
 311       (and
 312        (nnmail-activate 'nnmh)
 313        ;; We trick the choosing function into believing that only one
 314        ;; group is availiable.
 315        (let ((nnmail-split-methods (list (list group ""))))
 316          (car (nnmh-save-mail))))
 317     (and
 318      (nnmail-activate 'nnmh)
 319      (car (nnmh-save-mail)))))
 320
 321 (defun nnmh-request-replace-article (article group buffer)
 322   (nnmh-possibly-change-directory group)
 323   (save-excursion
 324     (set-buffer buffer)
 325     (nnmh-possibly-create-directory group)
 326     (condition-case ()
 327         (progn
 328           (write-region (point-min) (point-max)
 329                         (concat nnmh-current-directory (int-to-string article))
 330                         nil (if gnus-verbose-backends nil 'nomesg))
 331           t)
 332       (error nil))))
 333
 334 (defun nnmh-request-create-group (group &optional server)
 335   (nnmail-activate 'nnmh)
 336   (or (assoc group nnmh-group-alist)
 337       (let (active)
 338         (setq nnmh-group-alist (cons (list group (setq active (cons 1 0)))
 339                                      nnmh-group-alist))
 340         (nnmh-possibly-create-directory group)
 341         (nnmh-possibly-change-directory group)
 342         (let ((articles (mapcar
 343                          (lambda (file)
 344                            (string-to-int file))
 345                          (directory-files
 346                           nnmh-current-directory nil "^[0-9]+$"))))
 347           (and articles
 348                (progn
 349                  (setcar active (apply 'min articles))
 350                  (setcdr active (apply 'max articles)))))))
 351   t)
 352
 353 (defun nnmh-request-delete-group (group &optional force server)
 354   (nnmh-possibly-change-directory group)
 355   ;; Delete all articles in GROUP.
 356   (if (not force)
 357       ()                                ; Don't delete the articles.
 358     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 359       (while articles
 360         (and (file-writable-p (car articles))
 361              (progn
 362                (and gnus-verbose-backends
 363                     (message (message "Deleting article %s in %s..."
 364                                       (car articles) group)))
 365                (funcall nnmail-delete-file-function (car articles))))
 366         (setq articles (cdr articles))))
 367     ;; Try to delete the directory itself.
 368     (condition-case ()
 369         (delete-directory nnmh-current-directory)
 370       (error nil)))
 371   ;; Remove the group from all structures.
 372   (setq nnmh-group-alist
 373         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 374         nnmh-current-directory nil)
 375   t)
 376
 377 (defun nnmh-request-rename-group (group new-name &optional server)
 378   (nnmh-possibly-change-directory group)
 379   ;; Rename directory.
 380   (and (file-writable-p nnmh-current-directory)
 381        (condition-case ()
 382            (progn
 383              (rename-file
 384               (directory-file-name nnmh-current-directory)
 385               (directory-file-name
 386                (nnmail-group-pathname new-name nnmh-directory)))
 387              t)
 388          (error nil))
 389        ;; That went ok, so we change the internal structures.
 390        (let ((entry (assoc group nnmh-group-alist)))
 391          (and entry (setcar entry new-name))
 392          (setq nnmh-current-directory nil)
 393          t)))
 394
 395 \f
 396 ;;; Internal functions.
 397
 398 (defun nnmh-possibly-change-directory (newsgroup)
 399   (if newsgroup
 400       (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory)))
 401         (if (file-directory-p pathname)
 402             (setq nnmh-current-directory pathname)
 403           (error "No such newsgroup: %s" newsgroup)))))
 404
 405 (defun nnmh-possibly-create-directory (group)
 406   (let (dir dirs)
 407     (setq dir (nnmail-group-pathname group nnmh-directory))
 408     (while (not (file-directory-p dir))
 409       (setq dirs (cons dir dirs))
 410       (setq dir (file-name-directory (directory-file-name dir))))
 411     (while dirs
 412       (if (make-directory (directory-file-name (car dirs)))
 413           (error "Could not create directory %s" (car dirs)))
 414       (and gnus-verbose-backends
 415            (message "Creating mail directory %s" (car dirs)))
 416       (setq dirs (cdr dirs)))))
 417
 418 (defun nnmh-save-mail ()
 419   "Called narrowed to an article."
 420   (let ((group-art (nreverse (nnmail-article-group 'nnmh-active-number))))
 421     (nnmail-insert-lines)
 422     (nnmail-insert-xref group-art)
 423     (run-hooks 'nnmh-prepare-save-mail-hook)
 424     (goto-char (point-min))
 425     (while (looking-at "From ")
 426       (replace-match "X-From-Line: ")
 427       (forward-line 1))
 428     ;; We save the article in all the newsgroups it belongs in.
 429     (let ((ga group-art)
 430           first)
 431       (while ga
 432         (nnmh-possibly-create-directory (car (car ga)))
 433         (let ((file (concat (nnmail-group-pathname
 434                              (car (car ga)) nnmh-directory)
 435                             (int-to-string (cdr (car ga))))))
 436           (if first
 437               ;; It was already saved, so we just make a hard link.
 438               (add-name-to-file first file t)
 439             ;; Save the article.
 440             (write-region (point-min) (point-max) file nil nil)
 441             (setq first file)))
 442         (setq ga (cdr ga))))
 443     group-art))
 444
 445 (defun nnmh-active-number (group)
 446   "Compute the next article number in GROUP."
 447   (let ((active (car (cdr (assoc group nnmh-group-alist)))))
 448     ;; The group wasn't known to nnmh, so we just create an active
 449     ;; entry for it.
 450     (or active
 451         (progn
 452           (setq active (cons 1 0))
 453           (setq nnmh-group-alist (cons (list group active) nnmh-group-alist))))
 454     (setcdr active (1+ (cdr active)))
 455     (while (file-exists-p
 456             (concat (nnmail-group-pathname group nnmh-directory)
 457                     (int-to-string (cdr active))))
 458       (setcdr active (1+ (cdr active))))
 459     (cdr active)))
 460
 461 (defun nnmh-update-gnus-unreads (group)
 462   ;; Go through the .nnmh-articles file and compare with the actual
 463   ;; articles in this folder. The articles that are "new" will be
 464   ;; marked as unread by Gnus.
 465   (let* ((dir nnmh-current-directory)
 466          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 467                               (directory-files nnmh-current-directory
 468                                                nil "^[0-9]+$" t)) '<))
 469          (nnmh-file (concat dir ".nnmh-articles"))
 470          new articles)
 471     ;; Load the .nnmh-articles file.
 472     (if (file-exists-p nnmh-file)
 473         (setq articles
 474               (let (nnmh-newsgroup-articles)
 475                 (condition-case nil (load nnmh-file nil t t) (error nil))
 476                 nnmh-newsgroup-articles)))
 477     ;; Add all new articles to the `new' list.
 478     (let ((art files))
 479       (while art
 480         (if (not (assq (car art) articles)) (setq new (cons (car art) new)))
 481         (setq art (cdr art))))
 482     ;; Remove all deleted articles.
 483     (let ((art articles))
 484       (while art
 485         (if (not (memq (car (car art)) files))
 486             (setq articles (delq (car art) articles)))
 487         (setq art (cdr art))))
 488     ;; Check whether the highest-numbered articles really are the ones
 489     ;; that Gnus thinks they are by looking at the time-stamps.
 490     (let ((art articles))
 491       (while (and art
 492                   (not (equal
 493                         (nth 5 (file-attributes
 494                                 (concat dir (int-to-string (car (car art))))))
 495                         (cdr (car art)))))
 496         (setq articles (delq (car art) articles))
 497         (setq new (cons (car (car art)) new))
 498         (setq art (cdr art))))
 499     ;; Go through all the new articles and add them, and their
 500     ;; time-stamps to the list.
 501     (let ((n new))
 502       (while n
 503         (setq articles
 504               (cons (cons
 505                      (car n)
 506                      (nth 5 (file-attributes
 507                              (concat dir (int-to-string (car n))))))
 508                     articles))
 509         (setq n (cdr n))))
 510     ;; Make Gnus mark all new articles as unread.
 511     (or (zerop (length new))
 512         (gnus-make-articles-unread
 513          (gnus-group-prefixed-name group (list 'nnmh ""))
 514          (setq new (sort new '<))))
 515     ;; Sort the article list with highest numbers first.
 516     (setq articles (sort articles (lambda (art1 art2)
 517                                     (> (car art1) (car art2)))))
 518     ;; Finally write this list back to the .nnmh-articles file.
 519     (save-excursion
 520       (set-buffer (get-buffer-create "*nnmh out*"))
 521       (insert ";; Gnus article active file for " group "\n\n")
 522       (insert "(setq nnmh-newsgroup-articles '")
 523       (insert (prin1-to-string articles) ")\n")
 524       (write-region (point-min) (point-max) nnmh-file nil 'nomesg)
 525       (kill-buffer (current-buffer)))))
 526
 527 (defun nnmh-deletable-article-p (group article)
 528   "Say whether ARTICLE in GROUP can be deleted."
 529   (or (not nnmail-keep-last-article)
 530       (not (eq (cdr (nth 1 (assoc group nnmh-group-alist))) article))))
 531
 532 (provide 'nnmh)
 533
 534 ;;; nnmh.el ends here