cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'gnus-spec)
  30 (require 'gnus-group)
  31 (require 'gnus-int)
  32 (require 'gnus-range)
  33
  34 (defvar gnus-server-mode-hook nil
  35   "Hook run in `gnus-server-mode' buffers.")
  36
  37 (defconst gnus-server-line-format "     {%(%h:%w%)} %s\n"
  38   "Format of server lines.
  39 It works along the same lines as a normal formatting string,
  40 with some simple extensions.")
  41
  42 (defvar gnus-server-mode-line-format "Gnus  List of servers"
  43   "The format specification for the server mode line.")
  44
  45 (defvar gnus-server-exit-hook nil
  46   "*Hook run when exiting the server buffer.")
  47
  48 ;;; Internal variables.
  49
  50 (defvar gnus-inserted-opened-servers nil)
  51
  52 (defvar gnus-server-line-format-alist
  53   `((?h how ?s)
  54     (?n name ?s)
  55     (?w where ?s)
  56     (?s status ?s)))
  57
  58 (defvar gnus-server-mode-line-format-alist
  59   `((?S news-server ?s)
  60     (?M news-method ?s)
  61     (?u user-defined ?s)))
  62
  63 (defvar gnus-server-line-format-spec nil)
  64 (defvar gnus-server-mode-line-format-spec nil)
  65 (defvar gnus-server-killed-servers nil)
  66
  67 (defvar gnus-server-mode-map)
  68
  69 (defvar gnus-server-menu-hook nil
  70   "*Hook run after the creation of the server mode menu.")
  71
  72 (defun gnus-server-make-menu-bar ()
  73   (gnus-turn-off-edit-menu 'server)
  74   (unless (boundp 'gnus-server-server-menu)
  75     (easy-menu-define
  76      gnus-server-server-menu gnus-server-mode-map ""
  77      '("Server"
  78        ["Add" gnus-server-add-server t]
  79        ["Browse" gnus-server-read-server t]
  80        ["Scan" gnus-server-scan-server t]
  81        ["List" gnus-server-list-servers t]
  82        ["Kill" gnus-server-kill-server t]
  83        ["Yank" gnus-server-yank-server t]
  84        ["Copy" gnus-server-copy-server t]
  85        ["Edit" gnus-server-edit-server t]
  86        ["Regenerate" gnus-server-regenerate-server t]
  87        ["Exit" gnus-server-exit t]))
  88
  89     (easy-menu-define
  90      gnus-server-connections-menu gnus-server-mode-map ""
  91      '("Connections"
  92        ["Open" gnus-server-open-server t]
  93        ["Close" gnus-server-close-server t]
  94        ["Deny" gnus-server-deny-server t]
  95        "---"
  96        ["Open All" gnus-server-open-all-servers t]
  97        ["Close All" gnus-server-close-all-servers t]
  98        ["Reset All" gnus-server-remove-denials t]))
  99
 100     (run-hooks 'gnus-server-menu-hook)))
 101
 102 (defvar gnus-server-mode-map nil)
 103 (put 'gnus-server-mode 'mode-class 'special)
 104
 105 (unless gnus-server-mode-map
 106   (setq gnus-server-mode-map (make-sparse-keymap))
 107   (suppress-keymap gnus-server-mode-map)
 108
 109   (gnus-define-keys
 110    gnus-server-mode-map
 111    " " gnus-server-read-server
 112    "\r" gnus-server-read-server
 113    gnus-mouse-2 gnus-server-pick-server
 114    "q" gnus-server-exit
 115    "l" gnus-server-list-servers
 116    "k" gnus-server-kill-server
 117    "y" gnus-server-yank-server
 118    "c" gnus-server-copy-server
 119    "a" gnus-server-add-server
 120    "e" gnus-server-edit-server
 121    "s" gnus-server-scan-server
 122
 123    "O" gnus-server-open-server
 124    "\M-o" gnus-server-open-all-servers
 125    "C" gnus-server-close-server
 126    "\M-c" gnus-server-close-all-servers
 127    "D" gnus-server-deny-server
 128    "R" gnus-server-remove-denials
 129
 130    "g" gnus-server-regenerate-server
 131
 132     "\C-c\C-i" gnus-info-find-node
 133     "\C-c\C-b" gnus-bug))
 134
 135 (defun gnus-server-mode ()
 136   "Major mode for listing and editing servers.
 137
 138 All normal editing commands are switched off.
 139 \\<gnus-server-mode-map>
 140 For more in-depth information on this mode, read the manual
 141 (`\\[gnus-info-find-node]').
 142
 143 The following commands are available:
 144
 145 \\{gnus-server-mode-map}"
 146   (interactive)
 147   (when (gnus-visual-p 'server-menu 'menu)
 148     (gnus-server-make-menu-bar))
 149   (kill-all-local-variables)
 150   (gnus-simplify-mode-line)
 151   (setq major-mode 'gnus-server-mode)
 152   (setq mode-name "Server")
 153   (gnus-set-default-directory)
 154   (setq mode-line-process nil)
 155   (use-local-map gnus-server-mode-map)
 156   (buffer-disable-undo (current-buffer))
 157   (setq truncate-lines t)
 158   (setq buffer-read-only t)
 159   (run-hooks 'gnus-server-mode-hook))
 160
 161 (defun gnus-server-insert-server-line (name method)
 162   (let* ((how (car method))
 163          (where (nth 1 method))
 164          (elem (assoc method gnus-opened-servers))
 165          (status (cond ((eq (nth 1 elem) 'denied)
 166                         "(denied)")
 167                        ((or (gnus-server-opened method)
 168                             (eq (nth 1 elem) 'ok))
 169                         "(opened)")
 170                        (t
 171                         "(closed)"))))
 172     (beginning-of-line)
 173     (gnus-add-text-properties
 174      (point)
 175      (prog1 (1+ (point))
 176        ;; Insert the text.
 177        (eval gnus-server-line-format-spec))
 178      (list 'gnus-server (intern name)))))
 179
 180 (defun gnus-enter-server-buffer ()
 181   "Set up the server buffer."
 182   (gnus-server-setup-buffer)
 183   (gnus-configure-windows 'server)
 184   (gnus-server-prepare))
 185
 186 (defun gnus-server-setup-buffer ()
 187   "Initialize the server buffer."
 188   (unless (get-buffer gnus-server-buffer)
 189     (save-excursion
 190       (set-buffer (get-buffer-create gnus-server-buffer))
 191       (gnus-server-mode)
 192       (when gnus-carpal
 193         (gnus-carpal-setup-buffer 'server)))))
 194
 195 (defun gnus-server-prepare ()
 196   (setq gnus-server-mode-line-format-spec
 197         (gnus-parse-format gnus-server-mode-line-format
 198                            gnus-server-mode-line-format-alist))
 199   (setq gnus-server-line-format-spec
 200         (gnus-parse-format gnus-server-line-format
 201                            gnus-server-line-format-alist t))
 202   (let ((alist gnus-server-alist)
 203         (buffer-read-only nil)
 204         (opened gnus-opened-servers)
 205         done server op-ser)
 206     (erase-buffer)
 207     (setq gnus-inserted-opened-servers nil)
 208     ;; First we do the real list of servers.
 209     (while alist
 210       (push (caar alist) done)
 211       (cdr (setq server (pop alist)))
 212       (when (and server (car server) (cdr server))
 213         (gnus-server-insert-server-line (car server) (cdr server))))
 214     ;; Then we insert the list of servers that have been opened in
 215     ;; this session.
 216     (while opened
 217       (unless (member (cadaar opened) done)
 218         (push (cadaar opened) done)
 219         (gnus-server-insert-server-line
 220          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 221          (caar opened))
 222         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 223       (setq opened (cdr opened))))
 224   (goto-char (point-min))
 225   (gnus-server-position-point))
 226
 227 (defun gnus-server-server-name ()
 228   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 229     (and server (symbol-name server))))
 230
 231 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 232
 233 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 234
 235 (defun gnus-server-update-server (server)
 236   (save-excursion
 237     (set-buffer gnus-server-buffer)
 238     (let* ((buffer-read-only nil)
 239            (entry (assoc server gnus-server-alist))
 240            (oentry (assoc (gnus-server-to-method server)
 241                           gnus-opened-servers)))
 242       (when entry
 243         (gnus-dribble-enter
 244          (concat "(gnus-server-set-info \"" server "\" '"
 245                  (prin1-to-string (cdr entry)) ")\n")))
 246       (when (or entry oentry)
 247         ;; Buffer may be narrowed.
 248         (save-restriction
 249           (widen)
 250           (when (gnus-server-goto-server server)
 251             (gnus-delete-line))
 252           (if entry
 253               (gnus-server-insert-server-line (car entry) (cdr entry))
 254             (gnus-server-insert-server-line
 255              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 256              (car oentry)))
 257           (gnus-server-position-point))))))
 258
 259 (defun gnus-server-set-info (server info)
 260   ;; Enter a select method into the virtual server alist.
 261   (when (and server info)
 262     (gnus-dribble-enter
 263      (concat "(gnus-server-set-info \"" server "\" '"
 264              (prin1-to-string info) ")"))
 265     (let* ((server (nth 1 info))
 266            (entry (assoc server gnus-server-alist)))
 267       (if entry (setcdr entry info)
 268         (setq gnus-server-alist
 269               (nconc gnus-server-alist (list (cons server info))))))))
 270
 271 ;;; Interactive server functions.
 272
 273 (defun gnus-server-kill-server (server)
 274   "Kill the server on the current line."
 275   (interactive (list (gnus-server-server-name)))
 276   (unless (gnus-server-goto-server server)
 277     (if server (error "No such server: %s" server)
 278       (error "No server on the current line")))
 279   (unless (assoc server gnus-server-alist)
 280     (error "Read-only server %s" server))
 281   (gnus-dribble-enter "")
 282   (let ((buffer-read-only nil))
 283     (gnus-delete-line))
 284   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 285   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 286                                 gnus-server-alist))
 287   (gnus-server-position-point))
 288
 289 (defun gnus-server-yank-server ()
 290   "Yank the previously killed server."
 291   (interactive)
 292   (unless gnus-server-killed-servers
 293     (error "No killed servers to be yanked"))
 294   (let ((alist gnus-server-alist)
 295         (server (gnus-server-server-name))
 296         (killed (car gnus-server-killed-servers)))
 297     (if (not server)
 298         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 299       (if (string= server (caar gnus-server-alist))
 300           (push killed gnus-server-alist)
 301         (while (and (cdr alist)
 302                     (not (string= server (caadr alist))))
 303           (setq alist (cdr alist)))
 304         (if alist
 305             (setcdr alist (cons killed (cdr alist)))
 306           (setq gnus-server-alist (list killed)))))
 307     (gnus-server-update-server (car killed))
 308     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 309     (gnus-server-position-point)))
 310
 311 (defun gnus-server-exit ()
 312   "Return to the group buffer."
 313   (interactive)
 314   (kill-buffer (current-buffer))
 315   (switch-to-buffer gnus-group-buffer)
 316   (run-hooks 'gnus-server-exit-hook))
 317
 318 (defun gnus-server-list-servers ()
 319   "List all available servers."
 320   (interactive)
 321   (let ((cur (gnus-server-server-name)))
 322     (gnus-server-prepare)
 323     (if cur (gnus-server-goto-server cur)
 324       (goto-char (point-max))
 325       (forward-line -1))
 326     (gnus-server-position-point)))
 327
 328 (defun gnus-server-set-status (method status)
 329   "Make METHOD have STATUS."
 330   (let ((entry (assoc method gnus-opened-servers)))
 331     (if entry
 332         (setcar (cdr entry) status)
 333       (push (list method status) gnus-opened-servers))))
 334
 335 (defun gnus-opened-servers-remove (method)
 336   "Remove METHOD from the list of opened servers."
 337   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 338                                   gnus-opened-servers)))
 339
 340 (defun gnus-server-open-server (server)
 341   "Force an open of SERVER."
 342   (interactive (list (gnus-server-server-name)))
 343   (let ((method (gnus-server-to-method server)))
 344     (unless method
 345       (error "No such server: %s" server))
 346     (gnus-server-set-status method 'ok)
 347     (prog1
 348         (or (gnus-open-server method)
 349             (progn (message "Couldn't open %s" server) nil))
 350       (gnus-server-update-server server)
 351       (gnus-server-position-point))))
 352
 353 (defun gnus-server-open-all-servers ()
 354   "Open all servers."
 355   (interactive)
 356   (let ((servers gnus-inserted-opened-servers))
 357     (while servers
 358       (gnus-server-open-server (car (pop servers))))))
 359
 360 (defun gnus-server-close-server (server)
 361   "Close SERVER."
 362   (interactive (list (gnus-server-server-name)))
 363   (let ((method (gnus-server-to-method server)))
 364     (unless method
 365       (error "No such server: %s" server))
 366     (gnus-server-set-status method 'closed)
 367     (prog1
 368         (gnus-close-server method)
 369       (gnus-server-update-server server)
 370       (gnus-server-position-point))))
 371
 372 (defun gnus-server-close-all-servers ()
 373   "Close all servers."
 374   (interactive)
 375   (let ((servers gnus-inserted-opened-servers))
 376     (while servers
 377       (gnus-server-close-server (car (pop servers))))))
 378
 379 (defun gnus-server-deny-server (server)
 380   "Make sure SERVER will never be attempted opened."
 381   (interactive (list (gnus-server-server-name)))
 382   (let ((method (gnus-server-to-method server)))
 383     (unless method
 384       (error "No such server: %s" server))
 385     (gnus-server-set-status method 'denied))
 386   (gnus-server-update-server server)
 387   (gnus-server-position-point)
 388   t)
 389
 390 (defun gnus-server-remove-denials ()
 391   "Make all denied servers into closed servers."
 392   (interactive)
 393   (let ((servers gnus-opened-servers))
 394     (while servers
 395       (when (eq (nth 1 (car servers)) 'denied)
 396         (setcar (nthcdr 1 (car servers)) 'closed))
 397       (setq servers (cdr servers))))
 398   (gnus-server-list-servers))
 399
 400 (defun gnus-server-copy-server (from to)
 401   (interactive
 402    (list
 403     (or (gnus-server-server-name)
 404         (error "No server on the current line"))
 405     (read-string "Copy to: ")))
 406   (unless from
 407     (error "No server on current line"))
 408   (unless (and to (not (string= to "")))
 409     (error "No name to copy to"))
 410   (when (assoc to gnus-server-alist)
 411     (error "%s already exists" to))
 412   (unless (gnus-server-to-method from)
 413     (error "%s: no such server" from))
 414   (let ((to-entry (cons from (gnus-copy-sequence
 415                               (gnus-server-to-method from)))))
 416     (setcar to-entry to)
 417     (setcar (nthcdr 2 to-entry) to)
 418     (push to-entry gnus-server-killed-servers)
 419     (gnus-server-yank-server)))
 420
 421 (defun gnus-server-add-server (how where)
 422   (interactive
 423    (list (intern (completing-read "Server method: "
 424                                   gnus-valid-select-methods nil t))
 425          (read-string "Server name: ")))
 426   (when (assq where gnus-server-alist)
 427     (error "Server with that name already defined"))
 428   (push (list where how where) gnus-server-killed-servers)
 429   (gnus-server-yank-server))
 430
 431 (defun gnus-server-goto-server (server)
 432   "Jump to a server line."
 433   (interactive
 434    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 435   (let ((to (text-property-any (point-min) (point-max)
 436                                'gnus-server (intern server))))
 437     (when to
 438       (goto-char to)
 439       (gnus-server-position-point))))
 440
 441 (defun gnus-server-edit-server (server)
 442   "Edit the server on the current line."
 443   (interactive (list (gnus-server-server-name)))
 444   (unless server
 445     (error "No server on current line"))
 446   (unless (assoc server gnus-server-alist)
 447     (error "This server can't be edited"))
 448   (let ((info (cdr (assoc server gnus-server-alist))))
 449     (gnus-close-server info)
 450     (gnus-edit-form
 451      info "Editing the server."
 452      `(lambda (form)
 453         (gnus-server-set-info ,server form)
 454         (gnus-server-list-servers)
 455         (gnus-server-position-point)))))
 456
 457 (defun gnus-server-scan-server (server)
 458   "Request a scan from the current server."
 459   (interactive (list (gnus-server-server-name)))
 460   (gnus-message 3 "Scanning %s...done" server)
 461   (gnus-request-scan nil (gnus-server-to-method server))
 462   (gnus-message 3 "Scanning %s...done" server))
 463
 464 (defun gnus-server-read-server (server)
 465   "Browse a server."
 466   (interactive (list (gnus-server-server-name)))
 467   (let ((buf (current-buffer)))
 468     (prog1
 469         (gnus-browse-foreign-server (gnus-server-to-method server) buf)
 470       (save-excursion
 471         (set-buffer buf)
 472         (gnus-server-update-server (gnus-server-server-name))
 473         (gnus-server-position-point)))))
 474
 475 (defun gnus-server-pick-server (e)
 476   (interactive "e")
 477   (mouse-set-point e)
 478   (gnus-server-read-server (gnus-server-server-name)))
 479
 480 \f
 481 ;;;
 482 ;;; Browse Server Mode
 483 ;;;
 484
 485 (defvar gnus-browse-menu-hook nil
 486   "*Hook run after the creation of the browse mode menu.")
 487
 488 (defvar gnus-browse-mode-hook nil)
 489 (defvar gnus-browse-mode-map nil)
 490 (put 'gnus-browse-mode 'mode-class 'special)
 491
 492 (unless gnus-browse-mode-map
 493   (setq gnus-browse-mode-map (make-keymap))
 494   (suppress-keymap gnus-browse-mode-map)
 495
 496   (gnus-define-keys
 497    gnus-browse-mode-map
 498    " " gnus-browse-read-group
 499    "=" gnus-browse-select-group
 500    "n" gnus-browse-next-group
 501    "p" gnus-browse-prev-group
 502    "\177" gnus-browse-prev-group
 503    "N" gnus-browse-next-group
 504    "P" gnus-browse-prev-group
 505    "\M-n" gnus-browse-next-group
 506    "\M-p" gnus-browse-prev-group
 507    "\r" gnus-browse-select-group
 508    "u" gnus-browse-unsubscribe-current-group
 509    "l" gnus-browse-exit
 510    "L" gnus-browse-exit
 511    "q" gnus-browse-exit
 512    "Q" gnus-browse-exit
 513    "\C-c\C-c" gnus-browse-exit
 514    "?" gnus-browse-describe-briefly
 515
 516    "\C-c\C-i" gnus-info-find-node
 517    "\C-c\C-b" gnus-bug))
 518
 519 (defun gnus-browse-make-menu-bar ()
 520   (gnus-turn-off-edit-menu 'browse)
 521   (unless (boundp 'gnus-browse-menu)
 522     (easy-menu-define
 523      gnus-browse-menu gnus-browse-mode-map ""
 524      '("Browse"
 525        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 526        ["Read" gnus-browse-read-group t]
 527        ["Select" gnus-browse-read-group t]
 528        ["Next" gnus-browse-next-group t]
 529        ["Prev" gnus-browse-next-group t]
 530        ["Exit" gnus-browse-exit t]
 531        ))
 532     (run-hooks 'gnus-browse-menu-hook)))
 533
 534 (defvar gnus-browse-current-method nil)
 535 (defvar gnus-browse-return-buffer nil)
 536
 537 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 538
 539 (defun gnus-browse-foreign-server (method &optional return-buffer)
 540   "Browse the server METHOD."
 541   (setq gnus-browse-current-method method)
 542   (setq gnus-browse-return-buffer return-buffer)
 543   (let ((gnus-select-method method)
 544         groups group)
 545     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 546     (cond
 547      ((not (gnus-check-server method))
 548       (gnus-message
 549        1 "Unable to contact server: %s" (gnus-status-message method))
 550       nil)
 551      ((not
 552        (prog2
 553            (gnus-message 6 "Reading active file...")
 554            (gnus-request-list method)
 555          (gnus-message 6 "Reading active file...done")))
 556       (gnus-message
 557        1 "Couldn't request list: %s" (gnus-status-message method))
 558       nil)
 559      (t
 560       (get-buffer-create gnus-browse-buffer)
 561       (gnus-add-current-to-buffer-list)
 562       (when gnus-carpal
 563         (gnus-carpal-setup-buffer 'browse))
 564       (gnus-configure-windows 'browse)
 565       (buffer-disable-undo (current-buffer))
 566       (let ((buffer-read-only nil))
 567         (erase-buffer))
 568       (gnus-browse-mode)
 569       (setq mode-line-buffer-identification
 570             (list
 571              (format
 572               "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 573       (save-excursion
 574         (set-buffer nntp-server-buffer)
 575         (let ((cur (current-buffer)))
 576           (goto-char (point-min))
 577           (unless (string= gnus-ignored-newsgroups "")
 578             (delete-matching-lines gnus-ignored-newsgroups))
 579           (while (re-search-forward
 580                   "\\(^[^ \t]+\\)[ \t]+[0-9]+[ \t]+[0-9]+" nil t)
 581             (goto-char (match-end 1))
 582             (push (cons (match-string 1)
 583                         (max 0 (- (1+ (read cur)) (read cur))))
 584                   groups))))
 585       (setq groups (sort groups
 586                          (lambda (l1 l2)
 587                            (string< (car l1) (car l2)))))
 588       (let ((buffer-read-only nil))
 589         (while groups
 590           (setq group (car groups))
 591           (insert
 592            (format "K%7d: %s\n" (cdr group) (car group)))
 593           (setq groups (cdr groups))))
 594       (switch-to-buffer (current-buffer))
 595       (goto-char (point-min))
 596       (gnus-group-position-point)
 597       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 598       t))))
 599
 600 (defun gnus-browse-mode ()
 601   "Major mode for browsing a foreign server.
 602
 603 All normal editing commands are switched off.
 604
 605 \\<gnus-browse-mode-map>
 606 The only things you can do in this buffer is
 607
 608 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 609 The group will be inserted into the group buffer upon exit from this
 610 buffer.
 611
 612 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 613
 614 3) `\\[gnus-browse-exit]' to return to the group buffer."
 615   (interactive)
 616   (kill-all-local-variables)
 617   (when (gnus-visual-p 'browse-menu 'menu)
 618     (gnus-browse-make-menu-bar))
 619   (gnus-simplify-mode-line)
 620   (setq major-mode 'gnus-browse-mode)
 621   (setq mode-name "Browse Server")
 622   (setq mode-line-process nil)
 623   (use-local-map gnus-browse-mode-map)
 624   (buffer-disable-undo (current-buffer))
 625   (setq truncate-lines t)
 626   (gnus-set-default-directory)
 627   (setq buffer-read-only t)
 628   (run-hooks 'gnus-browse-mode-hook))
 629
 630 (defun gnus-browse-read-group (&optional no-article)
 631   "Enter the group at the current line."
 632   (interactive)
 633   (let ((group (gnus-group-real-name (gnus-browse-group-name))))
 634     (unless (gnus-group-read-ephemeral-group
 635              group gnus-browse-current-method nil
 636              (cons (current-buffer) 'browse))
 637       (error "Couldn't enter %s" group))))
 638
 639 (defun gnus-browse-select-group ()
 640   "Select the current group."
 641   (interactive)
 642   (gnus-browse-read-group 'no))
 643
 644 (defun gnus-browse-next-group (n)
 645   "Go to the next group."
 646   (interactive "p")
 647   (prog1
 648       (forward-line n)
 649     (gnus-group-position-point)))
 650
 651 (defun gnus-browse-prev-group (n)
 652   "Go to the next group."
 653   (interactive "p")
 654   (gnus-browse-next-group (- n)))
 655
 656 (defun gnus-browse-unsubscribe-current-group (arg)
 657   "(Un)subscribe to the next ARG groups."
 658   (interactive "p")
 659   (when (eobp)
 660     (error "No group at current line."))
 661   (let ((ward (if (< arg 0) -1 1))
 662         (arg (abs arg)))
 663     (while (and (> arg 0)
 664                 (not (eobp))
 665                 (gnus-browse-unsubscribe-group)
 666                 (zerop (gnus-browse-next-group ward)))
 667       (decf arg))
 668     (gnus-group-position-point)
 669     (when (/= 0 arg)
 670       (gnus-message 7 "No more newsgroups"))
 671     arg))
 672
 673 (defun gnus-browse-group-name ()
 674   (save-excursion
 675     (beginning-of-line)
 676     (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 677       (gnus-group-prefixed-name (match-string 1) gnus-browse-current-method))))
 678
 679 (defun gnus-browse-unsubscribe-group ()
 680   "Toggle subscription of the current group in the browse buffer."
 681   (let ((sub nil)
 682         (buffer-read-only nil)
 683         group)
 684     (save-excursion
 685       (beginning-of-line)
 686       ;; If this group it killed, then we want to subscribe it.
 687       (when (= (following-char) ?K)
 688         (setq sub t))
 689       (setq group (gnus-browse-group-name))
 690       ;; Make sure the group has been properly removed before we
 691       ;; subscribe to it.
 692       (gnus-kill-ephemeral-group group)
 693       (delete-char 1)
 694       (if sub
 695           (progn
 696             (gnus-group-change-level
 697              (list t group gnus-level-default-subscribed
 698                    nil nil gnus-browse-current-method)
 699              gnus-level-default-subscribed gnus-level-killed
 700              (and (car (nth 1 gnus-newsrc-alist))
 701                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 702                                 gnus-newsrc-hashtb))
 703              t)
 704             (insert ? ))
 705         (gnus-group-change-level
 706          group gnus-level-killed gnus-level-default-subscribed)
 707         (insert ?K)))
 708     t))
 709
 710 (defun gnus-browse-exit ()
 711   "Quit browsing and return to the group buffer."
 712   (interactive)
 713   (when (eq major-mode 'gnus-browse-mode)
 714     (kill-buffer (current-buffer)))
 715   ;; Insert the newly subscribed groups in the group buffer.
 716   (save-excursion
 717     (set-buffer gnus-group-buffer)
 718     (gnus-group-list-groups nil))
 719   (if gnus-browse-return-buffer
 720       (gnus-configure-windows 'server 'force)
 721     (gnus-configure-windows 'group 'force)))
 722
 723 (defun gnus-browse-describe-briefly ()
 724   "Give a one line description of the group mode commands."
 725   (interactive)
 726   (gnus-message 6
 727                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 728
 729 (defun gnus-server-regenerate-server ()
 730   "Issue a command to the server to regenerate all its data structures."
 731   (interactive)
 732   (let ((server (gnus-server-server-name)))
 733     (unless server
 734       (error "No server on the current line"))
 735     (if (not (gnus-check-backend-function
 736               'request-regenerate (car (gnus-server-to-method server))))
 737         (error "This backend doesn't support regeneration")
 738       (gnus-message 5 "Requesting regeneration of %s..." server)
 739       (if (gnus-request-regenerate server)
 740           (gnus-message 5 "Requesting regeneration of %s...done" server)
 741         (gnus-message 5 "Couldn't regenerate %s" server)))))
 742
 743 (provide 'gnus-srvr)
 744
 745 ;;; gnus-srvr.el ends here.