cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus-load)
  29 (require 'gnus-spec)
  30 (require 'gnus)
  31 (require 'gnus-group)
  32 (require 'gnus-int)
  33 (require 'gnus-range)
  34
  35 (defvar gnus-server-mode-hook nil
  36   "Hook run in `gnus-server-mode' buffers.")
  37
  38 (defconst gnus-server-line-format "     {%(%h:%w%)} %s\n"
  39   "Format of server lines.
  40 It works along the same lines as a normal formatting string,
  41 with some simple extensions.")
  42
  43 (defvar gnus-server-mode-line-format "Gnus  List of servers"
  44   "The format specification for the server mode line.")
  45
  46 (defvar gnus-server-exit-hook nil
  47   "*Hook run when exiting the server buffer.")
  48
  49 ;;; Internal variables.
  50
  51 (defvar gnus-inserted-opened-servers nil)
  52
  53 (defvar gnus-server-line-format-alist
  54   `((?h how ?s)
  55     (?n name ?s)
  56     (?w where ?s)
  57     (?s status ?s)))
  58
  59 (defvar gnus-server-mode-line-format-alist
  60   `((?S news-server ?s)
  61     (?M news-method ?s)
  62     (?u user-defined ?s)))
  63
  64 (defvar gnus-server-line-format-spec nil)
  65 (defvar gnus-server-mode-line-format-spec nil)
  66 (defvar gnus-server-killed-servers nil)
  67
  68 (defvar gnus-server-mode-map)
  69
  70 (defvar gnus-server-menu-hook nil
  71   "*Hook run after the creation of the server mode menu.")
  72
  73 (defun gnus-server-make-menu-bar ()
  74   (gnus-visual-turn-off-edit-menu 'server)
  75   (unless (boundp 'gnus-server-server-menu)
  76     (easy-menu-define
  77      gnus-server-server-menu gnus-server-mode-map ""
  78      '("Server"
  79        ["Add" gnus-server-add-server t]
  80        ["Browse" gnus-server-read-server t]
  81        ["List" gnus-server-list-servers t]
  82        ["Kill" gnus-server-kill-server t]
  83        ["Yank" gnus-server-yank-server t]
  84        ["Copy" gnus-server-copy-server t]
  85        ["Edit" gnus-server-edit-server t]
  86        ["Exit" gnus-server-exit t]
  87        ))
  88
  89     (easy-menu-define
  90      gnus-server-connections-menu gnus-server-mode-map ""
  91      '("Connections"
  92        ["Open" gnus-server-open-server t]
  93        ["Close" gnus-server-close-server t]
  94        ["Deny" gnus-server-deny-server t]
  95        ["Reset" gnus-server-remove-denials t]
  96        ))
  97
  98     (run-hooks 'gnus-server-menu-hook)))
  99
 100 (defvar gnus-server-mode-map nil)
 101 (put 'gnus-server-mode 'mode-class 'special)
 102
 103 (unless gnus-server-mode-map
 104   (setq gnus-server-mode-map (make-sparse-keymap))
 105   (suppress-keymap gnus-server-mode-map)
 106
 107   (gnus-define-keys
 108    gnus-server-mode-map
 109    " " gnus-server-read-server
 110    "\r" gnus-server-read-server
 111    gnus-mouse-2 gnus-server-pick-server
 112    "q" gnus-server-exit
 113    "l" gnus-server-list-servers
 114    "k" gnus-server-kill-server
 115    "y" gnus-server-yank-server
 116    "c" gnus-server-copy-server
 117    "a" gnus-server-add-server
 118    "e" gnus-server-edit-server
 119
 120    "O" gnus-server-open-server
 121    "C" gnus-server-close-server
 122    "D" gnus-server-deny-server
 123    "R" gnus-server-remove-denials
 124
 125     "\C-c\C-i" gnus-info-find-node))
 126
 127 (defun gnus-server-mode ()
 128   "Major mode for listing and editing servers.
 129
 130 All normal editing commands are switched off.
 131 \\<gnus-server-mode-map>
 132 For more in-depth information on this mode, read the manual
 133 (`\\[gnus-info-find-node]').
 134
 135 The following commands are available:
 136
 137 \\{gnus-server-mode-map}"
 138   (interactive)
 139   (when (and menu-bar-mode
 140              (gnus-visual-p 'server-menu 'menu))
 141     (gnus-server-make-menu-bar))
 142   (kill-all-local-variables)
 143   (gnus-simplify-mode-line)
 144   (setq major-mode 'gnus-server-mode)
 145   (setq mode-name "Server")
 146                                         ;  (gnus-group-set-mode-line)
 147   (setq mode-line-process nil)
 148   (use-local-map gnus-server-mode-map)
 149   (buffer-disable-undo (current-buffer))
 150   (setq truncate-lines t)
 151   (setq buffer-read-only t)
 152   (run-hooks 'gnus-server-mode-hook))
 153
 154 (defun gnus-server-insert-server-line (name method)
 155   (let* ((how (car method))
 156          (where (nth 1 method))
 157          (elem (assoc method gnus-opened-servers))
 158          (status (cond ((eq (nth 1 elem) 'denied)
 159                         "(denied)")
 160                        ((or (gnus-server-opened method)
 161                             (eq (nth 1 elem) 'ok))
 162                         "(opened)")
 163                        (t
 164                         "(closed)"))))
 165     (beginning-of-line)
 166     (gnus-add-text-properties
 167      (point)
 168      (prog1 (1+ (point))
 169        ;; Insert the text.
 170        (eval gnus-server-line-format-spec))
 171      (list 'gnus-server (intern name)))))
 172
 173 (defun gnus-enter-server-buffer ()
 174   "Set up the server buffer."
 175   (gnus-server-setup-buffer)
 176   (gnus-configure-windows 'server)
 177   (gnus-server-prepare))
 178
 179 (defun gnus-server-setup-buffer ()
 180   "Initialize the server buffer."
 181   (unless (get-buffer gnus-server-buffer)
 182     (save-excursion
 183       (set-buffer (get-buffer-create gnus-server-buffer))
 184       (gnus-server-mode)
 185       (when gnus-carpal
 186         (gnus-carpal-setup-buffer 'server)))))
 187
 188 (defun gnus-server-prepare ()
 189   (setq gnus-server-mode-line-format-spec
 190         (gnus-parse-format gnus-server-mode-line-format
 191                            gnus-server-mode-line-format-alist))
 192   (setq gnus-server-line-format-spec
 193         (gnus-parse-format gnus-server-line-format
 194                            gnus-server-line-format-alist t))
 195   (let ((alist gnus-server-alist)
 196         (buffer-read-only nil)
 197         (opened gnus-opened-servers)
 198         done server op-ser)
 199     (erase-buffer)
 200     (setq gnus-inserted-opened-servers nil)
 201     ;; First we do the real list of servers.
 202     (while alist
 203       (push (cdr (setq server (pop alist))) done)
 204       (when (and server (car server) (cdr server))
 205         (gnus-server-insert-server-line (car server) (cdr server))))
 206     ;; Then we insert the list of servers that have been opened in
 207     ;; this session.
 208     (while opened
 209       (unless (member (caar opened) done)
 210         (gnus-server-insert-server-line
 211          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 212          (caar opened))
 213         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 214       (setq opened (cdr opened))))
 215   (goto-char (point-min))
 216   (gnus-server-position-point))
 217
 218 (defun gnus-server-server-name ()
 219   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 220     (and server (symbol-name server))))
 221
 222 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 223
 224 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 225
 226 (defun gnus-server-update-server (server)
 227   (save-excursion
 228     (set-buffer gnus-server-buffer)
 229     (let* ((buffer-read-only nil)
 230            (entry (assoc server gnus-server-alist))
 231            (oentry (assoc (gnus-server-to-method server)
 232                           gnus-opened-servers)))
 233       (when entry
 234         (gnus-dribble-enter
 235          (concat "(gnus-server-set-info \"" server "\" '"
 236                  (prin1-to-string (cdr entry)) ")")))
 237       (when (or entry oentry)
 238         ;; Buffer may be narrowed.
 239         (save-restriction
 240           (widen)
 241           (when (gnus-server-goto-server server)
 242             (gnus-delete-line))
 243           (if entry
 244               (gnus-server-insert-server-line (car entry) (cdr entry))
 245             (gnus-server-insert-server-line
 246              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 247              (car oentry)))
 248           (gnus-server-position-point))))))
 249
 250 (defun gnus-server-set-info (server info)
 251   ;; Enter a select method into the virtual server alist.
 252   (when (and server info)
 253     (gnus-dribble-enter
 254      (concat "(gnus-server-set-info \"" server "\" '"
 255              (prin1-to-string info) ")"))
 256     (let* ((server (nth 1 info))
 257            (entry (assoc server gnus-server-alist)))
 258       (if entry (setcdr entry info)
 259         (setq gnus-server-alist
 260               (nconc gnus-server-alist (list (cons server info))))))))
 261
 262 ;;; Interactive server functions.
 263
 264 (defun gnus-server-kill-server (server)
 265   "Kill the server on the current line."
 266   (interactive (list (gnus-server-server-name)))
 267   (unless (gnus-server-goto-server server)
 268     (if server (error "No such server: %s" server)
 269       (error "No server on the current line")))
 270   (unless (assoc server gnus-server-alist)
 271     (error "Read-only server %s" server))
 272   (gnus-dribble-enter "")
 273   (let ((buffer-read-only nil))
 274     (gnus-delete-line))
 275   (setq gnus-server-killed-servers
 276         (cons (assoc server gnus-server-alist) gnus-server-killed-servers))
 277   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 278                                 gnus-server-alist))
 279   (gnus-server-position-point))
 280
 281 (defun gnus-server-yank-server ()
 282   "Yank the previously killed server."
 283   (interactive)
 284   (or gnus-server-killed-servers
 285       (error "No killed servers to be yanked"))
 286   (let ((alist gnus-server-alist)
 287         (server (gnus-server-server-name))
 288         (killed (car gnus-server-killed-servers)))
 289     (if (not server)
 290         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 291       (if (string= server (caar gnus-server-alist))
 292           (setq gnus-server-alist (cons killed gnus-server-alist))
 293         (while (and (cdr alist)
 294                     (not (string= server (caadr alist))))
 295           (setq alist (cdr alist)))
 296         (if alist
 297             (setcdr alist (cons killed (cdr alist)))
 298           (setq gnus-server-alist (list killed)))))
 299     (gnus-server-update-server (car killed))
 300     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 301     (gnus-server-position-point)))
 302
 303 (defun gnus-server-exit ()
 304   "Return to the group buffer."
 305   (interactive)
 306   (kill-buffer (current-buffer))
 307   (switch-to-buffer gnus-group-buffer)
 308   (run-hooks 'gnus-server-exit-hook))
 309
 310 (defun gnus-server-list-servers ()
 311   "List all available servers."
 312   (interactive)
 313   (let ((cur (gnus-server-server-name)))
 314     (gnus-server-prepare)
 315     (if cur (gnus-server-goto-server cur)
 316       (goto-char (point-max))
 317       (forward-line -1))
 318     (gnus-server-position-point)))
 319
 320 (defun gnus-server-set-status (method status)
 321   "Make METHOD have STATUS."
 322   (let ((entry (assoc method gnus-opened-servers)))
 323     (if entry
 324         (setcar (cdr entry) status)
 325       (push (list method status) gnus-opened-servers))))
 326
 327 (defun gnus-opened-servers-remove (method)
 328   "Remove METHOD from the list of opened servers."
 329   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 330                                   gnus-opened-servers)))
 331
 332 (defun gnus-server-open-server (server)
 333   "Force an open of SERVER."
 334   (interactive (list (gnus-server-server-name)))
 335   (let ((method (gnus-server-to-method server)))
 336     (or method (error "No such server: %s" server))
 337     (gnus-server-set-status method 'ok)
 338     (prog1
 339         (or (gnus-open-server method)
 340             (progn (message "Couldn't open %s" server) nil))
 341       (gnus-server-update-server server)
 342       (gnus-server-position-point))))
 343
 344 (defun gnus-server-close-server (server)
 345   "Close SERVER."
 346   (interactive (list (gnus-server-server-name)))
 347   (let ((method (gnus-server-to-method server)))
 348     (or method (error "No such server: %s" server))
 349     (gnus-server-set-status method 'closed)
 350     (prog1
 351         (gnus-close-server method)
 352       (gnus-server-update-server server)
 353       (gnus-server-position-point))))
 354
 355 (defun gnus-server-deny-server (server)
 356   "Make sure SERVER will never be attempted opened."
 357   (interactive (list (gnus-server-server-name)))
 358   (let ((method (gnus-server-to-method server)))
 359     (or method (error "No such server: %s" server))
 360     (gnus-server-set-status method 'denied))
 361   (gnus-server-update-server server)
 362   (gnus-server-position-point)
 363   t)
 364
 365 (defun gnus-server-remove-denials ()
 366   "Make all denied servers into closed servers."
 367   (interactive)
 368   (let ((servers gnus-opened-servers))
 369     (while servers
 370       (when (eq (nth 1 (car servers)) 'denied)
 371         (setcar (nthcdr 1 (car servers)) 'closed))
 372       (setq servers (cdr servers))))
 373   (gnus-server-list-servers))
 374
 375 (defun gnus-server-copy-server (from to)
 376   (interactive
 377    (list
 378     (or (gnus-server-server-name)
 379         (error "No server on the current line"))
 380     (read-string "Copy to: ")))
 381   (or from (error "No server on current line"))
 382   (or (and to (not (string= to ""))) (error "No name to copy to"))
 383   (and (assoc to gnus-server-alist) (error "%s already exists" to))
 384   (or (assoc from gnus-server-alist)
 385       (error "%s: no such server" from))
 386   (let ((to-entry (gnus-copy-sequence (assoc from gnus-server-alist))))
 387     (setcar to-entry to)
 388     (setcar (nthcdr 2 to-entry) to)
 389     (setq gnus-server-killed-servers
 390           (cons to-entry gnus-server-killed-servers))
 391     (gnus-server-yank-server)))
 392
 393 (defun gnus-server-add-server (how where)
 394   (interactive
 395    (list (intern (completing-read "Server method: "
 396                                   gnus-valid-select-methods nil t))
 397          (read-string "Server name: ")))
 398   (setq gnus-server-killed-servers
 399         (cons (list where how where) gnus-server-killed-servers))
 400   (gnus-server-yank-server))
 401
 402 (defun gnus-server-goto-server (server)
 403   "Jump to a server line."
 404   (interactive
 405    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 406   (let ((to (text-property-any (point-min) (point-max)
 407                                'gnus-server (intern server))))
 408     (and to
 409          (progn
 410            (goto-char to)
 411            (gnus-server-position-point)))))
 412
 413 (defun gnus-server-edit-server (server)
 414   "Edit the server on the current line."
 415   (interactive (list (gnus-server-server-name)))
 416   (unless server
 417     (error "No server on current line"))
 418   (unless (assoc server gnus-server-alist)
 419     (error "This server can't be edited"))
 420   (let ((winconf (current-window-configuration))
 421         (info (cdr (assoc server gnus-server-alist))))
 422     (gnus-close-server info)
 423     (get-buffer-create gnus-server-edit-buffer)
 424     (gnus-configure-windows 'edit-server)
 425     (gnus-add-current-to-buffer-list)
 426     (emacs-lisp-mode)
 427     (make-local-variable 'gnus-prev-winconf)
 428     (setq gnus-prev-winconf winconf)
 429     (use-local-map (copy-keymap (current-local-map)))
 430     (let ((done-func '(lambda ()
 431                         "Exit editing mode and update the information."
 432                         (interactive)
 433                         (gnus-server-edit-server-done 'group))))
 434       (setcar (cdr (nth 4 done-func)) server)
 435       (local-set-key "\C-c\C-c" done-func))
 436     (erase-buffer)
 437     (insert ";; Type `C-c C-c' after you have edited the server.\n\n")
 438     (insert (pp-to-string info))))
 439
 440 (defun gnus-server-edit-server-done (server)
 441   (interactive)
 442   (set-buffer (get-buffer-create gnus-server-edit-buffer))
 443   (goto-char (point-min))
 444   (let ((form (read (current-buffer)))
 445         (winconf gnus-prev-winconf))
 446     (gnus-server-set-info server form)
 447     (kill-buffer (current-buffer))
 448     (and winconf (set-window-configuration winconf))
 449     (set-buffer gnus-server-buffer)
 450     (gnus-server-update-server server)
 451     (gnus-server-list-servers)
 452     (gnus-server-position-point)))
 453
 454 (defun gnus-server-read-server (server)
 455   "Browse a server."
 456   (interactive (list (gnus-server-server-name)))
 457   (let ((buf (current-buffer)))
 458     (prog1
 459         (gnus-browse-foreign-server (gnus-server-to-method server) buf)
 460       (save-excursion
 461         (set-buffer buf)
 462         (gnus-server-update-server (gnus-server-server-name))
 463         (gnus-server-position-point)))))
 464
 465 (defun gnus-server-pick-server (e)
 466   (interactive "e")
 467   (mouse-set-point e)
 468   (gnus-server-read-server (gnus-server-server-name)))
 469
 470 \f
 471 ;;;
 472 ;;; Browse Server Mode
 473 ;;;
 474
 475 (defvar gnus-browse-menu-hook nil
 476   "*Hook run after the creation of the browse mode menu.")
 477
 478 (defvar gnus-browse-mode-hook nil)
 479 (defvar gnus-browse-mode-map nil)
 480 (put 'gnus-browse-mode 'mode-class 'special)
 481
 482 (unless gnus-browse-mode-map
 483   (setq gnus-browse-mode-map (make-keymap))
 484   (suppress-keymap gnus-browse-mode-map)
 485
 486   (gnus-define-keys
 487    gnus-browse-mode-map
 488    " " gnus-browse-read-group
 489    "=" gnus-browse-select-group
 490    "n" gnus-browse-next-group
 491    "p" gnus-browse-prev-group
 492    "\177" gnus-browse-prev-group
 493    "N" gnus-browse-next-group
 494    "P" gnus-browse-prev-group
 495    "\M-n" gnus-browse-next-group
 496    "\M-p" gnus-browse-prev-group
 497    "\r" gnus-browse-select-group
 498    "u" gnus-browse-unsubscribe-current-group
 499    "l" gnus-browse-exit
 500    "L" gnus-browse-exit
 501    "q" gnus-browse-exit
 502    "Q" gnus-browse-exit
 503    "\C-c\C-c" gnus-browse-exit
 504    "?" gnus-browse-describe-briefly
 505
 506    "\C-c\C-i" gnus-info-find-node))
 507
 508 (defun gnus-browse-make-menu-bar ()
 509   (gnus-visual-turn-off-edit-menu 'browse)
 510   (or
 511    (boundp 'gnus-browse-menu)
 512    (progn
 513      (easy-menu-define
 514       gnus-browse-menu gnus-browse-mode-map ""
 515       '("Browse"
 516         ["Subscribe" gnus-browse-unsubscribe-current-group t]
 517         ["Read" gnus-browse-read-group t]
 518         ["Select" gnus-browse-read-group t]
 519         ["Next" gnus-browse-next-group t]
 520         ["Prev" gnus-browse-next-group t]
 521         ["Exit" gnus-browse-exit t]
 522         ))
 523       (run-hooks 'gnus-browse-menu-hook))))
 524
 525 (defvar gnus-browse-current-method nil)
 526 (defvar gnus-browse-return-buffer nil)
 527
 528 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 529
 530 (defun gnus-browse-foreign-server (method &optional return-buffer)
 531   "Browse the server METHOD."
 532   (setq gnus-browse-current-method method)
 533   (setq gnus-browse-return-buffer return-buffer)
 534   (let ((gnus-select-method method)
 535         groups group)
 536     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 537     (cond
 538      ((not (gnus-check-server method))
 539       (gnus-message
 540        1 "Unable to contact server: %s" (gnus-status-message method))
 541       nil)
 542      ((not (gnus-request-list method))
 543       (gnus-message
 544        1 "Couldn't request list: %s" (gnus-status-message method))
 545       nil)
 546      (t
 547       (get-buffer-create gnus-browse-buffer)
 548       (gnus-add-current-to-buffer-list)
 549       (and gnus-carpal (gnus-carpal-setup-buffer 'browse))
 550       (gnus-configure-windows 'browse)
 551       (buffer-disable-undo (current-buffer))
 552       (let ((buffer-read-only nil))
 553         (erase-buffer))
 554       (gnus-browse-mode)
 555       (setq mode-line-buffer-identification
 556             (list
 557              (format
 558               "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 559       (save-excursion
 560         (set-buffer nntp-server-buffer)
 561         (let ((cur (current-buffer)))
 562           (goto-char (point-min))
 563           (or (string= gnus-ignored-newsgroups "")
 564               (delete-matching-lines gnus-ignored-newsgroups))
 565           (while (re-search-forward
 566                   "\\(^[^ \t]+\\)[ \t]+[0-9]+[ \t]+[0-9]+" nil t)
 567             (goto-char (match-end 1))
 568             (setq groups (cons (cons (match-string 1)
 569                                      (max 0 (- (1+ (read cur)) (read cur))))
 570                                groups)))))
 571       (setq groups (sort groups
 572                          (lambda (l1 l2)
 573                            (string< (car l1) (car l2)))))
 574       (let ((buffer-read-only nil))
 575         (while groups
 576           (setq group (car groups))
 577           (insert
 578            (format "K%7d: %s\n" (cdr group) (car group)))
 579           (setq groups (cdr groups))))
 580       (switch-to-buffer (current-buffer))
 581       (goto-char (point-min))
 582       (gnus-group-position-point)
 583       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 584       t))))
 585
 586 (defun gnus-browse-mode ()
 587   "Major mode for browsing a foreign server.
 588
 589 All normal editing commands are switched off.
 590
 591 \\<gnus-browse-mode-map>
 592 The only things you can do in this buffer is
 593
 594 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 595 The group will be inserted into the group buffer upon exit from this
 596 buffer.
 597
 598 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 599
 600 3) `\\[gnus-browse-exit]' to return to the group buffer."
 601   (interactive)
 602   (kill-all-local-variables)
 603   (when (and menu-bar-mode
 604              (gnus-visual-p 'browse-menu 'menu))
 605     (gnus-browse-make-menu-bar))
 606   (gnus-simplify-mode-line)
 607   (setq major-mode 'gnus-browse-mode)
 608   (setq mode-name "Browse Server")
 609   (setq mode-line-process nil)
 610   (use-local-map gnus-browse-mode-map)
 611   (buffer-disable-undo (current-buffer))
 612   (setq truncate-lines t)
 613   (setq buffer-read-only t)
 614   (run-hooks 'gnus-browse-mode-hook))
 615
 616 (defun gnus-browse-read-group (&optional no-article)
 617   "Enter the group at the current line."
 618   (interactive)
 619   (let ((group (gnus-browse-group-name)))
 620     (or (gnus-group-read-ephemeral-group
 621          group gnus-browse-current-method nil
 622          (cons (current-buffer) 'browse))
 623         (error "Couldn't enter %s" group))))
 624
 625 (defun gnus-browse-select-group ()
 626   "Select the current group."
 627   (interactive)
 628   (gnus-browse-read-group 'no))
 629
 630 (defun gnus-browse-next-group (n)
 631   "Go to the next group."
 632   (interactive "p")
 633   (prog1
 634       (forward-line n)
 635     (gnus-group-position-point)))
 636
 637 (defun gnus-browse-prev-group (n)
 638   "Go to the next group."
 639   (interactive "p")
 640   (gnus-browse-next-group (- n)))
 641
 642 (defun gnus-browse-unsubscribe-current-group (arg)
 643   "(Un)subscribe to the next ARG groups."
 644   (interactive "p")
 645   (when (eobp)
 646     (error "No group at current line."))
 647   (let ((ward (if (< arg 0) -1 1))
 648         (arg (abs arg)))
 649     (while (and (> arg 0)
 650                 (not (eobp))
 651                 (gnus-browse-unsubscribe-group)
 652                 (zerop (gnus-browse-next-group ward)))
 653       (decf arg))
 654     (gnus-group-position-point)
 655     (if (/= 0 arg) (gnus-message 7 "No more newsgroups"))
 656     arg))
 657
 658 (defun gnus-browse-group-name ()
 659   (save-excursion
 660     (beginning-of-line)
 661     (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 662       (gnus-group-prefixed-name (match-string 1) gnus-browse-current-method))))
 663
 664 (defun gnus-browse-unsubscribe-group ()
 665   "Toggle subscription of the current group in the browse buffer."
 666   (let ((sub nil)
 667         (buffer-read-only nil)
 668         group)
 669     (save-excursion
 670       (beginning-of-line)
 671       ;; If this group it killed, then we want to subscribe it.
 672       (if (= (following-char) ?K) (setq sub t))
 673       (setq group (gnus-browse-group-name))
 674       (delete-char 1)
 675       (if sub
 676           (progn
 677             (gnus-group-change-level
 678              (list t group gnus-level-default-subscribed
 679                    nil nil gnus-browse-current-method)
 680              gnus-level-default-subscribed gnus-level-killed
 681              (and (car (nth 1 gnus-newsrc-alist))
 682                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 683                                 gnus-newsrc-hashtb))
 684              t)
 685             (insert ? ))
 686         (gnus-group-change-level
 687          group gnus-level-killed gnus-level-default-subscribed)
 688         (insert ?K)))
 689     t))
 690
 691 (defun gnus-browse-exit ()
 692   "Quit browsing and return to the group buffer."
 693   (interactive)
 694   (when (eq major-mode 'gnus-browse-mode)
 695     (kill-buffer (current-buffer)))
 696   ;; Insert the newly subscribed groups in the group buffer.
 697   (save-excursion
 698     (set-buffer gnus-group-buffer)
 699     (gnus-group-list-groups nil))
 700   (if gnus-browse-return-buffer
 701       (gnus-configure-windows 'server 'force)
 702     (gnus-configure-windows 'group 'force)))
 703
 704 (defun gnus-browse-describe-briefly ()
 705   "Give a one line description of the group mode commands."
 706   (interactive)
 707   (gnus-message 6
 708                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 709
 710 (provide 'gnus-srvr)
 711
 712 ;;; gnus-srvr.el ends here.