cgit.sxemacs.org Git - gnus/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for MIME things
   2 ;; Copyright (C) 1998,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (defvar mm-mime-mule-charset-alist
  28   '((us-ascii ascii)
  29     (iso-8859-1 latin-iso8859-1)
  30     (iso-8859-2 latin-iso8859-2)
  31     (iso-8859-3 latin-iso8859-3)
  32     (iso-8859-4 latin-iso8859-4)
  33     (iso-8859-5 cyrillic-iso8859-5)
  34     (koi8-r cyrillic-iso8859-5)
  35     (iso-8859-6 arabic-iso8859-6)
  36     (iso-8859-7 greek-iso8859-7)
  37     (iso-8859-8 hebrew-iso8859-8)
  38     (iso-8859-9 latin-iso8859-9)
  39     (viscii vietnamese-viscii-lower)
  40     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
  41     (euc-kr korean-ksc5601)
  42     (cn-gb-2312 chinese-gb2312)
  43     (cn-big5 chinese-big5-1 chinese-big5-2)
  44     (tibetan tibetan)
  45     (thai-tis620 thai-tis620)
  46     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
  47     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
  48                    latin-jisx0201 japanese-jisx0208-1978
  49                    chinese-gb2312 japanese-jisx0208
  50                    korean-ksc5601 japanese-jisx0212
  51                    katakana-jisx0201)
  52     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
  53                     latin-jisx0201 japanese-jisx0208-1978
  54                     chinese-gb2312 japanese-jisx0208
  55                     korean-ksc5601 japanese-jisx0212
  56                     chinese-cns11643-1 chinese-cns11643-2)
  57     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
  58                     cyrillic-iso8859-5 greek-iso8859-7
  59                     latin-jisx0201 japanese-jisx0208-1978
  60                     chinese-gb2312 japanese-jisx0208
  61                     korean-ksc5601 japanese-jisx0212
  62                     chinese-cns11643-1 chinese-cns11643-2
  63                     chinese-cns11643-3 chinese-cns11643-4
  64                     chinese-cns11643-5 chinese-cns11643-6
  65                     chinese-cns11643-7))
  66   "Alist of MIME-charset/MULE-charsets.")
  67
  68
  69 (eval-and-compile
  70   (mapcar
  71    (lambda (elem)
  72      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  73        (if (fboundp (car elem))
  74            (defalias nfunc (car elem))
  75          (defalias nfunc (cdr elem)))))
  76    '((decode-coding-string . (lambda (s a) s))
  77      (encode-coding-string . (lambda (s a) s))
  78      (encode-coding-region . ignore)
  79      (coding-system-list . ignore)
  80      (decode-coding-region . ignore)
  81      (char-int . identity)
  82      (device-type . ignore)
  83      (coding-system-equal . equal)
  84      (annotationp . ignore)
  85      (set-buffer-file-coding-system . ignore)
  86      (make-char
  87       . (lambda (charset int)
  88           (int-to-char int)))
  89      (read-coding-system
  90       . (lambda (prompt)
  91           "Prompt the user for a coding system."
  92           (completing-read
  93            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
  94                           mm-mime-mule-charset-alist)))))))
  95
  96 (defvar mm-coding-system-list nil)
  97 (defun mm-get-coding-system-list ()
  98   "Get the coding system list."
  99   (or mm-coding-system-list
 100       (setq mm-coding-system-list (mm-coding-system-list))))
 101
 102 (defvar mm-charset-synonym-alist
 103   '((big5 . cn-big5)
 104     (gb2312 . cn-gb-2312)
 105     (x-ctext . ctext))
 106   "A mapping from invalid charset names to the real charset names.")
 107
 108 (defun mm-coding-system-p (sym)
 109   "Return non-nil if SYM is a coding system."
 110   (or (and (fboundp 'coding-system-p) (coding-system-p sym))
 111       (memq sym (mm-get-coding-system-list))))
 112
 113 (defvar mm-binary-coding-system
 114   (cond
 115    ((mm-coding-system-p 'binary) 'binary)
 116    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 117    (t nil))
 118   "100% binary coding system.")
 119
 120 (defvar mm-text-coding-system
 121   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 122           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 123         (and (mm-coding-system-p 'raw-text) 'raw-text))
 124       mm-binary-coding-system)
 125   "Text-safe coding system (For removing ^M).")
 126
 127 (defvar mm-text-coding-system-for-write nil
 128   "Text coding system for write.")
 129
 130 (defvar mm-auto-save-coding-system
 131   (cond
 132    ((mm-coding-system-p 'emacs-mule)
 133     (if (memq system-type '(windows-nt ms-dos ms-windows))
 134         (if (mm-coding-system-p 'emacs-mule-dos)
 135             'emacs-mule-dos mm-binary-coding-system)
 136       'emacs-mule))
 137    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 138    (t mm-binary-coding-system))
 139   "Coding system of auto save file.")
 140
 141 ;;; Internal variables:
 142
 143 ;;; Functions:
 144
 145 (defun mm-mule-charset-to-mime-charset (charset)
 146   "Return the MIME charset corresponding to MULE CHARSET."
 147   (let ((alist mm-mime-mule-charset-alist)
 148         out)
 149     (while alist
 150       (when (memq charset (cdar alist))
 151         (setq out (caar alist)
 152               alist nil))
 153       (pop alist))
 154     out))
 155
 156 (defun mm-charset-to-coding-system (charset &optional lbt)
 157   "Return coding-system corresponding to CHARSET.
 158 CHARSET is a symbol naming a MIME charset.
 159 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 160 used as the line break code type of the coding system."
 161   (when (stringp charset)
 162     (setq charset (intern (downcase charset))))
 163   (setq charset
 164         (or (cdr (assq charset mm-charset-synonym-alist))
 165             charset))
 166   (when lbt
 167     (setq charset (intern (format "%s-%s" charset lbt))))
 168   (cond
 169    ;; Running in a non-MULE environment.
 170    ((null (mm-get-coding-system-list))
 171     charset)
 172    ;; ascii
 173    ((eq charset 'us-ascii)
 174     'ascii)
 175    ;; Check to see whether we can handle this charset.
 176    ((memq charset (mm-get-coding-system-list))
 177     charset)
 178    ;; Nope.
 179    (t
 180     nil)))
 181
 182 (defun mm-replace-chars-in-string (string from to)
 183   "Replace characters in STRING from FROM to TO."
 184   (let ((string (substring string 0))   ;Copy string.
 185         (len (length string))
 186         (idx 0))
 187     ;; Replace all occurrences of FROM with TO.
 188     (while (< idx len)
 189       (when (= (aref string idx) from)
 190         (aset string idx to))
 191       (setq idx (1+ idx)))
 192     string))
 193
 194 (defsubst mm-enable-multibyte ()
 195   "Enable multibyte in the current buffer."
 196   (when (and (fboundp 'set-buffer-multibyte)
 197              (boundp 'enable-multibyte-characters)
 198              (default-value 'enable-multibyte-characters))
 199     (set-buffer-multibyte t)))
 200
 201 (defsubst mm-disable-multibyte ()
 202   "Disable multibyte in the current buffer."
 203   (when (fboundp 'set-buffer-multibyte)
 204     (set-buffer-multibyte nil)))
 205
 206 (defun mm-preferred-coding-system (charset)
 207   ;; A typo in some Emacs versions.
 208   (or (get-charset-property charset 'prefered-coding-system)
 209       (get-charset-property charset 'preferred-coding-system)))
 210
 211 (defun mm-charset-after (&optional pos)
 212   "Return charset of a character in current buffer at position POS.
 213 If POS is nil, it defauls to the current point.
 214 If POS is out of range, the value is nil.
 215 If the charset is `composition', return the actual one."
 216   (let ((charset (if (fboundp 'charset-after)
 217                      (charset-after pos)
 218                    (char-charset (char-after pos)))))
 219     (if (eq charset 'composition)
 220         (let ((p (or pos (point))))
 221           (cadr (find-charset-region p (1+ p))))
 222       charset)))
 223
 224 (defun mm-mime-charset (charset)
 225   "Return the MIME charset corresponding to the MULE CHARSET."
 226   (if (fboundp 'coding-system-get)
 227       ;; This exists in Emacs 20.
 228       (or
 229        (and (mm-preferred-coding-system charset)
 230             (coding-system-get
 231              (mm-preferred-coding-system charset) 'mime-charset))
 232        (and (eq charset 'ascii)
 233             'us-ascii)
 234        (mm-preferred-coding-system charset)
 235        (mm-mule-charset-to-mime-charset charset))
 236     ;; This is for XEmacs.
 237     (mm-mule-charset-to-mime-charset charset)))
 238
 239 (defun mm-find-mime-charset-region (b e)
 240   "Return the MIME charsets needed to encode the region between B and E."
 241   (let ((charsets (mapcar 'mm-mime-charset
 242                           (delq 'ascii
 243                                 (mm-find-charset-region b e)))))
 244     (when (memq 'iso-2022-jp-2 charsets)
 245       (setq charsets (delq 'iso-2022-jp charsets)))
 246     (setq charsets (delete-duplicates charsets))
 247     (if (and (> (length charsets) 1)
 248              (fboundp 'find-coding-systems-region)
 249              (memq 'utf-8 (find-coding-systems-region b e)))
 250         '(utf-8)
 251       charsets)))
 252
 253 (defsubst mm-multibyte-p ()
 254   "Say whether multibyte is enabled."
 255   (or (string-match "XEmacs\\|Lucid" emacs-version)
 256       (and (boundp 'enable-multibyte-characters)
 257            enable-multibyte-characters)))
 258
 259 (defmacro mm-with-unibyte-buffer (&rest forms)
 260   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 261 See also `with-temp-file' and `with-output-to-string'."
 262   (let ((temp-buffer (make-symbol "temp-buffer"))
 263         (multibyte (make-symbol "multibyte")))
 264     `(if (or (string-match "XEmacs\\|Lucid" emacs-version)
 265              (not (boundp 'enable-multibyte-characters)))
 266          (with-temp-buffer ,@forms)
 267        (let ((,multibyte (default-value 'enable-multibyte-characters))
 268              ,temp-buffer)
 269          (unwind-protect
 270              (progn
 271                (setq-default enable-multibyte-characters nil)
 272                (setq ,temp-buffer
 273                      (get-buffer-create (generate-new-buffer-name " *temp*")))
 274                (unwind-protect
 275                    (with-current-buffer ,temp-buffer
 276                      (let ((buffer-file-coding-system mm-binary-coding-system)
 277                            (coding-system-for-read mm-binary-coding-system)
 278                            (coding-system-for-write mm-binary-coding-system))
 279                        ,@forms))
 280                  (and (buffer-name ,temp-buffer)
 281                       (kill-buffer ,temp-buffer))))
 282            (setq-default enable-multibyte-characters ,multibyte))))))
 283 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 284 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 285
 286 (defmacro mm-with-unibyte-current-buffer (&rest forms)
 287   "Evaluate FORMS there like `progn' in current buffer."
 288   (let ((multibyte (make-symbol "multibyte")))
 289     `(if (or (string-match "XEmacs\\|Lucid" emacs-version)
 290              (not (fboundp 'set-buffer-multibyte)))
 291          (progn
 292            ,@forms)
 293        (let ((,multibyte (default-value 'enable-multibyte-characters)))
 294          (unwind-protect
 295              (let ((buffer-file-coding-system mm-binary-coding-system)
 296                    (coding-system-for-read mm-binary-coding-system)
 297                    (coding-system-for-write mm-binary-coding-system))
 298                (set-buffer-multibyte nil)
 299                ,@forms)
 300            (set-buffer-multibyte ,multibyte))))))
 301 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 302 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 303
 304 (defmacro mm-with-unibyte (&rest forms)
 305   "Set default `enable-multibyte-characters' to `nil', eval the FORMS."
 306   (let ((multibyte (make-symbol "multibyte")))
 307     `(if (or (string-match "XEmacs\\|Lucid" emacs-version)
 308              (not (boundp 'enable-multibyte-characters)))
 309          (progn ,@forms)
 310        (let ((,multibyte (default-value 'enable-multibyte-characters)))
 311          (unwind-protect
 312              (progn
 313                (setq-default enable-multibyte-characters nil)
 314                ,@forms)
 315            (setq-default enable-multibyte-characters ,multibyte))))))
 316 (put 'mm-with-unibyte 'lisp-indent-function 0)
 317 (put 'mm-with-unibyte 'edebug-form-spec '(body))
 318
 319 (defun mm-find-charset-region (b e)
 320   "Return a list of charsets in the region."
 321   (cond
 322    ((and (mm-multibyte-p)
 323          (fboundp 'find-charset-region))
 324     ;; Remove composition since the base charsets have been included.
 325     (delq 'composition (find-charset-region b e)))
 326    ((not (boundp 'current-language-environment))
 327     (save-excursion
 328       (save-restriction
 329         (narrow-to-region b e)
 330         (goto-char (point-min))
 331         (skip-chars-forward "\0-\177")
 332         (if (eobp)
 333             '(ascii)
 334           (delq nil (list 'ascii mail-parse-charset))))))
 335    (t
 336     ;; We are in a unibyte buffer, so we futz around a bit.
 337     (save-excursion
 338       (save-restriction
 339         (narrow-to-region b e)
 340         (goto-char (point-min))
 341         (let ((entry (assoc current-language-environment
 342                             language-info-alist)))
 343           (skip-chars-forward "\0-\177")
 344           (if (eobp)
 345               '(ascii)
 346             (delq nil (list 'ascii (car (last (assq 'charset entry))))))))))))
 347
 348 (defun mm-read-charset (prompt)
 349   "Return a charset."
 350   (intern
 351    (completing-read
 352     prompt
 353     (mapcar (lambda (e) (list (symbol-name (car e))))
 354             mm-mime-mule-charset-alist)
 355     nil t)))
 356
 357 (defun mm-quote-arg (arg)
 358   "Return a version of ARG that is safe to evaluate in a shell."
 359   (let ((pos 0) new-pos accum)
 360     ;; *** bug: we don't handle newline characters properly
 361     (while (setq new-pos (string-match "[]*[;!'`\"$\\& \t{} |()<>]" arg pos))
 362       (push (substring arg pos new-pos) accum)
 363       (push "\\" accum)
 364       (push (list (aref arg new-pos)) accum)
 365       (setq pos (1+ new-pos)))
 366     (if (= pos 0)
 367         arg
 368       (apply 'concat (nconc (nreverse accum) (list (substring arg pos)))))))
 369
 370 (defun mm-auto-mode-alist ()
 371   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 372   (let ((alist auto-mode-alist)
 373         out)
 374     (while alist
 375       (when (listp (cdar alist))
 376         (push (car alist) out))
 377       (pop alist))
 378     (nreverse out)))
 379
 380 (defvar mm-inhibit-file-name-handlers
 381   '(jka-compr-handler)
 382   "A list of handlers doing (un)compression (etc) thingies.")
 383
 384 (defun mm-insert-file-contents (filename &optional visit beg end replace
 385                                          inhibit)
 386   "Like `insert-file-contents', q.v., but only reads in the file.
 387 A buffer may be modified in several ways after reading into the buffer due
 388 to advanced Emacs features, such as file-name-handlers, format decoding,
 389 find-file-hooks, etc.
 390 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers.
 391   This function ensures that none of these modifications will take place."
 392   (let ((format-alist nil)
 393         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 394         (default-major-mode 'fundamental-mode)
 395         (enable-local-variables nil)
 396         (after-insert-file-functions nil)
 397         (enable-local-eval nil)
 398         (find-file-hooks nil)
 399         (inhibit-file-name-operation (if inhibit
 400                                          'insert-file-contents
 401                                        inhibit-file-name-operation))
 402         (inhibit-file-name-handlers
 403          (if inhibit
 404              (append mm-inhibit-file-name-handlers
 405                      inhibit-file-name-handlers)
 406            inhibit-file-name-handlers)))
 407     (insert-file-contents filename visit beg end replace)))
 408
 409 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 410   "Append the contents of the region to the end of file FILENAME.
 411 When called from a function, expects three arguments,
 412 START, END and FILENAME.  START and END are buffer positions
 413 saying what text to write.
 414 Optional fourth argument specifies the coding system to use when
 415 encoding the file.
 416 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 417   (let ((coding-system-for-write
 418          (or codesys mm-text-coding-system-for-write
 419              mm-text-coding-system))
 420         (inhibit-file-name-operation (if inhibit
 421                                          'append-to-file
 422                                        inhibit-file-name-operation))
 423         (inhibit-file-name-handlers
 424          (if inhibit
 425              (append mm-inhibit-file-name-handlers
 426                      inhibit-file-name-handlers)
 427            inhibit-file-name-handlers)))
 428     (append-to-file start end filename)))
 429
 430 (defun mm-write-region (start end filename &optional append visit lockname
 431                               coding-system inhibit)
 432
 433   "Like `write-region'.
 434 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 435   (let ((coding-system-for-write
 436          (or coding-system mm-text-coding-system-for-write
 437              mm-text-coding-system))
 438         (inhibit-file-name-operation (if inhibit
 439                                          'write-region
 440                                        inhibit-file-name-operation))
 441         (inhibit-file-name-handlers
 442          (if inhibit
 443              (append mm-inhibit-file-name-handlers
 444                      inhibit-file-name-handlers)
 445            inhibit-file-name-handlers)))
 446     (write-region start end filename append visit lockname)))
 447
 448 (provide 'mm-util)
 449
 450 ;;; mm-util.el ends here