cgit.sxemacs.org Git - gnus/blob - lisp/mm-decode.el

   1 ;;; mm-decode.el --- Functions for decoding MIME things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'mail-parse)
  29 (require 'mailcap)
  30 (require 'mm-bodies)
  31 (eval-when-compile (require 'cl)
  32                    (require 'term))
  33
  34 (eval-and-compile
  35   (autoload 'mm-inline-partial "mm-partial")
  36   (autoload 'mm-inline-external-body "mm-extern")
  37   (autoload 'mm-insert-inline "mm-view"))
  38
  39 (add-hook 'gnus-exit-gnus-hook 'mm-destroy-postponed-undisplay-list)
  40
  41 (defgroup mime-display ()
  42   "Display of MIME in mail and news articles."
  43   :link '(custom-manual "(emacs-mime)Display Customization")
  44   :version "21.1"
  45   :group 'mail
  46   :group 'news
  47   :group 'multimedia)
  48
  49 (defgroup mime-security ()
  50   "MIME security in mail and news articles."
  51   :link '(custom-manual "(emacs-mime)Display Customization")
  52   :group 'mail
  53   :group 'news
  54   :group 'multimedia)
  55
  56 ;;; Convenience macros.
  57
  58 (defmacro mm-handle-buffer (handle)
  59   `(nth 0 ,handle))
  60 (defmacro mm-handle-type (handle)
  61   `(nth 1 ,handle))
  62 (defsubst mm-handle-media-type (handle)
  63   (if (stringp (car handle))
  64       (car handle)
  65     (car (mm-handle-type handle))))
  66 (defsubst mm-handle-media-supertype (handle)
  67   (car (split-string (mm-handle-media-type handle) "/")))
  68 (defsubst mm-handle-media-subtype (handle)
  69   (cadr (split-string (mm-handle-media-type handle) "/")))
  70 (defmacro mm-handle-encoding (handle)
  71   `(nth 2 ,handle))
  72 (defmacro mm-handle-undisplayer (handle)
  73   `(nth 3 ,handle))
  74 (defmacro mm-handle-set-undisplayer (handle function)
  75   `(setcar (nthcdr 3 ,handle) ,function))
  76 (defmacro mm-handle-disposition (handle)
  77   `(nth 4 ,handle))
  78 (defmacro mm-handle-description (handle)
  79   `(nth 5 ,handle))
  80 (defmacro mm-handle-cache (handle)
  81   `(nth 6 ,handle))
  82 (defmacro mm-handle-set-cache (handle contents)
  83   `(setcar (nthcdr 6 ,handle) ,contents))
  84 (defmacro mm-handle-id (handle)
  85   `(nth 7 ,handle))
  86 (defmacro mm-handle-multipart-original-buffer (handle)
  87   `(get-text-property 0 'buffer (car ,handle)))
  88 (defmacro mm-handle-multipart-from (handle)
  89   `(get-text-property 0 'from (car ,handle)))
  90 (defmacro mm-handle-multipart-ctl-parameter (handle parameter)
  91   `(get-text-property 0 ,parameter (car ,handle)))
  92
  93 (defmacro mm-make-handle (&optional buffer type encoding undisplayer
  94                                     disposition description cache
  95                                     id)
  96   `(list ,buffer ,type ,encoding ,undisplayer
  97          ,disposition ,description ,cache ,id))
  98
  99 (defcustom mm-text-html-renderer
 100   (cond ((locate-library "w3") 'w3)
 101         ((executable-find "w3m") (if (locate-library "w3m")
 102                                      'w3m
 103                                    'w3m-standalone))
 104         ((executable-find "links") 'links)
 105         ((executable-find "lynx") 'lynx)
 106         (t 'html2text))
 107   "Render of HTML contents.
 108 It is one of defined renderer types, or a rendering function.
 109 The defined renderer types are:
 110 `w3'   : use Emacs/W3;
 111 `w3m'  : use emacs-w3m;
 112 `w3m-standalone': use w3m;
 113 `links': use links;
 114 `lynx' : use lynx;
 115 `html2text' : use html2text;
 116 nil    : use external viewer."
 117   :version "21.4"
 118   :type '(choice (const w3)
 119                  (const w3m)
 120                  (const w3m-standalone)
 121                  (const links)
 122                  (const lynx)
 123                  (const html2text)
 124                  (const nil)
 125                  (function))
 126   :group 'mime-display)
 127
 128 (defvar mm-inline-text-html-renderer nil
 129   "Function used for rendering inline HTML contents.
 130 It is suggested to customize `mm-text-html-renderer' instead.")
 131
 132 (defcustom mm-inline-text-html-with-images nil
 133   "If non-nil, Gnus will allow retrieving images in HTML contents with
 134 the <img> tags.  It has no effect on Emacs/w3.  See also the
 135 documentation for the `mm-w3m-safe-url-regexp' variable."
 136   :version "21.4"
 137   :type 'boolean
 138   :group 'mime-display)
 139
 140 (defcustom mm-w3m-safe-url-regexp "\\`cid:"
 141   "Regexp matching URLs which are considered to be safe.
 142 Some HTML mails might contain a nasty trick used by spammers, using
 143 the <img> tag which is far more evil than the [Click Here!] button.
 144 It is most likely intended to check whether the ominous spam mail has
 145 reached your eyes or not, in which case the spammer knows for sure
 146 that your email address is valid.  It is done by embedding an
 147 identifier string into a URL that you might automatically retrieve
 148 when displaying the image.  The default value is \"\\\\`cid:\" which only
 149 matches parts embedded to the Multipart/Related type MIME contents and
 150 Gnus will never connect to the spammer's site arbitrarily.  You may
 151 set this variable to nil if you consider all urls to be safe."
 152   :type '(choice (regexp :tag "Regexp")
 153                  (const :tag "All URLs are safe" nil))
 154   :group 'mime-display)
 155
 156 (defcustom mm-inline-text-html-with-w3m-keymap t
 157   "If non-nil, use emacs-w3m command keys in the article buffer."
 158   :type 'boolean
 159   :group 'mime-display)
 160
 161 (defcustom mm-enable-external t
 162   "Indicate whether external MIME handlers should be used.
 163
 164 If t, all defined external MIME handlers are used.  If nil, files are saved by
 165 `mailcap-save-binary-file'.  If it is the symbol `ask', you are prompted
 166 before the external MIME handler is invoked."
 167   :version "21.4"
 168   :type '(choice (const :tag "Always" t)
 169                  (const :tag "Never" nil)
 170                  (const :tag "Ask" ask))
 171   :group 'mime-display)
 172
 173 (defcustom mm-inline-media-tests
 174   '(("image/p?jpeg"
 175      mm-inline-image
 176      (lambda (handle)
 177        (mm-valid-and-fit-image-p 'jpeg handle)))
 178     ("image/png"
 179      mm-inline-image
 180      (lambda (handle)
 181        (mm-valid-and-fit-image-p 'png handle)))
 182     ("image/gif"
 183      mm-inline-image
 184      (lambda (handle)
 185        (mm-valid-and-fit-image-p 'gif handle)))
 186     ("image/tiff"
 187      mm-inline-image
 188      (lambda (handle)
 189        (mm-valid-and-fit-image-p 'tiff handle)) )
 190     ("image/xbm"
 191      mm-inline-image
 192      (lambda (handle)
 193        (mm-valid-and-fit-image-p 'xbm handle)))
 194     ("image/x-xbitmap"
 195      mm-inline-image
 196      (lambda (handle)
 197        (mm-valid-and-fit-image-p 'xbm handle)))
 198     ("image/xpm"
 199      mm-inline-image
 200      (lambda (handle)
 201        (mm-valid-and-fit-image-p 'xpm handle)))
 202     ("image/x-xpixmap"
 203      mm-inline-image
 204      (lambda (handle)
 205        (mm-valid-and-fit-image-p 'xpm handle)))
 206     ("image/bmp"
 207      mm-inline-image
 208      (lambda (handle)
 209        (mm-valid-and-fit-image-p 'bmp handle)))
 210     ("image/x-portable-bitmap"
 211      mm-inline-image
 212      (lambda (handle)
 213        (mm-valid-and-fit-image-p 'pbm handle)))
 214     ("text/plain" mm-inline-text identity)
 215     ("text/enriched" mm-inline-text identity)
 216     ("text/richtext" mm-inline-text identity)
 217     ("text/x-patch" mm-display-patch-inline
 218      (lambda (handle)
 219        (locate-library "diff-mode")))
 220     ("application/emacs-lisp" mm-display-elisp-inline identity)
 221     ("application/x-emacs-lisp" mm-display-elisp-inline identity)
 222     ("text/dns" mm-display-dns-inline identity)
 223     ("text/html"
 224      mm-inline-text-html
 225      (lambda (handle)
 226        (or mm-inline-text-html-renderer
 227            mm-text-html-renderer)))
 228     ("text/x-vcard"
 229      mm-inline-text-vcard
 230      (lambda (handle)
 231        (or (featurep 'vcard)
 232            (locate-library "vcard"))))
 233     ("message/delivery-status" mm-inline-text identity)
 234     ("message/rfc822" mm-inline-message identity)
 235     ("message/partial" mm-inline-partial identity)
 236     ("message/external-body" mm-inline-external-body identity)
 237     ("text/.*" mm-inline-text identity)
 238     ("audio/wav" mm-inline-audio
 239      (lambda (handle)
 240        (and (or (featurep 'nas-sound) (featurep 'native-sound))
 241             (device-sound-enabled-p))))
 242     ("audio/au"
 243      mm-inline-audio
 244      (lambda (handle)
 245        (and (or (featurep 'nas-sound) (featurep 'native-sound))
 246             (device-sound-enabled-p))))
 247     ("application/pgp-signature" ignore identity)
 248     ("application/x-pkcs7-signature" ignore identity)
 249     ("application/pkcs7-signature" ignore identity)
 250     ("application/x-pkcs7-mime" ignore identity)
 251     ("application/pkcs7-mime" ignore identity)
 252     ("multipart/alternative" ignore identity)
 253     ("multipart/mixed" ignore identity)
 254     ("multipart/related" ignore identity)
 255     ;; Disable audio and image
 256     ("audio/.*" ignore ignore)
 257     ("image/.*" ignore ignore)
 258     ;; Default to displaying as text
 259     (".*" mm-inline-text mm-readable-p))
 260   "Alist of media types/tests saying whether types can be displayed inline."
 261   :type '(repeat (list (regexp :tag "MIME type")
 262                        (function :tag "Display function")
 263                        (function :tag "Display test")))
 264   :group 'mime-display)
 265
 266 (defcustom mm-inlined-types
 267   '("image/.*" "text/.*" "message/delivery-status" "message/rfc822"
 268     "message/partial" "message/external-body" "application/emacs-lisp"
 269     "application/x-emacs-lisp"
 270     "application/pgp-signature" "application/x-pkcs7-signature"
 271     "application/pkcs7-signature" "application/x-pkcs7-mime"
 272     "application/pkcs7-mime")
 273   "List of media types that are to be displayed inline.
 274 See also `mm-inline-media-tests', which says how to display a media
 275 type inline."
 276   :type '(repeat string)
 277   :group 'mime-display)
 278
 279 (defcustom mm-keep-viewer-alive-types
 280   '("application/postscript" "application/msword" "application/vnd.ms-excel"
 281     "application/pdf" "application/x-dvi")
 282   "List of media types for which the external viewer will not be killed
 283 when selecting a different article."
 284   :version "21.4"
 285   :type '(repeat string)
 286   :group 'mime-display)
 287
 288 (defcustom mm-automatic-display
 289   '("text/plain" "text/enriched" "text/richtext" "text/html"
 290     "text/x-vcard" "image/.*" "message/delivery-status" "multipart/.*"
 291     "message/rfc822" "text/x-patch" "text/dns" "application/pgp-signature"
 292     "application/emacs-lisp" "application/x-emacs-lisp"
 293     "application/x-pkcs7-signature"
 294     "application/pkcs7-signature" "application/x-pkcs7-mime"
 295     "application/pkcs7-mime")
 296   "A list of MIME types to be displayed automatically."
 297   :type '(repeat string)
 298   :group 'mime-display)
 299
 300 (defcustom mm-attachment-override-types '("text/x-vcard"
 301                                           "application/pkcs7-mime"
 302                                           "application/x-pkcs7-mime"
 303                                           "application/pkcs7-signature"
 304                                           "application/x-pkcs7-signature")
 305   "Types to have \"attachment\" ignored if they can be displayed inline."
 306   :type '(repeat string)
 307   :group 'mime-display)
 308
 309 (defcustom mm-inline-override-types nil
 310   "Types to be treated as attachments even if they can be displayed inline."
 311   :type '(repeat string)
 312   :group 'mime-display)
 313
 314 (defcustom mm-automatic-external-display nil
 315   "List of MIME type regexps that will be displayed externally automatically."
 316   :type '(repeat string)
 317   :group 'mime-display)
 318
 319 (defcustom mm-discouraged-alternatives nil
 320   "List of MIME types that are discouraged when viewing multipart/alternative.
 321 Viewing agents are supposed to view the last possible part of a message,
 322 as that is supposed to be the richest.  However, users may prefer other
 323 types instead, and this list says what types are most unwanted.  If,
 324 for instance, text/html parts are very unwanted, and text/richtext are
 325 somewhat unwanted, then the value of this variable should be set
 326 to:
 327
 328  (\"text/html\" \"text/richtext\")"
 329   :type '(repeat string)
 330   :group 'mime-display)
 331
 332 (defcustom mm-tmp-directory
 333   (if (fboundp 'temp-directory)
 334       (temp-directory)
 335     (if (boundp 'temporary-file-directory)
 336         temporary-file-directory
 337       "/tmp/"))
 338   "Where mm will store its temporary files."
 339   :type 'directory
 340   :group 'mime-display)
 341
 342 (defcustom mm-inline-large-images nil
 343   "If non-nil, then all images fit in the buffer."
 344   :type 'boolean
 345   :group 'mime-display)
 346
 347 (defvar mm-file-name-rewrite-functions
 348   '(mm-file-name-delete-control mm-file-name-delete-gotchas)
 349   "*List of functions used for rewriting file names of MIME parts.
 350 Each function takes a file name as input and returns a file name.
 351
 352 Ready-made functions include
 353 `mm-file-name-delete-control'
 354 `mm-file-name-delete-gotchas'
 355 `mm-file-name-delete-whitespace',
 356 `mm-file-name-trim-whitespace',
 357 `mm-file-name-collapse-whitespace',
 358 `mm-file-name-replace-whitespace',
 359 `capitalize', `downcase', `upcase', and
 360 `upcase-initials'.")
 361
 362 (defvar mm-path-name-rewrite-functions nil
 363   "*List of functions for rewriting the full file names of MIME parts.
 364 This is used when viewing parts externally, and is meant for
 365 transforming the absolute name so that non-compliant programs can find
 366 the file where it's saved.
 367
 368 Each function takes a file name as input and returns a file name.")
 369
 370 (defvar mm-file-name-replace-whitespace nil
 371   "String used for replacing whitespace characters; default is `\"_\"'.")
 372
 373 (defcustom mm-default-directory nil
 374   "The default directory where mm will save files.
 375 If not set, `default-directory' will be used."
 376   :type '(choice directory (const :tag "Default" nil))
 377   :group 'mime-display)
 378
 379 (defcustom mm-attachment-file-modes 384
 380   "Set the mode bits of saved attachments to this integer."
 381   :type 'integer
 382   :group 'mime-display)
 383
 384 (defcustom mm-external-terminal-program "xterm"
 385   "The program to start an external terminal."
 386   :version "21.4"
 387   :type 'string
 388   :group 'mime-display)
 389
 390 ;;; Internal variables.
 391
 392 (defvar mm-last-shell-command "")
 393 (defvar mm-content-id-alist nil)
 394 (defvar mm-postponed-undisplay-list nil)
 395
 396 ;; According to RFC2046, in particular, in a digest, the default
 397 ;; Content-Type value for a body part is changed from "text/plain" to
 398 ;; "message/rfc822".
 399 (defvar mm-dissect-default-type "text/plain")
 400
 401 (autoload 'mml2015-verify "mml2015")
 402 (autoload 'mml2015-verify-test "mml2015")
 403 (autoload 'mml-smime-verify "mml-smime")
 404 (autoload 'mml-smime-verify-test "mml-smime")
 405
 406 (defvar mm-verify-function-alist
 407   '(("application/pgp-signature" mml2015-verify "PGP" mml2015-verify-test)
 408     ("application/x-gnus-pgp-signature" mm-uu-pgp-signed-extract-1 "PGP"
 409      mm-uu-pgp-signed-test)
 410     ("application/pkcs7-signature" mml-smime-verify "S/MIME"
 411      mml-smime-verify-test)
 412     ("application/x-pkcs7-signature" mml-smime-verify "S/MIME"
 413      mml-smime-verify-test)))
 414
 415 (defcustom mm-verify-option 'never
 416   "Option of verifying signed parts.
 417 `never', not verify; `always', always verify;
 418 `known', only verify known protocols.  Otherwise, ask user."
 419   :version "21.4"
 420   :type '(choice (item always)
 421                  (item never)
 422                  (item :tag "only known protocols" known)
 423                  (item :tag "ask" nil))
 424   :group 'mime-security)
 425
 426 (autoload 'mml2015-decrypt "mml2015")
 427 (autoload 'mml2015-decrypt-test "mml2015")
 428
 429 (defvar mm-decrypt-function-alist
 430   '(("application/pgp-encrypted" mml2015-decrypt "PGP" mml2015-decrypt-test)
 431     ("application/x-gnus-pgp-encrypted" mm-uu-pgp-encrypted-extract-1 "PGP"
 432      mm-uu-pgp-encrypted-test)))
 433
 434 (defcustom mm-decrypt-option nil
 435   "Option of decrypting encrypted parts.
 436 `never', not decrypt; `always', always decrypt;
 437 `known', only decrypt known protocols.  Otherwise, ask user."
 438   :type '(choice (item always)
 439                  (item never)
 440                  (item :tag "only known protocols" known)
 441                  (item :tag "ask" nil))
 442   :group 'mime-security)
 443
 444 (defvar mm-viewer-completion-map
 445   (let ((map (make-sparse-keymap 'mm-viewer-completion-map)))
 446     (set-keymap-parent map minibuffer-local-completion-map)
 447     map)
 448   "Keymap for input viewer with completion.")
 449
 450 ;; Should we bind other key to minibuffer-complete-word?
 451 (define-key mm-viewer-completion-map " " 'self-insert-command)
 452
 453 (defvar mm-viewer-completion-map
 454   (let ((map (make-sparse-keymap 'mm-viewer-completion-map)))
 455     (set-keymap-parent map minibuffer-local-completion-map)
 456     map)
 457   "Keymap for input viewer with completion.")
 458
 459 ;; Should we bind other key to minibuffer-complete-word?
 460 (define-key mm-viewer-completion-map " " 'self-insert-command)
 461
 462 ;;; The functions.
 463
 464 (defun mm-alist-to-plist (alist)
 465   "Convert association list ALIST into the equivalent property-list form.
 466 The plist is returned.  This converts from
 467
 468 \((a . 1) (b . 2) (c . 3))
 469
 470 into
 471
 472 \(a 1 b 2 c 3)
 473
 474 The original alist is not modified.  See also `destructive-alist-to-plist'."
 475   (let (plist)
 476     (while alist
 477       (let ((el (car alist)))
 478         (setq plist (cons (cdr el) (cons (car el) plist))))
 479       (setq alist (cdr alist)))
 480     (nreverse plist)))
 481
 482 (defun mm-keep-viewer-alive-p (handle)
 483   "Say whether external viewer for HANDLE should stay alive."
 484   (let ((types mm-keep-viewer-alive-types)
 485         (type (mm-handle-media-type handle))
 486         ty)
 487     (catch 'found
 488       (while (setq ty (pop types))
 489         (when (string-match ty type)
 490           (throw 'found t))))))
 491
 492 (defun mm-handle-set-external-undisplayer (handle function)
 493   "Set the undisplayer for HANDLE to FUNCTION.
 494 Postpone undisplaying of viewers for types in
 495 `mm-keep-viewer-alive-types'."
 496   (if (mm-keep-viewer-alive-p handle)
 497       (let ((new-handle (copy-sequence handle)))
 498         (mm-handle-set-undisplayer new-handle function)
 499         (mm-handle-set-undisplayer handle nil)
 500         (push new-handle mm-postponed-undisplay-list))
 501     (mm-handle-set-undisplayer handle function)))
 502
 503 (defun mm-destroy-postponed-undisplay-list ()
 504   (when mm-postponed-undisplay-list
 505     (message "Destroying external MIME viewers")
 506     (mm-destroy-parts mm-postponed-undisplay-list)))
 507
 508 (defun mm-dissect-buffer (&optional no-strict-mime loose-mime)
 509   "Dissect the current buffer and return a list of MIME handles."
 510   (save-excursion
 511     (let (ct ctl type subtype cte cd description id result from)
 512       (save-restriction
 513         (mail-narrow-to-head)
 514         (when (or no-strict-mime
 515                   loose-mime
 516                   (mail-fetch-field "mime-version"))
 517           (setq ct (mail-fetch-field "content-type")
 518                 ctl (ignore-errors (mail-header-parse-content-type ct))
 519                 cte (mail-fetch-field "content-transfer-encoding")
 520                 cd (mail-fetch-field "content-disposition")
 521                 description (mail-fetch-field "content-description")
 522                 from (mail-fetch-field "from")
 523                 id (mail-fetch-field "content-id"))
 524           ;; FIXME: In some circumstances, this code is running within
 525           ;; an unibyte macro.  mail-extract-address-components
 526           ;; creates unibyte buffers. This `if', though not a perfect
 527           ;; solution, avoids most of them.
 528           (if from
 529               (setq from (cadr (mail-extract-address-components from))))))
 530       (if (or (not ctl)
 531               (not (string-match "/" (car ctl))))
 532           (mm-dissect-singlepart
 533            (list mm-dissect-default-type)
 534            (and cte (intern (downcase (mail-header-strip cte))))
 535            no-strict-mime
 536            (and cd (ignore-errors (mail-header-parse-content-disposition cd)))
 537            description)
 538         (setq type (split-string (car ctl) "/"))
 539         (setq subtype (cadr type)
 540               type (pop type))
 541         (setq
 542          result
 543          (cond
 544           ((equal type "multipart")
 545            (let ((mm-dissect-default-type (if (equal subtype "digest")
 546                                               "message/rfc822"
 547                                             "text/plain"))
 548                  (start (cdr (assq 'start (cdr ctl)))))
 549              (add-text-properties 0 (length (car ctl))
 550                                   (mm-alist-to-plist (cdr ctl)) (car ctl))
 551
 552              ;; what really needs to be done here is a way to link a
 553              ;; MIME handle back to it's parent MIME handle (in a multilevel
 554              ;; MIME article).  That would probably require changing
 555              ;; the mm-handle API so we simply store the multipart buffert
 556              ;; name as a text property of the "multipart/whatever" string.
 557              (add-text-properties 0 (length (car ctl))
 558                                   (list 'buffer (mm-copy-to-buffer)
 559                                         'from from
 560                                         'start start)
 561                                   (car ctl))
 562              (cons (car ctl) (mm-dissect-multipart ctl))))
 563           (t
 564            (mm-possibly-verify-or-decrypt
 565             (mm-dissect-singlepart
 566              ctl
 567              (and cte (intern (downcase (mail-header-strip cte))))
 568              no-strict-mime
 569              (and cd (ignore-errors
 570                        (mail-header-parse-content-disposition cd)))
 571              description id)
 572             ctl))))
 573         (when id
 574           (when (string-match " *<\\(.*\\)> *" id)
 575             (setq id (match-string 1 id)))
 576           (push (cons id result) mm-content-id-alist))
 577         result))))
 578
 579 (defun mm-dissect-singlepart (ctl cte &optional force cdl description id)
 580   (when (or force
 581             (if (equal "text/plain" (car ctl))
 582                 ;; FIXME: This is a kludge.  Proper fix is to make
 583                 ;; gnus-display-mime invoke mm-uu-dissect on all
 584                 ;; textual MIME parts, and stop using mm-fill-flowed
 585                 ;; here.
 586                 (and mm-fill-flowed (assoc 'format ctl))
 587               t))
 588     (mm-make-handle
 589      (mm-copy-to-buffer) ctl cte nil cdl description nil id)))
 590
 591 (defun mm-dissect-multipart (ctl)
 592   (goto-char (point-min))
 593   (let* ((boundary (concat "\n--" (mail-content-type-get ctl 'boundary)))
 594          (close-delimiter (concat (regexp-quote boundary) "--[ \t]*$"))
 595          start parts
 596          (end (save-excursion
 597                 (goto-char (point-max))
 598                 (if (re-search-backward close-delimiter nil t)
 599                     (match-beginning 0)
 600                   (point-max)))))
 601     (setq boundary (concat (regexp-quote boundary) "[ \t]*$"))
 602     (while (and (< (point) end) (re-search-forward boundary end t))
 603       (goto-char (match-beginning 0))
 604       (when start
 605         (save-excursion
 606           (save-restriction
 607             (narrow-to-region start (point))
 608             (setq parts (nconc (list (mm-dissect-buffer t)) parts)))))
 609       (end-of-line 2)
 610       (or (looking-at boundary)
 611           (forward-line 1))
 612       (setq start (point)))
 613     (when (and start (< start end))
 614       (save-excursion
 615         (save-restriction
 616           (narrow-to-region start end)
 617           (setq parts (nconc (list (mm-dissect-buffer t)) parts)))))
 618     (mm-possibly-verify-or-decrypt (nreverse parts) ctl)))
 619
 620 (defun mm-copy-to-buffer ()
 621   "Copy the contents of the current buffer to a fresh buffer."
 622   (save-excursion
 623     (let ((obuf (current-buffer))
 624           beg)
 625       (goto-char (point-min))
 626       (search-forward-regexp "^\n" nil t)
 627       (setq beg (point))
 628       (set-buffer (generate-new-buffer " *mm*"))
 629       (insert-buffer-substring obuf beg)
 630       (current-buffer))))
 631
 632 (defun mm-display-parts (handle &optional no-default)
 633   (if (stringp (car handle))
 634       (mapcar 'mm-display-parts (cdr handle))
 635     (if (bufferp (car handle))
 636         (save-restriction
 637           (narrow-to-region (point) (point))
 638           (mm-display-part handle)
 639           (goto-char (point-max)))
 640       (mapcar 'mm-display-parts handle))))
 641
 642 (defun mm-display-part (handle &optional no-default)
 643   "Display the MIME part represented by HANDLE.
 644 Returns nil if the part is removed; inline if displayed inline;
 645 external if displayed external."
 646   (save-excursion
 647     (mailcap-parse-mailcaps)
 648     (if (mm-handle-displayed-p handle)
 649         (mm-remove-part handle)
 650       (let* ((type (mm-handle-media-type handle))
 651              (method (mailcap-mime-info type))
 652              (filename (or (mail-content-type-get
 653                             (mm-handle-disposition handle) 'filename)
 654                            (mail-content-type-get
 655                             (mm-handle-type handle) 'name)
 656                            "<file>"))
 657              (external mm-enable-external))
 658         (if (and (mm-inlinable-p handle)
 659                  (mm-inlined-p handle))
 660             (progn
 661               (forward-line 1)
 662               (mm-display-inline handle)
 663               'inline)
 664           (when (or method
 665                     (not no-default))
 666             (if (and (not method)
 667                      (equal "text" (car (split-string type))))
 668                 (progn
 669                   (forward-line 1)
 670                   (mm-insert-inline handle (mm-get-part handle))
 671                   'inline)
 672               (if (and method ;; If nil, we always use "save".
 673                        (stringp method) ;; 'mailcap-save-binary-file
 674                        (or (eq mm-enable-external t)
 675                            (and (eq mm-enable-external 'ask)
 676                                 (y-or-n-p
 677                                  (concat
 678                                   "Display part (" type
 679                                   ") using external program"
 680                                   ;; Can non-string method ever happen?
 681                                   (if (stringp method)
 682                                       (concat
 683                                        " \"" (format method filename) "\"")
 684                                     "")
 685                                   "? ")))))
 686                   (setq external t)
 687                 (setq external nil))
 688               (if external
 689                   (mm-display-external
 690                    handle (or method 'mailcap-save-binary-file))
 691                 (mm-display-external
 692                  handle 'mailcap-save-binary-file)))))))))
 693
 694 (defun mm-display-external (handle method)
 695   "Display HANDLE using METHOD."
 696   (let ((outbuf (current-buffer)))
 697     (mm-with-unibyte-buffer
 698       (if (functionp method)
 699           (let ((cur (current-buffer)))
 700             (if (eq method 'mailcap-save-binary-file)
 701                 (progn
 702                   (set-buffer (generate-new-buffer " *mm*"))
 703                   (setq method nil))
 704               (mm-insert-part handle)
 705               (let ((win (get-buffer-window cur t)))
 706                 (when win
 707                   (select-window win)))
 708               (switch-to-buffer (generate-new-buffer " *mm*")))
 709             (buffer-disable-undo)
 710             (mm-set-buffer-file-coding-system mm-binary-coding-system)
 711             (insert-buffer-substring cur)
 712             (goto-char (point-min))
 713             (when method
 714               (message "Viewing with %s" method))
 715             (let ((mm (current-buffer))
 716                   (non-viewer (assq 'non-viewer
 717                                     (mailcap-mime-info
 718                                      (mm-handle-media-type handle) t))))
 719               (unwind-protect
 720                   (if method
 721                       (funcall method)
 722                     (mm-save-part handle))
 723                 (when (and (not non-viewer)
 724                            method)
 725                   (mm-handle-set-undisplayer handle mm)))))
 726         ;; The function is a string to be executed.
 727         (mm-insert-part handle)
 728         (let* ((dir (mm-make-temp-file
 729                      (expand-file-name "emm." mm-tmp-directory) 'dir))
 730                (filename (or
 731                           (mail-content-type-get
 732                            (mm-handle-disposition handle) 'filename)
 733                           (mail-content-type-get
 734                            (mm-handle-type handle) 'name)))
 735                (mime-info (mailcap-mime-info
 736                            (mm-handle-media-type handle) t))
 737                (needsterm (or (assoc "needsterm" mime-info)
 738                               (assoc "needsterminal" mime-info)))
 739                (copiousoutput (assoc "copiousoutput" mime-info))
 740                file buffer)
 741           ;; We create a private sub-directory where we store our files.
 742           (set-file-modes dir 448)
 743           (if filename
 744               (setq file (expand-file-name
 745                           (gnus-map-function mm-file-name-rewrite-functions
 746                                              (file-name-nondirectory filename))
 747                           dir))
 748             (setq file (mm-make-temp-file (expand-file-name "mm." dir))))
 749           (let ((coding-system-for-write mm-binary-coding-system))
 750             (write-region (point-min) (point-max) file nil 'nomesg))
 751           (message "Viewing with %s" method)
 752           (cond
 753            (needsterm
 754             (let ((command (mm-mailcap-command
 755                             method file (mm-handle-type handle))))
 756               (unwind-protect
 757                   (if window-system
 758                       (start-process "*display*" nil
 759                                      mm-external-terminal-program
 760                                      "-e" shell-file-name
 761                                      shell-command-switch command)
 762                     (require 'term)
 763                     (require 'gnus-win)
 764                     (set-buffer
 765                      (setq buffer
 766                            (make-term "display"
 767                                       shell-file-name
 768                                       nil
 769                                       shell-command-switch command)))
 770                     (term-mode)
 771                     (term-char-mode)
 772                     (set-process-sentinel
 773                      (get-buffer-process buffer)
 774                      `(lambda (process state)
 775                         (if (eq 'exit (process-status process))
 776                             (gnus-configure-windows
 777                              ',gnus-current-window-configuration))))
 778                     (gnus-configure-windows 'display-term))
 779                 (mm-handle-set-external-undisplayer handle (cons file buffer)))
 780               (message "Displaying %s..." command))
 781             'external)
 782            (copiousoutput
 783             (with-current-buffer outbuf
 784               (forward-line 1)
 785               (mm-insert-inline
 786                handle
 787                (unwind-protect
 788                    (progn
 789                      (call-process shell-file-name nil
 790                                    (setq buffer
 791                                          (generate-new-buffer " *mm*"))
 792                                    nil
 793                                    shell-command-switch
 794                                    (mm-mailcap-command
 795                                     method file (mm-handle-type handle)))
 796                      (if (buffer-live-p buffer)
 797                          (save-excursion
 798                            (set-buffer buffer)
 799                            (buffer-string))))
 800                  (progn
 801                    (ignore-errors (delete-file file))
 802                    (ignore-errors (delete-directory
 803                                    (file-name-directory file)))
 804                    (ignore-errors (kill-buffer buffer))))))
 805             'inline)
 806            (t
 807             (let ((command (mm-mailcap-command
 808                             method file (mm-handle-type handle))))
 809               (unwind-protect
 810                   (start-process "*display*"
 811                                  (setq buffer
 812                                        (generate-new-buffer " *mm*"))
 813                                  shell-file-name
 814                                  shell-command-switch command)
 815                 (mm-handle-set-external-undisplayer
 816                  handle (cons file buffer)))
 817               (message "Displaying %s..." command))
 818             'external)))))))
 819
 820 (defun mm-mailcap-command (method file type-list)
 821   (let ((ctl (cdr type-list))
 822         (beg 0)
 823         (uses-stdin t)
 824         out sub total)
 825     (while (string-match "%{\\([^}]+\\)}\\|'%s'\\|\"%s\"\\|%s\\|%t\\|%%"
 826                          method beg)
 827       (push (substring method beg (match-beginning 0)) out)
 828       (setq beg (match-end 0)
 829             total (match-string 0 method)
 830             sub (match-string 1 method))
 831       (cond
 832        ((string= total "%%")
 833         (push "%" out))
 834        ((or (string= total "%s")
 835             ;; We do our own quoting.
 836             (string= total "'%s'")
 837             (string= total "\"%s\""))
 838         (setq uses-stdin nil)
 839         (push (shell-quote-argument
 840                (gnus-map-function mm-path-name-rewrite-functions file)) out))
 841        ((string= total "%t")
 842         (push (shell-quote-argument (car type-list)) out))
 843        (t
 844         (push (shell-quote-argument (or (cdr (assq (intern sub) ctl)) "")) out))))
 845     (push (substring method beg (length method)) out)
 846     (when uses-stdin
 847       (push "<" out)
 848       (push (shell-quote-argument
 849              (gnus-map-function mm-path-name-rewrite-functions file))
 850             out))
 851     (mapconcat 'identity (nreverse out) "")))
 852
 853 (defun mm-remove-parts (handles)
 854   "Remove the displayed MIME parts represented by HANDLES."
 855   (if (and (listp handles)
 856            (bufferp (car handles)))
 857       (mm-remove-part handles)
 858     (let (handle)
 859       (while (setq handle (pop handles))
 860         (cond
 861          ((stringp handle)
 862           (when (buffer-live-p (get-text-property 0 'buffer handle))
 863             (kill-buffer (get-text-property 0 'buffer handle))))
 864          ((and (listp handle)
 865                (stringp (car handle)))
 866           (mm-remove-parts (cdr handle)))
 867          (t
 868           (mm-remove-part handle)))))))
 869
 870 (defun mm-destroy-parts (handles)
 871   "Remove the displayed MIME parts represented by HANDLES."
 872   (if (and (listp handles)
 873            (bufferp (car handles)))
 874       (mm-destroy-part handles)
 875     (let (handle)
 876       (while (setq handle (pop handles))
 877         (cond
 878          ((stringp handle)
 879           (when (buffer-live-p (get-text-property 0 'buffer handle))
 880             (kill-buffer (get-text-property 0 'buffer handle))))
 881          ((and (listp handle)
 882                (stringp (car handle)))
 883           (mm-destroy-parts handle))
 884          (t
 885           (mm-destroy-part handle)))))))
 886
 887 (defun mm-remove-part (handle)
 888   "Remove the displayed MIME part represented by HANDLE."
 889   (when (listp handle)
 890     (let ((object (mm-handle-undisplayer handle)))
 891       (ignore-errors
 892         (cond
 893          ;; Internally displayed part.
 894          ((mm-annotationp object)
 895           (delete-annotation object))
 896          ((or (functionp object)
 897               (and (listp object)
 898                    (eq (car object) 'lambda)))
 899           (funcall object))
 900          ;; Externally displayed part.
 901          ((consp object)
 902           (condition-case ()
 903               (while (get-buffer-process (cdr object))
 904                 (interrupt-process (get-buffer-process (cdr object)))
 905                 (message "Waiting for external displayer to die...")
 906                 (sit-for 1))
 907             (quit)
 908             (error))
 909           (ignore-errors (and (cdr object) (kill-buffer (cdr object))))
 910           (message "Waiting for external displayer to die...done")
 911           (ignore-errors (delete-file (car object)))
 912           (ignore-errors (delete-directory (file-name-directory
 913                                             (car object)))))
 914          ((bufferp object)
 915           (when (buffer-live-p object)
 916             (kill-buffer object)))))
 917       (mm-handle-set-undisplayer handle nil))))
 918
 919 (defun mm-display-inline (handle)
 920   (let* ((type (mm-handle-media-type handle))
 921          (function (cadr (mm-assoc-string-match mm-inline-media-tests type))))
 922     (funcall function handle)
 923     (goto-char (point-min))))
 924
 925 (defun mm-assoc-string-match (alist type)
 926   (dolist (elem alist)
 927     (when (string-match (car elem) type)
 928       (return elem))))
 929
 930 (defun mm-automatic-display-p (handle)
 931   "Say whether the user wants HANDLE to be displayed automatically."
 932   (let ((methods mm-automatic-display)
 933         (type (mm-handle-media-type handle))
 934         method result)
 935     (while (setq method (pop methods))
 936       (when (and (not (mm-inline-override-p handle))
 937                  (string-match method type))
 938         (setq result t
 939               methods nil)))
 940     result))
 941
 942 (defun mm-inlinable-p (handle)
 943   "Say whether HANDLE can be displayed inline."
 944   (let ((alist mm-inline-media-tests)
 945         (type (mm-handle-media-type handle))
 946         test)
 947     (while alist
 948       (when (string-match (caar alist) type)
 949         (setq test (caddar alist)
 950               alist nil)
 951         (setq test (funcall test handle)))
 952       (pop alist))
 953     test))
 954
 955 (defun mm-inlined-p (handle)
 956   "Say whether the user wants HANDLE to be displayed inline."
 957   (let ((methods mm-inlined-types)
 958         (type (mm-handle-media-type handle))
 959         method result)
 960     (while (setq method (pop methods))
 961       (when (and (not (mm-inline-override-p handle))
 962                  (string-match method type))
 963         (setq result t
 964               methods nil)))
 965     result))
 966
 967 (defun mm-attachment-override-p (handle)
 968   "Say whether HANDLE should have attachment behavior overridden."
 969   (let ((types mm-attachment-override-types)
 970         (type (mm-handle-media-type handle))
 971         ty)
 972     (catch 'found
 973       (while (setq ty (pop types))
 974         (when (and (string-match ty type)
 975                    (mm-inlinable-p handle))
 976           (throw 'found t))))))
 977
 978 (defun mm-inline-override-p (handle)
 979   "Say whether HANDLE should have inline behavior overridden."
 980   (let ((types mm-inline-override-types)
 981         (type (mm-handle-media-type handle))
 982         ty)
 983     (catch 'found
 984       (while (setq ty (pop types))
 985         (when (string-match ty type)
 986           (throw 'found t))))))
 987
 988 (defun mm-automatic-external-display-p (type)
 989   "Return the user-defined method for TYPE."
 990   (let ((methods mm-automatic-external-display)
 991         method result)
 992     (while (setq method (pop methods))
 993       (when (string-match method type)
 994         (setq result t
 995               methods nil)))
 996     result))
 997
 998 (defun mm-destroy-part (handle)
 999   "Destroy the data structures connected to HANDLE."
1000   (when (listp handle)
1001     (mm-remove-part handle)
1002     (when (buffer-live-p (mm-handle-buffer handle))
1003       (kill-buffer (mm-handle-buffer handle)))))
1004
1005 (defun mm-handle-displayed-p (handle)
1006   "Say whether HANDLE is displayed or not."
1007   (mm-handle-undisplayer handle))
1008
1009 ;;;
1010 ;;; Functions for outputting parts
1011 ;;;
1012
1013 (defun mm-get-part (handle)
1014   "Return the contents of HANDLE as a string."
1015   (mm-with-unibyte-buffer
1016     (insert (with-current-buffer (mm-handle-buffer handle)
1017               (mm-with-unibyte-current-buffer
1018                 (buffer-string))))
1019     (mm-decode-content-transfer-encoding
1020      (mm-handle-encoding handle)
1021      (mm-handle-media-type handle))
1022     (buffer-string)))
1023
1024 (defun mm-insert-part (handle)
1025   "Insert the contents of HANDLE in the current buffer."
1026   (let ((cur (current-buffer)))
1027     (save-excursion
1028       (if (member (mm-handle-media-supertype handle) '("text" "message"))
1029           (with-temp-buffer
1030             (insert-buffer-substring (mm-handle-buffer handle))
1031             (prog1
1032                 (mm-decode-content-transfer-encoding
1033                  (mm-handle-encoding handle)
1034                  (mm-handle-media-type handle))
1035               (let ((temp (current-buffer)))
1036                 (set-buffer cur)
1037                 (insert-buffer-substring temp))))
1038         (mm-with-unibyte-buffer
1039           (insert-buffer-substring (mm-handle-buffer handle))
1040           (prog1
1041               (mm-decode-content-transfer-encoding
1042                (mm-handle-encoding handle)
1043                (mm-handle-media-type handle))
1044             (let ((temp (current-buffer)))
1045               (set-buffer cur)
1046               (insert-buffer-substring temp))))))))
1047
1048 (defun mm-file-name-delete-whitespace (file-name)
1049   "Remove all whitespace characters from FILE-NAME."
1050   (while (string-match "\\s-+" file-name)
1051     (setq file-name (replace-match "" t t file-name)))
1052   file-name)
1053
1054 (defun mm-file-name-trim-whitespace (file-name)
1055   "Remove leading and trailing whitespace characters from FILE-NAME."
1056   (when (string-match "\\`\\s-+" file-name)
1057     (setq file-name (substring file-name (match-end 0))))
1058   (when (string-match "\\s-+\\'" file-name)
1059     (setq file-name (substring file-name 0 (match-beginning 0))))
1060   file-name)
1061
1062 (defun mm-file-name-collapse-whitespace (file-name)
1063   "Collapse multiple whitespace characters in FILE-NAME."
1064   (while (string-match "\\s-\\s-+" file-name)
1065     (setq file-name (replace-match " " t t file-name)))
1066   file-name)
1067
1068 (defun mm-file-name-replace-whitespace (file-name)
1069   "Replace whitespace characters in FILE-NAME with underscores.
1070 Set the option `mm-file-name-replace-whitespace' to any other
1071 string if you do not like underscores."
1072   (let ((s (or mm-file-name-replace-whitespace "_")))
1073     (while (string-match "\\s-" file-name)
1074       (setq file-name (replace-match s t t file-name))))
1075   file-name)
1076
1077 (defun mm-file-name-delete-control (filename)
1078   "Delete control characters from FILENAME."
1079   (gnus-replace-in-string filename "[\x00-\x1f\x7f]" ""))
1080
1081 (defun mm-file-name-delete-gotchas (filename)
1082   "Delete shell gotchas from FILENAME."
1083   (setq filename (gnus-replace-in-string filename "[<>|]" ""))
1084   (gnus-replace-in-string filename "^[.-]+" ""))
1085
1086 (defun mm-save-part (handle)
1087   "Write HANDLE to a file."
1088   (let* ((name (mail-content-type-get (mm-handle-type handle) 'name))
1089          (filename (mail-content-type-get
1090                     (mm-handle-disposition handle) 'filename))
1091          file)
1092     (when filename
1093       (setq filename (gnus-map-function mm-file-name-rewrite-functions
1094                                         (file-name-nondirectory filename))))
1095     (setq file
1096           (mm-with-multibyte
1097             (read-file-name "Save MIME part to: "
1098                             (or mm-default-directory default-directory)
1099                             nil nil (or filename name ""))))
1100     (setq mm-default-directory (file-name-directory file))
1101     (and (or (not (file-exists-p file))
1102              (yes-or-no-p (format "File %s already exists; overwrite? "
1103                                   file)))
1104          (progn
1105            (mm-save-part-to-file handle file)
1106            file))))
1107
1108 (defun mm-save-part-to-file (handle file)
1109   (mm-with-unibyte-buffer
1110     (mm-insert-part handle)
1111     (let ((coding-system-for-write 'binary)
1112           (current-file-modes (default-file-modes))
1113           ;; Don't re-compress .gz & al.  Arguably we should make
1114           ;; `file-name-handler-alist' nil, but that would chop
1115           ;; ange-ftp, which is reasonable to use here.
1116           (inhibit-file-name-operation 'write-region)
1117           (inhibit-file-name-handlers
1118            (cons 'jka-compr-handler inhibit-file-name-handlers)))
1119       (set-default-file-modes mm-attachment-file-modes)
1120       (unwind-protect
1121           (write-region (point-min) (point-max) file)
1122         (set-default-file-modes current-file-modes)))))
1123
1124 (defun mm-pipe-part (handle)
1125   "Pipe HANDLE to a process."
1126   (let* ((name (mail-content-type-get (mm-handle-type handle) 'name))
1127          (command
1128           (read-string "Shell command on MIME part: " mm-last-shell-command)))
1129     (mm-with-unibyte-buffer
1130       (mm-insert-part handle)
1131       (let ((coding-system-for-write 'binary))
1132         (shell-command-on-region (point-min) (point-max) command nil)))))
1133
1134 (defun mm-interactively-view-part (handle)
1135   "Display HANDLE using METHOD."
1136   (let* ((type (mm-handle-media-type handle))
1137          (methods
1138           (mapcar (lambda (i) (list (cdr (assoc 'viewer i))))
1139                   (mailcap-mime-info type 'all)))
1140          (method (let ((minibuffer-local-completion-map
1141                         mm-viewer-completion-map))
1142                    (completing-read "Viewer: " methods))))
1143     (when (string= method "")
1144       (error "No method given"))
1145     (if (string-match "^[^% \t]+$" method)
1146         (setq method (concat method " %s")))
1147     (mm-display-external handle method)))
1148
1149 (defun mm-preferred-alternative (handles &optional preferred)
1150   "Say which of HANDLES are preferred."
1151   (let ((prec (if preferred (list preferred)
1152                 (mm-preferred-alternative-precedence handles)))
1153         p h result type handle)
1154     (while (setq p (pop prec))
1155       (setq h handles)
1156       (while h
1157         (setq handle (car h))
1158         (setq type (mm-handle-media-type handle))
1159         (when (and (equal p type)
1160                    (mm-automatic-display-p handle)
1161                    (or (stringp (car handle))
1162                        (not (mm-handle-disposition handle))
1163                        (equal (car (mm-handle-disposition handle))
1164                               "inline")))
1165           (setq result handle
1166                 h nil
1167                 prec nil))
1168         (pop h)))
1169     result))
1170
1171 (defun mm-preferred-alternative-precedence (handles)
1172   "Return the precedence based on HANDLES and `mm-discouraged-alternatives'."
1173   (let ((seq (nreverse (mapcar #'mm-handle-media-type
1174                                handles))))
1175     (dolist (disc (reverse mm-discouraged-alternatives))
1176       (dolist (elem (copy-sequence seq))
1177         (when (string-match disc elem)
1178           (setq seq (nconc (delete elem seq) (list elem))))))
1179     seq))
1180
1181 (defun mm-get-content-id (id)
1182   "Return the handle(s) referred to by ID."
1183   (cdr (assoc id mm-content-id-alist)))
1184
1185 (defconst mm-image-type-regexps
1186   '(("/\\*.*XPM.\\*/" . xpm)
1187     ("P[1-6]" . pbm)
1188     ("GIF8" . gif)
1189     ("\377\330" . jpeg)
1190     ("\211PNG\r\n" . png)
1191     ("#define" . xbm)
1192     ("\\(MM\0\\*\\)\\|\\(II\\*\0\\)" . tiff)
1193     ("%!PS" . postscript))
1194   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
1195 When the first bytes of an image file match REGEXP, it is assumed to
1196 be of image type IMAGE-TYPE.")
1197
1198 ;; Steal from image.el. image-type-from-data suffers multi-line matching bug.
1199 (defun mm-image-type-from-buffer ()
1200   "Determine the image type from data in the current buffer.
1201 Value is a symbol specifying the image type or nil if type cannot
1202 be determined."
1203   (let ((types mm-image-type-regexps)
1204         type)
1205     (goto-char (point-min))
1206     (while (and types (null type))
1207       (let ((regexp (car (car types)))
1208             (image-type (cdr (car types))))
1209         (when (looking-at regexp)
1210           (setq type image-type))
1211         (setq types (cdr types))))
1212     type))
1213
1214 (defun mm-get-image (handle)
1215   "Return an image instance based on HANDLE."
1216   (let ((type (mm-handle-media-subtype handle))
1217         spec)
1218     ;; Allow some common translations.
1219     (setq type
1220           (cond
1221            ((equal type "x-pixmap")
1222             "xpm")
1223            ((equal type "x-xbitmap")
1224             "xbm")
1225            ((equal type "x-portable-bitmap")
1226             "pbm")
1227            (t type)))
1228     (or (mm-handle-cache handle)
1229         (mm-with-unibyte-buffer
1230           (mm-insert-part handle)
1231           (prog1
1232               (setq spec
1233                     (ignore-errors
1234                       ;; Avoid testing `make-glyph' since W3 may define
1235                       ;; a bogus version of it.
1236                       (if (fboundp 'create-image)
1237                           (create-image (buffer-string)
1238                                         (or (mm-image-type-from-buffer)
1239                                             (intern type))
1240                                         'data-p)
1241                         (mm-create-image-xemacs type))))
1242             (mm-handle-set-cache handle spec))))))
1243
1244 (defun mm-create-image-xemacs (type)
1245   (cond
1246    ((equal type "xbm")
1247     ;; xbm images require special handling, since
1248     ;; the only way to create glyphs from these
1249     ;; (without a ton of work) is to write them
1250     ;; out to a file, and then create a file
1251     ;; specifier.
1252     (let ((file (mm-make-temp-file
1253                  (expand-file-name "emm.xbm"
1254                                    mm-tmp-directory))))
1255       (unwind-protect
1256           (progn
1257             (write-region (point-min) (point-max) file)
1258             (make-glyph (list (cons 'x file))))
1259         (ignore-errors
1260           (delete-file file)))))
1261    (t
1262     (make-glyph
1263      (vector
1264       (or (mm-image-type-from-buffer)
1265           (intern type))
1266       :data (buffer-string))))))
1267
1268 (defun mm-image-fit-p (handle)
1269   "Say whether the image in HANDLE will fit the current window."
1270   (let ((image (mm-get-image handle)))
1271     (if (fboundp 'glyph-width)
1272         ;; XEmacs' glyphs can actually tell us about their width, so
1273         ;; lets be nice and smart about them.
1274         (or mm-inline-large-images
1275             (and (< (glyph-width image) (window-pixel-width))
1276                  (< (glyph-height image) (window-pixel-height))))
1277       (let* ((size (image-size image))
1278              (w (car size))
1279              (h (cdr size)))
1280         (or mm-inline-large-images
1281             (and (< h (1- (window-height))) ; Don't include mode line.
1282                  (< w (window-width))))))))
1283
1284 (defun mm-valid-image-format-p (format)
1285   "Say whether FORMAT can be displayed natively by Emacs."
1286   (cond
1287    ;; Handle XEmacs
1288    ((fboundp 'valid-image-instantiator-format-p)
1289     (valid-image-instantiator-format-p format))
1290    ;; Handle Emacs 21
1291    ((fboundp 'image-type-available-p)
1292     (and (display-graphic-p)
1293          (image-type-available-p format)))
1294    ;; Nobody else can do images yet.
1295    (t
1296     nil)))
1297
1298 (defun mm-valid-and-fit-image-p (format handle)
1299   "Say whether FORMAT can be displayed natively and HANDLE fits the window."
1300   (and (mm-valid-image-format-p format)
1301        (mm-image-fit-p handle)))
1302
1303 (defun mm-find-part-by-type (handles type &optional notp recursive)
1304   "Search in HANDLES for part with TYPE.
1305 If NOTP, returns first non-matching part.
1306 If RECURSIVE, search recursively."
1307   (let (handle)
1308     (while handles
1309       (if (and recursive (stringp (caar handles)))
1310           (if (setq handle (mm-find-part-by-type (cdar handles) type
1311                                                  notp recursive))
1312               (setq handles nil))
1313         (if (if notp
1314                 (not (equal (mm-handle-media-type (car handles)) type))
1315               (equal (mm-handle-media-type (car handles)) type))
1316             (setq handle (car handles)
1317                   handles nil)))
1318       (setq handles (cdr handles)))
1319     handle))
1320
1321 (defun mm-find-raw-part-by-type (ctl type &optional notp)
1322   (goto-char (point-min))
1323   (let* ((boundary (concat "--" (mm-handle-multipart-ctl-parameter ctl
1324                                                                    'boundary)))
1325          (close-delimiter (concat "^" (regexp-quote boundary) "--[ \t]*$"))
1326          start
1327          (end (save-excursion
1328                 (goto-char (point-max))
1329                 (if (re-search-backward close-delimiter nil t)
1330                     (match-beginning 0)
1331                   (point-max))))
1332          result)
1333     (setq boundary (concat "^" (regexp-quote boundary) "[ \t]*$"))
1334     (while (and (not result)
1335                 (re-search-forward boundary end t))
1336       (goto-char (match-beginning 0))
1337       (when start
1338         (save-excursion
1339           (save-restriction
1340             (narrow-to-region start (1- (point)))
1341             (when (let ((ctl (ignore-errors
1342                                (mail-header-parse-content-type
1343                                 (mail-fetch-field "content-type")))))
1344                     (if notp
1345                         (not (equal (car ctl) type))
1346                       (equal (car ctl) type)))
1347               (setq result (buffer-string))))))
1348       (forward-line 1)
1349       (setq start (point)))
1350     (when (and (not result) start)
1351       (save-excursion
1352         (save-restriction
1353           (narrow-to-region start end)
1354           (when (let ((ctl (ignore-errors
1355                              (mail-header-parse-content-type
1356                               (mail-fetch-field "content-type")))))
1357                   (if notp
1358                       (not (equal (car ctl) type))
1359                     (equal (car ctl) type)))
1360             (setq result (buffer-string))))))
1361     result))
1362
1363 (defvar mm-security-handle nil)
1364
1365 (defsubst mm-set-handle-multipart-parameter (handle parameter value)
1366   ;; HANDLE could be a CTL.
1367   (when handle
1368     (put-text-property 0 (length (car handle)) parameter value
1369                        (car handle))))
1370
1371 (defun mm-possibly-verify-or-decrypt (parts ctl)
1372   (let ((type (car ctl))
1373         (subtype (cadr (split-string (car ctl) "/")))
1374         (mm-security-handle ctl) ;; (car CTL) is the type.
1375         protocol func functest)
1376     (cond
1377      ((or (equal type "application/x-pkcs7-mime")
1378           (equal type "application/pkcs7-mime"))
1379       (with-temp-buffer
1380         (when (and (cond
1381                     ((eq mm-decrypt-option 'never) nil)
1382                     ((eq mm-decrypt-option 'always) t)
1383                     ((eq mm-decrypt-option 'known) t)
1384                     (t (y-or-n-p
1385                         (format "Decrypt (S/MIME) part? "))))
1386                    (mm-view-pkcs7 parts))
1387           (setq parts (mm-dissect-buffer t)))))
1388      ((equal subtype "signed")
1389       (unless (and (setq protocol
1390                          (mm-handle-multipart-ctl-parameter ctl 'protocol))
1391                    (not (equal protocol "multipart/mixed")))
1392         ;; The message is broken or draft-ietf-openpgp-multsig-01.
1393         (let ((protocols mm-verify-function-alist))
1394           (while protocols
1395             (if (and (or (not (setq functest (nth 3 (car protocols))))
1396                          (funcall functest parts ctl))
1397                      (mm-find-part-by-type parts (caar protocols) nil t))
1398                 (setq protocol (caar protocols)
1399                       protocols nil)
1400               (setq protocols (cdr protocols))))))
1401       (setq func (nth 1 (assoc protocol mm-verify-function-alist)))
1402       (when (cond
1403              ((eq mm-verify-option 'never) nil)
1404              ((eq mm-verify-option 'always) t)
1405              ((eq mm-verify-option 'known)
1406               (and func
1407                    (or (not (setq functest
1408                                   (nth 3 (assoc protocol
1409                                                 mm-verify-function-alist))))
1410                        (funcall functest parts ctl))))
1411              (t
1412               (y-or-n-p
1413                (format "Verify signed (%s) part? "
1414                        (or (nth 2 (assoc protocol mm-verify-function-alist))
1415                            (format "protocol=%s" protocol))))))
1416         (save-excursion
1417           (if func
1418               (funcall func parts ctl)
1419             (mm-set-handle-multipart-parameter
1420              mm-security-handle 'gnus-details
1421              (format "Unknown sign protocol (%s)" protocol))))))
1422      ((equal subtype "encrypted")
1423       (unless (setq protocol
1424                     (mm-handle-multipart-ctl-parameter ctl 'protocol))
1425         ;; The message is broken.
1426         (let ((parts parts))
1427           (while parts
1428             (if (assoc (mm-handle-media-type (car parts))
1429                        mm-decrypt-function-alist)
1430                 (setq protocol (mm-handle-media-type (car parts))
1431                       parts nil)
1432               (setq parts (cdr parts))))))
1433       (setq func (nth 1 (assoc protocol mm-decrypt-function-alist)))
1434       (when (cond
1435              ((eq mm-decrypt-option 'never) nil)
1436              ((eq mm-decrypt-option 'always) t)
1437              ((eq mm-decrypt-option 'known)
1438               (and func
1439                    (or (not (setq functest
1440                                   (nth 3 (assoc protocol
1441                                                 mm-decrypt-function-alist))))
1442                        (funcall functest parts ctl))))
1443              (t
1444               (y-or-n-p
1445                (format "Decrypt (%s) part? "
1446                        (or (nth 2 (assoc protocol mm-decrypt-function-alist))
1447                            (format "protocol=%s" protocol))))))
1448         (save-excursion
1449           (if func
1450               (setq parts (funcall func parts ctl))
1451             (mm-set-handle-multipart-parameter
1452              mm-security-handle 'gnus-details
1453              (format "Unknown encrypt protocol (%s)" protocol))))))
1454      (t nil))
1455     parts))
1456
1457 (defun mm-multiple-handles (handles)
1458   (and (listp handles)
1459        (> (length handles) 1)
1460        (or (listp (car handles))
1461            (stringp (car handles)))))
1462
1463 (defun mm-complicated-handles (handles)
1464   (and (listp (car handles))
1465        (> (length handles) 1)))
1466
1467 (defun mm-merge-handles (handles1 handles2)
1468   (append
1469    (if (listp (car handles1))
1470        handles1
1471      (list handles1))
1472    (if (listp (car handles2))
1473        handles2
1474      (list handles2))))
1475
1476 (defun mm-readable-p (handle)
1477   "Say whether the content of HANDLE is readable."
1478   (and (< (with-current-buffer (mm-handle-buffer handle)
1479             (buffer-size)) 10000)
1480        (mm-with-unibyte-buffer
1481          (mm-insert-part handle)
1482          (and (eq (mm-body-7-or-8) '7bit)
1483               (not (mm-long-lines-p 76))))))
1484
1485 (provide 'mm-decode)
1486
1487 ;;; arch-tag: 4f35d360-56b8-4030-9388-3ed82d359b9b
1488 ;;; mm-decode.el ends here