cgit.sxemacs.org Git - gnus/blob - lisp/gnus-uu.el

   1 ;;; gnus-uu.el --- extract (uu)encoded files in Gnus
   2 ;; Copyright (C) 1985,86,87,93,94,95,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Created: 2 Oct 1993
   6 ;; Keyword: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-art)
  33 (require 'message)
  34 (require 'gnus-msg)
  35 (require 'mm-decode)
  36
  37 (defgroup gnus-extract nil
  38   "Extracting encoded files."
  39   :prefix "gnus-uu-"
  40   :group 'gnus)
  41
  42 (defgroup gnus-extract-view nil
  43   "Viewwing extracted files."
  44   :group 'gnus-extract)
  45
  46 (defgroup gnus-extract-archive nil
  47   "Extracting encoded archives."
  48   :group 'gnus-extract)
  49
  50 (defgroup gnus-extract-post nil
  51   "Extracting encoded archives."
  52   :prefix "gnus-uu-post"
  53   :group 'gnus-extract)
  54
  55 ;; Default viewing action rules
  56
  57 (defcustom gnus-uu-default-view-rules
  58   '(("\\.te?xt$\\|\\.doc$\\|read.*me\\|\\.c?$\\|\\.h$\\|\\.bat$\\|\\.asm$\\|makefile" "cat %s | sed 's/\r$//'")
  59     ("\\.pas$" "cat %s | sed 's/\r$//'")
  60     ("\\.[1-9]$" "groff -mandoc -Tascii %s | sed s/\b.//g")
  61     ("\\.\\(jpe?g\\|gif\\|tiff?\\|p[pgb]m\\|xwd\\|xbm\\|pcx\\)$" "xv")
  62     ("\\.tga$" "tgatoppm %s | xv -")
  63     ("\\.\\(wav\\|aiff\\|hcom\\|u[blw]\\|s[bfw]\\|voc\\|smp\\)$"
  64      "sox -v .5 %s -t .au -u - > /dev/audio")
  65     ("\\.au$" "cat %s > /dev/audio")
  66     ("\\.midi?$" "playmidi -f")
  67     ("\\.mod$" "str32")
  68     ("\\.ps$" "ghostview")
  69     ("\\.dvi$" "xdvi")
  70     ("\\.html$" "xmosaic")
  71     ("\\.mpe?g$" "mpeg_play")
  72     ("\\.\\(flc\\|fli\\|rle\\|iff\\|pfx\\|avi\\|sme\\|rpza\\|dl\\|qt\\|rsrc\\|mov\\)$" "xanim")
  73     ("\\.\\(tar\\|arj\\|zip\\|zoo\\|arc\\|gz\\|Z\\|lzh\\|ar\\|lha\\)$"
  74      "gnus-uu-archive"))
  75   "*Default actions to be taken when the user asks to view a file.
  76 To change the behaviour, you can either edit this variable or set
  77 `gnus-uu-user-view-rules' to something useful.
  78
  79 For example:
  80
  81 To make gnus-uu use 'xli' to display JPEG and GIF files, put the
  82 following in your .emacs file:
  83
  84   (setq gnus-uu-user-view-rules '((\"jpg$\\\\|gif$\" \"xli\")))
  85
  86 Both these variables are lists of lists with two string elements.  The
  87 first string is a regular expression.  If the file name matches this
  88 regular expression, the command in the second string is executed with
  89 the file as an argument.
  90
  91 If the command string contains \"%s\", the file name will be inserted
  92 at that point in the command string.  If there's no \"%s\" in the
  93 command string, the file name will be appended to the command string
  94 before executing.
  95
  96 There are several user variables to tailor the behaviour of gnus-uu to
  97 your needs.  First we have `gnus-uu-user-view-rules', which is the
  98 variable gnus-uu first consults when trying to decide how to view a
  99 file.  If this variable contains no matches, gnus-uu examines the
 100 default rule variable provided in this package.  If gnus-uu finds no
 101 match here, it uses `gnus-uu-user-view-rules-end' to try to make a
 102 match."
 103   :group 'gnus-extract-view
 104   :type '(repeat (group regexp (string :tag "Command"))))
 105
 106 (defcustom gnus-uu-user-view-rules nil
 107   "What actions are to be taken to view a file.
 108 See the documentation on the `gnus-uu-default-view-rules' variable for
 109 details."
 110   :group 'gnus-extract-view
 111   :type '(repeat (group regexp (string :tag "Command"))))
 112
 113 (defcustom gnus-uu-user-view-rules-end
 114   '(("" "file"))
 115   "*What actions are to be taken if no rule matched the file name.
 116 See the documentation on the `gnus-uu-default-view-rules' variable for
 117 details."
 118   :group 'gnus-extract-view
 119   :type '(repeat (group regexp (string :tag "Command"))))
 120
 121 ;; Default unpacking commands
 122
 123 (defcustom gnus-uu-default-archive-rules
 124   '(("\\.tar$" "tar xf")
 125     ("\\.zip$" "unzip -o")
 126     ("\\.ar$" "ar x")
 127     ("\\.arj$" "unarj x")
 128     ("\\.zoo$" "zoo -e")
 129     ("\\.\\(lzh\\|lha\\)$" "lha x")
 130     ("\\.Z$" "uncompress")
 131     ("\\.gz$" "gunzip")
 132     ("\\.arc$" "arc -x"))
 133   "*See `gnus-uu-user-archive-rules'."
 134   :group 'gnus-extract-archive
 135   :type '(repeat (group regexp (string :tag "Command"))))
 136
 137 (defvar gnus-uu-destructive-archivers
 138   (list "uncompress" "gunzip"))
 139
 140 (defcustom gnus-uu-user-archive-rules nil
 141   "A list that can be set to override the default archive unpacking commands.
 142 To use, for instance, 'untar' to unpack tar files and 'zip -x' to
 143 unpack zip files, say the following:
 144   (setq gnus-uu-user-archive-rules
 145     '((\"\\\\.tar$\" \"untar\")
 146       (\"\\\\.zip$\" \"zip -x\")))"
 147   :group 'gnus-extract-archive
 148   :type '(repeat (group regexp (string :tag "Command"))))
 149
 150 (defcustom gnus-uu-ignore-files-by-name nil
 151   "*A regular expression saying what files should not be viewed based on name.
 152 If, for instance, you want gnus-uu to ignore all .au and .wav files,
 153 you could say something like
 154
 155   (setq gnus-uu-ignore-files-by-name \"\\\\.au$\\\\|\\\\.wav$\")
 156
 157 Note that this variable can be used in conjunction with the
 158 `gnus-uu-ignore-files-by-type' variable."
 159   :group 'gnus-extract
 160   :type '(choice (const :tag "off" nil)
 161                  (regexp :format "%v")))
 162
 163 (defcustom gnus-uu-ignore-files-by-type nil
 164   "*A regular expression saying what files that shouldn't be viewed, based on MIME file type.
 165 If, for instance, you want gnus-uu to ignore all audio files and all mpegs,
 166 you could say something like
 167
 168   (setq gnus-uu-ignore-files-by-type \"audio/\\\\|video/mpeg\")
 169
 170 Note that this variable can be used in conjunction with the
 171 `gnus-uu-ignore-files-by-name' variable."
 172   :group 'gnus-extract
 173   :type '(choice (const :tag "off" nil)
 174                  (regexp :format "%v")))
 175
 176 ;; Pseudo-MIME support
 177
 178 (defconst gnus-uu-ext-to-mime-list
 179   '(("\\.gif$" "image/gif")
 180     ("\\.jpe?g$" "image/jpeg")
 181     ("\\.tiff?$" "image/tiff")
 182     ("\\.xwd$" "image/xwd")
 183     ("\\.pbm$" "image/pbm")
 184     ("\\.pgm$" "image/pgm")
 185     ("\\.ppm$" "image/ppm")
 186     ("\\.xbm$" "image/xbm")
 187     ("\\.pcx$" "image/pcx")
 188     ("\\.tga$" "image/tga")
 189     ("\\.ps$" "image/postscript")
 190     ("\\.fli$" "video/fli")
 191     ("\\.wav$" "audio/wav")
 192     ("\\.aiff$" "audio/aiff")
 193     ("\\.hcom$" "audio/hcom")
 194     ("\\.voc$" "audio/voc")
 195     ("\\.smp$" "audio/smp")
 196     ("\\.mod$" "audio/mod")
 197     ("\\.dvi$" "image/dvi")
 198     ("\\.mpe?g$" "video/mpeg")
 199     ("\\.au$" "audio/basic")
 200     ("\\.\\(te?xt\\|doc\\|c\\|h\\)$" "text/plain")
 201     ("\\.\\(c\\|h\\)$" "text/source")
 202     ("read.*me" "text/plain")
 203     ("\\.html$" "text/html")
 204     ("\\.bat$" "text/bat")
 205     ("\\.[1-6]$" "text/man")
 206     ("\\.flc$" "video/flc")
 207     ("\\.rle$" "video/rle")
 208     ("\\.pfx$" "video/pfx")
 209     ("\\.avi$" "video/avi")
 210     ("\\.sme$" "video/sme")
 211     ("\\.rpza$" "video/prza")
 212     ("\\.dl$" "video/dl")
 213     ("\\.qt$" "video/qt")
 214     ("\\.rsrc$" "video/rsrc")
 215     ("\\..*$" "unknown/unknown")))
 216
 217 ;; Various variables users may set
 218
 219 (defcustom gnus-uu-tmp-dir
 220   (cond ((fboundp 'temp-directory) (temp-directory))
 221         ((boundp 'temporary-file-directory) temporary-file-directory)
 222         ("/tmp/"))
 223   "*Variable saying where gnus-uu is to do its work.
 224 Default is \"/tmp/\"."
 225   :group 'gnus-extract
 226   :type 'directory)
 227
 228 (defcustom gnus-uu-do-not-unpack-archives nil
 229   "*Non-nil means that gnus-uu won't peek inside archives looking for files to display.
 230 Default is nil."
 231   :group 'gnus-extract-archive
 232   :type 'boolean)
 233
 234 (defcustom gnus-uu-ignore-default-view-rules nil
 235   "*Non-nil means that gnus-uu will ignore the default viewing rules.
 236 Only the user viewing rules will be consulted.  Default is nil."
 237   :group 'gnus-extract-view
 238   :type 'boolean)
 239
 240 (defcustom gnus-uu-grabbed-file-functions nil
 241   "Functions run on each file after successful decoding.
 242 They will be called with the name of the file as the argument.
 243 Likely functions you can use in this list are `gnus-uu-grab-view'
 244 and `gnus-uu-grab-move'."
 245   :group 'gnus-extract
 246   :options '(gnus-uu-grab-view gnus-uu-grab-move)
 247   :type 'hook)
 248
 249 (defcustom gnus-uu-ignore-default-archive-rules nil
 250   "*Non-nil means that gnus-uu will ignore the default archive unpacking commands.
 251 Only the user unpacking commands will be consulted.  Default is nil."
 252   :group 'gnus-extract-archive
 253   :type 'boolean)
 254
 255 (defcustom gnus-uu-kill-carriage-return t
 256   "*Non-nil means that gnus-uu will strip all carriage returns from articles.
 257 Default is t."
 258   :group 'gnus-extract
 259   :type 'boolean)
 260
 261 (defcustom gnus-uu-view-with-metamail nil
 262   "*Non-nil means that files will be viewed with metamail.
 263 The gnus-uu viewing functions will be ignored and gnus-uu will try
 264 to guess at a content-type based on file name suffixes.  Default
 265 it nil."
 266   :group 'gnus-extract
 267   :type 'boolean)
 268
 269 (defcustom gnus-uu-unmark-articles-not-decoded nil
 270   "*Non-nil means that gnus-uu will mark articles that were unsuccessfully decoded as unread.
 271 Default is nil."
 272   :group 'gnus-extract
 273   :type 'boolean)
 274
 275 (defcustom gnus-uu-correct-stripped-uucode nil
 276   "*Non-nil means that gnus-uu will *try* to fix uuencoded files that have had trailing spaces deleted.
 277 Default is nil."
 278   :group 'gnus-extract
 279   :type 'boolean)
 280
 281 (defcustom gnus-uu-save-in-digest nil
 282   "*Non-nil means that gnus-uu, when asked to save without decoding, will save in digests.
 283 If this variable is nil, gnus-uu will just save everything in a
 284 file without any embellishments.  The digesting almost conforms to RFC1153 -
 285 no easy way to specify any meaningful volume and issue numbers were found,
 286 so I simply dropped them."
 287   :group 'gnus-extract
 288   :type 'boolean)
 289
 290 (defcustom gnus-uu-pre-uudecode-hook nil
 291   "Hook run before sending a message to uudecode."
 292   :group 'gnus-extract
 293   :type 'hook)
 294
 295 (defcustom gnus-uu-digest-headers
 296   '("^Date:" "^From:" "^To:" "^Cc:" "^Subject:" "^Message-ID:" "^Keywords:"
 297     "^Summary:" "^References:" "^Content-Type:" "^Content-Transfer-Encoding:")
 298   "*List of regexps to match headers included in digested messages.
 299 The headers will be included in the sequence they are matched."
 300   :group 'gnus-extract
 301   :type '(repeat regexp))
 302
 303 (defcustom gnus-uu-save-separate-articles nil
 304   "*Non-nil means that gnus-uu will save articles in separate files."
 305   :group 'gnus-extract
 306   :type 'boolean)
 307
 308 (defcustom gnus-uu-be-dangerous 'ask
 309   "*Specifies what to do if unusual situations arise during decoding.
 310 If nil, be as conservative as possible.  If t, ignore things that
 311 didn't work, and overwrite existing files.  Otherwise, ask each time."
 312   :group 'gnus-extract
 313   :type '(choice (const :tag "conservative" nil)
 314                  (const :tag "ask" ask)
 315                  (const :tag "liberal" t)))
 316
 317 ;; Internal variables
 318
 319 (defvar gnus-uu-saved-article-name nil)
 320
 321 (defvar gnus-uu-begin-string "^begin[ \t]+[0-7][0-7][0-7][ \t]+\\(.*\\)$")
 322 (defvar gnus-uu-end-string "^end[ \t]*$")
 323
 324 (defvar gnus-uu-body-line "^M")
 325 (let ((i 61))
 326   (while (> (setq i (1- i)) 0)
 327     (setq gnus-uu-body-line (concat gnus-uu-body-line "[^a-z]")))
 328   (setq gnus-uu-body-line (concat gnus-uu-body-line ".?$")))
 329
 330 ;"^M.............................................................?$"
 331
 332 (defvar gnus-uu-shar-begin-string "^#! */bin/sh")
 333
 334 (defvar gnus-uu-shar-file-name nil)
 335 (defvar gnus-uu-shar-name-marker "begin [0-7][0-7][0-7][ \t]+\\(\\(\\w\\|\\.\\)*\\b\\)")
 336
 337 (defvar gnus-uu-postscript-begin-string "^%!PS-")
 338 (defvar gnus-uu-postscript-end-string "^%%EOF$")
 339
 340 (defvar gnus-uu-file-name nil)
 341 (defvar gnus-uu-uudecode-process nil)
 342 (defvar gnus-uu-binhex-article-name nil)
 343
 344 (defvar gnus-uu-work-dir nil)
 345
 346 (defvar gnus-uu-output-buffer-name " *Gnus UU Output*")
 347
 348 (defvar gnus-uu-default-dir gnus-article-save-directory)
 349 (defvar gnus-uu-digest-from-subject nil)
 350
 351 ;; Keymaps
 352
 353 (gnus-define-keys (gnus-uu-mark-map "P" gnus-summary-mark-map)
 354   "p" gnus-summary-mark-as-processable
 355   "u" gnus-summary-unmark-as-processable
 356   "U" gnus-summary-unmark-all-processable
 357   "v" gnus-uu-mark-over
 358   "s" gnus-uu-mark-series
 359   "r" gnus-uu-mark-region
 360   "g" gnus-uu-unmark-region
 361   "R" gnus-uu-mark-by-regexp
 362   "G" gnus-uu-unmark-by-regexp
 363   "t" gnus-uu-mark-thread
 364   "T" gnus-uu-unmark-thread
 365   "a" gnus-uu-mark-all
 366   "b" gnus-uu-mark-buffer
 367   "S" gnus-uu-mark-sparse
 368   "k" gnus-summary-kill-process-mark
 369   "y" gnus-summary-yank-process-mark
 370   "w" gnus-summary-save-process-mark
 371   "i" gnus-uu-invert-processable)
 372
 373 (gnus-define-keys (gnus-uu-extract-map "X" gnus-summary-mode-map)
 374   ;;"x" gnus-uu-extract-any
 375   ;;"m" gnus-uu-extract-mime
 376   "u" gnus-uu-decode-uu
 377   "U" gnus-uu-decode-uu-and-save
 378   "s" gnus-uu-decode-unshar
 379   "S" gnus-uu-decode-unshar-and-save
 380   "o" gnus-uu-decode-save
 381   "O" gnus-uu-decode-save
 382   "b" gnus-uu-decode-binhex
 383   "B" gnus-uu-decode-binhex
 384   "p" gnus-uu-decode-postscript
 385   "P" gnus-uu-decode-postscript-and-save)
 386
 387 (gnus-define-keys
 388  (gnus-uu-extract-view-map "v" gnus-uu-extract-map)
 389  "u" gnus-uu-decode-uu-view
 390  "U" gnus-uu-decode-uu-and-save-view
 391  "s" gnus-uu-decode-unshar-view
 392  "S" gnus-uu-decode-unshar-and-save-view
 393  "o" gnus-uu-decode-save-view
 394  "O" gnus-uu-decode-save-view
 395  "b" gnus-uu-decode-binhex-view
 396  "B" gnus-uu-decode-binhex-view
 397  "p" gnus-uu-decode-postscript-view
 398  "P" gnus-uu-decode-postscript-and-save-view)
 399
 400
 401 ;; Commands.
 402
 403 (defun gnus-uu-decode-uu (&optional n)
 404   "Uudecodes the current article."
 405   (interactive "P")
 406   (gnus-uu-decode-with-method 'gnus-uu-uustrip-article n))
 407
 408 (defun gnus-uu-decode-uu-and-save (n dir)
 409   "Decodes and saves the resulting file."
 410   (interactive
 411    (list current-prefix-arg
 412          (file-name-as-directory
 413           (read-file-name "Uudecode and save in dir: "
 414                           gnus-uu-default-dir
 415                           gnus-uu-default-dir t))))
 416   (gnus-uu-decode-with-method 'gnus-uu-uustrip-article n dir nil nil t))
 417
 418 (defun gnus-uu-decode-unshar (&optional n)
 419   "Unshars the current article."
 420   (interactive "P")
 421   (gnus-uu-decode-with-method 'gnus-uu-unshar-article n nil nil 'scan t))
 422
 423 (defun gnus-uu-decode-unshar-and-save (n dir)
 424   "Unshars and saves the current article."
 425   (interactive
 426    (list current-prefix-arg
 427          (file-name-as-directory
 428           (read-file-name "Unshar and save in dir: "
 429                           gnus-uu-default-dir
 430                           gnus-uu-default-dir t))))
 431   (gnus-uu-decode-with-method 'gnus-uu-unshar-article n dir nil 'scan t))
 432
 433 (defun gnus-uu-decode-save (n file)
 434   "Saves the current article."
 435   (interactive
 436    (list current-prefix-arg
 437          (read-file-name
 438           (if gnus-uu-save-separate-articles
 439               "Save articles is dir: "
 440             "Save articles in file: ")
 441           gnus-uu-default-dir
 442           gnus-uu-default-dir)))
 443   (setq gnus-uu-saved-article-name file)
 444   (gnus-uu-decode-with-method 'gnus-uu-save-article n nil t))
 445
 446 (defun gnus-uu-decode-binhex (n dir)
 447   "Unbinhexes the current article."
 448   (interactive
 449    (list current-prefix-arg
 450          (file-name-as-directory
 451           (read-file-name "Unbinhex and save in dir: "
 452                           gnus-uu-default-dir
 453                           gnus-uu-default-dir))))
 454   (setq gnus-uu-binhex-article-name
 455         (make-temp-name (concat gnus-uu-work-dir "binhex")))
 456   (gnus-uu-decode-with-method 'gnus-uu-binhex-article n dir))
 457
 458 (defun gnus-uu-decode-uu-view (&optional n)
 459   "Uudecodes and views the current article."
 460   (interactive "P")
 461   (let ((gnus-view-pseudos (or gnus-view-pseudos 'automatic)))
 462     (gnus-uu-decode-uu n)))
 463
 464 (defun gnus-uu-decode-uu-and-save-view (n dir)
 465   "Decodes, views and saves the resulting file."
 466   (interactive
 467    (list current-prefix-arg
 468          (read-file-name "Uudecode, view and save in dir: "
 469                          gnus-uu-default-dir
 470                          gnus-uu-default-dir t)))
 471   (let ((gnus-view-pseudos (or gnus-view-pseudos 'automatic)))
 472     (gnus-uu-decode-uu-and-save n dir)))
 473
 474 (defun gnus-uu-decode-unshar-view (&optional n)
 475   "Unshars and views the current article."
 476   (interactive "P")
 477   (let ((gnus-view-pseudos (or gnus-view-pseudos 'automatic)))
 478     (gnus-uu-decode-unshar n)))
 479
 480 (defun gnus-uu-decode-unshar-and-save-view (n dir)
 481   "Unshars and saves the current article."
 482   (interactive
 483    (list current-prefix-arg
 484          (read-file-name "Unshar, view and save in dir: "
 485                          gnus-uu-default-dir
 486                          gnus-uu-default-dir t)))
 487   (let ((gnus-view-pseudos (or gnus-view-pseudos 'automatic)))
 488     (gnus-uu-decode-unshar-and-save n dir)))
 489
 490 (defun gnus-uu-decode-save-view (n file)
 491   "Saves and views the current article."
 492   (interactive
 493    (list current-prefix-arg
 494          (read-file-name  (if gnus-uu-save-separate-articles
 495                               "Save articles is dir: "
 496                             "Save articles in file: ")
 497                           gnus-uu-default-dir gnus-uu-default-dir)))
 498   (let ((gnus-view-pseudos (or gnus-view-pseudos 'automatic)))
 499     (gnus-uu-decode-save n file)))
 500
 501 (defun gnus-uu-decode-binhex-view (n file)
 502   "Unbinhexes and views the current article."
 503   (interactive
 504    (list current-prefix-arg
 505          (read-file-name "Unbinhex, view and save in dir: "
 506                          gnus-uu-default-dir gnus-uu-default-dir)))
 507   (setq gnus-uu-binhex-article-name
 508         (make-temp-name (concat gnus-uu-work-dir "binhex")))
 509   (let ((gnus-view-pseudos (or gnus-view-pseudos 'automatic)))
 510     (gnus-uu-decode-binhex n file)))
 511
 512
 513 ;; Digest and forward articles
 514
 515 (defun gnus-uu-digest-mail-forward (&optional n post)
 516   "Digests and forwards all articles in this series."
 517   (interactive "P")
 518   (let ((gnus-uu-save-in-digest t)
 519         (file (make-temp-name (nnheader-concat gnus-uu-tmp-dir "forward")))
 520         buf subject from)
 521     (gnus-setup-message 'forward
 522       (setq gnus-uu-digest-from-subject nil)
 523       (gnus-uu-decode-save n file)
 524       (setq buf (switch-to-buffer
 525                  (gnus-get-buffer-create " *gnus-uu-forward*")))
 526       (erase-buffer)
 527       (insert-file file)
 528       (let ((fs gnus-uu-digest-from-subject))
 529         (when fs
 530           (setq from (caar fs)
 531                 subject (gnus-simplify-subject-fuzzy (cdar fs))
 532                 fs (cdr fs))
 533           (while (and fs (or from subject))
 534             (when from
 535               (unless (string= from (caar fs))
 536                 (setq from nil)))
 537             (when subject
 538               (unless (string= (gnus-simplify-subject-fuzzy (cdar fs))
 539                                subject)
 540                 (setq subject nil)))
 541             (setq fs (cdr fs))))
 542         (unless subject
 543           (setq subject "Digested Articles"))
 544         (unless from
 545           (setq from
 546                 (if (gnus-news-group-p gnus-newsgroup-name)
 547                     gnus-newsgroup-name
 548                   "Various"))))
 549       (goto-char (point-min))
 550       (when (re-search-forward "^Subject: ")
 551         (delete-region (point) (gnus-point-at-eol))
 552         (insert subject))
 553       (goto-char (point-min))
 554       (when (re-search-forward "^From: ")
 555         (delete-region (point) (gnus-point-at-eol))
 556         (insert from))
 557       (message-forward post))
 558     (delete-file file)
 559     (kill-buffer buf)
 560     (setq gnus-uu-digest-from-subject nil)))
 561
 562 (defun gnus-uu-digest-post-forward (&optional n)
 563   "Digest and forward to a newsgroup."
 564   (interactive "P")
 565   (gnus-uu-digest-mail-forward n t))
 566
 567 ;; Process marking.
 568
 569 (defun gnus-uu-mark-by-regexp (regexp &optional unmark)
 570   "Ask for a regular expression and set the process mark on all articles that match."
 571   (interactive (list (read-from-minibuffer "Mark (regexp): ")))
 572   (let ((articles (gnus-uu-find-articles-matching regexp)))
 573     (while articles
 574       (if unmark
 575           (gnus-summary-remove-process-mark (pop articles))
 576         (gnus-summary-set-process-mark (pop articles))))
 577     (message ""))
 578   (gnus-summary-position-point))
 579
 580 (defun gnus-uu-unmark-by-regexp (regexp &optional unmark)
 581   "Ask for a regular expression and remove the process mark on all articles that match."
 582   (interactive (list (read-from-minibuffer "Mark (regexp): ")))
 583   (gnus-uu-mark-by-regexp regexp t))
 584
 585 (defun gnus-uu-mark-series ()
 586   "Mark the current series with the process mark."
 587   (interactive)
 588   (let ((articles (gnus-uu-find-articles-matching)))
 589     (while articles
 590       (gnus-summary-set-process-mark (car articles))
 591       (setq articles (cdr articles)))
 592     (message ""))
 593   (gnus-summary-position-point))
 594
 595 (defun gnus-uu-mark-region (beg end &optional unmark)
 596   "Set the process mark on all articles between point and mark."
 597   (interactive "r")
 598   (save-excursion
 599     (goto-char beg)
 600     (while (< (point) end)
 601       (if unmark
 602           (gnus-summary-remove-process-mark (gnus-summary-article-number))
 603         (gnus-summary-set-process-mark (gnus-summary-article-number)))
 604       (forward-line 1)))
 605   (gnus-summary-position-point))
 606
 607 (defun gnus-uu-unmark-region (beg end)
 608   "Remove the process mark from all articles between point and mark."
 609   (interactive "r")
 610   (gnus-uu-mark-region beg end t))
 611
 612 (defun gnus-uu-mark-buffer ()
 613   "Set the process mark on all articles in the buffer."
 614   (interactive)
 615   (gnus-uu-mark-region (point-min) (point-max)))
 616
 617 (defun gnus-uu-unmark-buffer ()
 618   "Remove the process mark on all articles in the buffer."
 619   (interactive)
 620   (gnus-uu-mark-region (point-min) (point-max) t))
 621
 622 (defun gnus-uu-mark-thread ()
 623   "Marks all articles downwards in this thread."
 624   (interactive)
 625   (let ((level (gnus-summary-thread-level)))
 626     (while (and (gnus-summary-set-process-mark (gnus-summary-article-number))
 627                 (zerop (gnus-summary-next-subject 1))
 628                 (> (gnus-summary-thread-level) level))))
 629   (gnus-summary-position-point))
 630
 631 (defun gnus-uu-unmark-thread ()
 632   "Unmarks all articles downwards in this thread."
 633   (interactive)
 634   (let ((level (gnus-summary-thread-level)))
 635     (while (and (gnus-summary-remove-process-mark
 636                  (gnus-summary-article-number))
 637                 (zerop (gnus-summary-next-subject 1))
 638                 (> (gnus-summary-thread-level) level))))
 639   (gnus-summary-position-point))
 640
 641 (defun gnus-uu-invert-processable ()
 642   "Invert the list of process-marked articles."
 643   (interactive)
 644   (let ((data gnus-newsgroup-data)
 645         number)
 646     (save-excursion
 647       (while data
 648         (if (memq (setq number (gnus-data-number (pop data)))
 649                   gnus-newsgroup-processable)
 650             (gnus-summary-remove-process-mark number)
 651           (gnus-summary-set-process-mark number)))))
 652   (gnus-summary-position-point))
 653
 654 (defun gnus-uu-mark-over (&optional score)
 655   "Mark all articles with a score over SCORE (the prefix)."
 656   (interactive "P")
 657   (let ((score (gnus-score-default score))
 658         (data gnus-newsgroup-data))
 659     (save-excursion
 660       (while data
 661         (when (> (or (cdr (assq (gnus-data-number (car data))
 662                                 gnus-newsgroup-scored))
 663                      gnus-summary-default-score 0)
 664                  score)
 665           (gnus-summary-set-process-mark (caar data)))
 666         (setq data (cdr data))))
 667     (gnus-summary-position-point)))
 668
 669 (defun gnus-uu-mark-sparse ()
 670   "Mark all series that have some articles marked."
 671   (interactive)
 672   (let ((marked (nreverse gnus-newsgroup-processable))
 673         subject articles total headers)
 674     (unless marked
 675       (error "No articles marked with the process mark"))
 676     (setq gnus-newsgroup-processable nil)
 677     (save-excursion
 678       (while marked
 679         (and (vectorp (setq headers
 680                             (gnus-summary-article-header (car marked))))
 681              (setq subject (mail-header-subject headers)
 682                    articles (gnus-uu-find-articles-matching
 683                              (gnus-uu-reginize-string subject))
 684                    total (nconc total articles)))
 685         (while articles
 686           (gnus-summary-set-process-mark (car articles))
 687           (setcdr marked (delq (car articles) (cdr marked)))
 688           (setq articles (cdr articles)))
 689         (setq marked (cdr marked)))
 690       (setq gnus-newsgroup-processable (nreverse total)))
 691     (gnus-summary-position-point)))
 692
 693 (defun gnus-uu-mark-all ()
 694   "Mark all articles in \"series\" order."
 695   (interactive)
 696   (setq gnus-newsgroup-processable nil)
 697   (save-excursion
 698     (let ((data gnus-newsgroup-data)
 699           number)
 700       (while data
 701         (when (and (not (memq (setq number (gnus-data-number (car data)))
 702                               gnus-newsgroup-processable))
 703                    (vectorp (gnus-data-header (car data))))
 704           (gnus-summary-goto-subject number)
 705           (gnus-uu-mark-series))
 706         (setq data (cdr data)))))
 707   (gnus-summary-position-point))
 708
 709 ;; All PostScript functions written by Erik Selberg <speed@cs.washington.edu>.
 710
 711 (defun gnus-uu-decode-postscript (&optional n)
 712   "Gets postscript of the current article."
 713   (interactive "P")
 714   (gnus-uu-decode-with-method 'gnus-uu-decode-postscript-article n))
 715
 716 (defun gnus-uu-decode-postscript-view (&optional n)
 717   "Gets and views the current article."
 718   (interactive "P")
 719   (let ((gnus-view-pseudos (or gnus-view-pseudos 'automatic)))
 720     (gnus-uu-decode-postscript n)))
 721
 722 (defun gnus-uu-decode-postscript-and-save (n dir)
 723   "Extracts postscript and saves the current article."
 724   (interactive
 725    (list current-prefix-arg
 726          (file-name-as-directory
 727           (read-file-name "Save in dir: "
 728                           gnus-uu-default-dir
 729                           gnus-uu-default-dir t))))
 730   (gnus-uu-decode-with-method 'gnus-uu-decode-postscript-article
 731                               n dir nil nil t))
 732
 733 (defun gnus-uu-decode-postscript-and-save-view (n dir)
 734   "Decodes, views and saves the resulting file."
 735   (interactive
 736    (list current-prefix-arg
 737          (read-file-name "Where do you want to save the file(s)? "
 738                          gnus-uu-default-dir
 739                          gnus-uu-default-dir t)))
 740   (let ((gnus-view-pseudos (or gnus-view-pseudos 'automatic)))
 741     (gnus-uu-decode-postscript-and-save n dir)))
 742
 743
 744 ;; Internal functions.
 745
 746 (defun gnus-uu-decode-with-method (method n &optional save not-insert
 747                                           scan cdir)
 748   (gnus-uu-initialize scan)
 749   (when save
 750     (setq gnus-uu-default-dir save))
 751   ;; Create the directory we save to.
 752   (when (and scan cdir save
 753              (not (file-exists-p save)))
 754     (make-directory save t))
 755   (let ((articles (gnus-uu-get-list-of-articles n))
 756         files)
 757     (setq files (gnus-uu-grab-articles articles method t))
 758     (let ((gnus-current-article (car articles)))
 759       (when scan
 760         (setq files (gnus-uu-scan-directory gnus-uu-work-dir))))
 761     (when save
 762       (gnus-uu-save-files files save))
 763     (when (eq gnus-uu-do-not-unpack-archives nil)
 764       (setq files (gnus-uu-unpack-files files)))
 765     (setq files (nreverse (gnus-uu-get-actions files)))
 766     (or not-insert (not gnus-insert-pseudo-articles)
 767         (gnus-summary-insert-pseudos files save))))
 768
 769 (defun gnus-uu-scan-directory (dir &optional rec)
 770   "Return a list of all files under DIR."
 771   (let ((files (directory-files dir t))
 772         out file)
 773     (while (setq file (pop files))
 774       (unless (member (file-name-nondirectory file) '("." ".."))
 775         (push (list (cons 'name file)
 776                     (cons 'article gnus-current-article))
 777               out)
 778         (when (file-directory-p file)
 779           (setq out (nconc (gnus-uu-scan-directory file t) out)))))
 780     (if rec
 781         out
 782       (nreverse out))))
 783
 784 (defun gnus-uu-save-files (files dir)
 785   "Save FILES in DIR."
 786   (let ((len (length files))
 787         (reg (concat "^" (regexp-quote gnus-uu-work-dir)))
 788         to-file file fromdir)
 789     (while (setq file (cdr (assq 'name (pop files))))
 790       (when (file-exists-p file)
 791         (string-match reg file)
 792         (setq fromdir (substring file (match-end 0)))
 793         (if (file-directory-p file)
 794             (gnus-make-directory (concat dir fromdir))
 795           (setq to-file (concat dir fromdir))
 796           (when (or (not (file-exists-p to-file))
 797                     (eq gnus-uu-be-dangerous t)
 798                     (and gnus-uu-be-dangerous
 799                          (gnus-y-or-n-p (format "%s exists; overwrite? "
 800                                                 to-file))))
 801             (copy-file file to-file t t)))))
 802     (gnus-message 5 "Saved %d file%s" len (if (= len 1) "" "s"))))
 803
 804 ;; Functions for saving and possibly digesting articles without
 805 ;; any decoding.
 806
 807 ;; Function called by gnus-uu-grab-articles to treat each article.
 808 (defun gnus-uu-save-article (buffer in-state)
 809   (cond
 810    (gnus-uu-save-separate-articles
 811     (save-excursion
 812       (set-buffer buffer)
 813       (gnus-write-buffer
 814        (concat gnus-uu-saved-article-name gnus-current-article))
 815       (cond ((eq in-state 'first) (list gnus-uu-saved-article-name 'begin))
 816             ((eq in-state 'first-and-last) (list gnus-uu-saved-article-name
 817                                                  'begin 'end))
 818             ((eq in-state 'last) (list 'end))
 819             (t (list 'middle)))))
 820    ((not gnus-uu-save-in-digest)
 821     (save-excursion
 822       (set-buffer buffer)
 823       (write-region (point-min) (point-max) gnus-uu-saved-article-name t)
 824       (cond ((eq in-state 'first) (list gnus-uu-saved-article-name 'begin))
 825             ((eq in-state 'first-and-last) (list gnus-uu-saved-article-name
 826                                                  'begin 'end))
 827             ((eq in-state 'last) (list 'end))
 828             (t (list 'middle)))))
 829    (t
 830     (let ((header (gnus-summary-article-header)))
 831       (push (cons (mail-header-from header)
 832                   (mail-header-subject header))
 833             gnus-uu-digest-from-subject))
 834     (let ((name (file-name-nondirectory gnus-uu-saved-article-name))
 835           beg subj headers headline sorthead body end-string state)
 836       (if (or (eq in-state 'first)
 837               (eq in-state 'first-and-last))
 838           (progn
 839             (setq state (list 'begin))
 840             (save-excursion
 841               (set-buffer (gnus-get-buffer-create "*gnus-uu-body*"))
 842               (erase-buffer))
 843             (save-excursion
 844               (set-buffer (gnus-get-buffer-create "*gnus-uu-pre*"))
 845               (erase-buffer)
 846               (insert (format
 847                        "Date: %s\nFrom: %s\nSubject: %s Digest\n\nTopics:\n"
 848                        (current-time-string) name name))))
 849         (when (not (eq in-state 'end))
 850           (setq state (list 'middle))))
 851       (save-excursion
 852         (set-buffer "*gnus-uu-body*")
 853         (goto-char (setq beg (point-max)))
 854         (save-excursion
 855           (save-restriction
 856             (set-buffer buffer)
 857             (let (buffer-read-only)
 858               (gnus-set-text-properties (point-min) (point-max) nil)
 859               ;; These two are necessary for XEmacs 19.12 fascism.
 860               (put-text-property (point-min) (point-max) 'invisible nil)
 861               (put-text-property (point-min) (point-max) 'intangible nil))
 862             (goto-char (point-min))
 863             (re-search-forward "\n\n")
 864             ;; Quote all 30-dash lines.
 865             (save-excursion
 866               (while (re-search-forward "^-" nil t)
 867                 (beginning-of-line)
 868                 (delete-char 1)
 869                 (insert "- ")))
 870             (setq body (buffer-substring (1- (point)) (point-max)))
 871             (narrow-to-region (point-min) (point))
 872             (if (not (setq headers gnus-uu-digest-headers))
 873                 (setq sorthead (buffer-substring (point-min) (point-max)))
 874               (while headers
 875                 (setq headline (car headers))
 876                 (setq headers (cdr headers))
 877                 (goto-char (point-min))
 878                 (while (re-search-forward headline nil t)
 879                   (setq sorthead
 880                         (concat sorthead
 881                                 (buffer-substring
 882                                  (match-beginning 0)
 883                                  (or (and (re-search-forward "^[^ \t]" nil t)
 884                                           (1- (point)))
 885                                      (progn (forward-line 1) (point)))))))))
 886             (widen)))
 887         (insert sorthead) (goto-char (point-max))
 888         (insert body) (goto-char (point-max))
 889         (insert (concat "\n" (make-string 30 ?-) "\n\n"))
 890         (goto-char beg)
 891         (when (re-search-forward "^Subject: \\(.*\\)$" nil t)
 892           (setq subj (buffer-substring (match-beginning 1) (match-end 1)))
 893           (save-excursion
 894             (set-buffer "*gnus-uu-pre*")
 895             (insert (format "   %s\n" subj)))))
 896       (when (or (eq in-state 'last)
 897                 (eq in-state 'first-and-last))
 898         (save-excursion
 899           (set-buffer "*gnus-uu-pre*")
 900           (insert (format "\n\n%s\n\n" (make-string 70 ?-)))
 901           (gnus-write-buffer gnus-uu-saved-article-name))
 902         (save-excursion
 903           (set-buffer "*gnus-uu-body*")
 904           (goto-char (point-max))
 905           (insert
 906            (concat (setq end-string (format "End of %s Digest" name))
 907                    "\n"))
 908           (insert (concat (make-string (length end-string) ?*) "\n"))
 909           (write-region
 910            (point-min) (point-max) gnus-uu-saved-article-name t))
 911         (gnus-kill-buffer "*gnus-uu-pre*")
 912         (gnus-kill-buffer "*gnus-uu-body*")
 913         (push 'end state))
 914       (if (memq 'begin state)
 915           (cons gnus-uu-saved-article-name state)
 916         state)))))
 917
 918 ;; Binhex treatment - not very advanced.
 919
 920 (defvar gnus-uu-binhex-body-line
 921   "^[^:]...............................................................$")
 922 (defvar gnus-uu-binhex-begin-line
 923   "^:...............................................................$")
 924 (defvar gnus-uu-binhex-end-line
 925   ":$")
 926
 927 (defun gnus-uu-binhex-article (buffer in-state)
 928   (let (state start-char)
 929     (save-excursion
 930       (set-buffer buffer)
 931       (widen)
 932       (goto-char (point-min))
 933       (when (not (re-search-forward gnus-uu-binhex-begin-line nil t))
 934         (when (not (re-search-forward gnus-uu-binhex-body-line nil t))
 935           (setq state (list 'wrong-type))))
 936
 937       (if (memq 'wrong-type state)
 938           ()
 939         (beginning-of-line)
 940         (setq start-char (point))
 941         (if (looking-at gnus-uu-binhex-begin-line)
 942             (progn
 943               (setq state (list 'begin))
 944               (write-region 1 1 gnus-uu-binhex-article-name))
 945           (setq state (list 'middle)))
 946         (goto-char (point-max))
 947         (re-search-backward (concat gnus-uu-binhex-body-line "\\|"
 948                                     gnus-uu-binhex-end-line)
 949                             nil t)
 950         (when (looking-at gnus-uu-binhex-end-line)
 951           (setq state (if (memq 'begin state)
 952                           (cons 'end state)
 953                         (list 'end))))
 954         (beginning-of-line)
 955         (forward-line 1)
 956         (when (file-exists-p gnus-uu-binhex-article-name)
 957           (append-to-file start-char (point) gnus-uu-binhex-article-name))))
 958     (if (memq 'begin state)
 959         (cons gnus-uu-binhex-article-name state)
 960       state)))
 961
 962 ;; PostScript
 963
 964 (defun gnus-uu-decode-postscript-article (process-buffer in-state)
 965   (let ((state (list 'ok))
 966         start-char end-char file-name)
 967     (save-excursion
 968       (set-buffer process-buffer)
 969       (goto-char (point-min))
 970       (if (not (re-search-forward gnus-uu-postscript-begin-string nil t))
 971           (setq state (list 'wrong-type))
 972         (beginning-of-line)
 973         (setq start-char (point))
 974         (if (not (re-search-forward gnus-uu-postscript-end-string nil t))
 975             (setq state (list 'wrong-type))
 976           (setq end-char (point))
 977           (set-buffer (gnus-get-buffer-create gnus-uu-output-buffer-name))
 978           (insert-buffer-substring process-buffer start-char end-char)
 979           (setq file-name (concat gnus-uu-work-dir
 980                                   (cdr gnus-article-current) ".ps"))
 981           (write-region (point-min) (point-max) file-name)
 982           (setq state (list file-name 'begin 'end)))))
 983     state))
 984
 985
 986 ;; Find actions.
 987
 988 (defun gnus-uu-get-actions (files)
 989   (let ((ofiles files)
 990         action name)
 991     (while files
 992       (setq name (cdr (assq 'name (car files))))
 993       (and
 994        (setq action (gnus-uu-get-action name))
 995        (setcar files (nconc (list (if (string= action "gnus-uu-archive")
 996                                       (cons 'action "file")
 997                                     (cons 'action action))
 998                                   (cons 'execute (gnus-uu-command
 999                                                   action name)))
1000                             (car files))))
1001       (setq files (cdr files)))
1002     ofiles))
1003
1004 (defun gnus-uu-get-action (file-name)
1005   (let (action)
1006     (setq action
1007           (gnus-uu-choose-action
1008            file-name
1009            (append
1010             gnus-uu-user-view-rules
1011             (if gnus-uu-ignore-default-view-rules
1012                 nil
1013               gnus-uu-default-view-rules)
1014             gnus-uu-user-view-rules-end)))
1015     (when (and (not (string= (or action "") "gnus-uu-archive"))
1016                gnus-uu-view-with-metamail)
1017       (when (setq action
1018                   (gnus-uu-choose-action file-name gnus-uu-ext-to-mime-list))
1019         (setq action (format "metamail -d -b -c \"%s\"" action))))
1020     action))
1021
1022
1023 ;; Functions for treating subjects and collecting series.
1024
1025 (defun gnus-uu-reginize-string (string)
1026   ;; Takes a string and puts a \ in front of every special character;
1027   ;; replaces the last thing that looks like "2/3" with "[0-9]+/3"
1028   ;; or, if it can't find something like that, tries "2 of 3", then
1029   ;; finally just replaces the next to last number with "[0-9]+".
1030   (save-excursion
1031     (set-buffer (gnus-get-buffer-create gnus-uu-output-buffer-name))
1032     (buffer-disable-undo)
1033     (erase-buffer)
1034     (insert (regexp-quote string))
1035
1036     (setq case-fold-search nil)
1037
1038     (end-of-line)
1039     (if (re-search-backward "\\([^0-9]\\)[0-9]+/\\([0-9]+\\)" nil t)
1040         (replace-match "\\1[0-9]+/\\2")
1041
1042       (end-of-line)
1043       (if (re-search-backward "\\([^0-9]\\)[0-9]+[ \t]*of[ \t]*\\([0-9]+\\)"
1044                               nil t)
1045           (replace-match "\\1[0-9]+ of \\2")
1046
1047         (end-of-line)
1048         (if (re-search-backward "\\([^0-9]\\)[0-9]+\\([^0-9]+\\)[0-9]+"
1049                                 nil t)
1050             (replace-match "\\1[0-9]+\\2[0-9]+" t nil nil nil))))
1051
1052     (goto-char 1)
1053     (while (re-search-forward "[ \t]+" nil t)
1054       (replace-match "[ \t]+" t t))
1055
1056     (buffer-substring 1 (point-max))))
1057
1058 (defun gnus-uu-get-list-of-articles (n)
1059   ;; If N is non-nil, the article numbers of the N next articles
1060   ;; will be returned.
1061   ;; If any articles have been marked as processable, they will be
1062   ;; returned.
1063   ;; Failing that, articles that have subjects that are part of the
1064   ;; same "series" as the current will be returned.
1065   (let (articles)
1066     (cond
1067      (n
1068       (setq n (prefix-numeric-value n))
1069       (let ((backward (< n 0))
1070             (n (abs n)))
1071         (save-excursion
1072           (while (and (> n 0)
1073                       (push (gnus-summary-article-number)
1074                             articles)
1075                       (gnus-summary-search-forward nil nil backward))
1076             (setq n (1- n))))
1077         (nreverse articles)))
1078      (gnus-newsgroup-processable
1079       (reverse gnus-newsgroup-processable))
1080      (t
1081       (gnus-uu-find-articles-matching)))))
1082
1083 (defun gnus-uu-string< (l1 l2)
1084   (string< (car l1) (car l2)))
1085
1086 (defun gnus-uu-find-articles-matching
1087   (&optional subject only-unread do-not-translate)
1088   ;; Finds all articles that matches the regexp SUBJECT.  If it is
1089   ;; nil, the current article name will be used.  If ONLY-UNREAD is
1090   ;; non-nil, only unread articles are chosen.  If DO-NOT-TRANSLATE is
1091   ;; non-nil, article names are not equalized before sorting.
1092   (let ((subject (or subject
1093                      (gnus-uu-reginize-string (gnus-summary-article-subject))))
1094         list-of-subjects)
1095     (save-excursion
1096       (when subject
1097         ;; Collect all subjects matching subject.
1098         (let ((case-fold-search t)
1099               (data gnus-newsgroup-data)
1100               subj mark d)
1101           (while data
1102             (setq d (pop data))
1103             (and (not (gnus-data-pseudo-p d))
1104                  (or (not only-unread)
1105                      (= (setq mark (gnus-data-mark d))
1106                         gnus-unread-mark)
1107                      (= mark gnus-ticked-mark)
1108                      (= mark gnus-dormant-mark))
1109                  (setq subj (mail-header-subject (gnus-data-header d)))
1110                  (string-match subject subj)
1111                  (push (cons subj (gnus-data-number d))
1112                        list-of-subjects))))
1113
1114         ;; Expand numbers, sort, and return the list of article
1115         ;; numbers.
1116         (mapcar (lambda (sub) (cdr sub))
1117                 (sort (gnus-uu-expand-numbers
1118                        list-of-subjects
1119                        (not do-not-translate))
1120                       'gnus-uu-string<))))))
1121
1122 (defun gnus-uu-expand-numbers (string-list &optional translate)
1123   ;; Takes a list of strings and "expands" all numbers in all the
1124   ;; strings.  That is, this function makes all numbers equal length by
1125   ;; prepending lots of zeroes before each number.  This is to ease later
1126   ;; sorting to find out what sequence the articles are supposed to be
1127   ;; decoded in.  Returns the list of expanded strings.
1128   (let ((out-list string-list)
1129         string)
1130     (save-excursion
1131       (set-buffer (gnus-get-buffer-create gnus-uu-output-buffer-name))
1132       (buffer-disable-undo)
1133       (while string-list
1134         (erase-buffer)
1135         (insert (caar string-list))
1136         ;; Translate multiple spaces to one space.
1137         (goto-char (point-min))
1138         (while (re-search-forward "[ \t]+" nil t)
1139           (replace-match " "))
1140         ;; Translate all characters to "a".
1141         (goto-char (point-min))
1142         (when translate
1143           (while (re-search-forward "[A-Za-z]" nil t)
1144             (replace-match "a" t t)))
1145         ;; Expand numbers.
1146         (goto-char (point-min))
1147         (while (re-search-forward "[0-9]+" nil t)
1148           (replace-match
1149            (format "%06d"
1150                    (string-to-int (buffer-substring
1151                                    (match-beginning 0) (match-end 0))))))
1152         (setq string (buffer-substring 1 (point-max)))
1153         (setcar (car string-list) string)
1154         (setq string-list (cdr string-list))))
1155     out-list))
1156
1157
1158 ;; `gnus-uu-grab-articles' is the general multi-article treatment
1159 ;; function.  It takes a list of articles to be grabbed and a function
1160 ;; to apply to each article.
1161 ;;
1162 ;; The function to be called should take two parameters.  The first
1163 ;; parameter is the article buffer.  The function should leave the
1164 ;; result, if any, in this buffer.  Most treatment functions will just
1165 ;; generate files...
1166 ;;
1167 ;; The second parameter is the state of the list of articles, and can
1168 ;; have four values: `first', `middle', `last' and `first-and-last'.
1169 ;;
1170 ;; The function should return a list.  The list may contain the
1171 ;; following symbols:
1172 ;; `error' if an error occurred
1173 ;; `begin' if the beginning of an encoded file has been received
1174 ;;   If the list returned contains a `begin', the first element of
1175 ;;   the list *must* be a string with the file name of the decoded
1176 ;;   file.
1177 ;; `end' if the end of an encoded file has been received
1178 ;; `middle' if the article was a body part of an encoded file
1179 ;; `wrong-type' if the article was not a part of an encoded file
1180 ;; `ok', which can be used everything is ok
1181
1182 (defvar gnus-uu-has-been-grabbed nil)
1183
1184 (defun gnus-uu-unmark-list-of-grabbed (&optional dont-unmark-last-article)
1185   (let (art)
1186     (if (not (and gnus-uu-has-been-grabbed
1187                   gnus-uu-unmark-articles-not-decoded))
1188         ()
1189       (when dont-unmark-last-article
1190         (setq art (car gnus-uu-has-been-grabbed))
1191         (setq gnus-uu-has-been-grabbed (cdr gnus-uu-has-been-grabbed)))
1192       (while gnus-uu-has-been-grabbed
1193         (gnus-summary-tick-article (car gnus-uu-has-been-grabbed) t)
1194         (setq gnus-uu-has-been-grabbed (cdr gnus-uu-has-been-grabbed)))
1195       (when dont-unmark-last-article
1196         (setq gnus-uu-has-been-grabbed (list art))))))
1197
1198 ;; This function takes a list of articles and a function to apply to
1199 ;; each article grabbed.
1200 ;;
1201 ;; This function returns a list of files decoded if the grabbing and
1202 ;; the process-function has been successful and nil otherwise.
1203 (defun gnus-uu-grab-articles (articles process-function
1204                                        &optional sloppy limit no-errors)
1205   (let ((state 'first)
1206         (gnus-asynchronous nil)
1207         has-been-begin article result-file result-files process-state
1208         gnus-summary-display-article-function
1209         gnus-article-display-hook gnus-article-prepare-hook
1210         article-series files)
1211
1212     (while (and articles
1213                 (not (memq 'error process-state))
1214                 (or sloppy
1215                     (not (memq 'end process-state))))
1216
1217       (setq article (pop articles))
1218       (when (vectorp (gnus-summary-article-header article))
1219         (push article article-series)
1220
1221         (unless articles
1222           (if (eq state 'first)
1223               (setq state 'first-and-last)
1224             (setq state 'last)))
1225
1226         (let ((part (gnus-uu-part-number article)))
1227           (gnus-message 6 "Getting article %d%s..."
1228                         article (if (string= part "") "" (concat ", " part))))
1229         (gnus-summary-display-article article)
1230
1231         ;; Push the article to the processing function.
1232         (save-excursion
1233           (set-buffer gnus-original-article-buffer)
1234           (let ((buffer-read-only nil))
1235             (save-excursion
1236               (set-buffer gnus-summary-buffer)
1237               (setq process-state
1238                     (funcall process-function
1239                              gnus-original-article-buffer state)))))
1240
1241         (gnus-summary-remove-process-mark article)
1242
1243         ;; If this is the beginning of a decoded file, we push it
1244         ;; on to a list.
1245         (when (or (memq 'begin process-state)
1246                   (and (or (eq state 'first)
1247                            (eq state 'first-and-last))
1248                        (memq 'ok process-state)))
1249           (when has-been-begin
1250             ;; If there is a `result-file' here, that means that the
1251             ;; file was unsuccessfully decoded, so we delete it.
1252             (when (and result-file
1253                        (file-exists-p result-file)
1254                        (not gnus-uu-be-dangerous)
1255                        (or (eq gnus-uu-be-dangerous t)
1256                            (gnus-y-or-n-p
1257                             (format "Delete unsuccessfully decoded file %s"
1258                                     result-file))))
1259               (delete-file result-file)))
1260           (when (memq 'begin process-state)
1261             (setq result-file (car process-state)))
1262           (setq has-been-begin t))
1263
1264         ;; Check whether we have decoded one complete file.
1265         (when (memq 'end process-state)
1266           (setq article-series nil)
1267           (setq has-been-begin nil)
1268           (if (stringp result-file)
1269               (setq files (list result-file))
1270             (setq files result-file))
1271           (setq result-file (car files))
1272           (while files
1273             (push (list (cons 'name (pop files))
1274                         (cons 'article article))
1275                   result-files))
1276           ;; Allow user-defined functions to be run on this file.
1277           (when gnus-uu-grabbed-file-functions
1278             (let ((funcs gnus-uu-grabbed-file-functions))
1279               (unless (listp funcs)
1280                 (setq funcs (list funcs)))
1281               (while funcs
1282                 (funcall (pop funcs) result-file))))
1283           (setq result-file nil)
1284           ;; Check whether we have decoded enough articles.
1285           (and limit (= (length result-files) limit)
1286                (setq articles nil)))
1287
1288         ;; If this is the last article to be decoded, and
1289         ;; we still haven't reached the end, then we delete
1290         ;; the partially decoded file.
1291         (and (or (eq state 'last) (eq state 'first-and-last))
1292              (not (memq 'end process-state))
1293              result-file
1294              (file-exists-p result-file)
1295              (not gnus-uu-be-dangerous)
1296              (or (eq gnus-uu-be-dangerous t)
1297                  (gnus-y-or-n-p
1298                   (format "Delete incomplete file %s? " result-file)))
1299              (delete-file result-file))
1300
1301         ;; If this was a file of the wrong sort, then
1302         (when (and (or (memq 'wrong-type process-state)
1303                        (memq 'error process-state))
1304                    gnus-uu-unmark-articles-not-decoded)
1305           (gnus-summary-tick-article article t))
1306
1307         ;; Set the new series state.
1308         (if (and (not has-been-begin)
1309                  (not sloppy)
1310                  (or (memq 'end process-state)
1311                      (memq 'middle process-state)))
1312             (progn
1313               (setq process-state (list 'error))
1314               (gnus-message 2 "No begin part at the beginning")
1315               (sleep-for 2))
1316           (setq state 'middle)))
1317
1318       ;; When there are no result-files, then something must be wrong.
1319       (if result-files
1320           (message "")
1321         (cond
1322          ((not has-been-begin)
1323           (gnus-message 2 "Wrong type file"))
1324          ((memq 'error process-state)
1325           (gnus-message 2 "An error occurred during decoding"))
1326          ((not (or (memq 'ok process-state)
1327                    (memq 'end process-state)))
1328           (gnus-message 2 "End of articles reached before end of file")))
1329         ;; Make unsuccessfully decoded articles unread.
1330         (when gnus-uu-unmark-articles-not-decoded
1331           (while article-series
1332             (gnus-summary-tick-article (pop article-series) t)))))
1333
1334     result-files))
1335
1336 (defun gnus-uu-grab-view (file)
1337   "View FILE using the gnus-uu methods."
1338   (let ((action (gnus-uu-get-action file)))
1339     (gnus-execute-command
1340      (if (string-match "%" action)
1341          (format action file)
1342        (concat action " " file))
1343      (eq gnus-view-pseudos 'not-confirm))))
1344
1345 (defun gnus-uu-grab-move (file)
1346   "Move FILE to somewhere."
1347   (when gnus-uu-default-dir
1348     (let ((to-file (concat (file-name-as-directory gnus-uu-default-dir)
1349                            (file-name-nondirectory file))))
1350       (rename-file file to-file)
1351       (unless (file-exists-p file)
1352         (make-symbolic-link to-file file)))))
1353
1354 (defun gnus-uu-part-number (article)
1355   (let* ((header (gnus-summary-article-header article))
1356          (subject (and header (mail-header-subject header)))
1357          (part nil))
1358     (if subject
1359         (while (string-match "[0-9]+/[0-9]+\\|[0-9]+[ \t]+of[ \t]+[0-9]+"
1360                              subject)
1361           (setq part (match-string 0 subject))
1362           (setq subject (substring subject (match-end 0)))))
1363     (or part
1364         (while (string-match "\\([0-9]+\\)[^0-9]+\\([0-9]+\\)" subject)
1365           (setq part (match-string 0 subject))
1366           (setq subject (substring subject (match-end 0)))))
1367     (or part "")))
1368
1369 (defun gnus-uu-uudecode-sentinel (process event)
1370   (delete-process (get-process process)))
1371
1372 (defun gnus-uu-uustrip-article (process-buffer in-state)
1373   ;; Uudecodes a file asynchronously.
1374   (save-excursion
1375     (set-buffer process-buffer)
1376     (let ((state (list 'wrong-type))
1377           process-connection-type case-fold-search buffer-read-only
1378           files start-char)
1379       (goto-char (point-min))
1380
1381       ;; Deal with ^M at the end of the lines.
1382       (when gnus-uu-kill-carriage-return
1383         (save-excursion
1384           (while (search-forward "\r" nil t)
1385             (delete-backward-char 1))))
1386
1387       (while (or (re-search-forward gnus-uu-begin-string nil t)
1388                  (re-search-forward gnus-uu-body-line nil t))
1389         (setq state (list 'ok))
1390         ;; Ok, we are at the first uucoded line.
1391         (beginning-of-line)
1392         (setq start-char (point))
1393
1394         (if (not (looking-at gnus-uu-begin-string))
1395             (setq state (list 'middle))
1396           ;; This is the beginning of a uuencoded article.
1397           ;; We replace certain characters that could make things messy.
1398           (setq gnus-uu-file-name
1399                 (let ((nnheader-file-name-translation-alist
1400                        '((?/ . ?,) (? . ?_) (?* . ?_) (?$ . ?_))))
1401                   (nnheader-translate-file-chars (match-string 1))))
1402           (replace-match (concat "begin 644 " gnus-uu-file-name) t t)
1403
1404           ;; Remove any non gnus-uu-body-line right after start.
1405           (forward-line 1)
1406           (while (and (not (eobp))
1407                       (not (looking-at gnus-uu-body-line)))
1408             (gnus-delete-line))
1409
1410           ;; If a process is running, we kill it.
1411           (when (and gnus-uu-uudecode-process
1412                      (memq (process-status gnus-uu-uudecode-process)
1413                            '(run stop)))
1414             (delete-process gnus-uu-uudecode-process)
1415             (gnus-uu-unmark-list-of-grabbed t))
1416
1417           ;; Start a new uudecoding process.
1418           (let ((cdir default-directory))
1419             (unwind-protect
1420                 (progn
1421                   (cd gnus-uu-work-dir)
1422                   (setq gnus-uu-uudecode-process
1423                         (start-process
1424                          "*uudecode*"
1425                          (gnus-get-buffer-create gnus-uu-output-buffer-name)
1426                          shell-file-name shell-command-switch
1427                          (format "cd %s %s uudecode" gnus-uu-work-dir
1428                                  gnus-shell-command-separator))))
1429               (cd cdir)))
1430           (set-process-sentinel
1431            gnus-uu-uudecode-process 'gnus-uu-uudecode-sentinel)
1432           (setq state (list 'begin))
1433           (push (concat gnus-uu-work-dir gnus-uu-file-name) files))
1434
1435         ;; We look for the end of the thing to be decoded.
1436         (if (re-search-forward gnus-uu-end-string nil t)
1437             (push 'end state)
1438           (goto-char (point-max))
1439           (re-search-backward gnus-uu-body-line nil t))
1440
1441         (forward-line 1)
1442
1443         (when gnus-uu-uudecode-process
1444           (when (memq (process-status gnus-uu-uudecode-process) '(run stop))
1445             ;; Try to correct mishandled uucode.
1446             (when gnus-uu-correct-stripped-uucode
1447               (gnus-uu-check-correct-stripped-uucode start-char (point)))
1448             (gnus-run-hooks 'gnus-uu-pre-uudecode-hook)
1449
1450             ;; Send the text to the process.
1451             (condition-case nil
1452                 (process-send-region
1453                  gnus-uu-uudecode-process start-char (point))
1454               (error
1455                (progn
1456                  (delete-process gnus-uu-uudecode-process)
1457                  (gnus-message 2 "gnus-uu: Couldn't uudecode")
1458                  (setq state (list 'wrong-type)))))
1459
1460             (if (memq 'end state)
1461                 (progn
1462                   ;; Send an EOF, just in case.
1463                   (ignore-errors
1464                     (process-send-eof gnus-uu-uudecode-process))
1465                   (while (memq (process-status gnus-uu-uudecode-process)
1466                                '(open run))
1467                     (accept-process-output gnus-uu-uudecode-process 1)))
1468               (when (or (not gnus-uu-uudecode-process)
1469                         (not (memq (process-status gnus-uu-uudecode-process)
1470                                    '(run stop))))
1471                 (setq state (list 'wrong-type)))))))
1472
1473       (if (memq 'begin state)
1474           (cons (if (= (length files) 1) (car files) files) state)
1475         state))))
1476
1477 ;; This function is used by `gnus-uu-grab-articles' to treat
1478 ;; a shared article.
1479 (defun gnus-uu-unshar-article (process-buffer in-state)
1480   (let ((state (list 'ok))
1481         start-char)
1482     (save-excursion
1483       (set-buffer process-buffer)
1484       (goto-char (point-min))
1485       (if (not (re-search-forward gnus-uu-shar-begin-string nil t))
1486           (setq state (list 'wrong-type))
1487         (beginning-of-line)
1488         (setq start-char (point))
1489         (call-process-region
1490          start-char (point-max) shell-file-name nil
1491          (gnus-get-buffer-create gnus-uu-output-buffer-name) nil
1492          shell-command-switch
1493          (concat "cd " gnus-uu-work-dir " "
1494                  gnus-shell-command-separator  " sh"))))
1495     state))
1496
1497 ;; Returns the name of what the shar file is going to unpack.
1498 (defun gnus-uu-find-name-in-shar ()
1499   (let ((oldpoint (point))
1500         res)
1501     (goto-char (point-min))
1502     (when (re-search-forward gnus-uu-shar-name-marker nil t)
1503       (setq res (buffer-substring (match-beginning 1) (match-end 1))))
1504     (goto-char oldpoint)
1505     res))
1506
1507 ;; `gnus-uu-choose-action' chooses what action to perform given the name
1508 ;; and `gnus-uu-file-action-list'.  Returns either nil if no action is
1509 ;; found, or the name of the command to run if such a rule is found.
1510 (defun gnus-uu-choose-action (file-name file-action-list &optional no-ignore)
1511   (let ((action-list (copy-sequence file-action-list))
1512         (case-fold-search t)
1513         rule action)
1514     (and
1515      (unless no-ignore
1516        (and (not
1517              (and gnus-uu-ignore-files-by-name
1518                   (string-match gnus-uu-ignore-files-by-name file-name)))
1519             (not
1520              (and gnus-uu-ignore-files-by-type
1521                   (string-match gnus-uu-ignore-files-by-type
1522                                 (or (gnus-uu-choose-action
1523                                      file-name gnus-uu-ext-to-mime-list t)
1524                                     ""))))))
1525      (while (not (or (eq action-list ()) action))
1526        (setq rule (car action-list))
1527        (setq action-list (cdr action-list))
1528        (when (string-match (car rule) file-name)
1529          (setq action (cadr rule)))))
1530     action))
1531
1532 (defun gnus-uu-treat-archive (file-path)
1533   ;; Unpacks an archive.  Returns t if unpacking is successful.
1534   (let ((did-unpack t)
1535         action command dir)
1536     (setq action (gnus-uu-choose-action
1537                   file-path (append gnus-uu-user-archive-rules
1538                                     (if gnus-uu-ignore-default-archive-rules
1539                                         nil
1540                                       gnus-uu-default-archive-rules))))
1541
1542     (when (not action)
1543       (error "No unpackers for the file %s" file-path))
1544
1545     (string-match "/[^/]*$" file-path)
1546     (setq dir (substring file-path 0 (match-beginning 0)))
1547
1548     (when (member action gnus-uu-destructive-archivers)
1549       (copy-file file-path (concat file-path "~") t))
1550
1551     (setq command (format "cd %s ; %s" dir (gnus-uu-command action file-path)))
1552
1553     (save-excursion
1554       (set-buffer (gnus-get-buffer-create gnus-uu-output-buffer-name))
1555       (erase-buffer))
1556
1557     (gnus-message 5 "Unpacking: %s..." (gnus-uu-command action file-path))
1558
1559     (if (= 0 (call-process shell-file-name nil
1560                            (gnus-get-buffer-create gnus-uu-output-buffer-name)
1561                            nil shell-command-switch command))
1562         (message "")
1563       (gnus-message 2 "Error during unpacking of archive")
1564       (setq did-unpack nil))
1565
1566     (when (member action gnus-uu-destructive-archivers)
1567       (rename-file (concat file-path "~") file-path t))
1568
1569     did-unpack))
1570
1571 (defun gnus-uu-dir-files (dir)
1572   (let ((dirs (directory-files dir t "[^/][^\\.][^\\.]?$"))
1573         files file)
1574     (while dirs
1575       (if (file-directory-p (setq file (car dirs)))
1576           (setq files (append files (gnus-uu-dir-files file)))
1577         (push file files))
1578       (setq dirs (cdr dirs)))
1579     files))
1580
1581 (defun gnus-uu-unpack-files (files &optional ignore)
1582   ;; Go through FILES and look for files to unpack.
1583   (let* ((totfiles (gnus-uu-ls-r gnus-uu-work-dir))
1584          (ofiles files)
1585          file did-unpack)
1586     (while files
1587       (setq file (cdr (assq 'name (car files))))
1588       (when (and (not (member file ignore))
1589                  (equal (gnus-uu-get-action (file-name-nondirectory file))
1590                         "gnus-uu-archive"))
1591         (push file did-unpack)
1592         (unless (gnus-uu-treat-archive file)
1593           (gnus-message 2 "Error during unpacking of %s" file))
1594         (let* ((newfiles (gnus-uu-ls-r gnus-uu-work-dir))
1595                (nfiles newfiles))
1596           (while nfiles
1597             (unless (member (car nfiles) totfiles)
1598               (push (list (cons 'name (car nfiles))
1599                           (cons 'original file))
1600                     ofiles))
1601             (setq nfiles (cdr nfiles)))
1602           (setq totfiles newfiles)))
1603       (setq files (cdr files)))
1604     (if did-unpack
1605         (gnus-uu-unpack-files ofiles (append did-unpack ignore))
1606       ofiles)))
1607
1608 (defun gnus-uu-ls-r (dir)
1609   (let* ((files (gnus-uu-directory-files dir t))
1610          (ofiles files))
1611     (while files
1612       (when (file-directory-p (car files))
1613         (setq ofiles (delete (car files) ofiles))
1614         (setq ofiles (append ofiles (gnus-uu-ls-r (car files)))))
1615       (setq files (cdr files)))
1616     ofiles))
1617
1618 ;; Various stuff
1619
1620 (defun gnus-uu-directory-files (dir &optional full)
1621   (let (files out file)
1622     (setq files (directory-files dir full))
1623     (while files
1624       (setq file (car files))
1625       (setq files (cdr files))
1626       (unless (member (file-name-nondirectory file) '("." ".."))
1627         (push file out)))
1628     (setq out (nreverse out))
1629     out))
1630
1631 (defun gnus-uu-check-correct-stripped-uucode (start end)
1632   (save-excursion
1633     (let (found beg length)
1634       (if (not gnus-uu-correct-stripped-uucode)
1635           ()
1636         (goto-char start)
1637
1638         (if (re-search-forward " \\|`" end t)
1639             (progn
1640               (goto-char start)
1641               (while (not (eobp))
1642                 (progn
1643                   (when (looking-at "\n")
1644                     (replace-match ""))
1645                   (forward-line 1))))
1646
1647           (while (not (eobp))
1648             (if (looking-at (concat gnus-uu-begin-string "\\|"
1649                                     gnus-uu-end-string))
1650                 ()
1651               (when (not found)
1652                 (beginning-of-line)
1653                 (setq beg (point))
1654                 (end-of-line)
1655                 (setq length (- (point) beg)))
1656               (setq found t)
1657               (beginning-of-line)
1658               (setq beg (point))
1659               (end-of-line)
1660               (when (not (= length (- (point) beg)))
1661                 (insert (make-string (- length (- (point) beg)) ? ))))
1662             (forward-line 1)))))))
1663
1664 (defvar gnus-uu-tmp-alist nil)
1665
1666 (defun gnus-uu-initialize (&optional scan)
1667   (let (entry)
1668     (if (and (not scan)
1669              (when (setq entry (assoc gnus-newsgroup-name gnus-uu-tmp-alist))
1670                (if (file-exists-p (cdr entry))
1671                    (setq gnus-uu-work-dir (cdr entry))
1672                  (setq gnus-uu-tmp-alist (delq entry gnus-uu-tmp-alist))
1673                  nil)))
1674         t
1675       (setq gnus-uu-tmp-dir (file-name-as-directory
1676                              (expand-file-name gnus-uu-tmp-dir)))
1677       (if (not (file-directory-p gnus-uu-tmp-dir))
1678           (error "Temp directory %s doesn't exist" gnus-uu-tmp-dir)
1679         (when (not (file-writable-p gnus-uu-tmp-dir))
1680           (error "Temp directory %s can't be written to"
1681                  gnus-uu-tmp-dir)))
1682
1683       (setq gnus-uu-work-dir
1684             (make-temp-name (concat gnus-uu-tmp-dir "gnus")))
1685       (gnus-make-directory gnus-uu-work-dir)
1686       (set-file-modes gnus-uu-work-dir 448)
1687       (setq gnus-uu-work-dir (file-name-as-directory gnus-uu-work-dir))
1688       (push (cons gnus-newsgroup-name gnus-uu-work-dir)
1689             gnus-uu-tmp-alist))))
1690
1691
1692 ;; Kills the temporary uu buffers, kills any processes, etc.
1693 (defun gnus-uu-clean-up ()
1694   (let (buf)
1695     (and gnus-uu-uudecode-process
1696          (memq (process-status (or gnus-uu-uudecode-process "nevair"))
1697                '(stop run))
1698          (delete-process gnus-uu-uudecode-process))
1699     (when (setq buf (get-buffer gnus-uu-output-buffer-name))
1700       (kill-buffer buf))))
1701
1702 ;; Inputs an action and a filename and returns a full command, making sure
1703 ;; that the filename will be treated as a single argument when the shell
1704 ;; executes the command.
1705 (defun gnus-uu-command (action file)
1706   (let ((quoted-file (mm-quote-arg file)))
1707     (if (string-match "%s" action)
1708         (format action quoted-file)
1709       (concat action " " quoted-file))))
1710
1711 (defun gnus-uu-delete-work-dir (&optional dir)
1712   "Delete recursively all files and directories under `gnus-uu-work-dir'."
1713   (if dir
1714       (gnus-message 7 "Deleting directory %s..." dir)
1715     (setq dir gnus-uu-work-dir))
1716   (when (and dir
1717              (file-exists-p dir))
1718     (let ((files (directory-files dir t nil t))
1719           file)
1720       (while (setq file (pop files))
1721         (unless (member (file-name-nondirectory file) '("." ".."))
1722           (if (file-directory-p file)
1723               (gnus-uu-delete-work-dir file)
1724             (gnus-message 9 "Deleting file %s..." file)
1725             (delete-file file))))
1726       (delete-directory dir)))
1727   (gnus-message 7 ""))
1728
1729 ;; Initializing
1730
1731 (add-hook 'gnus-exit-group-hook 'gnus-uu-clean-up)
1732 (add-hook 'gnus-exit-group-hook 'gnus-uu-delete-work-dir)
1733
1734 \f
1735
1736 ;;;
1737 ;;; uuencoded posting
1738 ;;;
1739
1740 ;; Any function that is to be used as and encoding method will take two
1741 ;; parameters: PATH-NAME and FILE-NAME.  (E.g. "/home/gaga/spiral.jpg"
1742 ;; and "spiral.jpg", respectively.) The function should return nil if
1743 ;; the encoding wasn't successful.
1744 (defcustom gnus-uu-post-encode-method 'gnus-uu-post-encode-uuencode
1745   "Function used for encoding binary files.
1746 There are three functions supplied with gnus-uu for encoding files:
1747 `gnus-uu-post-encode-uuencode', which does straight uuencoding;
1748 `gnus-uu-post-encode-mime', which encodes with base64 and adds MIME
1749 headers; and `gnus-uu-post-encode-mime-uuencode', which encodes with
1750 uuencode and adds MIME headers."
1751   :group 'gnus-extract-post
1752   :type '(radio (function-item gnus-uu-post-encode-uuencode)
1753                 (function-item gnus-uu-post-encode-mime)
1754                 (function-item gnus-uu-post-encode-mime-uuencode)
1755                 (function :tag "Other")))
1756
1757 (defcustom gnus-uu-post-include-before-composing nil
1758   "Non-nil means that gnus-uu will ask for a file to encode before you compose the article.
1759 If this variable is t, you can either include an encoded file with
1760 \\[gnus-uu-post-insert-binary-in-article] or have one included for you when you post the article."
1761   :group 'gnus-extract-post
1762   :type 'boolean)
1763
1764 (defcustom gnus-uu-post-length 990
1765   "Maximum length of an article.
1766 The encoded file will be split into how many articles it takes to
1767 post the entire file."
1768   :group 'gnus-extract-post
1769   :type 'integer)
1770
1771 (defcustom gnus-uu-post-threaded nil
1772   "Non-nil means that gnus-uu will post the encoded file in a thread.
1773 This may not be smart, as no other decoder I have seen are able to
1774 follow threads when collecting uuencoded articles.  (Well, I have seen
1775 one package that does that - gnus-uu, but somehow, I don't think that
1776 counts...)  The default is nil."
1777   :group 'gnus-extract-post
1778   :type 'boolean)
1779
1780 (defcustom gnus-uu-post-separate-description t
1781   "Non-nil means that the description will be posted in a separate article.
1782 The first article will typically be numbered (0/x).  If this variable
1783 is nil, the description the user enters will be included at the
1784 beginning of the first article, which will be numbered (1/x).  Default
1785 is t."
1786   :group 'gnus-extract-post
1787   :type 'boolean)
1788
1789 (defvar gnus-uu-post-binary-separator "--binary follows this line--")
1790 (defvar gnus-uu-post-message-id nil)
1791 (defvar gnus-uu-post-inserted-file-name nil)
1792 (defvar gnus-uu-winconf-post-news nil)
1793
1794 (defun gnus-uu-post-news ()
1795   "Compose an article and post an encoded file."
1796   (interactive)
1797   (setq gnus-uu-post-inserted-file-name nil)
1798   (setq gnus-uu-winconf-post-news (current-window-configuration))
1799
1800   (gnus-summary-post-news)
1801
1802   (let ((map (make-sparse-keymap)))
1803     (set-keymap-parent map (current-local-map))
1804     (use-local-map map))
1805   (local-set-key "\C-c\C-c" 'gnus-summary-edit-article-done)
1806   (local-set-key "\C-c\C-c" 'gnus-uu-post-news-inews)
1807   (local-set-key "\C-c\C-s" 'gnus-uu-post-news-inews)
1808   (local-set-key "\C-c\C-i" 'gnus-uu-post-insert-binary-in-article)
1809
1810   (when gnus-uu-post-include-before-composing
1811     (save-excursion (setq gnus-uu-post-inserted-file-name
1812                           (gnus-uu-post-insert-binary)))))
1813
1814 (defun gnus-uu-post-insert-binary-in-article ()
1815   "Inserts an encoded file in the buffer.
1816 The user will be asked for a file name."
1817   (interactive)
1818   (save-excursion
1819     (setq gnus-uu-post-inserted-file-name (gnus-uu-post-insert-binary))))
1820
1821 ;; Encodes with uuencode and substitutes all spaces with backticks.
1822 (defun gnus-uu-post-encode-uuencode (path file-name)
1823   (when (gnus-uu-post-encode-file "uuencode" path file-name)
1824     (goto-char (point-min))
1825     (forward-line 1)
1826     (while (re-search-forward " " nil t)
1827       (replace-match "`"))
1828     t))
1829
1830 ;; Encodes with uuencode and adds MIME headers.
1831 (defun gnus-uu-post-encode-mime-uuencode (path file-name)
1832   (when (gnus-uu-post-encode-uuencode path file-name)
1833     (gnus-uu-post-make-mime file-name "x-uue")
1834     t))
1835
1836 ;; Encodes with base64 and adds MIME headers
1837 (defun gnus-uu-post-encode-mime (path file-name)
1838   (when (zerop (call-process shell-file-name nil t nil shell-command-switch
1839                              (format "%s %s -o %s" "mmencode" path file-name)))
1840     (gnus-uu-post-make-mime file-name "base64")
1841     t))
1842
1843 ;; Adds MIME headers.
1844 (defun gnus-uu-post-make-mime (file-name encoding)
1845   (goto-char (point-min))
1846   (insert (format "Content-Type: %s; name=\"%s\"\n"
1847                   (gnus-uu-choose-action file-name gnus-uu-ext-to-mime-list)
1848                   file-name))
1849   (insert (format "Content-Transfer-Encoding: %s\n\n" encoding))
1850   (save-restriction
1851     (set-buffer gnus-message-buffer)
1852     (goto-char (point-min))
1853     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1854     (forward-line -1)
1855     (narrow-to-region 1 (point))
1856     (unless (mail-fetch-field "mime-version")
1857       (widen)
1858       (insert "MIME-Version: 1.0\n"))
1859     (widen)))
1860
1861 ;; Encodes a file PATH with COMMAND, leaving the result in the
1862 ;; current buffer.
1863 (defun gnus-uu-post-encode-file (command path file-name)
1864   (= 0 (call-process shell-file-name nil t nil shell-command-switch
1865                      (format "%s %s %s" command path file-name))))
1866
1867 (defun gnus-uu-post-news-inews ()
1868   "Posts the composed news article and encoded file.
1869 If no file has been included, the user will be asked for a file."
1870   (interactive)
1871
1872   (let (file-name)
1873
1874     (if gnus-uu-post-inserted-file-name
1875         (setq file-name gnus-uu-post-inserted-file-name)
1876       (setq file-name (gnus-uu-post-insert-binary)))
1877
1878     (gnus-uu-post-encoded file-name gnus-uu-post-threaded))
1879   (setq gnus-uu-post-inserted-file-name nil)
1880   (when gnus-uu-winconf-post-news
1881     (set-window-configuration gnus-uu-winconf-post-news)))
1882
1883 ;; Asks for a file to encode, encodes it and inserts the result in
1884 ;; the current buffer.  Returns the file name the user gave.
1885 (defun gnus-uu-post-insert-binary ()
1886   (let ((uuencode-buffer-name "*uuencode buffer*")
1887         file-path uubuf file-name)
1888
1889     (setq file-path (read-file-name
1890                      "What file do you want to encode? "))
1891     (when (not (file-exists-p file-path))
1892       (error "%s: No such file" file-path))
1893
1894     (goto-char (point-max))
1895     (insert (format "\n%s\n" gnus-uu-post-binary-separator))
1896
1897     ;; #### Unix-specific?
1898     (when (string-match "^~/" file-path)
1899       (setq file-path (concat "$HOME" (substring file-path 1))))
1900     ;; #### Unix-specific?
1901     (if (string-match "/[^/]*$" file-path)
1902         (setq file-name (substring file-path (1+ (match-beginning 0))))
1903       (setq file-name file-path))
1904
1905     (unwind-protect
1906         (if (save-excursion
1907               (set-buffer (setq uubuf
1908                                 (gnus-get-buffer-create uuencode-buffer-name)))
1909               (erase-buffer)
1910               (funcall gnus-uu-post-encode-method file-path file-name))
1911             (insert-buffer-substring uubuf)
1912           (error "Encoding unsuccessful"))
1913       (kill-buffer uubuf))
1914     file-name))
1915
1916 ;; Posts the article and all of the encoded file.
1917 (defun gnus-uu-post-encoded (file-name &optional threaded)
1918   (let ((send-buffer-name "*uuencode send buffer*")
1919         (encoded-buffer-name "*encoded buffer*")
1920         (top-string "[ cut here %s (%s %d/%d) %s gnus-uu ]")
1921         (separator (concat mail-header-separator "\n\n"))
1922         uubuf length parts header i end beg
1923         beg-line minlen post-buf whole-len beg-binary end-binary)
1924
1925     (setq post-buf (current-buffer))
1926
1927     (goto-char (point-min))
1928     (when (not (re-search-forward
1929                 (if gnus-uu-post-separate-description
1930                     (concat "^" (regexp-quote gnus-uu-post-binary-separator)
1931                             "$")
1932                   (concat "^" (regexp-quote mail-header-separator) "$"))
1933                 nil t))
1934       (error "Internal error: No binary/header separator"))
1935     (beginning-of-line)
1936     (forward-line 1)
1937     (setq beg-binary (point))
1938     (setq end-binary (point-max))
1939
1940     (save-excursion
1941       (set-buffer (setq uubuf (gnus-get-buffer-create encoded-buffer-name)))
1942       (erase-buffer)
1943       (insert-buffer-substring post-buf beg-binary end-binary)
1944       (goto-char (point-min))
1945       (setq length (count-lines 1 (point-max)))
1946       (setq parts (/ length gnus-uu-post-length))
1947       (unless (< (% length gnus-uu-post-length) 4)
1948         (incf parts)))
1949
1950     (when gnus-uu-post-separate-description
1951       (forward-line -1))
1952     (delete-region (point) (point-max))
1953
1954     (goto-char (point-min))
1955     (re-search-forward
1956      (concat "^" (regexp-quote mail-header-separator) "$") nil t)
1957     (beginning-of-line)
1958     (setq header (buffer-substring 1 (point)))
1959
1960     (goto-char (point-min))
1961     (when gnus-uu-post-separate-description
1962       (when (re-search-forward "^Subject: " nil t)
1963         (end-of-line)
1964         (insert (format " (0/%d)" parts)))
1965       (save-excursion
1966         (message-send))
1967       (setq gnus-uu-post-message-id (message-fetch-field "message-id")))
1968
1969     (save-excursion
1970       (setq i 1)
1971       (setq beg 1)
1972       (while (not (> i parts))
1973         (set-buffer (gnus-get-buffer-create send-buffer-name))
1974         (erase-buffer)
1975         (insert header)
1976         (when (and threaded gnus-uu-post-message-id)
1977           (insert "References: " gnus-uu-post-message-id "\n"))
1978         (insert separator)
1979         (setq whole-len
1980               (- 62 (length (format top-string "" file-name i parts ""))))
1981         (when (> 1 (setq minlen (/ whole-len 2)))
1982           (setq minlen 1))
1983         (setq
1984          beg-line
1985          (format top-string
1986                  (make-string minlen ?-)
1987                  file-name i parts
1988                  (make-string
1989                   (if (= 0 (% whole-len 2)) (1- minlen) minlen) ?-)))
1990
1991         (goto-char (point-min))
1992         (when (re-search-forward "^Subject: " nil t)
1993           (end-of-line)
1994           (insert (format " (%d/%d)" i parts)))
1995
1996         (goto-char (point-max))
1997         (save-excursion
1998           (set-buffer uubuf)
1999           (goto-char beg)
2000           (if (= i parts)
2001               (goto-char (point-max))
2002             (forward-line gnus-uu-post-length))
2003           (when (and (= (1+ i) parts) (< (count-lines (point) (point-max)) 4))
2004             (forward-line -4))
2005           (setq end (point)))
2006         (insert-buffer-substring uubuf beg end)
2007         (insert beg-line "\n")
2008         (setq beg end)
2009         (incf i)
2010         (goto-char (point-min))
2011         (re-search-forward
2012          (concat "^" (regexp-quote mail-header-separator) "$") nil t)
2013         (beginning-of-line)
2014         (forward-line 2)
2015         (when (re-search-forward
2016                (concat "^" (regexp-quote gnus-uu-post-binary-separator) "$")
2017                nil t)
2018           (replace-match "")
2019           (forward-line 1))
2020         (insert beg-line)
2021         (insert "\n")
2022         (let (message-sent-message-via)
2023           (save-excursion
2024             (message-send))
2025           (setq gnus-uu-post-message-id
2026                 (concat (message-fetch-field "references") " "
2027                         (message-fetch-field "message-id"))))))
2028
2029     (gnus-kill-buffer send-buffer-name)
2030     (gnus-kill-buffer encoded-buffer-name)
2031
2032     (when (not gnus-uu-post-separate-description)
2033       (set-buffer-modified-p nil)
2034       (when (fboundp 'bury-buffer)
2035         (bury-buffer)))))
2036
2037 (provide 'gnus-uu)
2038
2039 ;; gnus-uu.el ends here