cgit.sxemacs.org Git - gnus/blob - lisp/mml.el

   1 ;;; mml.el --- A package for parsing and validating MML documents
   2 ;; Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (require 'mm-util)
  27 (require 'mm-bodies)
  28 (require 'mm-encode)
  29 (require 'mm-decode)
  30 (require 'mml-sec)
  31 (eval-when-compile (require 'cl))
  32
  33 (eval-and-compile
  34   (autoload 'message-make-message-id "message")
  35   (autoload 'gnus-setup-posting-charset "gnus-msg")
  36   (autoload 'message-fetch-field "message")
  37   (autoload 'message-posting-charset "message"))
  38
  39 (defvar mml-generate-multipart-alist nil
  40   "*Alist of multipart generation functions.
  41 Each entry has the form (NAME . FUNCTION), where
  42 NAME is a string containing the name of the part (without the
  43 leading \"/multipart/\"),
  44 FUNCTION is a Lisp function which is called to generate the part.
  45
  46 The Lisp function has to supply the appropriate MIME headers and the
  47 contents of this part.")
  48
  49 (defvar mml-syntax-table
  50   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
  51     (modify-syntax-entry ?\\ "/" table)
  52     (modify-syntax-entry ?< "(" table)
  53     (modify-syntax-entry ?> ")" table)
  54     (modify-syntax-entry ?@ "w" table)
  55     (modify-syntax-entry ?/ "w" table)
  56     (modify-syntax-entry ?= " " table)
  57     (modify-syntax-entry ?* " " table)
  58     (modify-syntax-entry ?\; " " table)
  59     (modify-syntax-entry ?\' " " table)
  60     table))
  61
  62 (defvar mml-boundary-function 'mml-make-boundary
  63   "A function called to suggest a boundary.
  64 The function may be called several times, and should try to make a new
  65 suggestion each time.  The function is called with one parameter,
  66 which is a number that says how many times the function has been
  67 called for this message.")
  68
  69 (defvar mml-confirmation-set nil
  70   "A list of symbols, each of which disables some warning.
  71 `unknown-encoding': always send messages contain characters with
  72 unknown encoding; `use-ascii': always use ASCII for those characters
  73 with unknown encoding; `multipart': always send messages with more than
  74 one charsets.")
  75
  76 (defvar mml-generate-default-type "text/plain")
  77
  78 (defvar mml-buffer-list nil)
  79
  80 (defun mml-generate-new-buffer (name)
  81   (let ((buf (generate-new-buffer name)))
  82     (push buf mml-buffer-list)
  83     buf))
  84
  85 (defun mml-destroy-buffers ()
  86   (let (kill-buffer-hook)
  87     (mapcar 'kill-buffer mml-buffer-list)
  88     (setq mml-buffer-list nil)))
  89
  90 (defun mml-parse ()
  91   "Parse the current buffer as an MML document."
  92   (goto-char (point-min))
  93   (let ((table (syntax-table)))
  94     (unwind-protect
  95         (progn
  96           (set-syntax-table mml-syntax-table)
  97           (mml-parse-1))
  98       (set-syntax-table table))))
  99
 100 (defun mml-parse-1 ()
 101   "Parse the current buffer as an MML document."
 102   (let (struct tag point contents charsets warn use-ascii no-markup-p raw)
 103     (while (and (not (eobp))
 104                 (not (looking-at "<#/multipart")))
 105       (cond
 106        ((looking-at "<#multipart")
 107         (push (nconc (mml-read-tag) (mml-parse-1)) struct))
 108        ((looking-at "<#external")
 109         (push (nconc (mml-read-tag) (list (cons 'contents (mml-read-part))))
 110               struct))
 111        (t
 112         (if (or (looking-at "<#part") (looking-at "<#mml"))
 113             (setq tag (mml-read-tag)
 114                   no-markup-p nil
 115                   warn nil)
 116           (setq tag (list 'part '(type . "text/plain"))
 117                 no-markup-p t
 118                 warn t))
 119         (setq raw (cdr (assq 'raw tag))
 120               point (point)
 121               contents (mml-read-part (eq 'mml (car tag)))
 122               charsets (if raw nil
 123                          (mm-find-mime-charset-region point (point))))
 124         (when (and (not raw) (memq nil charsets))
 125           (if (or (memq 'unknown-encoding mml-confirmation-set)
 126                   (y-or-n-p
 127                    "Message contains characters with unknown encoding.  Really send?"))
 128               (if (setq use-ascii
 129                         (or (memq 'use-ascii mml-confirmation-set)
 130                             (y-or-n-p "Use ASCII as charset?")))
 131                   (setq charsets (delq nil charsets))
 132                 (setq warn nil))
 133             (error "Edit your message to remove those characters")))
 134         (if (or raw
 135                 (eq 'mml (car tag))
 136                 (< (length charsets) 2))
 137             (if (or (not no-markup-p)
 138                     (string-match "[^ \t\r\n]" contents))
 139                 ;; Don't create blank parts.
 140                 (push (nconc tag (list (cons 'contents contents)))
 141                       struct))
 142           (let ((nstruct (mml-parse-singlepart-with-multiple-charsets
 143                           tag point (point) use-ascii)))
 144             (when (and warn
 145                        (not (memq 'multipart mml-confirmation-set))
 146                        (not
 147                         (y-or-n-p
 148                          (format
 149                           "Warning: Your message contains more than %d parts.  Really send? "
 150                           (length nstruct)))))
 151               (error "Edit your message to use only one charset"))
 152             (setq struct (nconc nstruct struct)))))))
 153     (unless (eobp)
 154       (forward-line 1))
 155     (nreverse struct)))
 156
 157 (defun mml-parse-singlepart-with-multiple-charsets
 158   (orig-tag beg end &optional use-ascii)
 159   (save-excursion
 160     (save-restriction
 161       (narrow-to-region beg end)
 162       (goto-char (point-min))
 163       (let ((current (or (mm-mime-charset (mm-charset-after))
 164                          (and use-ascii 'us-ascii)))
 165             charset struct space newline paragraph)
 166         (while (not (eobp))
 167           (setq charset (mm-mime-charset (mm-charset-after)))
 168           (cond
 169            ;; The charset remains the same.
 170            ((eq charset 'us-ascii))
 171            ((or (and use-ascii (not charset))
 172                 (eq charset current))
 173             (setq space nil
 174                   newline nil
 175                   paragraph nil))
 176            ;; The initial charset was ascii.
 177            ((eq current 'us-ascii)
 178             (setq current charset
 179                   space nil
 180                   newline nil
 181                   paragraph nil))
 182            ;; We have a change in charsets.
 183            (t
 184             (push (append
 185                    orig-tag
 186                    (list (cons 'contents
 187                                (buffer-substring-no-properties
 188                                 beg (or paragraph newline space (point))))))
 189                   struct)
 190             (setq beg (or paragraph newline space (point))
 191                   current charset
 192                   space nil
 193                   newline nil
 194                   paragraph nil)))
 195           ;; Compute places where it might be nice to break the part.
 196           (cond
 197            ((memq (following-char) '(?  ?\t))
 198             (setq space (1+ (point))))
 199            ((and (eq (following-char) ?\n)
 200                  (not (bobp))
 201                  (eq (char-after (1- (point))) ?\n))
 202             (setq paragraph (point)))
 203            ((eq (following-char) ?\n)
 204             (setq newline (1+ (point)))))
 205           (forward-char 1))
 206         ;; Do the final part.
 207         (unless (= beg (point))
 208           (push (append orig-tag
 209                         (list (cons 'contents
 210                                     (buffer-substring-no-properties
 211                                      beg (point)))))
 212                 struct))
 213         struct))))
 214
 215 (defun mml-read-tag ()
 216   "Read a tag and return the contents."
 217   (let (contents name elem val)
 218     (forward-char 2)
 219     (setq name (buffer-substring-no-properties
 220                 (point) (progn (forward-sexp 1) (point))))
 221     (skip-chars-forward " \t\n")
 222     (while (not (looking-at ">[ \t]*\n?"))
 223       (setq elem (buffer-substring-no-properties
 224                   (point) (progn (forward-sexp 1) (point))))
 225       (skip-chars-forward "= \t\n")
 226       (setq val (buffer-substring-no-properties
 227                  (point) (progn (forward-sexp 1) (point))))
 228       (when (string-match "^\"\\(.*\\)\"$" val)
 229         (setq val (match-string 1 val)))
 230       (push (cons (intern elem) val) contents)
 231       (skip-chars-forward " \t\n"))
 232     (goto-char (match-end 0))
 233     ;; Don't skip the leading space.
 234     ;;(skip-chars-forward " \t\n")
 235     (cons (intern name) (nreverse contents))))
 236
 237 (defun mml-read-part (&optional mml)
 238   "Return the buffer up till the next part, multipart or closing part or multipart.
 239 If MML is non-nil, return the buffer up till the correspondent mml tag."
 240   (let ((beg (point)) (count 1))
 241     ;; If the tag ended at the end of the line, we go to the next line.
 242     (when (looking-at "[ \t]*\n")
 243       (forward-line 1))
 244     (if mml
 245         (progn
 246           (while (and (> count 0) (not (eobp)))
 247             (if (re-search-forward "<#\\(/\\)?mml." nil t)
 248                 (setq count (+ count (if (match-beginning 1) -1 1)))
 249               (goto-char (point-max))))
 250           (buffer-substring-no-properties beg (if (> count 0)
 251                                                   (point)
 252                                                 (match-beginning 0))))
 253       (if (re-search-forward
 254            "<#\\(/\\)?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 255           (prog1
 256               (buffer-substring-no-properties beg (match-beginning 0))
 257             (if (or (not (match-beginning 1))
 258                     (equal (match-string 2) "multipart"))
 259                 (goto-char (match-beginning 0))
 260               (when (looking-at "[ \t]*\n")
 261                 (forward-line 1))))
 262         (buffer-substring-no-properties beg (goto-char (point-max)))))))
 263
 264 (defvar mml-boundary nil)
 265 (defvar mml-base-boundary "-=-=")
 266 (defvar mml-multipart-number 0)
 267
 268 (defun mml-generate-mime ()
 269   "Generate a MIME message based on the current MML document."
 270   (let ((cont (mml-parse))
 271         (mml-multipart-number mml-multipart-number))
 272     (if (not cont)
 273         nil
 274       (with-temp-buffer
 275         (if (and (consp (car cont))
 276                  (= (length cont) 1))
 277             (mml-generate-mime-1 (car cont))
 278           (mml-generate-mime-1 (nconc (list 'multipart '(type . "mixed"))
 279                                       cont)))
 280         (buffer-string)))))
 281
 282 (defun mml-generate-mime-1 (cont)
 283   (let ((mm-use-ultra-safe-encoding
 284          (or mm-use-ultra-safe-encoding (assq 'sign cont))))
 285     (save-restriction
 286       (narrow-to-region (point) (point))
 287       (cond
 288        ((or (eq (car cont) 'part) (eq (car cont) 'mml))
 289         (let ((raw (cdr (assq 'raw cont)))
 290               coded encoding charset filename type)
 291           (setq type (or (cdr (assq 'type cont)) "text/plain"))
 292           (if (and (not raw)
 293                    (member (car (split-string type "/")) '("text" "message")))
 294               (with-temp-buffer
 295                 (setq charset (mm-charset-to-coding-system
 296                                (cdr (assq 'charset cont))))
 297                 (cond
 298                  ((cdr (assq 'buffer cont))
 299                   (insert-buffer-substring (cdr (assq 'buffer cont))))
 300                  ((and (setq filename (cdr (assq 'filename cont)))
 301                        (not (equal (cdr (assq 'nofile cont)) "yes")))
 302                   (let ((coding-system-for-read charset))
 303                     (mm-insert-file-contents filename)))
 304                  ((eq 'mml (car cont))
 305                   (insert (cdr (assq 'contents cont))))
 306                  (t
 307                   (save-restriction
 308                     (narrow-to-region (point) (point))
 309                     (insert (cdr (assq 'contents cont)))
 310                     ;; Remove quotes from quoted tags.
 311                     (goto-char (point-min))
 312                     (while (re-search-forward
 313                             "<#!+/?\\(part\\|multipart\\|external\\|mml\\)" nil t)
 314                       (delete-region (+ (match-beginning 0) 2)
 315                                      (+ (match-beginning 0) 3))))))
 316                 (cond
 317                  ((eq (car cont) 'mml)
 318                   (let ((mml-boundary (funcall mml-boundary-function
 319                                                (incf mml-multipart-number)))
 320                         (mml-generate-default-type "text/plain"))
 321                     (mml-to-mime))
 322                   (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 323                     ;; ignore 0x1b, it is part of iso-2022-jp
 324                     (setq encoding (mm-body-7-or-8))))
 325                  ((string= (car (split-string type "/")) "message")
 326                   (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 327                     ;; ignore 0x1b, it is part of iso-2022-jp
 328                     (setq encoding (mm-body-7-or-8))))
 329                  (t
 330                   (setq charset (mm-encode-body charset))
 331                   (setq encoding (mm-body-encoding
 332                                   charset (cdr (assq 'encoding cont))))))
 333                 (setq coded (buffer-string)))
 334             (mm-with-unibyte-buffer
 335               (cond
 336                ((cdr (assq 'buffer cont))
 337                 (insert-buffer-substring (cdr (assq 'buffer cont))))
 338                ((and (setq filename (cdr (assq 'filename cont)))
 339                      (not (equal (cdr (assq 'nofile cont)) "yes")))
 340                 (let ((coding-system-for-read mm-binary-coding-system))
 341                   (mm-insert-file-contents filename nil nil nil nil t)))
 342                (t
 343                 (insert (cdr (assq 'contents cont)))))
 344               (setq encoding (mm-encode-buffer type)
 345                     coded (buffer-string))))
 346           (mml-insert-mime-headers cont type charset encoding)
 347           (insert "\n")
 348           (insert coded)))
 349        ((eq (car cont) 'external)
 350         (insert "Content-Type: message/external-body")
 351         (let ((parameters (mml-parameter-string
 352                            cont '(expiration size permission)))
 353               (name (cdr (assq 'name cont)))
 354               (url (cdr (assq 'url cont))))
 355           (when name
 356             (setq name (mml-parse-file-name name))
 357             (if (stringp name)
 358                 (mml-insert-parameter
 359                  (mail-header-encode-parameter "name" name)
 360                  "access-type=local-file")
 361               (mml-insert-parameter
 362                (mail-header-encode-parameter
 363                 "name" (file-name-nondirectory (nth 2 name)))
 364                (mail-header-encode-parameter "site" (nth 1 name))
 365                (mail-header-encode-parameter
 366                 "directory" (file-name-directory (nth 2 name))))
 367               (mml-insert-parameter
 368                (concat "access-type="
 369                        (if (member (nth 0 name) '("ftp@" "anonymous@"))
 370                            "anon-ftp"
 371                          "ftp")))))
 372           (when url
 373             (mml-insert-parameter
 374              (mail-header-encode-parameter "url" url)
 375              "access-type=url"))
 376           (when parameters
 377             (mml-insert-parameter-string
 378              cont '(expiration size permission))))
 379         (insert "\n\n")
 380         (insert "Content-Type: " (cdr (assq 'type cont)) "\n")
 381         (insert "Content-ID: " (message-make-message-id) "\n")
 382         (insert "Content-Transfer-Encoding: "
 383                 (or (cdr (assq 'encoding cont)) "binary"))
 384         (insert "\n\n")
 385         (insert (or (cdr (assq 'contents cont))))
 386         (insert "\n"))
 387        ((eq (car cont) 'multipart)
 388         (let* ((type (or (cdr (assq 'type cont)) "mixed"))
 389                (mml-generate-default-type (if (equal type "digest")
 390                                               "message/rfc822"
 391                                             "text/plain"))
 392                (handler (assoc type mml-generate-multipart-alist)))
 393           (if handler
 394               (funcall (cdr handler) cont)
 395             ;; No specific handler.  Use default one.
 396             (let ((mml-boundary (mml-compute-boundary cont)))
 397               (insert (format "Content-Type: multipart/%s; boundary=\"%s\"\n"
 398                               type mml-boundary))
 399               ;; Skip `multipart' and `type' elements.
 400               (setq cont (cddr cont))
 401               (while cont
 402                 (insert "\n--" mml-boundary "\n")
 403                 (mml-generate-mime-1 (pop cont)))
 404               (insert "\n--" mml-boundary "--\n")))))
 405        (t
 406         (error "Invalid element: %S" cont)))
 407       (let ((item (assoc (cdr (assq 'sign cont)) mml-sign-alist))
 408             sender recipients)
 409         (when item
 410           (if (setq sender (cdr (assq 'sender cont)))
 411               (message-options-set 'message-sender sender))
 412           (if (setq recipients (cdr (assq 'recipients cont)))
 413               (message-options-set 'message-sender recipients))
 414           (funcall (nth 1 item) cont)))
 415       (let ((item (assoc (cdr (assq 'encrypt cont)) mml-encrypt-alist))
 416             sender recipients)
 417         (when item
 418           (if (setq sender (cdr (assq 'sender cont)))
 419               (message-options-set 'message-sender sender))
 420           (if (setq recipients (cdr (assq 'recipients cont)))
 421               (message-options-set 'message-sender recipients))
 422           (funcall (nth 1 item) cont))))))
 423
 424 (defun mml-compute-boundary (cont)
 425   "Return a unique boundary that does not exist in CONT."
 426   (let ((mml-boundary (funcall mml-boundary-function
 427                                (incf mml-multipart-number))))
 428     ;; This function tries again and again until it has found
 429     ;; a unique boundary.
 430     (while (not (catch 'not-unique
 431                   (mml-compute-boundary-1 cont))))
 432     mml-boundary))
 433
 434 (defun mml-compute-boundary-1 (cont)
 435   (let (filename)
 436     (cond
 437      ((eq (car cont) 'part)
 438       (with-temp-buffer
 439         (cond
 440          ((cdr (assq 'buffer cont))
 441           (insert-buffer-substring (cdr (assq 'buffer cont))))
 442          ((and (setq filename (cdr (assq 'filename cont)))
 443                (not (equal (cdr (assq 'nofile cont)) "yes")))
 444           (mm-insert-file-contents filename))
 445          (t
 446           (insert (cdr (assq 'contents cont)))))
 447         (goto-char (point-min))
 448         (when (re-search-forward (concat "^--" (regexp-quote mml-boundary))
 449                                  nil t)
 450           (setq mml-boundary (funcall mml-boundary-function
 451                                       (incf mml-multipart-number)))
 452           (throw 'not-unique nil))))
 453      ((eq (car cont) 'multipart)
 454       (mapcar 'mml-compute-boundary-1 (cddr cont))))
 455     t))
 456
 457 (defun mml-make-boundary (number)
 458   (concat (make-string (% number 60) ?=)
 459           (if (> number 17)
 460               (format "%x" number)
 461             "")
 462           mml-base-boundary))
 463
 464 (defun mml-insert-mime-headers (cont type charset encoding)
 465   (let (parameters disposition description)
 466     (setq parameters
 467           (mml-parameter-string
 468            cont '(name access-type expiration size permission)))
 469     (when (or charset
 470               parameters
 471               (not (equal type mml-generate-default-type)))
 472       (when (consp charset)
 473         (error
 474          "Can't encode a part with several charsets."))
 475       (insert "Content-Type: " type)
 476       (when charset
 477         (insert "; " (mail-header-encode-parameter
 478                       "charset" (symbol-name charset))))
 479       (when parameters
 480         (mml-insert-parameter-string
 481          cont '(name access-type expiration size permission)))
 482       (insert "\n"))
 483     (setq parameters
 484           (mml-parameter-string
 485            cont '(filename creation-date modification-date read-date)))
 486     (when (or (setq disposition (cdr (assq 'disposition cont)))
 487               parameters)
 488       (insert "Content-Disposition: " (or disposition "inline"))
 489       (when parameters
 490         (mml-insert-parameter-string
 491          cont '(filename creation-date modification-date read-date)))
 492       (insert "\n"))
 493     (unless (eq encoding '7bit)
 494       (insert (format "Content-Transfer-Encoding: %s\n" encoding)))
 495     (when (setq description (cdr (assq 'description cont)))
 496       (insert "Content-Description: "
 497               (mail-encode-encoded-word-string description) "\n"))))
 498
 499 (defun mml-parameter-string (cont types)
 500   (let ((string "")
 501         value type)
 502     (while (setq type (pop types))
 503       (when (setq value (cdr (assq type cont)))
 504         ;; Strip directory component from the filename parameter.
 505         (when (eq type 'filename)
 506           (setq value (file-name-nondirectory value)))
 507         (setq string (concat string "; "
 508                              (mail-header-encode-parameter
 509                               (symbol-name type) value)))))
 510     (when (not (zerop (length string)))
 511       string)))
 512
 513 (defun mml-insert-parameter-string (cont types)
 514   (let (value type)
 515     (while (setq type (pop types))
 516       (when (setq value (cdr (assq type cont)))
 517         ;; Strip directory component from the filename parameter.
 518         (when (eq type 'filename)
 519           (setq value (file-name-nondirectory value)))
 520         (mml-insert-parameter
 521          (mail-header-encode-parameter
 522           (symbol-name type) value))))))
 523
 524 (defvar ange-ftp-name-format)
 525 (defvar efs-path-regexp)
 526 (defun mml-parse-file-name (path)
 527   (if (if (boundp 'efs-path-regexp)
 528           (string-match efs-path-regexp path)
 529         (if (boundp 'ange-ftp-name-format)
 530             (string-match (car ange-ftp-name-format) path)))
 531       (list (match-string 1 path) (match-string 2 path)
 532             (substring path (1+ (match-end 2))))
 533     path))
 534
 535 (defun mml-insert-buffer (buffer)
 536   "Insert BUFFER at point and quote any MML markup."
 537   (save-restriction
 538     (narrow-to-region (point) (point))
 539     (insert-buffer-substring buffer)
 540     (mml-quote-region (point-min) (point-max))
 541     (goto-char (point-max))))
 542
 543 ;;;
 544 ;;; Transforming MIME to MML
 545 ;;;
 546
 547 (defun mime-to-mml (&optional handles)
 548   "Translate the current buffer (which should be a message) into MML.
 549 If HANDLES is non-nil, use it instead reparsing the buffer."
 550   ;; First decode the head.
 551   (save-restriction
 552     (message-narrow-to-head)
 553     (mail-decode-encoded-word-region (point-min) (point-max)))
 554   (unless handles
 555     (setq handles (mm-dissect-buffer t)))
 556   (goto-char (point-min))
 557   (search-forward "\n\n" nil t)
 558   (delete-region (point) (point-max))
 559   (if (stringp (car handles))
 560       (mml-insert-mime handles)
 561     (mml-insert-mime handles t))
 562   (mm-destroy-parts handles)
 563   (save-restriction
 564     (message-narrow-to-head)
 565     ;; Remove them, they are confusing.
 566     (message-remove-header "Content-Type")
 567     (message-remove-header "MIME-Version")
 568     (message-remove-header "Content-Transfer-Encoding")))
 569
 570 (defun mml-to-mime ()
 571   "Translate the current buffer from MML to MIME."
 572   (message-encode-message-body)
 573   (save-restriction
 574     (message-narrow-to-headers-or-head)
 575     (let ((mail-parse-charset message-default-charset))
 576       (mail-encode-encoded-word-buffer))))
 577
 578 (defun mml-insert-mime (handle &optional no-markup)
 579   (let (textp buffer mmlp)
 580     ;; Determine type and stuff.
 581     (unless (stringp (car handle))
 582       (unless (setq textp (equal (mm-handle-media-supertype handle) "text"))
 583         (save-excursion
 584           (set-buffer (setq buffer (mml-generate-new-buffer " *mml*")))
 585           (mm-insert-part handle)
 586           (if (setq mmlp (equal (mm-handle-media-type handle)
 587                                 "message/rfc822"))
 588               (mime-to-mml)))))
 589     (if mmlp
 590         (mml-insert-mml-markup handle nil t t)
 591       (unless (and no-markup
 592                    (equal (mm-handle-media-type handle) "text/plain"))
 593         (mml-insert-mml-markup handle buffer textp)))
 594     (cond
 595      (mmlp
 596       (insert-buffer buffer)
 597       (goto-char (point-max))
 598       (insert "<#/mml>\n"))
 599      ((stringp (car handle))
 600       (mapcar 'mml-insert-mime (cdr handle))
 601       (insert "<#/multipart>\n"))
 602      (textp
 603       (let ((charset (mail-content-type-get
 604                       (mm-handle-type handle) 'charset)))
 605         (if (eq charset 'gnus-decoded)
 606             (mm-insert-part handle)
 607           (insert (mm-decode-string (mm-get-part handle) charset))))
 608       (goto-char (point-max)))
 609      (t
 610       (insert "<#/part>\n")))))
 611
 612 (defun mml-insert-mml-markup (handle &optional buffer nofile mmlp)
 613   "Take a MIME handle and insert an MML tag."
 614   (if (stringp (car handle))
 615       (insert "<#multipart type=" (mm-handle-media-subtype handle)
 616               ">\n")
 617     (if mmlp
 618         (insert "<#mml type=" (mm-handle-media-type handle))
 619       (insert "<#part type=" (mm-handle-media-type handle)))
 620     (dolist (elem (append (cdr (mm-handle-type handle))
 621                           (cdr (mm-handle-disposition handle))))
 622       (unless (symbolp (cdr elem))
 623         (insert " " (symbol-name (car elem)) "=\"" (cdr elem) "\"")))
 624     (when (mm-handle-disposition handle)
 625       (insert " disposition=" (car (mm-handle-disposition handle))))
 626     (when buffer
 627       (insert " buffer=\"" (buffer-name buffer) "\""))
 628     (when nofile
 629       (insert " nofile=yes"))
 630     (when (mm-handle-description handle)
 631       (insert " description=\"" (mm-handle-description handle) "\""))
 632     (insert ">\n")))
 633
 634 (defun mml-insert-parameter (&rest parameters)
 635   "Insert PARAMETERS in a nice way."
 636   (dolist (param parameters)
 637     (insert ";")
 638     (let ((point (point)))
 639       (insert " " param)
 640       (when (> (current-column) 71)
 641         (goto-char point)
 642         (insert "\n ")
 643         (end-of-line)))))
 644
 645 ;;;
 646 ;;; Mode for inserting and editing MML forms
 647 ;;;
 648
 649 (defvar mml-mode-map
 650   (let ((sign (make-sparse-keymap))
 651         (encrypt (make-sparse-keymap))
 652         (map (make-sparse-keymap))
 653         (main (make-sparse-keymap)))
 654     (define-key sign "p" 'mml-secure-sign-pgpmime)
 655     (define-key sign "s" 'mml-secure-sign-smime)
 656     (define-key encrypt "p" 'mml-secure-encrypt-pgpmime)
 657     (define-key encrypt "s" 'mml-secure-encrypt-smime)
 658     (define-key map "f" 'mml-attach-file)
 659     (define-key map "b" 'mml-attach-buffer)
 660     (define-key map "e" 'mml-attach-external)
 661     (define-key map "q" 'mml-quote-region)
 662     (define-key map "m" 'mml-insert-multipart)
 663     (define-key map "p" 'mml-insert-part)
 664     (define-key map "v" 'mml-validate)
 665     (define-key map "P" 'mml-preview)
 666     (define-key map "s" sign)
 667     (define-key map "c" encrypt)
 668     ;;(define-key map "n" 'mml-narrow-to-part)
 669     (define-key main "\M-m" map)
 670     main))
 671
 672 (easy-menu-define
 673  mml-menu mml-mode-map ""
 674  '("MML"
 675    ("Attach"
 676     ["File" mml-attach-file t]
 677     ["Buffer" mml-attach-buffer t]
 678     ["External" mml-attach-external t])
 679    ("Insert"
 680     ["Multipart" mml-insert-multipart t]
 681     ["Part" mml-insert-part t])
 682    ("Security"
 683     ("Sign"
 684      ["PGP/MIME" mml-secure-sign-pgpmime t]
 685      ["S/MIME" mml-secure-sign-smime t])
 686     ("Encrypt"
 687      ["PGP/MIME" mml-secure-encrypt-pgpmime t]
 688      ["S/MIME" mml-secure-encrypt-smime t]))
 689    ;;["Narrow" mml-narrow-to-part t]
 690    ["Quote" mml-quote-region t]
 691    ["Validate" mml-validate t]
 692    ["Preview" mml-preview t]))
 693
 694 (defvar mml-mode nil
 695   "Minor mode for editing MML.")
 696
 697 (defun mml-mode (&optional arg)
 698   "Minor mode for editing MML.
 699
 700 \\{mml-mode-map}"
 701   (interactive "P")
 702   (when (set (make-local-variable 'mml-mode)
 703              (if (null arg) (not mml-mode)
 704                (> (prefix-numeric-value arg) 0)))
 705     (gnus-add-minor-mode 'mml-mode " MML" mml-mode-map)
 706     (easy-menu-add mml-menu mml-mode-map)
 707     (run-hooks 'mml-mode-hook)))
 708
 709 ;;;
 710 ;;; Helper functions for reading MIME stuff from the minibuffer and
 711 ;;; inserting stuff to the buffer.
 712 ;;;
 713
 714 (defun mml-minibuffer-read-file (prompt)
 715   (let ((file (read-file-name prompt nil nil t)))
 716     ;; Prevent some common errors.  This is inspired by similar code in
 717     ;; VM.
 718     (when (file-directory-p file)
 719       (error "%s is a directory, cannot attach" file))
 720     (unless (file-exists-p file)
 721       (error "No such file: %s" file))
 722     (unless (file-readable-p file)
 723       (error "Permission denied: %s" file))
 724     file))
 725
 726 (defun mml-minibuffer-read-type (name &optional default)
 727   (mailcap-parse-mimetypes)
 728   (let* ((default (or default
 729                       (mm-default-file-encoding name)
 730                       ;; Perhaps here we should check what the file
 731                       ;; looks like, and offer text/plain if it looks
 732                       ;; like text/plain.
 733                       "application/octet-stream"))
 734          (string (completing-read
 735                   (format "Content type (default %s): " default)
 736                   (mapcar 'list (mailcap-mime-types)))))
 737     (if (not (equal string ""))
 738         string
 739       default)))
 740
 741 (defun mml-minibuffer-read-description ()
 742   (let ((description (read-string "One line description: ")))
 743     (when (string-match "\\`[ \t]*\\'" description)
 744       (setq description nil))
 745     description))
 746
 747 (defun mml-quote-region (beg end)
 748   "Quote the MML tags in the region."
 749   (interactive "r")
 750   (save-excursion
 751     (save-restriction
 752       ;; Temporarily narrow the region to defend from changes
 753       ;; invalidating END.
 754       (narrow-to-region beg end)
 755       (goto-char (point-min))
 756       ;; Quote parts.
 757       (while (re-search-forward
 758               "<#!*/?\\(multipart\\|part\\|external\\|mml\\)" nil t)
 759         ;; Insert ! after the #.
 760         (goto-char (+ (match-beginning 0) 2))
 761         (insert "!")))))
 762
 763 (defun mml-insert-tag (name &rest plist)
 764   "Insert an MML tag described by NAME and PLIST."
 765   (when (symbolp name)
 766     (setq name (symbol-name name)))
 767   (insert "<#" name)
 768   (while plist
 769     (let ((key (pop plist))
 770           (value (pop plist)))
 771       (when value
 772         ;; Quote VALUE if it contains suspicious characters.
 773         (when (string-match "[\"'\\~/*;() \t\n]" value)
 774           (setq value (prin1-to-string value)))
 775         (insert (format " %s=%s" key value)))))
 776   (insert ">\n"))
 777
 778 (defun mml-insert-empty-tag (name &rest plist)
 779   "Insert an empty MML tag described by NAME and PLIST."
 780   (when (symbolp name)
 781     (setq name (symbol-name name)))
 782   (apply #'mml-insert-tag name plist)
 783   (insert "<#/" name ">\n"))
 784
 785 ;;; Attachment functions.
 786
 787 (defun mml-attach-file (file &optional type description)
 788   "Attach a file to the outgoing MIME message.
 789 The file is not inserted or encoded until you send the message with
 790 `\\[message-send-and-exit]' or `\\[message-send]'.
 791
 792 FILE is the name of the file to attach.  TYPE is its content-type, a
 793 string of the form \"type/subtype\".  DESCRIPTION is a one-line
 794 description of the attachment."
 795   (interactive
 796    (let* ((file (mml-minibuffer-read-file "Attach file: "))
 797           (type (mml-minibuffer-read-type file))
 798           (description (mml-minibuffer-read-description)))
 799      (list file type description)))
 800   (mml-insert-empty-tag 'part 'type type 'filename file
 801                         'disposition "attachment" 'description description))
 802
 803 (defun mml-attach-buffer (buffer &optional type description)
 804   "Attach a buffer to the outgoing MIME message.
 805 See `mml-attach-file' for details of operation."
 806   (interactive
 807    (let* ((buffer (read-buffer "Attach buffer: "))
 808           (type (mml-minibuffer-read-type buffer "text/plain"))
 809           (description (mml-minibuffer-read-description)))
 810      (list buffer type description)))
 811   (mml-insert-empty-tag 'part 'type type 'buffer buffer
 812                         'disposition "attachment" 'description description))
 813
 814 (defun mml-attach-external (file &optional type description)
 815   "Attach an external file into the buffer.
 816 FILE is an ange-ftp/efs specification of the part location.
 817 TYPE is the MIME type to use."
 818   (interactive
 819    (let* ((file (mml-minibuffer-read-file "Attach external file: "))
 820           (type (mml-minibuffer-read-type file))
 821           (description (mml-minibuffer-read-description)))
 822      (list file type description)))
 823   (mml-insert-empty-tag 'external 'type type 'name file
 824                         'disposition "attachment" 'description description))
 825
 826 (defun mml-insert-multipart (&optional type)
 827   (interactive (list (completing-read "Multipart type (default mixed): "
 828                                       '(("mixed") ("alternative") ("digest") ("parallel")
 829                                         ("signed") ("encrypted"))
 830                                       nil nil "mixed")))
 831   (or type
 832       (setq type "mixed"))
 833   (mml-insert-empty-tag "multipart" 'type type)
 834   (forward-line -1))
 835
 836 (defun mml-insert-part (&optional type)
 837   (interactive
 838    (list (mml-minibuffer-read-type "")))
 839   (mml-insert-tag 'part 'type type 'disposition "inline")
 840   (forward-line -1))
 841
 842 (defun mml-preview (&optional raw)
 843   "Display current buffer with Gnus, in a new buffer.
 844 If RAW, don't highlight the article."
 845   (interactive "P")
 846   (let ((buf (current-buffer))
 847         (message-options message-options)
 848         (message-posting-charset (or (gnus-setup-posting-charset
 849                                       (save-restriction
 850                                         (message-narrow-to-headers-or-head)
 851                                         (message-fetch-field "Newsgroups")))
 852                                      message-posting-charset)))
 853     (message-options-set-recipient)
 854     (switch-to-buffer (generate-new-buffer
 855                        (concat (if raw "*Raw MIME preview of "
 856                                  "*MIME preview of ") (buffer-name))))
 857     (erase-buffer)
 858     (insert-buffer buf)
 859     (if (re-search-forward
 860          (concat "^" (regexp-quote mail-header-separator) "\n") nil t)
 861         (replace-match "\n"))
 862     (mml-to-mime)
 863     (if raw
 864         (when (fboundp 'set-buffer-multibyte)
 865           (let ((s (buffer-string)))
 866             ;; Insert the content into unibyte buffer.
 867             (erase-buffer)
 868             (mm-disable-multibyte)
 869             (insert s)))
 870       (let ((gnus-newsgroup-charset (car message-posting-charset)))
 871         (run-hooks 'gnus-article-decode-hook)
 872         (let ((gnus-newsgroup-name "dummy"))
 873           (gnus-article-prepare-display))))
 874     (fundamental-mode)
 875     (setq buffer-read-only t)
 876     (goto-char (point-min))))
 877
 878 (defun mml-validate ()
 879   "Validate the current MML document."
 880   (interactive)
 881   (mml-parse))
 882
 883 (provide 'mml)
 884
 885 ;;; mml.el ends here