cgit.sxemacs.org Git - gnus/blob - lisp/nnfolder.el

   1 ;;; nnfolder.el --- mail folder access for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Simon Josefsson <simon@josefsson.org> (adding MARKS)
   7 ;;      ShengHuo Zhu <zsh@cs.rochester.edu> (adding NOV)
   8 ;;      Scott Byer <byer@mv.us.adobe.com>
   9 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
  10 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
  11 ;; Keywords: mail
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  28 ;; Boston, MA 02110-1301, USA.
  29
  30 ;;; Commentary:
  31
  32 ;;; Code:
  33
  34 (require 'nnheader)
  35 (require 'message)
  36 (require 'nnmail)
  37 (require 'nnoo)
  38 (eval-when-compile (require 'cl))
  39 (require 'gnus)
  40 (require 'gnus-util)
  41 (require 'gnus-range)
  42
  43 (eval-and-compile
  44   (autoload 'gnus-article-unpropagatable-p "gnus-sum")
  45   (autoload 'gnus-intersection "gnus-range"))
  46
  47 (nnoo-declare nnfolder)
  48
  49 (defvoo nnfolder-directory (expand-file-name message-directory)
  50   "The name of the nnfolder directory.")
  51
  52 (defvoo nnfolder-nov-directory nil
  53   "The name of the nnfolder NOV directory.
  54 If nil, `nnfolder-directory' is used.")
  55
  56 (defvoo nnfolder-marks-directory nil
  57   "The name of the nnfolder MARKS directory.
  58 If nil, `nnfolder-directory' is used.")
  59
  60 (defvoo nnfolder-active-file
  61     (nnheader-concat nnfolder-directory "active")
  62   "The name of the active file.")
  63
  64 ;; I renamed this variable to something more in keeping with the general GNU
  65 ;; style. -SLB
  66
  67 (defvoo nnfolder-ignore-active-file nil
  68   "If non-nil, the active file is ignored.
  69 This causes nnfolder to do some extra work in order to determine the
  70 true active ranges of an mbox file.  Note that the active file is
  71 still saved, but its values are not used.  This costs some extra time
  72 when scanning an mbox when opening it.")
  73
  74 (defvoo nnfolder-distrust-mbox nil
  75   "If non-nil, the folder will be distrusted.
  76 This means that nnfolder will not trust the user with respect to
  77 inserting unaccounted for mail in the middle of an mbox file.  This
  78 can greatly slow down scans, which now must scan the entire file for
  79 unmarked messages.  When nil, scans occur forward from the last marked
  80 message, a huge time saver for large mailboxes.")
  81
  82 (defvoo nnfolder-newsgroups-file
  83     (concat (file-name-as-directory nnfolder-directory) "newsgroups")
  84   "Mail newsgroups description file.")
  85
  86 (defvoo nnfolder-get-new-mail t
  87   "If non-nil, nnfolder will check the incoming mail file and split the mail.")
  88
  89 (defvoo nnfolder-prepare-save-mail-hook nil
  90   "Hook run narrowed to an article before saving.")
  91
  92 (defvoo nnfolder-save-buffer-hook nil
  93   "Hook run before saving the nnfolder mbox buffer.")
  94
  95
  96 (defvoo nnfolder-inhibit-expiry nil
  97   "If non-nil, inhibit expiry.")
  98
  99 \f
 100
 101 (defconst nnfolder-version "nnfolder 2.0"
 102   "nnfolder version.")
 103
 104 (defconst nnfolder-article-marker "X-Gnus-Article-Number: "
 105   "String used to demarcate what the article number for a message is.")
 106
 107 (defvoo nnfolder-current-group nil)
 108 (defvoo nnfolder-current-buffer nil)
 109 (defvoo nnfolder-status-string "")
 110 (defvoo nnfolder-group-alist nil)
 111 (defvoo nnfolder-buffer-alist nil)
 112 (defvoo nnfolder-scantime-alist nil)
 113 (defvoo nnfolder-active-timestamp nil)
 114 (defvoo nnfolder-active-file-coding-system mm-text-coding-system)
 115 (defvoo nnfolder-active-file-coding-system-for-write
 116     nnmail-active-file-coding-system)
 117 (defvoo nnfolder-file-coding-system mm-text-coding-system)
 118 (defvoo nnfolder-file-coding-system-for-write nnheader-file-coding-system
 119   "Coding system for save nnfolder file.
 120 if nil, `nnfolder-file-coding-system' is used.") ; FIXME: fill-in the doc-string of this variable
 121
 122 (defvoo nnfolder-nov-is-evil nil
 123   "If non-nil, Gnus will never generate and use nov databases for mail groups.
 124 Using nov databases will speed up header fetching considerably.
 125 This variable shouldn't be flipped much.  If you have, for some reason,
 126 set this to t, and want to set it to nil again, you should always run
 127 the `nnfolder-generate-active-file' command.  The function will go
 128 through all nnfolder directories and generate nov databases for them
 129 all.  This may very well take some time.")
 130
 131 (defvoo nnfolder-nov-file-suffix ".nov")
 132
 133 (defvoo nnfolder-nov-buffer-alist nil)
 134
 135 (defvar nnfolder-nov-buffer-file-name nil)
 136
 137 (defvoo nnfolder-marks-is-evil nil
 138   "If non-nil, Gnus will never generate and use marks file for mail groups.
 139 Using marks files makes it possible to backup and restore mail groups
 140 separately from `.newsrc.eld'.  If you have, for some reason, set
 141 this to t, and want to set it to nil again, you should always remove
 142 the corresponding marks file (usually base nnfolder file name
 143 concatenated with `.mrk', but see `nnfolder-marks-file-suffix') for
 144 the group.  Then the marks file will be regenerated properly by Gnus.")
 145
 146 (defvoo nnfolder-marks nil)
 147
 148 (defvoo nnfolder-marks-file-suffix ".mrk")
 149
 150 (defvar nnfolder-marks-modtime (gnus-make-hashtable))
 151
 152 \f
 153
 154 ;;; Interface functions
 155
 156 (nnoo-define-basics nnfolder)
 157
 158 (deffoo nnfolder-retrieve-headers (articles &optional group server fetch-old)
 159   (save-excursion
 160     (set-buffer nntp-server-buffer)
 161     (erase-buffer)
 162     (let (article start stop num)
 163       (nnfolder-possibly-change-group group server)
 164       (when nnfolder-current-buffer
 165         (set-buffer nnfolder-current-buffer)
 166         (goto-char (point-min))
 167         (if (stringp (car articles))
 168             'headers
 169           (if (nnfolder-retrieve-headers-with-nov articles fetch-old)
 170               'nov
 171             (setq articles (gnus-sorted-intersection
 172                             ;; Is ARTICLES sorted?
 173                             (sort articles '<)
 174                             (nnfolder-existing-articles)))
 175             (while (setq article (pop articles))
 176               (set-buffer nnfolder-current-buffer)
 177               (cond ((nnfolder-goto-article article)
 178                      (setq start (point))
 179                      (setq stop (if (search-forward "\n\n" nil t)
 180                                     (1- (point))
 181                                   (point-max)))
 182                      (set-buffer nntp-server-buffer)
 183                      (insert (format "221 %d Article retrieved.\n" article))
 184                      (insert-buffer-substring nnfolder-current-buffer
 185                                               start stop)
 186                      (goto-char (point-max))
 187                      (insert ".\n"))
 188
 189                     ;; If we couldn't find this article, skip over ranges
 190                     ;; of missing articles so we don't search the whole file
 191                     ;; for each of them.
 192                     ((numberp article)
 193                      (setq start (point))
 194                      (and
 195                       ;; Check that we are either at BOF or after an
 196                       ;; article with a lower number.  We do this so we
 197                       ;; won't be confused by out-of-order article numbers,
 198                       ;; as caused by active file bogosity.
 199                       (cond
 200                        ((bobp))
 201                        ((search-backward (concat "\n" nnfolder-article-marker)
 202                                          nil t)
 203                         (goto-char (match-end 0))
 204                         (setq num (string-to-number
 205                                    (buffer-substring
 206                                     (point) (point-at-eol))))
 207                         (goto-char start)
 208                         (< num article)))
 209                       ;; Check that we are before an article with a
 210                       ;; higher number.
 211                       (search-forward (concat "\n" nnfolder-article-marker)
 212                                       nil t)
 213                       (progn
 214                         (setq num (string-to-number
 215                                    (buffer-substring
 216                                     (point) (point-at-eol))))
 217                         (> num article))
 218                       ;; Discard any article numbers before the one we're
 219                       ;; now looking at.
 220                       (while (and articles
 221                                   (< (car articles) num))
 222                         (setq articles (cdr articles))))
 223                      (goto-char start))))
 224             (set-buffer nntp-server-buffer)
 225             (nnheader-fold-continuation-lines)
 226             'headers))))))
 227
 228 (deffoo nnfolder-open-server (server &optional defs)
 229   (nnoo-change-server 'nnfolder server defs)
 230   (nnmail-activate 'nnfolder t)
 231   (gnus-make-directory nnfolder-directory)
 232   (unless (or gnus-nov-is-evil nnfolder-nov-is-evil)
 233     (and nnfolder-nov-directory
 234          (gnus-make-directory nnfolder-nov-directory)))
 235   (unless nnfolder-marks-is-evil
 236     (and nnfolder-marks-directory
 237          (gnus-make-directory nnfolder-marks-directory)))
 238   (cond
 239    ((not (file-exists-p nnfolder-directory))
 240     (nnfolder-close-server)
 241     (nnheader-report 'nnfolder "Couldn't create directory: %s"
 242                      nnfolder-directory))
 243    ((not (file-directory-p (file-truename nnfolder-directory)))
 244     (nnfolder-close-server)
 245     (nnheader-report 'nnfolder "Not a directory: %s" nnfolder-directory))
 246    (t
 247     (nnmail-activate 'nnfolder)
 248     (nnheader-report 'nnfolder "Opened server %s using directory %s"
 249                      server nnfolder-directory)
 250     t)))
 251
 252 (deffoo nnfolder-request-close ()
 253   (let ((alist nnfolder-buffer-alist))
 254     (while alist
 255       (nnfolder-close-group (caar alist) nil t)
 256       (setq alist (cdr alist))))
 257   (nnoo-close-server 'nnfolder)
 258   (setq nnfolder-buffer-alist nil
 259         nnfolder-group-alist nil))
 260
 261 (deffoo nnfolder-request-article (article &optional group server buffer)
 262   (nnfolder-possibly-change-group group server)
 263   (save-excursion
 264     (set-buffer nnfolder-current-buffer)
 265     (goto-char (point-min))
 266     (when (nnfolder-goto-article article)
 267       (let (start stop)
 268         (setq start (point))
 269         (forward-line 1)
 270         (unless (and (nnmail-search-unix-mail-delim)
 271                      (forward-line -1))
 272           (goto-char (point-max)))
 273         (setq stop (point))
 274         (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 275           (set-buffer nntp-server-buffer)
 276           (erase-buffer)
 277           (insert-buffer-substring nnfolder-current-buffer start stop)
 278           (goto-char (point-min))
 279           (while (looking-at "From ")
 280             (delete-char 5)
 281             (insert "X-From-Line: ")
 282             (forward-line 1))
 283           (if (numberp article)
 284               (cons nnfolder-current-group article)
 285             (goto-char (point-min))
 286             (cons nnfolder-current-group
 287                   (if (search-forward (concat "\n" nnfolder-article-marker)
 288                                       nil t)
 289                       (string-to-number (buffer-substring
 290                                       (point) (point-at-eol)))
 291                     -1))))))))
 292
 293 (deffoo nnfolder-request-group (group &optional server dont-check)
 294   (nnfolder-possibly-change-group group server t)
 295   (save-excursion
 296     (if (not (assoc group nnfolder-group-alist))
 297         (nnheader-report 'nnfolder "No such group: %s" group)
 298       (if dont-check
 299           (progn
 300             (nnheader-report 'nnfolder "Selected group %s" group)
 301             t)
 302         (let* ((active (assoc group nnfolder-group-alist))
 303                (group (car active))
 304                (range (cadr active)))
 305           (cond
 306            ((null active)
 307             (nnheader-report 'nnfolder "No such group: %s" group))
 308            ((null nnfolder-current-group)
 309             (nnheader-report 'nnfolder "Empty group: %s" group))
 310            (t
 311             (nnheader-report 'nnfolder "Selected group %s" group)
 312             (nnheader-insert "211 %d %d %d %s\n"
 313                              (1+ (- (cdr range) (car range)))
 314                              (car range) (cdr range) group))))))))
 315
 316 (deffoo nnfolder-request-scan (&optional group server)
 317   (nnfolder-possibly-change-group nil server)
 318   (when nnfolder-get-new-mail
 319     (nnfolder-possibly-change-group group server)
 320     (nnmail-get-new-mail
 321      'nnfolder
 322      (lambda ()
 323        (let ((bufs nnfolder-buffer-alist))
 324          (save-excursion
 325            (while bufs
 326              (if (not (gnus-buffer-live-p (nth 1 (car bufs))))
 327                  (setq nnfolder-buffer-alist
 328                        (delq (car bufs) nnfolder-buffer-alist))
 329                (set-buffer (nth 1 (car bufs)))
 330                (nnfolder-save-buffer)
 331                (kill-buffer (current-buffer)))
 332              (setq bufs (cdr bufs))))))
 333      nnfolder-directory
 334      group)))
 335
 336 ;; Don't close the buffer if we're not shutting down the server.  This way,
 337 ;; we can keep the buffer in the group buffer cache, and not have to grovel
 338 ;; over the buffer again unless we add new mail to it or modify it in some
 339 ;; way.
 340
 341 (deffoo nnfolder-close-group (group &optional server force)
 342   ;; Make sure we _had_ the group open.
 343   (when (or (assoc group nnfolder-buffer-alist)
 344             (equal group nnfolder-current-group))
 345     (let ((inf (assoc group nnfolder-buffer-alist)))
 346       (when inf
 347         (when (and nnfolder-current-group
 348                    nnfolder-current-buffer)
 349           (push (list nnfolder-current-group nnfolder-current-buffer)
 350                 nnfolder-buffer-alist))
 351         (setq nnfolder-buffer-alist
 352               (delq inf nnfolder-buffer-alist))
 353         (setq nnfolder-current-buffer (cadr inf)
 354               nnfolder-current-group (car inf))))
 355     (when (and nnfolder-current-buffer
 356                (buffer-name nnfolder-current-buffer))
 357       (save-excursion
 358         (set-buffer nnfolder-current-buffer)
 359         ;; If the buffer was modified, write the file out now.
 360         (nnfolder-save-buffer)
 361         ;; If we're shutting the server down, we need to kill the
 362         ;; buffer and remove it from the open buffer list.  Or, of
 363         ;; course, if we're trying to minimize our space impact.
 364         (kill-buffer (current-buffer))
 365         (setq nnfolder-buffer-alist (delq (assoc group nnfolder-buffer-alist)
 366                                           nnfolder-buffer-alist)))))
 367   (setq nnfolder-current-group nil
 368         nnfolder-current-buffer nil)
 369   t)
 370
 371 (deffoo nnfolder-request-create-group (group &optional server args)
 372   (nnfolder-possibly-change-group nil server)
 373   (nnmail-activate 'nnfolder)
 374   (when (and group
 375              (not (assoc group nnfolder-group-alist)))
 376     (push (list group (cons 1 0)) nnfolder-group-alist)
 377     (nnfolder-save-active nnfolder-group-alist nnfolder-active-file)
 378     (save-current-buffer
 379       (nnfolder-read-folder group)))
 380   t)
 381
 382 (deffoo nnfolder-request-list (&optional server)
 383   (nnfolder-possibly-change-group nil server)
 384   (save-excursion
 385     (let ((nnmail-file-coding-system nnfolder-active-file-coding-system))
 386       (nnmail-find-file nnfolder-active-file)
 387       (setq nnfolder-group-alist (nnmail-get-active)))
 388     t))
 389
 390 (deffoo nnfolder-request-newgroups (date &optional server)
 391   (nnfolder-possibly-change-group nil server)
 392   (nnfolder-request-list server))
 393
 394 (deffoo nnfolder-request-list-newsgroups (&optional server)
 395   (nnfolder-possibly-change-group nil server)
 396   (save-excursion
 397     (let ((nnmail-file-coding-system nnfolder-file-coding-system))
 398       (nnmail-find-file nnfolder-newsgroups-file))))
 399
 400 ;; Return a list consisting of all article numbers existing in the
 401 ;; current folder.
 402
 403 (defun nnfolder-existing-articles ()
 404   (save-excursion
 405     (when nnfolder-current-buffer
 406       (set-buffer nnfolder-current-buffer)
 407       (goto-char (point-min))
 408       (let ((marker (concat "\n" nnfolder-article-marker))
 409             (number "[0-9]+")
 410             numbers)
 411         (while (and (search-forward marker nil t)
 412                     (re-search-forward number nil t))
 413           (let ((newnum (string-to-number (match-string 0))))
 414             (if (nnmail-within-headers-p)
 415                 (push newnum numbers))))
 416       ;; The article numbers are increasing, so this result is sorted.
 417         (nreverse numbers)))))
 418
 419 (deffoo nnfolder-request-expire-articles
 420     (articles newsgroup &optional server force)
 421   (nnfolder-possibly-change-group newsgroup server)
 422   (let* ((is-old t)
 423          ;; The articles we have deleted so far.
 424          (deleted-articles nil)
 425          ;; The articles that really exist and will
 426          ;; be expired if they are old enough.
 427          (maybe-expirable
 428           (gnus-sorted-intersection articles (nnfolder-existing-articles))))
 429     (nnmail-activate 'nnfolder)
 430
 431     (save-excursion
 432       (set-buffer nnfolder-current-buffer)
 433       ;; Since messages are sorted in arrival order and expired in the
 434       ;; same order, we can stop as soon as we find a message that is
 435       ;; too old.
 436       (while (and maybe-expirable is-old)
 437         (goto-char (point-min))
 438         (when (and (nnfolder-goto-article (car maybe-expirable))
 439                    (search-forward (concat "\n" nnfolder-article-marker)
 440                                    nil t))
 441           (forward-sexp)
 442           (when (setq is-old
 443                       (nnmail-expired-article-p
 444                        newsgroup
 445                        (buffer-substring
 446                         (point) (progn (end-of-line) (point)))
 447                        force nnfolder-inhibit-expiry))
 448             (unless (eq nnmail-expiry-target 'delete)
 449               (with-temp-buffer
 450                 (nnfolder-request-article (car maybe-expirable)
 451                                           newsgroup server (current-buffer))
 452                 (let ((nnfolder-current-directory nil))
 453                   (nnmail-expiry-target-group
 454                    nnmail-expiry-target newsgroup)))
 455               (nnfolder-possibly-change-group newsgroup server))
 456             (nnheader-message 5 "Deleting article %d in %s..."
 457                               (car maybe-expirable) newsgroup)
 458             (nnfolder-delete-mail)
 459             (unless (or gnus-nov-is-evil nnfolder-nov-is-evil)
 460               (nnfolder-nov-delete-article newsgroup (car maybe-expirable)))
 461             ;; Must remember which articles were actually deleted
 462             (push (car maybe-expirable) deleted-articles)))
 463         (setq maybe-expirable (cdr maybe-expirable)))
 464       (unless nnfolder-inhibit-expiry
 465         (nnheader-message 5 "Deleting articles...done"))
 466       (nnfolder-save-buffer)
 467       (nnfolder-adjust-min-active newsgroup)
 468       (nnfolder-save-active nnfolder-group-alist nnfolder-active-file)
 469       (gnus-sorted-difference articles (nreverse deleted-articles)))))
 470
 471 (deffoo nnfolder-request-move-article (article group server accept-form
 472                                                &optional last move-is-internal)
 473   (save-excursion
 474     (let ((buf (get-buffer-create " *nnfolder move*"))
 475           result)
 476       (and
 477        (nnfolder-request-article article group server)
 478        (save-excursion
 479          (set-buffer buf)
 480          (erase-buffer)
 481          (insert-buffer-substring nntp-server-buffer)
 482          (goto-char (point-min))
 483          (while (re-search-forward
 484                  (concat "^" nnfolder-article-marker)
 485                  (save-excursion (and (search-forward "\n\n" nil t) (point)))
 486                  t)
 487            (gnus-delete-line))
 488          (setq result (eval accept-form))
 489          (kill-buffer buf)
 490          result)
 491        (save-excursion
 492          (nnfolder-possibly-change-group group server)
 493          (set-buffer nnfolder-current-buffer)
 494          (goto-char (point-min))
 495          (when (nnfolder-goto-article article)
 496            (nnfolder-delete-mail))
 497          (unless (or gnus-nov-is-evil nnfolder-nov-is-evil)
 498            (nnfolder-nov-delete-article group article))
 499          (when last
 500            (nnfolder-save-buffer)
 501            (nnfolder-adjust-min-active group)
 502            (nnfolder-save-active nnfolder-group-alist nnfolder-active-file))))
 503       result)))
 504
 505 (deffoo nnfolder-request-accept-article (group &optional server last)
 506   (save-excursion
 507     (nnfolder-possibly-change-group group server)
 508     (nnmail-check-syntax)
 509     (let ((buf (current-buffer))
 510           result art-group)
 511       (goto-char (point-min))
 512       (when (looking-at "X-From-Line: ")
 513         (replace-match "From ")
 514         (while (progn (forward-line) (looking-at "[ \t]"))
 515           (delete-char -1)))
 516       (with-temp-buffer
 517         (let ((nnmail-file-coding-system nnfolder-active-file-coding-system)
 518               (nntp-server-buffer (current-buffer)))
 519           (nnmail-find-file nnfolder-active-file)
 520           (setq nnfolder-group-alist (nnmail-parse-active))))
 521       (save-excursion
 522         (goto-char (point-min))
 523         (if (search-forward "\n\n" nil t)
 524             (forward-line -1)
 525           (goto-char (point-max)))
 526         (while (re-search-backward (concat "^" nnfolder-article-marker) nil t)
 527           (delete-region (point) (progn (forward-line 1) (point))))
 528         (when nnmail-cache-accepted-message-ids
 529           (nnmail-cache-insert (nnmail-fetch-field "message-id")
 530                                group
 531                                (nnmail-fetch-field "subject")
 532                                (nnmail-fetch-field "from")))
 533         (setq result (if (stringp group)
 534                          (list (cons group (nnfolder-active-number group)))
 535                        (setq art-group
 536                              (nnmail-article-group 'nnfolder-active-number))))
 537         (if (and (null result)
 538                  (yes-or-no-p "Moved to `junk' group; delete article? "))
 539             (setq result 'junk)
 540           (setq result
 541                 (car (nnfolder-save-mail result)))))
 542       (when last
 543         (save-excursion
 544           (nnfolder-possibly-change-folder (or (caar art-group) group))
 545           (nnfolder-save-buffer)
 546           (when nnmail-cache-accepted-message-ids
 547             (nnmail-cache-close))))
 548       (nnfolder-save-active nnfolder-group-alist nnfolder-active-file)
 549       (unless result
 550         (nnheader-report 'nnfolder "Couldn't store article"))
 551       result)))
 552
 553 (deffoo nnfolder-request-replace-article (article group buffer)
 554   (nnfolder-possibly-change-group group)
 555   (save-excursion
 556     (set-buffer buffer)
 557     (goto-char (point-min))
 558     (if (not (looking-at "X-From-Line: "))
 559         (insert "From nobody " (current-time-string) "\n")
 560       (replace-match "From ")
 561       (forward-line 1)
 562       (while (looking-at "[ \t]")
 563         (delete-char -1)
 564         (forward-line 1)))
 565     (nnfolder-normalize-buffer)
 566     (set-buffer nnfolder-current-buffer)
 567     (goto-char (point-min))
 568     (if (not (nnfolder-goto-article article))
 569         nil
 570       (nnfolder-delete-mail)
 571       (insert-buffer-substring buffer)
 572       (unless (or gnus-nov-is-evil nnfolder-nov-is-evil)
 573         (save-excursion
 574           (set-buffer buffer)
 575           (let ((headers (nnfolder-parse-head article
 576                                               (point-min) (point-max))))
 577             (with-current-buffer (nnfolder-open-nov group)
 578               (if (nnheader-find-nov-line article)
 579                   (delete-region (point) (progn (forward-line 1) (point))))
 580               (nnheader-insert-nov headers)))))
 581       (nnfolder-save-buffer)
 582       t)))
 583
 584 (deffoo nnfolder-request-delete-group (group &optional force server)
 585   (nnfolder-close-group group server t)
 586   ;; Delete all articles in GROUP.
 587   (if (not force)
 588       ()                                ; Don't delete the articles.
 589     ;; Delete the file that holds the group.
 590     (let ((data (nnfolder-group-pathname group))
 591           (nov (nnfolder-group-nov-pathname group))
 592           (mrk (nnfolder-group-marks-pathname group)))
 593       (ignore-errors (delete-file data))
 594       (ignore-errors (delete-file nov))
 595       (ignore-errors (delete-file mrk))))
 596   ;; Remove the group from all structures.
 597   (setq nnfolder-group-alist
 598         (delq (assoc group nnfolder-group-alist) nnfolder-group-alist)
 599         nnfolder-current-group nil
 600         nnfolder-current-buffer nil)
 601   ;; Save the active file.
 602   (nnfolder-save-active nnfolder-group-alist nnfolder-active-file)
 603   t)
 604
 605 (deffoo nnfolder-request-rename-group (group new-name &optional server)
 606   (nnfolder-possibly-change-group group server)
 607   (save-excursion
 608     (set-buffer nnfolder-current-buffer)
 609     (and (file-writable-p buffer-file-name)
 610          (ignore-errors
 611            (let ((new-file (nnfolder-group-pathname new-name)))
 612              (gnus-make-directory (file-name-directory new-file))
 613              (rename-file buffer-file-name new-file)
 614              (when (file-exists-p (nnfolder-group-nov-pathname group))
 615                (setq new-file (nnfolder-group-nov-pathname new-name))
 616                (gnus-make-directory (file-name-directory new-file))
 617                (rename-file (nnfolder-group-nov-pathname group) new-file))
 618              (when (file-exists-p (nnfolder-group-marks-pathname group))
 619                (setq new-file (nnfolder-group-marks-pathname new-name))
 620                (gnus-make-directory (file-name-directory new-file))
 621                (rename-file (nnfolder-group-marks-pathname group) new-file)))
 622            t)
 623          ;; That went ok, so we change the internal structures.
 624          (let ((entry (assoc group nnfolder-group-alist)))
 625            (and entry (setcar entry new-name))
 626            (setq nnfolder-current-buffer nil
 627                  nnfolder-current-group nil)
 628            ;; Save the new group alist.
 629            (nnfolder-save-active nnfolder-group-alist nnfolder-active-file)
 630            ;; We kill the buffer instead of renaming it and stuff.
 631            (kill-buffer (current-buffer))
 632            t))))
 633
 634 (deffoo nnfolder-request-regenerate (server)
 635   (nnfolder-possibly-change-group nil server)
 636   (nnfolder-generate-active-file)
 637   t)
 638
 639 \f
 640 ;;; Internal functions.
 641
 642 (defun nnfolder-adjust-min-active (group)
 643   ;; Find the lowest active article in this group.
 644   (let* ((active (cadr (assoc group nnfolder-group-alist)))
 645          (marker (concat "\n" nnfolder-article-marker))
 646          (number "[0-9]+")
 647          (activemin (cdr active)))
 648     (save-excursion
 649       (set-buffer nnfolder-current-buffer)
 650       (goto-char (point-min))
 651       (while (and (search-forward marker nil t)
 652                   (re-search-forward number nil t))
 653         (let ((newnum (string-to-number (match-string 0))))
 654           (if (nnmail-within-headers-p)
 655               (setq activemin (min activemin newnum)))))
 656       (setcar active activemin))))
 657
 658 (defun nnfolder-article-string (article)
 659   (if (numberp article)
 660       (concat "\n" nnfolder-article-marker (int-to-string article) " ")
 661     (concat "\nMessage-ID: " article)))
 662
 663 (defun nnfolder-goto-article (article)
 664   "Place point at the start of the headers of ARTICLE.
 665 ARTICLE can be an article number or a Message-ID.
 666 Returns t if successful, nil otherwise."
 667   (let ((art-string (nnfolder-article-string article))
 668         start found)
 669     ;; It is likely that we are at or before the delimiter line.
 670     ;; We therefore go to the end of the previous line, and start
 671     ;; searching from there.
 672     (beginning-of-line)
 673     (unless (bobp)
 674       (forward-char -1))
 675     (setq start (point))
 676     ;; First search forward.
 677     (while (and (setq found (search-forward art-string nil t))
 678                 (not (nnmail-within-headers-p))))
 67