cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   6 ;;         Jim Radford <radford@robby.caltech.edu>
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Todo, major things:
  29 ;;
  30 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  31 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  32 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  33 ;;   o Sieve
  34 ;;   o MIME (partial article fetches)
  35 ;;   o Split to other backends, different split rules for different
  36 ;;     servers/inboxes
  37 ;;
  38 ;; Todo, minor things:
  39 ;;
  40 ;;   o Don't require half of Gnus -- backends should be standalone
  41 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  42 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  43 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  44 ;;   o What do I do with gnus-newsgroup-*?
  45 ;;   o Tell Gnus about new groups (how can we tell?)
  46 ;;   o Respooling (fix Gnus?) (unnecessary?)
  47 ;;   o Add support for the following: (if applicable)
  48 ;;       request-list-newsgroups, request-regenerate
  49 ;;       list-active-group,
  50 ;;       request-associate-buffer, request-restore-buffer,
  51 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  52 ;;   o Support RFC2221 (Login referrals)
  53 ;;   o IMAP2BIS compatibility? (RFC2061)
  54 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  55 ;;     .newsrc.eld)
  56 ;;   o What about Gnus's article editing, can we support it?  NO!
  57 ;;   o Use \Draft to support the draft group??
  58 ;;   o Duplicate suppression
  59 ;;   o Rewrite UID SEARCH UID X as UID FETCH X (UID) for those with slow servers
  60
  61 ;;; Code:
  62
  63 (require 'imap)
  64 (require 'nnoo)
  65 (require 'nnmail)
  66 (require 'nnheader)
  67 (require 'mm-util)
  68 (require 'gnus)
  69 (require 'gnus-range)
  70 (require 'gnus-start)
  71 (require 'gnus-int)
  72
  73 (eval-when-compile (require 'cl))
  74
  75 (nnoo-declare nnimap)
  76
  77 (defconst nnimap-version "nnimap 1.0")
  78
  79 (defgroup nnimap nil
  80   "Reading IMAP mail with Gnus."
  81   :group 'gnus)
  82
  83 (defvoo nnimap-address nil
  84   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  85
  86 (defvoo nnimap-server-port nil
  87   "Port number on physical IMAP server.
  88 If nil, defaults to 993 for TLS/SSL connections and 143 otherwise.")
  89
  90 ;; Splitting variables
  91
  92 (defcustom nnimap-split-crosspost t
  93   "If non-nil, do crossposting if several split methods match the mail.
  94 If nil, the first match found will be used."
  95   :group 'nnimap
  96   :type 'boolean)
  97
  98 (defcustom nnimap-split-inbox nil
  99   "Name of mailbox to split mail from.
 100
 101 Mail is read from this mailbox and split according to rules in
 102 `nnimap-split-rule'.
 103
 104 This can be a string or a list of strings."
 105   :group 'nnimap
 106   :type '(choice (string)
 107                  (repeat string)))
 108
 109 (define-widget 'nnimap-strict-function 'function
 110   "This widget only matches values that are functionp.
 111
 112 Warning: This means that a value that is the symbol of a not yet
 113 loaded function will not match.  Use with care."
 114   :match 'nnimap-strict-function-match)
 115
 116 (defun nnimap-strict-function-match (widget value)
 117   "Ignoring WIDGET, match if VALUE is a function."
 118   (functionp value))
 119
 120 (defcustom nnimap-split-rule nil
 121   "Mail will be split according to these rules.
 122
 123 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 124
 125 If you'd like, for instance, one mail group for mail from the
 126 \"gnus-imap\" mailing list, one group for junk mail and leave
 127 everything else in the incoming mailbox, you could do something like
 128 this:
 129
 130 \(setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 131                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 132
 133 As you can see, `nnimap-split-rule' is a list of lists, where the
 134 first element in each \"rule\" is the name of the IMAP mailbox (or the
 135 symbol `junk' if you want to remove the mail), and the second is a
 136 regexp that nnimap will try to match on the header to find a fit.
 137
 138 The second element can also be a function.  In that case, it will be
 139 called narrowed to the headers with the first element of the rule as
 140 the argument.  It should return a non-nil value if it thinks that the
 141 mail belongs in that group.
 142
 143 This variable can also have a function as its value, the function will
 144 be called with the headers narrowed and should return a group where it
 145 thinks the article should be splitted to.  See `nnimap-split-fancy'.
 146
 147 To allow for different split rules on different virtual servers, and
 148 even different split rules in different inboxes on the same server,
 149 the syntax of this variable have been extended along the lines of:
 150
 151 \(setq nnimap-split-rule
 152       '((\"my1server\"    (\".*\"    ((\"ding\"    \"ding@gnus.org\")
 153                                   (\"junk\"    \"From:.*Simon\")))
 154         (\"my2server\"    (\"INBOX\" nnimap-split-fancy))
 155         (\"my[34]server\" (\".*\"    ((\"private\" \"To:.*Simon\")
 156                                   (\"junk\"    my-junk-func)))))
 157
 158 The virtual server name is in fact a regexp, so that the same rules
 159 may apply to several servers.  In the example, the servers
 160 \"my3server\" and \"my4server\" both use the same rules.  Similarly,
 161 the inbox string is also a regexp.  The actual splitting rules are as
 162 before, either a function, or a list with group/regexp or
 163 group/function elements."
 164   :group 'nnimap
 165   :type '(choice :tag "Rule type"
 166                  (repeat :menu-tag "Single-server"
 167                          :tag "Single-server list"
 168                          (list (string :tag "Mailbox")
 169                                (choice :tag "Predicate"
 170                                        (regexp :tag "A regexp")
 171                                        (nnimap-strict-function :tag "A function"))))
 172                  (choice :menu-tag "A function"
 173                          :tag "A function"
 174                          (function-item nnimap-split-fancy)
 175                          (function-item nnmail-split-fancy)
 176                          (nnimap-strict-function :tag "User-defined function"))
 177                  (repeat :menu-tag "Multi-server (extended)"
 178                          :tag "Multi-server list"
 179                          (list (regexp :tag "Server regexp")
 180                                (list (regexp :tag "Incoming Mailbox regexp")
 181                                      (repeat :tag "Rules for matching server(s) and mailbox(es)"
 182                                              (list (string :tag "Destination mailbox")
 183                                                    (choice :tag "Predicate"
 184                                                            (regexp :tag "A Regexp")
 185                                                            (nnimap-strict-function :tag "A Function")))))))))
 186
 187 (defcustom nnimap-split-predicate "UNSEEN UNDELETED"
 188   "The predicate used to find articles to split.
 189 If you use another IMAP client to peek on articles but always would
 190 like nnimap to split them once it's started, you could change this to
 191 \"UNDELETED\". Other available predicates are available in
 192 RFC2060 section 6.4.4."
 193   :group 'nnimap
 194   :type 'string)
 195
 196 (defcustom nnimap-split-fancy nil
 197   "Like the variable `nnmail-split-fancy'."
 198   :group 'nnimap
 199   :type 'sexp)
 200
 201 (defvar nnimap-split-download-body-default nil
 202   "Internal variable with default value for `nnimap-split-download-body'.")
 203
 204 (defcustom nnimap-split-download-body 'default
 205   "Whether to download entire articles during splitting.
 206 This is generally not required, and will slow things down considerably.
 207 You may need it if you want to use an advanced splitting function that
 208 analyses the body before splitting the article.
 209 If this variable is nil, bodies will not be downloaded; if this
 210 variable is the symbol `default' the default behaviour is
 211 used (which currently is nil, unless you use a statistical
 212 spam.el test); if this variable is another non-nil value bodies
 213 will be downloaded."
 214   :group 'nnimap
 215   :type '(choice (const :tag "Let system decide" deault)
 216                  boolean))
 217
 218 ;; Performance / bug workaround variables
 219
 220 (defcustom nnimap-close-asynchronous t
 221   "Close mailboxes asynchronously in `nnimap-close-group'.
 222 This means that errors cought by nnimap when closing the mailbox will
 223 not prevent Gnus from updating the group status, which may be harmful.
 224 However, it increases speed."
 225   :type 'boolean
 226   :group 'nnimap)
 227
 228 (defcustom nnimap-dont-close t
 229   "Never close mailboxes.
 230 This increases the speed of closing mailboxes (quiting group) but may
 231 decrease the speed of selecting another mailbox later.  Re-selecting
 232 the same mailbox will be faster though."
 233   :type 'boolean
 234   :group 'nnimap)
 235
 236 (defcustom nnimap-retrieve-groups-asynchronous t
 237   "Send asynchronous STATUS commands for each mailbox before checking mail.
 238 If you have mailboxes that rarely receives mail, this speeds up new
 239 mail checking.  It works by first sending STATUS commands for each
 240 mailbox, and then only checking groups which has a modified UIDNEXT
 241 more carefully for new mail.
 242
 243 In summary, the default is O((1-p)*k+p*n) and changing it to nil makes
 244 it O(n).  If p is small, then the default is probably faster."
 245   :type 'boolean
 246   :group 'nnimap)
 247
 248 (defvoo nnimap-need-unselect-to-notice-new-mail nil
 249   "Unselect mailboxes before looking for new mail in them.
 250 Some servers seem to need this under some circumstances.")
 251
 252 ;; Authorization / Privacy variables
 253
 254 (defvoo nnimap-auth-method nil
 255   "Obsolete.")
 256
 257 (defvoo nnimap-stream nil
 258   "How nnimap will connect to the server.
 259
 260 The default, nil, will try to use the \"best\" method the server can
 261 handle.
 262
 263 Change this if
 264
 265 1) you want to connect with TLS/SSL.  The TLS/SSL integration
 266    with IMAP is suboptimal so you'll have to tell it
 267    specifically.
 268
 269 2) your server is more capable than your environment -- i.e. your
 270    server accept Kerberos login's but you haven't installed the
 271    `imtest' program or your machine isn't configured for Kerberos.
 272
 273 Possible choices: gssapi, kerberos4, starttls, tls, ssl, network, shell.
 274 See also `imap-streams' and `imap-stream-alist'.")
 275
 276 (defvoo nnimap-authenticator nil
 277   "How nnimap authenticate itself to the server.
 278
 279 The default, nil, will try to use the \"best\" method the server can
 280 handle.
 281
 282 There is only one reason for fiddling with this variable, and that is
 283 if your server is more capable than your environment -- i.e. you
 284 connect to a server that accept Kerberos login's but you haven't
 285 installed the `imtest' program or your machine isn't configured for
 286 Kerberos.
 287
 288 Possible choices: gssapi, kerberos4, digest-md5, cram-md5, login, anonymous.
 289 See also `imap-authenticators' and `imap-authenticator-alist'")
 290
 291 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 292   "Directory to keep NOV cache files for nnimap groups.
 293 See also `nnimap-nov-file-name'.")
 294
 295 (defvoo nnimap-nov-file-name "nnimap."
 296   "NOV cache base filename.
 297 The group name and `nnimap-nov-file-name-suffix' will be appended.  A
 298 typical complete file name would be
 299 ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 300 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 301 `nnmail-use-long-file-names' is nil")
 302
 303 (defvoo nnimap-nov-file-name-suffix ".novcache"
 304   "Suffix for NOV cache base filename.")
 305
 306 (defvoo nnimap-nov-is-evil gnus-agent
 307   "If non-nil, never generate or use a local nov database for this backend.
 308 Using nov databases should speed up header fetching considerably.
 309 However, it will invoke a UID SEARCH UID command on the server, and
 310 some servers implement this command inefficiently by opening each and
 311 every message in the group, thus making it quite slow.
 312 Unlike other backends, you do not need to take special care if you
 313 flip this variable.")
 314
 315 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 316   "Whether to expunge a group when it is closed.
 317 When a IMAP group with articles marked for deletion is closed, this
 318 variable determine if nnimap should actually remove the articles or
 319 not.
 320
 321 If always, nnimap always perform a expunge when closing the group.
 322 If never, nnimap never expunges articles marked for deletion.
 323 If ask, nnimap will ask you if you wish to expunge marked articles.
 324
 325 When setting this variable to `never', you can only expunge articles
 326 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 327
 328 (defvoo nnimap-list-pattern "*"
 329   "A string LIMIT or list of strings with mailbox wildcards used to limit available groups.
 330 See below for available wildcards.
 331
 332 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 333 REFERENCE will be passed as the first parameter to LIST/LSUB.  The
 334 semantics of this are server specific, on the University of Washington
 335 server you can specify a directory.
 336
 337 Example:
 338  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 339
 340 There are two wildcards * and %. * matches everything, % matches
 341 everything in the current hierarchy.")
 342
 343 (defvoo nnimap-news-groups nil
 344   "IMAP support a news-like mode, also known as bulletin board mode,
 345 where replies is sent via IMAP instead of SMTP.
 346
 347 This variable should contain a regexp matching groups where you wish
 348 replies to be stored to the mailbox directly.
 349
 350 Example:
 351   '(\"^[^I][^N][^B][^O][^X].*$\")
 352
 353 This will match all groups not beginning with \"INBOX\".
 354
 355 Note that there is nothing technically different between mail-like and
 356 news-like mailboxes.  If you wish to have a group with todo items or
 357 similar which you wouldn't want to set up a mailing list for, you can
 358 use this to make replies go directly to the group.")
 359
 360 (defvoo nnimap-expunge-search-string "UID %s NOT SINCE %s"
 361   "IMAP search command to use for articles that are to be expired.
 362 The first %s is replaced by a UID set of articles to search on,
 363 and the second %s is replaced by a date criterium.
 364
 365 One useful (and perhaps the only useful) value to change this to would
 366 be `UID %s NOT SENTSINCE %s' to make nnimap use the Date: header
 367 instead of the internal date of messages.  See section 6.4.4 of RFC
 368 2060 for more information on valid strings.")
 369
 370 (defvoo nnimap-importantize-dormant t
 371   "If non-nil, mark \"dormant\" articles as \"ticked\" for other IMAP clients.
 372 Note that within Gnus, dormant articles will still (only) be
 373 marked as ticked.  This is to make \"dormant\" articles stand out,
 374 just like \"ticked\" articles, in other IMAP clients.")
 375
 376 (defvoo nnimap-server-address nil
 377   "Obsolete.  Use `nnimap-address'.")
 378
 379 (defcustom nnimap-authinfo-file "~/.authinfo"
 380   "Authorization information for IMAP servers.  In .netrc format."
 381   :type
 382   '(choice file
 383            (repeat :tag "Entries"
 384                    :menu-tag "Inline"
 385                    (list :format "%v"
 386                          :value ("" ("login" . "") ("password" . ""))
 387                          (string :tag "Host")
 388                          (checklist :inline t
 389                                     (cons :format "%v"
 390                                           (const :format "" "login")
 391                                           (string :format "Login: %v"))
 392                                     (cons :format "%v"
 393                                           (const :format "" "password")
 394                                           (string :format "Password: %v"))))))
 395   :group 'nnimap)
 396
 397 (defcustom nnimap-prune-cache t
 398   "If non-nil, nnimap check whether articles still exist on server before using data stored in NOV cache."
 399   :type 'boolean
 400   :group 'nnimap)
 401
 402 (defvar nnimap-request-list-method 'imap-mailbox-list
 403   "Method to use to request a list of all folders from the server.
 404 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 405 restrict visible folders.")
 406
 407 (defcustom nnimap-id nil
 408   "Plist with client identity to send to server upon login.
 409 Nil means no information is sent, symbol `no' to disable ID query
 410 alltogheter, or plist with identifier-value pairs to send to
 411 server.  RFC 2971 describes the list as follows:
 412
 413    Any string may be sent as a field, but the following are defined to
 414    describe certain values that might be sent.  Implementations are free
 415    to send none, any, or all of these.  Strings are not case-sensitive.
 416    Field strings MUST NOT be longer than 30 octets.  Value strings MUST
 417    NOT be longer than 1024 octets.  Implementations MUST NOT send more
 418    than 30 field-value pairs.
 419
 420      name            Name of the program
 421      version         Version number of the program
 422      os              Name of the operating system
 423      os-version      Version of the operating system
 424      vendor          Vendor of the client/server
 425      support-url     URL to contact for support
 426      address         Postal address of contact/vendor
 427      date            Date program was released, specified as a date-time
 428                        in IMAP4rev1
 429      command         Command used to start the program
 430      arguments       Arguments supplied on the command line, if any
 431                        if any
 432      environment     Description of environment, i.e., UNIX environment
 433                        variables or Windows registry settings
 434
 435    Implementations MUST NOT send the same field name more than once.
 436
 437 An example plist would be '(\"name\" \"Gnus\" \"version\" gnus-version-number
 438 \"os\" system-configuration \"vendor\" \"GNU\")."
 439   :group 'nnimap
 440   :type '(choice (const :tag "No information" nil)
 441                  (const :tag "Disable ID query" no)
 442                  (plist :key-type string :value-type string)))
 443
 444 (defcustom nnimap-debug nil
 445   "If non-nil, random debug spews are placed in *nnimap-debug* buffer."
 446   :group 'nnimap
 447   :type 'boolean)
 448
 449 ;; Internal variables:
 450
 451 (defvar nnimap-debug-buffer "*nnimap-debug*")
 452 (defvar nnimap-mailbox-info (gnus-make-hashtable 997))
 453 (defvar nnimap-current-move-server nil)
 454 (defvar nnimap-current-move-group nil)
 455 (defvar nnimap-current-move-article nil)
 456 (defvar nnimap-length)
 457 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 458 (defvar nnimap-progress-how-often 20)
 459 (defvar nnimap-counter)
 460 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 461 (defvar nnimap-current-server nil) ;; Current server
 462 (defvar nnimap-server-buffer nil) ;; Current servers' buffer
 463
 464 \f
 465
 466 (nnoo-define-basics nnimap)
 467
 468 ;; Utility functions:
 469
 470 (defsubst nnimap-get-server-buffer (server)
 471   "Return buffer for SERVER, if nil use current server."
 472   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 473
 474 (defun nnimap-possibly-change-server (server)
 475   "Return buffer for SERVER, changing the current server as a side-effect.
 476 If SERVER is nil, uses the current server."
 477   (setq nnimap-current-server (or server nnimap-current-server)
 478         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 479
 480 (defun nnimap-verify-uidvalidity (group server)
 481   "Verify stored uidvalidity match current one in GROUP on SERVER."
 482   (let* ((gnusgroup (gnus-group-prefixed-name
 483                      group (gnus-server-to-method
 484                             (format "nnimap:%s" server))))
 485          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 486          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity))
 487          (dir (file-name-as-directory (expand-file-name nnimap-directory)))
 488          (nameuid (nnheader-translate-file-chars
 489                    (concat nnimap-nov-file-name
 490                            (if (equal server "")
 491                                "unnamed"
 492                              server) "." group "." old-uidvalidity
 493                            nnimap-nov-file-name-suffix) t))
 494          (file (if (or nnmail-use-long-file-names
 495                        (file-exists-p (expand-file-name nameuid dir)))
 496                    (expand-file-name nameuid dir)
 497                  (expand-file-name
 498                   (mm-encode-coding-string
 499                    (nnheader-replace-chars-in-string nameuid ?. ?/)
 500                    nnmail-pathname-coding-system)
 501                   dir))))
 502     (if old-uidvalidity
 503         (if (not (equal old-uidvalidity new-uidvalidity))
 504             ;; uidvalidity clash
 505             (gnus-delete-file file)
 506           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 507           t)
 508       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 509       t)))
 510
 511 (defun nnimap-before-find-minmax-bugworkaround ()
 512   "Function called before iterating through mailboxes with
 513 `nnimap-find-minmax-uid'."
 514   (when nnimap-need-unselect-to-notice-new-mail
 515     ;; XXX this is for UoW imapd problem, it doesn't notice new mail in
 516     ;; currently selected mailbox without a re-select/examine.
 517     (or (null (imap-current-mailbox nnimap-server-buffer))
 518         (imap-mailbox-unselect nnimap-server-buffer))))
 519
 520 (defun nnimap-find-minmax-uid (group &optional examine)
 521   "Find lowest and highest active article number in GROUP.
 522 If EXAMINE is non-nil the group is selected read-only."
 523   (with-current-buffer nnimap-server-buffer
 524     (when (or (string= group (imap-current-mailbox))
 525               (imap-mailbox-select group examine))
 526       (let (minuid maxuid)
 527         (when (> (imap-mailbox-get 'exists) 0)
 528           (imap-fetch "1,*" "UID" nil 'nouidfetch)
 529           (imap-message-map (lambda (uid Uid)
 530                               (setq minuid (if minuid (min minuid uid) uid)
 531                                     maxuid (if maxuid (max maxuid uid) uid)))
 532                             'UID))
 533         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 534
 535 (defun nnimap-possibly-change-group (group &optional server)
 536   "Make GROUP the current group, and SERVER the current server."
 537   (when (nnimap-possibly-change-server server)
 538     (with-current-buffer nnimap-server-buffer
 539       (if (or (null group) (imap-current-mailbox-p group))
 540           imap-current-mailbox
 541         (if (imap-mailbox-select group)
 542             (if (or (nnimap-verify-uidvalidity
 543                      group (or server nnimap-current-server))
 544                     (zerop (imap-mailbox-get 'exists group))
 545                     t ;; for OGnus to see if ignoring uidvalidity
 546                     ;; changes has any bad effects.
 547                     (yes-or-no-p
 548                      (format
 549                       "nnimap: Group %s is not uidvalid.  Continue? " group)))
 550                 imap-current-mailbox
 551               (imap-mailbox-unselect)
 552               (error "nnimap: Group %s is not uid-valid" group))
 553           (nnheader-report 'nnimap (imap-error-text)))))))
 554
 555 (defun nnimap-replace-whitespace (string)
 556   "Return STRING with all whitespace replaced with space."
 557   (when string
 558     (while (string-match "[\r\n\t]+" string)
 559       (setq string (replace-match " " t t string)))
 560     string))
 561
 562 ;; Required backend functions
 563
 564 (defun nnimap-retrieve-headers-progress ()
 565   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 566   (and (numberp nnmail-large-newsgroup)
 567        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 568        (> nnimap-length nnmail-large-newsgroup)
 569        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 570                          (nth (/ (% nnimap-counter
 571                                     (* (length nnimap-progress-chars)
 572                                        nnimap-progress-how-often))
 573                                  nnimap-progress-how-often)
 574                               nnimap-progress-chars)))
 575   (with-current-buffer nntp-server-buffer
 576     (let (headers lines chars uid mbx)
 577       (with-current-buffer nnimap-server-buffer
 578         (setq uid imap-current-message
 579               mbx imap-current-mailbox
 580               headers (nnimap-demule
 581                        (if (imap-capability 'IMAP4rev1)
 582                            ;; xxx don't just use car? alist doesn't contain
 583                            ;; anything else now, but it might...
 584                            (nth 2 (car (imap-message-get uid 'BODYDETAIL)))
 585                          (imap-message-get uid 'RFC822.HEADER)))
 586               lines (imap-body-lines (imap-message-body imap-current-message))
 587               chars (imap-message-get imap-current-message 'RFC822.SIZE)))
 588       (nnheader-insert-nov
 589        (with-temp-buffer
 590          (buffer-disable-undo)
 591          (insert headers)
 592          (let ((head (nnheader-parse-naked-head uid)))
 593            (mail-header-set-number head uid)
 594            (mail-header-set-chars head chars)
 595            (mail-header-set-lines head lines)
 596            (mail-header-set-xref
 597             head (format "%s %s:%d" (system-name) mbx uid))
 598            head))))))
 599
 600 (defun nnimap-retrieve-which-headers (articles fetch-old)
 601   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 602   (with-current-buffer nnimap-server-buffer
 603     (if (numberp (car-safe articles))
 604         (imap-search
 605          (concat "UID "
 606                  (imap-range-to-message-set
 607                   (gnus-compress-sequence
 608                    (append (gnus-uncompress-sequence
 609                             (and fetch-old
 610                                  (cons (if (numberp fetch-old)
 611                                            (max 1 (- (car articles) fetch-old))
 612                                          1)
 613                                        (1- (car articles)))))
 614                            articles)))))
 615       (mapcar (lambda (msgid)
 616                 (imap-search
 617                  (format "HEADER Message-Id \"%s\"" msgid)))
 618               articles))))
 619
 620 (defun nnimap-group-overview-filename (group server)
 621   "Make file name for GROUP on SERVER."
 622   (let* ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 623          (uidvalidity (gnus-group-get-parameter
 624                        (gnus-group-prefixed-name
 625                         group (gnus-server-to-method
 626                                (format "nnimap:%s" server)))
 627                        'uidvalidity))
 628          (name (nnheader-translate-file-chars
 629                 (concat nnimap-nov-file-name
 630                         (if (equal server "")
 631                             "unnamed"
 632                           server) "." group nnimap-nov-file-name-suffix) t))
 633          (nameuid (nnheader-translate-file-chars
 634                    (concat nnimap-nov-file-name
 635                            (if (equal server "")
 636                                "unnamed"
 637                              server) "." group "." uidvalidity
 638                            nnimap-nov-file-name-suffix) t))
 639          (oldfile (if (or nnmail-use-long-file-names
 640                           (file-exists-p (expand-file-name name dir)))
 641                       (expand-file-name name dir)
 642                     (expand-file-name
 643                      (mm-encode-coding-string
 644                       (nnheader-replace-chars-in-string name ?. ?/)
 645                       nnmail-pathname-coding-system)
 646                      dir)))
 647          (newfile (if (or nnmail-use-long-file-names
 648                           (file-exists-p (expand-file-name nameuid dir)))
 649                       (expand-file-name nameuid dir)
 650                     (expand-file-name
 651                      (mm-encode-coding-string
 652                       (nnheader-replace-chars-in-string nameuid ?. ?/)
 653                       nnmail-pathname-coding-system)
 654                      dir))))
 655     (when (and (file-exists-p oldfile) (not (file-exists-p newfile)))
 656       (message "nnimap: Upgrading novcache filename...")
 657       (sit-for 1)
 658       (gnus-make-directory (file-name-directory newfile))
 659       (unless (ignore-errors (rename-file oldfile newfile) t)
 660         (if (ignore-errors (copy-file oldfile newfile) t)
 661             (delete-file oldfile)
 662           (error "Can't rename `%s' to `%s'" oldfile newfile))))
 663     newfile))
 664
 665 (defun nnimap-retrieve-headers-from-file (group server)
 666   (with-current-buffer nntp-server-buffer
 667     (let ((nov (nnimap-group-overview-filename group server)))
 668       (when (file-exists-p nov)
 669         (mm-insert-file-contents nov)
 670         (set-buffer-modified-p nil)
 671         (let ((min (ignore-errors (goto-char (point-min))
 672                                   (read (current-buffer))))
 673               (max (ignore-errors (goto-char (point-max))
 674                                   (forward-line -1)
 675                                   (read (current-buffer)))))
 676           (if (and (numberp min) (numberp max))
 677               (cons min max)
 678             ;; junk, remove it, it's saved later
 679             (erase-buffer)
 680             nil))))))
 681
 682 (defun nnimap-retrieve-headers-from-server (articles group server)
 683   (with-current-buffer nnimap-server-buffer
 684     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 685           (nnimap-length (gnus-range-length articles))
 686           (nnimap-counter 0))
 687       (imap-fetch (imap-range-to-message-set articles)
 688                   (concat "(UID RFC822.SIZE BODY "
 689                           (let ((headers
 690                                  (append '(Subject From Date Message-Id
 691                                                    References In-Reply-To Xref)
 692                                          (copy-sequence
 693                                           nnmail-extra-headers))))
 694                             (if (imap-capability 'IMAP4rev1)
 695                                 (format "BODY.PEEK[HEADER.FIELDS %s])" headers)
 696                               (format "RFC822.HEADER.LINES %s)" headers)))))
 697       (and (numberp nnmail-large-newsgroup)
 698            (> nnimap-length nnmail-large-newsgroup)
 699            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 700
 701 (defun nnimap-dont-use-nov-p (group server)
 702   (or gnus-nov-is-evil nnimap-nov-is-evil
 703       (unless (and (gnus-make-directory
 704                     (file-name-directory
 705                      (nnimap-group-overview-filename group server)))
 706                    (file-writable-p
 707                     (nnimap-group-overview-filename group server)))
 708         (message "nnimap: Nov cache not writable, %s"
 709                  (nnimap-group-overview-filename group server)))))
 710
 711 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 712   (when (nnimap-possibly-change-group group server)
 713     (with-current-buffer nntp-server-buffer
 714       (erase-buffer)
 715       (if (nnimap-dont-use-nov-p group server)
 716           (nnimap-retrieve-headers-from-server
 717            (gnus-compress-sequence articles) group server)
 718         (let (uids cached low high)
 719           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 720                       low (car uids)
 721                       high (car (last uids)))
 722             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 723                 (progn
 724                   ;; fetch articles with uids before cache block
 725                   (when (< low (car cached))
 726                     (goto-char (point-min))
 727                     (nnimap-retrieve-headers-from-server
 728                      (cons low (1- (car cached))) group server))
 729                   ;; fetch articles with uids after cache block
 730                   (when (> high (cdr cached))
 731                     (goto-char (point-max))
 732                     (nnimap-retrieve-headers-from-server
 733                      (cons (1+ (cdr cached)) high) group server))
 734                   (when nnimap-prune-cache
 735                     ;; remove nov's for articles which has expired on server
 736                     (goto-char (point-min))
 737                     (dolist (uid (gnus-set-difference articles uids))
 738                       (when (re-search-forward (format "^%d\t" uid) nil t)
 739                         (gnus-delete-line)))))
 740               ;; nothing cached, fetch whole range from server
 741               (nnimap-retrieve-headers-from-server
 742                (cons low high) group server))
 743             (when (buffer-modified-p)
 744               (nnmail-write-region
 745                (point-min) (point-max)
 746                (nnimap-group-overview-filename group server) nil 'nomesg))
 747             (nnheader-nov-delete-outside-range low high))))
 748       'nov)))
 749
 750 (defun nnimap-open-connection (server)
 751   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 752                       nnimap-authenticator nnimap-server-buffer))
 753       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 754     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 755                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 756       (imap-close nnimap-server-buffer)
 757       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 758     (let* ((list (netrc-parse nnimap-authinfo-file))
 759            (port (if nnimap-server-port
 760                      (int-to-string nnimap-server-port)
 761                    "imap"))
 762            (alist (or (netrc-machine list server port "imap")
 763                       (netrc-machine list
 764                                      (or nnimap-server-address
 765                                          nnimap-address)
 766                                      port "imap")
 767                       (netrc-machine list server port "imaps")
 768                       (netrc-machine list
 769                                      (or nnimap-server-address
 770                                          nnimap-address)
 771                                      port "imaps")))
 772            (user (netrc-get alist "login"))
 773            (passwd (netrc-get alist "password")))
 774       (if (imap-authenticate user passwd nnimap-server-buffer)
 775           (prog1
 776               (push (list server nnimap-server-buffer)
 777                     nnimap-server-buffer-alist)
 778             (imap-id nnimap-id nnimap-server-buffer)
 779             (nnimap-possibly-change-server server))
 780         (imap-close nnimap-server-buffer)
 781         (kill-buffer nnimap-server-buffer)
 782         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 783
 784 (deffoo nnimap-open-server (server &optional defs)
 785   (nnheader-init-server-buffer)
 786   (if (nnimap-server-opened server)
 787       t
 788     (unless (assq 'nnimap-server-buffer defs)
 789       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 790     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 791     ;; for people that configured nnimap with a very old version
 792     (unless (assq 'nnimap-address defs)
 793       (if (assq 'nnimap-server-address defs)
 794           (push (list 'nnimap-address
 795                       (cadr (assq 'nnimap-server-address defs))) defs)
 796         (push (list 'nnimap-address server) defs)))
 797     (nnoo-change-server 'nnimap server defs)
 798     (or nnimap-server-buffer
 799         (setq nnimap-server-buffer (cadr (assq 'nnimap-server-buffer defs))))
 800     (with-current-buffer (get-buffer-create nnimap-server-buffer)
 801       (nnoo-change-server 'nnimap server defs))
 802     (or (and nnimap-server-buffer
 803              (imap-opened nnimap-server-buffer)
 804              (if (with-current-buffer nnimap-server-buffer
 805                    (memq imap-state '(auth select examine)))
 806                  t
 807                (imap-close nnimap-server-buffer)
 808                (nnimap-open-connection server)))
 809         (nnimap-open-connection server))))
 810
 811 (deffoo nnimap-server-opened (&optional server)
 812   "Whether SERVER is opened.
 813 If SERVER is the current virtual server, and the connection to the
 814 physical server is alive, this function return a non-nil value.  If
 815 SERVER is nil, it is treated as the current server."
 816   ;; clean up autologouts??
 817   (and (or server nnimap-current-server)
 818        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 819        (imap-opened (nnimap-get-server-buffer server))))
 820
 821 (deffoo nnimap-close-server (&optional server)
 822   "Close connection to server and free all resources connected to it.
 823 Return nil if the server couldn't be closed for some reason."
 824   (let ((server (or server nnimap-current-server)))
 825     (when (or (nnimap-server-opened server)
 826               (imap-opened (nnimap-get-server-buffer server)))
 827       (imap-close (nnimap-get-server-buffer server))
 828       (kill-buffer (nnimap-get-server-buffer server))
 829       (setq nnimap-server-buffer nil
 830             nnimap-current-server nil
 831             nnimap-server-buffer-alist
 832             (delq server nnimap-server-buffer-alist)))
 833     (nnoo-close-server 'nnimap server)))
 834
 835 (deffoo nnimap-request-close ()
 836   "Close connection to all servers and free all resources that the backend have reserved.
 837 All buffers that have been created by that
 838 backend should be killed.  (Not the nntp-server-buffer, though.) This
 839 function is generally only called when Gnus is shutting down."
 840   (mapc (lambda (server) (nnimap-close-server (car server)))
 841         nnimap-server-buffer-alist)
 842   (setq nnimap-server-buffer-alist nil))
 843
 844 (deffoo nnimap-status-message (&optional server)
 845   "This function returns the last error message from server."
 846   (when (nnimap-possibly-change-server server)
 847     (nnoo-status-message 'nnimap server)))
 848
 849 (defun nnimap-demule (string)
 850   ;; BEWARE: we used to use string-as-multibyte here which is braindead
 851   ;; because it will turn accidental emacs-mule-valid byte sequences
 852   ;; into multibyte chars.  --Stef
 853   (funcall (if (and (fboundp 'string-to-multibyte)
 854                     (subrp (symbol-function 'string-to-multibyte)))
 855                'string-to-multibyte
 856              'identity)
 857            (or string "")))
 858
 859 (defun nnimap-make-callback (article gnus-callback buffer)
 860   "Return a callback function."
 861   `(lambda ()
 862      (nnimap-callback ,article ,gnus-callback ,buffer)))
 863
 864 (defun nnimap-callback (article gnus-callback buffer)
 865   (when (eq article (imap-current-message))
 866     (remove-hook 'imap-fetch-data-hook
 867                  (nnimap-make-callback article gnus-callback buffer))
 868     (with-current-buffer buffer
 869       (insert
 870        (with-current-buffer nnimap-server-buffer
 871          (nnimap-demule
 872           (if (imap-capability 'IMAP4rev1)
 873               ;; xxx don't just use car? alist doesn't contain
 874               ;; anything else now, but it might...
 875               (nth 2 (car (imap-message-get article 'BODYDETAIL)))
 876             (imap-message-get article 'RFC822)))))
 877       (nnheader-ms-strip-cr)
 878       (funcall gnus-callback t))))
 879
 880 (defun nnimap-request-article-part (article part prop &optional
 881                                             group server to-buffer detail)
 882   (when (nnimap-possibly-change-group group server)
 883     (let ((article (if (stringp article)
 884                        (car-safe (imap-search
 885                                   (format "HEADER Message-Id \"%s\"" article)
 886                                   nnimap-server-buffer))
 887                      article)))
 888       (when article
 889         (gnus-message 10 "nnimap: Fetching (part of) article %d from %s..."
 890                       article (or group imap-current-mailbox
 891                                   gnus-newsgroup-name))
 892         (if (not nnheader-callback-function)
 893             (with-current-buffer (or to-buffer nntp-server-buffer)
 894               (erase-buffer)
 895               (let ((data (imap-fetch article part prop nil
 896                                       nnimap-server-buffer)))
 897                 (insert (nnimap-demule (if detail
 898                                            (nth 2 (car data))
 899                                          data))))
 900               (nnheader-ms-strip-cr)
 901               (gnus-message
 902                10 "nnimap: Fetching (part of) article %d from %s...done"
 903                article (or group imap-current-mailbox gnus-newsgroup-name))
 904               (if (bobp)
 905                   (nnheader-report 'nnimap "No such article %d in %s: %s"
 906                                    article (or group imap-current-mailbox
 907                                                gnus-newsgroup-name)
 908                                    (imap-error-text nnimap-server-buffer))
 909                 (cons group article)))
 910           (add-hook 'imap-fetch-data-hook
 911                     (nnimap-make-callback article
 912                                           nnheader-callback-function
 913                                           nntp-server-buffer))
 914           (imap-fetch-asynch article part nil nnimap-server-buffer)
 915           (cons group article))))))
 916
 917 (deffoo nnimap-asynchronous-p ()
 918   t)
 919
 920 (deffoo nnimap-request-article (article &optional group server to-buffer)
 921   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 922       (nnimap-request-article-part
 923        article "BODY.PEEK[]" 'BODYDETAIL group server to-buffer 'detail)
 924     (nnimap-request-article-part
 925      article "RFC822.PEEK" 'RFC822 group server to-buffer)))
 926
 927 (deffoo nnimap-request-head (article &optional group server to-buffer)
 928   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 929       (nnimap-request-article-part
 930        article "BODY.PEEK[HEADER]" 'BODYDETAIL group server to-buffer 'detail)
 931     (nnimap-request-article-part
 932      article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer)))
 933
 934 (deffoo nnimap-request-body (article &optional group server to-buffer)
 935   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 936       (nnimap-request-article-part
 937        article "BODY.PEEK[TEXT]" 'BODYDETAIL group server to-buffer 'detail)
 938     (nnimap-request-article-part
 939      article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer)))
 940
 941 (deffoo nnimap-request-group (group &optional server fast)
 942   (nnimap-request-update-info-internal
 943    group
 944    (gnus-get-info (gnus-group-prefixed-name
 945                    group (gnus-server-to-method (format "nnimap:%s" server))))
 946    server)
 947   (when (nnimap-possibly-change-group group server)
 948     (nnimap-before-find-minmax-bugworkaround)
 949     (let (info)
 950       (cond (fast group)
 951             ((null (setq info (nnimap-find-minmax-uid group t)))
 952              (nnheader-report 'nnimap "Could not get active info for %s"
 953                               group))
 954             (t
 955              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
 956                               (max 1 (or (nth 1 info) 1))
 957                               (or (nth 2 info) 0) group)
 958              (nnheader-report 'nnimap "Group %s selected" group)
 959              t)))))
 960
 961 (defun nnimap-update-unseen (group &optional server)
 962   "Update the unseen count in `nnimap-mailbox-info'."
 963   (gnus-sethash
 964    (gnus-group-prefixed-name group server)
 965    (let ((old (gnus-gethash-safe (gnus-group-prefixed-name group server)
 966                                  nnimap-mailbox-info)))
 967      (list (nth 0 old) (nth 1 old)
 968            (imap-mailbox-status group 'unseen nnimap-server-buffer)
 969            (nth 3 old)))
 970    nnimap-mailbox-info))
 971
 972 (defun nnimap-close-group (group &optional server)
 973   (with-current-buffer nnimap-server-buffer
 974     (when (and (imap-opened)
 975                (nnimap-possibly-change-group group server))
 976       (nnimap-update-unseen group server)
 977       (case nnimap-expunge-on-close
 978         (always (progn
 979                   (imap-mailbox-expunge nnimap-close-asynchronous)
 980                   (unless nnimap-dont-close
 981                     (imap-mailbox-close nnimap-close-asynchronous))))
 982         (ask (if (and (imap-search "DELETED")
 983                       (gnus-y-or-n-p (format "Expunge articles in group `%s'? "
 984                                              imap-current-mailbox)))
 985                  (progn
 986                    (imap-mailbox-expunge nnimap-close-asynchronous)
 987                    (unless nnimap-dont-close
 988                      (imap-mailbox-close nnimap-close-asynchronous)))
 989                (imap-mailbox-unselect)))
 990         (t (imap-mailbox-unselect)))
 991       (not imap-current-mailbox))))
 992
 993 (defun nnimap-pattern-to-list-arguments (pattern)
 994   (mapcar (lambda (p)
 995             (cons (car-safe p) (or (cdr-safe p) p)))
 996           (if (and (listp pattern)
 997                    (listp (cdr pattern)))
 998               pattern
 999             (list pattern))))
1000
1001 (deffoo nnimap-request-list (&optional server)
1002   (when (nnimap-possibly-change-server server)
1003     (with-current-buffer nntp-server-buffer
1004       (erase-buffer))
1005     (gnus-message 5 "nnimap: Generating active list%s..."
1006                   (if (> (length server) 0) (concat " for " server) ""))
1007     (nnimap-before-find-minmax-bugworkaround)
1008     (with-current-buffer nnimap-server-buffer
1009       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
1010         (dolist (mbx (funcall nnimap-request-list-method
1011                               (cdr pattern) (car pattern)))
1012           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
1013               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1014                 (when info
1015                   (with-current-buffer nntp-server-buffer
1016                     (insert (format "\"%s\" %d %d y\n"
1017                                     mbx (or (nth 2 info) 0)
1018                                     (max 1 (or (nth 1 info) 1)))))))))))
1019     (gnus-message 5 "nnimap: Generating active list%s...done"
1020                   (if (> (length server) 0) (concat " for " server) ""))
1021     t))
1022
1023 (deffoo nnimap-request-post (&optional server)
1024   (let ((success t))
1025     (dolist (mbx (message-unquote-tokens
1026                   (message-tokenize-header
1027                    (message-fetch-field "Newsgroups") ", ")) success)
1028       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
1029         (or (gnus-active to-newsgroup)
1030             (gnus-activate-group to-newsgroup)
1031             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
1032                                        to-newsgroup))
1033                 (or (and (gnus-request-create-group
1034                           to-newsgroup gnus-command-method)
1035                          (gnus-activate-group to-newsgroup nil nil
1036                                               gnus-command-method))
1037                     (error "Couldn't create group %s" to-newsgroup)))
1038             (error "No such group: %s" to-newsgroup))
1039         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
1040           (setq success nil))))))
1041
1042 ;; Optional backend functions
1043
1044 (defun nnimap-string-lessp-numerical (s1 s2)
1045   "Return t if first arg string is less than second in numerical order."
1046   (cond ((string= s1 s2)
1047          nil)
1048         ((> (length s1) (length s2))
1049          nil)
1050         ((< (length s1) (length s2))
1051          t)
1052         ((< (string-to-number (substring s1 0 1))
1053             (string-to-number (substring s2 0 1)))
1054          t)
1055         ((> (string-to-number (substring s1 0 1))
1056             (string-to-number (substring s2 0 1)))
1057          nil)
1058         (t
1059          (nnimap-string-lessp-numerical (substring s1 1) (substring s2 1)))))
1060
1061 (deffoo nnimap-retrieve-groups (groups &optional server)
1062   (when (nnimap-possibly-change-server server)
1063     (gnus-message 5 "nnimap: Checking mailboxes...")
1064     (with-current-buffer nntp-server-buffer
1065       (erase-buffer)
1066       (nnimap-before-find-minmax-bugworkaround)
1067       (let (asyncgroups slowgroups)
1068         (if (null nnimap-retrieve-groups-asynchronous)
1069             (setq slowgroups groups)
1070           (dolist (group groups)
1071             (gnus-message 9 "nnimap: Quickly checking mailbox %s" group)
1072             (add-to-list (if (gnus-gethash-safe
1073                               (gnus-group-prefixed-name group server)
1074                               nnimap-mailbox-info)
1075                              'asyncgroups
1076                            'slowgroups)
1077                          (list group (imap-mailbox-status-asynch
1078                                       group '(uidvalidity uidnext unseen)
1079                                       nnimap-server-buffer))))
1080           (dolist (asyncgroup asyncgroups)
1081             (let ((group (nth 0 asyncgroup))
1082                   (tag   (nth 1 asyncgroup))
1083                   new old)
1084               (when (imap-ok-p (imap-wait-for-tag tag nnimap-server-buffer))
1085                 (if (or (not (string=
1086                               (nth 0 (gnus-gethash (gnus-group-prefixed-name
1087                                                     group server)
1088                                                    nnimap-mailbox-info))
1089                               (imap-mailbox-get 'uidvalidity group
1090                                                 nnimap-server-buffer)))
1091                         (not (string=
1092                               (nth 1 (gnus-gethash (gnus-group-prefixed-name
1093                                                     group server)
1094                                                    nnimap-mailbox-info))
1095                               (imap-mailbox-get 'uidnext group
1096                                                 nnimap-server-buffer))))
1097                     (push (list group) slowgroups)
1098                   (insert (nth 3 (gnus-gethash (gnus-group-prefixed-name
1099                                                 group server)
1100                                                nnimap-mailbox-info))))))))
1101         (dolist (group slowgroups)
1102           (if nnimap-retrieve-groups-asynchronous
1103               (setq group (car group)))
1104           (gnus-message 7 "nnimap: Mailbox %s modified" group)
1105           (imap-mailbox-put 'uidnext nil group nnimap-server-buffer)
1106           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags group
1107                                                      nnimap-server-buffer))
1108               (let* ((info (nnimap-find-minmax-uid group 'examine))
1109                      (str (format "\"%s\" %d %d y\n" group
1110                                   (or (nth 2 info) 0)
1111                                   (max 1 (or (nth 1 info) 1)))))
1112                 (when (> (or (imap-mailbox-get 'recent group
1113                                                nnimap-server-buffer) 0)
1114                          0)
1115                   (push (list (cons group 0)) nnmail-split-history))
1116                 (insert str)
1117                 (when nnimap-retrieve-groups-asynchronous
1118                   (gnus-sethash
1119                    (gnus-group-prefixed-name group server)
1120                    (list (or (imap-mailbox-get
1121                               'uidvalidity group nnimap-server-buffer)
1122                              (imap-mailbox-status
1123                               group 'uidvalidity nnimap-server-buffer))
1124                          (or (imap-mailbox-get
1125                               'uidnext group nnimap-server-buffer)
1126                              (imap-mailbox-status
1127                               group 'uidnext nnimap-server-buffer))
1128                          (or (imap-mailbox-get
1129                               'unseen group nnimap-server-buffer)
1130                              (imap-mailbox-status
1131                               group 'unseen nnimap-server-buffer))
1132                          str)
1133                    nnimap-mailbox-info)))))))
1134     (gnus-message 5 "nnimap: Checking mailboxes...done")
1135     'active))
1136
1137 (deffoo nnimap-request-update-info-internal (group info &optional server)
1138   (when (nnimap-possibly-change-group group server)
1139     (when info ;; xxx what does this mean? should we create a info?
1140       (with-current-buffer nnimap-server-buffer
1141         (gnus-message 5 "nnimap: Updating info for %s..."
1142                       (gnus-info-group info))
1143
1144         (when (nnimap-mark-permanent-p 'read)
1145           (let (seen unseen)
1146             ;; read info could contain articles marked unread by other
1147             ;; imap clients!  we correct this
1148             (setq seen (gnus-uncompress-range (gnus-info-read info))
1149                   unseen (imap-search "UNSEEN UNDELETED")
1150                   seen (gnus-set-difference seen unseen)
1151                   ;; seen might lack articles marked as read by other
1152                   ;; imap clients! we correct this
1153                   seen (append seen (imap-search "SEEN"))
1154                   ;; remove dupes
1155                   seen (sort seen '<)
1156                   seen (gnus-compress-sequence seen t)
1157                   ;; we can't return '(1) since this isn't a "list of ranges",
1158                   ;; and we can't return '((1)) since g-list-of-unread-articles
1159                   ;; is buggy so we return '((1 . 1)).
1160                   seen (if (and (integerp (car seen))
1161                                 (null (cdr seen)))
1162                            (list (cons (car seen) (car seen)))
1163                          seen))
1164             (gnus-info-set-read info seen)))
1165
1166         (mapcar (lambda (pred)
1167                   (when (or (eq (cdr pred) 'recent)
1168                             (and (nnimap-mark-permanent-p (cdr pred))
1169                                  (member (nnimap-mark-to-flag (cdr pred))
1170                                          (imap-mailbox-get 'flags))))
1171                     (gnus-info-set-marks
1172                      info
1173                      (gnus-update-alist-soft
1174                       (cdr pred)
1175                       (gnus-compress-sequence
1176                        (imap-search (nnimap-mark-to-predicate (cdr pred))))
1177                       (gnus-info-marks info))
1178                      t)))
1179                 gnus-article-mark-lists)
1180
1181         (when nnimap-importantize-dormant
1182           ;; nnimap mark dormant article as ticked too (for other clients)
1183           ;; so we remove that mark for gnus since we support dormant
1184           (gnus-info-set-marks
1185            info
1186            (gnus-update-alist-soft
1187             'tick
1188             (gnus-remove-from-range
1189              (cdr-safe (assoc 'tick (gnus-info-marks info)))
1190              (cdr-safe (assoc 'dormant (gnus-info-marks info))))
1191             (gnus-info-marks info))
1192            t))
1193
1194         (gnus-message 5 "nnimap: Updating info for %s...done"
1195                       (gnus-info-group info))
1196
1197         info))))
1198
1199 (deffoo nnimap-request-type (group &optional article)
1200   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
1201       'news
1202     'mail))
1203
1204 (deffoo nnimap-request-set-mark (group actions &optional server)
1205   (when (nnimap-possibly-change-group group server)
1206     (with-current-buffer nnimap-server-buffer
1207       (let (action)
1208         (gnus-message 7 "nnimap: Setting marks in %s..." group)
1209         (while (setq action (pop actions))
1210           (let ((range (nth 0 action))
1211                 (what  (nth 1 action))
1212                 (cmdmarks (nth 2 action))
1213                 marks)
1214             ;; bookmark can't be stored (not list/range
1215             (setq cmdmarks (delq 'bookmark cmdmarks))
1216             ;; killed can't be stored (not list/range
1217             (setq cmdmarks (delq 'killed cmdmarks))
1218             ;; unsent are for nndraft groups only
1219             (setq cmdmarks (delq 'unsent cmdmarks))
1220             ;; cache flags are pointless on the server
1221             (setq cmdmarks (delq 'cache cmdmarks))
1222             ;; seen flags are local to each gnus
1223             (setq cmdmarks (delq 'seen cmdmarks))
1224             ;; recent marks can't be set
1225             (setq cmdmarks (delq 'recent cmdmarks))
1226             (when nnimap-importantize-dormant
1227               ;; flag dormant articles as ticked
1228               (if (memq 'dormant cmdmarks)
1229                   (setq cmdmarks (cons 'tick cmdmarks))))
1230             ;; remove stuff we are forbidden to store
1231             (mapc (lambda (mark)
1232                     (if (imap-message-flag-permanent-p
1233                          (nnimap-mark-to-flag mark))
1234                         (setq marks (cons mark marks))))
1235                   cmdmarks)
1236             (when (and range marks)
1237               (cond ((eq what 'del)
1238                      (imap-message-flags-del
1239                       (imap-range-to-message-set range)
1240                       (nnimap-mark-to-flag marks nil t)))
1241                     ((eq what 'add)
1242                      (imap-message-flags-add
1243                       (imap-range-to-message-set range)
1244                       (nnimap-mark-to-flag marks nil t)))
1245                     ((eq what 'set)
1246                      (imap-message-flags-set
1247                       (imap-range-to-message-set range)
1248                       (nnimap-mark-to-flag marks nil t)))))))
1249         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
1250   nil)
1251
1252 (defun nnimap-split-fancy ()
1253   "Like the function `nnmail-split-fancy', but uses `nnimap-split-fancy'."
1254   (let ((nnmail-split-fancy nnimap-split-fancy))
1255     (nnmail-split-fancy)))
1256
1257 (defun nnimap-split-to-groups (rules)
1258   ;; tries to match all rules in nnimap-split-rule against content of
1259   ;; nntp-server-buffer, returns a list of groups that matched.
1260   (with-current-buffer nntp-server-buffer
1261     ;; Fold continuation lines.
1262     (goto-char (point-min))
1263     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
1264       (replace-match " " t t))
1265     (if (functionp rules)
1266         (funcall rules)
1267       (let (to-groups regrepp)
1268         (catch 'split-done
1269           (dolist (rule rules to-groups)
1270             (let ((group (car rule))
1271                   (regexp (cadr rule)))
1272               (goto-char (point-min))
1273               (when (and (if (stringp regexp)
1274                              (progn
1275                                (if (not (stringp group))
1276                                    (setq group (eval group))
1277                                  (setq regrepp
1278                                        (string-match "\\\\[0-9&]" group)))
1279                                (re-search-forward regexp nil t))
1280                            (funcall regexp group))
1281                          ;; Don't enter the article into the same group twice.
1282                          (not (assoc group to-groups)))
1283                 (push (if regrepp
1284                           (nnmail-expand-newtext group)
1285                         group)
1286                       to-groups)
1287                 (or nnimap-split-crosspost
1288                     (throw 'split-done to-groups))))))))))
1289
1290 (defun nnimap-assoc-match (key alist)
1291   (let (element)
1292     (while (and alist (not element))
1293       (if (string-match (car (car alist)) key)
1294           (setq element (car alist)))
1295       (setq alist (cdr alist)))
1296     element))
1297
1298 (defun nnimap-split-find-rule (server inbox)
1299   (if (and (listp nnimap-split-rule) (listp (car nnimap-split-rule))
1300            (list (cdar nnimap-split-rule)) (listp (cadar nnimap-split-rule)))
1301       ;; extended format
1302       (cadr (nnimap-assoc-match inbox (cdr (nnimap-assoc-match
1303                                             server nnimap-split-rule))))
1304     nnimap-split-rule))
1305
1306 (defun nnimap-split-find-inbox (server)
1307   (if (listp nnimap-split-inbox)
1308       nnimap-split-inbox
1309     (list nnimap-split-inbox)))
1310
1311 (defun nnimap-split-articles (&optional group server)
1312   (when (nnimap-possibly-change-server server)
1313     (with-current-buffer nnimap-server-buffer
1314       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
1315         ;; iterate over inboxes
1316         (while (and (setq inbox (pop inboxes))
1317                     (nnimap-possibly-change-group inbox)) ;; SELECT
1318           ;; find split rule for this server / inbox
1319           (when (setq rule (nnimap-split-find-rule server inbox))
1320             ;; iterate over articles
1321             (dolist (article (imap-search nnimap-split-predicate))
1322               (when (if (if (eq nnimap-split-download-body 'default)
1323                             nnimap-split-download-body-default
1324                           nnimap-split-download-body)
1325                         (and (nnimap-request-article article)
1326                              (with-current-buffer nntp-server-buffer (mail-narrow-to-head)))
1327                       (nnimap-request-head article))
1328                 ;; copy article to right group(s)
1329                 (setq removeorig nil)
1330                 (dolist (to-group (nnimap-split-to-groups rule))
1331                   (cond ((eq to-group 'junk)
1332                          (message "IMAP split removed %s:%s:%d" server inbox
1333                                   article)
1334                          (setq removeorig t))
1335                         ((imap-message-copy (number-to-string article)
1336                                             to-group nil 'nocopyuid)
1337                          (message "IMAP split moved %s:%s:%d to %s" server
1338                                   inbox article to-group)
1339                          (setq removeorig t)
1340                          (when nnmail-cache-accepted-message-ids
1341                            (with-current-buffer nntp-server-buffer
1342                              (let (msgid)
1343                                (and (setq msgid
1344                                           (nnmail-fetch-field "message-id"))
1345                                     (nnmail-cache-insert msgid
1346                                                          to-group
1347                                                          (nnmail-fetch-field "subject"))))))
1348                          ;; Add the group-art list to the history list.
1349                          (push (list (cons to-group 0)) nnmail-split-history))
1350                         (t
1351                          (message "IMAP split failed to move %s:%s:%d to %s"
1352                                   server inbox article to-group))))
1353                 (if (if (eq nnimap-split-download-body 'default)
1354                         nnimap-split-download-body-default
1355                       nnimap-split-download-body)
1356                     (widen))
1357                 ;; remove article if it was successfully copied somewhere
1358                 (and removeorig
1359                      (imap-message-flags-add (format "%d" article)
1360                                              "\\Seen \\Deleted")))))
1361           (when (imap-mailbox-select inbox) ;; just in case
1362             ;; todo: UID EXPUNGE (if available) to remove splitted articles
1363             (imap-mailbox-expunge)
1364             (imap-mailbox-close)))
1365         (when nnmail-cache-accepted-message-ids
1366           (nnmail-cache-close))
1367         t))))
1368
1369 (deffoo nnimap-request-scan (&optional group server)
1370   (nnimap-split-articles group server))
1371
1372 (deffoo nnimap-request-newgroups (date &optional server)
1373   (when (nnimap-possibly-change-server server)
1374     (with-current-buffer nntp-server-buffer
1375       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
1376                     (if (> (length server) 0) " on " "") server)
1377       (erase-buffer)
1378       (nnimap-before-find-minmax-bugworkaround)
1379       (dolist (pattern (nnimap-pattern-to-list-arguments
1380                         nnimap-list-pattern))
1381         (dolist (mbx (imap-mailbox-lsub (cdr pattern) (car pattern) nil
1382                                         nnimap-server-buffer))
1383           (or (catch 'found
1384                 (dolist (mailbox (imap-mailbox-get 'list-flags mbx
1385                                                    nnimap-server-buffer))
1386                   (if (string= (downcase mailbox) "\\noselect")
1387                       (throw 'found t)))
1388                 nil)
1389               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1390                 (when info
1391                   (insert (format "\"%s\" %d %d y\n"
1392                                   mbx (or (nth 2 info) 0)
1393                                   (max 1 (or (nth 1 info) 1)))))))))
1394       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
1395                     (if (> (length server) 0) " on " "") server))
1396     t))
1397
1398 (deffoo nnimap-request-create-group (group &optional server args)
1399   (when (nnimap-possibly-change-server server)
1400     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
1401         (imap-mailbox-create group nnimap-server-buffer)
1402         (nnheader-report 'nnimap "%S"
1403                          (imap-error-text nnimap-server-buffer)))))
1404
1405 (defun nnimap-time-substract (time1 time2)
1406   "Return TIME for TIME1 - TIME2."
1407   (let* ((ms (- (car time1) (car time2)))
1408          (ls (- (nth 1 time1) (nth 1 time2))))
1409     (if (< ls 0)
1410         (list (- ms 1) (+ (expt 2 16) ls))
1411       (list ms ls))))
1412
1413 (defun nnimap-date-days-ago (daysago)
1414   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
1415   (let* ((time (nnimap-time-substract (current-time) (days-to-time daysago)))
1416          (date (format-time-string
1417                 (format "%%d-%s-%%Y"
1418                         (capitalize (car (rassoc (nth 4 (decode-time time))
1419                                                  parse-time-months))))
1420                 time)))
1421     (if (eq ?0 (string-to-char date))
1422         (substring date 1)
1423       date)))
1424
1425 (defun nnimap-request-expire-articles-progress ()
1426   (gnus-message 5 "nnimap: Marking article %d for deletion..."
1427                 imap-current-message))
1428
1429 (defun nnimap-expiry-target (arts group server)
1430   (unless (eq nnmail-expiry-target 'delete)
1431     (with-temp-buffer
1432       (dolist (art arts)
1433         (nnimap-request-article art group server (current-buffer))
1434         ;; hints for optimization in `nnimap-request-accept-article'
1435         (let ((nnimap-current-move-article art)
1436               (nnimap-current-move-group group)
1437               (nnimap-current-move-server server))
1438           (nnmail-expiry-target-group nnmail-expiry-target group))))
1439     ;; It is not clear if `nnmail-expiry-target' somehow cause the
1440     ;; current group to be changed or not, so we make sure here.
1441     (nnimap-possibly-change-group group server)))
1442
1443 ;; Notice that we don't actually delete anything, we just mark them deleted.
1444 (deffoo nnimap-request-expire-articles (articles group &optional server force)
1445   (let ((artseq (gnus-compress-sequence articles)))
1446     (when (and artseq (nnimap-possibly-change-group group server))
1447       (with-current-buffer nnimap-server-buffer
1448         (let ((days (or (and nnmail-expiry-wait-function
1449                              (funcall nnmail-expiry-wait-function group))
1450                         nnmail-expiry-wait)))
1451           (cond ((or force (eq days 'immediate))
1452                  (let ((oldarts (imap-search
1453                                  (concat "UID "
1454                                          (imap-range-to-message-set artseq)))))
1455                    (when oldarts
1456                      (nnimap-expiry-target oldarts group server)
1457                      (when (imap-message-flags-add
1458                             (imap-range-to-message-set
1459                              (gnus-compress-sequence oldarts)) "\\Deleted")
1460                        (setq articles (gnus-set-difference
1461                                        articles oldarts))))))
1462                 ((numberp days)
1463                  (let ((oldarts (imap-search
1464                                  (format nnimap-expunge-search-string
1465                                          (imap-range-to-message-set artseq)
1466                                          (nnimap-date-days-ago days))))
1467                        (imap-fetch-data-hook
1468                         '(nnimap-request-expire-articles-progress)))
1469                    (when oldarts
1470                      (nnimap-expiry-target oldarts group server)
1471                      (when (imap-message-flags-add
1472                             (imap-range-to-message-set
1473                              (gnus-compress-sequence oldarts)) "\\Deleted")
1474                        (setq articles (gnus-set-difference
1475                                        articles oldarts)))))))))))
1476   ;; return articles not deleted
1477   articles)
1478
1479 (deffoo nnimap-request-move-article (article group server
1480                                              accept-form &optional last)
1481   (when (nnimap-possibly-change-server server)
1482     (save-excursion
1483       (let ((buf (get-buffer-create " *nnimap move*"))
1484             (nnimap-current-move-article article)
1485             (nnimap-current-move-group group)
1486             (nnimap-current-move-server nnimap-current-server)
1487             result)
1488         (and (nnimap-request-article article group server)
1489              (save-excursion
1490                (set-buffer buf)
1491                (buffer-disable-undo (current-buffer))
1492                (insert-buffer-substring nntp-server-buffer)
1493                (setq result (eval accept-form))
1494                (kill-buffer buf)
1495                result)
1496              (imap-message-flags-add
1497               (imap-range-to-message-set (list article))
1498               "\\Deleted" 'silent nnimap-server-buffer))
1499         result))))
1500
1501 (deffoo nnimap-request-accept-article (group &optional server last)
1502   (when (nnimap-possibly-change-server server)
1503     (let (uid)
1504       (if (setq uid
1505                 (if (string= nnimap-current-server nnimap-current-move-server)
1506                     ;; moving article within same server, speed it up...
1507                     (and (nnimap-possibly-change-group
1508                           nnimap-current-move-group)
1509                          (imap-message-copy (number-to-string
1510                                              nnimap-current-move-article)
1511                                             group 'dontcreate nil
1512                                             nnimap-server-buffer))
1513                   (with-current-buffer (current-buffer)
1514                     (goto-char (point-min))
1515                     ;; remove any 'From blabla' lines, some IMAP servers
1516                     ;; reject the entire message otherwise.
1517                     (when (looking-at "^From[^:]")
1518                       (delete-region (point) (progn (forward-line) (point))))
1519                     ;; turn into rfc822 format (\r\n eol's)
1520                     (while (search-forward "\n" nil t)
1521                       (replace-match "\r\n"))
1522                     (when nnmail-cache-accepted-message-ids
1523                       (nnmail-cache-insert (nnmail-fetch-field "message-id")
1524                                            group
1525                                            (nnmail-fetch-field "subject"))))
1526                   (when (and last nnmail-cache-accepted-message-ids)
1527                     (nnmail-cache-close))
1528                   ;; this 'or' is for Cyrus server bug
1529                   (or (null (imap-current-mailbox nnimap-server-buffer))
1530                       (imap-mailbox-unselect nnimap-server-buffer))
1531                   (imap-message-append group (current-buffer) nil nil
1532                                        nnimap-server-buffer)))
1533           (cons group (nth 1 uid))
1534         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1535
1536 (deffoo nnimap-request-delete-group (group force &optional server)
1537   (when (nnimap-possibly-change-server server)
1538     (with-current-buffer nnimap-server-buffer
1539       (if force
1540           (or (null (imap-mailbox-status group 'uidvalidity))
1541               (imap-mailbox-delete group))
1542         ;; UNSUBSCRIBE?
1543         t))))
1544
1545 (deffoo nnimap-request-rename-group (group new-name &optional server)
1546   (when (nnimap-possibly-change-server server)
1547     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1548
1549 (defun nnimap-expunge (mailbox server)
1550   (when (nnimap-possibly-change-group mailbox server)
1551     (imap-mailbox-expunge nil nnimap-server-buffer)))
1552
1553 (defun nnimap-acl-get (mailbox server)
1554   (when (nnimap-possibly-change-server server)
1555     (and (imap-capability 'ACL nnimap-server-buffer)
1556          (imap-mailbox-acl-get mailbox nnimap-server-buffer))))
1557
1558 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1559   (when (nnimap-possibly-change-server (cadr method))
1560     (unless (imap-capability 'ACL nnimap-server-buffer)
1561       (error "Your server does not support ACL editing"))
1562     (with-current-buffer nnimap-server-buffer
1563       ;; delete all removed identifiers
1564       (mapc (lambda (old-acl)
1565               (unless (assoc (car old-acl) new-acls)
1566                 (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1567                     (error "Can't delete ACL for %s" (car old-acl)))))
1568             old-acls)
1569       ;; set all changed acl's
1570       (mapc (lambda (new-acl)
1571               (let ((new-rights (cdr new-acl))
1572                     (old-rights (cdr (assoc (car new-acl) old-acls))))
1573                 (unless (and old-rights new-rights
1574                              (string= old-rights new-rights))
1575                   (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1576                       (error "Can't set ACL for %s to %s" (car new-acl)
1577                              new-rights)))))
1578             new-acls)
1579       t)))
1580
1581 \f
1582 ;;; Internal functions
1583
1584 ;;
1585 ;; This is confusing.
1586 ;;
1587 ;; mark      => read, tick, draft, reply etc
1588 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1589 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1590 ;;
1591 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1592 ;; world, but we cheat.  Mark == gnus-article-mark-lists + '(read . read).
1593 ;;
1594
1595 (defconst nnimap-mark-to-predicate-alist
1596   (mapcar
1597    (lambda (pair)                       ; cdr is the mark
1598      (or (assoc (cdr pair)
1599                 '((read . "SEEN")
1600                   (tick . "FLAGGED")
1601                   (draft . "DRAFT")
1602                   (recent . "RECENT")
1603                   (reply . "ANSWERED")))
1604          (cons (cdr pair)
1605                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1606    (cons '(read . read) gnus-article-mark-lists)))
1607
1608 (defun nnimap-mark-to-predicate (pred)
1609   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP predicate.
1610 This is a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD gnus-expire\",
1611 to be used within a IMAP SEARCH query."
1612   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1613
1614 (defconst nnimap-mark-to-flag-alist
1615   (mapcar
1616    (lambda (pair)
1617      (or (assoc (cdr pair)
1618                 '((read . "\\Seen")
1619                   (tick . "\\Flagged")
1620                   (draft . "\\Draft")
1621                   (recent . "\\Recent")
1622                   (reply . "\\Answered")))
1623          (cons (cdr pair)
1624                (format "gnus-%s" (symbol-name (cdr pair))))))
1625    (cons '(read . read) gnus-article-mark-lists)))
1626
1627 (defun nnimap-mark-to-flag-1 (preds)
1628   (if (and (not (null preds)) (listp preds))
1629       (cons (nnimap-mark-to-flag (car preds))
1630             (nnimap-mark-to-flag (cdr preds)))
1631     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1632
1633 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1634   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP flag.
1635 This is a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\", to
1636 be used in a STORE FLAGS command."
1637   (let ((result (nnimap-mark-to-flag-1 preds)))
1638     (setq result (if (and (or make-string always-list)
1639                           (not (listp result)))
1640                      (list result)
1641                    result))
1642     (if make-string
1643         (mapconcat (lambda (flag)
1644                      (if (listp flag)
1645                          (mapconcat 'identity flag " ")
1646                        flag))
1647                    result " ")
1648       result)))
1649
1650 (defun nnimap-mark-permanent-p (mark &optional group)
1651   "Return t iff MARK can be permanently (between IMAP sessions) saved on articles, in GROUP."
1652   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1653
1654 (when nnimap-debug
1655   (require 'trace)
1656   (buffer-disable-undo (get-buffer-create nnimap-debug-buffer))
1657   (mapcar (lambda (f) (trace-function-background f nnimap-debug-buffer))
1658           '(
1659             nnimap-possibly-change-server
1660             nnimap-verify-uidvalidity
1661             nnimap-find-minmax-uid
1662             nnimap-before-find-minmax-bugworkaround
1663             nnimap-possibly-change-group
1664             ;;nnimap-replace-whitespace
1665             nnimap-retrieve-headers-progress
1666             nnimap-retrieve-which-headers
1667             nnimap-group-overview-filename
1668             nnimap-retrieve-headers-from-file
1669             nnimap-retrieve-headers-from-server
1670             nnimap-retrieve-headers
1671             nnimap-open-connection
1672             nnimap-open-server
1673             nnimap-server-opened
1674             nnimap-close-server
1675             nnimap-request-close
1676             nnimap-status-message
1677             ;;nnimap-demule
1678             nnimap-request-article-part
1679             nnimap-request-article
1680             nnimap-request-head
1681             nnimap-request-body
1682             nnimap-request-group
1683             nnimap-close-group
1684             nnimap-pattern-to-list-arguments
1685             nnimap-request-list
1686             nnimap-request-post
1687             nnimap-retrieve-groups
1688             nnimap-request-update-info-internal
1689             nnimap-request-type
1690             nnimap-request-set-mark
1691             nnimap-split-to-groups
1692             nnimap-split-find-rule
1693             nnimap-split-find-inbox
1694             nnimap-split-articles
1695             nnimap-request-scan
1696             nnimap-request-newgroups
1697             nnimap-request-create-group
1698             nnimap-time-substract
1699             nnimap-date-days-ago
1700             nnimap-request-expire-articles-progress
1701             nnimap-request-expire-articles
1702             nnimap-request-move-article
1703             nnimap-request-accept-article
1704             nnimap-request-delete-group
1705             nnimap-request-rename-group
1706             gnus-group-nnimap-expunge
1707             gnus-group-nnimap-edit-acl
1708             gnus-group-nnimap-edit-acl-done
1709             nnimap-group-mode-hook
1710             nnimap-mark-to-predicate
1711             nnimap-mark-to-flag-1
1712             nnimap-mark-to-flag
1713             nnimap-mark-permanent-p
1714             )))
1715
1716 (provide 'nnimap)
1717
1718 ;; arch-tag: 2b001f20-3ff9-4094-a0ad-46807c1ba70b
1719 ;;; nnimap.el ends here