cgit.sxemacs.org Git - gnus/blob - lisp/mail-source.el

   1 ;;; mail-source.el --- functions for fetching mail
   2 ;; Copyright (C) 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news, mail
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile
  29   (require 'cl)
  30   (require 'imap)
  31   (eval-when-compile (defvar display-time-mail-function)))
  32 (eval-and-compile
  33   (autoload 'pop3-movemail "pop3")
  34   (autoload 'pop3-get-message-count "pop3")
  35   (autoload 'nnheader-cancel-timer "nnheader")
  36   (autoload 'nnheader-run-at-time "nnheader"))
  37 (require 'format-spec)
  38 (require 'mm-util)
  39 (require 'message) ;; for `message-directory'
  40
  41 (defgroup mail-source nil
  42   "The mail-fetching library."
  43   :version "21.1"
  44   :group 'gnus)
  45
  46 ;; Define these at compile time to avoid dragging in imap always.
  47 (defconst mail-source-imap-authenticators
  48   (eval-when-compile
  49     (mapcar (lambda (a)
  50               (list 'const (car a)))
  51      imap-authenticator-alist)))
  52 (defconst mail-source-imap-streams
  53   (eval-when-compile
  54     (mapcar (lambda (a)
  55               (list 'const (car a)))
  56      imap-stream-alist)))
  57
  58 (defcustom mail-sources nil
  59   "*Where the mail backends will look for incoming mail.
  60 This variable is a list of mail source specifiers.
  61 See Info node `(gnus)Mail Source Specifiers'."
  62   :group 'mail-source
  63   :type `(repeat
  64           (choice :format "%[Value Menu%] %v"
  65                   :value (file)
  66                   (cons :tag "Spool file"
  67                         (const :format "" file)
  68                         (checklist :tag "Options" :greedy t
  69                                    (group :inline t
  70                                           (const :format "" :value :path)
  71                                           file)))
  72                   (cons :tag "Several files in a directory"
  73                         (const :format "" directory)
  74                         (checklist :tag "Options" :greedy t
  75                                    (group :inline t
  76                                           (const :format "" :value :path)
  77                                           (directory :tag "Path"))
  78                                    (group :inline t
  79                                           (const :format "" :value :suffix)
  80                                           (string :tag "Suffix"))
  81                                    (group :inline t
  82                                           (const :format "" :value :predicate)
  83                                           (function :tag "Predicate"))
  84                                    (group :inline t
  85                                           (const :format "" :value :prescript)
  86                                           (string :tag "Prescript"))
  87                                    (group :inline t
  88                                           (const :format "" :value :postscript)
  89                                           (string :tag "Postscript"))
  90                                    (group :inline t
  91                                           (const :format "" :value :plugged)
  92                                           (boolean :tag "Plugged"))))
  93                   (cons :tag "POP3 server"
  94                         (const :format "" pop)
  95                         (checklist :tag "Options" :greedy t
  96                                    (group :inline t
  97                                           (const :format "" :value :server)
  98                                           (string :tag "Server"))
  99                                    (group :inline t
 100                                           (const :format "" :value :port)
 101                                           (choice :tag "Port"
 102                                                   :value "pop3"
 103                                                   (number :format "%v")
 104                                                   (string :format "%v")))
 105                                    (group :inline t
 106                                           (const :format "" :value :user)
 107                                           (string :tag "User"))
 108                                    (group :inline t
 109                                           (const :format "" :value :password)
 110                                           (string :tag "Password"))
 111                                    (group :inline t
 112                                           (const :format "" :value :program)
 113                                           (string :tag "Program"))
 114                                    (group :inline t
 115                                           (const :format "" :value :prescript)
 116                                           (string :tag "Prescript"))
 117                                    (group :inline t
 118                                           (const :format "" :value :postscript)
 119                                           (string :tag "Postscript"))
 120                                    (group :inline t
 121                                           (const :format "" :value :function)
 122                                           (function :tag "Function"))
 123                                    (group :inline t
 124                                           (const :format ""
 125                                                  :value :authentication)
 126                                           (choice :tag "Authentication"
 127                                                   :value apop
 128                                                   (const password)
 129                                                   (const apop)))
 130                                    (group :inline t
 131                                           (const :format "" :value :plugged)
 132                                           (boolean :tag "Plugged"))))
 133                   (cons :tag "Maildir (qmail, postfix...)"
 134                         (const :format "" maildir)
 135                         (checklist :tag "Options" :greedy t
 136                                    (group :inline t
 137                                           (const :format "" :value :path)
 138                                           (directory :tag "Path"))
 139                                    (group :inline t
 140                                           (const :format "" :value :plugged)
 141                                           (boolean :tag "Plugged"))))
 142                   (cons :tag "IMAP server"
 143                         (const :format "" imap)
 144                         (checklist :tag "Options" :greedy t
 145                                    (group :inline t
 146                                           (const :format "" :value :server)
 147                                           (string :tag "Server"))
 148                                    (group :inline t
 149                                           (const :format "" :value :port)
 150                                           (choice :tag "Port"
 151                                                   :value 143
 152                                                   number string))
 153                                    (group :inline t
 154                                           (const :format "" :value :user)
 155                                           (string :tag "User"))
 156                                    (group :inline t
 157                                           (const :format "" :value :password)
 158                                           (string :tag "Password"))
 159                                    (group :inline t
 160                                           (const :format "" :value :stream)
 161                                           (choice :tag "Stream"
 162                                                   :value network
 163                                                   ,@mail-source-imap-streams))
 164                                    (group :inline t
 165                                           (const :format "" :value :program)
 166                                           (string :tag "Program"))
 167                                    (group :inline t
 168                                           (const :format ""
 169                                                  :value :authenticator)
 170                                           (choice :tag "Authenticator"
 171                                                   :value login
 172                                                   ,@mail-source-imap-authenticators))
 173                                    (group :inline t
 174                                           (const :format "" :value :mailbox)
 175                                           (string :tag "Mailbox"
 176                                                   :value "INBOX"))
 177                                    (group :inline t
 178                                           (const :format "" :value :predicate)
 179                                           (string :tag "Predicate"
 180                                                   :value "UNSEEN UNDELETED"))
 181                                    (group :inline t
 182                                           (const :format "" :value :fetchflag)
 183                                           (string :tag "Fetchflag"
 184                                                   :value  "\\Deleted"))
 185                                    (group :inline t
 186                                           (const :format ""
 187                                                  :value :dontexpunge)
 188                                           (boolean :tag "Dontexpunge"))
 189                                    (group :inline t
 190                                           (const :format "" :value :plugged)
 191                                           (boolean :tag "Plugged"))))
 192                   (cons :tag "Webmail server"
 193                         (const :format "" webmail)
 194                         (checklist :tag "Options" :greedy t
 195                                    (group :inline t
 196                                          (const :format "" :value :subtype)
 197                                          ;; Should be generated from
 198                                          ;; `webmail-type-definition', but we
 199                                          ;; can't require webmail without W3.
 200                                          (choice :tag "Subtype"
 201                                                  :value hotmail
 202                                                  (const hotmail)
 203                                                  (const yahoo)
 204                                                  (const netaddress)
 205                                                  (const netscape)
 206                                                  (const my-deja)))
 207                                    (group :inline t
 208                                           (const :format "" :value :user)
 209                                           (string :tag "User"))
 210                                    (group :inline t
 211                                           (const :format "" :value :password)
 212                                           (string :tag "Password"))
 213                                    (group :inline t
 214                                           (const :format ""
 215                                                  :value :dontexpunge)
 216                                           (boolean :tag "Dontexpunge"))
 217                                    (group :inline t
 218                                           (const :format "" :value :plugged)
 219                                           (boolean :tag "Plugged")))))))
 220
 221 (defcustom mail-source-primary-source nil
 222   "*Primary source for incoming mail.
 223 If non-nil, this maildrop will be checked periodically for new mail."
 224   :group 'mail-source
 225   :type 'sexp)
 226
 227 (defcustom mail-source-flash t
 228   "*If non-nil, flash periodically when mail is available."
 229   :group 'mail-source
 230   :type 'boolean)
 231
 232 (defcustom mail-source-crash-box "~/.emacs-mail-crash-box"
 233   "File where mail will be stored while processing it."
 234   :group 'mail-source
 235   :type 'file)
 236
 237 (defcustom mail-source-directory message-directory
 238   "Directory where files (if any) will be stored."
 239   :group 'mail-source
 240   :type 'directory)
 241
 242 (defcustom mail-source-default-file-modes 384
 243   "Set the mode bits of all new mail files to this integer."
 244   :group 'mail-source
 245   :type 'integer)
 246
 247 (defcustom mail-source-delete-incoming nil
 248   "*If non-nil, delete incoming files after handling."
 249   :group 'mail-source
 250   :type 'boolean)
 251
 252 (defcustom mail-source-incoming-file-prefix "Incoming"
 253   "Prefix for file name for storing incoming mail"
 254   :group 'mail-source
 255   :type 'string)
 256
 257 (defcustom mail-source-report-new-mail-interval 5
 258   "Interval in minutes between checks for new mail."
 259   :group 'mail-source
 260   :type 'number)
 261
 262 (defcustom mail-source-idle-time-delay 5
 263   "Number of idle seconds to wait before checking for new mail."
 264   :group 'mail-source
 265   :type 'number)
 266
 267 (defcustom mail-source-movemail-program nil
 268   "If non-nil, name of program for fetching new mail."
 269   :group 'mail-source
 270   :type '(choice (const nil) string))
 271
 272 ;;; Internal variables.
 273
 274 (defvar mail-source-string ""
 275   "A dynamically bound string that says what the current mail source is.")
 276
 277 (defvar mail-source-new-mail-available nil
 278   "Flag indicating when new mail is available.")
 279
 280 (eval-and-compile
 281   (defvar mail-source-common-keyword-map
 282     '((:plugged))
 283     "Mapping from keywords to default values.
 284 Common keywords should be listed here.")
 285
 286   (defvar mail-source-keyword-map
 287     '((file
 288        (:prescript)
 289        (:prescript-delay)
 290        (:postscript)
 291        (:path (or (getenv "MAIL")
 292                   (expand-file-name (user-login-name) rmail-spool-directory))))
 293       (directory
 294        (:prescript)
 295        (:prescript-delay)
 296        (:postscript)
 297        (:path)
 298        (:suffix ".spool")
 299        (:predicate identity))
 300       (pop
 301        (:prescript)
 302        (:prescript-delay)
 303        (:postscript)
 304        (:server (getenv "MAILHOST"))
 305        (:port 110)
 306        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 307        (:program)
 308        (:function)
 309        (:password)
 310        (:authentication password))
 311       (maildir
 312        (:path (or (getenv "MAILDIR") "~/Maildir/"))
 313        (:subdirs ("new" "cur"))
 314        (:function))
 315       (imap
 316        (:server (getenv "MAILHOST"))
 317        (:port)
 318        (:stream)
 319        (:program)
 320        (:authentication)
 321        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 322        (:password)
 323        (:mailbox "INBOX")
 324        (:predicate "UNSEEN UNDELETED")
 325        (:fetchflag "\\Deleted")
 326        (:dontexpunge))
 327       (webmail
 328        (:subtype hotmail)
 329        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 330        (:password)
 331        (:dontexpunge)
 332        (:authentication password)))
 333     "Mapping from keywords to default values.
 334 All keywords that can be used must be listed here."))
 335
 336 (defvar mail-source-fetcher-alist
 337   '((file mail-source-fetch-file)
 338     (directory mail-source-fetch-directory)
 339     (pop mail-source-fetch-pop)
 340     (maildir mail-source-fetch-maildir)
 341     (imap mail-source-fetch-imap)
 342     (webmail mail-source-fetch-webmail))
 343   "A mapping from source type to fetcher function.")
 344
 345 (defvar mail-source-password-cache nil)
 346
 347 (defvar mail-source-plugged t)
 348
 349 ;;; Functions
 350
 351 (eval-and-compile
 352   (defun mail-source-strip-keyword (keyword)
 353     "Strip the leading colon off the KEYWORD."
 354     (intern (substring (symbol-name keyword) 1))))
 355
 356 (eval-and-compile
 357   (defun mail-source-bind-1 (type)
 358     (let* ((defaults (cdr (assq type mail-source-keyword-map)))
 359            default bind)
 360       (while (setq default (pop defaults))
 361         (push (list (mail-source-strip-keyword (car default))
 362                     nil)
 363               bind))
 364       bind)))
 365
 366 (defmacro mail-source-bind (type-source &rest body)
 367   "Return a `let' form that binds all variables in source TYPE.
 368 TYPE-SOURCE is a list where the first element is the TYPE, and
 369 the second variable is the SOURCE.
 370 At run time, the mail source specifier SOURCE will be inspected,
 371 and the variables will be set according to it.  Variables not
 372 specified will be given default values.
 373
 374 After this is done, BODY will be executed in the scope
 375 of the `let' form.
 376
 377 The variables bound and their default values are described by
 378 the `mail-source-keyword-map' variable."
 379   `(let ,(mail-source-bind-1 (car type-source))
 380      (mail-source-set-1 ,(cadr type-source))
 381      ,@body))
 382
 383 (put 'mail-source-bind 'lisp-indent-function 1)
 384 (put 'mail-source-bind 'edebug-form-spec '(sexp body))
 385
 386 (defun mail-source-set-1 (source)
 387   (let* ((type (pop source))
 388          (defaults (cdr (assq type mail-source-keyword-map)))
 389          default value keyword)
 390     (while (setq default (pop defaults))
 391       (set (mail-source-strip-keyword (setq keyword (car default)))
 392            (if (setq value (plist-get source keyword))
 393                (mail-source-value value)
 394              (mail-source-value (cadr default)))))))
 395
 396 (eval-and-compile
 397   (defun mail-source-bind-common-1 ()
 398     (let* ((defaults mail-source-common-keyword-map)
 399            default bind)
 400       (while (setq default (pop defaults))
 401         (push (list (mail-source-strip-keyword (car default))
 402                     nil)
 403               bind))
 404       bind)))
 405
 406 (defun mail-source-set-common-1 (source)
 407   (let* ((type (pop source))
 408          (defaults mail-source-common-keyword-map)
 409          (defaults-1 (cdr (assq type mail-source-keyword-map)))
 410          default value keyword)
 411     (while (setq default (pop defaults))
 412       (set (mail-source-strip-keyword (setq keyword (car default)))
 413            (if (setq value (plist-get source keyword))
 414                (mail-source-value value)
 415              (if (setq value (assq  keyword defaults-1))
 416                  (mail-source-value (cadr value))
 417                (mail-source-value (cadr default))))))))
 418
 419 (defmacro mail-source-bind-common (source &rest body)
 420   "Return a `let' form that binds all common variables.
 421 See `mail-source-bind'."
 422   `(let ,(mail-source-bind-common-1)
 423      (mail-source-set-common-1 source)
 424      ,@body))
 425
 426 (put 'mail-source-bind-common 'lisp-indent-function 1)
 427 (put 'mail-source-bind-common 'edebug-form-spec '(sexp body))
 428
 429 (defun mail-source-value (value)
 430   "Return the value of VALUE."
 431   (cond
 432    ;; String
 433    ((stringp value)
 434     value)
 435    ;; Function
 436    ((and (listp value)
 437          (functionp (car value)))
 438     (eval value))
 439    ;; Just return the value.
 440    (t
 441     value)))
 442
 443 (defun mail-source-fetch (source callback)
 444   "Fetch mail from SOURCE and call CALLBACK zero or more times.
 445 CALLBACK will be called with the name of the file where (some of)
 446 the mail from SOURCE is put.
 447 Return the number of files that were found."
 448   (mail-source-bind-common source
 449     (if (or mail-source-plugged plugged)
 450         (save-excursion
 451           (let ((function (cadr (assq (car source) mail-source-fetcher-alist)))
 452                 (found 0))
 453             (unless function
 454               (error "%S is an invalid mail source specification" source))
 455             ;; If there's anything in the crash box, we do it first.
 456             (when (file-exists-p mail-source-crash-box)
 457               (message "Processing mail from %s..." mail-source-crash-box)
 458               (setq found (mail-source-callback
 459                            callback mail-source-crash-box)))
 460             (+ found
 461                (if (or debug-on-quit debug-on-error)
 462                    (funcall function source callback)
 463                  (condition-case err
 464                      (funcall function source callback)
 465                    (error
 466                     (unless (yes-or-no-p
 467                              (format "Mail source error (%s).  Continue? " err))
 468                       (error "Cannot get new mail"))
 469                     0)))))))))
 470
 471 (defun mail-source-make-complex-temp-name (prefix)
 472   (let ((newname (make-temp-name prefix))
 473         (newprefix prefix))
 474     (while (file-exists-p newname)
 475       (setq newprefix (concat newprefix "x"))
 476       (setq newname (make-temp-name newprefix)))
 477     newname))
 478
 479 (defun mail-source-callback (callback info)
 480   "Call CALLBACK on the mail file, and then remove the mail file.
 481 Pass INFO on to CALLBACK."
 482   (if (or (not (file-exists-p mail-source-crash-box))
 483           (zerop (nth 7 (file-attributes mail-source-crash-box))))
 484       (progn
 485         (when (file-exists-p mail-source-crash-box)
 486           (delete-file mail-source-crash-box))
 487         0)
 488     (prog1
 489         (funcall callback mail-source-crash-box info)
 490       (when (file-exists-p mail-source-crash-box)
 491         ;; Delete or move the incoming mail out of the way.
 492         (if mail-source-delete-incoming
 493             (delete-file mail-source-crash-box)
 494           (let ((incoming
 495                  (mail-source-make-complex-temp-name
 496                   (expand-file-name
 497                    mail-source-incoming-file-prefix
 498                    mail-source-directory))))
 499             (unless (file-exists-p (file-name-directory incoming))
 500               (make-directory (file-name-directory incoming) t))
 501             (rename-file mail-source-crash-box incoming t)))))))
 502
 503 (defun mail-source-movemail (from to)
 504   "Move FROM to TO using movemail."
 505   (if (not (file-writable-p to))
 506       (error "Can't write to crash box %s.  Not moving mail" to)
 507     (let ((to (file-truename (expand-file-name to)))
 508           errors result)
 509       (setq to (file-truename to)
 510             from (file-truename from))
 511       ;; Set TO if have not already done so, and rename or copy
 512       ;; the file FROM to TO if and as appropriate.
 513       (cond
 514        ((file-exists-p to)
 515         ;; The crash box exists already.
 516         t)
 517        ((not (file-exists-p from))
 518         ;; There is no inbox.
 519         (setq to nil))
 520        ((zerop (nth 7 (file-attributes from)))
 521         ;; Empty file.
 522         (setq to nil))
 523        (t
 524         ;; If getting from mail spool directory, use movemail to move
 525         ;; rather than just renaming, so as to interlock with the
 526         ;; mailer.
 527         (unwind-protect
 528             (save-excursion
 529               (setq errors (generate-new-buffer " *mail source loss*"))
 530               (let ((default-directory "/"))
 531                 (setq result
 532                       (apply
 533                        'call-process
 534                        (append
 535                         (list
 536                          (or mail-source-movemail-program
 537                              (expand-file-name "movemail" exec-directory))
 538                          nil errors nil from to)))))
 539               (when (file-exists-p to)
 540                 (set-file-modes to mail-source-default-file-modes))
 541               (if (and (or (not (buffer-modified-p errors))
 542                            (zerop (buffer-size errors)))
 543                        (zerop result))
 544                   ;; No output => movemail won.
 545                   t
 546                 (set-buffer errors)
 547                 ;; There may be a warning about older revisions.  We
 548                 ;; ignore that.
 549                 (goto-char (point-min))
 550                 (if (search-forward "older revision" nil t)
 551                     t
 552                   ;; Probably a real error.
 553                   (subst-char-in-region (point-min) (point-max) ?\n ?\  )
 554                   (goto-char (point-max))
 555                   (skip-chars-backward " \t")
 556                   (delete-region (point) (point-max))
 557                   (goto-char (point-min))
 558                   (when (looking-at "movemail: ")
 559                     (delete-region (point-min) (match-end 0)))
 560                   ;; Result may be a signal description string.
 561                   (unless (yes-or-no-p
 562                            (format "movemail: %s (%s return).  Continue? "
 563                                    (buffer-string) result))
 564                     (error "%s" (buffer-string)))
 565                   (setq to nil)))))))
 566       (when (and errors
 567                  (buffer-name errors))
 568         (kill-buffer errors))
 569       ;; Return whether we moved successfully or not.
 570       to)))
 571
 572 (defun mail-source-movemail-and-remove (from to)
 573   "Move FROM to TO using movemail, then remove FROM if empty."
 574   (or (not (mail-source-movemail from to))
 575       (not (zerop (nth 7 (file-attributes from))))
 576       (delete-file from)))
 577
 578 (defvar mail-source-read-passwd nil)
 579 (defun mail-source-read-passwd (prompt &rest args)
 580   "Read a password using PROMPT.
 581 If ARGS, PROMPT is used as an argument to `format'."
 582   (let ((prompt
 583          (if args
 584              (apply 'format prompt args)
 585            prompt)))
 586     (unless mail-source-read-passwd
 587       (if (or (fboundp 'read-passwd) (load "passwd" t))
 588           (setq mail-source-read-passwd 'read-passwd)
 589         (unless (fboundp 'ange-ftp-read-passwd)
 590           (autoload 'ange-ftp-read-passwd "ange-ftp"))
 591         (setq mail-source-read-passwd 'ange-ftp-read-passwd)))
 592     (funcall mail-source-read-passwd prompt)))
 593
 594 (defun mail-source-fetch-with-program (program)
 595   (zerop (call-process shell-file-name nil nil nil
 596                        shell-command-switch program)))
 597
 598 (defun mail-source-run-script (script spec &optional delay)
 599   (when script
 600     (if (and (symbolp script) (fboundp script))
 601         (funcall script)
 602       (mail-source-call-script
 603        (format-spec script spec))))
 604   (when delay
 605     (sleep-for delay)))
 606
 607 (defun mail-source-call-script (script)
 608   (let ((background nil))
 609     (when (string-match "& *$" script)
 610       (setq script (substring script 0 (match-beginning 0))
 611             background 0))
 612     (call-process shell-file-name nil background nil
 613                   shell-command-switch script)))
 614
 615 ;;;
 616 ;;; Different fetchers
 617 ;;;
 618
 619 (defun mail-source-fetch-file (source callback)
 620   "Fetcher for single-file sources."
 621   (mail-source-bind (file source)
 622     (mail-source-run-script
 623      prescript (format-spec-make ?t mail-source-crash-box)
 624      prescript-delay)
 625     (let ((mail-source-string (format "file:%s" path)))
 626       (if (mail-source-movemail path mail-source-crash-box)
 627           (prog1
 628               (mail-source-callback callback path)
 629             (mail-source-run-script
 630              postscript (format-spec-make ?t mail-source-crash-box)))
 631         0))))
 632
 633 (defun mail-source-fetch-directory (source callback)
 634   "Fetcher for directory sources."
 635   (mail-source-bind (directory source)
 636     (mail-source-run-script
 637      prescript (format-spec-make ?t path)
 638      prescript-delay)
 639     (let ((found 0)
 640           (mail-source-string (format "directory:%s" path)))
 641       (dolist (file (directory-files
 642                      path t (concat (regexp-quote suffix) "$")))
 643         (when (and (file-regular-p file)
 644                    (funcall predicate file)
 645                    (mail-source-movemail file mail-source-crash-box))
 646           (incf found (mail-source-callback callback file))))
 647       (mail-source-run-script
 648        postscript (format-spec-make ?t path))
 649       found)))
 650
 651 (defun mail-source-fetch-pop (source callback)
 652   "Fetcher for single-file sources."
 653   (mail-source-bind (pop source)
 654     (mail-source-run-script
 655      prescript
 656      (format-spec-make ?p password ?t mail-source-crash-box
 657                        ?s server ?P port ?u user)
 658      prescript-delay)
 659     (let ((from (format "%s:%s:%s" server user port))
 660           (mail-source-string (format "pop:%s@%s" user server))
 661           result)
 662       (when (eq authentication 'password)
 663         (setq password
 664               (or password
 665                   (cdr (assoc from mail-source-password-cache))
 666                   (mail-source-read-passwd
 667                    (format "Password for %s at %s: " user server)))))
 668       (when server
 669         (setenv "MAILHOST" server))
 670       (setq result
 671             (cond
 672              (program
 673               (mail-source-fetch-with-program
 674                (format-spec
 675                 program
 676                 (format-spec-make ?p password ?t mail-source-crash-box
 677                                   ?s server ?P port ?u user))))
 678              (function
 679               (funcall function mail-source-crash-box))
 680              ;; The default is to use pop3.el.
 681              (t
 682               (let ((pop3-password password)
 683                     (pop3-maildrop user)
 684                     (pop3-mailhost server)
 685                     (pop3-port port)
 686                     (pop3-authentication-scheme
 687                      (if (eq authentication 'apop) 'apop 'pass)))
 688                 (if (or debug-on-quit debug-on-error)
 689                     (save-excursion (pop3-movemail mail-source-crash-box))
 690                   (condition-case err
 691                       (save-excursion (pop3-movemail mail-source-crash-box))
 692                     (error
 693                      ;; We nix out the password in case the error
 694                      ;; was because of a wrong password being given.
 695                      (setq mail-source-password-cache
 696                            (delq (assoc from mail-source-password-cache)
 697                                  mail-source-password-cache))
 698                      (signal (car err) (cdr err)))))))))
 699       (if result
 700           (progn
 701             (when (eq authentication 'password)
 702               (unless (assoc from mail-source-password-cache)
 703                 (push (cons from password) mail-source-password-cache)))
 704             (prog1
 705                 (mail-source-callback callback server)
 706               ;; Update display-time's mail flag, if relevant.
 707               (if (equal source mail-source-primary-source)
 708                   (setq mail-source-new-mail-available nil))
 709               (mail-source-run-script
 710                postscript
 711                (format-spec-make ?p password ?t mail-source-crash-box
 712                                  ?s server ?P port ?u user))))
 713         ;; We nix out the password in case the error
 714         ;; was because of a wrong password being given.
 715         (setq mail-source-password-cache
 716               (delq (assoc from mail-source-password-cache)
 717                     mail-source-password-cache))
 718         0))))
 719
 720 (defun mail-source-check-pop (source)
 721   "Check whether there is new mail."
 722   (mail-source-bind (pop source)
 723     (let ((from (format "%s:%s:%s" server user port))
 724           (mail-source-string (format "pop:%s@%s" user server))
 725           result)
 726       (when (eq authentication 'password)
 727         (setq password
 728               (or password
 729                   (cdr (assoc from mail-source-password-cache))
 730                   (mail-source-read-passwd
 731                    (format "Password for %s at %s: " user server))))
 732         (unless (assoc from mail-source-password-cache)
 733           (push (cons from password) mail-source-password-cache)))
 734       (when server
 735         (setenv "MAILHOST" server))
 736       (setq result
 737             (cond
 738              ;; No easy way to check whether mail is waiting for these.
 739              (program)
 740              (function)
 741              ;; The default is to use pop3.el.
 742              (t
 743               (let ((pop3-password password)
 744                     (pop3-maildrop user)
 745                     (pop3-mailhost server)
 746                     (pop3-port port)
 747                     (pop3-authentication-scheme
 748                      (if (eq authentication 'apop) 'apop 'pass)))
 749                 (if (or debug-on-quit debug-on-error)
 750                     (save-excursion (pop3-get-message-count))
 751                   (condition-case err
 752                       (save-excursion (pop3-get-message-count))
 753                     (error
 754                      ;; We nix out the password in case the error
 755                      ;; was because of a wrong password being given.
 756                      (setq mail-source-password-cache
 757                            (delq (assoc from mail-source-password-cache)
 758                                  mail-source-password-cache))
 759                      (signal (car err) (cdr err)))))))))
 760       (if result
 761           ;; Inform display-time that we have new mail.
 762           (setq mail-source-new-mail-available (> result 0))
 763         ;; We nix out the password in case the error
 764         ;; was because of a wrong password being given.
 765         (setq mail-source-password-cache
 766               (delq (assoc from mail-source-password-cache)
 767                     mail-source-password-cache)))
 768       result)))
 769
 770 (defun mail-source-new-mail-p ()
 771   "Handler for `display-time' to indicate when new mail is available."
 772   ;; Flash (ie. ring the visible bell) if mail is available.
 773   (if (and mail-source-flash mail-source-new-mail-available)
 774       (let ((visible-bell t))
 775         (ding)))
 776   ;; Only report flag setting; flag is updated on a different schedule.
 777   mail-source-new-mail-available)
 778
 779
 780 (defvar mail-source-report-new-mail nil)
 781 (defvar mail-source-report-new-mail-timer nil)
 782 (defvar mail-source-report-new-mail-idle-timer nil)
 783
 784 (eval-when-compile
 785   (if (featurep 'xemacs)
 786       (require 'itimer)
 787     (require 'timer)))
 788
 789 (defun mail-source-start-idle-timer ()
 790   ;; Start our idle timer if necessary, so we delay the check until the
 791   ;; user isn't typing.
 792   (unless mail-source-report-new-mail-idle-timer
 793     (setq mail-source-report-new-mail-idle-timer
 794           (run-with-idle-timer
 795            mail-source-idle-time-delay
 796            nil
 797            (lambda ()
 798              (unwind-protect
 799                  (mail-source-check-pop mail-source-primary-source)
 800                (setq mail-source-report-new-mail-idle-timer nil)))))
 801     ;; Since idle timers created when Emacs is already in the idle
 802     ;; state don't get activated until Emacs _next_ becomes idle, we
 803     ;; need to force our timer to be considered active now.  We do
 804     ;; this by being naughty and poking the timer internals directly
 805     ;; (element 0 of the vector is nil if the timer is active).
 806     (aset mail-source-report-new-mail-idle-timer 0 nil)))
 807
 808 (defun mail-source-report-new-mail (arg)
 809   "Toggle whether to report when new mail is available.
 810 This only works when `display-time' is enabled."
 811   (interactive "P")
 812   (if (not mail-source-primary-source)
 813       (error "Need to set `mail-source-primary-source' to check for new mail"))
 814   (let ((on (if (null arg)
 815                 (not mail-source-report-new-mail)
 816               (> (prefix-numeric-value arg) 0))))
 817     (setq mail-source-report-new-mail on)
 818     (and mail-source-report-new-mail-timer
 819          (nnheader-cancel-timer mail-source-report-new-mail-timer))
 820     (and mail-source-report-new-mail-idle-timer
 821          (nnheader-cancel-timer mail-source-report-new-mail-idle-timer))
 822     (setq mail-source-report-new-mail-timer nil)
 823     (setq mail-source-report-new-mail-idle-timer nil)
 824     (if on
 825         (progn
 826           (require 'time)
 827           ;; display-time-mail-function is an Emacs 21 feature.
 828           (setq display-time-mail-function #'mail-source-new-mail-p)
 829           ;; Set up the main timer.
 830           (setq mail-source-report-new-mail-timer
 831                 (nnheader-run-at-time
 832                  (* 60 mail-source-report-new-mail-interval)
 833                  (* 60 mail-source-report-new-mail-interval)
 834                  #'mail-source-start-idle-timer))
 835           ;; When you get new mail, clear "Mail" from the mode line.
 836           (add-hook 'nnmail-post-get-new-mail-hook
 837                     'display-time-event-handler)
 838           (message "Mail check enabled"))
 839       (setq display-time-mail-function nil)
 840       (remove-hook 'nnmail-post-get-new-mail-hook
 841                    'display-time-event-handler)
 842       (message "Mail check disabled"))))
 843
 844 (defun mail-source-fetch-maildir (source callback)
 845   "Fetcher for maildir sources."
 846   (mail-source-bind (maildir source)
 847     (let ((found 0)
 848           mail-source-string)
 849       (unless (string-match "/$" path)
 850         (setq path (concat path "/")))
 851       (dolist (subdir subdirs)
 852         (when (file-directory-p (concat path subdir))
 853           (setq mail-source-string (format "maildir:%s%s" path subdir))
 854           (dolist (file (directory-files (concat path subdir) t))
 855             (when (and (not (file-directory-p file))
 856                        (not (if function
 857                                 (funcall function file mail-source-crash-box)
 858                               (let ((coding-system-for-write
 859                                      mm-text-coding-system)
 860                                     (coding-system-for-read
 861                                      mm-text-coding-system))
 862                                 (with-temp-file mail-source-crash-box
 863                                   (insert-file-contents file)
 864                                   (goto-char (point-min))
 865 ;;;                               ;; Unix mail format
 866 ;;;                               (unless (looking-at "\n*From ")
 867 ;;;                                 (insert "From maildir "
 868 ;;;                                         (current-time-string) "\n"))
 869 ;;;                               (while (re-search-forward "^From " nil t)
 870 ;;;                                 (replace-match ">From "))
 871 ;;;                               (goto-char (point-max))
 872 ;;;                               (insert "\n\n")
 873                                   ;; MMDF mail format
 874                                   (insert "\001\001\001\001\n"))
 875                                 (delete-file file)))))
 876               (incf found (mail-source-callback callback file))))))
 877       found)))
 878
 879 (eval-and-compile
 880   (autoload 'imap-open "imap")
 881   (autoload 'imap-authenticate "imap")
 882   (autoload 'imap-mailbox-select "imap")
 883   (autoload 'imap-mailbox-unselect "imap")
 884   (autoload 'imap-mailbox-close "imap")
 885   (autoload 'imap-search "imap")
 886   (autoload 'imap-fetch "imap")
 887   (autoload 'imap-close "imap")
 888   (autoload 'imap-error-text "imap")
 889   (autoload 'imap-message-flags-add "imap")
 890   (autoload 'imap-list-to-message-set "imap")
 891   (autoload 'imap-range-to-message-set "imap")
 892   (autoload 'nnheader-ms-strip-cr "nnheader"))
 893
 894 (defvar mail-source-imap-file-coding-system 'binary
 895   "Coding system for the crashbox made by `mail-source-fetch-imap'.")
 896
 897 (defun mail-source-fetch-imap (source callback)
 898   "Fetcher for imap sources."
 899   (mail-source-bind (imap source)
 900     (let ((from (format "%s:%s:%s" server user port))
 901           (found 0)
 902           (buf (get-buffer-create (generate-new-buffer-name " *imap source*")))
 903           (mail-source-string (format "imap:%s:%s" server mailbox))
 904           (imap-shell-program (or (list program) imap-shell-program))
 905           remove)
 906       (if (and (imap-open server port stream authentication buf)
 907                (imap-authenticate
 908                 user (or (cdr (assoc from mail-source-password-cache))
 909                          password) buf)
 910                (imap-mailbox-select mailbox nil buf))
 911           (let ((coding-system-for-write mail-source-imap-file-coding-system)
 912                 str)
 913             (with-temp-file mail-source-crash-box
 914               ;; Avoid converting 8-bit chars from inserted strings to
 915               ;; multibyte.
 916               (mm-disable-multibyte)
 917               ;; remember password
 918               (with-current-buffer buf
 919                 (when (or imap-password
 920                           (assoc from mail-source-password-cache))
 921                   (push (cons from imap-password) mail-source-password-cache)))
 922               ;; if predicate is nil, use all uids
 923               (dolist (uid (imap-search (or predicate "1:*") buf))
 924                 (when (setq str
 925                             (if (imap-capability 'IMAP4rev1 buf)
 926                                 (caddar (imap-fetch uid "BODY.PEEK[]"
 927                                                     'BODYDETAIL nil buf))
 928                               (imap-fetch uid "RFC822.PEEK" 'RFC822 nil buf)))
 929                   (push uid remove)
 930                   (insert "From imap " (current-time-string) "\n")
 931                   (save-excursion
 932                     (insert str "\n\n"))
 933                   (while (re-search-forward "^From " nil t)
 934                     (replace-match ">From "))
 935                   (goto-char (point-max))))
 936               (nnheader-ms-strip-cr))
 937             (incf found (mail-source-callback callback server))
 938             (when (and remove fetchflag)
 939               (imap-message-flags-add
 940                (imap-range-to-message-set (gnus-compress-sequence remove))
 941                fetchflag nil buf))
 942             (if dontexpunge
 943                 (imap-mailbox-unselect buf)
 944               (imap-mailbox-close nil buf))
 945             (imap-close buf))
 946         (imap-close buf)
 947         ;; We nix out the password in case the error
 948         ;; was because of a wrong password being given.
 949         (setq mail-source-password-cache
 950               (delq (assoc from mail-source-password-cache)
 951                     mail-source-password-cache))
 952         (error (imap-error-text buf)))
 953       (kill-buffer buf)
 954       found)))
 955
 956 (eval-and-compile
 957   (autoload 'webmail-fetch "webmail"))
 958
 959 (defun mail-source-fetch-webmail (source callback)
 960   "Fetch for webmail source."
 961   (mail-source-bind (webmail source)
 962     (let ((mail-source-string (format "webmail:%s:%s" subtype user))
 963           (webmail-newmail-only dontexpunge)
 964           (webmail-move-to-trash-can (not dontexpunge)))
 965       (when (eq authentication 'password)
 966         (setq password
 967               (or password
 968                   (cdr (assoc (format "webmail:%s:%s" subtype user)
 969                               mail-source-password-cache))
 970                   (mail-source-read-passwd
 971                    (format "Password for %s at %s: " user subtype))))
 972         (when (and password
 973                    (not (assoc (format "webmail:%s:%s" subtype user)
 974                                mail-source-password-cache)))
 975           (push (cons (format "webmail:%s:%s" subtype user) password)
 976                 mail-source-password-cache)))
 977       (webmail-fetch mail-source-crash-box subtype user password)
 978       (mail-source-callback callback (symbol-name subtype)))))
 979
 980 (provide 'mail-source)
 981
 982 ;;; mail-source.el ends here