cgit.sxemacs.org Git - gnus/blob - lisp/mml.el

   1 ;;; mml.el --- A package for parsing and validating MML documents
   2 ;; Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (require 'mm-util)
  27 (require 'mm-bodies)
  28 (require 'mm-encode)
  29 (require 'mm-decode)
  30 (require 'mml-sec)
  31 (eval-when-compile (require 'cl))
  32
  33 (eval-and-compile
  34   (autoload 'message-make-message-id "message")
  35   (autoload 'gnus-setup-posting-charset "gnus-msg")
  36   (autoload 'message-fetch-field "message")
  37   (autoload 'message-posting-charset "message"))
  38
  39 (defvar mml-generate-multipart-alist nil
  40   "*Alist of multipart generation functions.
  41 Each entry has the form (NAME . FUNCTION), where
  42 NAME is a string containing the name of the part (without the
  43 leading \"/multipart/\"),
  44 FUNCTION is a Lisp function which is called to generate the part.
  45
  46 The Lisp function has to supply the appropriate MIME headers and the
  47 contents of this part.")
  48
  49 (defvar mml-syntax-table
  50   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
  51     (modify-syntax-entry ?\\ "/" table)
  52     (modify-syntax-entry ?< "(" table)
  53     (modify-syntax-entry ?> ")" table)
  54     (modify-syntax-entry ?@ "w" table)
  55     (modify-syntax-entry ?/ "w" table)
  56     (modify-syntax-entry ?= " " table)
  57     (modify-syntax-entry ?* " " table)
  58     (modify-syntax-entry ?\; " " table)
  59     (modify-syntax-entry ?\' " " table)
  60     table))
  61
  62 (defvar mml-boundary-function 'mml-make-boundary
  63   "A function called to suggest a boundary.
  64 The function may be called several times, and should try to make a new
  65 suggestion each time.  The function is called with one parameter,
  66 which is a number that says how many times the function has been
  67 called for this message.")
  68
  69 (defvar mml-confirmation-set nil
  70   "A list of symbols, each of which disables some warning.
  71 `unknown-encoding': always send messages contain characters with
  72 unknown encoding; `use-ascii': always use ASCII for those characters
  73 with unknown encoding; `multipart': always send messages with more than
  74 one charsets.")
  75
  76 (defvar mml-generate-default-type "text/plain")
  77
  78 (defvar mml-buffer-list nil)
  79
  80 (defun mml-generate-new-buffer (name)
  81   (let ((buf (generate-new-buffer name)))
  82     (push buf mml-buffer-list)
  83     buf))
  84
  85 (defun mml-destroy-buffers ()
  86   (let (kill-buffer-hook)
  87     (mapcar 'kill-buffer mml-buffer-list)
  88     (setq mml-buffer-list nil)))
  89
  90 (defun mml-parse ()
  91   "Parse the current buffer as an MML document."
  92   (goto-char (point-min))
  93   (let ((table (syntax-table)))
  94     (unwind-protect
  95         (progn
  96           (set-syntax-table mml-syntax-table)
  97           (mml-parse-1))
  98       (set-syntax-table table))))
  99
 100 (defun mml-parse-1 ()
 101   "Parse the current buffer as an MML document."
 102   (let (struct tag point contents charsets warn use-ascii no-markup-p raw)
 103     (while (and (not (eobp))
 104                 (not (looking-at "<#/multipart")))
 105       (cond
 106        ((looking-at "<#multipart")
 107         (push (nconc (mml-read-tag) (mml-parse-1)) struct))
 108        ((looking-at "<#external")
 109         (push (nconc (mml-read-tag) (list (cons 'contents (mml-read-part))))
 110               struct))
 111        (t
 112         (if (or (looking-at "<#part") (looking-at "<#mml"))
 113             (setq tag (mml-read-tag)
 114                   no-markup-p nil
 115                   warn nil)
 116           (setq tag (list 'part '(type . "text/plain"))
 117                 no-markup-p t
 118                 warn t))
 119         (setq raw (cdr (assq 'raw tag))
 120               point (point)
 121               contents (mml-read-part (eq 'mml (car tag)))
 122               charsets (if raw nil
 123                          (mm-find-mime-charset-region point (point))))
 124         (when (and (not raw) (memq nil charsets))
 125           (if (or (memq 'unknown-encoding mml-confirmation-set)
 126                   (y-or-n-p
 127                    "Message contains characters with unknown encoding.  Really send?"))
 128               (if (setq use-ascii
 129                         (or (memq 'use-ascii mml-confirmation-set)
 130                             (y-or-n-p "Use ASCII as charset?")))
 131                   (setq charsets (delq nil charsets))
 132                 (setq warn nil))
 133             (error "Edit your message to remove those characters")))
 134         (if (or raw
 135                 (eq 'mml (car tag))
 136                 (< (length charsets) 2))
 137             (if (or (not no-markup-p)
 138                     (string-match "[^ \t\r\n]" contents))
 139                 ;; Don't create blank parts.
 140                 (push (nconc tag (list (cons 'contents contents)))
 141                       struct))
 142           (let ((nstruct (mml-parse-singlepart-with-multiple-charsets
 143                           tag point (point) use-ascii)))
 144             (when (and warn
 145                        (not (memq 'multipart mml-confirmation-set))
 146                        (not
 147                         (y-or-n-p
 148                          (format
 149                           "Warning: Your message contains more than %d parts.  Really send? "
 150                           (length nstruct)))))
 151               (error "Edit your message to use only one charset"))
 152             (setq struct (nconc nstruct struct)))))))
 153     (unless (eobp)
 154       (forward-line 1))
 155     (nreverse struct)))
 156
 157 (defun mml-parse-singlepart-with-multiple-charsets
 158   (orig-tag beg end &optional use-ascii)
 159   (save-excursion
 160     (save-restriction
 161       (narrow-to-region beg end)
 162       (goto-char (point-min))
 163       (let ((current (or (mm-mime-charset (mm-charset-after))
 164                          (and use-ascii 'us-ascii)))
 165             charset struct space newline paragraph)
 166         (while (not (eobp))
 167           (setq charset (mm-mime-charset (mm-charset-after)))
 168           (cond
 169            ;; The charset remains the same.
 170            ((eq charset 'us-ascii))
 171            ((or (and use-ascii (not charset))
 172                 (eq charset current))
 173             (setq space nil
 174                   newline nil
 175                   paragraph nil))
 176            ;; The initial charset was ascii.
 177            ((eq current 'us-ascii)
 178             (setq current charset
 179                   space nil
 180                   newline nil
 181                   paragraph nil))
 182            ;; We have a change in charsets.
 183            (t
 184             (push (append
 185                    orig-tag
 186                    (list (cons 'contents
 187                                (buffer-substring-no-properties
 188                                 beg (or paragraph newline space (point))))))
 189                   struct)
 190             (setq beg (or paragraph newline space (point))
 191                   current charset
 192                   space nil
 193                   newline nil
 194                   paragraph nil)))
 195           ;; Compute places where it might be nice to break the part.
 196           (cond
 197            ((memq (following-char) '(?  ?\t))
 198             (setq space (1+ (point))))
 199            ((and (eq (following-char) ?\n)
 200                  (not (bobp))
 201                  (eq (char-after (1- (point))) ?\n))
 202             (setq paragraph (point)))
 203            ((eq (following-char) ?\n)
 204             (setq newline (1+ (point)))))
 205           (forward-char 1))
 206         ;; Do the final part.
 207         (unless (= beg (point))
 208           (push (append orig-tag
 209                         (list (cons 'contents
 210                                     (buffer-substring-no-properties
 211                                      beg (point)))))
 212                 struct))
 213         struct))))
 214
 215 (defun mml-read-tag ()
 216   "Read a tag and return the contents."
 217   (let (contents name elem val)
 218     (forward-char 2)
 219     (setq name (buffer-substring-no-properties
 220                 (point) (progn (forward-sexp 1) (point))))
 221     (skip-chars-forward " \t\n")
 222     (while (not (looking-at ">[ \t]*\n?"))
 223       (setq elem (buffer-substring-no-properties
 224                   (point) (progn (forward-sexp 1) (point))))
 225       (skip-chars-forward "= \t\n")
 226       (setq val (buffer-substring-no-properties
 227                  (point) (progn (forward-sexp 1) (point))))
 228       (when (string-match "^\"\\(.*\\)\"$" val)
 229         (setq val (match-string 1 val)))
 230       (push (cons (intern elem) val) contents)
 231       (skip-chars-forward " \t\n"))
 232     (goto-char (match-end 0))
 233     ;; Don't skip the leading space.
 234     ;;(skip-chars-forward " \t\n")
 235     (cons (intern name) (nreverse contents))))
 236
 237 (defun mml-read-part (&optional mml)
 238   "Return the buffer up till the next part, multipart or closing part or multipart.
 239 If MML is non-nil, return the buffer up till the correspondent mml tag."
 240   (let ((beg (point)) (count 1))
 241     ;; If the tag ended at the end of the line, we go to the next line.
 242     (when (looking-at "[ \t]*\n")
 243       (forward-line 1))
 244     (if mml
 245         (progn
 246           (while (and (> count 0) (not (eobp)))
 247             (if (re-search-forward "<#\\(/\\)?mml." nil t)
 248                 (setq count (+ count (if (match-beginning 1) -1 1)))
 249               (goto-char (point-max))))
 250           (buffer-substring-no-properties beg (if (> count 0)
 251                                                   (point)
 252                                                 (match-beginning 0))))
 253       (if (re-search-forward
 254            "<#\\(/\\)?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 255           (prog1
 256               (buffer-substring-no-properties beg (match-beginning 0))
 257             (if (or (not (match-beginning 1))
 258                     (equal (match-string 2) "multipart"))
 259                 (goto-char (match-beginning 0))
 260               (when (looking-at "[ \t]*\n")
 261                 (forward-line 1))))
 262         (buffer-substring-no-properties beg (goto-char (point-max)))))))
 263
 264 (defvar mml-boundary nil)
 265 (defvar mml-base-boundary "-=-=")
 266 (defvar mml-multipart-number 0)
 267
 268 (defun mml-generate-mime ()
 269   "Generate a MIME message based on the current MML document."
 270   (let ((cont (mml-parse))
 271         (mml-multipart-number mml-multipart-number))
 272     (if (not cont)
 273         nil
 274       (with-temp-buffer
 275         (if (and (consp (car cont))
 276                  (= (length cont) 1))
 277             (mml-generate-mime-1 (car cont))
 278           (mml-generate-mime-1 (nconc (list 'multipart '(type . "mixed"))
 279                                       cont)))
 280         (buffer-string)))))
 281
 282 (defun mml-generate-mime-1 (cont)
 283   (let ((mm-use-ultra-safe-encoding
 284          (or mm-use-ultra-safe-encoding (assq 'sign cont))))
 285     (save-restriction
 286       (narrow-to-region (point) (point))
 287       (cond
 288        ((or (eq (car cont) 'part) (eq (car cont) 'mml))
 289         (let ((raw (cdr (assq 'raw cont)))
 290               coded encoding charset filename type)
 291           (setq type (or (cdr (assq 'type cont)) "text/plain"))
 292           (if (and (not raw)
 293                    (member (car (split-string type "/")) '("text" "message")))
 294               (with-temp-buffer
 295                 (setq charset (mm-charset-to-coding-system
 296                                (cdr (assq 'charset cont))))
 297                 (if (eq charset 'ascii) (setq charset nil))
 298                 (cond
 299                  ((cdr (assq 'buffer cont))
 300                   (insert-buffer-substring (cdr (assq 'buffer cont))))
 301                  ((and (setq filename (cdr (assq 'filename cont)))
 302                        (not (equal (cdr (assq 'nofile cont)) "yes")))
 303                   (let ((coding-system-for-read charset))
 304                     (mm-insert-file-contents filename)))
 305                  ((eq 'mml (car cont))
 306                   (insert (cdr (assq 'contents cont))))
 307                  (t
 308                   (save-restriction
 309                     (narrow-to-region (point) (point))
 310                     (insert (cdr (assq 'contents cont)))
 311                     ;; Remove quotes from quoted tags.
 312                     (goto-char (point-min))
 313                     (while (re-search-forward
 314                             "<#!+/?\\(part\\|multipart\\|external\\|mml\\)" nil t)
 315                       (delete-region (+ (match-beginning 0) 2)
 316                                      (+ (match-beginning 0) 3))))))
 317                 (cond
 318                  ((eq (car cont) 'mml)
 319                   (let ((mml-boundary (funcall mml-boundary-function
 320                                                (incf mml-multipart-number)))
 321                         (mml-generate-default-type "text/plain"))
 322                     (mml-to-mime))
 323                   (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 324                     ;; ignore 0x1b, it is part of iso-2022-jp
 325                     (setq encoding (mm-body-7-or-8))))
 326                  ((string= (car (split-string type "/")) "message")
 327                   (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 328                     ;; ignore 0x1b, it is part of iso-2022-jp
 329                     (setq encoding (mm-body-7-or-8))))
 330                  (t
 331                   (setq charset (mm-encode-body charset))
 332                   (setq encoding (mm-body-encoding
 333                                   charset (cdr (assq 'encoding cont))))))
 334                 (setq coded (buffer-string)))
 335             (mm-with-unibyte-buffer
 336               (cond
 337                ((cdr (assq 'buffer cont))
 338                 (insert-buffer-substring (cdr (assq 'buffer cont))))
 339                ((and (setq filename (cdr (assq 'filename cont)))
 340                      (not (equal (cdr (assq 'nofile cont)) "yes")))
 341                 (let ((coding-system-for-read mm-binary-coding-system))
 342                   (mm-insert-file-contents filename nil nil nil nil t)))
 343                (t
 344                 (insert (cdr (assq 'contents cont)))))
 345               (setq encoding (mm-encode-buffer type)
 346                     coded (buffer-string))))
 347           (mml-insert-mime-headers cont type charset encoding)
 348           (insert "\n")
 349           (insert coded)))
 350        ((eq (car cont) 'external)
 351         (insert "Content-Type: message/external-body")
 352         (let ((parameters (mml-parameter-string
 353                            cont '(expiration size permission)))
 354               (name (cdr (assq 'name cont)))
 355               (url (cdr (assq 'url cont))))
 356           (when name
 357             (setq name (mml-parse-file-name name))
 358             (if (stringp name)
 359                 (mml-insert-parameter
 360                  (mail-header-encode-parameter "name" name)
 361                  "access-type=local-file")
 362               (mml-insert-parameter
 363                (mail-header-encode-parameter
 364                 "name" (file-name-nondirectory (nth 2 name)))
 365                (mail-header-encode-parameter "site" (nth 1 name))
 366                (mail-header-encode-parameter
 367                 "directory" (file-name-directory (nth 2 name))))
 368               (mml-insert-parameter
 369                (concat "access-type="
 370                        (if (member (nth 0 name) '("ftp@" "anonymous@"))
 371                            "anon-ftp"
 372                          "ftp")))))
 373           (when url
 374             (mml-insert-parameter
 375              (mail-header-encode-parameter "url" url)
 376              "access-type=url"))
 377           (when parameters
 378             (mml-insert-parameter-string
 379              cont '(expiration size permission))))
 380         (insert "\n\n")
 381         (insert "Content-Type: " (cdr (assq 'type cont)) "\n")
 382         (insert "Content-ID: " (message-make-message-id) "\n")
 383         (insert "Content-Transfer-Encoding: "
 384                 (or (cdr (assq 'encoding cont)) "binary"))
 385         (insert "\n\n")
 386         (insert (or (cdr (assq 'contents cont))))
 387         (insert "\n"))
 388        ((eq (car cont) 'multipart)
 389         (let* ((type (or (cdr (assq 'type cont)) "mixed"))
 390                (mml-generate-default-type (if (equal type "digest")
 391                                               "message/rfc822"
 392                                             "text/plain"))
 393                (handler (assoc type mml-generate-multipart-alist)))
 394           (if handler
 395               (funcall (cdr handler) cont)
 396             ;; No specific handler.  Use default one.
 397             (let ((mml-boundary (mml-compute-boundary cont)))
 398               (insert (format "Content-Type: multipart/%s; boundary=\"%s\"\n"
 399                               type mml-boundary))
 400               (let ((cont cont) part)
 401                 (while (setq part (pop cont))
 402                   ;; Skip `multipart' and attributes.
 403                   (when (and (consp part) (consp (cdr part)))
 404                     (insert "\n--" mml-boundary "\n")
 405                     (mml-generate-mime-1 part))))
 406               (insert "\n--" mml-boundary "--\n")))))
 407        (t
 408         (error "Invalid element: %S" cont)))
 409       (let ((item (assoc (cdr (assq 'sign cont)) mml-sign-alist))
 410             sender recipients)
 411         (when item
 412           (if (setq sender (cdr (assq 'sender cont)))
 413               (message-options-set 'message-sender sender))
 414           (if (setq recipients (cdr (assq 'recipients cont)))
 415               (message-options-set 'message-sender recipients))
 416           (funcall (nth 1 item) cont)))
 417       (let ((item (assoc (cdr (assq 'encrypt cont)) mml-encrypt-alist))
 418             sender recipients)
 419         (when item
 420           (if (setq sender (cdr (assq 'sender cont)))
 421               (message-options-set 'message-sender sender))
 422           (if (setq recipients (cdr (assq 'recipients cont)))
 423               (message-options-set 'message-sender recipients))
 424           (funcall (nth 1 item) cont))))))
 425
 426 (defun mml-compute-boundary (cont)
 427   "Return a unique boundary that does not exist in CONT."
 428   (let ((mml-boundary (funcall mml-boundary-function
 429                                (incf mml-multipart-number))))
 430     ;; This function tries again and again until it has found
 431     ;; a unique boundary.
 432     (while (not (catch 'not-unique
 433                   (mml-compute-boundary-1 cont))))
 434     mml-boundary))
 435
 436 (defun mml-compute-boundary-1 (cont)
 437   (let (filename)
 438     (cond
 439      ((eq (car cont) 'part)
 440       (with-temp-buffer
 441         (cond
 442          ((cdr (assq 'buffer cont))
 443           (insert-buffer-substring (cdr (assq 'buffer cont))))
 444          ((and (setq filename (cdr (assq 'filename cont)))
 445                (not (equal (cdr (assq 'nofile cont)) "yes")))
 446           (mm-insert-file-contents filename))
 447          (t
 448           (insert (cdr (assq 'contents cont)))))
 449         (goto-char (point-min))
 450         (when (re-search-forward (concat "^--" (regexp-quote mml-boundary))
 451                                  nil t)
 452           (setq mml-boundary (funcall mml-boundary-function
 453                                       (incf mml-multipart-number)))
 454           (throw 'not-unique nil))))
 455      ((eq (car cont) 'multipart)
 456       (mapcar 'mml-compute-boundary-1 (cddr cont))))
 457     t))
 458
 459 (defun mml-make-boundary (number)
 460   (concat (make-string (% number 60) ?=)
 461           (if (> number 17)
 462               (format "%x" number)
 463             "")
 464           mml-base-boundary))
 465
 466 (defun mml-insert-mime-headers (cont type charset encoding)
 467   (let (parameters disposition description)
 468     (setq parameters
 469           (mml-parameter-string
 470            cont '(name access-type expiration size permission)))
 471     (when (or charset
 472               parameters
 473               (not (equal type mml-generate-default-type)))
 474       (when (consp charset)
 475         (error
 476          "Can't encode a part with several charsets."))
 477       (insert "Content-Type: " type)
 478       (when charset
 479         (insert "; " (mail-header-encode-parameter
 480                       "charset" (symbol-name charset))))
 481       (when parameters
 482         (mml-insert-parameter-string
 483          cont '(name access-type expiration size permission)))
 484       (insert "\n"))
 485     (setq parameters
 486           (mml-parameter-string
 487            cont '(filename creation-date modification-date read-date)))
 488     (when (or (setq disposition (cdr (assq 'disposition cont)))
 489               parameters)
 490       (insert "Content-Disposition: " (or disposition "inline"))
 491       (when parameters
 492         (mml-insert-parameter-string
 493          cont '(filename creation-date modification-date read-date)))
 494       (insert "\n"))
 495     (unless (eq encoding '7bit)
 496       (insert (format "Content-Transfer-Encoding: %s\n" encoding)))
 497     (when (setq description (cdr (assq 'description cont)))
 498       (insert "Content-Description: "
 499               (mail-encode-encoded-word-string description) "\n"))))
 500
 501 (defun mml-parameter-string (cont types)
 502   (let ((string "")
 503         value type)
 504     (while (setq type (pop types))
 505       (when (setq value (cdr (assq type cont)))
 506         ;; Strip directory component from the filename parameter.
 507         (when (eq type 'filename)
 508           (setq value (file-name-nondirectory value)))
 509         (setq string (concat string "; "
 510                              (mail-header-encode-parameter
 511                               (symbol-name type) value)))))
 512     (when (not (zerop (length string)))
 513       string)))
 514
 515 (defun mml-insert-parameter-string (cont types)
 516   (let (value type)
 517     (while (setq type (pop types))
 518       (when (setq value (cdr (assq type cont)))
 519         ;; Strip directory component from the filename parameter.
 520         (when (eq type 'filename)
 521           (setq value (file-name-nondirectory value)))
 522         (mml-insert-parameter
 523          (mail-header-encode-parameter
 524           (symbol-name type) value))))))
 525
 526 (eval-when-compile
 527   (defvar ange-ftp-name-format)
 528   (defvar efs-path-regexp))
 529 (defun mml-parse-file-name (path)
 530   (if (if (boundp 'efs-path-regexp)
 531           (string-match efs-path-regexp path)
 532         (if (boundp 'ange-ftp-name-format)
 533             (string-match (car ange-ftp-name-format) path)))
 534       (list (match-string 1 path) (match-string 2 path)
 535             (substring path (1+ (match-end 2))))
 536     path))
 537
 538 (defun mml-insert-buffer (buffer)
 539   "Insert BUFFER at point and quote any MML markup."
 540   (save-restriction
 541     (narrow-to-region (point) (point))
 542     (insert-buffer-substring buffer)
 543     (mml-quote-region (point-min) (point-max))
 544     (goto-char (point-max))))
 545
 546 ;;;
 547 ;;; Transforming MIME to MML
 548 ;;;
 549
 550 (defun mime-to-mml (&optional handles)
 551   "Translate the current buffer (which should be a message) into MML.
 552 If HANDLES is non-nil, use it instead reparsing the buffer."
 553   ;; First decode the head.
 554   (save-restriction
 555     (message-narrow-to-head)
 556     (mail-decode-encoded-word-region (point-min) (point-max)))
 557   (unless handles
 558     (setq handles (mm-dissect-buffer t)))
 559   (goto-char (point-min))
 560   (search-forward "\n\n" nil t)
 561   (delete-region (point) (point-max))
 562   (if (stringp (car handles))
 563       (mml-insert-mime handles)
 564     (mml-insert-mime handles t))
 565   (mm-destroy-parts handles)
 566   (save-restriction
 567     (message-narrow-to-head)
 568     ;; Remove them, they are confusing.
 569     (message-remove-header "Content-Type")
 570     (message-remove-header "MIME-Version")
 571     (message-remove-header "Content-Transfer-Encoding")))
 572
 573 (defun mml-to-mime ()
 574   "Translate the current buffer from MML to MIME."
 575   (message-encode-message-body)
 576   (save-restriction
 577     (message-narrow-to-headers-or-head)
 578     (let ((mail-parse-charset message-default-charset))
 579       (mail-encode-encoded-word-buffer))))
 580
 581 (defun mml-insert-mime (handle &optional no-markup)
 582   (let (textp buffer mmlp)
 583     ;; Determine type and stuff.
 584     (unless (stringp (car handle))
 585       (unless (setq textp (equal (mm-handle-media-supertype handle) "text"))
 586         (save-excursion
 587           (set-buffer (setq buffer (mml-generate-new-buffer " *mml*")))
 588           (mm-insert-part handle)
 589           (if (setq mmlp (equal (mm-handle-media-type handle)
 590                                 "message/rfc822"))
 591               (mime-to-mml)))))
 592     (if mmlp
 593         (mml-insert-mml-markup handle nil t t)
 594       (unless (and no-markup
 595                    (equal (mm-handle-media-type handle) "text/plain"))
 596         (mml-insert-mml-markup handle buffer textp)))
 597     (cond
 598      (mmlp
 599       (insert-buffer buffer)
 600       (goto-char (point-max))
 601       (insert "<#/mml>\n"))
 602      ((stringp (car handle))
 603       (mapcar 'mml-insert-mime (cdr handle))
 604       (insert "<#/multipart>\n"))
 605      (textp
 606       (let ((charset (mail-content-type-get
 607                       (mm-handle-type handle) 'charset)))
 608         (if (eq charset 'gnus-decoded)
 609             (mm-insert-part handle)
 610           (insert (mm-decode-string (mm-get-part handle) charset))))
 611       (goto-char (point-max)))
 612      (t
 613       (insert "<#/part>\n")))))
 614
 615 (defun mml-insert-mml-markup (handle &optional buffer nofile mmlp)
 616   "Take a MIME handle and insert an MML tag."
 617   (if (stringp (car handle))
 618       (insert "<#multipart type=" (mm-handle-media-subtype handle)
 619               ">\n")
 620     (if mmlp
 621         (insert "<#mml type=" (mm-handle-media-type handle))
 622       (insert "<#part type=" (mm-handle-media-type handle)))
 623     (dolist (elem (append (cdr (mm-handle-type handle))
 624                           (cdr (mm-handle-disposition handle))))
 625       (unless (symbolp (cdr elem))
 626         (insert " " (symbol-name (car elem)) "=\"" (cdr elem) "\"")))
 627     (when (mm-handle-disposition handle)
 628       (insert " disposition=" (car (mm-handle-disposition handle))))
 629     (when buffer
 630       (insert " buffer=\"" (buffer-name buffer) "\""))
 631     (when nofile
 632       (insert " nofile=yes"))
 633     (when (mm-handle-description handle)
 634       (insert " description=\"" (mm-handle-description handle) "\""))
 635     (insert ">\n")))
 636
 637 (defun mml-insert-parameter (&rest parameters)
 638   "Insert PARAMETERS in a nice way."
 639   (dolist (param parameters)
 640     (insert ";")
 641     (let ((point (point)))
 642       (insert " " param)
 643       (when (> (current-column) 71)
 644         (goto-char point)
 645         (insert "\n ")
 646         (end-of-line)))))
 647
 648 ;;;
 649 ;;; Mode for inserting and editing MML forms
 650 ;;;
 651
 652 (defvar mml-mode-map
 653   (let ((sign (make-sparse-keymap))
 654         (encrypt (make-sparse-keymap))
 655         (map (make-sparse-keymap))
 656         (main (make-sparse-keymap)))
 657     (define-key sign "p" 'mml-secure-sign-pgpmime)
 658     (define-key sign "s" 'mml-secure-sign-smime)
 659     (define-key encrypt "p" 'mml-secure-encrypt-pgpmime)
 660     (define-key encrypt "s" 'mml-secure-encrypt-smime)
 661     (define-key map "f" 'mml-attach-file)
 662     (define-key map "b" 'mml-attach-buffer)
 663     (define-key map "e" 'mml-attach-external)
 664     (define-key map "q" 'mml-quote-region)
 665     (define-key map "m" 'mml-insert-multipart)
 666     (define-key map "p" 'mml-insert-part)
 667     (define-key map "v" 'mml-validate)
 668     (define-key map "P" 'mml-preview)
 669     (define-key map "s" sign)
 670     (define-key map "c" encrypt)
 671     ;;(define-key map "n" 'mml-narrow-to-part)
 672     ;; `M-m' conflicts with `back-to-indentation'.
 673     ;; (define-key main "\M-m" map)
 674     (define-key main "\C-c\C-m" map)
 675     main))
 676
 677 (easy-menu-define
 678  mml-menu mml-mode-map ""
 679  '("MML"
 680    ("Attach"
 681     ["File" mml-attach-file t]
 682     ["Buffer" mml-attach-buffer t]
 683     ["External" mml-attach-external t])
 684    ("Insert"
 685     ["Multipart" mml-insert-multipart t]
 686     ["Part" mml-insert-part t])
 687    ("Security"
 688     ("Sign"
 689      ["PGP/MIME" mml-secure-sign-pgpmime t]
 690      ["S/MIME" mml-secure-sign-smime t])
 691     ("Encrypt"
 692      ["PGP/MIME" mml-secure-encrypt-pgpmime t]
 693      ["S/MIME" mml-secure-encrypt-smime t]))
 694    ;;["Narrow" mml-narrow-to-part t]
 695    ["Quote" mml-quote-region t]
 696    ["Validate" mml-validate t]
 697    ["Preview" mml-preview t]))
 698
 699 (defvar mml-mode nil
 700   "Minor mode for editing MML.")
 701
 702 (defun mml-mode (&optional arg)
 703   "Minor mode for editing MML.
 704
 705 \\{mml-mode-map}"
 706   (interactive "P")
 707   (when (set (make-local-variable 'mml-mode)
 708              (if (null arg) (not mml-mode)
 709                (> (prefix-numeric-value arg) 0)))
 710     (gnus-add-minor-mode 'mml-mode " MML" mml-mode-map)
 711     (easy-menu-add mml-menu mml-mode-map)
 712     (run-hooks 'mml-mode-hook)))
 713
 714 ;;;
 715 ;;; Helper functions for reading MIME stuff from the minibuffer and
 716 ;;; inserting stuff to the buffer.
 717 ;;;
 718
 719 (defun mml-minibuffer-read-file (prompt)
 720   (let ((file (read-file-name prompt nil nil t)))
 721     ;; Prevent some common errors.  This is inspired by similar code in
 722     ;; VM.
 723     (when (file-directory-p file)
 724       (error "%s is a directory, cannot attach" file))
 725     (unless (file-exists-p file)
 726       (error "No such file: %s" file))
 727     (unless (file-readable-p file)
 728       (error "Permission denied: %s" file))
 729     file))
 730
 731 (defun mml-minibuffer-read-type (name &optional default)
 732   (mailcap-parse-mimetypes)
 733   (let* ((default (or default
 734                       (mm-default-file-encoding name)
 735                       ;; Perhaps here we should check what the file
 736                       ;; looks like, and offer text/plain if it looks
 737                       ;; like text/plain.
 738                       "application/octet-stream"))
 739          (string (completing-read
 740                   (format "Content type (default %s): " default)
 741                   (mapcar 'list (mailcap-mime-types)))))
 742     (if (not (equal string ""))
 743         string
 744       default)))
 745
 746 (defun mml-minibuffer-read-description ()
 747   (let ((description (read-string "One line description: ")))
 748     (when (string-match "\\`[ \t]*\\'" description)
 749       (setq description nil))
 750     description))
 751
 752 (defun mml-quote-region (beg end)
 753   "Quote the MML tags in the region."
 754   (interactive "r")
 755   (save-excursion
 756     (save-restriction
 757       ;; Temporarily narrow the region to defend from changes
 758       ;; invalidating END.
 759       (narrow-to-region beg end)
 760       (goto-char (point-min))
 761       ;; Quote parts.
 762       (while (re-search-forward
 763               "<#!*/?\\(multipart\\|part\\|external\\|mml\\)" nil t)
 764         ;; Insert ! after the #.
 765         (goto-char (+ (match-beginning 0) 2))
 766         (insert "!")))))
 767
 768 (defun mml-insert-tag (name &rest plist)
 769   "Insert an MML tag described by NAME and PLIST."
 770   (when (symbolp name)
 771     (setq name (symbol-name name)))
 772   (insert "<#" name)
 773   (while plist
 774     (let ((key (pop plist))
 775           (value (pop plist)))
 776       (when value
 777         ;; Quote VALUE if it contains suspicious characters.
 778         (when (string-match "[\"'\\~/*;() \t\n]" value)
 779           (setq value (prin1-to-string value)))
 780         (insert (format " %s=%s" key value)))))
 781   (insert ">\n"))
 782
 783 (defun mml-insert-empty-tag (name &rest plist)
 784   "Insert an empty MML tag described by NAME and PLIST."
 785   (when (symbolp name)
 786     (setq name (symbol-name name)))
 787   (apply #'mml-insert-tag name plist)
 788   (insert "<#/" name ">\n"))
 789
 790 ;;; Attachment functions.
 791
 792 (defun mml-attach-file (file &optional type description)
 793   "Attach a file to the outgoing MIME message.
 794 The file is not inserted or encoded until you send the message with
 795 `\\[message-send-and-exit]' or `\\[message-send]'.
 796
 797 FILE is the name of the file to attach.  TYPE is its content-type, a
 798 string of the form \"type/subtype\".  DESCRIPTION is a one-line
 799 description of the attachment."
 800   (interactive
 801    (let* ((file (mml-minibuffer-read-file "Attach file: "))
 802           (type (mml-minibuffer-read-type file))
 803           (description (mml-minibuffer-read-description)))
 804      (list file type description)))
 805   (mml-insert-empty-tag 'part 'type type 'filename file
 806                         'disposition "attachment" 'description description))
 807
 808 (defun mml-attach-buffer (buffer &optional type description)
 809   "Attach a buffer to the outgoing MIME message.
 810 See `mml-attach-file' for details of operation."
 811   (interactive
 812    (let* ((buffer (read-buffer "Attach buffer: "))
 813           (type (mml-minibuffer-read-type buffer "text/plain"))
 814           (description (mml-minibuffer-read-description)))
 815      (list buffer type description)))
 816   (mml-insert-empty-tag 'part 'type type 'buffer buffer
 817                         'disposition "attachment" 'description description))
 818
 819 (defun mml-attach-external (file &optional type description)
 820   "Attach an external file into the buffer.
 821 FILE is an ange-ftp/efs specification of the part location.
 822 TYPE is the MIME type to use."
 823   (interactive
 824    (let* ((file (mml-minibuffer-read-file "Attach external file: "))
 825           (type (mml-minibuffer-read-type file))
 826           (description (mml-minibuffer-read-description)))
 827      (list file type description)))
 828   (mml-insert-empty-tag 'external 'type type 'name file
 829                         'disposition "attachment" 'description description))
 830
 831 (defun mml-insert-multipart (&optional type)
 832   (interactive (list (completing-read "Multipart type (default mixed): "
 833                                       '(("mixed") ("alternative") ("digest") ("parallel")
 834                                         ("signed") ("encrypted"))
 835                                       nil nil "mixed")))
 836   (or type
 837       (setq type "mixed"))
 838   (mml-insert-empty-tag "multipart" 'type type)
 839   (forward-line -1))
 840
 841 (defun mml-insert-part (&optional type)
 842   (interactive
 843    (list (mml-minibuffer-read-type "")))
 844   (mml-insert-tag 'part 'type type 'disposition "inline")
 845   (forward-line -1))
 846
 847 (defun mml-preview (&optional raw)
 848   "Display current buffer with Gnus, in a new buffer.
 849 If RAW, don't highlight the article."
 850   (interactive "P")
 851   (let ((buf (current-buffer))
 852         (message-options message-options)
 853         (message-posting-charset (or (gnus-setup-posting-charset
 854                                       (save-restriction
 855                                         (message-narrow-to-headers-or-head)
 856                                         (message-fetch-field "Newsgroups")))
 857                                      message-posting-charset)))
 858     (message-options-set-recipient)
 859     (switch-to-buffer (generate-new-buffer
 860                        (concat (if raw "*Raw MIME preview of "
 861                                  "*MIME preview of ") (buffer-name))))
 862     (erase-buffer)
 863     (insert-buffer buf)
 864     (if (re-search-forward
 865          (concat "^" (regexp-quote mail-header-separator) "\n") nil t)
 866         (replace-match "\n"))
 867     (mml-to-mime)
 868     (if raw
 869         (when (fboundp 'set-buffer-multibyte)
 870           (let ((s (buffer-string)))
 871             ;; Insert the content into unibyte buffer.
 872             (erase-buffer)
 873             (mm-disable-multibyte)
 874             (insert s)))
 875       (let ((gnus-newsgroup-charset (car message-posting-charset)))
 876         (run-hooks 'gnus-article-decode-hook)
 877         (let ((gnus-newsgroup-name "dummy"))
 878           (gnus-article-prepare-display))))
 879     (fundamental-mode)
 880     (setq buffer-read-only t)
 881     (goto-char (point-min))))
 882
 883 (defun mml-validate ()
 884   "Validate the current MML document."
 885   (interactive)
 886   (mml-parse))
 887
 888 (provide 'mml)
 889
 890 ;;; mml.el ends here