cgit.sxemacs.org Git - gnus/blob - lisp/nnkiboze.el

   1 ;;; nnkiboze.el --- select virtual news access for (ding) Gnus
   2 ;; Copyright (C) 1995 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; The other access methods (nntp, nnspool, etc) are general news
  26 ;; access methods. This module relies on Gnus and can not be used
  27 ;; separately.
  28
  29 ;;; Code:
  30
  31 (require 'nntp)
  32 (require 'nnheader)
  33 (require 'gnus)
  34 (require 'gnus-score)
  35
  36 (defvar nnkiboze-directory
  37   (expand-file-name (or gnus-article-save-directory "~/News/"))
  38   "nnkiboze will put its files in this directory.")
  39
  40 \f
  41
  42 (defconst nnkiboze-version "nnkiboze 0.0"
  43   "Version numbers of this version of nnkiboze.")
  44
  45 (defvar nnkiboze-current-group nil)
  46 (defvar nnkiboze-current-score-group "")
  47 (defvar nnkiboze-status-string "")
  48
  49 \f
  50
  51 ;;; Interface functions.
  52
  53 (defun nnkiboze-retrieve-headers (articles &optional group server)
  54   (nnkiboze-possibly-change-newsgroups group)
  55   (if (or gnus-nov-is-evil)
  56       nil
  57     (let ((first (car articles))
  58           (last (progn (while (cdr articles) (setq articles (cdr articles)))
  59                        (car articles)))
  60           (nov (nnkiboze-nov-file-name)))
  61       (if (file-exists-p nov)
  62           (save-excursion
  63             (set-buffer nntp-server-buffer)
  64             (erase-buffer)
  65             (insert-file-contents nov)
  66             (goto-char (point-min))
  67             (while (and (not (eobp)) (< first (read (current-buffer))))
  68               (forward-line 1))
  69             (beginning-of-line)
  70             (if (not (eobp)) (delete-region 1 (point)))
  71             (while (and (not (eobp)) (>= last (read (current-buffer))))
  72               (forward-line 1))
  73             (beginning-of-line)
  74             (if (not (eobp)) (delete-region (point) (point-max)))
  75             'nov)))))
  76
  77 (defun nnkiboze-open-server (newsgroups &optional something)
  78   "Open a virtual newsgroup that contains NEWSGROUPS."
  79   (gnus-make-directory nnkiboze-directory)
  80   (nnheader-init-server-buffer))
  81
  82 (defun nnkiboze-close-server (&rest dum)
  83   "Close news server."
  84   t)
  85
  86 (fset 'nnkiboze-request-quit (symbol-function 'nnkiboze-close-server))
  87
  88 (defun nnkiboze-server-opened (&optional server)
  89   "Return server process status, T or NIL.
  90 If the stream is opened, return T, otherwise return NIL."
  91   (and nntp-server-buffer
  92        (get-buffer nntp-server-buffer)))
  93
  94 (defun nnkiboze-status-message (&optional server)
  95   "Return server status response as string."
  96   nnkiboze-status-string)
  97
  98 (defun nnkiboze-request-article (article &optional newsgroup server buffer)
  99   "Select article by message number."
 100   (nnkiboze-possibly-change-newsgroups newsgroup)
 101   (if (not (numberp article))
 102       ;; This is a real cludge. It might not work at times, but it
 103       ;; does no harm I think. The only alternative is to offer no
 104       ;; article fetching by message-id at all.
 105       (nntp-request-article article newsgroup gnus-nntp-server buffer)
 106     (let* ((header (gnus-get-header-by-number article))
 107            (xref (header-xref header))
 108            igroup iarticle)
 109       (or xref (error "nnkiboze: No xref"))
 110       (or (string-match " \\([^ ]+\\):\\([0-9]+\\)" xref)
 111           (error "nnkiboze: Malformed xref"))
 112       (setq igroup (substring xref (match-beginning 1) (match-end 1)))
 113       (setq iarticle (string-to-int
 114                       (substring xref (match-beginning 2) (match-end 2))))
 115       (and (gnus-request-group igroup t)
 116            (gnus-request-article iarticle igroup buffer)))))
 117
 118 (defun nnkiboze-request-group (group &optional server dont-check)
 119   "Make GROUP the current newsgroup."
 120   (nnkiboze-possibly-change-newsgroups group)
 121   (if dont-check
 122       ()
 123     (let ((nov-file (nnkiboze-nov-file-name))
 124           beg end total)
 125       (save-excursion
 126         (set-buffer nntp-server-buffer)
 127         (erase-buffer)
 128         (if (not (file-exists-p nov-file))
 129             (insert (format "211 0 0 0 %s\n" group))
 130           (insert-file-contents nov-file)
 131           (if (zerop (buffer-size))
 132               (insert (format "211 0 0 0 %s\n" group))
 133             (goto-char (point-min))
 134             (and (looking-at "[0-9]+") (setq beg (read (current-buffer))))
 135             (goto-char (point-max))
 136             (and (re-search-backward "^[0-9]" nil t)
 137                  (setq end (read (current-buffer))))
 138             (setq total (count-lines (point-min) (point-max)))
 139             (erase-buffer)
 140             (insert (format "211 %d %d %d %s\n" total beg end group)))))))
 141   t)
 142
 143 (defun nnkiboze-close-group (group &optional server)
 144   (nnkiboze-possibly-change-newsgroups group)
 145   ;; Remove NOV lines of articles that are marked as read.
 146   (save-excursion
 147     (let ((unreads gnus-newsgroup-unreads)
 148           (unselected gnus-newsgroup-unselected))
 149       (set-buffer (get-buffer-create "*nnkiboze work*"))
 150       (buffer-disable-undo (current-buffer))
 151       (erase-buffer)
 152       (let ((cur (current-buffer))
 153             article)
 154         (insert-file-contents (nnkiboze-nov-file-name))
 155         (goto-char (point-min))
 156         (while (looking-at "[0-9]+")
 157           (if (or (memq (setq article (read cur)) unreads)
 158                   (memq article unselected))
 159               (forward-line 1)
 160             (delete-region (progn (beginning-of-line) (point))
 161                            (progn (forward-line 1) (point)))))
 162         (write-file (nnkiboze-nov-file-name))
 163         (kill-buffer (current-buffer)))))
 164   (setq nnkiboze-current-group nil))
 165
 166 (defun nnkiboze-request-list (&optional server)
 167   (setq nnkiboze-status-string "nnkiboze: LIST is not implemented.")
 168   nil)
 169
 170 (defun nnkiboze-request-newgroups (date &optional server)
 171   "List new groups."
 172   (setq nnkiboze-status-string "NEWGROUPS is not supported.")
 173   nil)
 174
 175 (defun nnkiboze-request-list-newsgroups (&optional server)
 176   (setq nnkiboze-status-string "nnkiboze: LIST NEWSGROUPS is not implemented.")
 177   nil)
 178
 179 (fset 'nnkiboze-request-post 'nntp-request-post)
 180
 181 (fset 'nnkiboze-request-post-buffer 'nntp-request-post-buffer)
 182
 183 \f
 184 ;;; Internal functions.
 185
 186 (defun nnkiboze-possibly-change-newsgroups (group)
 187   (setq nnkiboze-current-group group))
 188
 189 (defun nnkiboze-prefixed-name (group)
 190   (gnus-group-prefixed-name group '(nnkiboze "")))
 191
 192 ;;;###autoload
 193 (defun nnkiboze-generate-groups ()
 194   "Usage: emacs -batch -l nnkiboze -f nnkiboze-generate-groups
 195 Finds out what articles are to be part of the nnkiboze groups."
 196   (interactive)
 197   (let ((nnmail-spool-file nil)
 198         (gnus-use-dribble-file nil)
 199         (gnus-read-active-file t)
 200         (gnus-expert-user t))
 201     (gnus))
 202   (let* ((gnus-newsrc-alist (gnus-copy-sequence gnus-newsrc-alist))
 203          (newsrc gnus-newsrc-alist))
 204     (while newsrc
 205       (if (string-match "nnkiboze" (car (car newsrc)))
 206           (nnkiboze-generate-group (car (car newsrc))))
 207       (setq newsrc (cdr newsrc)))))
 208
 209 (defun nnkiboze-score-file (group)
 210   (list (expand-file-name
 211          (concat gnus-kill-files-directory nnkiboze-current-score-group
 212                  "." gnus-score-file-suffix))))
 213
 214 (defun nnkiboze-generate-group (group)
 215   (let* ((info (nth 2 (gnus-gethash group gnus-newsrc-hashtb)))
 216          (newsrc-file (concat nnkiboze-directory group ".newsrc"))
 217          (nov-file (concat nnkiboze-directory group ".nov"))
 218          (regexp (nth 1 (nth 4 info)))
 219          (gnus-expert-user t)
 220          (gnus-large-newsgroup nil)
 221          (gnus-score-find-score-files-function 'nnkiboze-score-file)
 222          method nnkiboze-newsrc nov-buffer gname newsrc active
 223          ginfo lowest)
 224     (setq nnkiboze-current-score-group group)
 225     (or info (error "No such group: %s" group))
 226     (and (file-exists-p newsrc-file) (load newsrc-file))
 227     (save-excursion
 228       (set-buffer (setq nov-buffer (find-file-noselect nov-file)))
 229       (buffer-disable-undo (current-buffer)))
 230     (mapatoms
 231      (lambda (group)
 232        (if (and (string-match regexp (setq gname (symbol-name group)))
 233                 (not (assoc gname nnkiboze-newsrc)))
 234            (setq nnkiboze-newsrc
 235                  (cons (cons gname (1- (car (symbol-value group))))
 236                        nnkiboze-newsrc))))
 237      gnus-active-hashtb)
 238     (setq newsrc nnkiboze-newsrc)
 239     (while newsrc
 240       (if (not (setq active (gnus-gethash
 241                              (car (car newsrc)) gnus-active-hashtb)))
 242           (setq nnkiboze-newsrc (delq (car newsrc) nnkiboze-newsrc))
 243         (switch-to-buffer gnus-group-buffer)
 244         (gnus-group-jump-to-group (car (car newsrc)))
 245         (if (and (setq ginfo (nth 2 (gnus-gethash (gnus-group-group-name)
 246                                                   gnus-newsrc-hashtb)))
 247                  (nth 3 ginfo))
 248             (setcar (nthcdr 3 ginfo) nil))
 249         (if (not (and (or (not ginfo)
 250                           (> (length (gnus-list-of-unread-articles
 251                                       (car ginfo))) 0))
 252                       (progn
 253                         (gnus-group-select-group nil)
 254                         (eq major-mode 'gnus-summary-mode))))
 255             ()
 256           (setq lowest (cdr (car newsrc)))
 257           (setq method (gnus-find-method-for-group gnus-newsgroup-name))
 258           (and (eq method gnus-select-method) (setq method nil))
 259           (while gnus-newsgroup-scored
 260             (if (> (car (car gnus-newsgroup-scored)) lowest)
 261                 (nnkiboze-enter-nov
 262                  nov-buffer
 263                  (gnus-get-header-by-number (car (car gnus-newsgroup-scored)))
 264                  (if method
 265                      (gnus-group-prefixed-name gnus-newsgroup-name method)
 266                    gnus-newsgroup-name)))
 267             (setq gnus-newsgroup-scored (cdr gnus-newsgroup-scored)))
 268           (gnus-summary-quit)))
 269       (setcdr (car newsrc) (car active))
 270       (setq newsrc (cdr newsrc)))
 271     (set-buffer nov-buffer)
 272     (save-buffer)
 273     (kill-buffer (current-buffer))
 274     (set-buffer (get-buffer-create "*nnkiboze work*"))
 275     (buffer-disable-undo (current-buffer))
 276     (erase-buffer)
 277     (insert "(setq nnkiboze-newsrc '" (prin1-to-string nnkiboze-newsrc)
 278             ")\n")
 279     (write-file newsrc-file)
 280     (kill-buffer (current-buffer))
 281     (switch-to-buffer gnus-group-buffer)
 282     (gnus-group-list-groups 5 nil)))
 283
 284 (defun nnkiboze-enter-nov (buffer header group)
 285   (save-excursion
 286     (set-buffer buffer)
 287     (goto-char (point-max))
 288     (let ((xref (header-xref header))
 289           (prefix (gnus-group-real-prefix group))
 290           (first t)
 291           article)
 292       (if (zerop (forward-line -1))
 293           (progn
 294             (setq article (1+ (read (current-buffer))))
 295             (forward-line 1))
 296         (setq article 1))
 297       (insert (int-to-string article) "\t"
 298               (or (header-subject header) "") "\t"
 299               (or (header-from header) "") "\t"
 300               (or (header-date header) "") "\t"
 301               (or (header-id header) "") "\t"
 302               (or (header-references header) "") "\t"
 303               (int-to-string (or (header-chars header) 0)) "\t"
 304               (int-to-string (or (header-lines header) 0)) "\t")
 305       (if (or (not xref) (equal "" xref))
 306           (insert "Xref " (system-name) " " group ":"
 307                   (int-to-string (header-number header))
 308                   "\t\n")
 309         (insert (header-xref header) "\t\n")
 310         (search-backward "\t" nil t)
 311         (search-backward "\t" nil t)
 312         (while (re-search-forward
 313                 "[^ ]+:[0-9]+"
 314                 (save-excursion (end-of-line) (point)) t)
 315           (if first
 316               ;; The first xref has to be the group this article
 317               ;; really came for - this is the article nnkiboze
 318               ;; will request when it is asked for the article.
 319               (save-excursion
 320                 (goto-char (match-beginning 0))
 321                 (insert prefix group ":"
 322                         (int-to-string (header-number header)) " ")
 323                 (setq first nil)))
 324           (save-excursion
 325             (goto-char (match-beginning 0))
 326             (insert prefix)))))))
 327
 328 (defun nnkiboze-nov-file-name ()
 329   (concat nnkiboze-directory
 330           (nnkiboze-prefixed-name nnkiboze-current-group) ".nov"))
 331
 332 (provide 'nnkiboze)
 333
 334 ;;; nnkiboze.el ends here