cgit.sxemacs.org Git - gnus/blob - lisp/gnus-score.el

   1 ;;; gnus-score.el --- scoring code for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Per Abrahamsen <amanda@iesd.auc.dk>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-sum)
  33 (require 'gnus-range)
  34 (require 'gnus-win)
  35 (require 'message)
  36 (require 'score-mode)
  37
  38 (defcustom gnus-global-score-files nil
  39   "List of global score files and directories.
  40 Set this variable if you want to use people's score files.  One entry
  41 for each score file or each score file directory.  Gnus will decide
  42 by itself what score files are applicable to which group.
  43
  44 Say you want to use the single score file
  45 \"/ftp.gnus.org@ftp:/pub/larsi/ding/score/soc.motss.SCORE\" and all
  46 score files in the \"/ftp.some-where:/pub/score\" directory.
  47
  48  (setq gnus-global-score-files
  49        '(\"/ftp.gnus.org:/pub/larsi/ding/score/soc.motss.SCORE\"
  50          \"/ftp.some-where:/pub/score\"))"
  51   :group 'gnus-score-files
  52   :type '(repeat file))
  53
  54 (defcustom gnus-score-file-single-match-alist nil
  55   "Alist mapping regexps to lists of score files.
  56 Each element of this alist should be of the form
  57         (\"REGEXP\" [ \"SCORE-FILE-1\" ] [ \"SCORE-FILE-2\" ] ... )
  58
  59 If the name of a group is matched by REGEXP, the corresponding scorefiles
  60 will be used for that group.
  61 The first match found is used, subsequent matching entries are ignored (to
  62 use multiple matches, see `gnus-score-file-multiple-match-alist').
  63
  64 These score files are loaded in addition to any files returned by
  65 `gnus-score-find-score-files-function'."
  66   :group 'gnus-score-files
  67   :type '(repeat (cons regexp (repeat file))))
  68
  69 (defcustom gnus-score-file-multiple-match-alist nil
  70   "Alist mapping regexps to lists of score files.
  71 Each element of this alist should be of the form
  72         (\"REGEXP\" [ \"SCORE-FILE-1\" ] [ \"SCORE-FILE-2\" ] ... )
  73
  74 If the name of a group is matched by REGEXP, the corresponding scorefiles
  75 will be used for that group.
  76 If multiple REGEXPs match a group, the score files corresponding to each
  77 match will be used (for only one match to be used, see
  78 `gnus-score-file-single-match-alist').
  79
  80 These score files are loaded in addition to any files returned by
  81 `gnus-score-find-score-files-function'."
  82   :group 'gnus-score-files
  83   :type '(repeat (cons regexp (repeat file))))
  84
  85 (defcustom gnus-score-file-suffix "SCORE"
  86   "Suffix of the score files."
  87   :group 'gnus-score-files
  88   :type 'string)
  89
  90 (defcustom gnus-adaptive-file-suffix "ADAPT"
  91   "Suffix of the adaptive score files."
  92   :group 'gnus-score-files
  93   :group 'gnus-score-adapt
  94   :type 'string)
  95
  96 (defcustom gnus-score-find-score-files-function 'gnus-score-find-bnews
  97   "Function used to find score files.
  98 The function will be called with the group name as the argument, and
  99 should return a list of score files to apply to that group.  The score
 100 files do not actually have to exist.
 101
 102 Predefined values are:
 103
 104 `gnus-score-find-single': Only apply the group's own score file.
 105 `gnus-score-find-hierarchical': Also apply score files from parent groups.
 106 `gnus-score-find-bnews': Apply score files whose names matches.
 107
 108 See the documentation to these functions for more information.
 109
 110 This variable can also be a list of functions to be called.  Each
 111 function is given the group name as argument and should either return
 112 a list of score files, or a list of score alists.
 113
 114 If functions other than these pre-defined functions are used,
 115 the `a' symbolic prefix to the score commands will always use
 116 \"all.SCORE\"."
 117   :group 'gnus-score-files
 118   :type '(radio (function-item gnus-score-find-single)
 119                 (function-item gnus-score-find-hierarchical)
 120                 (function-item gnus-score-find-bnews)
 121                 (repeat :tag "List of functions"
 122                         (choice (function :tag "Other" :value 'ignore)
 123                                 (function-item gnus-score-find-single)
 124                                 (function-item gnus-score-find-hierarchical)
 125                                 (function-item gnus-score-find-bnews)))
 126                 (function :tag "Other" :value 'ignore)))
 127
 128 (defcustom gnus-score-interactive-default-score 1000
 129   "*Scoring commands will raise/lower the score with this number as the default."
 130   :group 'gnus-score-default
 131   :type 'integer)
 132
 133 (defcustom gnus-score-expiry-days 7
 134   "*Number of days before unused score file entries are expired.
 135 If this variable is nil, no score file entries will be expired."
 136   :group 'gnus-score-expire
 137   :type '(choice (const :tag "never" nil)
 138                  number))
 139
 140 (defcustom gnus-update-score-entry-dates t
 141   "*If non-nil, update matching score entry dates.
 142 If this variable is nil, then score entries that provide matches
 143 will be expired along with non-matching score entries."
 144   :group 'gnus-score-expire
 145   :type 'boolean)
 146
 147 (defcustom gnus-decay-scores nil
 148   "*If non-nil, decay non-permanent scores.
 149
 150 If it is a regexp, only decay score files matching regexp."
 151   :group 'gnus-score-decay
 152   :type `(choice (const :tag "never" nil)
 153                  (const :tag "always" t)
 154                  (const :tag "adaptive score files"
 155                         ,(concat "\\." gnus-adaptive-file-suffix "\\'"))
 156                  (regexp)))
 157
 158 (defcustom gnus-decay-score-function 'gnus-decay-score
 159   "*Function called to decay a score.
 160 It is called with one parameter -- the score to be decayed."
 161   :group 'gnus-score-decay
 162   :type '(radio (function-item gnus-decay-score)
 163                 (function :tag "Other")))
 164
 165 (defcustom gnus-score-decay-constant 3
 166   "*Decay all \"small\" scores with this amount."
 167   :group 'gnus-score-decay
 168   :type 'integer)
 169
 170 (defcustom gnus-score-decay-scale .05
 171   "*Decay all \"big\" scores with this factor."
 172   :group 'gnus-score-decay
 173   :type 'number)
 174
 175 (defcustom gnus-home-score-file nil
 176   "Variable to control where interactive score entries are to go.
 177 It can be:
 178
 179  * A string
 180    This file will be used as the home score file.
 181
 182  * A function
 183    The result of this function will be used as the home score file.
 184    The function will be passed the name of the group as its
 185    parameter.
 186
 187  * A list
 188    The elements in this list can be:
 189
 190    * `(regexp file-name ...)'
 191      If the `regexp' matches the group name, the first `file-name'
 192      will be used as the home score file.  (Multiple filenames are
 193      allowed so that one may use gnus-score-file-single-match-alist to
 194      set this variable.)
 195
 196    * A function.
 197      If the function returns non-nil, the result will be used
 198      as the home score file.  The function will be passed the
 199      name of the group as its parameter.
 200
 201    * A string.  Use the string as the home score file.
 202
 203    The list will be traversed from the beginning towards the end looking
 204    for matches."
 205   :group 'gnus-score-files
 206   :type '(choice string
 207                  (repeat (choice string
 208                                  (cons regexp (repeat file))
 209                                  function))
 210                  (function-item gnus-hierarchial-home-score-file)
 211                  (function-item gnus-current-home-score-file)
 212                  function))
 213
 214 (defcustom gnus-home-adapt-file nil
 215   "Variable to control where new adaptive score entries are to go.
 216 This variable allows the same syntax as `gnus-home-score-file'."
 217   :group 'gnus-score-adapt
 218   :group 'gnus-score-files
 219   :type '(choice string
 220                  (repeat (choice string
 221                                  (cons regexp (repeat file))
 222                                  function))
 223                  function))
 224
 225 (defcustom gnus-default-adaptive-score-alist
 226   `((gnus-kill-file-mark)
 227     (gnus-unread-mark)
 228     (gnus-read-mark
 229      (from , (+ 2 gnus-score-decay-constant))
 230      (subject , (+ 27 gnus-score-decay-constant)))
 231     (gnus-catchup-mark
 232      (subject , (+ -7 (* -1 gnus-score-decay-constant))))
 233     (gnus-killed-mark
 234      (from , (- -1 gnus-score-decay-constant))
 235      (subject , (+ -17 (* -1 gnus-score-decay-constant))))
 236     (gnus-del-mark
 237      (from , (- -1 gnus-score-decay-constant))
 238      (subject , (+ -12 (* -1 gnus-score-decay-constant)))))
 239   "Alist of marks and scores.
 240 If you use score decays, you might want to set values higher than
 241 `gnus-score-decay-constant'."
 242   :group 'gnus-score-adapt
 243   :type '(repeat (cons (symbol :tag "Mark")
 244                        (repeat (list (choice :tag "Header"
 245                                              (const from)
 246                                              (const subject)
 247                                              (symbol :tag "other"))
 248                                      (integer :tag "Score"))))))
 249
 250 (defcustom gnus-adaptive-word-length-limit nil
 251   "*Words of a length lesser than this limit will be ignored when doing adaptive scoring."
 252   :version "22.1"
 253   :group 'gnus-score-adapt
 254   :type '(radio (const :format "Unlimited " nil)
 255                 (integer :format "Maximum length: %v")))
 256
 257 (defcustom gnus-ignored-adaptive-words nil
 258   "List of words to be ignored when doing adaptive word scoring."
 259   :group 'gnus-score-adapt
 260   :type '(repeat string))
 261
 262 (defcustom gnus-default-ignored-adaptive-words
 263   '("a" "i" "the" "to" "of" "and" "in" "is" "it" "for" "that" "if" "you"
 264     "this" "be" "on" "with" "not" "have" "are" "or" "as" "from" "can"
 265     "but" "by" "at" "an" "will" "no" "all" "was" "do" "there" "my" "one"
 266     "so" "we" "they" "what" "would" "any" "which" "about" "get" "your"
 267     "use" "some" "me" "then" "name" "like" "out" "when" "up" "time"
 268     "other" "more" "only" "just" "end" "also" "know" "how" "new" "should"
 269     "been" "than" "them" "he" "who" "make" "may" "people" "these" "now"
 270     "their" "here" "into" "first" "could" "way" "had" "see" "work" "well"
 271     "were" "two" "very" "where" "while" "us" "because" "good" "same"
 272     "even" "much" "most" "many" "such" "long" "his" "over" "last" "since"
 273     "right" "before" "our" "without" "too" "those" "why" "must" "part"
 274     "being" "current" "back" "still" "go" "point" "value" "each" "did"
 275     "both" "true" "off" "say" "another" "state" "might" "under" "start"
 276     "try" "re")
 277   "*Default list of words to be ignored when doing adaptive word scoring."
 278   :group 'gnus-score-adapt
 279   :type '(repeat string))
 280
 281 (defcustom gnus-default-adaptive-word-score-alist
 282   `((,gnus-read-mark . 30)
 283     (,gnus-catchup-mark . -10)
 284     (,gnus-killed-mark . -20)
 285     (,gnus-del-mark . -15))
 286   "*Alist of marks and scores."
 287   :group 'gnus-score-adapt
 288   :type '(repeat (cons (character :tag "Mark")
 289                        (integer :tag "Score"))))
 290
 291 (defcustom gnus-adaptive-word-minimum nil
 292   "If a number, this is the minimum score value that can be assigned to a word."
 293   :group 'gnus-score-adapt
 294   :type '(choice (const nil) integer))
 295
 296 (defcustom gnus-adaptive-word-no-group-words nil
 297   "If t, don't adaptively score words included in the group name."
 298   :group 'gnus-score-adapt
 299   :type 'boolean)
 300
 301 (defcustom gnus-score-mimic-keymap nil
 302   "*Have the score entry functions pretend that they are a keymap."
 303   :group 'gnus-score-default
 304   :type 'boolean)
 305
 306 (defcustom gnus-score-exact-adapt-limit 10
 307   "*Number that says how long a match has to be before using substring matching.
 308 When doing adaptive scoring, one normally uses fuzzy or substring
 309 matching.  However, if the header one matches is short, the possibility
 310 for false positives is great, so if the length of the match is less
 311 than this variable, exact matching will be used.
 312
 313 If this variable is nil, exact matching will always be used."
 314   :group 'gnus-score-adapt
 315   :type '(choice (const nil) integer))
 316
 317 (defcustom gnus-score-uncacheable-files "ADAPT$"
 318   "All score files that match this regexp will not be cached."
 319   :group 'gnus-score-adapt
 320   :group 'gnus-score-files
 321   :type 'regexp)
 322
 323 (defcustom gnus-adaptive-pretty-print nil
 324   "If non-nil, adaptive score files fill are pretty printed."
 325   :group 'gnus-score-files
 326   :group 'gnus-score-adapt
 327   :version "23.1" ;; No Gnus
 328   :type 'boolean)
 329
 330 (defcustom gnus-score-default-header nil
 331   "Default header when entering new scores.
 332
 333 Should be one of the following symbols.
 334
 335  a: from
 336  s: subject
 337  b: body
 338  h: head
 339  i: message-id
 340  t: references
 341  x: xref
 342  e: `extra' (non-standard overview)
 343  l: lines
 344  d: date
 345  f: followup
 346
 347 If nil, the user will be asked for a header."
 348   :group 'gnus-score-default
 349   :type '(choice (const :tag "from" a)
 350                  (const :tag "subject" s)
 351                  (const :tag "body" b)
 352                  (const :tag "head" h)
 353                  (const :tag "message-id" i)
 354                  (const :tag "references" t)
 355                  (const :tag "xref" x)
 356                  (const :tag "extra" e)
 357                  (const :tag "lines" l)
 358                  (const :tag "date" d)
 359                  (const :tag "followup" f)
 360                  (const :tag "ask" nil)))
 361
 362 (defcustom gnus-score-default-type nil
 363   "Default match type when entering new scores.
 364
 365 Should be one of the following symbols.
 366
 367  s: substring
 368  e: exact string
 369  f: fuzzy string
 370  r: regexp string
 371  b: before date
 372  a: after date
 373  n: this date
 374  <: less than number
 375  >: greater than number
 376  =: equal to number
 377
 378 If nil, the user will be asked for a match type."
 379   :group 'gnus-score-default
 380   :type '(choice (const :tag "substring" s)
 381                  (const :tag "exact string" e)
 382                  (const :tag "fuzzy string" f)
 383                  (const :tag "regexp string" r)
 384                  (const :tag "before date" b)
 385                  (const :tag "after date" a)
 386                  (const :tag "this date" n)
 387                  (const :tag "less than number" <)
 388                  (const :tag "greater than number" >)
 389                  (const :tag "equal than number" =)
 390                  (const :tag "ask" nil)))
 391
 392 (defcustom gnus-score-default-fold nil
 393   "Non-nil means use case folding for new score file entries."
 394   :group 'gnus-score-default
 395   :type 'boolean)
 396
 397 (defcustom gnus-score-default-duration nil
 398   "Default duration of effect when entering new scores.
 399
 400 Should be one of the following symbols.
 401
 402  t: temporary
 403  p: permanent
 404  i: immediate
 405
 406 If nil, the user will be asked for a duration."
 407   :group 'gnus-score-default
 408   :type '(choice (const :tag "temporary" t)
 409                  (const :tag "permanent" p)
 410                  (const :tag "immediate" i)
 411                  (const :tag "ask" nil)))
 412
 413 (defcustom gnus-score-after-write-file-function nil
 414   "Function called with the name of the score file just written to disk."
 415   :group 'gnus-score-files
 416   :type '(choice (const nil) function))
 417
 418 (defcustom gnus-score-thread-simplify nil
 419   "If non-nil, subjects will simplified as in threading."
 420   :group 'gnus-score-various
 421   :type 'boolean)
 422
 423 (defcustom gnus-inhibit-slow-scoring nil
 424   "Inhibit slow scoring, e.g. scoring on headers or body.
 425
 426 If a regexp, scoring on headers or body is inhibited if the group
 427 matches the regexp.  If it is t, scoring on headers or body is
 428 inhibited for all groups."
 429   :group 'gnus-score-various
 430   :version "23.1" ;; No Gnus
 431   :type '(choice (const :tag "All" nil)
 432                  (const :tag "None" t)
 433                  regexp))
 434
 435 \f
 436
 437 ;; Internal variables.
 438
 439 (defvar gnus-score-use-all-scores t
 440   "If nil, only `gnus-score-find-score-files-function' is used.")
 441
 442 (defvar gnus-adaptive-word-syntax-table
 443   (let ((table (copy-syntax-table (standard-syntax-table)))
 444         (numbers '(?0 ?1 ?2 ?3 ?4 ?5 ?6 ?7 ?8 ?9)))
 445     (while numbers
 446       (modify-syntax-entry (pop numbers) " " table))
 447     (modify-syntax-entry ?' "w" table)
 448     table)
 449   "Syntax table used when doing adaptive word scoring.")
 450
 451 (defvar gnus-scores-exclude-files nil)
 452 (defvar gnus-internal-global-score-files nil)
 453 (defvar gnus-score-file-list nil)
 454
 455 (defvar gnus-short-name-score-file-cache nil)
 456
 457 (defvar gnus-score-help-winconf nil)
 458 (defvar gnus-adaptive-score-alist gnus-default-adaptive-score-alist)
 459 (defvar gnus-adaptive-word-score-alist gnus-default-adaptive-word-score-alist)
 460 (defvar gnus-score-trace nil)
 461 (defvar gnus-score-edit-buffer nil)
 462
 463 (defvar gnus-score-alist nil
 464   "Alist containing score information.
 465 The keys can be symbols or strings.  The following symbols are defined.
 466
 467 touched: If this alist has been modified.
 468 mark:    Automatically mark articles below this.
 469 expunge: Automatically expunge articles below this.
 470 files:   List of other score files to load when loading this one.
 471 eval:    Sexp to be evaluated when the score file is loaded.
 472
 473 String entries have the form (HEADER (MATCH TYPE SCORE DATE) ...)
 474 where HEADER is the header being scored, MATCH is the string we are
 475 looking for, TYPE is a flag indicating whether it should use regexp or
 476 substring matching, SCORE is the score to add and DATE is the date
 477 of the last successful match.")
 478
 479 (defvar gnus-score-cache nil)
 480 (defvar gnus-scores-articles nil)
 481 (defvar gnus-score-index nil)
 482
 483
 484 (defconst gnus-header-index
 485   ;; Name to index alist.
 486   '(("number" 0 gnus-score-integer)
 487     ("subject" 1 gnus-score-string)
 488     ("from" 2 gnus-score-string)
 489     ("date" 3 gnus-score-date)
 490     ("message-id" 4 gnus-score-string)
 491     ("references" 5 gnus-score-string)
 492     ("chars" 6 gnus-score-integer)
 493     ("lines" 7 gnus-score-integer)
 494     ("xref" 8 gnus-score-string)
 495     ("extra" 9 gnus-score-string)
 496     ("head" -1 gnus-score-body)
 497     ("body" -1 gnus-score-body)
 498     ("all" -1 gnus-score-body)
 499     ("followup" 2 gnus-score-followup)
 500     ("thread" 5 gnus-score-thread)))
 501
 502 ;;; Summary mode score maps.
 503
 504 (gnus-define-keys (gnus-summary-score-map "V" gnus-summary-mode-map)
 505   "s" gnus-summary-set-score
 506   "S" gnus-summary-current-score
 507   "c" gnus-score-change-score-file
 508   "C" gnus-score-customize
 509   "m" gnus-score-set-mark-below
 510   "x" gnus-score-set-expunge-below
 511   "R" gnus-summary-rescore
 512   "e" gnus-score-edit-current-scores
 513   "f" gnus-score-edit-file
 514   "F" gnus-score-flush-cache
 515   "t" gnus-score-find-trace
 516   "w" gnus-score-find-favourite-words)
 517
 518 ;; Summary score file commands
 519
 520 ;; Much modification of the kill (ahem, score) code and lots of the
 521 ;; functions are written by Per Abrahamsen <amanda@iesd.auc.dk>.
 522
 523 (defun gnus-summary-lower-score (&optional score symp)
 524   "Make a score entry based on the current article.
 525 The user will be prompted for header to score on, match type,
 526 permanence, and the string to be used.  The numerical prefix will be
 527 used as score.  A symbolic prefix of `a' says to use the `all.SCORE'
 528 file for the command instead of the current score file."
 529   (interactive (gnus-interactive "P\ny"))
 530   (gnus-summary-increase-score (- (gnus-score-delta-default score)) symp))
 531
 532 (defun gnus-score-kill-help-buffer ()
 533   (when (get-buffer "*Score Help*")
 534     (kill-buffer "*Score Help*")
 535     (when gnus-score-help-winconf
 536       (set-window-configuration gnus-score-help-winconf))))
 537
 538 (defun gnus-summary-increase-score (&optional score symp)
 539   "Make a score entry based on the current article.
 540 The user will be prompted for header to score on, match type,
 541 permanence, and the string to be used.  The numerical prefix will be
 542 used as score.  A symbolic prefix of `a' says to use the `all.SCORE'
 543 file for the command instead of the current score file."
 544   (interactive (gnus-interactive "P\ny"))
 545   (let* ((nscore (gnus-score-delta-default score))
 546          (prefix (if (< nscore 0) ?L ?I))
 547          (increase (> nscore 0))
 548          (char-to-header
 549           '((?a "from" nil nil string)
 550             (?s "subject" nil nil string)
 551             (?b "body" "" nil body-string)
 552             (?h "head" "" nil body-string)
 553             (?i "message-id" nil nil string)
 554             (?r "references" "message-id" nil string)
 555             (?x "xref" nil nil string)
 556             (?e "extra" nil nil string)
 557             (?l "lines" nil nil number)
 558             (?d "date" nil nil date)
 559             (?f "followup" nil nil string)
 560             (?t "thread" "message-id" nil string)))
 561          (char-to-type
 562           '((?s s "substring" string)
 563             (?e e "exact string" string)
 564             (?f f "fuzzy string" string)
 565             (?r r "regexp string" string)
 566             (?z s "substring" body-string)
 567             (?p r "regexp string" body-string)
 568             (?b before "before date" date)
 569             (?a after "after date" date)
 570             (?n at "this date" date)
 571             (?< < "less than number" number)
 572             (?> > "greater than number" number)
 573             (?= = "equal to number" number)))
 574          (current-score-file gnus-current-score-file)
 575          (char-to-perm
 576           (list (list ?t (current-time-string) "temporary")
 577                 '(?p perm "permanent") '(?i now "immediate")))
 578          (mimic gnus-score-mimic-keymap)
 579          (hchar (and gnus-score-default-header
 580                      (aref (symbol-name gnus-score-default-header) 0)))
 581          (tchar (and gnus-score-default-type
 582                      (aref (symbol-name gnus-score-default-type) 0)))
 583          (pchar (and gnus-score-default-duration
 584                      (aref (symbol-name gnus-score-default-duration) 0)))
 585          entry temporary type match extra)
 586
 587     (unwind-protect
 588         (progn
 589
 590           ;; First we read the header to score.
 591           (while (not hchar)
 592             (if mimic
 593                 (progn
 594                   (sit-for 1)
 595                   (message "%c-" prefix))
 596               (message "%s header (%s?): " (if increase "Increase" "Lower")
 597                        (mapconcat (lambda (s) (char-to-string (car s)))
 598                                   char-to-header "")))
 599             (setq hchar (read-char))
 600             (when (or (= hchar ??) (= hchar ?\C-h))
 601               (setq hchar nil)
 602               (gnus-score-insert-help "Match on header" char-to-header 1)))
 603
 604           (gnus-score-kill-help-buffer)
 605           (unless (setq entry (assq (downcase hchar) char-to-header))
 606             (if mimic (error "%c %c" prefix hchar)
 607               (error "Invalid header type")))
 608
 609           (when (/= (downcase hchar) hchar)
 610             ;; This was a majuscule, so we end reading and set the defaults.
 611             (if mimic (message "%c %c" prefix hchar) (message ""))
 612             (setq tchar (or tchar ?s)
 613                   pchar (or pchar ?t)))
 614
 615           (let ((legal-types
 616                  (delq nil
 617                        (mapcar (lambda (s)
 618                                  (if (eq (nth 4 entry)
 619                                          (nth 3 s))
 620                                      s nil))
 621                                char-to-type))))
 622             ;; We continue reading - the type.
 623             (while (not tchar)
 624               (if mimic
 625                   (progn
 626                     (sit-for 1) (message "%c %c-" prefix hchar))
 627                 (message "%s header '%s' with match type (%s?): "
 628                          (if increase "Increase" "Lower")
 629                          (nth 1 entry)
 630                          (mapconcat (lambda (s) (char-to-string (car s)))
 631                                     legal-types "")))
 632               (setq tchar (read-char))
 633               (when (or (= tchar ??) (= tchar ?\C-h))
 634                 (setq tchar nil)
 635                 (gnus-score-insert-help "Match type" legal-types 2)))
 636
 637             (gnus-score-kill-help-buffer)
 638             (unless (setq type (nth 1 (assq (downcase tchar) legal-types)))
 639               (if mimic (error "%c %c" prefix hchar)
 640                 (error "Invalid match type"))))
 641
 642           (when (/= (downcase tchar) tchar)
 643             ;; It was a majuscule, so we end reading and use the default.
 644             (if mimic (message "%c %c %c" prefix hchar tchar)
 645               (message ""))
 646             (setq pchar (or pchar ?t)))
 647
 648           ;; We continue reading.
 649           (while (not pchar)
 650             (if mimic
 651                 (progn
 652                   (sit-for 1) (message "%c %c %c-" prefix hchar tchar))
 653               (message "%s permanence (%s?): " (if increase "Increase" "Lower")
 654                        (mapconcat (lambda (s) (char-to-string (car s)))
 655                                   char-to-perm "")))
 656             (setq pchar (read-char))
 657             (when (or (= pchar ??) (= pchar ?\C-h))
 658               (setq pchar nil)
 659               (gnus-score-insert-help "Match permanence" char-to-perm 2)))
 660
 661           (gnus-score-kill-help-buffer)
 662           (if mimic (message "%c %c %c %c" prefix hchar tchar pchar)
 663             (message ""))
 664           (unless (setq temporary (cadr (assq pchar char-to-perm)))
 665             ;; Deal with der(r)ided superannuated paradigms.
 666             (when (and (eq (1+ prefix) 77)
 667                        (eq (+ hchar 12) 109)
 668                        (eq (1- tchar) 113)
 669                        (eq (- pchar 4) 111))
 670               (error "You rang?"))
 671             (if mimic
 672                 (error "%c %c %c %c" prefix hchar tchar pchar)
 673               (error "Invalid match duration"))))
 674       ;; Always kill the score help buffer.
 675       (gnus-score-kill-help-buffer))
 676
 677     ;; If scoring an extra (non-standard overview) header,
 678     ;; we must find out which header is in question.
 679     (setq extra
 680           (and gnus-extra-headers
 681                (equal (nth 1 entry) "extra")
 682                (intern                  ; need symbol
 683                 (let ((collection (mapcar 'symbol-name gnus-extra-headers)))
 684                   (gnus-completing-read
 685                    "Score extra header"  ; prompt
 686                    collection            ; completion list
 687                    t                     ; require match
 688                    nil                   ; no history
 689                    nil                   ; no initial-input
 690                    (car collection)))))) ; default value
 691     ;; extra is now nil or a symbol.
 692
 693     ;; We have all the data, so we enter this score.
 694     (setq match (if (string= (nth 2 entry) "") ""
 695                   (gnus-summary-header (or (nth 2 entry) (nth 1 entry))
 696                                        nil extra)))
 697
 698     ;; Modify the match, perhaps.
 699     (cond
 700      ((equal (nth 1 entry) "xref")
 701       (when (string-match "^Xref: *" match)
 702         (setq match (substring match (match-end 0))))
 703       (when (string-match "^[^:]* +" match)
 704         (setq match (substring match (match-end 0))))))
 705
 706     (when (memq type '(r R regexp Regexp))
 707       (setq match (regexp-quote match)))
 708
 709     ;; Change score file to the "all.SCORE" file.
 710     (when (eq symp 'a)
 711       (with-current-buffer gnus-summary-buffer
 712         (gnus-score-load-file
 713          ;; This is a kludge; yes...
 714          (cond
 715           ((eq gnus-score-find-score-files-function
 716                'gnus-score-find-hierarchical)
 717            (gnus-score-file-name ""))
 718           ((eq gnus-score-find-score-files-function 'gnus-score-find-single)
 719            current-score-file)
 720           (t
 721            (gnus-score-file-name "all"))))))
 722
 723     (gnus-summary-score-entry
 724      (nth 1 entry)                      ; Header
 725      match                              ; Match
 726      type                               ; Type
 727      (if (eq score 's) nil score)       ; Score
 728      (if (eq temporary 'perm)           ; Temp
 729          nil
 730        temporary)
 731      (not (nth 3 entry))                ; Prompt
 732      nil                                ; not silent
 733      extra)                             ; non-standard overview.
 734
 735     (when (eq symp 'a)
 736       ;; We change the score file back to the previous one.
 737       (with-current-buffer gnus-summary-buffer
 738         (gnus-score-load-file current-score-file)))))
 739
 740 (defun gnus-score-insert-help (string alist idx)
 741   (setq gnus-score-help-winconf (current-window-configuration))
 742   (with-current-buffer (gnus-get-buffer-create "*Score Help*")
 743     (buffer-disable-undo)
 744     (delete-windows-on (current-buffer))
 745     (erase-buffer)
 746     (insert string ":\n\n")
 747     (let ((max -1)
 748           (list alist)
 749           (i 0)
 750           n width pad format)
 751       ;; find the longest string to display
 752       (while list
 753         (setq n (length (nth idx (car list))))
 754         (unless (> max n)
 755           (setq max n))
 756         (setq list (cdr list)))
 757       (setq max (+ max 4))              ; %c, `:', SPACE, a SPACE at end
 758       (setq n (/ (1- (window-width)) max)) ; items per line
 759       (setq width (/ (1- (window-width)) n)) ; width of each item
 760       ;; insert `n' items, each in a field of width `width'
 761       (while alist
 762         (if (< i n)
 763             ()
 764           (setq i 0)
 765           (delete-char -1)              ; the `\n' takes a char
 766           (insert "\n"))
 767         (setq pad (- width 3))
 768         (setq format (concat "%c: %-" (int-to-string pad) "s"))
 769         (insert (format format (caar alist) (nth idx (car alist))))
 770         (setq alist (cdr alist))
 771         (setq i (1+ i))))
 772     (goto-char (point-min))
 773     ;; display ourselves in a small window at the bottom
 774     (gnus-select-lowest-window)
 775     (if (< (/ (window-height) 2) window-min-height)
 776         (switch-to-buffer "*Score Help*")
 777       (split-window)
 778       (pop-to-buffer "*Score Help*"))
 779     (let ((window-min-height 1))
 780       (shrink-window-if-larger-than-buffer))
 781     (select-window (gnus-get-buffer-window gnus-summary-buffer t))))
 782
 783 (defun gnus-summary-header (header &optional no-err extra)
 784   ;; Return HEADER for current articles, or error.
 785   (let ((article (gnus-summary-article-number))
 786         headers)
 787     (if article
 788         (if (and (setq headers (gnus-summary-article-header article))
 789                  (vectorp headers))
 790             (if extra                   ; `header' must be "extra"
 791                 (or (cdr (assq extra (mail-header-extra headers))) "")
 792               (aref headers (nth 1 (assoc header gnus-header-index))))
 793           (if no-err
 794               nil
 795             (error "Pseudo-articles can't be scored")))
 796       (if no-err
 797           (error "No article on current line")
 798         nil))))
 799
 800 (defun gnus-newsgroup-score-alist ()
 801   (or
 802    (let ((param-file (gnus-group-find-parameter
 803                       gnus-newsgroup-name 'score-file)))
 804      (when param-file
 805        (gnus-score-load param-file)))
 806    (gnus-score-load
 807     (gnus-score-file-name gnus-newsgroup-name)))
 808   gnus-score-alist)
 809
 810 (defsubst gnus-score-get (symbol &optional alist)
 811   ;; Get SYMBOL's definition in ALIST.
 812   (cdr (assoc symbol
 813               (or alist
 814                   gnus-score-alist
 815                   (gnus-newsgroup-score-alist)))))
 816
 817 (defun gnus-summary-score-entry (header match type score date
 818                                         &optional prompt silent extra)
 819   "Enter score file entry.
 820 HEADER is the header being scored.
 821 MATCH is the string we are looking for.
 822 TYPE is the match type: substring, regexp, exact, fuzzy.
 823 SCORE is the score to add.
 824 DATE is the expire date, or nil for no expire, or 'now for immediate expire.
 825 If optional argument `PROMPT' is non-nil, allow user to edit match.
 826 If optional argument `SILENT' is nil, show effect of score entry.
 827 If optional argument `EXTRA' is non-nil, it's a non-standard overview header."
 828   ;; Regexp is the default type.
 829   (when (eq type t)
 830     (setq type 'r))
 831   ;; Simplify matches...
 832   (cond ((or (eq type 'r) (eq type 's) (eq type nil))
 833          (setq match (if match (gnus-simplify-subject-re match) "")))
 834         ((eq type 'f)
 835          (setq match (gnus-simplify-subject-fuzzy match))))
 836   (let ((score (gnus-score-delta-default score))
 837         (header (downcase header))
 838         new)
 839     (set-text-properties 0 (length header) nil header)
 840     (when prompt
 841       (setq match (read-string
 842                    (format "Match %s on %s, %s: "
 843                            (cond ((eq date 'now)
 844                                   "now")
 845                                  ((stringp date)
 846                                   "temp")
 847                                  (t "permanent"))
 848                            header
 849                            (if (< score 0) "lower" "raise"))
 850                    (if (numberp match)
 851                        (int-to-string match)
 852                      match))))
 853
 854     ;; If this is an integer comparison, we transform from string to int.
 855     (if (eq (nth 2 (assoc header gnus-header-index)) 'gnus-score-integer)
 856         (if (stringp match)
 857             (setq match (string-to-number match)))
 858       (set-text-properties 0 (length match) nil match))
 859
 860     (unless (eq date 'now)
 861       ;; Add the score entry to the score file.
 862       (when (= score gnus-score-interactive-default-score)
 863         (setq score nil))
 864       (let ((old (gnus-score-get header))
 865             elem)
 866         (setq new
 867               (cond
 868                (extra
 869                 (list match score
 870                       (and date (if (numberp date) date
 871                                   (date-to-day date)))
 872                       type (symbol-name extra)))
 873                (type
 874                 (list match score
 875                       (and date (if (numberp date) date
 876                                   (date-to-day date)))
 877                       type))
 878                (date (list match score (date-to-day date)))
 879                (score (list match score))
 880                (t (list match))))
 881         ;; We see whether we can collapse some score entries.
 882         ;; This isn't quite correct, because there may be more elements
 883         ;; later on with the same key that have matching elems...  Hm.
 884         (if (and old
 885                  (setq elem (assoc match old))
 886                  (eq (nth 3 elem) (nth 3 new))
 887                  (or (and (numberp (nth 2 elem)) (numberp (nth 2 new)))
 888                      (and (not (nth 2 elem)) (not (nth 2 new)))))
 889             ;; Yup, we just add this new score to the old elem.
 890             (setcar (cdr elem) (+ (or (nth 1 elem)
 891                                       gnus-score-interactive-default-score)
 892                                   (or (nth 1 new)
 893                                       gnus-score-interactive-default-score)))
 894           ;; Nope, we have to add a new elem.
 895           (gnus-score-set header (if old (cons new old) (list new)) nil t))
 896         (gnus-score-set 'touched '(t))))
 897
 898     ;; Score the current buffer.
 899     (unless silent
 900       (if (and (>= (nth 1 (assoc header gnus-header-index)) 0)
 901                (eq (nth 2 (assoc header gnus-header-index))
 902                    'gnus-score-string))
 903           (gnus-summary-score-effect header match type score extra)
 904         (gnus-summary-rescore)))
 905
 906     ;; Return the new scoring rule.
 907     new))
 908
 909 (defun gnus-summary-score-effect (header match type score &optional extra)
 910   "Simulate the effect of a score file entry.
 911 HEADER is the header being scored.
 912 MATCH is the string we are looking for.
 913 TYPE is the score type.
 914 SCORE is the score to add.
 915 EXTRA is the possible non-standard header."
 916   (interactive (list (gnus-completing-read "Header"
 917                                            (mapcar
 918                                             'car
 919                                             (remove-if-not
 920                                              (lambda (x) (fboundp (nth 2 x)))
 921                                              gnus-header-index))
 922                                            t)
 923                      (read-string "Match: ")
 924                      (if (y-or-n-p "Use regexp match? ") 'r 's)
 925                      (string-to-number (read-string "Score: "))))
 926   (save-excursion
 927     (unless (and (stringp match) (> (length match) 0))
 928       (error "No match"))
 929     (goto-char (point-min))
 930     (let ((regexp (cond ((eq type 'f)
 931                          (gnus-simplify-subject-fuzzy match))
 932                         ((eq type 'r)
 933                          match)
 934                         ((eq type 'e)
 935                          (concat "\\`" (regexp-quote match) "\\'"))
 936                         (t
 937                          (regexp-quote match)))))
 938       (while (not (eobp))
 939         (let ((content (gnus-summary-header header 'noerr extra))
 940               (case-fold-search t))
 941           (and content
 942                (when (if (eq type 'f)
 943                          (string-equal (gnus-simplify-subject-fuzzy content)
 944                                        regexp)
 945                        (string-match regexp content))
 946                  (gnus-summary-raise-score score))))
 947         (beginning-of-line 2))))
 948   (gnus-set-mode-line 'summary))
 949
 950 (defun gnus-summary-score-crossposting (score date)
 951   ;; Enter score file entry for current crossposting.
 952   ;; SCORE is the score to add.
 953   ;; DATE is the expire date.
 954   (let ((xref (gnus-summary-header "xref"))
 955         (start 0)
 956         group)
 957     (unless xref
 958       (error "This article is not crossposted"))
 959     (while (string-match " \\([^ \t]+\\):" xref start)
 960       (setq start (match-end 0))
 961       (when (not (string=
 962                   (setq group
 963                         (substring xref (match-beginning 1) (match-end 1)))
 964                   gnus-newsgroup-name))
 965         (gnus-summary-score-entry
 966          "xref" (concat " " group ":") nil score date t)))))
 967
 968 \f
 969 ;;;
 970 ;;; Gnus Score Files
 971 ;;;
 972
 973 ;; All score code written by Per Abrahamsen <abraham@iesd.auc.dk>.
 974
 975 (defun gnus-score-set-mark-below (score)
 976   "Automatically mark articles with score below SCORE as read."
 977   (interactive
 978    (list (or (and current-prefix-arg (prefix-numeric-value current-prefix-arg))
 979              (string-to-number (read-string "Mark below: ")))))
 980   (setq score (or score gnus-summary-default-score 0))
 981   (gnus-score-set 'mark (list score))
 982   (gnus-score-set 'touched '(t))
 983   (setq gnus-summary-mark-below score)
 984   (gnus-score-update-lines))
 985
 986 (defun gnus-score-update-lines ()
 987   "Update all lines in the summary buffer."
 988   (save-excursion
 989     (goto-char (point-min))
 990     (while (not (eobp))
 991       (gnus-summary-update-line)
 992       (forward-line 1))))
 993
 994 (defun gnus-score-update-all-lines ()
 995   "Update all lines in the summary buffer, even the hidden ones."
 996   (save-excursion
 997     (goto-char (point-min))
 998     (let (hidden)
 999       (while (not (eobp))
1000         (when (gnus-summary-show-thread)
1001           (push (point) hidden))
1002         (gnus-summary-update-line)
1003         (forward-line 1))
1004       ;; Re-hide the hidden threads.
1005       (while hidden
1006         (goto-char (pop hidden))
1007         (gnus-summary-hide-thread)))))
1008
1009 (defun gnus-score-set-expunge-below (score)
1010   "Automatically expunge articles with score below SCORE."
1011   (interactive
1012    (list (or (and current-prefix-arg (prefix-numeric-value current-prefix-arg))
1013              (string-to-number (read-string "Set expunge below: ")))))
1014   (setq score (or score gnus-summary-default-score 0))
1015   (gnus-score-set 'expunge (list score))
1016   (gnus-score-set 'touched '(t)))
1017
1018 (defun gnus-score-followup-article (&optional score)
1019   "Add SCORE to all followups to the article in the current buffer."
1020   (interactive "P")
1021   (setq score (gnus-score-delta-default score))
1022   (when (gnus-buffer-live-p gnus-summary-buffer)
1023     (save-excursion
1024       (save-restriction
1025         (message-narrow-to-headers)
1026         (let ((id (mail-fetch-field "message-id")))
1027           (when id
1028             (set-buffer gnus-summary-buffer)
1029             (gnus-summary-score-entry
1030              "references" (concat id "[ \t]*$") 'r
1031              score (current-time-string) nil t)))))))
1032
1033 (defun gnus-score-followup-thread (&optional score)
1034   "Add SCORE to all later articles in the thread the current buffer is part of."
1035   (interactive "P")
1036   (setq score (gnus-score-delta-default score))
1037   (when (gnus-buffer-live-p gnus-summary-buffer)
1038     (save-excursion
1039       (save-restriction
1040         (goto-char (point-min))
1041         (let ((id (mail-fetch-field "message-id")))
1042           (when id
1043             (set-buffer gnus-summary-buffer)
1044             (gnus-summary-score-entry
1045              "references" id 's
1046              score (current-time-string))))))))
1047
1048 (defun gnus-score-set (symbol value &optional alist warn)
1049   ;; Set SYMBOL to VALUE in ALIST.
1050   (let* ((alist
1051           (or alist
1052               gnus-score-alist
1053               (gnus-newsgroup-score-alist)))
1054          (entry (assoc symbol alist)))
1055     (cond ((gnus-score-get 'read-only alist)
1056            ;; This is a read-only score file, so we do nothing.
1057            (when warn
1058              (gnus-message 4 "Note: read-only score file; entry discarded")))
1059           (entry
1060            (setcdr entry value))
1061           ((null alist)
1062            (error "Empty alist"))
1063           (t
1064            (setcdr alist
1065                    (cons (cons symbol value) (cdr alist)))))))
1066
1067 (defun gnus-summary-raise-score (n)
1068   "Raise the score of the current article by N."
1069   (interactive "p")
1070   (gnus-summary-set-score (+ (gnus-summary-article-score)
1071                              (or n gnus-score-interactive-default-score ))))
1072
1073 (defun gnus-summary-set-score (n)
1074   "Set the score of the current article to N."
1075   (interactive "p")
1076   (save-excursion
1077     (gnus-summary-show-thread)
1078     (let ((buffer-read-only nil))
1079       ;; Set score.
1080       (gnus-summary-update-mark
1081        (if (= n (or gnus-summary-default-score 0)) ?  ;Whitespace
1082          (if (< n (or gnus-summary-default-score 0))
1083              gnus-score-below-mark gnus-score-over-mark))
1084        'score))
1085     (let* ((article (gnus-summary-article-number))
1086            (score (assq article gnus-newsgroup-scored)))
1087       (if score (setcdr score n)
1088         (push (cons article n) gnus-newsgroup-scored)))
1089     (gnus-summary-update-line)))
1090
1091 (defun gnus-summary-current-score ()
1092   "Return the score of the current article."
1093   (interactive)
1094   (gnus-message 1 "%s" (gnus-summary-article-score)))
1095
1096 (defun gnus-score-change-score-file (file)
1097   "Change current score alist."
1098   (interactive
1099    (list (read-file-name "Change to score file: " gnus-kill-files-directory)))
1100   (gnus-score-load-file file)
1101   (gnus-set-mode-line 'summary))
1102
1103 (defvar gnus-score-edit-exit-function)
1104 (defun gnus-score-edit-current-scores (file)
1105   "Edit the current score alist."
1106   (interactive (list gnus-current-score-file))
1107   (if (not gnus-current-score-file)
1108       (error "No current score file")
1109     (let ((winconf (current-window-configuration)))
1110       (when (buffer-name gnus-summary-buffer)
1111         (gnus-score-save))
1112       (gnus-make-directory (file-name-directory file))
1113       (setq gnus-score-edit-buffer (find-file-noselect file))
1114       (gnus-configure-windows 'edit-score)
1115       (gnus-score-mode)
1116       (setq gnus-score-edit-exit-function 'gnus-score-edit-done)
1117       (make-local-variable 'gnus-prev-winconf)
1118       (setq gnus-prev-winconf winconf))
1119     (gnus-message
1120      4 "%s" (substitute-command-keys
1121              "\\<gnus-score-mode-map>\\[gnus-score-edit-exit] to save edits"))))
1122
1123 (defun gnus-score-edit-all-score ()
1124   "Edit the all.SCORE file."
1125   (interactive)
1126   (find-file (gnus-score-file-name "all"))
1127   (gnus-score-mode)
1128   (setq gnus-score-edit-exit-function 'gnus-score-edit-done)
1129   (gnus-message
1130    4 (substitute-command-keys
1131       "\\<gnus-score-mode-map>\\[gnus-score-edit-exit] to save edits")))
1132
1133 (defun gnus-score-edit-file (file)
1134   "Edit a score file."
1135   (interactive
1136    (list (read-file-name "Edit score file: " gnus-kill-files-directory)))
1137   (gnus-make-directory (file-name-directory file))
1138   (when (buffer-name gnus-summary-buffer)
1139     (gnus-score-save))
1140   (let ((winconf (current-window-configuration)))
1141     (setq gnus-score-edit-buffer (find-file-noselect file))
1142     (gnus-configure-windows 'edit-score)
1143     (gnus-score-mode)
1144     (setq gnus-score-edit-exit-function 'gnus-score-edit-done)
1145     (make-local-variable 'gnus-prev-winconf)
1146     (setq gnus-prev-winconf winconf))
1147   (gnus-message
1148    4 "%s" (substitute-command-keys
1149            "\\<gnus-score-mode-map>\\[gnus-score-edit-exit] to save edits")))
1150
1151 (defun gnus-score-edit-file-at-point (&optional format)
1152   "Edit score file at point in Score Trace buffers.
1153 If FORMAT, also format the current score file."
1154   (let* ((rule (save-excursion
1155                  (beginning-of-line)
1156                  (read (current-buffer))))
1157          (sep "[ \n\r\t]*")
1158          ;; Must be synced with `gnus-score-find-trace':
1159          (reg " -> +")
1160          (file (save-excursion
1161                  (end-of-line)
1162                  (if (and (re-search-backward reg (point-at-bol) t)
1163                           (re-search-forward  reg (point-at-eol) t))
1164                      (buffer-substring (point) (point-at-eol))
1165                    nil))))
1166     (if (or (not file)
1167             (string-match "\\<\\(non-file rule\\|A file\\)\\>" file)
1168             ;; (see `gnus-score-find-trace' and `gnus-score-advanced')
1169             (string= "" file))
1170         (gnus-error 3 "Can't find a score file in current line.")
1171       (gnus-score-edit-file file)
1172       (when format
1173         (gnus-score-pretty-print))
1174       (when (consp rule) ;; the rule exists
1175         (setq rule (mapconcat #'(lambda (obj)
1176                                   (regexp-quote (format "%S" obj)))
1177                               rule
1178                               sep))
1179         (goto-char (point-min))
1180         (re-search-forward rule nil t)
1181         ;; make it easy to use `kill-sexp':
1182         (goto-char (1- (match-beginning 0)))))))
1183
1184 (defun gnus-score-load-file (file)
1185   ;; Load score file FILE.  Returns a list a retrieved score-alists.
1186   (let* ((file (expand-file-name
1187                 (or (and (string-match
1188                           (concat "^" (regexp-quote
1189                                        (expand-file-name
1190                                         gnus-kill-files-directory)))
1191                           (expand-file-name file))
1192                          file)
1193                     (expand-file-name file gnus-kill-files-directory))))
1194          (cached (assoc file gnus-score-cache))
1195          (global (member file gnus-internal-global-score-files))
1196          lists alist)
1197     (if cached
1198         ;; The score file was already loaded.
1199         (setq alist (cdr cached))
1200       ;; We load the score file.
1201       (setq gnus-score-alist nil)
1202       (setq alist (gnus-score-load-score-alist file))
1203       ;; We add '(touched) to the alist to signify that it hasn't been
1204       ;; touched (yet).
1205       (unless (assq 'touched alist)
1206         (push (list 'touched nil) alist))
1207       ;; If it is a global score file, we make it read-only.
1208       (and global
1209            (not (assq 'read-only alist))
1210            (push (list 'read-only t) alist))
1211       (push (cons file alist) gnus-score-cache))
1212     (let ((a alist)
1213           found)
1214       (while a
1215         ;; Downcase all header names.
1216         (cond
1217          ((stringp (caar a))
1218           (setcar (car a) (downcase (caar a)))
1219           (setq found t))
1220          ;; Advanced scoring.
1221          ((consp (caar a))
1222           (setq found t)))
1223         (pop a))
1224       ;; If there are actual scores in the alist, we add it to the
1225       ;; return value of this function.
1226       (when found
1227         (setq lists (list alist))))
1228     ;; Treat the other possible atoms in the score alist.
1229     (let ((mark (car (gnus-score-get 'mark alist)))
1230           (expunge (car (gnus-score-get 'expunge alist)))
1231           (mark-and-expunge (car (gnus-score-get 'mark-and-expunge alist)))
1232           (files (gnus-score-get 'files alist))
1233           (exclude-files (gnus-score-get 'exclude-files alist))
1234           (orphan (car (gnus-score-get 'orphan alist)))
1235           (adapt (gnus-score-get 'adapt alist))
1236           (thread-mark-and-expunge
1237            (car (gnus-score-get 'thread-mark-and-expunge alist)))
1238           (adapt-file (car (gnus-score-get 'adapt-file alist)))
1239           (local (gnus-score-get 'local alist))
1240           (decay (car (gnus-score-get 'decay alist)))
1241           (eval (car (gnus-score-get 'eval alist))))
1242       ;; Perform possible decays.
1243       (when (and (if (stringp gnus-decay-scores)
1244                      (string-match gnus-decay-scores file)
1245                    gnus-decay-scores)
1246                  (or cached (file-exists-p file))
1247                  (or (not decay)
1248                      (gnus-decay-scores alist decay)))
1249         (gnus-score-set 'touched '(t) alist)
1250         (gnus-score-set 'decay (list (time-to-days (current-time))) alist))
1251       ;; We do not respect eval and files atoms from global score
1252       ;; files.
1253       (when (and files (not global))
1254         (setq lists (apply 'append lists
1255                            (mapcar 'gnus-score-load-file
1256                                    (if adapt-file (cons adapt-file files)
1257                                      files)))))
1258       (when (and eval (not global))
1259         (eval eval))
1260       ;; We then expand any exclude-file directives.
1261       (setq gnus-scores-exclude-files
1262             (nconc
1263              (apply
1264               'nconc
1265               (mapcar
1266                (lambda (sfile)
1267                  (list
1268                   (expand-file-name sfile (file-name-directory file))
1269                   (expand-file-name sfile gnus-kill-files-directory)))
1270                exclude-files))
1271              gnus-scores-exclude-files))
1272       (when local
1273         (with-current-buffer gnus-summary-buffer
1274           (while local
1275             (and (consp (car local))
1276                  (symbolp (caar local))
1277                  (progn
1278                    (make-local-variable (caar local))
1279                    (set (caar local) (nth 1 (car local)))))
1280             (setq local (cdr local)))))
1281       (when orphan
1282         (setq gnus-orphan-score orphan))
1283       (setq gnus-adaptive-score-alist
1284             (cond ((equal adapt '(t))
1285                    (setq gnus-newsgroup-adaptive t)
1286                    gnus-default-adaptive-score-alist)
1287                   ((equal adapt '(ignore))
1288                    (setq gnus-newsgroup-adaptive nil))
1289                   ((consp adapt)
1290                    (setq gnus-newsgroup-adaptive t)
1291                    adapt)
1292                   (t
1293                    gnus-default-adaptive-score-alist)))
1294       (setq gnus-thread-expunge-below
1295             (or thread-mark-and-expunge gnus-thread-expunge-below))
1296       (setq gnus-summary-mark-below
1297             (or mark mark-and-expunge gnus-summary-mark-below))
1298       (setq gnus-summary-expunge-below
1299             (or expunge mark-and-expunge gnus-summary-expunge-below))
1300       (setq gnus-newsgroup-adaptive-score-file
1301             (or adapt-file gnus-newsgroup-adaptive-score-file)))
1302     (setq gnus-current-score-file file)
1303     (setq gnus-score-alist alist)
1304     lists))
1305
1306 (defun gnus-score-load (file)
1307   ;; Load score FILE.
1308   (let ((cache (assoc file gnus-score-cache)))
1309     (if cache
1310         (setq gnus-score-alist (cdr cache))
1311       (setq gnus-score-alist nil)
1312       (gnus-score-load-score-alist file)
1313       (unless gnus-score-alist
1314         (setq gnus-score-alist (copy-alist '((touched nil)))))
1315       (push (cons file gnus-score-alist) gnus-score-cache))))
1316
1317 (defun gnus-score-remove-from-cache (file)
1318   (setq gnus-score-cache
1319         (delq (assoc file gnus-score-cache) gnus-score-cache)))
1320
1321 (defun gnus-score-load-score-alist (file)
1322   "Read score FILE."
1323   (let (alist)
1324     (if (not (file-readable-p file))
1325         ;; Couldn't read file.
1326         (setq gnus-score-alist nil)
1327       ;; Read file.
1328       (with-temp-buffer
1329         (let ((coding-system-for-read score-mode-coding-system))
1330           (insert-file-contents file))
1331         (goto-char (point-min))
1332         ;; Only do the loading if the score file isn't empty.
1333         (when (save-excursion (re-search-forward "[()0-9a-zA-Z]" nil t))
1334           (setq alist
1335                 (condition-case ()
1336                     (read (current-buffer))
1337                   (error
1338                    (gnus-error 3.2 "Problem with score file %s" file))))))
1339       (cond
1340        ((and alist
1341              (atom alist))
1342         ;; Bogus score file.
1343         (error "Invalid syntax with score file %s" file))
1344        ((eq (car alist) 'setq)
1345         ;; This is an old-style score file.
1346         (setq gnus-score-alist (gnus-score-transform-old-to-new alist)))
1347        (t
1348         (setq gnus-score-alist alist)))
1349       ;; Check the syntax of the score file.
1350       (setq gnus-score-alist
1351             (gnus-score-check-syntax gnus-score-alist file)))))
1352
1353 (defun gnus-score-check-syntax (alist file)
1354   "Check the syntax of the score ALIST."
1355   (cond
1356    ((null alist)
1357     nil)
1358    ((not (consp alist))
1359     (gnus-message 1 "Score file is not a list: %s" file)
1360     (ding)
1361     nil)
1362    (t
1363     (let ((a alist)
1364           sr err s type)
1365       (while (and a (not err))
1366         (setq
1367          err
1368          (cond
1369           ((not (listp (car a)))
1370            (format "Invalid score element %s in %s" (car a) file))
1371           ((stringp (caar a))
1372            (cond
1373             ((not (listp (setq sr (cdar a))))
1374              (format "Invalid header match %s in %s" (nth 1 (car a)) file))
1375             (t
1376              (setq type (caar a))
1377              (while (and sr (not err))
1378                (setq s (pop sr))
1379                (setq
1380                 err
1381                 (cond
1382                  ((if (member (downcase type) '("lines" "chars"))
1383                       (not (numberp (car s)))
1384                     (not (stringp (car s))))
1385                   (format "Invalid match %s in %s" (car s) file))
1386                  ((and (cadr s) (not (integerp (cadr s))))
1387                   (format "Non-integer score %s in %s" (cadr s) file))
1388                  ((and (caddr s) (not (integerp (caddr s))))
1389                   (format "Non-integer date %s in %s" (caddr s) file))
1390                  ((and (cadddr s) (not (symbolp (cadddr s))))
1391                   (format "Non-symbol match type %s in %s" (cadddr s) file)))))
1392              err)))))
1393         (setq a (cdr a)))
1394       (if err
1395           (progn
1396             (ding)
1397             (gnus-message 3 "%s" err)
1398             (sit-for 2)
1399             nil)
1400         alist)))))
1401
1402 (defun gnus-score-transform-old-to-new (alist)
1403   (let* ((alist (nth 2 alist))
1404          out entry)
1405     (when (eq (car alist) 'quote)
1406       (setq alist (nth 1 alist)))
1407     (while alist
1408       (setq entry (car alist))
1409       (if (stringp (car entry))
1410           (let ((scor (cdr entry)))
1411             (push entry out)
1412             (while scor
1413               (setcar scor
1414                       (list (caar scor) (nth 2 (car scor))
1415                             (and (nth 3 (car scor))
1416                                  (date-to-day (nth 3 (car scor))))
1417                             (if (nth 1 (car scor)) 'r 's)))
1418               (setq scor (cdr scor))))
1419         (push (if (not (listp (cdr entry)))
1420                   (list (car entry) (cdr entry))
1421                 entry)
1422               out))
1423       (setq alist (cdr alist)))
1424     (cons (list 'touched t) (nreverse out))))
1425
1426 (defun gnus-score-save ()
1427   ;; Save all score information.
1428   (let ((cache gnus-score-cache)
1429         entry score file)
1430     (save-excursion
1431       (setq gnus-score-alist nil)
1432       (nnheader-set-temp-buffer " *Gnus Scores*")
1433       (while cache
1434         (current-buffer)
1435         (setq entry (pop cache)
1436               file (nnheader-translate-file-chars (car entry) t)
1437               score (cdr entry))
1438         (if (or (not (equal (gnus-score-get 'touched score) '(t)))
1439                 (gnus-score-get 'read-only score)
1440                 (and (file-exists-p file)
1441                      (not (file-writable-p file))))
1442             ()
1443           (setq score (setcdr entry (gnus-delete-alist 'touched score)))
1444           (erase-buffer)
1445           (let (emacs-lisp-mode-hook)
1446             (if (and (not gnus-adaptive-pretty-print)
1447                      (string-match
1448                       (concat (regexp-quote gnus-adaptive-file-suffix) "$")
1449                       file))
1450                 ;; This is an adaptive score file, so we do not run it through
1451                 ;; `pp' unless requested.  These files can get huge, and are
1452                 ;; not meant to be edited by human hands.
1453                 (gnus-prin1 score)
1454               ;; This is a normal score file, so we print it very
1455               ;; prettily.
1456               (let ((lisp-mode-syntax-table score-mode-syntax-table))
1457                 (gnus-pp score))))
1458           (gnus-make-directory (file-name-directory file))
1459           ;; If the score file is empty, we delete it.
1460           (if (zerop (buffer-size))
1461               (delete-file file)
1462             ;; There are scores, so we write the file.
1463             (when (file-writable-p file)
1464               (let ((coding-system-for-write score-mode-coding-system))
1465                 (gnus-write-buffer file))
1466               (when gnus-score-after-write-file-function
1467                 (funcall gnus-score-after-write-file-function file)))))
1468         (and gnus-score-uncacheable-files
1469              (string-match gnus-score-uncacheable-files file)
1470              (gnus-score-remove-from-cache file)))
1471       (kill-buffer (current-buffer)))))
1472
1473 (defun gnus-score-load-files (score-files)
1474   "Load all score files in SCORE-FILES."
1475   ;; Load the score files.
1476   (let (scores)
1477     (while score-files
1478       (if (stringp (car score-files))
1479           ;; It is a string, which means that it's a score file name,
1480           ;; so we load the score file and add the score alist to
1481           ;; the list of alists.
1482           (setq scores (nconc (gnus-score-load-file (car score-files)) scores))
1483         ;; It is an alist, so we just add it to the list directly.
1484         (setq scores (nconc (car score-files) scores)))
1485       (setq score-files (cdr score-files)))
1486     ;; Prune the score files that are to be excluded, if any.
1487     (when gnus-scores-exclude-files
1488       (let ((s scores)
1489             c)
1490         (while s
1491           (and (setq c (rassq (car s) gnus-score-cache))
1492                (member (car c) gnus-scores-exclude-files)
1493                (setq scores (delq (car s) scores)))
1494           (setq s (cdr s)))))
1495     scores))
1496
1497 (defun gnus-score-headers (score-files &optional trace)
1498   ;; Score `gnus-newsgroup-headers'.
1499   (let (scores news)
1500     ;; PLM: probably this is not the best place to clear orphan-score
1501     (setq gnus-orphan-score nil
1502           gnus-scores-articles nil
1503           gnus-scores-exclude-files nil
1504           scores (gnus-score-load-files score-files))
1505     (setq news scores)
1506     ;; Do the scoring.
1507     (while news
1508       (setq scores news
1509             news nil)
1510       (when (and gnus-summary-default-score
1511                  scores)
1512         (let* ((entries gnus-header-index)
1513                (now (date-to-day (current-time-string)))
1514                (expire (and gnus-score-expiry-days
1515                             (- now gnus-score-expiry-days)))
1516                (headers gnus-newsgroup-headers)
1517                (current-score-file gnus-current-score-file)
1518                entry header new)
1519           (gnus-message 7 "Scoring...")
1520           ;; Create articles, an alist of the form `(HEADER . SCORE)'.
1521           (while (setq header (pop headers))
1522             ;; WARNING: The assq makes the function O(N*S) while it could
1523             ;; be written as O(N+S), where N is (length gnus-newsgroup-headers)
1524             ;; and S is (length gnus-newsgroup-scored).
1525             (unless (assq (mail-header-number header) gnus-newsgroup-scored)
1526               (setq gnus-scores-articles ;Total of 2 * N cons-cells used.
1527                     (cons (cons header (or gnus-summary-default-score 0))
1528                           gnus-scores-articles))))
1529
1530           (with-current-buffer (gnus-get-buffer-create "*Headers*")
1531             (buffer-disable-undo)
1532             (when (gnus-buffer-live-p gnus-summary-buffer)
1533               (message-clone-locals gnus-summary-buffer))
1534
1535             ;; Set the global variant of this variable.
1536             (setq gnus-current-score-file current-score-file)
1537             ;; score orphans
1538             (when gnus-orphan-score
1539               (setq gnus-score-index
1540                     (nth 1 (assoc "references" gnus-header-index)))
1541               (gnus-score-orphans gnus-orphan-score))
1542             ;; Run each header through the score process.
1543             (while entries
1544               (setq entry (pop entries)
1545                     header (nth 0 entry)
1546                     gnus-score-index (nth 1 (assoc header gnus-header-index)))
1547               (when (< 0 (apply 'max (mapcar
1548                                       (lambda (score)
1549                                         (length (gnus-score-get header score)))
1550                                       scores)))
1551                 (when (if (and gnus-inhibit-slow-scoring
1552                                (or (eq gnus-inhibit-slow-scoring t)
1553                                    (and (stringp gnus-inhibit-slow-scoring)
1554                                         ;; Always true here?
1555                                         ;; (stringp gnus-newsgroup-name)
1556                                         (string-match
1557                                          gnus-inhibit-slow-scoring
1558                                          gnus-newsgroup-name)))
1559                                (> 0 (nth 1 (assoc header gnus-header-index))))
1560                           (progn
1561                             (gnus-message
1562                              7 "Scoring on headers or body skipped.")
1563                             nil)
1564                         ;; Call the scoring function for this type of "header".
1565                         (setq new (funcall (nth 2 entry) scores header
1566                                            now expire trace)))
1567                   (push new news))))
1568             (when (gnus-buffer-live-p gnus-summary-buffer)
1569               (let ((scored gnus-newsgroup-scored))
1570                 (with-current-buffer gnus-summary-buffer
1571                   (setq gnus-newsgroup-scored scored))))
1572             ;; Remove the buffer.
1573             (gnus-kill-buffer (current-buffer)))
1574
1575           ;; Add articles to `gnus-newsgroup-scored'.
1576           (while gnus-scores-articles
1577             (when (or (/= gnus-summary-default-score
1578                           (cdar gnus-scores-articles))
1579                       gnus-save-score)
1580               (push (cons (mail-header-number (caar gnus-scores-articles))
1581                           (cdar gnus-scores-articles))
1582                     gnus-newsgroup-scored))
1583             (setq gnus-scores-articles (cdr gnus-scores-articles)))
1584
1585           (let (score)
1586             (while (setq score (pop scores))
1587               (while score
1588                 (when (consp (caar score))
1589                   (gnus-score-advanced (car score) trace))
1590                 (pop score))))
1591
1592           (gnus-message 7 "Scoring...done"))))))
1593
1594 (defun gnus-score-lower-thread (thread score-adjust)
1595   "Lower the score on THREAD with SCORE-ADJUST.
1596 THREAD is expected to contain a list of the form `(PARENT [CHILD1
1597 CHILD2 ...])' where PARENT is a header array and each CHILD is a list
1598 of the same form as THREAD.  The empty list nil is valid.  For each
1599 article in the tree, the score of the corresponding entry in
1600 `gnus-newsgroup-scored' is adjusted by SCORE-ADJUST."
1601   (while thread
1602     (let ((head (car thread)))
1603       (if (listp head)
1604           ;; handle a child and its descendants
1605           (gnus-score-lower-thread head score-adjust)
1606         ;; handle the parent
1607         (let* ((article (mail-header-number head))
1608                (score (assq article gnus-newsgroup-scored)))
1609           (if score (setcdr score (+ (cdr score) score-adjust))
1610             (push (cons article score-adjust) gnus-newsgroup-scored)))))
1611     (setq thread (cdr thread))))
1612
1613 (defun gnus-score-orphans (score)
1614   "Score orphans.
1615 A root is an article with no references.  An orphan is an article
1616 which has references, but is not connected via its references to a
1617 root article.  This function finds all the orphans, and adjusts their
1618 score in `gnus-newsgroup-scored' by SCORE."
1619   ;; gnus-make-threads produces a list, where each entry is a "thread"
1620   ;; as described in the gnus-score-lower-thread docs.  This function
1621   ;; will be called again (after limiting has been done) if the display
1622   ;; is threaded.  It would be nice to somehow save this info and use
1623   ;; it later.
1624   (dolist (thread (gnus-make-threads))
1625     (let ((id (aref (car thread) gnus-score-index)))
1626       ;; If the parent of the thread is not a root, lower the score of
1627       ;; it and its descendants.  Note that some roots seem to satisfy
1628       ;; (eq id nil) and some (eq id "");  not sure why.
1629       (when (and id
1630                  (not (string= id "")))
1631         (gnus-score-lower-thread thread score)))))
1632
1633 (defun gnus-score-integer (scores header now expire &optional trace)
1634   (let ((gnus-score-index (nth 1 (assoc header gnus-header-index)))
1635         entries alist)
1636     ;; Find matches.
1637     (while scores
1638       (setq alist (car scores)
1639             scores (cdr scores)
1640             entries (assoc header alist))
1641       (while (cdr entries)              ;First entry is the header index.
1642         (let* ((rest (cdr entries))
1643                (kill (car rest))
1644                (match (nth 0 kill))
1645                (type (or (nth 3 kill) '>))
1646                (score (or (nth 1 kill) gnus-score-interactive-default-score))
1647                (date (nth 2 kill))
1648                (found nil)
1649                (match-func (if (or (eq type '>) (eq type '<) (eq type '<=)
1650                                    (eq type '>=) (eq type '=))
1651                                type
1652                              (error "Invalid match type: %s" type)))
1653                (articles gnus-scores-articles))
1654           ;; Instead of doing all the clever stuff that
1655           ;; `gnus-score-string' does to minimize searches and stuff,
1656           ;; I will assume that people generally will put so few
1657           ;; matches on numbers that any cleverness will take more
1658           ;; time than one would gain.
1659           (while articles
1660             (when (funcall match-func
1661                            (or (aref (caar articles) gnus-score-index) 0)
1662                            match)
1663               (when trace
1664                 (push (cons (car-safe (rassq alist gnus-score-cache)) kill)
1665                       gnus-score-trace))
1666               (setq found t)
1667               (setcdr (car articles) (+ score (cdar articles))))
1668             (setq articles (cdr articles)))
1669           ;; Update expire date
1670           (cond ((null date))           ;Permanent entry.
1671                 ((and found gnus-update-score-entry-dates) ;Match, update date.
1672                  (gnus-score-set 'touched '(t) alist)
1673                  (setcar (nthcdr 2 kill) now))
1674                 ((and expire (< date expire)) ;Old entry, remove.
1675                  (gnus-score-set 'touched '(t) alist)
1676                  (setcdr entries (cdr rest))
1677                  (setq rest entries)))
1678           (setq entries rest)))))
1679   nil)
1680
1681 (defun gnus-score-date (scores header now expire &optional trace)
1682   (let ((gnus-score-index (nth 1 (assoc header gnus-header-index)))
1683         entries alist match match-func article)
1684     ;; Find matches.
1685     (while scores
1686       (setq alist (car scores)
1687             scores (cdr scores)
1688             entries (assoc header alist))
1689       (while (cdr entries)              ;First entry is the header index.
1690         (let* ((rest (cdr entries))
1691                (kill (car rest))
1692                (type (or (nth 3 kill) 'before))
1693                (score (or (nth 1 kill) gnus-score-interactive-default-score))
1694                (date (nth 2 kill))
1695                (found nil)
1696                (articles gnus-scores-articles)
1697                l)
1698           (cond
1699            ((eq type 'after)
1700             (setq match-func 'string<
1701                   match (gnus-date-iso8601 (nth 0 kill))))
1702            ((eq type 'before)
1703             (setq match-func 'gnus-string>
1704                   match (gnus-date-iso8601 (nth 0 kill))))
1705            ((eq type 'at)
1706             (setq match-func 'string=
1707                   match (gnus-date-iso8601 (nth 0 kill))))
1708            ((eq type 'regexp)
1709             (setq match-func 'string-match
1710                   match (nth 0 kill)))
1711            (t (error "Invalid match type: %s" type)))
1712           ;; Instead of doing all the clever stuff that
1713           ;; `gnus-score-string' does to minimize searches and stuff,
1714           ;; I will assume that people generally will put so few
1715           ;; matches on numbers that any cleverness will take more
1716           ;; time than one would gain.
1717           (while (setq article (pop articles))
1718             (when (and
1719                    (setq l (aref (car article) gnus-score-index))
1720                    (funcall match-func match (gnus-date-iso8601 l)))
1721               (when trace
1722                 (push (cons (car-safe (rassq alist gnus-score-cache)) kill)
1723                       gnus-score-trace))
1724               (setq found t)
1725               (setcdr article (+ score (cdr article)))))
1726           ;; Update expire date
1727           (cond ((null date))           ;Permanent entry.
1728                 ((and found gnus-update-score-entry-dates) ;Match, update date.
1729                  (gnus-score-set 'touched '(t) alist)
1730                  (setcar (nthcdr 2 kill) now))
1731                 ((and expire (< date expire)) ;Old entry, remove.
1732                  (gnus-score-set 'touched '(t) alist)
1733                  (setcdr entries (cdr rest))
1734                  (setq rest entries)))
1735           (setq entries rest)))))
1736   nil)
1737
1738 (defun gnus-score-body (scores header now expire &optional trace)
1739   (if gnus-agent-fetching
1740       nil
1741     (save-excursion
1742       (setq gnus-scores-articles
1743             (sort gnus-scores-articles
1744                   (lambda (a1 a2)
1745                     (< (mail-header-number (car a1))
1746                        (mail-header-number (car a2))))))
1747       (set-buffer nntp-server-buffer)
1748       (save-restriction
1749         (let* ((buffer-read-only nil)
1750                (articles gnus-scores-articles)
1751                (all-scores scores)
1752                (request-func (cond ((string= "head" header)
1753                                     'gnus-request-head)
1754                                    ((string= "body" header)
1755                                     'gnus-request-body)
1756                                    (t 'gnus-request-article)))
1757                entries alist ofunc article last)
1758           (when articles
1759             (setq last (mail-header-number (caar (last articles))))
1760           ;; Not all backends support partial fetching.  In that case,
1761             ;; we just fetch the entire article.
1762             (unless (gnus-check-backend-function
1763                      (and (string-match "^gnus-" (symbol-name request-func))
1764                           (intern (substring (symbol-name request-func)
1765                                              (match-end 0))))
1766                      gnus-newsgroup-name)
1767               (setq ofunc request-func)
1768               (setq request-func 'gnus-request-article))
1769             (while articles
1770               (setq article (mail-header-number (caar articles)))
1771               (gnus-message 7 "Scoring article %s of %s..." article last)
1772               (widen)
1773               (when (funcall request-func article gnus-newsgroup-name)
1774                 (goto-char (point-min))
1775             ;; If just parts of the article is to be searched, but the
1776             ;; backend didn't support partial fetching, we just narrow
1777                 ;; to the relevant parts.
1778                 (when ofunc
1779                   (if (eq ofunc 'gnus-request-head)
1780                       (narrow-to-region
1781                        (point)
1782                        (or (search-forward "\n\n" nil t) (point-max)))
1783                     (narrow-to-region
1784                      (or (search-forward "\n\n" nil t) (point))
1785                      (point-max))))
1786                 (setq scores all-scores)
1787                 ;; Find matches.
1788                 (while scores
1789                   (setq alist (pop scores)
1790                         entries (assoc header alist))
1791                   (while (cdr entries) ;First entry is the header index.
1792                     (let* ((rest (cdr entries))
1793                            (kill (car rest))
1794                            (match (nth 0 kill))
1795                            (type (or (nth 3 kill) 's))
1796                            (score (or (nth 1 kill)
1797                                       gnus-score-interactive-default-score))
1798                            (date (nth 2 kill))
1799                            (found nil)
1800                            (case-fold-search
1801                             (not (or (eq type 'R) (eq type 'S)
1802                                      (eq type 'Regexp) (eq type 'String))))
1803                            (search-func
1804                             (cond ((or (eq type 'r) (eq type 'R)
1805                                        (eq type 'regexp) (eq type 'Regexp))
1806                                    're-search-forward)
1807                                   ((or (eq type 's) (eq type 'S)
1808                                        (eq type 'string) (eq type 'String))
1809                                    'search-forward)
1810                                   (t
1811                                    (error "Invalid match type: %s" type)))))
1812                       (goto-char (point-min))
1813                       (when (funcall search-func match nil t)
1814                         ;; Found a match, update scores.
1815                         (setcdr (car articles) (+ score (cdar articles)))
1816                         (setq found t)
1817                         (when trace
1818                           (push
1819                            (cons (car-safe (rassq alist gnus-score-cache))
1820                                  kill)
1821                            gnus-score-trace)))
1822                       ;; Update expire date
1823                       (unless trace
1824                         (cond
1825                          ((null date))  ;Permanent entry.
1826                          ((and found gnus-update-score-entry-dates)
1827                           ;; Match, update date.
1828                           (gnus-score-set 'touched '(t) alist)
1829                           (setcar (nthcdr 2 kill) now))
1830                          ((and expire (< date expire)) ;Old entry, remove.
1831                           (gnus-score-set 'touched '(t) alist)
1832                           (setcdr entries (cdr rest))
1833                           (setq rest entries))))
1834                       (setq entries rest)))))
1835               (setq articles (cdr articles)))))))
1836     nil))
1837
1838 (defun gnus-score-thread (scores header now expire &optional trace)
1839   (gnus-score-followup scores header now expire trace t))
1840
1841 (defun gnus-score-followup (scores header now expire &optional trace thread)
1842   (if gnus-agent-fetching
1843       ;; FIXME: It seems doable in fetching mode.
1844       nil
1845     ;; Insert the unique article headers in the buffer.
1846     (let ((gnus-score-index (nth 1 (assoc header gnus-header-index)))
1847           (current-score-file gnus-current-score-file)
1848           (all-scores scores)
1849           ;; gnus-score-index is used as a free variable.
1850           alike last this art entries alist articles
1851           new news)
1852
1853       ;; Change score file to the adaptive score file.  All entries that
1854       ;; this function makes will be put into this file.
1855       (with-current-buffer gnus-summary-buffer
1856         (gnus-score-load-file
1857          (or gnus-newsgroup-adaptive-score-file
1858              (gnus-score-file-name
1859               gnus-newsgroup-name gnus-adaptive-file-suffix))))
1860
1861       (setq gnus-scores-articles (sort gnus-scores-articles
1862                                        'gnus-score-string<)
1863             articles gnus-scores-articles)
1864
1865       (erase-buffer)
1866       (while articles
1867         (setq art (car articles)
1868               this (aref (car art) gnus-score-index)
1869               articles (cdr articles))
1870         (if (equal last this)
1871             (push art alike)
1872           (when last
1873             (insert last ?\n)
1874             (put-text-property (1- (point)) (point) 'articles alike))
1875           (setq alike (list art)
1876                 last this)))
1877       (when last                        ; Bwadr, duplicate code.
1878         (insert last ?\n)
1879         (put-text-property (1- (point)) (point) 'articles alike))
1880
1881       ;; Find matches.
1882       (while scores
1883         (setq alist (car scores)
1884               scores (cdr scores)
1885               entries (assoc header alist))
1886         (while (cdr entries)            ;First entry is the header index.
1887           (let* ((rest (cdr entries))
1888                  (kill (car rest))
1889                  (match (nth 0 kill))
1890                  (type (or (nth 3 kill) 's))
1891                  (score (or (nth 1 kill) gnus-score-interactive-default-score))
1892                  (date (nth 2 kill))
1893                  (found nil)
1894                  (mt (aref (symbol-name type) 0))
1895                  (case-fold-search
1896                   (not (or (= mt ?R) (= mt ?S) (= mt ?E) (= mt ?F))))
1897                  (dmt (downcase mt))
1898                  (search-func
1899                   (cond ((= dmt ?r) 're-search-forward)
1900                         ((or (= dmt ?e) (= dmt ?s) (= dmt ?f)) 'search-forward)
1901                         (t (error "Invalid match type: %s" type))))
1902                  arts art)
1903             (goto-char (point-min))
1904             (if (= dmt ?e)
1905                 (while (funcall search-func match nil t)
1906                   (and (= (point-at-bol)
1907                           (match-beginning 0))
1908                        (= (progn (end-of-line) (point))
1909                           (match-end 0))
1910                        (progn
1911                          (setq found (setq arts (get-text-property
1912                                                  (point) 'articles)))
1913                          ;; Found a match, update scores.
1914                          (while arts
1915                            (setq art (car arts)
1916                                  arts (cdr arts))
1917                            (gnus-score-add-followups
1918                             (car art) score all-scores thread))))
1919                   (end-of-line))
1920               (while (funcall search-func match nil t)
1921