cgit.sxemacs.org Git - gnus/blob - lisp/mml1991.el

   1 ;;; mml1991.el --- Old PGP message format (RFC 1991) support for MML
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Sascha Lüdecke <sascha@meta-x.de>,
   7 ;;      Simon Josefsson <simon@josefsson.org> (Mailcrypt interface, Gnus glue)
   8 ;; Keywords PGP
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (eval-when-compile
  32   (require 'cl)
  33   (require 'mm-util))
  34
  35 (require 'mml-sec)
  36
  37 (defvar mc-pgp-always-sign)
  38
  39 (autoload 'quoted-printable-decode-region "qp")
  40 (autoload 'quoted-printable-encode-region "qp")
  41
  42 (defvar mml1991-use mml2015-use
  43   "The package used for PGP.")
  44
  45 (defvar mml1991-function-alist
  46   '((mailcrypt mml1991-mailcrypt-sign
  47                mml1991-mailcrypt-encrypt)
  48     (gpg mml1991-gpg-sign
  49          mml1991-gpg-encrypt)
  50     (pgg mml1991-pgg-sign
  51          mml1991-pgg-encrypt)
  52     (epg mml1991-epg-sign
  53          mml1991-epg-encrypt))
  54   "Alist of PGP functions.")
  55
  56 (defvar mml1991-verbose mml-secure-verbose
  57   "If non-nil, ask the user about the current operation more verbosely.")
  58
  59 (defvar mml1991-cache-passphrase mml-secure-cache-passphrase
  60   "If t, cache passphrase.")
  61
  62 (defvar mml1991-passphrase-cache-expiry mml-secure-passphrase-cache-expiry
  63   "How many seconds the passphrase is cached.
  64 Whether the passphrase is cached at all is controlled by
  65 `mml1991-cache-passphrase'.")
  66
  67 (defvar mml1991-signers nil
  68   "A list of key ID which will be used to sign a message.")
  69
  70 ;;; mailcrypt wrapper
  71
  72 (eval-and-compile
  73   (autoload 'mc-sign-generic "mc-toplev"))
  74
  75 (defvar mml1991-decrypt-function 'mailcrypt-decrypt)
  76 (defvar mml1991-verify-function 'mailcrypt-verify)
  77
  78 (defun mml1991-mailcrypt-sign (cont)
  79   (let ((text (current-buffer))
  80         headers signature
  81         (result-buffer (get-buffer-create "*GPG Result*")))
  82     ;; Save MIME Content[^ ]+: headers from signing
  83     (goto-char (point-min))
  84     (while (looking-at "^Content[^ ]+:") (forward-line))
  85     (unless (bobp)
  86       (setq headers (buffer-string))
  87       (delete-region (point-min) (point)))
  88     (goto-char (point-max))
  89     (unless (bolp)
  90       (insert "\n"))
  91     (quoted-printable-decode-region (point-min) (point-max))
  92     (with-temp-buffer
  93       (setq signature (current-buffer))
  94       (insert-buffer-substring text)
  95       (unless (mc-sign-generic (message-options-get 'message-sender)
  96                                nil nil nil nil)
  97         (unless (> (point-max) (point-min))
  98           (pop-to-buffer result-buffer)
  99           (error "Sign error")))
 100       (goto-char (point-min))
 101       (while (re-search-forward "\r+$" nil t)
 102         (replace-match "" t t))
 103       (quoted-printable-encode-region (point-min) (point-max))
 104       (set-buffer text)
 105       (delete-region (point-min) (point-max))
 106       (if headers (insert headers))
 107       (insert "\n")
 108       (insert-buffer-substring signature)
 109       (goto-char (point-max)))))
 110
 111 (defun mml1991-mailcrypt-encrypt (cont &optional sign)
 112   (let ((text (current-buffer))
 113         (mc-pgp-always-sign
 114          (or mc-pgp-always-sign
 115              sign
 116              (eq t (or (message-options-get 'message-sign-encrypt)
 117                        (message-options-set
 118                         'message-sign-encrypt
 119                         (or (y-or-n-p "Sign the message? ")
 120                             'not))))
 121              'never))
 122         cipher
 123         (result-buffer (get-buffer-create "*GPG Result*")))
 124     ;; Strip MIME Content[^ ]: headers since it will be ASCII ARMOURED
 125     (goto-char (point-min))
 126     (while (looking-at "^Content[^ ]+:") (forward-line))
 127     (unless (bobp)
 128       (delete-region (point-min) (point)))
 129     (mm-with-unibyte-current-buffer
 130       (with-temp-buffer
 131         (setq cipher (current-buffer))
 132         (insert-buffer-substring text)
 133         (unless (mc-encrypt-generic
 134                  (or
 135                   (message-options-get 'message-recipients)
 136                   (message-options-set 'message-recipients
 137                                        (read-string "Recipients: ")))
 138                  nil
 139                  (point-min) (point-max)
 140                  (message-options-get 'message-sender)
 141                  'sign)
 142           (unless (> (point-max) (point-min))
 143             (pop-to-buffer result-buffer)
 144             (error "Encrypt error")))
 145         (goto-char (point-min))
 146         (while (re-search-forward "\r+$" nil t)
 147           (replace-match "" t t))
 148         (set-buffer text)
 149         (delete-region (point-min) (point-max))
 150         ;;(insert "Content-Type: application/pgp-encrypted\n\n")
 151         ;;(insert "Version: 1\n\n")
 152         (insert "\n")
 153         (insert-buffer-substring cipher)
 154         (goto-char (point-max))))))
 155
 156 ;;; gpg wrapper
 157
 158 (eval-and-compile
 159   (autoload 'gpg-sign-cleartext "gpg"))
 160
 161 (defun mml1991-gpg-sign (cont)
 162   (let ((text (current-buffer))
 163         headers signature
 164         (result-buffer (get-buffer-create "*GPG Result*")))
 165     ;; Save MIME Content[^ ]+: headers from signing
 166     (goto-char (point-min))
 167     (while (looking-at "^Content[^ ]+:") (forward-line))
 168     (unless (bobp)
 169       (setq headers (buffer-string))
 170       (delete-region (point-min) (point)))
 171     (goto-char (point-max))
 172     (unless (bolp)
 173       (insert "\n"))
 174     (quoted-printable-decode-region (point-min) (point-max))
 175     (with-temp-buffer
 176       (unless (gpg-sign-cleartext text (setq signature (current-buffer))
 177                                   result-buffer
 178                                   nil
 179                                   (message-options-get 'message-sender))
 180         (unless (> (point-max) (point-min))
 181           (pop-to-buffer result-buffer)
 182           (error "Sign error")))
 183       (goto-char (point-min))
 184       (while (re-search-forward "\r+$" nil t)
 185         (replace-match "" t t))
 186       (quoted-printable-encode-region (point-min) (point-max))
 187       (set-buffer text)
 188       (delete-region (point-min) (point-max))
 189       (if headers (insert headers))
 190       (insert "\n")
 191       (insert-buffer-substring signature)
 192       (goto-char (point-max)))))
 193
 194 (defun mml1991-gpg-encrypt (cont &optional sign)
 195   (let ((text (current-buffer))
 196         cipher
 197         (result-buffer (get-buffer-create "*GPG Result*")))
 198     ;; Strip MIME Content[^ ]: headers since it will be ASCII ARMOURED
 199     (goto-char (point-min))
 200     (while (looking-at "^Content[^ ]+:") (forward-line))
 201     (unless (bobp)
 202       (delete-region (point-min) (point)))
 203     (mm-with-unibyte-current-buffer
 204       (with-temp-buffer
 205         (flet ((gpg-encrypt-func
 206                 (sign plaintext ciphertext result recipients &optional
 207                       passphrase sign-with-key armor textmode)
 208                 (if sign
 209                     (gpg-sign-encrypt
 210                      plaintext ciphertext result recipients passphrase
 211                      sign-with-key armor textmode)
 212                   (gpg-encrypt
 213                    plaintext ciphertext result recipients passphrase
 214                    armor textmode))))
 215           (unless (gpg-encrypt-func
 216                    sign
 217                    text (setq cipher (current-buffer))
 218                    result-buffer
 219                    (split-string
 220                     (or
 221                      (message-options-get 'message-recipients)
 222                      (message-options-set 'message-recipients
 223                                           (read-string "Recipients: ")))
 224                     "[ \f\t\n\r\v,]+")
 225                    nil
 226                    (message-options-get 'message-sender)
 227                    t t) ; armor & textmode
 228             (unless (> (point-max) (point-min))
 229               (pop-to-buffer result-buffer)
 230               (error "Encrypt error"))))
 231         (goto-char (point-min))
 232         (while (re-search-forward "\r+$" nil t)
 233           (replace-match "" t t))
 234         (set-buffer text)
 235         (delete-region (point-min) (point-max))
 236         ;;(insert "Content-Type: application/pgp-encrypted\n\n")
 237         ;;(insert "Version: 1\n\n")
 238         (insert "\n")
 239         (insert-buffer-substring cipher)
 240         (goto-char (point-max))))))
 241
 242 ;; pgg wrapper
 243
 244 (eval-when-compile
 245   (defvar pgg-default-user-id)
 246   (defvar pgg-errors-buffer)
 247   (defvar pgg-output-buffer))
 248
 249 (defun mml1991-pgg-sign (cont)
 250   (let ((pgg-text-mode t)
 251         (pgg-default-user-id (or (message-options-get 'mml-sender)
 252                                  pgg-default-user-id))
 253         headers cte)
 254     ;; Don't sign headers.
 255     (goto-char (point-min))
 256     (when (re-search-forward "^$" nil t)
 257       (setq headers (buffer-substring (point-min) (point)))
 258       (save-restriction
 259         (narrow-to-region (point-min) (point))
 260         (setq cte (mail-fetch-field "content-transfer-encoding")))
 261       (forward-line 1)
 262       (delete-region (point-min) (point))
 263       (when cte
 264         (setq cte (intern (downcase cte)))
 265         (mm-decode-content-transfer-encoding cte)))
 266     (unless (pgg-sign-region (point-min) (point-max) t)
 267       (pop-to-buffer pgg-errors-buffer)
 268       (error "Encrypt error"))
 269     (delete-region (point-min) (point-max))
 270     (mm-with-unibyte-current-buffer
 271       (insert-buffer-substring pgg-output-buffer)
 272       (goto-char (point-min))
 273       (while (re-search-forward "\r+$" nil t)
 274         (replace-match "" t t))
 275       (when cte
 276         (mm-encode-content-transfer-encoding cte))
 277       (goto-char (point-min))
 278       (when headers
 279         (insert headers))
 280       (insert "\n"))
 281     t))
 282
 283 (defun mml1991-pgg-encrypt (cont &optional sign)
 284   (goto-char (point-min))
 285   (when (re-search-forward "^$" nil t)
 286     (let ((cte (save-restriction
 287                  (narrow-to-region (point-min) (point))
 288                  (mail-fetch-field "content-transfer-encoding"))))
 289       ;; Strip MIME headers since it will be ASCII armoured.
 290       (forward-line 1)
 291       (delete-region (point-min) (point))
 292       (when cte
 293         (mm-decode-content-transfer-encoding (intern (downcase cte))))))
 294   (unless (let ((pgg-text-mode t))
 295             (pgg-encrypt-region
 296              (point-min) (point-max)
 297              (split-string
 298               (or
 299                (message-options-get 'message-recipients)
 300                (message-options-set 'message-recipients
 301                                     (read-string "Recipients: ")))
 302               "[ \f\t\n\r\v,]+")
 303              sign))
 304     (pop-to-buffer pgg-errors-buffer)
 305     (error "Encrypt error"))
 306   (delete-region (point-min) (point-max))
 307   (insert "\n")
 308   (insert-buffer-substring pgg-output-buffer)
 309   t)
 310
 311 ;; epg wrapper
 312
 313 (eval-and-compile
 314   (autoload 'epg-make-context "epg"))
 315
 316 (eval-when-compile
 317   (defvar epg-user-id-alist)
 318   (autoload 'epg-passphrase-callback-function "epg")
 319   (autoload 'epa-select-keys "epa")
 320   (autoload 'epg-list-keys "epg")
 321   (autoload 'epg-context-set-armor "epg")
 322   (autoload 'epg-context-set-textmode "epg")
 323   (autoload 'epg-context-set-signers "epg")
 324   (autoload 'epg-context-set-passphrase-callback "epg")
 325   (autoload 'epg-sign-string "epg")
 326   (autoload 'epg-encrypt-string "epg"))
 327
 328 (eval-when-compile
 329   (defvar password-cache-expiry)
 330   (autoload 'password-read "password")
 331   (autoload 'password-cache-add "password")
 332   (autoload 'password-cache-remove "password"))
 333
 334 (defvar mml1991-epg-secret-key-id-list nil)
 335
 336 (defun mml1991-epg-passphrase-callback (context key-id ignore)
 337   (if (eq key-id 'SYM)
 338       (epg-passphrase-callback-function context key-id nil)
 339     (let* ((entry (assoc key-id epg-user-id-alist))
 340            (passphrase
 341             (password-read
 342              (format "GnuPG passphrase for %s: "
 343                      (if entry
 344                          (cdr entry)
 345                        key-id))
 346              (if (eq key-id 'PIN)
 347                  "PIN"
 348                key-id))))
 349       (when passphrase
 350         (let ((password-cache-expiry mml1991-passphrase-cache-expiry))
 351           (password-cache-add key-id passphrase))
 352         (setq mml1991-epg-secret-key-id-list
 353               (cons key-id mml1991-epg-secret-key-id-list))
 354         (copy-sequence passphrase)))))
 355
 356 (defun mml1991-epg-sign (cont)
 357   (let ((context (epg-make-context))
 358         headers cte signers signature)
 359     (if mml1991-verbose
 360         (setq signers (epa-select-keys context "Select keys for signing.
 361 If no one is selected, default secret key is used.  "
 362                                        mml1991-signers t))
 363       (setq signers (mapcar (lambda (name)
 364                               (car (epg-list-keys context name t)))
 365                             (or mml1991-signers
 366                                 (list (message-options-get 'mml-sender))))))
 367     (epg-context-set-armor context t)
 368     (epg-context-set-textmode context t)
 369     (epg-context-set-signers context signers)
 370     (if mml1991-cache-passphrase
 371         (epg-context-set-passphrase-callback
 372          context
 373          #'mml1991-epg-passphrase-callback))
 374     ;; Don't sign headers.
 375     (goto-char (point-min))
 376     (when (re-search-forward "^$" nil t)
 377       (setq headers (buffer-substring (point-min) (point)))
 378       (save-restriction
 379         (narrow-to-region (point-min) (point))
 380         (setq cte (mail-fetch-field "content-transfer-encoding")))
 381       (forward-line 1)
 382       (delete-region (point-min) (point))
 383       (when cte
 384         (setq cte (intern (downcase cte)))
 385         (mm-decode-content-transfer-encoding cte)))
 386     (condition-case error
 387         (setq signature (epg-sign-string context (buffer-string) 'clear)
 388               mml1991-epg-secret-key-id-list nil)
 389       (error
 390        (while mml1991-epg-secret-key-id-list
 391          (password-cache-remove (car mml1991-epg-secret-key-id-list))
 392          (setq mml1991-epg-secret-key-id-list
 393                (cdr mml1991-epg-secret-key-id-list)))
 394        (signal (car error) (cdr error))))
 395     (delete-region (point-min) (point-max))
 396     (mm-with-unibyte-current-buffer
 397       (insert signature)
 398       (goto-char (point-min))
 399       (while (re-search-forward "\r+$" nil t)
 400         (replace-match "" t t))
 401       (when cte
 402         (mm-encode-content-transfer-encoding cte))
 403       (goto-char (point-min))
 404       (when headers
 405         (insert headers))
 406       (insert "\n"))
 407     t))
 408
 409 (defun mml1991-epg-encrypt (cont &optional sign)
 410   (goto-char (point-min))
 411   (when (re-search-forward "^$" nil t)
 412     (let ((cte (save-restriction
 413                  (narrow-to-region (point-min) (point))
 414                  (mail-fetch-field "content-transfer-encoding"))))
 415       ;; Strip MIME headers since it will be ASCII armoured.
 416       (forward-line 1)
 417       (delete-region (point-min) (point))
 418       (when cte
 419         (mm-decode-content-transfer-encoding (intern (downcase cte))))))
 420   (let ((context (epg-make-context))
 421         recipients cipher signers)
 422     (if (or mml1991-verbose
 423             (null (message-options-get 'message-recipients)))
 424         (setq recipients
 425               (epa-select-keys context "Select recipients for encryption.
 426 If no one is selected, symmetric encryption will be performed.  "
 427                                (if (message-options-get 'message-recipients)
 428                                    (split-string
 429                                     (message-options-get 'message-recipients)
 430                                     "[ \f\t\n\r\v,]+"))))
 431       (setq recipients
 432             (mapcar (lambda (name)
 433                       (car (epg-list-keys context name)))
 434                     (split-string
 435                      (message-options-get 'message-recipients)
 436                      "[ \f\t\n\r\v,]+"))))
 437     (when sign
 438       (if mml1991-verbose
 439           (setq signers (epa-select-keys context "Select keys for signing.
 440 If no one is selected, default secret key is used.  "
 441                                          mml1991-signers t))
 442         (setq signers (mapcar (lambda (name)
 443                                 (car (epg-list-keys context name t)))
 444                               (or mml1991-signers
 445                                   (list (message-options-get 'mml-sender))))))
 446       (epg-context-set-signers context signers))
 447     (epg-context-set-armor context t)
 448     (epg-context-set-textmode context t)
 449     (if mml1991-cache-passphrase
 450         (epg-context-set-passphrase-callback
 451          context
 452          #'mml1991-epg-passphrase-callback))
 453     (condition-case error
 454         (setq cipher
 455               (epg-encrypt-string context (buffer-string) recipients sign)
 456               mml1991-epg-secret-key-id-list nil)
 457       (error
 458        (while mml1991-epg-secret-key-id-list
 459          (password-cache-remove (car mml1991-epg-secret-key-id-list))
 460          (setq mml1991-epg-secret-key-id-list
 461                (cdr mml1991-epg-secret-key-id-list)))
 462        (signal (car error) (cdr error))))
 463     (delete-region (point-min) (point-max))
 464     (insert "\n" cipher))
 465   t)
 466
 467 ;;;###autoload
 468 (defun mml1991-encrypt (cont &optional sign)
 469   (let ((func (nth 2 (assq mml1991-use mml1991-function-alist))))
 470     (if func
 471         (funcall func cont sign)
 472       (error "Cannot find encrypt function"))))
 473
 474 ;;;###autoload
 475 (defun mml1991-sign (cont)
 476   (let ((func (nth 1 (assq mml1991-use mml1991-function-alist))))
 477     (if func
 478         (funcall func cont)
 479       (error "Cannot find sign function"))))
 480
 481 (provide 'mml1991)
 482
 483 ;; Local Variables:
 484 ;; coding: iso-8859-1
 485 ;; End:
 486
 487 ;;; arch-tag: e542be18-ab28-4393-9b33-97fe9cf30706
 488 ;;; mml1991.el ends here