cgit.sxemacs.org Git - gnus/blob - lisp/gnus-salt.el

   1 ;;; gnus-salt.el --- alternate summary mode interfaces for Gnus
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  20 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (require 'gnus)
  27 (eval-when-compile (require 'cl))
  28
  29 ;;;
  30 ;;; gnus-pick-mode
  31 ;;;
  32
  33 (defvar gnus-pick-mode nil
  34   "Minor mode for providing a pick-and-read interface in Gnus summary buffers.")
  35
  36 (defvar gnus-pick-display-summary nil
  37   "*Display summary while reading.")
  38
  39 (defvar gnus-pick-mode-hook nil
  40   "Hook run in summary pick mode buffers.")
  41
  42 ;;; Internal variables.
  43
  44 (defvar gnus-pick-mode-map nil)
  45
  46 (unless gnus-pick-mode-map
  47   (setq gnus-pick-mode-map (make-sparse-keymap))
  48
  49   (gnus-define-keys
  50    gnus-pick-mode-map
  51    "t" gnus-uu-mark-thread
  52    "T" gnus-uu-unmark-thread
  53    " " gnus-summary-mark-as-processable
  54    "u" gnus-summary-unmark-as-processable
  55    "U" gnus-summary-unmark-all-processable
  56    "v" gnus-uu-mark-over
  57    "r" gnus-uu-mark-region
  58    "R" gnus-uu-unmark-region
  59    "e" gnus-uu-mark-by-regexp
  60    "E" gnus-uu-mark-by-regexp
  61    "b" gnus-uu-mark-buffer
  62    "B" gnus-uu-unmark-buffer
  63    "\r" gnus-pick-start-reading))
  64
  65 (defun gnus-pick-make-menu-bar ()
  66   (unless (boundp 'gnus-pick-menu)
  67     (easy-menu-define
  68      gnus-pick-menu gnus-pick-mode-map ""
  69      '("Pick"
  70        ("Pick"
  71         ["Article" gnus-summary-mark-as-processable t]
  72         ["Thread" gnus-uu-mark-thread t]
  73         ["Region" gnus-uu-mark-region t]
  74         ["Regexp" gnus-uu-mark-regexp t]
  75         ["Buffer" gnus-uu-mark-buffer t])
  76        ("Unpick"
  77         ["Article" gnus-summary-unmark-as-processable t]
  78         ["Thread" gnus-uu-unmark-thread t]
  79         ["Region" gnus-uu-unmark-region t]
  80         ["Regexp" gnus-uu-unmark-regexp t]
  81         ["Buffer" gnus-uu-unmark-buffer t])
  82        ["Start reading" gnus-pick-start-reading t]
  83        ["Switch pick mode off" gnus-pick-mode gnus-pick-mode]))))
  84
  85 (defun gnus-pick-mode (&optional arg)
  86   "Minor mode for provind a pick-and-read interface in Gnus summary buffers."
  87   (interactive "P")
  88   (when (eq major-mode 'gnus-summary-mode)
  89     (make-local-variable 'gnus-pick-mode)
  90     (setq gnus-pick-mode
  91           (if (null arg) (not gnus-pick-mode)
  92             (> (prefix-numeric-value arg) 0)))
  93     (when gnus-pick-mode
  94       ;; Make sure that we don't select any articles upon group entry.
  95       (make-local-variable 'gnus-auto-select-first)
  96       (setq gnus-auto-select-first nil)
  97       ;; Set up the menu.
  98       (when (and menu-bar-mode
  99                  (gnus-visual-p 'pick-menu 'menu))
 100         (gnus-pick-make-menu-bar))
 101       (unless (assq 'gnus-pick-mode minor-mode-alist)
 102         (push '(gnus-pick-mode " Pick") minor-mode-alist))
 103       (unless (assq 'gnus-topic-mode minor-mode-map-alist)
 104         (push (cons 'gnus-topic-mode gnus-pick-mode-map)
 105               minor-mode-map-alist))
 106       (run-hooks 'gnus-pick-mode-hook))))
 107
 108 (defun gnus-pick-start-reading (&optional catch-up)
 109   "Start reading the picked articles.
 110 If given a prefix, mark all unpicked articles as read."
 111   (interactive "P")
 112   (unless gnus-newsgroup-processable
 113     (error "No articles have been picked"))
 114   (gnus-summary-limit-to-articles nil)
 115   (when catch-up
 116     (gnus-summary-limit-mark-excluded-as-read))
 117   (gnus-configure-windows (if gnus-pick-display-summary 'summary 'pick) t))
 118
 119
 120 ;;;
 121 ;;; gnus-binary-mode
 122 ;;;
 123
 124 (defvar gnus-binary-mode nil
 125   "Minor mode for provind a binary group interface in Gnus summary buffers.")
 126
 127 (defvar gnus-binary-mode-hook nil
 128   "Hook run in summary binary mode buffers.")
 129
 130 (defvar gnus-binary-mode-map nil)
 131
 132 (unless gnus-binary-mode-map
 133   (setq gnus-binary-mode-map (make-sparse-keymap))
 134
 135   (gnus-define-keys
 136    gnus-binary-mode-map
 137    "g" gnus-binary-show-article))
 138
 139 (defun gnus-binary-make-menu-bar ()
 140   (unless (boundp 'gnus-binary-menu)
 141     (easy-menu-define
 142      gnus-binary-menu gnus-binary-mode-map ""
 143      '("Pick"
 144        ["Switch binary mode off" gnus-binary-mode t]))))
 145
 146 (defun gnus-binary-mode (&optional arg)
 147   "Minor mode for providing a binary group interface in Gnus summary buffers."
 148   (interactive "P")
 149   (when (eq major-mode 'gnus-summary-mode)
 150     (make-local-variable 'gnus-binary-mode)
 151     (setq gnus-binary-mode
 152           (if (null arg) (not gnus-binary-mode)
 153             (> (prefix-numeric-value arg) 0)))
 154     (when gnus-binary-mode
 155       ;; Make sure that we don't select any articles upon group entry.
 156       (make-local-variable 'gnus-auto-select-first)
 157       (setq gnus-auto-select-first nil)
 158       (make-local-variable 'gnus-summary-display-article-function)
 159       (setq gnus-summary-display-article-function 'gnus-binary-display-article)
 160       ;; Set up the menu.
 161       (when (and menu-bar-mode
 162                  (gnus-visual-p 'binary-menu 'menu))
 163         (gnus-binary-make-menu-bar))
 164       (unless (assq 'gnus-binary-mode minor-mode-alist)
 165         (push '(gnus-binary-mode " Binary") minor-mode-alist))
 166       (unless (assq 'gnus-topic-mode minor-mode-map-alist)
 167         (push (cons 'gnus-topic-mode gnus-binary-mode-map)
 168               minor-mode-map-alist))
 169       (run-hooks 'gnus-binary-mode-hook))))
 170
 171 (defun gnus-binary-display-article (article &optional all-header)
 172   "Run ARTICLE through the binary decode functions."
 173   (when (gnus-summary-goto-subject article)
 174     (let ((gnus-view-pseudos 'automatic))
 175       (gnus-uu-decode-uu))))
 176
 177 (defun gnus-binary-show-article (&optional arg)
 178   "Bypass the binary functions and show the article."
 179   (interactive "P")
 180   (let (gnus-summary-display-article-function)
 181     (gnus-summary-show-article arg)))
 182
 183 ;;;
 184 ;;; gnus-tree-mode
 185 ;;;
 186
 187 (defvar gnus-tree-line-format "%(%[%3,3n%]%)"
 188   "Format of tree elements.")
 189
 190 (defvar gnus-tree-minimize-window t
 191   "If non-nil, minimize the tree buffer window.
 192 If a number, never let the tree buffer grow taller than that number of
 193 lines.")
 194
 195 (defvar gnus-selected-tree-face 'modeline
 196   "*Face used for highlighting selected articles in the thread tree.")
 197
 198 (defvar gnus-tree-brackets '((?\[ . ?\]) (?\( . ?\)) (?\{ . ?\}))
 199   "Brackets used in tree nodes.")
 200
 201 (defvar gnus-tree-parent-child-edges '(?- ?\\ ?|)
 202   "Charaters used to connect parents with children.")
 203
 204 (defvar gnus-tree-mode-line-format "Gnus: %%b %S %Z"
 205   "*The format specification for the tree mode line.")
 206
 207 (defvar gnus-generate-tree-function 'gnus-generate-vertical-tree
 208   "*Function for generating a thread tree.
 209 Two predefined functions are available:
 210 `gnus-generate-horizontal-tree' and `gnus-generate-vertical-tree'.")
 211
 212 (defvar gnus-tree-mode-hook nil
 213   "*Hook run in tree mode buffers.")
 214
 215 (defvar gnus-tree-buffer "*Tree*"
 216   "Buffer where Gnus thread trees are displayed.")
 217
 218 ;;; Internal variables.
 219
 220 (defvar gnus-tree-line-format-alist
 221   `((?n gnus-tmp-name ?s)
 222     (?f gnus-tmp-from ?s)
 223     (?N gnus-tmp-number ?d)
 224     (?\[ gnus-tmp-open-bracket ?c)
 225     (?\] gnus-tmp-close-bracket ?c)
 226     (?s gnus-tmp-subject ?s)))
 227
 228 (defvar gnus-tree-mode-line-format-alist gnus-summary-mode-line-format-alist)
 229
 230 (defvar gnus-tree-mode-line-format-spec nil)
 231 (defvar gnus-tree-line-format-spec nil)
 232
 233 (defvar gnus-tree-node-length nil)
 234 (defvar gnus-selected-tree-overlay nil)
 235
 236 (defvar gnus-tree-displayed-thread nil)
 237
 238 (defvar gnus-tree-mode-map nil)
 239 (put 'gnus-tree-mode 'mode-class 'special)
 240
 241 (unless gnus-tree-mode-map
 242   (setq gnus-tree-mode-map (make-keymap))
 243   (suppress-keymap gnus-tree-mode-map)
 244   (gnus-define-keys
 245    gnus-tree-mode-map
 246    "\r" gnus-tree-select-article
 247    gnus-mouse-2 gnus-tree-pick-article
 248    "\C-?" gnus-tree-read-summary-keys)
 249
 250   (substitute-key-definition
 251    'undefined 'gnus-tree-read-summary-keys gnus-tree-mode-map))
 252
 253 (defun gnus-tree-make-menu-bar ()
 254   )
 255
 256 (defun gnus-tree-mode ()
 257   "Major mode for displaying thread trees."
 258   (interactive)
 259   (setq gnus-tree-mode-line-format-spec
 260         (gnus-parse-format gnus-tree-mode-line-format
 261                            gnus-summary-mode-line-format-alist))
 262   (setq gnus-tree-line-format-spec
 263         (gnus-parse-format gnus-tree-line-format
 264                            gnus-tree-line-format-alist t))
 265   (when (and menu-bar-mode
 266              (gnus-visual-p 'tree-menu 'menu))
 267     (gnus-tree-make-menu-bar))
 268   (kill-all-local-variables)
 269   (gnus-simplify-mode-line)
 270   (setq mode-name "Tree")
 271   (setq major-mode 'gnus-tree-mode)
 272   (use-local-map gnus-tree-mode-map)
 273   (buffer-disable-undo (current-buffer))
 274   (setq buffer-read-only t)
 275   (setq truncate-lines t)
 276   (save-excursion
 277     (gnus-set-work-buffer)
 278     (gnus-tree-node-insert (make-mail-header "") nil)
 279     (setq gnus-tree-node-length (1- (point))))
 280   (run-hooks 'gnus-tree-mode-hook))
 281
 282 (defun gnus-tree-read-summary-keys (&optional arg)
 283   "Read a summary buffer key sequence and execute it."
 284   (interactive "P")
 285   (let ((buf (current-buffer))
 286         win)
 287     (gnus-article-read-summary-keys arg nil t)
 288     (when (setq win (get-buffer-window buf))
 289       (select-window win)
 290       (when gnus-selected-tree-overlay
 291         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 292       (gnus-tree-minimize))))
 293
 294 (defun gnus-tree-select-article (article)
 295   "Select the article under point, if any."
 296   (interactive (list (gnus-tree-article-number)))
 297   (let ((buf (current-buffer)))
 298     (when article
 299       (save-excursion
 300         (set-buffer gnus-summary-buffer)
 301         (gnus-summary-goto-article article))
 302       (select-window (get-buffer-window buf)))))
 303
 304 (defun gnus-tree-pick-article (e)
 305   "Select the article under the mouse pointer."
 306   (interactive "e")
 307   (mouse-set-point e)
 308   (gnus-tree-select-article (gnus-tree-article-number)))
 309
 310 (defun gnus-tree-article-number ()
 311   (get-text-property (point) 'gnus-number))
 312
 313 (defun gnus-tree-article-region (article)
 314   "Return a cons with BEG and END of the article region."
 315   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 316     (when pos
 317       (cons pos (next-single-property-change pos 'gnus-number)))))
 318
 319 (defun gnus-tree-goto-article (article)
 320   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 321     (when pos
 322       (goto-char pos))))
 323
 324 (defun gnus-tree-recenter ()
 325   "Center point in the tree window."
 326   (let ((selected (selected-window))
 327         (cur-window (get-buffer-window (current-buffer) t)))
 328     (when cur-window
 329       (select-window cur-window)
 330       (when gnus-selected-tree-overlay
 331         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 332       (let* ((top (cond ((< (window-height) 4) 0)
 333                         ((< (window-height) 7) 1)
 334                         (t 2)))
 335              (height (1- (window-height)))
 336              (bottom (save-excursion (goto-char (point-max))
 337                                      (forward-line (- height))
 338                                      (point))))
 339         ;; Set the window start to either `bottom', which is the biggest
 340         ;; possible valid number, or the second line from the top,
 341         ;; whichever is the least.
 342         (set-window-start
 343          cur-window (min bottom (save-excursion
 344                               (forward-line (- top)) (point)))))
 345       (select-window selected))))
 346
 347 (defun gnus-get-tree-buffer ()
 348   "Return the tree buffer properly initialized."
 349   (save-excursion
 350     (set-buffer (get-buffer-create gnus-tree-buffer))
 351     (unless (eq major-mode 'gnus-tree-mode)
 352       (gnus-add-current-to-buffer-list)
 353       (gnus-tree-mode))
 354     (current-buffer)))
 355
 356 (defun gnus-tree-minimize ()
 357   (when (and gnus-tree-minimize-window
 358              (not (one-window-p)))
 359     (let* ((window-min-height 2)
 360            (height (count-lines (point-min) (point-max)))
 361            (min (max (1- window-min-height) height))
 362            (tot (if (numberp gnus-tree-minimize-window)
 363                     (min gnus-tree-minimize-window min)
 364                   min))
 365            (win (get-buffer-window (current-buffer)))
 366            (wh (and win (1- (window-height win)))))
 367       (when (and win
 368                  (not (eq tot wh)))
 369         (let ((selected (selected-window)))
 370           (select-window win)
 371           (enlarge-window (- tot wh))
 372           (select-window selected))))))
 373
 374 ;;; Generating the tree.
 375
 376 (defun gnus-tree-node-insert (header sparse)
 377   (let* ((dummy (stringp header))
 378          (header (if (vectorp header) header
 379                    (progn
 380                      (setq header (make-mail-header "*****"))
 381                      (mail-header-set-number header 0)
 382                      (mail-header-set-lines header 0)
 383                      (mail-header-set-chars header 0)
 384                      header)))
 385          (gnus-tmp-from (mail-header-from header))
 386          (gnus-tmp-subject (mail-header-subject header))
 387          (gnus-tmp-number (mail-header-number header))
 388          (gnus-tmp-name
 389           (cond
 390            ((string-match "(.+)" gnus-tmp-from)
 391             (substring gnus-tmp-from
 392                        (1+ (match-beginning 0)) (1- (match-end 0))))
 393            ((string-match "<[^>]+> *$" gnus-tmp-from)
 394             (let ((beg (match-beginning 0)))
 395               (or (and (string-match "^\"[^\"]*\"" gnus-tmp-from)
 396                        (substring gnus-tmp-from (1+ (match-beginning 0))
 397                                   (1- (match-end 0))))
 398                   (substring gnus-tmp-from 0 beg))))
 399            ((memq gnus-tmp-number sparse)
 400             "***")
 401            (t gnus-tmp-from)))
 402          (gnus-tmp-open-bracket
 403           (cond ((memq gnus-tmp-number sparse)
 404                  (caadr gnus-tree-brackets))
 405                 (dummy (caaddr gnus-tree-brackets))
 406                 (t (caar gnus-tree-brackets))))
 407          (gnus-tmp-close-bracket
 408           (cond ((memq gnus-tmp-number sparse)
 409                  (cdadr gnus-tree-brackets))
 410                 (dummy
 411                  (cdaddr gnus-tree-brackets))
 412                 (t (cdar gnus-tree-brackets))))
 413          (buffer-read-only nil)
 414          beg end)
 415     (add-text-properties
 416      (setq beg (point))
 417      (setq end (progn (eval gnus-tree-line-format-spec) (point)))
 418      (list 'gnus-number gnus-tmp-number))
 419     (when (or t (gnus-visual-p 'tree-highlight 'highlight))
 420       (gnus-tree-highlight-node gnus-tmp-number beg end))))
 421
 422 (defun gnus-tree-highlight-node (article beg end)
 423   "Highlight current line according to `gnus-summary-highlight'."
 424   (let ((list gnus-summary-highlight)
 425         face)
 426     (save-excursion
 427       (set-buffer gnus-summary-buffer)
 428       (let* ((score (or (cdr (assq article gnus-newsgroup-scored))
 429                         gnus-summary-default-score 0))
 430              (default gnus-summary-default-score)
 431              (mark (or (gnus-summary-article-mark article) gnus-unread-mark)))
 432         ;; Eval the cars of the lists until we find a match.
 433         (while (and list
 434                     (not (eval (caar list))))
 435           (setq list (cdr list)))))
 436     (unless (eq (setq face (cdar list)) (get-text-property beg 'face))
 437       (put-text-property
 438        beg end 'face
 439        (if (boundp face) (symbol-value face) face)))))
 440
 441 (defun gnus-tree-indent (level)
 442   (insert (make-string (1- (* (1+ gnus-tree-node-length) level)) ? )))
 443
 444 (defvar gnus-tmp-limit)
 445 (defvar gnus-tmp-sparse)
 446 (defvar gnus-tmp-indent)
 447
 448 (defun gnus-generate-tree (thread)
 449   "Generate a thread tree for THREAD."
 450   (save-excursion
 451     (set-buffer (gnus-get-tree-buffer))
 452     (let ((buffer-read-only nil)
 453           (gnus-tmp-indent 0))
 454       (erase-buffer)
 455       (funcall gnus-generate-tree-function thread 0)
 456       (gnus-set-mode-line 'tree)
 457       (goto-char (point-min))
 458       (gnus-tree-minimize)
 459       (gnus-tree-recenter)
 460       (let ((selected (selected-window)))
 461         (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 462         (gnus-horizontal-recenter)
 463         (select-window selected)))))
 464
 465 (defun gnus-generate-horizontal-tree (thread level &optional dummyp)
 466   "Generate a horizontal tree."
 467   (let* ((dummy (stringp (car thread)))
 468          (do (or dummy
 469                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 470          col beg)
 471     (if (not do)
 472         ;; We don't want this article.
 473         (setq thread (cdr thread))
 474       (if (not (bolp))
 475           ;; Not the first article on the line, so we insert a "-".
 476           (insert (car gnus-tree-parent-child-edges))
 477         ;; If the level isn't zero, then we insert some indentation.
 478         (unless (zerop level)
 479           (gnus-tree-indent level)
 480           (insert (cadr gnus-tree-parent-child-edges))
 481           (setq col (- (setq beg (point)) (gnus-point-at-bol) 1))
 482           ;; Draw "|" lines upwards.
 483           (while (progn
 484                    (forward-line -1)
 485                    (forward-char col)
 486                    (= (following-char) ? ))
 487             (delete-char 1)
 488             (insert (caddr gnus-tree-parent-child-edges)))
 489           (goto-char beg)))
 490       (setq dummyp nil)
 491       ;; Insert the article node.
 492       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse))
 493     (if (null thread)
 494         ;; End of the thread, so we go to the next line.
 495         (unless (bolp)
 496           (insert "\n"))
 497       ;; Recurse downwards in all children of this article.
 498       (while thread
 499         (gnus-generate-horizontal-tree
 500          (pop thread) (if do (1+ level) level)
 501          (or dummyp dummy))))))
 502
 503 (defsubst gnus-tree-indent-vertical ()
 504   (let ((len (- (* (1+ gnus-tree-node-length) gnus-tmp-indent)
 505                 (- (point) (gnus-point-at-bol)))))
 506     (when (> len 0)
 507       (insert (make-string len ? )))))
 508
 509 (defsubst gnus-tree-forward-line (n)
 510   (while (>= (decf n) 0)
 511     (unless (zerop (forward-line 1))
 512       (end-of-line)
 513       (insert "\n")))
 514   (end-of-line))
 515
 516 (defun gnus-generate-vertical-tree (thread level &optional dummyp)
 517   "Generate a vertical tree."
 518   (let* ((dummy (stringp (car thread)))
 519          (do (or dummy
 520                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 521          col beg)
 522     (if (not do)
 523         ;; We don't want this article.
 524         (setq thread (cdr thread))
 525       (if (not (save-excursion (beginning-of-line) (bobp)))
 526           ;; Not the first article on the line, so we insert a "-".
 527           (progn
 528             (gnus-tree-indent-vertical)
 529             (insert (make-string (/ gnus-tree-node-length 2) ? ))
 530             (insert (caddr gnus-tree-parent-child-edges))
 531             (gnus-tree-forward-line 1))
 532         ;; If the level isn't zero, then we insert some indentation.
 533         (unless (zerop gnus-tmp-indent)
 534           (gnus-tree-forward-line (1- (* 2 level)))
 535           (gnus-tree-indent-vertical)
 536           (delete-char -1)
 537           (insert (cadr gnus-tree-parent-child-edges))
 538           (setq beg (point))
 539           ;; Draw "-" lines leftwards.
 540           (while (progn
 541                    (forward-char -2)
 542                    (= (following-char) ? ))
 543             (delete-char 1)
 544             (insert (car gnus-tree-parent-child-edges)))
 545           (goto-char beg)
 546           (gnus-tree-forward-line 1)))
 547       (setq dummyp nil)
 548       ;; Insert the article node.
 549       (gnus-tree-indent-vertical)
 550       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse)
 551       (gnus-tree-forward-line 1))
 552     (if (null thread)
 553         ;; End of the thread, so we go to the next line.
 554         (progn
 555           (goto-char (point-min))
 556           (end-of-line)
 557           (incf gnus-tmp-indent))
 558       ;; Recurse downwards in all children of this article.
 559       (while thread
 560         (gnus-generate-vertical-tree
 561          (pop thread) (if do (1+ level) level)
 562          (or dummyp dummy))))))
 563
 564 ;;; Interface functions.
 565
 566 (defun gnus-possibly-generate-tree (article &optional force)
 567   "Generate the thread tree for ARTICLE if it isn't displayed already."
 568   (save-excursion
 569     (let ((top (save-excursion
 570                  (set-buffer gnus-summary-buffer)
 571                  (gnus-cut-thread
 572                   (gnus-remove-thread
 573                    (mail-header-id (gnus-summary-article-header article)) t))))
 574           (gnus-tmp-limit gnus-newsgroup-limit)
 575           (gnus-tmp-sparse gnus-newsgroup-sparse))
 576       (when (or force
 577                 (not (eq top gnus-tree-displayed-thread)))
 578         (gnus-generate-tree top)
 579         (setq gnus-tree-displayed-thread top)))))
 580
 581 (defun gnus-tree-open (group)
 582   (gnus-get-tree-buffer))
 583
 584 (defun gnus-tree-close (group)
 585   (gnus-kill-buffer gnus-tree-buffer))
 586
 587 (defun gnus-highlight-selected-tree (article)
 588   "Highlight the selected article in the tree."
 589   (let ((buf (current-buffer))
 590         region)
 591     (set-buffer gnus-tree-buffer)
 592     (when (setq region (gnus-tree-article-region article))
 593       (when (or (not gnus-selected-tree-overlay)
 594                 (and (fboundp 'extent-detached-p)
 595                      (extent-detached-p gnus-selected-tree-overlay)))
 596         ;; Create a new overlay.
 597         (gnus-overlay-put
 598          (setq gnus-selected-tree-overlay (gnus-make-overlay 1 2))
 599          'face gnus-selected-tree-face))
 600       ;; Move the overlay to the article.
 601       (gnus-move-overlay
 602        gnus-selected-tree-overlay (goto-char (car region)) (cdr region))
 603       (gnus-tree-minimize)
 604       (gnus-tree-recenter)
 605       (let ((selected (selected-window)))
 606         (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 607         (gnus-horizontal-recenter)
 608         (select-window selected)))
 609     ;; If we remove this save-excursion, it updates the wrong mode lines?!?
 610     (save-excursion
 611       (set-buffer gnus-tree-buffer)
 612       (gnus-set-mode-line 'tree))
 613     (set-buffer buf)))
 614
 615 (defun gnus-tree-highlight-article (article face)
 616   (save-excursion
 617     (set-buffer (gnus-get-tree-buffer))
 618     (let (region)
 619       (when (setq region (gnus-tree-article-region article))
 620         (put-text-property (car region) (cdr region) 'face face)
 621         (set-window-point
 622          (get-buffer-window (current-buffer) t) (cdr region))))))
 623
 624
 625 ;;; Allow redefinition of functions.
 626 (gnus-ems-redefine)
 627
 628 (provide 'gnus-salt)
 629
 630 ;;; gnus-salt.el ends here