cgit.sxemacs.org Git - gnus/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'gnus)
  36 (require 'nnoo)
  37 (eval-and-compile (require 'cl))
  38
  39 (nnoo-declare nnmh)
  40
  41 (defvoo nnmh-directory message-directory
  42   "*Mail spool directory.")
  43
  44 (defvoo nnmh-get-new-mail t
  45   "*If non-nil, nnmh will check the incoming mail file and split the mail.")
  46
  47 (defvoo nnmh-prepare-save-mail-hook nil
  48   "*Hook run narrowed to an article before saving.")
  49
  50 (defvoo nnmh-be-safe nil
  51   "*If non-nil, nnmh will check all articles to make sure whether they are new or not.")
  52
  53 \f
  54
  55 (defconst nnmh-version "nnmh 1.0"
  56   "nnmh version.")
  57
  58 (defvoo nnmh-current-directory nil
  59   "Current news group directory.")
  60
  61 (defvoo nnmh-status-string "")
  62 (defvoo nnmh-group-alist nil)
  63
  64 \f
  65
  66 ;;; Interface functions.
  67
  68 (nnoo-define-basics nnmh)
  69
  70 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  71   (save-excursion
  72     (set-buffer nntp-server-buffer)
  73     (erase-buffer)
  74     (let* ((file nil)
  75            (number (length articles))
  76            (large (and (numberp nnmail-large-newsgroup)
  77                        (> number nnmail-large-newsgroup)))
  78            (count 0)
  79            beg article)
  80       (nnmh-possibly-change-directory newsgroup server)
  81       ;; We don't support fetching by Message-ID.
  82       (if (stringp (car articles))
  83           'headers
  84         (while articles
  85           (when (and (file-exists-p
  86                       (setq file (concat (file-name-as-directory
  87                                           nnmh-current-directory)
  88                                          (int-to-string
  89                                           (setq article (pop articles))))))
  90                      (not (file-directory-p file)))
  91             (insert (format "221 %d Article retrieved.\n" article))
  92             (setq beg (point))
  93             (nnheader-insert-head file)
  94             (goto-char beg)
  95             (if (search-forward "\n\n" nil t)
  96                 (forward-char -1)
  97               (goto-char (point-max))
  98               (insert "\n\n"))
  99             (insert ".\n")
 100             (delete-region (point) (point-max)))
 101           (setq count (1+ count))
 102
 103           (and large
 104                (zerop (% count 20))
 105                (message "nnmh: Receiving headers... %d%%"
 106                         (/ (* count 100) number))))
 107
 108         (and large (message "nnmh: Receiving headers...done"))
 109
 110         (nnheader-fold-continuation-lines)
 111         'headers))))
 112
 113 (deffoo nnmh-open-server (server &optional defs)
 114   (nnoo-change-server 'nnmh server defs)
 115   (when (not (file-exists-p nnmh-directory))
 116     (condition-case ()
 117         (make-directory nnmh-directory t)
 118       (error t)))
 119   (cond
 120    ((not (file-exists-p nnmh-directory))
 121     (nnmh-close-server)
 122     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 123    ((not (file-directory-p (file-truename nnmh-directory)))
 124     (nnmh-close-server)
 125     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 126    (t
 127     (nnheader-report 'nnmh "Opened server %s using directory %s"
 128                      server nnmh-directory)
 129     t)))
 130
 131 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 132   (nnmh-possibly-change-directory newsgroup server)
 133   (let ((file (if (stringp id)
 134                   nil
 135                 (concat nnmh-current-directory (int-to-string id))))
 136         (nntp-server-buffer (or buffer nntp-server-buffer)))
 137     (and (stringp file)
 138          (file-exists-p file)
 139          (not (file-directory-p file))
 140          (save-excursion (nnmail-find-file file))
 141          (string-to-int (file-name-nondirectory file)))))
 142
 143 (deffoo nnmh-request-group (group &optional server dont-check)
 144   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 145         dir)
 146     (cond
 147      ((not (file-directory-p pathname))
 148       (nnheader-report
 149        'nnmh "Can't select group (no such directory): %s" group))
 150      (t
 151       (setq nnmh-current-directory pathname)
 152       (and nnmh-get-new-mail
 153            nnmh-be-safe
 154            (nnmh-update-gnus-unreads group))
 155       (cond
 156        (dont-check
 157         (nnheader-report 'nnmh "Selected group %s" group)
 158         t)
 159        (t
 160         (setq dir
 161               (sort
 162                (mapcar (lambda (name) (string-to-int name))
 163                        (directory-files pathname nil "^[0-9]+$" t))
 164                '<))
 165           (cond
 166            (dir
 167             (nnheader-report 'nnmh "Selected group %s" group)
 168             (nnheader-insert
 169              "211 %d %d %d %s\n" (length dir) (car dir)
 170              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 171              group))
 172            (t
 173             (nnheader-report 'nnmh "Empty group %s" group)
 174             (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 175
 176 (deffoo nnmh-request-scan (&optional group server)
 177   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 178
 179 (deffoo nnmh-request-list (&optional server dir)
 180   (nnheader-insert "")
 181   (let ((nnmh-toplev
 182          (or dir (file-truename (file-name-as-directory nnmh-directory)))))
 183     (nnmh-request-list-1 nnmh-toplev))
 184   (setq nnmh-group-alist (nnmail-get-active))
 185   t)
 186
 187 (defvar nnmh-toplev)
 188 (defun nnmh-request-list-1 (dir)
 189   (setq dir (expand-file-name dir))
 190   ;; Recurse down all directories.
 191   (let ((dirs (and (file-readable-p dir)
 192                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 193                    (directory-files dir t nil t)))
 194         dir)
 195     ;; Recurse down directories.
 196     (while (setq dir (pop dirs))
 197       (when (and (not (member (file-name-nondirectory dir) '("." "..")))
 198                  (file-directory-p dir)
 199                  (file-readable-p dir))
 200         (nnmh-request-list-1 dir))))
 201   ;; For each directory, generate an active file line.
 202   (unless (string= (expand-file-name nnmh-toplev) dir)
 203     (let ((files (mapcar
 204                   (lambda (name) (string-to-int name))
 205                   (directory-files dir nil "^[0-9]+$" t))))
 206       (when files
 207         (save-excursion
 208           (set-buffer nntp-server-buffer)
 209           (goto-char (point-max))
 210           (insert
 211            (format
 212             "%s %d %d y\n"
 213             (progn
 214               (string-match
 215                (file-truename (file-name-as-directory
 216                                (expand-file-name nnmh-toplev))) dir)
 217               (nnheader-replace-chars-in-string
 218                (substring dir (match-end 0)) ?/ ?.))
 219             (apply (function max) files)
 220             (apply (function min) files)))))))
 221   t)
 222
 223 (deffoo nnmh-request-newgroups (date &optional server)
 224   (nnmh-request-list server))
 225
 226 (deffoo nnmh-request-expire-articles (articles newsgroup &optional server force)
 227   (nnmh-possibly-change-directory newsgroup server)
 228   (let* ((active-articles
 229           (mapcar
 230            (function
 231             (lambda (name)
 232               (string-to-int name)))
 233            (directory-files nnmh-current-directory nil "^[0-9]+$" t)))
 234          (is-old t)
 235          article rest mod-time)
 236     (nnmail-activate 'nnmh)
 237
 238     (while (and articles is-old)
 239       (setq article (concat nnmh-current-directory
 240                             (int-to-string (car articles))))
 241       (if (setq mod-time (nth 5 (file-attributes article)))
 242           (if (and (nnmh-deletable-article-p newsgroup (car articles))
 243                    (setq is-old
 244                          (nnmail-expired-article-p newsgroup mod-time force)))
 245               (progn
 246                 (nnheader-message 5 "Deleting article %s in %s..."
 247                                   article newsgroup)
 248                 (condition-case ()
 249                     (funcall nnmail-delete-file-function article)
 250                   (file-error
 251                    (setq rest (cons (car articles) rest)))))
 252             (setq rest (cons (car articles) rest))))
 253       (setq articles (cdr articles)))
 254     (message "")
 255     (nconc rest articles)))
 256
 257 (deffoo nnmh-close-group (group &optional server)
 258   t)
 259
 260 (deffoo nnmh-request-move-article
 261   (article group server accept-form &optional last)
 262   (let ((buf (get-buffer-create " *nnmh move*"))
 263         result)
 264     (and
 265      (nnmh-deletable-article-p group article)
 266      (nnmh-request-article article group server)
 267      (save-excursion
 268        (set-buffer buf)
 269        (insert-buffer-substring nntp-server-buffer)
 270        (setq result (eval accept-form))
 271        (kill-buffer (current-buffer))
 272        result)
 273      (condition-case ()
 274          (funcall nnmail-delete-file-function
 275                   (concat nnmh-current-directory (int-to-string article)))
 276        (file-error nil)))
 277     result))
 278
 279 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 280   (nnmh-possibly-change-directory group server)
 281   (if (stringp group)
 282       (and
 283        (nnmail-activate 'nnmh)
 284        ;; We trick the choosing function into believing that only one
 285        ;; group is available.
 286        (let ((nnmail-split-methods (list (list group ""))))
 287          (car (nnmh-save-mail noinsert))))
 288     (and
 289      (nnmail-activate 'nnmh)
 290      (car (nnmh-save-mail noinsert)))))
 291
 292 (deffoo nnmh-request-replace-article (article group buffer)
 293   (nnmh-possibly-change-directory group)
 294   (save-excursion
 295     (set-buffer buffer)
 296     (nnmh-possibly-create-directory group)
 297     (condition-case ()
 298         (progn
 299           (write-region (point-min) (point-max)
 300                         (concat nnmh-current-directory (int-to-string article))
 301                         nil (if (nnheader-be-verbose 5) nil 'nomesg))
 302           t)
 303       (error nil))))
 304
 305 (deffoo nnmh-request-create-group (group &optional server)
 306   (nnmail-activate 'nnmh)
 307   (or (assoc group nnmh-group-alist)
 308       (let (active)
 309         (setq nnmh-group-alist (cons (list group (setq active (cons 1 0)))
 310                                      nnmh-group-alist))
 311         (nnmh-possibly-create-directory group)
 312         (nnmh-possibly-change-directory group server)
 313         (let ((articles (mapcar
 314                          (lambda (file)
 315                            (string-to-int file))
 316                          (directory-files
 317                           nnmh-current-directory nil "^[0-9]+$"))))
 318           (and articles
 319                (progn
 320                  (setcar active (apply 'min articles))
 321                  (setcdr active (apply 'max articles)))))))
 322   t)
 323
 324 (deffoo nnmh-request-delete-group (group &optional force server)
 325   (nnmh-possibly-change-directory group server)
 326   ;; Delete all articles in GROUP.
 327   (if (not force)
 328       ()                                ; Don't delete the articles.
 329     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 330       (while articles
 331         (and (file-writable-p (car articles))
 332              (progn
 333                (nnheader-message 5 "Deleting article %s in %s..."
 334                                  (car articles) group)
 335                (funcall nnmail-delete-file-function (car articles))))
 336         (setq articles (cdr articles))))
 337     ;; Try to delete the directory itself.
 338     (condition-case ()
 339         (delete-directory nnmh-current-directory)
 340       (error nil)))
 341   ;; Remove the group from all structures.
 342   (setq nnmh-group-alist
 343         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 344         nnmh-current-directory nil)
 345   t)
 346
 347 (deffoo nnmh-request-rename-group (group new-name &optional server)
 348   (nnmh-possibly-change-directory group server)
 349   ;; Rename directory.
 350   (and (file-writable-p nnmh-current-directory)
 351        (condition-case ()
 352            (progn
 353              (rename-file
 354               (directory-file-name nnmh-current-directory)
 355               (directory-file-name
 356                (nnmail-group-pathname new-name nnmh-directory)))
 357              t)
 358          (error nil))
 359        ;; That went ok, so we change the internal structures.
 360        (let ((entry (assoc group nnmh-group-alist)))
 361          (and entry (setcar entry new-name))
 362          (setq nnmh-current-directory nil)
 363          t)))
 364
 365 \f
 366 ;;; Internal functions.
 367
 368 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 369   (when (and server
 370              (not (nnmh-server-opened server)))
 371     (nnmh-open-server server))
 372   (if newsgroup
 373       (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory)))
 374         (if (file-directory-p pathname)
 375             (setq nnmh-current-directory pathname)
 376           (error "No such newsgroup: %s" newsgroup)))))
 377
 378 (defun nnmh-possibly-create-directory (group)
 379   (let (dir dirs)
 380     (setq dir (nnmail-group-pathname group nnmh-directory))
 381     (while (not (file-directory-p dir))
 382       (setq dirs (cons dir dirs))
 383       (setq dir (file-name-directory (directory-file-name dir))))
 384     (while dirs
 385       (if (make-directory (directory-file-name (car dirs)))
 386           (error "Could not create directory %s" (car dirs)))
 387       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 388       (setq dirs (cdr dirs)))))
 389
 390 (defun nnmh-save-mail (&optional noinsert)
 391   "Called narrowed to an article."
 392   (let ((group-art (nreverse (nnmail-article-group 'nnmh-active-number))))
 393     (unless noinsert
 394       (nnmail-insert-lines)
 395       (nnmail-insert-xref group-art))
 396     (run-hooks 'nnmail-prepare-save-mail-hook)
 397     (run-hooks 'nnmh-prepare-save-mail-hook)
 398     (goto-char (point-min))
 399     (while (looking-at "From ")
 400       (replace-match "X-From-Line: ")
 401       (forward-line 1))
 402     ;; We save the article in all the newsgroups it belongs in.
 403     (let ((ga group-art)
 404           first)
 405       (while ga
 406         (nnmh-possibly-create-directory (caar ga))
 407         (let ((file (concat (nnmail-group-pathname
 408                              (caar ga) nnmh-directory)
 409                             (int-to-string (cdar ga)))))
 410           (if first
 411               ;; It was already saved, so we just make a hard link.
 412               (funcall nnmail-crosspost-link-function first file t)
 413             ;; Save the article.
 414             (write-region (point-min) (point-max) file nil nil)
 415             (setq first file)))
 416         (setq ga (cdr ga))))
 417     group-art))
 418
 419 (defun nnmh-active-number (group)
 420   "Compute the next article number in GROUP."
 421   (let ((active (cadr (assoc group nnmh-group-alist))))
 422     ;; The group wasn't known to nnmh, so we just create an active
 423     ;; entry for it.
 424     (or active
 425         (progn
 426           (setq active (cons 1 0))
 427           (setq nnmh-group-alist (cons (list group active) nnmh-group-alist))))
 428     (setcdr active (1+ (cdr active)))
 429     (while (file-exists-p
 430             (concat (nnmail-group-pathname group nnmh-directory)
 431                     (int-to-string (cdr active))))
 432       (setcdr active (1+ (cdr active))))
 433     (cdr active)))
 434
 435 (defun nnmh-update-gnus-unreads (group)
 436   ;; Go through the .nnmh-articles file and compare with the actual
 437   ;; articles in this folder. The articles that are "new" will be
 438   ;; marked as unread by Gnus.
 439   (let* ((dir nnmh-current-directory)
 440          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 441                               (directory-files nnmh-current-directory
 442                                                nil "^[0-9]+$" t)) '<))
 443          (nnmh-file (concat dir ".nnmh-articles"))
 444          new articles)
 445     ;; Load the .nnmh-articles file.
 446     (if (file-exists-p nnmh-file)
 447         (setq articles
 448               (let (nnmh-newsgroup-articles)
 449                 (condition-case nil (load nnmh-file nil t t) (error nil))
 450                 nnmh-newsgroup-articles)))
 451     ;; Add all new articles to the `new' list.
 452     (let ((art files))
 453       (while art
 454         (if (not (assq (car art) articles)) (setq new (cons (car art) new)))
 455         (setq art (cdr art))))
 456     ;; Remove all deleted articles.
 457     (let ((art articles))
 458       (while art
 459         (if (not (memq (caar art) files))
 460             (setq articles (delq (car art) articles)))
 461         (setq art (cdr art))))
 462     ;; Check whether the highest-numbered articles really are the ones
 463     ;; that Gnus thinks they are by looking at the time-stamps.
 464     (let ((art articles))
 465       (while (and art
 466                   (not (equal
 467                         (nth 5 (file-attributes
 468                                 (concat dir (int-to-string (caar art)))))
 469                         (cdar art))))
 470         (setq articles (delq (car art) articles))
 471         (setq new (cons (caar art) new))
 472         (setq art (cdr art))))
 473     ;; Go through all the new articles and add them, and their
 474     ;; time-stamps to the list.
 475     (let ((n new))
 476       (while n
 477         (setq articles
 478               (cons (cons
 479                      (car n)
 480                      (nth 5 (file-attributes
 481                              (concat dir (int-to-string (car n))))))
 482                     articles))
 483         (setq n (cdr n))))
 484     ;; Make Gnus mark all new articles as unread.
 485     (or (zerop (length new))
 486         (gnus-make-articles-unread
 487          (gnus-group-prefixed-name group (list 'nnmh ""))
 488          (setq new (sort new '<))))
 489     ;; Sort the article list with highest numbers first.
 490     (setq articles (sort articles (lambda (art1 art2)
 491                                     (> (car art1) (car art2)))))
 492     ;; Finally write this list back to the .nnmh-articles file.
 493     (save-excursion
 494       (set-buffer (get-buffer-create "*nnmh out*"))
 495       (insert ";; Gnus article active file for " group "\n\n")
 496       (insert "(setq nnmh-newsgroup-articles '")
 497       (insert (prin1-to-string articles) ")\n")
 498       (write-region (point-min) (point-max) nnmh-file nil 'nomesg)
 499       (kill-buffer (current-buffer)))))
 500
 501 (defun nnmh-deletable-article-p (group article)
 502   "Say whether ARTICLE in GROUP can be deleted."
 503   (let ((path (concat nnmh-current-directory (int-to-string article))))
 504     (and (file-writable-p path)
 505          (or (not nnmail-keep-last-article)
 506              (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 507                       article))))))
 508
 509 (provide 'nnmh)
 510
 511 ;;; nnmh.el ends here