cgit.sxemacs.org Git - gnus/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for Mule and low level things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;   Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29 (require 'mail-prsvr)
  30
  31 (eval-and-compile
  32   (mapcar
  33    (lambda (elem)
  34      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  35        (if (fboundp (car elem))
  36            (defalias nfunc (car elem))
  37          (defalias nfunc (cdr elem)))))
  38    '((decode-coding-string . (lambda (s a) s))
  39      (encode-coding-string . (lambda (s a) s))
  40      (encode-coding-region . ignore)
  41      (coding-system-list . ignore)
  42      (decode-coding-region . ignore)
  43      (char-int . identity)
  44      (coding-system-equal . equal)
  45      (annotationp . ignore)
  46      (set-buffer-file-coding-system . ignore)
  47      (read-charset
  48       . (lambda (prompt)
  49           "Return a charset."
  50           (intern
  51            (completing-read
  52             prompt
  53             (mapcar (lambda (e) (list (symbol-name (car e))))
  54                     mm-mime-mule-charset-alist)
  55             nil t))))
  56      (subst-char-in-string
  57       . (lambda (from to string &optional inplace) ;; stolen (and renamed) from nnheader.el
  58           "Replace characters in STRING from FROM to TO.
  59           Unless optional argument INPLACE is non-nil, return a new string."
  60           (let ((string (if inplace string (copy-sequence string)))
  61                 (len (length string))
  62                 (idx 0))
  63             ;; Replace all occurrences of FROM with TO.
  64             (while (< idx len)
  65               (when (= (aref string idx) from)
  66                 (aset string idx to))
  67               (setq idx (1+ idx)))
  68             string)))
  69      (replace-in-string
  70       . (lambda (string regexp rep &optional literal)
  71           "See `replace-regexp-in-string', only the order of args differs."
  72           (replace-regexp-in-string regexp rep string nil literal)))
  73      (string-as-unibyte . identity)
  74      (string-make-unibyte . identity)
  75      (string-as-multibyte . identity)
  76      (multibyte-string-p . ignore)
  77      ;; It is not a MIME function, but some MIME functions use it.
  78      (make-temp-file . (lambda (prefix &optional dir-flag)
  79                          (let ((file (expand-file-name
  80                                       (make-temp-name prefix)
  81                                       (if (fboundp 'temp-directory)
  82                                           (temp-directory)
  83                                         temporary-file-directory))))
  84                            (if dir-flag
  85                                (make-directory file))
  86                            file)))
  87      (insert-byte . insert-char)
  88      (multibyte-char-to-unibyte . identity))))
  89
  90 (eval-and-compile
  91   (defalias 'mm-char-or-char-int-p
  92     (cond
  93      ((fboundp 'char-or-char-int-p) 'char-or-char-int-p)
  94      ((fboundp 'char-valid-p) 'char-valid-p)
  95      (t 'identity))))
  96
  97 ;; Fixme:  This seems always to be used to read a MIME charset, so it
  98 ;; should be re-named and fixed (in Emacs) to offer completion only on
  99 ;; proper charset names (base coding systems which have a
 100 ;; mime-charset defined).  XEmacs doesn't believe in mime-charset;
 101 ;; test with
 102 ;;   `(or (coding-system-get 'iso-8859-1 'mime-charset)
 103 ;;        (coding-system-get 'iso-8859-1 :mime-charset))'
 104 ;; Actually, there should be an `mm-coding-system-mime-charset'.
 105 (eval-and-compile
 106   (defalias 'mm-read-coding-system
 107     (cond
 108      ((fboundp 'read-coding-system)
 109       (if (and (featurep 'xemacs)
 110                (<= (string-to-number emacs-version) 21.1))
 111           (lambda (prompt &optional default-coding-system)
 112             (read-coding-system prompt))
 113         'read-coding-system))
 114      (t (lambda (prompt &optional default-coding-system)
 115           "Prompt the user for a coding system."
 116           (completing-read
 117            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
 118                           mm-mime-mule-charset-alist)))))))
 119
 120 (defvar mm-coding-system-list nil)
 121 (defun mm-get-coding-system-list ()
 122   "Get the coding system list."
 123   (or mm-coding-system-list
 124       (setq mm-coding-system-list (mm-coding-system-list))))
 125
 126 (defun mm-coding-system-p (cs)
 127   "Return non-nil if CS is a symbol naming a coding system.
 128 In XEmacs, also return non-nil if CS is a coding system object.
 129 If CS is available, return CS itself in Emacs, and return a coding
 130 system object in XEmacs."
 131   (if (fboundp 'find-coding-system)
 132       (find-coding-system cs)
 133     (if (fboundp 'coding-system-p)
 134         (when (coding-system-p cs)
 135           cs)
 136       ;; Is this branch ever actually useful?
 137       (car (memq cs (mm-get-coding-system-list))))))
 138
 139 (defvar mm-charset-synonym-alist
 140   `(
 141     ;; Not in XEmacs, but it's not a proper MIME charset anyhow.
 142     ,@(unless (mm-coding-system-p 'x-ctext)
 143        '((x-ctext . ctext)))
 144     ;; ISO-8859-15 is very similar to ISO-8859-1.  But it's _different_!
 145     ,@(unless (mm-coding-system-p 'iso-8859-15)
 146        '((iso-8859-15 . iso-8859-1)))
 147     ;; BIG-5HKSCS is similar to, but different than, BIG-5.
 148     ,@(unless (mm-coding-system-p 'big5-hkscs)
 149         '((big5-hkscs . big5)))
 150     ;; Windows-1252 is actually a superset of Latin-1.  See also
 151     ;; `gnus-article-dumbquotes-map'.
 152     ,@(unless (mm-coding-system-p 'windows-1252)
 153        (if (mm-coding-system-p 'cp1252)
 154            '((windows-1252 . cp1252))
 155          '((windows-1252 . iso-8859-1))))
 156     ;; Windows-1250 is a variant of Latin-2 heavily used by Microsoft
 157     ;; Outlook users in Czech republic. Use this to allow reading of their
 158     ;; e-mails. cp1250 should be defined by M-x codepage-setup.
 159     ,@(if (and (not (mm-coding-system-p 'windows-1250))
 160                (mm-coding-system-p 'cp1250))
 161           '((windows-1250 . cp1250)))
 162     ;; A Microsoft misunderstanding.
 163     ,@(unless (mm-coding-system-p 'ks_c_5601-1987)
 164         (if (mm-coding-system-p 'cp949)
 165             '((ks_c_5601-1987 . cp949))
 166           '((ks_c_5601-1987 . euc-kr))))
 167     )
 168   "A mapping from invalid charset names to the real charset names.")
 169
 170 (defvar mm-binary-coding-system
 171   (cond
 172    ((mm-coding-system-p 'binary) 'binary)
 173    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 174    (t nil))
 175   "100% binary coding system.")
 176
 177 (defvar mm-text-coding-system
 178   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 179           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 180         (and (mm-coding-system-p 'raw-text) 'raw-text))
 181       mm-binary-coding-system)
 182   "Text-safe coding system (For removing ^M).")
 183
 184 (defvar mm-text-coding-system-for-write nil
 185   "Text coding system for write.")
 186
 187 (defvar mm-auto-save-coding-system
 188   (cond
 189    ((mm-coding-system-p 'utf-8-emacs)   ; Mule 7
 190     (if (memq system-type '(windows-nt ms-dos ms-windows))
 191         (if (mm-coding-system-p 'utf-8-emacs-dos)
 192             'utf-8-emacs-dos mm-binary-coding-system)
 193       'utf-8-emacs))
 194    ((mm-coding-system-p 'emacs-mule)
 195     (if (memq system-type '(windows-nt ms-dos ms-windows))
 196         (if (mm-coding-system-p 'emacs-mule-dos)
 197             'emacs-mule-dos mm-binary-coding-system)
 198       'emacs-mule))
 199    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 200    (t mm-binary-coding-system))
 201   "Coding system of auto save file.")
 202
 203 (defvar mm-universal-coding-system mm-auto-save-coding-system
 204   "The universal coding system.")
 205
 206 ;; Fixme: some of the cars here aren't valid MIME charsets.  That
 207 ;; should only matter with XEmacs, though.
 208 (defvar mm-mime-mule-charset-alist
 209   `((us-ascii ascii)
 210     (iso-8859-1 latin-iso8859-1)
 211     (iso-8859-2 latin-iso8859-2)
 212     (iso-8859-3 latin-iso8859-3)
 213     (iso-8859-4 latin-iso8859-4)
 214     (iso-8859-5 cyrillic-iso8859-5)
 215     ;; Non-mule (X)Emacs uses the last mule-charset for 8bit characters.
 216     ;; The fake mule-charset, gnus-koi8-r, tells Gnus that the default
 217     ;; charset is koi8-r, not iso-8859-5.
 218     (koi8-r cyrillic-iso8859-5 gnus-koi8-r)
 219     (iso-8859-6 arabic-iso8859-6)
 220     (iso-8859-7 greek-iso8859-7)
 221     (iso-8859-8 hebrew-iso8859-8)
 222     (iso-8859-9 latin-iso8859-9)
 223     (iso-8859-14 latin-iso8859-14)
 224     (iso-8859-15 latin-iso8859-15)
 225     (viscii vietnamese-viscii-lower)
 226     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
 227     (euc-kr korean-ksc5601)
 228     (gb2312 chinese-gb2312)
 229     (big5 chinese-big5-1 chinese-big5-2)
 230     (tibetan tibetan)
 231     (thai-tis620 thai-tis620)
 232     (windows-1251 cyrillic-iso8859-5)
 233     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
 234     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
 235                    latin-jisx0201 japanese-jisx0208-1978
 236                    chinese-gb2312 japanese-jisx0208
 237                    korean-ksc5601 japanese-jisx0212)
 238     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
 239                     latin-jisx0201 japanese-jisx0208-1978
 240                     chinese-gb2312 japanese-jisx0208
 241                     korean-ksc5601 japanese-jisx0212
 242                     chinese-cns11643-1 chinese-cns11643-2)
 243     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
 244                     cyrillic-iso8859-5 greek-iso8859-7
 245                     latin-jisx0201 japanese-jisx0208-1978
 246                     chinese-gb2312 japanese-jisx0208
 247                     korean-ksc5601 japanese-jisx0212
 248                     chinese-cns11643-1 chinese-cns11643-2
 249                     chinese-cns11643-3 chinese-cns11643-4
 250                     chinese-cns11643-5 chinese-cns11643-6
 251                     chinese-cns11643-7)
 252     (iso-2022-jp-3 latin-jisx0201 japanese-jisx0208-1978 japanese-jisx0208
 253                    japanese-jisx0213-1 japanese-jisx0213-2)
 254     (shift_jis latin-jisx0201 katakana-jisx0201 japanese-jisx0208)
 255     ,(if (or (not (fboundp 'charsetp)) ;; non-Mule case
 256              (charsetp 'unicode-a)
 257              (not (mm-coding-system-p 'mule-utf-8)))
 258          '(utf-8 unicode-a unicode-b unicode-c unicode-d unicode-e)
 259        ;; If we have utf-8 we're in Mule 5+.
 260        (append '(utf-8)
 261                (delete 'ascii
 262                        (coding-system-get 'mule-utf-8 'safe-charsets)))))
 263   "Alist of MIME-charset/MULE-charsets.")
 264
 265 (defun mm-enrich-utf-8-by-mule-ucs ()
 266   "Make the `utf-8' MIME charset usable by the Mule-UCS package.
 267 This function will run when the `un-define' module is loaded under
 268 XEmacs, and fill the `utf-8' entry in `mm-mime-mule-charset-alist'
 269 with Mule charsets.  It is completely useless for Emacs."
 270   (setq after-load-alist
 271         (delete '("un-define" (mm-enrich-utf-8-by-mule-ucs))
 272                 after-load-alist))
 273   (when (boundp 'unicode-basic-translation-charset-order-list)
 274     (condition-case nil
 275         (let ((val (delq
 276                     'ascii
 277                     (symbol-value
 278                      'unicode-basic-translation-charset-order-list)))
 279               (elem (assq 'utf-8 mm-mime-mule-charset-alist)))
 280           (if elem
 281               (setcdr elem val)
 282             (setq mm-mime-mule-charset-alist
 283                   (nconc mm-mime-mule-charset-alist
 284                          (list (cons 'utf-8 val))))))
 285       (error))))
 286
 287 ;; Correct by construction, but should be unnecessary for Emacs:
 288 (if (featurep 'xemacs)
 289     (eval-after-load "un-define" '(mm-enrich-utf-8-by-mule-ucs))
 290   (when (and (fboundp 'coding-system-list)
 291              (fboundp 'sort-coding-systems))
 292     (let ((css (sort-coding-systems (coding-system-list 'base-only)))
 293           cs mime mule alist)
 294       (while css
 295         (setq cs (pop css)
 296               mime (or (coding-system-get cs :mime-charset) ; Emacs 22
 297                        (coding-system-get cs 'mime-charset)))
 298         (when (and mime
 299                    (not (eq t (setq mule
 300                                     (coding-system-get cs 'safe-charsets))))
 301                    (not (assq mime alist)))
 302           (push (cons mime (delq 'ascii mule)) alist)))
 303       (setq mm-mime-mule-charset-alist (nreverse alist)))))
 304
 305 (defvar mm-hack-charsets '(iso-8859-15 iso-2022-jp-2)
 306   "A list of special charsets.
 307 Valid elements include:
 308 `iso-8859-15'    convert ISO-8859-1, -9 to ISO-8859-15 if ISO-8859-15 exists.
 309 `iso-2022-jp-2'  convert ISO-2022-jp to ISO-2022-jp-2 if ISO-2022-jp-2 exists."
 310 )
 311
 312 (defvar mm-iso-8859-15-compatible
 313   '((iso-8859-1 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE")
 314     (iso-8859-9 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE\xD0\xDD\xDE\xF0\xFD\xFE"))
 315   "ISO-8859-15 exchangeable coding systems and inconvertible characters.")
 316
 317 (defvar mm-iso-8859-x-to-15-table
 318   (and (fboundp 'coding-system-p)
 319        (mm-coding-system-p 'iso-8859-15)
 320        (mapcar
 321         (lambda (cs)
 322           (if (mm-coding-system-p (car cs))
 323               (let ((c (string-to-char
 324                         (decode-coding-string "\341" (car cs)))))
 325                 (cons (char-charset c)
 326                       (cons
 327                        (- (string-to-char
 328                            (decode-coding-string "\341" 'iso-8859-15)) c)
 329                        (string-to-list (decode-coding-string (car (cdr cs))
 330                                                              (car cs))))))
 331             '(gnus-charset 0)))
 332         mm-iso-8859-15-compatible))
 333   "A table of the difference character between ISO-8859-X and ISO-8859-15.")
 334
 335 (defcustom mm-coding-system-priorities
 336   (if (boundp 'current-language-environment)
 337       (let ((lang (symbol-value 'current-language-environment)))
 338         (cond ((string= lang "Japanese")
 339                ;; Japanese users may prefer iso-2022-jp to shift_jis.
 340                '(iso-2022-jp iso-2022-jp-2 shift_jis iso-8859-1 utf-8)))))
 341   "Preferred coding systems for encoding outgoing messages.
 342
 343 More than one suitable coding system may be found for some text.
 344 By default, the coding system with the highest priority is used
 345 to encode outgoing messages (see `sort-coding-systems').  If this
 346 variable is set, it overrides the default priority."
 347   :type '(repeat (symbol :tag "Coding system"))
 348   :group 'mime)
 349
 350 ;; ??
 351 (defvar mm-use-find-coding-systems-region
 352   (fboundp 'find-coding-systems-region)
 353   "Use `find-coding-systems-region' to find proper coding systems.
 354
 355 Setting it to nil is useful on Emacsen supporting Unicode if sending
 356 mail with multiple parts is preferred to sending a Unicode one.")
 357
 358 ;;; Internal variables:
 359
 360 ;;; Functions:
 361
 362 (defun mm-mule-charset-to-mime-charset (charset)
 363   "Return the MIME charset corresponding to the given Mule CHARSET."
 364   (if (and (fboundp 'find-coding-systems-for-charsets)
 365            (fboundp 'sort-coding-systems))
 366       (let ((css (sort (sort-coding-systems
 367                         (find-coding-systems-for-charsets (list charset)))
 368                        'mm-sort-coding-systems-predicate))
 369             cs mime)
 370         (while (and (not mime)
 371                     css)
 372           (when (setq cs (pop css))
 373             (setq mime (or (coding-system-get cs :mime-charset)
 374                            (coding-system-get cs 'mime-charset)))))
 375         mime)
 376     (let ((alist (mapcar (lambda (cs)
 377                            (assq cs mm-mime-mule-charset-alist))
 378                          (sort (mapcar 'car mm-mime-mule-charset-alist)
 379                                'mm-sort-coding-systems-predicate)))
 380           out)
 381       (while alist
 382         (when (memq charset (cdar alist))
 383           (setq out (caar alist)
 384                 alist nil))
 385         (pop alist))
 386       out)))
 387
 388 (defun mm-charset-to-coding-system (charset &optional lbt)
 389   "Return coding-system corresponding to CHARSET.
 390 CHARSET is a symbol naming a MIME charset.
 391 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 392 used as the line break code type of the coding system."
 393   (when (stringp charset)
 394     (setq charset (intern (downcase charset))))
 395   (when lbt
 396     (setq charset (intern (format "%s-%s" charset lbt))))
 397   (cond
 398    ((null charset)
 399     charset)
 400    ;; Running in a non-MULE environment.
 401    ((or (null (mm-get-coding-system-list))
 402         (not (fboundp 'coding-system-get)))
 403     charset)
 404    ;; ascii
 405    ((eq charset 'us-ascii)
 406     'ascii)
 407    ;; Check to see whether we can handle this charset.  (This depends
 408    ;; on there being some coding system matching each `mime-charset'
 409    ;; property defined, as there should be.)
 410    ((and (mm-coding-system-p charset)
 411 ;;; Doing this would potentially weed out incorrect charsets.
 412 ;;;      charset
 413 ;;;      (eq charset (coding-system-get charset 'mime-charset))
 414          )
 415     charset)
 416    ;; Translate invalid charsets.
 417    ((let ((cs (cdr (assq charset mm-charset-synonym-alist))))
 418       (and cs (mm-coding-system-p cs) cs)))
 419    ;; Last resort: search the coding system list for entries which
 420    ;; have the right mime-charset in case the canonical name isn't
 421    ;; defined (though it should be).
 422    ((let (cs)
 423       ;; mm-get-coding-system-list returns a list of cs without lbt.
 424       ;; Do we need -lbt?
 425       (dolist (c (mm-get-coding-system-list))
 426         (if (and (null cs)
 427                  (eq charset (or (coding-system-get c :mime-charset)
 428                                  (coding-system-get c 'mime-charset))))
 429             (setq cs c)))
 430       cs))))
 431
 432 (eval-and-compile
 433   (defvar mm-emacs-mule (and (not (featurep 'xemacs))
 434                              (boundp 'default-enable-multibyte-characters)
 435                              default-enable-multibyte-characters
 436                              (fboundp 'set-buffer-multibyte))
 437     "True in Emacs with Mule.")
 438
 439   (if mm-emacs-mule
 440       (defun mm-enable-multibyte ()
 441         "Set the multibyte flag of the current buffer.
 442 Only do this if the default value of `enable-multibyte-characters' is
 443 non-nil.  This is a no-op in XEmacs."
 444         (set-buffer-multibyte 'to))
 445     (defalias 'mm-enable-multibyte 'ignore))
 446
 447   (if mm-emacs-mule
 448       (defun mm-disable-multibyte ()
 449         "Unset the multibyte flag of in the current buffer.
 450 This is a no-op in XEmacs."
 451         (set-buffer-multibyte nil))
 452     (defalias 'mm-disable-multibyte 'ignore)))
 453
 454 (defun mm-preferred-coding-system (charset)
 455   ;; A typo in some Emacs versions.
 456   (or (get-charset-property charset 'preferred-coding-system)
 457       (get-charset-property charset 'prefered-coding-system)))
 458
 459 ;; Mule charsets shouldn't be used.
 460 (defsubst mm-guess-charset ()
 461   "Guess Mule charset from the language environment."
 462   (or
 463    mail-parse-mule-charset ;; cached mule-charset
 464    (progn
 465      (setq mail-parse-mule-charset
 466            (and (boundp 'current-language-environment)
 467                 (car (last
 468                       (assq 'charset
 469                             (assoc current-language-environment
 470                                    language-info-alist))))))
 471      (if (or (not mail-parse-mule-charset)
 472              (eq mail-parse-mule-charset 'ascii))
 473          (setq mail-parse-mule-charset
 474                (or (car (last (assq mail-parse-charset
 475                                     mm-mime-mule-charset-alist)))
 476                    ;; default
 477                    'latin-iso8859-1)))
 478      mail-parse-mule-charset)))
 479
 480 (defun mm-charset-after (&optional pos)
 481   "Return charset of a character in current buffer at position POS.
 482 If POS is nil, it defauls to the current point.
 483 If POS is out of range, the value is nil.
 484 If the charset is `composition', return the actual one."
 485   (let ((char (char-after pos)) charset)
 486     (if (< (mm-char-int char) 128)
 487         (setq charset 'ascii)
 488       ;; charset-after is fake in some Emacsen.
 489       (setq charset (and (fboundp 'char-charset) (char-charset char)))
 490       (if (eq charset 'composition)     ; Mule 4
 491           (let ((p (or pos (point))))
 492             (cadr (find-charset-region p (1+ p))))
 493         (if (and charset (not (memq charset '(ascii eight-bit-control
 494                                                     eight-bit-graphic))))
 495             charset
 496           (mm-guess-charset))))))
 497
 498 (defun mm-mime-charset (charset)
 499   "Return the MIME charset corresponding to the given Mule CHARSET."
 500   (if (eq charset 'unknown)
 501       (error "The message contains non-printable characters, please use attachment"))
 502   (if (and (fboundp 'coding-system-get) (fboundp 'get-charset-property))
 503       ;; This exists in Emacs 20.
 504       (or
 505        (and (mm-preferred-coding-system charset)
 506             (or (coding-system-get
 507                  (mm-preferred-coding-system charset) :mime-charset)
 508                 (coding-system-get
 509                  (mm-preferred-coding-system charset) 'mime-charset)))
 510        (and (eq charset 'ascii)
 511             'us-ascii)
 512        (mm-preferred-coding-system charset)
 513        (mm-mule-charset-to-mime-charset charset))
 514     ;; This is for XEmacs.
 515     (mm-mule-charset-to-mime-charset charset)))
 516
 517 (defun mm-delete-duplicates (list)
 518   "Simple substitute for CL `delete-duplicates', testing with `equal'."
 519   (let (result head)
 520     (while list
 521       (setq head (car list))
 522       (setq list (delete head list))
 523       (setq result (cons head result)))
 524     (nreverse result)))
 525
 526 ;; Fixme:  This is used in places when it should be testing the
 527 ;; default multibyteness.  See mm-default-multibyte-p.
 528 (eval-and-compile
 529   (if (and (not (featurep 'xemacs))
 530            (boundp 'enable-multibyte-characters))
 531       (defun mm-multibyte-p ()
 532         "Non-nil if multibyte is enabled in the current buffer."
 533         enable-multibyte-characters)
 534     (defun mm-multibyte-p () (featurep 'mule))))
 535
 536 (defun mm-default-multibyte-p ()
 537   "Return non-nil if the session is multibyte.
 538 This affects whether coding conversion should be attempted generally."
 539   (if (featurep 'mule)
 540       (if (boundp 'default-enable-multibyte-characters)
 541           default-enable-multibyte-characters
 542         t)))
 543
 544 (defun mm-iso-8859-x-to-15-region (&optional b e)
 545   (if (fboundp 'char-charset)
 546       (let (charset item c inconvertible)
 547         (save-restriction
 548           (if e (narrow-to-region b e))
 549           (goto-char (point-min))
 550           (skip-chars-forward "\0-\177")
 551           (while (not (eobp))
 552             (cond
 553              ((not (setq item (assq (char-charset (setq c (char-after)))
 554                                     mm-iso-8859-x-to-15-table)))
 555               (forward-char))
 556              ((memq c (cdr (cdr item)))
 557               (setq inconvertible t)
 558               (forward-char))
 559              (t
 560               (insert-before-markers (prog1 (+ c (car (cdr item)))
 561                                        (delete-char 1)))))
 562             (skip-chars-forward "\0-\177")))
 563         (not inconvertible))))
 564
 565 (defun mm-sort-coding-systems-predicate (a b)
 566   (let ((priorities
 567          (mapcar (lambda (cs)
 568                    ;; Note: invalid entries are dropped silently
 569                    (and (setq cs (mm-coding-system-p cs))
 570                         (coding-system-base cs)))
 571                  mm-coding-system-priorities)))
 572     (and (setq a (mm-coding-system-p a))
 573          (if (setq b (mm-coding-system-p b))
 574              (> (length (memq (coding-system-base a) priorities))
 575                 (length (memq (coding-system-base b) priorities)))
 576            t))))
 577
 578 (defun mm-find-mime-charset-region (b e &optional hack-charsets)
 579   "Return the MIME charsets needed to encode the region between B and E.
 580 nil means ASCII, a single-element list represents an appropriate MIME
 581 charset, and a longer list means no appropriate charset."
 582   (let (charsets)
 583     ;; The return possibilities of this function are a mess...
 584     (or (and (mm-multibyte-p)
 585              mm-use-find-coding-systems-region
 586              ;; Find the mime-charset of the most preferred coding
 587              ;; system that has one.
 588              (let ((systems (find-coding-systems-region b e)))
 589                (when mm-coding-system-priorities
 590                  (setq systems
 591                        (sort systems 'mm-sort-coding-systems-predicate)))
 592                (setq systems (delq 'compound-text systems))
 593                (unless (equal systems '(undecided))
 594                  (while systems
 595                    (let* ((head (pop systems))
 596                           (cs (or (coding-system-get head :mime-charset)
 597                                   (coding-system-get head 'mime-charset))))
 598                      ;; The mime-charset (`x-ctext') of
 599                      ;; `compound-text' is not in the IANA list.  We
 600                      ;; shouldn't normally use anything here with a
 601                      ;; mime-charset having an `x-' prefix.
 602                      ;; Fixme:  Allow this to be overridden, since
 603                      ;; there is existing use of x-ctext.
 604                      ;; Also people apparently need the coding system
 605                      ;; `iso-2022-jp-3' (which Mule-UCS defines with
 606                      ;; mime-charset, though it's not valid).
 607                      (if (and cs
 608                               (not (string-match "^[Xx]-" (symbol-name cs)))
 609                               ;; UTF-16 of any variety is invalid for
 610                               ;; text parts and, unfortunately, has
 611                               ;; mime-charset defined both in Mule-UCS
 612                               ;; and versions of Emacs.  (The name
 613                               ;; might be `mule-utf-16...'  or
 614                               ;; `utf-16...'.)
 615                               (not (string-match "utf-16" (symbol-name cs))))
 616                          (setq systems nil
 617                                charsets (list cs))))))
 618                charsets))
 619         ;; Otherwise we're not multibyte, we're XEmacs, or a single
 620         ;; coding system won't cover it.
 621         (setq charsets
 622               (mm-delete-duplicates
 623                (mapcar 'mm-mime-charset
 624                        (delq 'ascii
 625                              (mm-find-charset-region b e))))))
 626     (if (and (> (length charsets) 1)
 627              (memq 'iso-8859-15 charsets)
 628              (memq 'iso-8859-15 hack-charsets)
 629              (save-excursion (mm-iso-8859-x-to-15-region b e)))
 630         (mapcar (lambda (x) (setq charsets (delq (car x) charsets)))
 631                 mm-iso-8859-15-compatible))
 632     (if (and (memq 'iso-2022-jp-2 charsets)
 633              (memq 'iso-2022-jp-2 hack-charsets))
 634         (setq charsets (delq 'iso-2022-jp charsets)))
 635     charsets))
 636
 637 (defmacro mm-with-unibyte-buffer (&rest forms)
 638   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 639 Use unibyte mode for this."
 640   `(let (default-enable-multibyte-characters)
 641      (with-temp-buffer ,@forms)))
 642 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 643 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 644
 645 (defmacro mm-with-multibyte-buffer (&rest forms)
 646   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 647 Use multibyte mode for this."
 648   `(let ((default-enable-multibyte-characters t))
 649      (with-temp-buffer ,@forms)))
 650 (put 'mm-with-multibyte-buffer 'lisp-indent-function 0)
 651 (put 'mm-with-multibyte-buffer 'edebug-form-spec '(body))
 652
 653 (defmacro mm-with-unibyte-current-buffer (&rest forms)
 654   "Evaluate FORMS with current buffer temporarily made unibyte.
 655 Also bind `default-enable-multibyte-characters' to nil.
 656 Equivalent to `progn' in XEmacs"
 657   (let ((multibyte (make-symbol "multibyte"))
 658         (buffer (make-symbol "buffer")))
 659     `(if mm-emacs-mule
 660          (let ((,multibyte enable-multibyte-characters)
 661                (,buffer (current-buffer)))
 662            (unwind-protect
 663                (let (default-enable-multibyte-characters)
 664                  (set-buffer-multibyte nil)
 665                  ,@forms)
 666              (set-buffer ,buffer)
 667              (set-buffer-multibyte ,multibyte)))
 668        (let (default-enable-multibyte-characters)
 669          ,@forms))))
 670 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 671 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 672
 673 (defmacro mm-with-unibyte (&rest forms)
 674   "Eval the FORMS with the default value of `enable-multibyte-characters' nil."
 675   `(let (default-enable-multibyte-characters)
 676      ,@forms))
 677 (put 'mm-with-unibyte 'lisp-indent-function 0)
 678 (put 'mm-with-unibyte 'edebug-form-spec '(body))
 679
 680 (defmacro mm-with-multibyte (&rest forms)
 681   "Eval the FORMS with the default value of `enable-multibyte-characters' t."
 682   `(let ((default-enable-multibyte-characters t))
 683      ,@forms))
 684 (put 'mm-with-multibyte 'lisp-indent-function 0)
 685 (put 'mm-with-multibyte 'edebug-form-spec '(body))
 686
 687 (defun mm-find-charset-region (b e)
 688   "Return a list of Emacs charsets in the region B to E."
 689   (cond
 690    ((and (mm-multibyte-p)
 691          (fboundp 'find-charset-region))
 692     ;; Remove composition since the base charsets have been included.
 693     ;; Remove eight-bit-*, treat them as ascii.
 694     (let ((css (find-charset-region b e)))
 695       (mapcar (lambda (cs) (setq css (delq cs css)))
 696               '(composition eight-bit-control eight-bit-graphic
 697                             control-1))
 698       css))
 699    (t
 700     ;; We are in a unibyte buffer or XEmacs non-mule, so we futz around a bit.
 701     (save-excursion
 702       (save-restriction
 703         (narrow-to-region b e)
 704         (goto-char (point-min))
 705         (skip-chars-forward "\0-\177")
 706         (if (eobp)
 707             '(ascii)
 708           (let (charset)
 709             (setq charset
 710                   (and (boundp 'current-language-environment)
 711                        (car (last (assq 'charset
 712                                         (assoc current-language-environment
 713                                                language-info-alist))))))
 714             (if (eq charset 'ascii) (setq charset nil))
 715             (or charset
 716                 (setq charset
 717                       (car (last (assq mail-parse-charset
 718                                        mm-mime-mule-charset-alist)))))
 719             (list 'ascii (or charset 'latin-iso8859-1)))))))))
 720
 721 (defun mm-auto-mode-alist ()
 722   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 723   (let ((alist auto-mode-alist)
 724         out)
 725     (while alist
 726       (when (listp (cdar alist))
 727         (push (car alist) out))
 728       (pop alist))
 729     (nreverse out)))
 730
 731 (defvar mm-inhibit-file-name-handlers
 732   '(jka-compr-handler image-file-handler)
 733   "A list of handlers doing (un)compression (etc) thingies.")
 734
 735 (defun mm-insert-file-contents (filename &optional visit beg end replace
 736                                          inhibit)
 737   "Like `insert-file-contents', but only reads in the file.
 738 A buffer may be modified in several ways after reading into the buffer due
 739 to advanced Emacs features, such as file-name-handlers, format decoding,
 740 `find-file-hooks', etc.
 741 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'.
 742   This function ensures that none of these modifications will take place."
 743   (let ((format-alist nil)
 744         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 745         (default-major-mode 'fundamental-mode)
 746         (enable-local-variables nil)
 747         (after-insert-file-functions nil)
 748         (enable-local-eval nil)
 749         (find-file-hooks nil)
 750         (inhibit-file-name-operation (if inhibit
 751                                          'insert-file-contents
 752                                        inhibit-file-name-operation))
 753         (inhibit-file-name-handlers
 754          (if inhibit
 755              (append mm-inhibit-file-name-handlers
 756                      inhibit-file-name-handlers)
 757            inhibit-file-name-handlers)))
 758     (insert-file-contents filename visit beg end replace)))
 759
 760 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 761   "Append the contents of the region to the end of file FILENAME.
 762 When called from a function, expects three arguments,
 763 START, END and FILENAME.  START and END are buffer positions
 764 saying what text to write.
 765 Optional fourth argument specifies the coding system to use when
 766 encoding the file.
 767 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
 768   (let ((coding-system-for-write
 769          (or codesys mm-text-coding-system-for-write
 770              mm-text-coding-system))
 771         (inhibit-file-name-operation (if inhibit
 772                                          'append-to-file
 773                                        inhibit-file-name-operation))
 774         (inhibit-file-name-handlers
 775          (if inhibit
 776              (append mm-inhibit-file-name-handlers
 777                      inhibit-file-name-handlers)
 778            inhibit-file-name-handlers)))
 779     (write-region start end filename t 'no-message)
 780     (message "Appended to %s" filename)))
 781
 782 (defun mm-write-region (start end filename &optional append visit lockname
 783                               coding-system inhibit)
 784
 785   "Like `write-region'.
 786 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
 787   (let ((coding-system-for-write
 788          (or coding-system mm-text-coding-system-for-write
 789              mm-text-coding-system))
 790         (inhibit-file-name-operation (if inhibit
 791                                          'write-region
 792                                        inhibit-file-name-operation))
 793         (inhibit-file-name-handlers
 794          (if inhibit
 795              (append mm-inhibit-file-name-handlers
 796                      inhibit-file-name-handlers)
 797            inhibit-file-name-handlers)))
 798     (write-region start end filename append visit lockname)))
 799
 800 (defun mm-image-load-path (&optional package)
 801   (let (dir result)
 802     (dolist (path load-path (nreverse result))
 803       (when (and path
 804                  (file-directory-p
 805                   (setq dir (concat (file-name-directory
 806                                      (directory-file-name path))
 807                                     "etc/" (or package "gnus/")))))
 808         (push dir result))
 809       (push path result))))
 810
 811 ;; Fixme: This doesn't look useful where it's used.
 812 (if (fboundp 'detect-coding-region)
 813     (defun mm-detect-coding-region (start end)
 814       "Like `detect-coding-region' except returning the best one."
 815       (let ((coding-systems
 816              (detect-coding-region (point) (point-max))))
 817         (or (car-safe coding-systems)
 818             coding-systems)))
 819   (defun mm-detect-coding-region (start end)
 820     (let ((point (point)))
 821       (goto-char start)
 822       (skip-chars-forward "\0-\177" end)
 823       (prog1
 824           (if (eq (point) end) 'ascii (mm-guess-charset))
 825         (goto-char point)))))
 826
 827 (if (fboundp 'coding-system-get)
 828     (defun mm-detect-mime-charset-region (start end)
 829       "Detect MIME charset of the text in the region between START and END."
 830       (let ((cs (mm-detect-coding-region start end)))
 831         (coding-system-get cs 'mime-charset)))
 832   (defun mm-detect-mime-charset-region (start end)
 833     "Detect MIME charset of the text in the region between START and END."
 834     (let ((cs (mm-detect-coding-region start end)))
 835       cs)))
 836
 837
 838 (provide 'mm-util)
 839
 840 ;;; arch-tag: 94dc5388-825d-4fd1-bfa5-2100aa351238
 841 ;;; mm-util.el ends here