cgit.sxemacs.org Git - gnus/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'text-props)
  29 (defvar menu-bar-mode (featurep 'menubar))
  30 (require 'messagexmas)
  31
  32 (defvar gnus-xmas-glyph-directory nil
  33   "*Directory where Gnus logos and icons are located.
  34 If this variable is nil, Gnus will try to locate the directory
  35 automatically.")
  36
  37 (defvar gnus-xmas-logo-color-alist
  38   '((flame "#cc3300" "#ff2200")
  39     (pine "#c0cc93" "#f8ffb8")
  40     (moss "#a1cc93" "#d2ffb8")
  41     (irish "#04cc90" "#05ff97")
  42     (sky "#049acc" "#05deff")
  43     (tin "#6886cc" "#82b6ff")
  44     (velvet "#7c68cc" "#8c82ff")
  45     (grape "#b264cc" "#cf7df")
  46     (labia "#cc64c2" "#fd7dff")
  47     (berry "#cc6485" "#ff7db5")
  48     (neutral "#b4b4b4" "#878787")
  49     (september "#bf9900" "#ffcc00"))
  50   "Color alist used for the Gnus logo.")
  51
  52 (defvar gnus-xmas-logo-color-style 'flame
  53   "Color styles used for the Gnus logo.")
  54
  55 (defvar gnus-xmas-logo-colors
  56   (cdr (assq gnus-xmas-logo-color-style gnus-xmas-logo-color-alist))
  57   "Colors used for the Gnus logo.")
  58
  59 (defvar gnus-article-x-face-command
  60   (if (featurep 'xface)
  61       'gnus-xmas-article-display-xface
  62     "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | xv -quit -")
  63   "String or function to be executed to display an X-Face header.
  64 If it is a string, the command will be executed in a sub-shell
  65 asynchronously.  The compressed face will be piped to this command.")
  66
  67 ;;; Internal variables.
  68
  69 ;; Don't warn about these undefined variables.
  70
  71 (defvar gnus-group-mode-hook)
  72 (defvar gnus-summary-mode-hook)
  73 (defvar gnus-article-mode-hook)
  74
  75 ;;defined in gnus.el
  76 (defvar gnus-active-hashtb)
  77 (defvar gnus-article-buffer)
  78 (defvar gnus-auto-center-summary)
  79 (defvar gnus-buffer-list)
  80 (defvar gnus-current-headers)
  81 (defvar gnus-level-killed)
  82 (defvar gnus-level-zombie)
  83 (defvar gnus-newsgroup-bookmarks)
  84 (defvar gnus-newsgroup-dependencies)
  85 (defvar gnus-newsgroup-selected-overlay)
  86 (defvar gnus-newsrc-hashtb)
  87 (defvar gnus-read-mark)
  88 (defvar gnus-refer-article-method)
  89 (defvar gnus-reffed-article-number)
  90 (defvar gnus-unread-mark)
  91 (defvar gnus-version)
  92 (defvar gnus-view-pseudos)
  93 (defvar gnus-view-pseudos-separately)
  94 (defvar gnus-visual)
  95 (defvar gnus-zombie-list)
  96 ;;defined in gnus-msg.el
  97 (defvar gnus-article-copy)
  98 (defvar gnus-check-before-posting)
  99 ;;defined in gnus-vis.el
 100 (defvar gnus-article-button-face)
 101 (defvar gnus-article-mouse-face)
 102 (defvar gnus-summary-selected-face)
 103 (defvar gnus-group-reading-menu)
 104 (defvar gnus-group-group-menu)
 105 (defvar gnus-group-misc-menu)
 106 (defvar gnus-summary-article-menu)
 107 (defvar gnus-summary-thread-menu)
 108 (defvar gnus-summary-misc-menu)
 109 (defvar gnus-summary-post-menu)
 110 (defvar gnus-summary-kill-menu)
 111 (defvar gnus-article-article-menu)
 112 (defvar gnus-article-treatment-menu)
 113 (defvar gnus-mouse-2)
 114 (defvar standard-display-table)
 115 (defvar gnus-tree-minimize-window)
 116
 117 (defun gnus-xmas-set-text-properties (start end props &optional buffer)
 118   "You should NEVER use this function.  It is ideologically blasphemous.
 119 It is provided only to ease porting of broken FSF Emacs programs."
 120   (if (stringp buffer)
 121       nil
 122     (map-extents (lambda (extent ignored)
 123                    (remove-text-properties
 124                     start end
 125                     (list (extent-property extent 'text-prop) nil)
 126                     buffer))
 127                  buffer start end nil nil 'text-prop)
 128     (gnus-add-text-properties start end props buffer)))
 129
 130 (defun gnus-xmas-highlight-selected-summary ()
 131   ;; Highlight selected article in summary buffer
 132   (when gnus-summary-selected-face
 133     (when gnus-newsgroup-selected-overlay
 134       (delete-extent gnus-newsgroup-selected-overlay))
 135     (setq gnus-newsgroup-selected-overlay
 136           (make-extent (gnus-point-at-bol) (gnus-point-at-eol)))
 137     (set-extent-face gnus-newsgroup-selected-overlay
 138                      gnus-summary-selected-face)))
 139
 140 (defvar gnus-xmas-force-redisplay t
 141   "If non-nil, force a redisplay before recentering the summary buffer.
 142 This is ugly, but it works around a bug in `window-displayed-height'.")
 143
 144 (defun gnus-xmas-summary-recenter ()
 145   "\"Center\" point in the summary window.
 146 If `gnus-auto-center-summary' is nil, or the article buffer isn't
 147 displayed, no centering will be performed."
 148   ;; Suggested by earle@mahendo.JPL.NASA.GOV (Greg Earle).
 149   ;; Recenter only when requested.  Suggested by popovich@park.cs.columbia.edu.
 150   ;; Force redisplay to get properly computed window height.
 151   (when gnus-xmas-force-redisplay
 152     (sit-for 0))
 153   (when gnus-auto-center-summary
 154     (let* ((height (if (fboundp 'window-displayed-height)
 155                        (window-displayed-height)
 156                      (- (window-height) 2)))
 157            (top (cond ((< height 4) 0)
 158                       ((< height 7) 1)
 159                       (t 2)))
 160            (bottom (save-excursion (goto-char (point-max))
 161                                    (forward-line (- height))
 162                                    (point)))
 163            (window (get-buffer-window (current-buffer))))
 164       (when (get-buffer-window gnus-article-buffer)
 165         ;; Only do recentering when the article buffer is displayed,
 166         ;; Set the window start to either `bottom', which is the biggest
 167         ;; possible valid number, or the second line from the top,
 168         ;; whichever is the least.
 169         (set-window-start
 170          window (min bottom (save-excursion (forward-line (- top)) (point)))))
 171       ;; Do horizontal recentering while we're at it.
 172       (when (and (get-buffer-window (current-buffer) t)
 173                  (not (eq gnus-auto-center-summary 'vertical)))
 174         (let ((selected (selected-window)))
 175           (select-window (get-buffer-window (current-buffer) t))
 176           (gnus-summary-position-point)
 177           (gnus-horizontal-recenter)
 178           (select-window selected))))))
 179
 180 (defun gnus-xmas-add-hook (hook function &optional append local)
 181   (add-hook hook function))
 182
 183 (defun gnus-xmas-add-text-properties (start end props &optional object)
 184   (add-text-properties start end props object)
 185   (put-text-property start end 'start-closed nil object))
 186
 187 (defun gnus-xmas-put-text-property (start end prop value &optional object)
 188   (put-text-property start end prop value object)
 189   (put-text-property start end 'start-closed nil object))
 190
 191 (defun gnus-xmas-extent-start-open (point)
 192   (map-extents (lambda (extent arg)
 193                  (set-extent-property extent 'start-open t))
 194                nil point (min (1+ (point)) (point-max))))
 195
 196 (defun gnus-xmas-article-push-button (event)
 197   "Check text under the mouse pointer for a callback function.
 198 If the text under the mouse pointer has a `gnus-callback' property,
 199 call it with the value of the `gnus-data' text property."
 200   (interactive "e")
 201   (set-buffer (window-buffer (event-window event)))
 202   (let* ((pos (event-closest-point event))
 203          (data (get-text-property pos 'gnus-data))
 204          (fun (get-text-property pos 'gnus-callback)))
 205     (when fun
 206       (funcall fun data))))
 207
 208 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 209   (set-extent-endpoints extent start end))
 210
 211 ;; Fixed by Christopher Davis <ckd@loiosh.kei.com>.
 212 (defun gnus-xmas-article-add-button (from to fun &optional data)
 213   "Create a button between FROM and TO with callback FUN and data DATA."
 214   (when gnus-article-button-face
 215     (gnus-overlay-put (gnus-make-overlay from to)
 216                       'face gnus-article-button-face))
 217   (gnus-add-text-properties
 218    from to
 219    (nconc
 220     (and gnus-article-mouse-face
 221          (list 'mouse-face gnus-article-mouse-face))
 222     (list 'gnus-callback fun)
 223     (and data (list 'gnus-data data))
 224     (list 'highlight t))))
 225
 226 (defun gnus-xmas-window-top-edge (&optional window)
 227   (nth 1 (window-pixel-edges window)))
 228
 229 (defun gnus-xmas-tree-minimize ()
 230   (when (and gnus-tree-minimize-window
 231              (not (one-window-p)))
 232     (let* ((window-min-height 2)
 233            (height (1+ (count-lines (point-min) (point-max))))
 234            (min (max (1- window-min-height) height))
 235            (tot (if (numberp gnus-tree-minimize-window)
 236                     (min gnus-tree-minimize-window min)
 237                   min))
 238            (win (get-buffer-window (current-buffer)))
 239            (wh (and win (1- (window-height win)))))
 240       (when (and win
 241                  (not (eq tot wh)))
 242         (let ((selected (selected-window)))
 243           (select-window win)
 244           (enlarge-window (- tot wh))
 245           (select-window selected))))))
 246
 247 ;; Select the lowest window on the frame.
 248 (defun gnus-xmas-appt-select-lowest-window ()
 249   (let* ((lowest-window (selected-window))
 250          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 251          (last-window (previous-window))
 252          (window-search t))
 253     (while window-search
 254       (let* ((this-window (next-window))
 255              (next-bottom-edge (car (cdr (cdr (cdr
 256                                                (window-pixel-edges
 257                                                 this-window)))))))
 258         (when (< bottom-edge next-bottom-edge)
 259           (setq bottom-edge next-bottom-edge)
 260           (setq lowest-window this-window))
 261
 262         (select-window this-window)
 263         (when (eq last-window this-window)
 264           (select-window lowest-window)
 265           (setq window-search nil))))))
 266
 267 (defmacro gnus-xmas-menu-add (type &rest menus)
 268   `(gnus-xmas-menu-add-1 ',type ',menus))
 269 (put 'gnus-xmas-menu-add 'lisp-indent-function 1)
 270
 271 (defun gnus-xmas-menu-add-1 (type menus)
 272   (when (and menu-bar-mode
 273              (gnus-visual-p (intern (format "%s-menu" type)) 'menu))
 274     (while menus
 275       (easy-menu-add (symbol-value (pop menus))))))
 276
 277 (defun gnus-xmas-group-menu-add ()
 278   (gnus-xmas-menu-add group
 279     gnus-group-reading-menu gnus-group-group-menu gnus-group-misc-menu))
 280
 281 (defun gnus-xmas-summary-menu-add ()
 282   (gnus-xmas-menu-add summary
 283     gnus-summary-misc-menu gnus-summary-kill-menu
 284     gnus-summary-article-menu gnus-summary-thread-menu
 285     gnus-summary-post-menu ))
 286
 287 (defun gnus-xmas-article-menu-add ()
 288   (gnus-xmas-menu-add article
 289     gnus-article-article-menu gnus-article-treatment-menu))
 290
 291 (defun gnus-xmas-score-menu-add ()
 292   (gnus-xmas-menu-add score
 293     gnus-score-menu))
 294
 295 (defun gnus-xmas-pick-menu-add ()
 296   (gnus-xmas-menu-add pick
 297     gnus-pick-menu))
 298
 299 (defun gnus-xmas-topic-menu-add ()
 300   (gnus-xmas-menu-add topic
 301     gnus-topic-menu))
 302
 303 (defun gnus-xmas-binary-menu-add ()
 304   (gnus-xmas-menu-add binary
 305     gnus-binary-menu))
 306
 307 (defun gnus-xmas-tree-menu-add ()
 308   (gnus-xmas-menu-add tree
 309     gnus-tree-menu))
 310
 311 (defun gnus-xmas-server-menu-add ()
 312   (gnus-xmas-menu-add menu
 313     gnus-server-server-menu gnus-server-connections-menu))
 314
 315 (defun gnus-xmas-browse-menu-add ()
 316   (gnus-xmas-menu-add browse
 317     gnus-browse-menu))
 318
 319 (defun gnus-xmas-grouplens-menu-add ()
 320   (gnus-xmas-menu-add grouplens
 321     gnus-grouplens-menu))
 322
 323 (defun gnus-xmas-read-event-char ()
 324   "Get the next event."
 325   (let ((event (next-command-event)))
 326     ;; We junk all non-key events.  Is this naughty?
 327     (while (not (key-press-event-p event))
 328       (setq event (next-command-event)))
 329     (cons (and (key-press-event-p event)
 330                (event-to-character event))
 331           event)))
 332
 333 (defun gnus-xmas-group-remove-excess-properties ()
 334   (let ((end (point))
 335         (beg (progn (forward-line -1) (point))))
 336     (remove-text-properties (1+ beg) end '(gnus-group nil))
 337     (remove-text-properties
 338      beg end
 339      '(gnus-topic nil gnus-topic-level nil gnus-topic-visible nil))
 340     (goto-char end)
 341     (map-extents
 342      (lambda (e ma)
 343        (set-extent-property e 'start-closed t))
 344      (current-buffer) beg end)))
 345
 346 (defun gnus-xmas-topic-remove-excess-properties ()
 347   (let ((end (point))
 348         (beg (progn (forward-line -1) (point))))
 349     (remove-text-properties beg end '(gnus-group nil gnus-unread nil))
 350     (remove-text-properties (1+ beg) end '(gnus-topic nil))
 351     (goto-char end)))
 352
 353 (defun gnus-xmas-seconds-since-epoch (date)
 354   "Return a floating point number that says how many seconds have lapsed between Jan 1 12:00:00 1970 and DATE."
 355   (let* ((tdate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 356                         (timezone-parse-date date)))
 357          (ttime (mapcar (lambda (ti) (and ti (string-to-int ti)))
 358                         (timezone-parse-time
 359                          (aref (timezone-parse-date date) 3))))
 360          (edate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 361                         (timezone-parse-date "Jan 1 12:00:00 1970")))
 362          (tday (- (timezone-absolute-from-gregorian
 363                    (nth 1 tdate) (nth 2 tdate) (nth 0 tdate))
 364                   (timezone-absolute-from-gregorian
 365                    (nth 1 edate) (nth 2 edate) (nth 0 edate)))))
 366     (+ (nth 2 ttime)
 367        (* (nth 1 ttime) 60)
 368        (* (float (nth 0 ttime)) 60 60)
 369        (* (float tday) 60 60 24))))
 370
 371 (defun gnus-xmas-define ()
 372   (setq gnus-mouse-2 [button2])
 373
 374   (unless (memq 'underline (face-list))
 375     (and (fboundp 'make-face)
 376          (funcall (intern "make-face") 'underline)))
 377   ;; Must avoid calling set-face-underline-p directly, because it
 378   ;; is a defsubst in emacs19, and will make the .elc files non
 379   ;; portable!
 380   (unless (face-differs-from-default-p 'underline)
 381     (funcall (intern "set-face-underline-p") 'underline t))
 382
 383   (fset 'gnus-make-overlay 'make-extent)
 384   (fset 'gnus-overlay-put 'set-extent-property)
 385   (fset 'gnus-move-overlay 'gnus-xmas-move-overlay)
 386   (fset 'gnus-overlay-end 'extent-end-position)
 387   (fset 'gnus-extent-detached-p 'extent-detached-p)
 388   (fset 'gnus-add-text-properties 'gnus-xmas-add-text-properties)
 389   (fset 'gnus-put-text-property 'gnus-xmas-put-text-property)
 390
 391   (require 'text-props)
 392   (when (< emacs-minor-version 14)
 393     (fset 'gnus-set-text-properties 'gnus-xmas-set-text-properties))
 394
 395   (unless (boundp 'standard-display-table)
 396     (setq standard-display-table nil))
 397
 398   (defvar gnus-mouse-face-prop 'highlight)
 399
 400   (unless (fboundp 'encode-time)
 401     (defun encode-time (sec minute hour day month year &optional zone)
 402       (let ((seconds
 403              (gnus-xmas-seconds-since-epoch
 404               (timezone-make-arpa-date
 405                year month day (timezone-make-time-string hour minute sec)
 406                zone))))
 407         (list (floor (/ seconds (expt 2 16)))
 408               (round (mod seconds (expt 2 16)))))))
 409
 410   (defun gnus-byte-code (func)
 411     "Return a form that can be `eval'ed based on FUNC."
 412     (let ((fval (symbol-function func)))
 413       (if (compiled-function-p fval)
 414           (list 'funcall fval)
 415         (cons 'progn (cdr (cdr fval))))))
 416
 417   (fset 'gnus-x-color-values
 418         (if (fboundp 'x-color-values)
 419             'x-color-values
 420           (lambda (color)
 421             (color-instance-rgb-components
 422              (make-color-instance color))))))
 423
 424
 425 (defun gnus-xmas-redefine ()
 426   "Redefine lots of Gnus functions for XEmacs."
 427   (fset 'gnus-summary-make-display-table 'ignore)
 428   (fset 'gnus-visual-turn-off-edit-menu 'identity)
 429   (fset 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 430   (fset 'gnus-extent-start-open 'gnus-xmas-extent-start-open)
 431   (fset 'gnus-article-push-button 'gnus-xmas-article-push-button)
 432   (fset 'gnus-article-add-button 'gnus-xmas-article-add-button)
 433   (fset 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 434   (fset 'gnus-read-event-char 'gnus-xmas-read-event-char)
 435   (fset 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 436   (fset 'gnus-tree-minimize 'gnus-xmas-tree-minimize)
 437   (fset 'gnus-appt-select-lowest-window
 438         'gnus-xmas-appt-select-lowest-window)
 439   (fset 'gnus-mail-strip-quoted-names 'gnus-xmas-mail-strip-quoted-names)
 440   (fset 'gnus-make-local-hook 'make-local-variable)
 441   (fset 'gnus-add-hook 'gnus-xmas-add-hook)
 442   (fset 'gnus-character-to-event 'character-to-event)
 443   (fset 'gnus-article-show-hidden-text 'gnus-xmas-article-show-hidden-text)
 444   (fset 'gnus-mode-line-buffer-identification
 445         'gnus-xmas-mode-line-buffer-identification)
 446
 447   (add-hook 'gnus-group-mode-hook 'gnus-xmas-group-menu-add)
 448   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-summary-menu-add)
 449   (add-hook 'gnus-article-mode-hook 'gnus-xmas-article-menu-add)
 450   (add-hook 'gnus-score-mode-hook 'gnus-xmas-score-menu-add)
 451
 452   (add-hook 'gnus-pick-mode-hook 'gnus-xmas-pick-menu-add)
 453   (add-hook 'gnus-topic-mode-hook 'gnus-xmas-topic-menu-add)
 454   (add-hook 'gnus-tree-mode-hook 'gnus-xmas-tree-menu-add)
 455   (add-hook 'gnus-binary-mode-hook 'gnus-xmas-binary-menu-add)
 456   (add-hook 'gnus-grouplens-mode-hook 'gnus-xmas-grouplens-menu-add)
 457   (add-hook 'gnus-server-mode-hook 'gnus-xmas-server-menu-add)
 458   (add-hook 'gnus-browse-mode-hook 'gnus-xmas-browse-menu-add)
 459
 460   (add-hook 'gnus-group-mode-hook 'gnus-xmas-setup-group-toolbar)
 461   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-setup-summary-toolbar)
 462
 463   (when (and (<= emacs-major-version 19)
 464              (<= emacs-minor-version 13))
 465     (setq gnus-article-x-face-too-ugly (when (eq (device-type) 'tty)
 466                                          "."))
 467     (fset 'gnus-highlight-selected-summary
 468           'gnus-xmas-highlight-selected-summary)
 469     (fset 'gnus-group-remove-excess-properties
 470           'gnus-xmas-group-remove-excess-properties)
 471     (fset 'gnus-topic-remove-excess-properties
 472           'gnus-xmas-topic-remove-excess-properties)
 473     (fset 'gnus-mode-line-buffer-identification 'identity)
 474     (unless (boundp 'shell-command-switch)
 475       (setq shell-command-switch "-c"))
 476     ))
 477
 478
 479 ;;; XEmacs logo and toolbar.
 480
 481 (defun gnus-xmas-group-startup-message (&optional x y)
 482   "Insert startup message in current buffer."
 483   ;; Insert the message.
 484   (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 485   (erase-buffer)
 486   (let ((logo (and gnus-xmas-glyph-directory
 487                    (concat
 488                     (file-name-as-directory gnus-xmas-glyph-directory)
 489                     "gnus."
 490                     (if (featurep 'xpm) "xpm" "xbm"))))
 491         (xpm-color-symbols
 492          (and (featurep 'xpm)
 493               (append `(("thing" ,(car gnus-xmas-logo-colors))
 494                         ("shadow" ,(cadr gnus-xmas-logo-colors)))
 495                       xpm-color-symbols))))
 496     (if (and (featurep 'xpm)
 497              (not (equal (device-type) 'tty))
 498              logo
 499              (file-exists-p logo))
 500         (progn
 501           (setq logo (make-glyph logo))
 502           (insert " ")
 503           (set-extent-begin-glyph (make-extent (point) (point)) logo)
 504           (goto-char (point-min))
 505           (while (not (eobp))
 506             (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 507                                  ? ))
 508             (forward-line 1))
 509           (goto-char (point-min))
 510           (let* ((pheight (+ 20 (count-lines (point-min) (point-max))))
 511                  (wheight (window-height))
 512                  (rest (- wheight pheight)))
 513             (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 514
 515       (insert
 516        (format "              %s
 517           _    ___ _             _
 518           _ ___ __ ___  __    _ ___
 519           __   _     ___    __  ___
 520               _           ___     _
 521              _  _ __             _
 522              ___   __            _
 523                    __           _
 524                     _      _   _
 525                    _      _    _
 526                       _  _    _
 527                   __  ___
 528                  _   _ _     _
 529                 _   _
 530               _    _
 531              _    _
 532             _
 533           __
 534
 535 "
 536                ""))
 537       ;; And then hack it.
 538       (gnus-indent-rigidly (point-min) (point-max)
 539                            (/ (max (- (window-width) (or x 46)) 0) 2))
 540       (goto-char (point-min))
 541       (forward-line 1)
 542       (let* ((pheight (count-lines (point-min) (point-max)))
 543              (wheight (window-height))
 544              (rest (- wheight pheight)))
 545         (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 546     ;; Fontify some.
 547     (goto-char (point-min))
 548     (put-text-property (point-min) (point-max) 'face 'gnus-splash-face)
 549     (goto-char (point-min))
 550     (setq modeline-buffer-identification
 551           (list (concat gnus-version ": *Group*")))
 552     (set-buffer-modified-p t)))
 553
 554
 555 ;;; The toolbar.
 556
 557 (defvar gnus-use-toolbar (if (featurep 'toolbar)
 558                              'default-toolbar
 559                            nil)
 560   "*If nil, do not use a toolbar.
 561 If it is non-nil, it must be a toolbar.  The five legal values are
 562 `default-toolbar', `top-toolbar', `bottom-toolbar',
 563 `right-toolbar', and `left-toolbar'.")
 564
 565 (defvar gnus-group-toolbar
 566   '([gnus-group-get-new-news gnus-group-get-new-news t "Get new news"]
 567     [gnus-group-get-new-news-this-group
 568      gnus-group-get-new-news-this-group t "Get new news in this group"]
 569     [gnus-group-catchup-current
 570      gnus-group-catchup-current t "Catchup group"]
 571     [gnus-group-describe-group
 572      gnus-group-describe-group t "Describe group"]
 573     [gnus-group-unsubscribe gnus-group-unsubscribe t "Unsubscribe group"]
 574     [gnus-group-subscribe gnus-group-subscribe t "Subscribe group"]
 575     [gnus-group-kill-group gnus-group-kill-group t "Kill group"]
 576     [gnus-group-exit gnus-group-exit t "Exit Gnus"]
 577     )
 578   "The group buffer toolbar.")
 579
 580 (defvar gnus-summary-toolbar
 581   '([gnus-summary-prev-unread
 582      gnus-summary-prev-unread-article t "Prev unread article"]
 583     [gnus-summary-next-unread
 584      gnus-summary-next-unread-article t "Next unread article"]
 585     [gnus-summary-post-news
 586      gnus-summary-post-news t "Post an article"]
 587     [gnus-summary-followup-with-original
 588      gnus-summary-followup-with-original t
 589      "Post a followup and yank the original"]
 590     [gnus-summary-followup
 591      gnus-summary-followup t "Post a followup"]
 592     [gnus-summary-reply-with-original
 593      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 594     [gnus-summary-reply
 595      gnus-summary-reply t "Mail a reply"]
 596     [gnus-summary-caesar-message
 597      gnus-summary-caesar-message t "Rot 13"]
 598     [gnus-uu-decode-uu
 599      gnus-uu-decode-uu t "Decode uuencoded articles"]
 600     [gnus-summary-save-article-file
 601      gnus-summary-save-article-file t "Save article in file"]
 602     [gnus-summary-save-article
 603      gnus-summary-save-article t "Save article"]
 604     [gnus-uu-post-news
 605      gnus-uu-post-news t "Post an uuencoded article"]
 606     [gnus-summary-cancel-article
 607      gnus-summary-cancel-article t "Cancel article"]
 608     [gnus-summary-catchup
 609      gnus-summary-catchup t "Catchup"]
 610     [gnus-summary-catchup-and-exit
 611      gnus-summary-catchup-and-exit t "Catchup and exit"]
 612     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 613     )
 614   "The summary buffer toolbar.")
 615
 616 (defvar gnus-summary-mail-toolbar
 617   '(
 618     [gnus-summary-prev-unread
 619      gnus-summary-prev-unread-article t "Prev unread article"]
 620     [gnus-summary-next-unread
 621      gnus-summary-next-unread-article t "Next unread article"]
 622     [gnus-summary-mail-reply gnus-summary-reply t "Reply"]
 623 ;    [gnus-summary-mail-get gnus-mail-get t "Message get"]
 624     [gnus-summary-mail-originate gnus-summary-post-news t "Originate"]
 625     [gnus-summary-mail-save gnus-summary-save-article t "Save"]
 626     [gnus-summary-mail-copy gnus-summary-copy-article t "Copy message"]
 627 ;    [gnus-summary-mail-delete gnus-summary-delete-article t "Delete message"]
 628     [gnus-summary-mail-forward gnus-summary-mail-forward t "Forward message"]
 629 ;    [gnus-summary-mail-spell gnus-mail-spell t "Spell"]
 630 ;    [gnus-summary-mail-help gnus-mail-help  t "Message help"]
 631     [gnus-summary-caesar-message
 632      gnus-summary-caesar-message t "Rot 13"]
 633     [gnus-uu-decode-uu
 634      gnus-uu-decode-uu t "Decode uuencoded articles"]
 635     [gnus-summary-save-article-file
 636      gnus-summary-save-article-file t "Save article in file"]
 637     [gnus-summary-save-article
 638      gnus-summary-save-article t "Save article"]
 639     [gnus-summary-catchup-and-exit
 640      gnus-summary-catchup-and-exit t "Catchup and exit"]
 641     [gnus-summary-catchup
 642      gnus-summary-catchup t "Catchup"]
 643     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 644     )
 645   "The summary buffer mail toolbar.")
 646
 647 (defun gnus-xmas-setup-group-toolbar ()
 648   (and gnus-use-toolbar
 649        (message-xmas-setup-toolbar gnus-group-toolbar nil "gnus")
 650        (set-specifier (symbol-value gnus-use-toolbar)
 651                       (cons (current-buffer) gnus-group-toolbar))))
 652
 653 (defun gnus-xmas-setup-summary-toolbar ()
 654   (let ((bar (if (gnus-news-group-p gnus-newsgroup-name)
 655                  gnus-summary-toolbar gnus-summary-mail-toolbar)))
 656     (and gnus-use-toolbar
 657          (message-xmas-setup-toolbar bar nil "gnus")
 658          (set-specifier (symbol-value gnus-use-toolbar)
 659                         (cons (current-buffer) bar)))))
 660
 661 (defun gnus-xmas-mail-strip-quoted-names (address)
 662   "Protect mail-strip-quoted-names from NIL input.
 663 XEmacs compatibility workaround."
 664   (if (null address)
 665       nil
 666     (mail-strip-quoted-names address)))
 667
 668 (defun gnus-xmas-call-region (command &rest args)
 669   (apply
 670    'call-process-region (point-min) (point-max) command t '(t nil) nil
 671    args))
 672
 673 (unless (find-face 'gnus-x-face)
 674   (copy-face 'default 'gnus-x-face)
 675   (set-face-foreground 'gnus-x-face "black")
 676   (set-face-background 'gnus-x-face "white"))
 677
 678 (defun gnus-xmas-article-display-xface (beg end)
 679   "Display any XFace headers in the current article."
 680   (save-excursion
 681     (let (xface-glyph)
 682       (if (featurep 'xface)
 683           (setq xface-glyph
 684                 (make-glyph (vector 'xface :data
 685                                     (concat "X-Face: "
 686                                             (buffer-substring beg end)))))
 687         (let ((cur (current-buffer)))
 688           (save-excursion
 689             (gnus-set-work-buffer)
 690             (insert (format "%s" (buffer-substring beg end cur)))
 691             (gnus-xmas-call-region "uncompface")
 692             (goto-char (point-min))
 693             (insert "/* Width=48, Height=48 */\n")
 694             (gnus-xmas-call-region "icontopbm")
 695             (gnus-xmas-call-region "ppmtoxpm")
 696             (setq xface-glyph
 697                   (make-glyph
 698                    (vector 'xpm :data (buffer-string )))))))
 699       (set-glyph-face xface-glyph 'gnus-x-face)
 700       (goto-char (point-min))
 701       (re-search-forward "^From:" nil t)
 702       (set-extent-begin-glyph
 703        (make-extent (point) (1+ (point))) xface-glyph))))
 704
 705 (defun gnus-xmas-article-show-hidden-text (type &optional hide)
 706   "Show all hidden text of type TYPE.
 707 If HIDE, hide the text instead."
 708   (save-excursion
 709     (set-buffer gnus-article-buffer)
 710     (let ((buffer-read-only nil)
 711           (inhibit-point-motion-hooks t)
 712           (beg (point-min)))
 713       (while (gnus-goto-char (text-property-any
 714                               beg (point-max) 'gnus-type type))
 715         (setq beg (point))
 716         (forward-char)
 717         (if hide
 718             (article-hide-text beg (point) gnus-hidden-properties)
 719           (article-unhide-text beg (point)))
 720         (setq beg (point)))
 721       (save-window-excursion
 722         (select-window (get-buffer-window (current-buffer)))
 723         (recenter))
 724       t)))
 725
 726 (defvar gnus-xmas-pointer-glyph
 727   (progn
 728     (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 729     (make-pointer-glyph (concat gnus-xmas-glyph-directory "gnus-pointer."
 730                                 (if (featurep 'xpm) "xpm" "xbm")))))
 731
 732 (defvar gnus-xmas-modeline-left-extent
 733   (let ((ext (copy-extent modeline-buffer-id-left-extent)))
 734     ;(set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 735     ext))
 736
 737 (defvar gnus-xmas-modeline-right-extent
 738   (let ((ext (copy-extent modeline-buffer-id-right-extent)))
 739     ;(set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 740     ext))
 741
 742 (defvar gnus-xmas-modeline-glyph
 743   (progn
 744     (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 745     (let* ((file (concat gnus-xmas-glyph-directory "gnus-pointer."
 746                          (if (featurep 'xpm) "xpm" "xbm")))
 747            (glyph (make-glyph file)))
 748       (when (and (featurep 'x)
 749                  (file-exists-p file))
 750         (set-glyph-face glyph 'modeline-buffer-id))
 751       (set-glyph-property glyph 'image (cons 'tty "Gnus:"))
 752       glyph)))
 753
 754 (defun gnus-xmas-mode-line-buffer-identification (line)
 755   (let ((line (car line))
 756         chop)
 757     (if (not (stringp line))
 758         (list line)
 759       (when (string-match "^Gnus:" line)
 760         (setq chop (match-end 0))
 761         (list
 762          (if gnus-xmas-modeline-glyph
 763              (cons gnus-xmas-modeline-left-extent gnus-xmas-modeline-glyph)
 764            (cons gnus-xmas-modeline-left-extent (substring line 0 chop)))
 765          (cons gnus-xmas-modeline-right-extent (substring line chop)))))))
 766
 767 (defun gnus-xmas-splash ()
 768   (when (eq (device-type) 'x)
 769     (gnus-splash)))
 770
 771 (provide 'gnus-xmas)
 772
 773 ;;; gnus-xmas.el ends here