cgit.sxemacs.org Git - gnus/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for Mule and low level things
   2 ;; Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28 (require 'mail-prsvr)
  29
  30 (defvar mm-mime-mule-charset-alist
  31   '((us-ascii ascii)
  32     (iso-8859-1 latin-iso8859-1)
  33     (iso-8859-2 latin-iso8859-2)
  34     (iso-8859-3 latin-iso8859-3)
  35     (iso-8859-4 latin-iso8859-4)
  36     (iso-8859-5 cyrillic-iso8859-5)
  37     ;; Non-mule (X)Emacs uses the last mule-charset for 8bit characters.
  38     ;; The fake mule-charset, gnus-koi8-r, tells Gnus that the default
  39     ;; charset is koi8-r, not iso-8859-5.
  40     (koi8-r cyrillic-iso8859-5 gnus-koi8-r)
  41     (iso-8859-6 arabic-iso8859-6)
  42     (iso-8859-7 greek-iso8859-7)
  43     (iso-8859-8 hebrew-iso8859-8)
  44     (iso-8859-9 latin-iso8859-9)
  45     (iso-8859-14 latin-iso8859-14)
  46     (iso-8859-15 latin-iso8859-15)
  47     (viscii vietnamese-viscii-lower)
  48     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
  49     (euc-kr korean-ksc5601)
  50     (cn-gb-2312 chinese-gb2312)
  51     (cn-big5 chinese-big5-1 chinese-big5-2)
  52     (tibetan tibetan)
  53     (thai-tis620 thai-tis620)
  54     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
  55     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
  56                    latin-jisx0201 japanese-jisx0208-1978
  57                    chinese-gb2312 japanese-jisx0208
  58                    korean-ksc5601 japanese-jisx0212
  59                    katakana-jisx0201)
  60     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
  61                     latin-jisx0201 japanese-jisx0208-1978
  62                     chinese-gb2312 japanese-jisx0208
  63                     korean-ksc5601 japanese-jisx0212
  64                     chinese-cns11643-1 chinese-cns11643-2)
  65     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
  66                     cyrillic-iso8859-5 greek-iso8859-7
  67                     latin-jisx0201 japanese-jisx0208-1978
  68                     chinese-gb2312 japanese-jisx0208
  69                     korean-ksc5601 japanese-jisx0212
  70                     chinese-cns11643-1 chinese-cns11643-2
  71                     chinese-cns11643-3 chinese-cns11643-4
  72                     chinese-cns11643-5 chinese-cns11643-6
  73                     chinese-cns11643-7)
  74     (utf-8 unicode-a unicode-b unicode-c unicode-d unicode-e))
  75   "Alist of MIME-charset/MULE-charsets.")
  76
  77 (eval-and-compile
  78   (mapcar
  79    (lambda (elem)
  80      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  81        (if (fboundp (car elem))
  82            (defalias nfunc (car elem))
  83          (defalias nfunc (cdr elem)))))
  84    '((decode-coding-string . (lambda (s a) s))
  85      (encode-coding-string . (lambda (s a) s))
  86      (encode-coding-region . ignore)
  87      (coding-system-list . ignore)
  88      (decode-coding-region . ignore)
  89      (char-int . identity)
  90      (device-type . ignore)
  91      (coding-system-equal . equal)
  92      (annotationp . ignore)
  93      (set-buffer-file-coding-system . ignore)
  94      (make-char
  95       . (lambda (charset int)
  96           (int-to-char int)))
  97      (read-coding-system
  98       . (lambda (prompt)
  99           "Prompt the user for a coding system."
 100           (completing-read
 101            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
 102                           mm-mime-mule-charset-alist))))
 103      (read-charset
 104       . (lambda (prompt)
 105           "Return a charset."
 106           (intern
 107            (completing-read
 108             prompt
 109             (mapcar (lambda (e) (list (symbol-name (car e))))
 110                     mm-mime-mule-charset-alist)
 111             nil t))))
 112      (subst-char-in-string
 113       . (lambda (from to string) ;; stolen (and renamed) from nnheader.el
 114           "Replace characters in STRING from FROM to TO."
 115           (let ((string (substring string 0))   ;Copy string.
 116                 (len (length string))
 117                 (idx 0))
 118             ;; Replace all occurrences of FROM with TO.
 119             (while (< idx len)
 120               (when (= (aref string idx) from)
 121                 (aset string idx to))
 122               (setq idx (1+ idx)))
 123             string)))
 124      (string-as-unibyte . identity)
 125       )))
 126
 127 (eval-and-compile
 128   (defalias 'mm-char-or-char-int-p
 129     (cond
 130      ((fboundp 'char-or-char-int-p) 'char-or-char-int-p)
 131      ((fboundp 'char-valid-p) 'char-valid-p)
 132      (t 'identity))))
 133
 134 (defvar mm-coding-system-list nil)
 135 (defun mm-get-coding-system-list ()
 136   "Get the coding system list."
 137   (or mm-coding-system-list
 138       (setq mm-coding-system-list (mm-coding-system-list))))
 139
 140 (defun mm-coding-system-p (sym)
 141   "Return non-nil if SYM is a coding system."
 142   (or (and (fboundp 'coding-system-p) (coding-system-p sym))
 143       (memq sym (mm-get-coding-system-list))))
 144
 145 (defvar mm-charset-synonym-alist
 146   `((big5 . cn-big5)
 147     (gb2312 . cn-gb-2312)
 148     (cn-gb . cn-gb-2312)
 149     ;; Windows-1252 is actually a superset of Latin-1.  See also
 150     ;; `gnus-article-dumbquotes-map'.
 151     ,(unless (mm-coding-system-p 'windows-1252) ; should be defined eventually
 152        '(windows-1252 . iso-8859-1))
 153     (x-ctext . ctext))
 154   "A mapping from invalid charset names to the real charset names.")
 155
 156 (defvar mm-binary-coding-system
 157   (cond
 158    ((mm-coding-system-p 'binary) 'binary)
 159    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 160    (t nil))
 161   "100% binary coding system.")
 162
 163 (defvar mm-text-coding-system
 164   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 165           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 166         (and (mm-coding-system-p 'raw-text) 'raw-text))
 167       mm-binary-coding-system)
 168   "Text-safe coding system (For removing ^M).")
 169
 170 (defvar mm-text-coding-system-for-write nil
 171   "Text coding system for write.")
 172
 173 (defvar mm-auto-save-coding-system
 174   (cond
 175    ((mm-coding-system-p 'emacs-mule)
 176     (if (memq system-type '(windows-nt ms-dos ms-windows))
 177         (if (mm-coding-system-p 'emacs-mule-dos)
 178             'emacs-mule-dos mm-binary-coding-system)
 179       'emacs-mule))
 180    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 181    (t mm-binary-coding-system))
 182   "Coding system of auto save file.")
 183
 184 ;;; Internal variables:
 185
 186 ;;; Functions:
 187
 188 (defun mm-mule-charset-to-mime-charset (charset)
 189   "Return the MIME charset corresponding to the given Mule CHARSET."
 190   (let ((alist mm-mime-mule-charset-alist)
 191         out)
 192     (while alist
 193       (when (memq charset (cdar alist))
 194         (setq out (caar alist)
 195               alist nil))
 196       (pop alist))
 197     out))
 198
 199 (defun mm-charset-to-coding-system (charset &optional lbt)
 200   "Return coding-system corresponding to CHARSET.
 201 CHARSET is a symbol naming a MIME charset.
 202 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 203 used as the line break code type of the coding system."
 204   (when (stringp charset)
 205     (setq charset (intern (downcase charset))))
 206   (setq charset
 207         (or (cdr (assq charset mm-charset-synonym-alist))
 208             charset))
 209   (when lbt
 210     (setq charset (intern (format "%s-%s" charset lbt))))
 211   (cond
 212    ;; Running in a non-MULE environment.
 213    ((null (mm-get-coding-system-list))
 214     charset)
 215    ;; ascii
 216    ((eq charset 'us-ascii)
 217     'ascii)
 218    ;; Check to see whether we can handle this charset.  (This depends
 219    ;; on there being some coding system matching each `mime-charset'
 220    ;; coding sysytem property defined, as there should be.)
 221    ((memq charset (mm-get-coding-system-list))
 222     charset)
 223    ;; Nope.
 224    (t
 225     nil)))
 226
 227 (defsubst mm-replace-chars-in-string (string from to)
 228   (mm-subst-char-in-string from to string))
 229
 230 (defsubst mm-enable-multibyte ()
 231   "Set the multibyte flag of the current buffer.
 232 Only do this if the default value of `enable-multibyte-characters' is
 233 non-nil.  This is a no-op in XEmacs."
 234   (when (and (not (featurep 'xemacs))
 235              (boundp 'default-enable-multibyte-characters)
 236              default-enable-multibyte-characters
 237              (fboundp 'set-buffer-multibyte))
 238     (set-buffer-multibyte t)))
 239
 240 (defsubst mm-disable-multibyte ()
 241   "Unset the multibyte flag of in the current buffer.
 242 This is a no-op in XEmacs."
 243   (when (and (not (featurep 'xemacs))
 244              (fboundp 'set-buffer-multibyte))
 245     (set-buffer-multibyte nil)))
 246
 247 (defsubst mm-enable-multibyte-mule4 ()
 248   "Enable multibyte in the current buffer.
 249 Only used in Emacs Mule 4."
 250   (when (and (not (featurep 'xemacs))
 251              (boundp 'default-enable-multibyte-characters)
 252              default-enable-multibyte-characters
 253              (fboundp 'set-buffer-multibyte)
 254              (fboundp 'charsetp)
 255              (not (charsetp 'eight-bit-control)))
 256     (set-buffer-multibyte t)))
 257
 258 (defsubst mm-disable-multibyte-mule4 ()
 259   "Disable multibyte in the current buffer.
 260 Only used in Emacs Mule 4."
 261   (when (and (not (featurep 'xemacs))
 262              (fboundp 'set-buffer-multibyte)
 263              (fboundp 'charsetp)
 264              (not (charsetp 'eight-bit-control)))
 265     (set-buffer-multibyte nil)))
 266
 267 (defun mm-preferred-coding-system (charset)
 268   ;; A typo in some Emacs versions.
 269   (or (get-charset-property charset 'prefered-coding-system)
 270       (get-charset-property charset 'preferred-coding-system)))
 271
 272 (defun mm-charset-after (&optional pos)
 273   "Return charset of a character in current buffer at position POS.
 274 If POS is nil, it defauls to the current point.
 275 If POS is out of range, the value is nil.
 276 If the charset is `composition', return the actual one."
 277   (let ((char (char-after pos)) charset)
 278     (if (< (mm-char-int char) 128)
 279         (setq charset 'ascii)
 280       ;; charset-after is fake in some Emacsen.
 281       (setq charset (and (fboundp 'char-charset) (char-charset char)))
 282       (if (eq charset 'composition)
 283           (let ((p (or pos (point))))
 284             (cadr (find-charset-region p (1+ p))))
 285         (if (and charset (not (memq charset '(ascii eight-bit-control
 286                                                     eight-bit-graphic))))
 287             charset
 288           (or
 289            mail-parse-mule-charset ;; cached mule-charset
 290            (progn
 291              (setq mail-parse-mule-charset
 292                    (and (boundp 'current-language-environment)
 293                       (car (last
 294                             (assq 'charset
 295                                   (assoc current-language-environment
 296                                          language-info-alist))))))
 297              (if (or (not mail-parse-mule-charset)
 298                      (eq mail-parse-mule-charset 'ascii))
 299                  (setq mail-parse-mule-charset
 300                        (or (car (last (assq mail-parse-charset
 301                                             mm-mime-mule-charset-alist)))
 302                            'latin-iso8859-1)))
 303              mail-parse-mule-charset)))))))
 304
 305 (defun mm-mime-charset (charset)
 306   "Return the MIME charset corresponding to the MULE CHARSET."
 307   (if (eq charset 'unknown)
 308       (error "8-bit characters are found in the message, please specify charset."))
 309   (if (and (fboundp 'coding-system-get) (fboundp 'get-charset-property))
 310       ;; This exists in Emacs 20.
 311       (or
 312        (and (mm-preferred-coding-system charset)
 313             (coding-system-get
 314              (mm-preferred-coding-system charset) 'mime-charset))
 315        (and (eq charset 'ascii)
 316             'us-ascii)
 317        (mm-preferred-coding-system charset)
 318        (mm-mule-charset-to-mime-charset charset))
 319     ;; This is for XEmacs.
 320     (mm-mule-charset-to-mime-charset charset)))
 321
 322 (defun mm-delete-duplicates (list)
 323   "Simple  substitute for CL `delete-duplicates', testing with `equal'."
 324   (let (result head)
 325     (while list
 326       (setq head (car list))
 327       (setq list (delete head list))
 328       (setq result (cons head result)))
 329     (nreverse result)))
 330
 331 (defun mm-find-mime-charset-region (b e)
 332   "Return the MIME charsets needed to encode the region between B and E."
 333   (let ((charsets (mapcar 'mm-mime-charset
 334                           (delq 'ascii
 335                                 (mm-find-charset-region b e)))))
 336     (when (memq 'iso-2022-jp-2 charsets)
 337       (setq charsets (delq 'iso-2022-jp charsets)))
 338     (setq charsets (mm-delete-duplicates charsets))
 339     (if (and (> (length charsets) 1)
 340              (fboundp 'find-coding-systems-region)
 341              (memq 'utf-8 (find-coding-systems-region b e)))
 342         '(utf-8)
 343       charsets)))
 344
 345 (defsubst mm-multibyte-p ()
 346   "Say whether multibyte is enabled."
 347   (if (and (not (featurep 'xemacs))
 348            (boundp 'enable-multibyte-characters))
 349       enable-multibyte-characters
 350     (featurep 'mule)))
 351
 352 (defmacro mm-with-unibyte-buffer (&rest forms)
 353   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 354 Use unibyte mode for this."
 355   `(let (default-enable-multibyte-characters)
 356      (with-temp-buffer ,@forms)))
 357 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 358 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 359
 360 (defmacro mm-with-unibyte-current-buffer (&rest forms)
 361   "Evaluate FORMS with current current buffer temporarily made unibyte.
 362 Also bind `default-enable-multibyte-characters' to nil.
 363 Equivalent to `progn' in XEmacs"
 364   (let ((buffer (make-symbol "buffer")))
 365     `(if (and (not (featurep 'xemacs))
 366               (boundp 'enable-multibyte-characters)
 367               enable-multibyte-characters
 368               (fboundp 'set-buffer-multibyte))
 369          (let ((,buffer (current-buffer)))
 370            (unwind-protect
 371                (let (default-enable-multibyte-characters)
 372                  (set-buffer-multibyte nil)
 373                  ,@forms)
 374              (set-buffer ,buffer)
 375              (set-buffer-multibyte t)))
 376        (let (default-enable-multibyte-characters)
 377          ,@forms))))
 378 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 379 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 380
 381 (defmacro mm-with-unibyte-current-buffer-mule4 (&rest forms)
 382   "Evaluate FORMS there like `progn' in current buffer.
 383 Mule4 only."
 384   (let ((buffer (make-symbol "buffer")))
 385     `(if (and (not (featurep 'xemacs))
 386               (boundp 'enable-multibyte-characters)
 387               enable-multibyte-characters
 388               (fboundp 'set-buffer-multibyte)
 389               (fboundp 'charsetp)
 390               (not (charsetp 'eight-bit-control))) ;; For Emacs Mule 4 only.
 391        (let ((,buffer (current-buffer)))
 392          (unwind-protect
 393              (let (default-enable-multibyte-characters)
 394                (set-buffer-multibyte nil)
 395                ,@forms)
 396            (set-buffer ,buffer)
 397            (set-buffer-multibyte t)))
 398        (let (default-enable-multibyte-characters)
 399          ,@forms))))
 400 (put 'mm-with-unibyte-current-buffer-mule4 'lisp-indent-function 0)
 401 (put 'mm-with-unibyte-current-buffer-mule4 'edebug-form-spec '(body))
 402
 403 (defmacro mm-with-unibyte (&rest forms)
 404   "Eval the FORMS with the default value of `enable-multibyte-characters' nil, ."
 405   `(let (default-enable-multibyte-characters)
 406      ,@forms))
 407 (put 'mm-with-unibyte 'lisp-indent-function 0)
 408 (put 'mm-with-unibyte 'edebug-form-spec '(body))
 409
 410 (defun mm-find-charset-region (b e)
 411   "Return a list of Emacs charsets in the region B to E."
 412   (cond
 413    ((and (mm-multibyte-p)
 414          (fboundp 'find-charset-region))
 415     ;; Remove composition since the base charsets have been included.
 416     ;; Remove eight-bit-*, treat them as ascii.
 417     (let ((css (find-charset-region b e)))
 418       (mapcar (lambda (cs) (setq css (delq cs css)))
 419               '(composition eight-bit-control eight-bit-graphic))
 420       css))
 421    (t
 422     ;; We are in a unibyte buffer or XEmacs non-mule, so we futz around a bit.
 423     (save-excursion
 424       (save-restriction
 425         (narrow-to-region b e)
 426         (goto-char (point-min))
 427         (skip-chars-forward "\0-\177")
 428         (if (eobp)
 429             '(ascii)
 430           (let (charset)
 431             (setq charset
 432                   (and (boundp 'current-language-environment)
 433                        (car (last (assq 'charset
 434                                         (assoc current-language-environment
 435                                                language-info-alist))))))
 436             (if (eq charset 'ascii) (setq charset nil))
 437             (or charset
 438                 (setq charset
 439                       (car (last (assq mail-parse-charset
 440                                        mm-mime-mule-charset-alist)))))
 441             (list 'ascii (or charset 'latin-iso8859-1)))))))))
 442
 443 (if (fboundp 'shell-quote-argument)
 444     (defalias 'mm-quote-arg 'shell-quote-argument)
 445   (defun mm-quote-arg (arg)
 446     "Return a version of ARG that is safe to evaluate in a shell."
 447     (let ((pos 0) new-pos accum)
 448       ;; *** bug: we don't handle newline characters properly
 449       (while (setq new-pos (string-match "[]*[;!'`\"$\\& \t{} |()<>]" arg pos))
 450         (push (substring arg pos new-pos) accum)
 451         (push "\\" accum)
 452         (push (list (aref arg new-pos)) accum)
 453         (setq pos (1+ new-pos)))
 454       (if (= pos 0)
 455           arg
 456         (apply 'concat (nconc (nreverse accum) (list (substring arg pos))))))))
 457
 458 (defun mm-auto-mode-alist ()
 459   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 460   (let ((alist auto-mode-alist)
 461         out)
 462     (while alist
 463       (when (listp (cdar alist))
 464         (push (car alist) out))
 465       (pop alist))
 466     (nreverse out)))
 467
 468 (defvar mm-inhibit-file-name-handlers
 469   '(jka-compr-handler)
 470   "A list of handlers doing (un)compression (etc) thingies.")
 471
 472 (defun mm-insert-file-contents (filename &optional visit beg end replace
 473                                          inhibit)
 474   "Like `insert-file-contents', q.v., but only reads in the file.
 475 A buffer may be modified in several ways after reading into the buffer due
 476 to advanced Emacs features, such as file-name-handlers, format decoding,
 477 find-file-hooks, etc.
 478 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers.
 479   This function ensures that none of these modifications will take place."
 480   (let ((format-alist nil)
 481         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 482         (default-major-mode 'fundamental-mode)
 483         (enable-local-variables nil)
 484         (after-insert-file-functions nil)
 485         (enable-local-eval nil)
 486         (find-file-hooks nil)
 487         (inhibit-file-name-operation (if inhibit
 488                                          'insert-file-contents
 489                                        inhibit-file-name-operation))
 490         (inhibit-file-name-handlers
 491          (if inhibit
 492              (append mm-inhibit-file-name-handlers
 493                      inhibit-file-name-handlers)
 494            inhibit-file-name-handlers)))
 495     (insert-file-contents filename visit beg end replace)))
 496
 497 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 498   "Append the contents of the region to the end of file FILENAME.
 499 When called from a function, expects three arguments,
 500 START, END and FILENAME.  START and END are buffer positions
 501 saying what text to write.
 502 Optional fourth argument specifies the coding system to use when
 503 encoding the file.
 504 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 505   (let ((coding-system-for-write
 506          (or codesys mm-text-coding-system-for-write
 507              mm-text-coding-system))
 508         (inhibit-file-name-operation (if inhibit
 509                                          'append-to-file
 510                                        inhibit-file-name-operation))
 511         (inhibit-file-name-handlers
 512          (if inhibit
 513              (append mm-inhibit-file-name-handlers
 514                      inhibit-file-name-handlers)
 515            inhibit-file-name-handlers)))
 516     (append-to-file start end filename)))
 517
 518 (defun mm-write-region (start end filename &optional append visit lockname
 519                               coding-system inhibit)
 520
 521   "Like `write-region'.
 522 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 523   (let ((coding-system-for-write
 524          (or coding-system mm-text-coding-system-for-write
 525              mm-text-coding-system))
 526         (inhibit-file-name-operation (if inhibit
 527                                          'write-region
 528                                        inhibit-file-name-operation))
 529         (inhibit-file-name-handlers
 530          (if inhibit
 531              (append mm-inhibit-file-name-handlers
 532                      inhibit-file-name-handlers)
 533            inhibit-file-name-handlers)))
 534     (write-region start end filename append visit lockname)))
 535
 536 (defun mm-image-load-path (&optional package)
 537   (let (dir result)
 538     (dolist (path load-path (nreverse result))
 539       (if (file-directory-p
 540            (setq dir (concat (file-name-directory
 541                               (directory-file-name path))
 542                              "etc/" (or package "gnus/"))))
 543           (push dir result))
 544       (push path result))))
 545
 546 (provide 'mm-util)
 547
 548 ;;; mm-util.el ends here