cgit.sxemacs.org Git - gnus/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for Mule and low level things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28 (require 'mail-prsvr)
  29
  30 (eval-and-compile
  31   (mapcar
  32    (lambda (elem)
  33      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  34        (if (fboundp (car elem))
  35            (defalias nfunc (car elem))
  36          (defalias nfunc (cdr elem)))))
  37    '((decode-coding-string . (lambda (s a) s))
  38      (encode-coding-string . (lambda (s a) s))
  39      (encode-coding-region . ignore)
  40      (coding-system-list . ignore)
  41      (decode-coding-region . ignore)
  42      (char-int . identity)
  43      (device-type . ignore)
  44      (coding-system-equal . equal)
  45      (annotationp . ignore)
  46      (set-buffer-file-coding-system . ignore)
  47      (make-char
  48       . (lambda (charset int)
  49           (int-to-char int)))
  50      (read-charset
  51       . (lambda (prompt)
  52           "Return a charset."
  53           (intern
  54            (completing-read
  55             prompt
  56             (mapcar (lambda (e) (list (symbol-name (car e))))
  57                     mm-mime-mule-charset-alist)
  58             nil t))))
  59      (subst-char-in-string
  60       . (lambda (from to string) ;; stolen (and renamed) from nnheader.el
  61           "Replace characters in STRING from FROM to TO."
  62           (let ((string (substring string 0)) ;Copy string.
  63                 (len (length string))
  64                 (idx 0))
  65             ;; Replace all occurrences of FROM with TO.
  66             (while (< idx len)
  67               (when (= (aref string idx) from)
  68                 (aset string idx to))
  69               (setq idx (1+ idx)))
  70             string)))
  71      (string-as-unibyte . identity)
  72      (string-as-multibyte . identity)
  73      (multibyte-string-p . ignore))))
  74
  75 (eval-and-compile
  76   (defalias 'mm-char-or-char-int-p
  77     (cond
  78      ((fboundp 'char-or-char-int-p) 'char-or-char-int-p)
  79      ((fboundp 'char-valid-p) 'char-valid-p)
  80      (t 'identity))))
  81
  82 (eval-and-compile
  83   (defalias 'mm-read-coding-system
  84     (cond
  85      ((fboundp 'read-coding-system)
  86       (if (and (featurep 'xemacs)
  87                (<= (string-to-number emacs-version) 21.1))
  88           (lambda (prompt &optional default-coding-system)
  89             (read-coding-system prompt))
  90         'read-coding-system))
  91      (t (lambda (prompt &optional default-coding-system)
  92           "Prompt the user for a coding system."
  93           (completing-read
  94            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
  95                           mm-mime-mule-charset-alist)))))))
  96
  97 (defvar mm-coding-system-list nil)
  98 (defun mm-get-coding-system-list ()
  99   "Get the coding system list."
 100   (or mm-coding-system-list
 101       (setq mm-coding-system-list (mm-coding-system-list))))
 102
 103 (defun mm-coding-system-p (sym)
 104   "Return non-nil if SYM is a coding system."
 105   (or (and (fboundp 'coding-system-p) (coding-system-p sym))
 106       (memq sym (mm-get-coding-system-list))))
 107
 108 (defvar mm-charset-synonym-alist
 109   `(
 110     ;; Perfectly fine?  A valid MIME name, anyhow.
 111     ,(unless (mm-coding-system-p 'big5)
 112        '(big5 . cn-big5))
 113     ;; Not in XEmacs, but it's not a proper MIME charset anyhow.
 114     ,(unless (mm-coding-system-p 'x-ctext)
 115        '(x-ctext . ctext))
 116     ;; Apparently not defined in Emacs 20, but is a valid MIME name.
 117     ,(unless (mm-coding-system-p 'gb2312)
 118        '(gb2312 . cn-gb-2312))
 119     ;; Windows-1252 is actually a superset of Latin-1.  See also
 120     ;; `gnus-article-dumbquotes-map'.
 121     ;;,(unless (mm-coding-system-p 'windows-1252)
 122                                         ; should be defined eventually
 123     ;;  '(windows-1252 . iso-8859-1))
 124     ;; ISO-8859-15 is very similar to ISO-8859-1.
 125     ;;,(unless (mm-coding-system-p 'iso-8859-15) ; Emacs 21 defines it.
 126     ;;   '(iso-8859-15 . iso-8859-1))
 127     ;; Windows-1250 is a variant of Latin-2 heavily used by Microsoft
 128     ;; Outlook users in Czech republic. Use this to allow reading of their
 129     ;; e-mails. cp1250 should be defined by M-x codepage-setup.
 130     ;;,(unless (mm-coding-system-p 'windows-1250)
 131                                         ; should be defined eventually
 132     ;;  '(windows-1250 . cp1250))
 133     )
 134   "A mapping from invalid charset names to the real charset names.")
 135
 136 (defvar mm-binary-coding-system
 137   (cond
 138    ((mm-coding-system-p 'binary) 'binary)
 139    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 140    (t nil))
 141   "100% binary coding system.")
 142
 143 (defvar mm-text-coding-system
 144   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 145           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 146         (and (mm-coding-system-p 'raw-text) 'raw-text))
 147       mm-binary-coding-system)
 148   "Text-safe coding system (For removing ^M).")
 149
 150 (defvar mm-text-coding-system-for-write nil
 151   "Text coding system for write.")
 152
 153 (defvar mm-auto-save-coding-system
 154   (cond
 155    ((mm-coding-system-p 'emacs-mule)
 156     (if (memq system-type '(windows-nt ms-dos ms-windows))
 157         (if (mm-coding-system-p 'emacs-mule-dos)
 158             'emacs-mule-dos mm-binary-coding-system)
 159       'emacs-mule))
 160    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 161    (t mm-binary-coding-system))
 162   "Coding system of auto save file.")
 163
 164 (defvar mm-universal-coding-system mm-auto-save-coding-system
 165   "The universal Coding system.")
 166
 167 ;; Fixme: some of the cars here aren't valid MIME charsets.  That
 168 ;; should only matter with XEmacs, though.
 169 (defvar mm-mime-mule-charset-alist
 170   `((us-ascii ascii)
 171     (iso-8859-1 latin-iso8859-1)
 172     (iso-8859-2 latin-iso8859-2)
 173     (iso-8859-3 latin-iso8859-3)
 174     (iso-8859-4 latin-iso8859-4)
 175     (iso-8859-5 cyrillic-iso8859-5)
 176     ;; Non-mule (X)Emacs uses the last mule-charset for 8bit characters.
 177     ;; The fake mule-charset, gnus-koi8-r, tells Gnus that the default
 178     ;; charset is koi8-r, not iso-8859-5.
 179     (koi8-r cyrillic-iso8859-5 gnus-koi8-r)
 180     (iso-8859-6 arabic-iso8859-6)
 181     (iso-8859-7 greek-iso8859-7)
 182     (iso-8859-8 hebrew-iso8859-8)
 183     (iso-8859-9 latin-iso8859-9)
 184     (iso-8859-14 latin-iso8859-14)
 185     (iso-8859-15 latin-iso8859-15)
 186     (viscii vietnamese-viscii-lower)
 187     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
 188     (euc-kr korean-ksc5601)
 189     (gb2312 chinese-gb2312)
 190     (big5 chinese-big5-1 chinese-big5-2)
 191     (tibetan tibetan)
 192     (thai-tis620 thai-tis620)
 193     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
 194     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
 195                    latin-jisx0201 japanese-jisx0208-1978
 196                    chinese-gb2312 japanese-jisx0208
 197                    korean-ksc5601 japanese-jisx0212
 198                    katakana-jisx0201)
 199     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
 200                     latin-jisx0201 japanese-jisx0208-1978
 201                     chinese-gb2312 japanese-jisx0208
 202                     korean-ksc5601 japanese-jisx0212
 203                     chinese-cns11643-1 chinese-cns11643-2)
 204     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
 205                     cyrillic-iso8859-5 greek-iso8859-7
 206                     latin-jisx0201 japanese-jisx0208-1978
 207                     chinese-gb2312 japanese-jisx0208
 208                     korean-ksc5601 japanese-jisx0212
 209                     chinese-cns11643-1 chinese-cns11643-2
 210                     chinese-cns11643-3 chinese-cns11643-4
 211                     chinese-cns11643-5 chinese-cns11643-6
 212                     chinese-cns11643-7)
 213     ,(if (or (not (fboundp 'charsetp)) ;; non-Mule case
 214              (charsetp 'unicode-a)
 215              (not (mm-coding-system-p 'mule-utf-8)))
 216          '(utf-8 unicode-a unicode-b unicode-c unicode-d unicode-e)
 217        ;; If we have utf-8 we're in Mule 5+.
 218        (append '(utf-8)
 219                (delete 'ascii
 220                        (coding-system-get 'mule-utf-8 'safe-charsets)))))
 221   "Alist of MIME-charset/MULE-charsets.")
 222
 223 ;; Correct by construction, but should be unnecessary:
 224 ;; XEmacs hates it.
 225 (when (and (not (featurep 'xemacs))
 226            (fboundp 'coding-system-list)
 227            (fboundp 'sort-coding-systems))
 228   (setq mm-mime-mule-charset-alist
 229         (apply
 230          'nconc
 231          (mapcar
 232           (lambda (cs)
 233             (when (and (coding-system-get cs 'mime-charset)
 234                        (not (eq t (coding-system-get cs 'safe-charsets))))
 235               (list (cons (coding-system-get cs 'mime-charset)
 236                           (delq 'ascii
 237                                 (coding-system-get cs 'safe-charsets))))))
 238           (sort-coding-systems (coding-system-list 'base-only))))))
 239
 240 ;;; Internal variables:
 241
 242 ;;; Functions:
 243
 244 (defun mm-mule-charset-to-mime-charset (charset)
 245   "Return the MIME charset corresponding to the given Mule CHARSET."
 246   (if (fboundp 'find-coding-systems-for-charsets)
 247       (let (mime)
 248         (dolist (cs (find-coding-systems-for-charsets (list charset)))
 249           (unless mime
 250             (when cs
 251               (setq mime (coding-system-get cs 'mime-charset)))))
 252         mime)
 253     (let ((alist mm-mime-mule-charset-alist)
 254           out)
 255       (while alist
 256         (when (memq charset (cdar alist))
 257           (setq out (caar alist)
 258                 alist nil))
 259         (pop alist))
 260       out)))
 261
 262 (defun mm-charset-to-coding-system (charset &optional lbt)
 263   "Return coding-system corresponding to CHARSET.
 264 CHARSET is a symbol naming a MIME charset.
 265 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 266 used as the line break code type of the coding system."
 267   (when (stringp charset)
 268     (setq charset (intern (downcase charset))))
 269   (when lbt
 270     (setq charset (intern (format "%s-%s" charset lbt))))
 271   (cond
 272    ;; Running in a non-MULE environment.
 273    ((null (mm-get-coding-system-list))
 274     charset)
 275    ;; ascii
 276    ((eq charset 'us-ascii)
 277     'ascii)
 278    ;; Check to see whether we can handle this charset.  (This depends
 279    ;; on there being some coding system matching each `mime-charset'
 280    ;; property defined, as there should be.)
 281    ((and (mm-coding-system-p charset)
 282 ;;; Doing this would potentially weed out incorrect charsets.
 283 ;;;      charset
 284 ;;;      (eq charset (coding-system-get charset 'mime-charset))
 285          )
 286     charset)
 287    ;; Translate invalid charsets.
 288    ((mm-coding-system-p (setq charset
 289                            (cdr (assq charset
 290                                       mm-charset-synonym-alist))))
 291     charset)
 292    ;; Last resort: search the coding system list for entries which
 293    ;; have the right mime-charset in case the canonical name isn't
 294    ;; defined (though it should be).
 295    ((let (cs)
 296       ;; mm-get-coding-system-list returns a list of cs without lbt.
 297       ;; Do we need -lbt?
 298       (dolist (c (mm-get-coding-system-list))
 299         (if (and (null cs)
 300                  (eq charset (coding-system-get c 'mime-charset)))
 301             (setq cs c)))
 302       cs))))
 303
 304 (defsubst mm-replace-chars-in-string (string from to)
 305   (mm-subst-char-in-string from to string))
 306
 307 (eval-and-compile
 308   (defvar mm-emacs-mule (and (not (featurep 'xemacs))
 309                              (boundp 'default-enable-multibyte-characters)
 310                              default-enable-multibyte-characters
 311                              (fboundp 'set-buffer-multibyte))
 312     "Emacs mule.")
 313
 314   (defvar mm-mule4-p (and mm-emacs-mule
 315                           (fboundp 'charsetp)
 316                           (not (charsetp 'eight-bit-control)))
 317     "Mule version 4.")
 318
 319   (if mm-emacs-mule
 320       (defun mm-enable-multibyte ()
 321         "Set the multibyte flag of the current buffer.
 322 Only do this if the default value of `enable-multibyte-characters' is
 323 non-nil.  This is a no-op in XEmacs."
 324         (set-buffer-multibyte t))
 325     (defalias 'mm-enable-multibyte 'ignore))
 326
 327   (if mm-emacs-mule
 328       (defun mm-disable-multibyte ()
 329         "Unset the multibyte flag of in the current buffer.
 330 This is a no-op in XEmacs."
 331         (set-buffer-multibyte nil))
 332     (defalias 'mm-disable-multibyte 'ignore))
 333
 334   (if mm-mule4-p
 335       (defun mm-enable-multibyte-mule4  ()
 336         "Enable multibyte in the current buffer.
 337 Only used in Emacs Mule 4."
 338         (set-buffer-multibyte t))
 339     (defalias 'mm-enable-multibyte-mule4 'ignore))
 340
 341   (if mm-mule4-p
 342       (defun mm-disable-multibyte-mule4 ()
 343         "Disable multibyte in the current buffer.
 344 Only used in Emacs Mule 4."
 345         (set-buffer-multibyte nil))
 346     (defalias 'mm-disable-multibyte-mule4 'ignore)))
 347
 348 (defun mm-preferred-coding-system (charset)
 349   ;; A typo in some Emacs versions.
 350   (or (get-charset-property charset 'prefered-coding-system)
 351       (get-charset-property charset 'preferred-coding-system)))
 352
 353 (defun mm-charset-after (&optional pos)
 354   "Return charset of a character in current buffer at position POS.
 355 If POS is nil, it defauls to the current point.
 356 If POS is out of range, the value is nil.
 357 If the charset is `composition', return the actual one."
 358   (let ((char (char-after pos)) charset)
 359     (if (< (mm-char-int char) 128)
 360         (setq charset 'ascii)
 361       ;; charset-after is fake in some Emacsen.
 362       (setq charset (and (fboundp 'char-charset) (char-charset char)))
 363       (if (eq charset 'composition)
 364           (let ((p (or pos (point))))
 365             (cadr (find-charset-region p (1+ p))))
 366         (if (and charset (not (memq charset '(ascii eight-bit-control
 367                                                     eight-bit-graphic))))
 368             charset
 369           (or
 370            mail-parse-mule-charset ;; cached mule-charset
 371            (progn
 372              (setq mail-parse-mule-charset
 373                    (and (boundp 'current-language-environment)
 374                         (car (last
 375                               (assq 'charset
 376                                     (assoc current-language-environment
 377                                            language-info-alist))))))
 378              (if (or (not mail-parse-mule-charset)
 379                      (eq mail-parse-mule-charset 'ascii))
 380                  (setq mail-parse-mule-charset
 381                        (or (car (last (assq mail-parse-charset
 382                                             mm-mime-mule-charset-alist)))
 383                            ;; Fixme: don't fix that!
 384                            'latin-iso8859-1)))
 385              mail-parse-mule-charset)))))))
 386
 387 (defun mm-mime-charset (charset)
 388   "Return the MIME charset corresponding to the MULE CHARSET."
 389   (if (eq charset 'unknown)
 390       (error "The message contains non-printable characters, please use attachment"))
 391   (if (and (fboundp 'coding-system-get) (fboundp 'get-charset-property))
 392       ;; This exists in Emacs 20.
 393       (or
 394        (and (mm-preferred-coding-system charset)
 395             (coding-system-get
 396              (mm-preferred-coding-system charset) 'mime-charset))
 397        (and (eq charset 'ascii)
 398             'us-ascii)
 399        (mm-preferred-coding-system charset)
 400        (mm-mule-charset-to-mime-charset charset))
 401     ;; This is for XEmacs.
 402     (mm-mule-charset-to-mime-charset charset)))
 403
 404 (defun mm-delete-duplicates (list)
 405   "Simple  substitute for CL `delete-duplicates', testing with `equal'."
 406   (let (result head)
 407     (while list
 408       (setq head (car list))
 409       (setq list (delete head list))
 410       (setq result (cons head result)))
 411     (nreverse result)))
 412
 413 ;; It's not clear whether this is supposed to mean the global or local
 414 ;; setting.  I think it's used inconsistently.  -- fx
 415 (defsubst mm-multibyte-p ()
 416   "Say whether multibyte is enabled."
 417   (if (and (not (featurep 'xemacs))
 418            (boundp 'enable-multibyte-characters))
 419       enable-multibyte-characters
 420     (featurep 'mule)))
 421
 422 (defun mm-find-mime-charset-region (b e)
 423   "Return the MIME charsets needed to encode the region between B and E.
 424 Nil means ASCII, a single-element list represents an appropriate MIME
 425 charset, and a longer list means no appropriate charset."
 426   ;; The return possibilities of this function are a mess...
 427   (or (and
 428        (mm-multibyte-p)
 429        (fboundp 'find-coding-systems-region)
 430        ;; Find the mime-charset of the most preferred coding
 431        ;; system that has one.
 432        (let ((systems (find-coding-systems-region b e))
 433              result)
 434          ;; Fixme: The `mime-charset' (`x-ctext') of `compound-text'
 435          ;; is not in the IANA list.
 436          (setq systems (delq 'compound-text systems))
 437          (unless (equal systems '(undecided))
 438            (while systems
 439              (let ((cs (coding-system-get (pop systems) 'mime-charset)))
 440                (if cs
 441                    (setq systems nil
 442                          result (list cs))))))
 443          result))
 444       ;; Otherwise we're not multibyte, XEmacs or a single coding
 445       ;; system won't cover it.
 446       (let ((charsets
 447              (mm-delete-duplicates
 448               (mapcar 'mm-mime-charset
 449                       (delq 'ascii
 450                             (mm-find-charset-region b e))))))
 451         (if (memq 'iso-2022-jp-2 charsets)
 452             (delq 'iso-2022-jp charsets)
 453           charsets))))
 454
 455 (defmacro mm-with-unibyte-buffer (&rest forms)
 456   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 457 Use unibyte mode for this."
 458   `(let (default-enable-multibyte-characters)
 459      (with-temp-buffer ,@forms)))
 460 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 461 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 462
 463 (defmacro mm-with-unibyte-current-buffer (&rest forms)
 464   "Evaluate FORMS with current current buffer temporarily made unibyte.
 465 Also bind `default-enable-multibyte-characters' to nil.
 466 Equivalent to `progn' in XEmacs"
 467   (let ((multibyte (make-symbol "multibyte"))
 468         (buffer (make-symbol "buffer")))
 469     `(if mm-emacs-mule
 470          (let ((,multibyte enable-multibyte-characters)
 471                (,buffer (current-buffer)))
 472            (unwind-protect
 473                (let (default-enable-multibyte-characters)
 474                  (set-buffer-multibyte nil)
 475                  ,@forms)
 476              (set-buffer ,buffer)
 477              (set-buffer-multibyte ,multibyte)))
 478        (let (default-enable-multibyte-characters)
 479          ,@forms))))
 480 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 481 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 482
 483 (defmacro mm-with-unibyte-current-buffer-mule4 (&rest forms)
 484   "Evaluate FORMS there like `progn' in current buffer.
 485 Mule4 only."
 486   (let ((multibyte (make-symbol "multibyte"))
 487         (buffer (make-symbol "buffer")))
 488     `(if mm-mule4-p
 489          (let ((,multibyte enable-multibyte-characters)
 490                (,buffer (current-buffer)))
 491            (unwind-protect
 492                (let (default-enable-multibyte-characters)
 493                  (set-buffer-multibyte nil)
 494                  ,@forms)
 495              (set-buffer ,buffer)
 496              (set-buffer-multibyte ,multibyte)))
 497        (let (default-enable-multibyte-characters)
 498          ,@forms))))
 499 (put 'mm-with-unibyte-current-buffer-mule4 'lisp-indent-function 0)
 500 (put 'mm-with-unibyte-current-buffer-mule4 'edebug-form-spec '(body))
 501
 502 (defmacro mm-with-unibyte (&rest forms)
 503   "Eval the FORMS with the default value of `enable-multibyte-characters' nil, ."
 504   `(let (default-enable-multibyte-characters)
 505      ,@forms))
 506 (put 'mm-with-unibyte 'lisp-indent-function 0)
 507 (put 'mm-with-unibyte 'edebug-form-spec '(body))
 508
 509 (defun mm-find-charset-region (b e)
 510   "Return a list of Emacs charsets in the region B to E."
 511   (cond
 512    ((and (mm-multibyte-p)
 513          (fboundp 'find-charset-region))
 514     ;; Remove composition since the base charsets have been included.
 515     ;; Remove eight-bit-*, treat them as ascii.
 516     (let ((css (find-charset-region b e)))
 517       (mapcar (lambda (cs) (setq css (delq cs css)))
 518               '(composition eight-bit-control eight-bit-graphic
 519                             control-1))
 520       css))
 521    (t
 522     ;; We are in a unibyte buffer or XEmacs non-mule, so we futz around a bit.
 523     (save-excursion
 524       (save-restriction
 525         (narrow-to-region b e)
 526         (goto-char (point-min))
 527         (skip-chars-forward "\0-\177")
 528         (if (eobp)
 529             '(ascii)
 530           (let (charset)
 531             (setq charset
 532                   (and (boundp 'current-language-environment)
 533                        (car (last (assq 'charset
 534                                         (assoc current-language-environment
 535                                                language-info-alist))))))
 536             (if (eq charset 'ascii) (setq charset nil))
 537             (or charset
 538                 (setq charset
 539                       (car (last (assq mail-parse-charset
 540                                        mm-mime-mule-charset-alist)))))
 541             (list 'ascii (or charset 'latin-iso8859-1)))))))))
 542
 543 (if (fboundp 'shell-quote-argument)
 544     (defalias 'mm-quote-arg 'shell-quote-argument)
 545   (defun mm-quote-arg (arg)
 546     "Return a version of ARG that is safe to evaluate in a shell."
 547     (let ((pos 0) new-pos accum)
 548       ;; *** bug: we don't handle newline characters properly
 549       (while (setq new-pos (string-match "[]*[;!'`\"$\\& \t{} |()<>]" arg pos))
 550         (push (substring arg pos new-pos) accum)
 551         (push "\\" accum)
 552         (push (list (aref arg new-pos)) accum)
 553         (setq pos (1+ new-pos)))
 554       (if (= pos 0)
 555           arg
 556         (apply 'concat (nconc (nreverse accum) (list (substring arg pos))))))))
 557
 558 (defun mm-auto-mode-alist ()
 559   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 560   (let ((alist auto-mode-alist)
 561         out)
 562     (while alist
 563       (when (listp (cdar alist))
 564         (push (car alist) out))
 565       (pop alist))
 566     (nreverse out)))
 567
 568 (defvar mm-inhibit-file-name-handlers
 569   '(jka-compr-handler image-file-handler)
 570   "A list of handlers doing (un)compression (etc) thingies.")
 571
 572 (defun mm-insert-file-contents (filename &optional visit beg end replace
 573                                          inhibit)
 574   "Like `insert-file-contents', q.v., but only reads in the file.
 575 A buffer may be modified in several ways after reading into the buffer due
 576 to advanced Emacs features, such as file-name-handlers, format decoding,
 577 find-file-hooks, etc.
 578 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers.
 579   This function ensures that none of these modifications will take place."
 580   (let ((format-alist nil)
 581         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 582         (default-major-mode 'fundamental-mode)
 583         (enable-local-variables nil)
 584         (after-insert-file-functions nil)
 585         (enable-local-eval nil)
 586         (find-file-hooks nil)
 587         (inhibit-file-name-operation (if inhibit
 588                                          'insert-file-contents
 589                                        inhibit-file-name-operation))
 590         (inhibit-file-name-handlers
 591          (if inhibit
 592              (append mm-inhibit-file-name-handlers
 593                      inhibit-file-name-handlers)
 594            inhibit-file-name-handlers)))
 595     (insert-file-contents filename visit beg end replace)))
 596
 597 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 598   "Append the contents of the region to the end of file FILENAME.
 599 When called from a function, expects three arguments,
 600 START, END and FILENAME.  START and END are buffer positions
 601 saying what text to write.
 602 Optional fourth argument specifies the coding system to use when
 603 encoding the file.
 604 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 605   (let ((coding-system-for-write
 606          (or codesys mm-text-coding-system-for-write
 607              mm-text-coding-system))
 608         (inhibit-file-name-operation (if inhibit
 609                                          'append-to-file
 610                                        inhibit-file-name-operation))
 611         (inhibit-file-name-handlers
 612          (if inhibit
 613              (append mm-inhibit-file-name-handlers
 614                      inhibit-file-name-handlers)
 615            inhibit-file-name-handlers)))
 616     (append-to-file start end filename)))
 617
 618 (defun mm-write-region (start end filename &optional append visit lockname
 619                               coding-system inhibit)
 620
 621   "Like `write-region'.
 622 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 623   (let ((coding-system-for-write
 624          (or coding-system mm-text-coding-system-for-write
 625              mm-text-coding-system))
 626         (inhibit-file-name-operation (if inhibit
 627                                          'write-region
 628                                        inhibit-file-name-operation))
 629         (inhibit-file-name-handlers
 630          (if inhibit
 631              (append mm-inhibit-file-name-handlers
 632                      inhibit-file-name-handlers)
 633            inhibit-file-name-handlers)))
 634     (write-region start end filename append visit lockname)))
 635
 636 (defun mm-image-load-path (&optional package)
 637   (let (dir result)
 638     (dolist (path load-path (nreverse result))
 639       (if (file-directory-p
 640            (setq dir (concat (file-name-directory
 641                               (directory-file-name path))
 642                              "etc/" (or package "gnus/"))))
 643           (push dir result))
 644       (push path result))))
 645
 646 (provide 'mm-util)
 647
 648 ;;; mm-util.el ends here