cgit.sxemacs.org Git - gnus/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for Mule and low level things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28 (require 'mail-prsvr)
  29
  30 (eval-and-compile
  31   (mapcar
  32    (lambda (elem)
  33      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  34        (if (fboundp (car elem))
  35            (defalias nfunc (car elem))
  36          (defalias nfunc (cdr elem)))))
  37    '((decode-coding-string . (lambda (s a) s))
  38      (encode-coding-string . (lambda (s a) s))
  39      (encode-coding-region . ignore)
  40      (coding-system-list . ignore)
  41      (decode-coding-region . ignore)
  42      (char-int . identity)
  43      (device-type . ignore)
  44      (coding-system-equal . equal)
  45      (annotationp . ignore)
  46      (set-buffer-file-coding-system . ignore)
  47      (make-char
  48       . (lambda (charset int)
  49           (int-to-char int)))
  50      (read-charset
  51       . (lambda (prompt)
  52           "Return a charset."
  53           (intern
  54            (completing-read
  55             prompt
  56             (mapcar (lambda (e) (list (symbol-name (car e))))
  57                     mm-mime-mule-charset-alist)
  58             nil t))))
  59      (subst-char-in-string
  60       . (lambda (from to string) ;; stolen (and renamed) from nnheader.el
  61           "Replace characters in STRING from FROM to TO."
  62           (let ((string (substring string 0)) ;Copy string.
  63                 (len (length string))
  64                 (idx 0))
  65             ;; Replace all occurrences of FROM with TO.
  66             (while (< idx len)
  67               (when (= (aref string idx) from)
  68                 (aset string idx to))
  69               (setq idx (1+ idx)))
  70             string)))
  71      (string-as-unibyte . identity)
  72      (string-as-multibyte . identity)
  73      (multibyte-string-p . ignore))))
  74
  75 (eval-and-compile
  76   (defalias 'mm-char-or-char-int-p
  77     (cond
  78      ((fboundp 'char-or-char-int-p) 'char-or-char-int-p)
  79      ((fboundp 'char-valid-p) 'char-valid-p)
  80      (t 'identity))))
  81
  82 (eval-and-compile
  83   (defalias 'mm-read-coding-system
  84     (cond
  85      ((fboundp 'read-coding-system)
  86       (if (and (featurep 'xemacs)
  87                (<= (string-to-number emacs-version) 21.1))
  88           (lambda (prompt &optional default-coding-system)
  89             (read-coding-system prompt))
  90         'read-coding-system))
  91      (t (lambda (prompt &optional default-coding-system)
  92           "Prompt the user for a coding system."
  93           (completing-read
  94            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
  95                           mm-mime-mule-charset-alist)))))))
  96
  97 (defvar mm-coding-system-list nil)
  98 (defun mm-get-coding-system-list ()
  99   "Get the coding system list."
 100   (or mm-coding-system-list
 101       (setq mm-coding-system-list (mm-coding-system-list))))
 102
 103 (defun mm-coding-system-p (sym)
 104   "Return non-nil if SYM is a coding system."
 105   (or (and (fboundp 'coding-system-p) (coding-system-p sym))
 106       (memq sym (mm-get-coding-system-list))))
 107
 108 (defvar mm-charset-synonym-alist
 109   `(
 110     ;; Perfectly fine?  A valid MIME name, anyhow.
 111     ,@(unless (mm-coding-system-p 'big5)
 112        '((big5 . cn-big5)))
 113     ;; Not in XEmacs, but it's not a proper MIME charset anyhow.
 114     ,@(unless (mm-coding-system-p 'x-ctext)
 115        '((x-ctext . ctext)))
 116     ;; Apparently not defined in Emacs 20, but is a valid MIME name.
 117     ,@(unless (mm-coding-system-p 'gb2312)
 118        '((gb2312 . cn-gb-2312)))
 119     ;; ISO-8859-15 is very similar to ISO-8859-1.
 120     ,@(unless (mm-coding-system-p 'iso-8859-15) ; Emacs 21 defines it.
 121        '((iso-8859-15 . iso-8859-1)))
 122     ;; Windows-1252 is actually a superset of Latin-1.  See also
 123     ;; `gnus-article-dumbquotes-map'.
 124     ,@(unless (mm-coding-system-p 'windows-1252)
 125        (if (mm-coding-system-p 'cp1252)
 126            '((windows-1252 . cp1252))
 127          '((windows-1252 . iso-8859-1))))
 128     ;; Windows-1250 is a variant of Latin-2 heavily used by Microsoft
 129     ;; Outlook users in Czech republic. Use this to allow reading of their
 130     ;; e-mails. cp1250 should be defined by M-x codepage-setup.
 131     ,@(if (and (not (mm-coding-system-p 'windows-1250))
 132                (mm-coding-system-p 'cp1250))
 133           '((windows-1250 . cp1250)))
 134     )
 135   "A mapping from invalid charset names to the real charset names.")
 136
 137 (defvar mm-binary-coding-system
 138   (cond
 139    ((mm-coding-system-p 'binary) 'binary)
 140    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 141    (t nil))
 142   "100% binary coding system.")
 143
 144 (defvar mm-text-coding-system
 145   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 146           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 147         (and (mm-coding-system-p 'raw-text) 'raw-text))
 148       mm-binary-coding-system)
 149   "Text-safe coding system (For removing ^M).")
 150
 151 (defvar mm-text-coding-system-for-write nil
 152   "Text coding system for write.")
 153
 154 (defvar mm-auto-save-coding-system
 155   (cond
 156    ((mm-coding-system-p 'emacs-mule)
 157     (if (memq system-type '(windows-nt ms-dos ms-windows))
 158         (if (mm-coding-system-p 'emacs-mule-dos)
 159             'emacs-mule-dos mm-binary-coding-system)
 160       'emacs-mule))
 161    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 162    (t mm-binary-coding-system))
 163   "Coding system of auto save file.")
 164
 165 (defvar mm-universal-coding-system mm-auto-save-coding-system
 166   "The universal coding system.")
 167
 168 ;; Fixme: some of the cars here aren't valid MIME charsets.  That
 169 ;; should only matter with XEmacs, though.
 170 (defvar mm-mime-mule-charset-alist
 171   `((us-ascii ascii)
 172     (iso-8859-1 latin-iso8859-1)
 173     (iso-8859-2 latin-iso8859-2)
 174     (iso-8859-3 latin-iso8859-3)
 175     (iso-8859-4 latin-iso8859-4)
 176     (iso-8859-5 cyrillic-iso8859-5)
 177     ;; Non-mule (X)Emacs uses the last mule-charset for 8bit characters.
 178     ;; The fake mule-charset, gnus-koi8-r, tells Gnus that the default
 179     ;; charset is koi8-r, not iso-8859-5.
 180     (koi8-r cyrillic-iso8859-5 gnus-koi8-r)
 181     (iso-8859-6 arabic-iso8859-6)
 182     (iso-8859-7 greek-iso8859-7)
 183     (iso-8859-8 hebrew-iso8859-8)
 184     (iso-8859-9 latin-iso8859-9)
 185     (iso-8859-14 latin-iso8859-14)
 186     (iso-8859-15 latin-iso8859-15)
 187     (viscii vietnamese-viscii-lower)
 188     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
 189     (euc-kr korean-ksc5601)
 190     (gb2312 chinese-gb2312)
 191     (big5 chinese-big5-1 chinese-big5-2)
 192     (tibetan tibetan)
 193     (thai-tis620 thai-tis620)
 194     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
 195     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
 196                    latin-jisx0201 japanese-jisx0208-1978
 197                    chinese-gb2312 japanese-jisx0208
 198                    korean-ksc5601 japanese-jisx0212
 199                    katakana-jisx0201)
 200     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
 201                     latin-jisx0201 japanese-jisx0208-1978
 202                     chinese-gb2312 japanese-jisx0208
 203                     korean-ksc5601 japanese-jisx0212
 204                     chinese-cns11643-1 chinese-cns11643-2)
 205     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
 206                     cyrillic-iso8859-5 greek-iso8859-7
 207                     latin-jisx0201 japanese-jisx0208-1978
 208                     chinese-gb2312 japanese-jisx0208
 209                     korean-ksc5601 japanese-jisx0212
 210                     chinese-cns11643-1 chinese-cns11643-2
 211                     chinese-cns11643-3 chinese-cns11643-4
 212                     chinese-cns11643-5 chinese-cns11643-6
 213                     chinese-cns11643-7)
 214     ,(if (or (not (fboundp 'charsetp)) ;; non-Mule case
 215              (charsetp 'unicode-a)
 216              (not (mm-coding-system-p 'mule-utf-8)))
 217          '(utf-8 unicode-a unicode-b unicode-c unicode-d unicode-e)
 218        ;; If we have utf-8 we're in Mule 5+.
 219        (append '(utf-8)
 220                (delete 'ascii
 221                        (coding-system-get 'mule-utf-8 'safe-charsets)))))
 222   "Alist of MIME-charset/MULE-charsets.")
 223
 224 ;; Correct by construction, but should be unnecessary:
 225 ;; XEmacs hates it.
 226 (when (and (not (featurep 'xemacs))
 227            (fboundp 'coding-system-list)
 228            (fboundp 'sort-coding-systems))
 229   (setq mm-mime-mule-charset-alist
 230         (apply
 231          'nconc
 232          (mapcar
 233           (lambda (cs)
 234             (when (and (coding-system-get cs 'mime-charset)
 235                        (not (eq t (coding-system-get cs 'safe-charsets))))
 236               (list (cons (coding-system-get cs 'mime-charset)
 237                           (delq 'ascii
 238                                 (coding-system-get cs 'safe-charsets))))))
 239           (sort-coding-systems (coding-system-list 'base-only))))))
 240
 241 (defvar mm-hack-charsets '(iso-8859-15 iso-2022-jp-2)
 242   "A list of special charsets.
 243 Valid elements include:
 244 `iso-8859-15'    convert ISO-8859-1, -9 to ISO-8859-15 if ISO-8859-15 exists.
 245 `iso-2022-jp-2'  convert ISO-2022-jp to ISO-2022-jp-2 if ISO-2022-jp-2 exists."
 246 )
 247
 248 (defvar mm-iso-8859-15-compatible
 249   '((iso-8859-1 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE")
 250     (iso-8859-9 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE\xD0\xDD\xDE\xF0\xFD\xFE"))
 251   "ISO-8859-15 exchangeable coding systems and inconvertible characters.")
 252
 253 (defvar mm-iso-8859-x-to-15-table
 254   (and (fboundp 'coding-system-p)
 255        (mm-coding-system-p 'iso-8859-15)
 256        (mapcar
 257         (lambda (cs)
 258           (if (mm-coding-system-p (car cs))
 259               (let ((c (string-to-char
 260                         (decode-coding-string "\341" (car cs)))))
 261                 (cons (char-charset c)
 262                       (cons
 263                        (- (string-to-char
 264                            (decode-coding-string "\341" 'iso-8859-15)) c)
 265                        (string-to-list (decode-coding-string (car (cdr cs))
 266                                                              (car cs))))))
 267             '(gnus-charset 0)))
 268         mm-iso-8859-15-compatible))
 269   "A table of the difference character between ISO-8859-X and ISO-8859-15.")
 270
 271 (defvar mm-coding-system-priorities nil
 272   "Preferred coding systems for encoding outgoing mails.
 273
 274 More than one suitable coding systems may be found for some texts.  By
 275 default, a coding system with the highest priority is used to encode
 276 outgoing mails (see `sort-coding-systems').  If this variable is set,
 277 it overrides the default priority.  For example, Japanese users may
 278 prefer iso-2022-jp to japanese-shift-jis:
 279
 280 \(setq mm-coding-system-priorities
 281   '(iso-2022-jp iso-2022-jp-2 japanese-shift-jis utf-8))
 282 ")
 283
 284 ;;; Internal variables:
 285
 286 ;;; Functions:
 287
 288 (defun mm-mule-charset-to-mime-charset (charset)
 289   "Return the MIME charset corresponding to the given Mule CHARSET."
 290   (if (fboundp 'find-coding-systems-for-charsets)
 291       (let (mime)
 292         (dolist (cs (find-coding-systems-for-charsets (list charset)))
 293           (unless mime
 294             (when cs
 295               (setq mime (coding-system-get cs 'mime-charset)))))
 296         mime)
 297     (let ((alist mm-mime-mule-charset-alist)
 298           out)
 299       (while alist
 300         (when (memq charset (cdar alist))
 301           (setq out (caar alist)
 302                 alist nil))
 303         (pop alist))
 304       out)))
 305
 306 (defun mm-charset-to-coding-system (charset &optional lbt)
 307   "Return coding-system corresponding to CHARSET.
 308 CHARSET is a symbol naming a MIME charset.
 309 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 310 used as the line break code type of the coding system."
 311   (when (stringp charset)
 312     (setq charset (intern (downcase charset))))
 313   (when lbt
 314     (setq charset (intern (format "%s-%s" charset lbt))))
 315   (cond
 316    ((null charset)
 317     charset)
 318    ;; Running in a non-MULE environment.
 319    ((null (mm-get-coding-system-list))
 320     charset)
 321    ;; ascii
 322    ((eq charset 'us-ascii)
 323     'ascii)
 324    ;; Check to see whether we can handle this charset.  (This depends
 325    ;; on there being some coding system matching each `mime-charset'
 326    ;; property defined, as there should be.)
 327    ((and (mm-coding-system-p charset)
 328 ;;; Doing this would potentially weed out incorrect charsets.
 329 ;;;      charset
 330 ;;;      (eq charset (coding-system-get charset 'mime-charset))
 331          )
 332     charset)
 333    ;; Translate invalid charsets.
 334    ((let ((cs (cdr (assq charset mm-charset-synonym-alist))))
 335       (and cs (mm-coding-system-p charset) cs)))
 336    ;; Last resort: search the coding system list for entries which
 337    ;; have the right mime-charset in case the canonical name isn't
 338    ;; defined (though it should be).
 339    ((let (cs)
 340       ;; mm-get-coding-system-list returns a list of cs without lbt.
 341       ;; Do we need -lbt?
 342       (dolist (c (mm-get-coding-system-list))
 343         (if (and (null cs)
 344                  (eq charset (coding-system-get c 'mime-charset)))
 345             (setq cs c)))
 346       cs))))
 347
 348 (defsubst mm-replace-chars-in-string (string from to)
 349   (mm-subst-char-in-string from to string))
 350
 351 (eval-and-compile
 352   (defvar mm-emacs-mule (and (not (featurep 'xemacs))
 353                              (boundp 'default-enable-multibyte-characters)
 354                              default-enable-multibyte-characters
 355                              (fboundp 'set-buffer-multibyte))
 356     "Emacs mule.")
 357
 358   (defvar mm-mule4-p (and mm-emacs-mule
 359                           (fboundp 'charsetp)
 360                           (not (charsetp 'eight-bit-control)))
 361     "Mule version 4.")
 362
 363   (if mm-emacs-mule
 364       (defun mm-enable-multibyte ()
 365         "Set the multibyte flag of the current buffer.
 366 Only do this if the default value of `enable-multibyte-characters' is
 367 non-nil.  This is a no-op in XEmacs."
 368         (set-buffer-multibyte t))
 369     (defalias 'mm-enable-multibyte 'ignore))
 370
 371   (if mm-emacs-mule
 372       (defun mm-disable-multibyte ()
 373         "Unset the multibyte flag of in the current buffer.
 374 This is a no-op in XEmacs."
 375         (set-buffer-multibyte nil))
 376     (defalias 'mm-disable-multibyte 'ignore))
 377
 378   (if mm-mule4-p
 379       (defun mm-enable-multibyte-mule4  ()
 380         "Enable multibyte in the current buffer.
 381 Only used in Emacs Mule 4."
 382         (set-buffer-multibyte t))
 383     (defalias 'mm-enable-multibyte-mule4 'ignore))
 384
 385   (if mm-mule4-p
 386       (defun mm-disable-multibyte-mule4 ()
 387         "Disable multibyte in the current buffer.
 388 Only used in Emacs Mule 4."
 389         (set-buffer-multibyte nil))
 390     (defalias 'mm-disable-multibyte-mule4 'ignore)))
 391
 392 (defun mm-preferred-coding-system (charset)
 393   ;; A typo in some Emacs versions.
 394   (or (get-charset-property charset 'preferred-coding-system)
 395       (get-charset-property charset 'prefered-coding-system)))
 396
 397 (defun mm-charset-after (&optional pos)
 398   "Return charset of a character in current buffer at position POS.
 399 If POS is nil, it defauls to the current point.
 400 If POS is out of range, the value is nil.
 401 If the charset is `composition', return the actual one."
 402   (let ((char (char-after pos)) charset)
 403     (if (< (mm-char-int char) 128)
 404         (setq charset 'ascii)
 405       ;; charset-after is fake in some Emacsen.
 406       (setq charset (and (fboundp 'char-charset) (char-charset char)))
 407       (if (eq charset 'composition)
 408           (let ((p (or pos (point))))
 409             (cadr (find-charset-region p (1+ p))))
 410         (if (and charset (not (memq charset '(ascii eight-bit-control
 411                                                     eight-bit-graphic))))
 412             charset
 413           (or
 414            mail-parse-mule-charset ;; cached mule-charset
 415            (progn
 416              (setq mail-parse-mule-charset
 417                    (and (boundp 'current-language-environment)
 418                         (car (last
 419                               (assq 'charset
 420                                     (assoc current-language-environment
 421                                            language-info-alist))))))
 422              (if (or (not mail-parse-mule-charset)
 423                      (eq mail-parse-mule-charset 'ascii))
 424                  (setq mail-parse-mule-charset
 425                        (or (car (last (assq mail-parse-charset
 426                                             mm-mime-mule-charset-alist)))
 427                            ;; Fixme: don't fix that!
 428                            'latin-iso8859-1)))
 429              mail-parse-mule-charset)))))))
 430
 431 (defun mm-mime-charset (charset)
 432   "Return the MIME charset corresponding to the given Mule CHARSET."
 433   (if (eq charset 'unknown)
 434       (error "The message contains non-printable characters, please use attachment"))
 435   (if (and (fboundp 'coding-system-get) (fboundp 'get-charset-property))
 436       ;; This exists in Emacs 20.
 437       (or
 438        (and (mm-preferred-coding-system charset)
 439             (coding-system-get
 440              (mm-preferred-coding-system charset) 'mime-charset))
 441        (and (eq charset 'ascii)
 442             'us-ascii)
 443        (mm-preferred-coding-system charset)
 444        (mm-mule-charset-to-mime-charset charset))
 445     ;; This is for XEmacs.
 446     (mm-mule-charset-to-mime-charset charset)))
 447
 448 (defun mm-delete-duplicates (list)
 449   "Simple  substitute for CL `delete-duplicates', testing with `equal'."
 450   (let (result head)
 451     (while list
 452       (setq head (car list))
 453       (setq list (delete head list))
 454       (setq result (cons head result)))
 455     (nreverse result)))
 456
 457 ;; It's not clear whether this is supposed to mean the global or local
 458 ;; setting.  I think it's used inconsistently.  -- fx
 459 (defsubst mm-multibyte-p ()
 460   "Say whether multibyte is enabled."
 461   (if (and (not (featurep 'xemacs))
 462            (boundp 'enable-multibyte-characters))
 463       enable-multibyte-characters
 464     (featurep 'mule)))
 465
 466 (defun mm-iso-8859-x-to-15-region (&optional b e)
 467   (if (fboundp 'char-charset)
 468       (let (charset item c inconvertible)
 469         (save-restriction
 470           (if e (narrow-to-region b e))
 471           (goto-char (point-min))
 472           (skip-chars-forward "\0-\177")
 473           (while (not (eobp))
 474             (cond
 475              ((not (setq item (assq (char-charset (setq c (char-after)))
 476                                     mm-iso-8859-x-to-15-table)))
 477               (forward-char))
 478              ((memq c (cdr (cdr item)))
 479               (setq inconvertible t)
 480               (forward-char))
 481              (t
 482               (insert-before-markers (prog1 (+ c (car (cdr item)))
 483                                        (delete-char 1))))
 484             (skip-chars-forward "\0-\177"))))
 485         (not inconvertible))))
 486
 487 (defun mm-sort-coding-systems-predicate (a b)
 488   (> (length (memq a mm-coding-system-priorities))
 489      (length (memq b mm-coding-system-priorities))))
 490
 491 (defun mm-find-mime-charset-region (b e &optional hack-charsets)
 492   "Return the MIME charsets needed to encode the region between B and E.
 493 nil means ASCII, a single-element list represents an appropriate MIME
 494 charset, and a longer list means no appropriate charset."
 495   (let (charsets)
 496     ;; The return possibilities of this function are a mess...
 497     (or (and (mm-multibyte-p)
 498              (fboundp 'find-coding-systems-region)
 499              ;; Find the mime-charset of the most preferred coding
 500              ;; system that has one.
 501              (let ((systems (find-coding-systems-region b e)))
 502                (when mm-coding-system-priorities
 503                  (setq systems
 504                        (sort systems 'mm-sort-coding-systems-predicate)))
 505                ;; Fixme: The `mime-charset' (`x-ctext') of `compound-text'
 506                ;; is not in the IANA list.
 507                (setq systems (delq 'compound-text systems))
 508                (unless (equal systems '(undecided))
 509                  (while systems
 510                    (let ((cs (coding-system-get (pop systems) 'mime-charset)))
 511                      (if cs
 512                          (setq systems nil
 513                                charsets (list cs))))))
 514                charsets))
 515         ;; Otherwise we're not multibyte, XEmacs or a single coding
 516         ;; system won't cover it.
 517         (setq charsets
 518               (mm-delete-duplicates
 519                (mapcar 'mm-mime-charset
 520                        (delq 'ascii
 521                              (mm-find-charset-region b e))))))
 522     (if (and (memq 'iso-8859-15 charsets)
 523              (memq 'iso-8859-15 hack-charsets)
 524              (save-excursion (mm-iso-8859-x-to-15-region b e)))
 525         (mapcar (lambda (x) (setq charsets (delq (car x) charsets)))
 526                 mm-iso-8859-15-compatible))
 527     (if (and (memq 'iso-2022-jp-2 charsets)
 528              (memq 'iso-2022-jp-2 hack-charsets))
 529         (setq charsets (delq 'iso-2022-jp charsets)))
 530     charsets))
 531
 532 (defmacro mm-with-unibyte-buffer (&rest forms)
 533   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 534 Use unibyte mode for this."
 535   `(let (default-enable-multibyte-characters)
 536      (with-temp-buffer ,@forms)))
 537 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 538 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 539
 540 (defmacro mm-with-unibyte-current-buffer (&rest forms)
 541   "Evaluate FORMS with current current buffer temporarily made unibyte.
 542 Also bind `default-enable-multibyte-characters' to nil.
 543 Equivalent to `progn' in XEmacs"
 544   (let ((multibyte (make-symbol "multibyte"))
 545         (buffer (make-symbol "buffer")))
 546     `(if mm-emacs-mule
 547          (let ((,multibyte enable-multibyte-characters)
 548                (,buffer (current-buffer)))
 549            (unwind-protect
 550                (let (default-enable-multibyte-characters)
 551                  (set-buffer-multibyte nil)
 552                  ,@forms)
 553              (set-buffer ,buffer)
 554              (set-buffer-multibyte ,multibyte)))
 555        (let (default-enable-multibyte-characters)
 556          ,@forms))))
 557 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 558 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 559
 560 (defmacro mm-with-unibyte-current-buffer-mule4 (&rest forms)
 561   "Evaluate FORMS there like `progn' in current buffer.
 562 Mule4 only."
 563   (let ((multibyte (make-symbol "multibyte"))
 564         (buffer (make-symbol "buffer")))
 565     `(if mm-mule4-p
 566          (let ((,multibyte enable-multibyte-characters)
 567                (,buffer (current-buffer)))
 568            (unwind-protect
 569                (let (default-enable-multibyte-characters)
 570                  (set-buffer-multibyte nil)
 571                  ,@forms)
 572              (set-buffer ,buffer)
 573              (set-buffer-multibyte ,multibyte)))
 574        (let (default-enable-multibyte-characters)
 575          ,@forms))))
 576 (put 'mm-with-unibyte-current-buffer-mule4 'lisp-indent-function 0)
 577 (put 'mm-with-unibyte-current-buffer-mule4 'edebug-form-spec '(body))
 578
 579 (defmacro mm-with-unibyte (&rest forms)
 580   "Eval the FORMS with the default value of `enable-multibyte-characters' nil, ."
 581   `(let (default-enable-multibyte-characters)
 582      ,@forms))
 583 (put 'mm-with-unibyte 'lisp-indent-function 0)
 584 (put 'mm-with-unibyte 'edebug-form-spec '(body))
 585
 586 (defun mm-find-charset-region (b e)
 587   "Return a list of Emacs charsets in the region B to E."
 588   (cond
 589    ((and (mm-multibyte-p)
 590          (fboundp 'find-charset-region))
 591     ;; Remove composition since the base charsets have been included.
 592     ;; Remove eight-bit-*, treat them as ascii.
 593     (let ((css (find-charset-region b e)))
 594       (mapcar (lambda (cs) (setq css (delq cs css)))
 595               '(composition eight-bit-control eight-bit-graphic
 596                             control-1))
 597       css))
 598    (t
 599     ;; We are in a unibyte buffer or XEmacs non-mule, so we futz around a bit.
 600     (save-excursion
 601       (save-restriction
 602         (narrow-to-region b e)
 603         (goto-char (point-min))
 604         (skip-chars-forward "\0-\177")
 605         (if (eobp)
 606             '(ascii)
 607           (let (charset)
 608             (setq charset
 609                   (and (boundp 'current-language-environment)
 610                        (car (last (assq 'charset
 611                                         (assoc current-language-environment
 612                                                language-info-alist))))))
 613             (if (eq charset 'ascii) (setq charset nil))
 614             (or charset
 615                 (setq charset
 616                       (car (last (assq mail-parse-charset
 617                                        mm-mime-mule-charset-alist)))))
 618             (list 'ascii (or charset 'latin-iso8859-1)))))))))
 619
 620 (if (fboundp 'shell-quote-argument)
 621     (defalias 'mm-quote-arg 'shell-quote-argument)
 622   (defun mm-quote-arg (arg)
 623     "Return a version of ARG that is safe to evaluate in a shell."
 624     (let ((pos 0) new-pos accum)
 625       ;; *** bug: we don't handle newline characters properly
 626       (while (setq new-pos (string-match "[]*[;!'`\"$\\& \t{} |()<>]" arg pos))
 627         (push (substring arg pos new-pos) accum)
 628         (push "\\" accum)
 629         (push (list (aref arg new-pos)) accum)
 630         (setq pos (1+ new-pos)))
 631       (if (= pos 0)
 632           arg
 633         (apply 'concat (nconc (nreverse accum) (list (substring arg pos))))))))
 634
 635 (defun mm-auto-mode-alist ()
 636   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 637   (let ((alist auto-mode-alist)
 638         out)
 639     (while alist
 640       (when (listp (cdar alist))
 641         (push (car alist) out))
 642       (pop alist))
 643     (nreverse out)))
 644
 645 (defvar mm-inhibit-file-name-handlers
 646   '(jka-compr-handler image-file-handler)
 647   "A list of handlers doing (un)compression (etc) thingies.")
 648
 649 (defun mm-insert-file-contents (filename &optional visit beg end replace
 650                                          inhibit)
 651   "Like `insert-file-contents', q.v., but only reads in the file.
 652 A buffer may be modified in several ways after reading into the buffer due
 653 to advanced Emacs features, such as file-name-handlers, format decoding,
 654 find-file-hooks, etc.
 655 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers.
 656   This function ensures that none of these modifications will take place."
 657   (let ((format-alist nil)
 658         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 659         (default-major-mode 'fundamental-mode)
 660         (enable-local-variables nil)
 661         (after-insert-file-functions nil)
 662         (enable-local-eval nil)
 663         (find-file-hooks nil)
 664         (inhibit-file-name-operation (if inhibit
 665                                          'insert-file-contents
 666                                        inhibit-file-name-operation))
 667         (inhibit-file-name-handlers
 668          (if inhibit
 669              (append mm-inhibit-file-name-handlers
 670                      inhibit-file-name-handlers)
 671            inhibit-file-name-handlers)))
 672     (insert-file-contents filename visit beg end replace)))
 673
 674 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 675   "Append the contents of the region to the end of file FILENAME.
 676 When called from a function, expects three arguments,
 677 START, END and FILENAME.  START and END are buffer positions
 678 saying what text to write.
 679 Optional fourth argument specifies the coding system to use when
 680 encoding the file.
 681 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 682   (let ((coding-system-for-write
 683          (or codesys mm-text-coding-system-for-write
 684              mm-text-coding-system))
 685         (inhibit-file-name-operation (if inhibit
 686                                          'append-to-file
 687                                        inhibit-file-name-operation))
 688         (inhibit-file-name-handlers
 689          (if inhibit
 690              (append mm-inhibit-file-name-handlers
 691                      inhibit-file-name-handlers)
 692            inhibit-file-name-handlers)))
 693     (append-to-file start end filename)))
 694
 695 (defun mm-write-region (start end filename &optional append visit lockname
 696                               coding-system inhibit)
 697
 698   "Like `write-region'.
 699 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 700   (let ((coding-system-for-write
 701          (or coding-system mm-text-coding-system-for-write
 702              mm-text-coding-system))
 703         (inhibit-file-name-operation (if inhibit
 704                                          'write-region
 705                                        inhibit-file-name-operation))
 706         (inhibit-file-name-handlers
 707          (if inhibit
 708              (append mm-inhibit-file-name-handlers
 709                      inhibit-file-name-handlers)
 710            inhibit-file-name-handlers)))
 711     (write-region start end filename append visit lockname)))
 712
 713 (defun mm-image-load-path (&optional package)
 714   (let (dir result)
 715     (dolist (path load-path (nreverse result))
 716       (if (file-directory-p
 717            (setq dir (concat (file-name-directory
 718                               (directory-file-name path))
 719                              "etc/" (or package "gnus/"))))
 720           (push dir result))
 721       (push path result))))
 722
 723 (provide 'mm-util)
 724
 725 ;;; mm-util.el ends here