cgit.sxemacs.org Git - gnus/blob - lisp/gnus-salt.el

   1 ;;; gnus-salt.el --- alternate summary mode interfaces for Gnus
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28 (eval-when-compile (require 'cl))
  29
  30 ;;;
  31 ;;; gnus-pick-mode
  32 ;;;
  33
  34 (defvar gnus-pick-mode nil
  35   "Minor mode for providing a pick-and-read interface in Gnus summary buffers.")
  36
  37 (defvar gnus-pick-display-summary nil
  38   "*Display summary while reading.")
  39
  40 (defvar gnus-pick-mode-hook nil
  41   "Hook run in summary pick mode buffers.")
  42
  43 ;;; Internal variables.
  44
  45 (defvar gnus-pick-mode-map nil)
  46
  47 (unless gnus-pick-mode-map
  48   (setq gnus-pick-mode-map (make-sparse-keymap))
  49
  50   (gnus-define-keys
  51    gnus-pick-mode-map
  52    "t" gnus-uu-mark-thread
  53    "T" gnus-uu-unmark-thread
  54    " " gnus-summary-mark-as-processable
  55    "u" gnus-summary-unmark-as-processable
  56    "U" gnus-summary-unmark-all-processable
  57    "v" gnus-uu-mark-over
  58    "r" gnus-uu-mark-region
  59    "R" gnus-uu-unmark-region
  60    "e" gnus-uu-mark-by-regexp
  61    "E" gnus-uu-mark-by-regexp
  62    "b" gnus-uu-mark-buffer
  63    "B" gnus-uu-unmark-buffer
  64    "\r" gnus-pick-start-reading))
  65
  66 (defun gnus-pick-make-menu-bar ()
  67   (unless (boundp 'gnus-pick-menu)
  68     (easy-menu-define
  69      gnus-pick-menu gnus-pick-mode-map ""
  70      '("Pick"
  71        ("Pick"
  72         ["Article" gnus-summary-mark-as-processable t]
  73         ["Thread" gnus-uu-mark-thread t]
  74         ["Region" gnus-uu-mark-region t]
  75         ["Regexp" gnus-uu-mark-regexp t]
  76         ["Buffer" gnus-uu-mark-buffer t])
  77        ("Unpick"
  78         ["Article" gnus-summary-unmark-as-processable t]
  79         ["Thread" gnus-uu-unmark-thread t]
  80         ["Region" gnus-uu-unmark-region t]
  81         ["Regexp" gnus-uu-unmark-regexp t]
  82         ["Buffer" gnus-uu-unmark-buffer t])
  83        ["Start reading" gnus-pick-start-reading t]
  84        ["Switch pick mode off" gnus-pick-mode gnus-pick-mode]))))
  85
  86 (defun gnus-pick-mode (&optional arg)
  87   "Minor mode for providing a pick-and-read interface in Gnus summary buffers."
  88   (interactive "P")
  89   (when (eq major-mode 'gnus-summary-mode)
  90     (make-local-variable 'gnus-pick-mode)
  91     (setq gnus-pick-mode
  92           (if (null arg) (not gnus-pick-mode)
  93             (> (prefix-numeric-value arg) 0)))
  94     (when gnus-pick-mode
  95       ;; Make sure that we don't select any articles upon group entry.
  96       (make-local-variable 'gnus-auto-select-first)
  97       (setq gnus-auto-select-first nil)
  98       ;; Set up the menu.
  99       (when (and menu-bar-mode
 100                  (gnus-visual-p 'pick-menu 'menu))
 101         (gnus-pick-make-menu-bar))
 102       (unless (assq 'gnus-pick-mode minor-mode-alist)
 103         (push '(gnus-pick-mode " Pick") minor-mode-alist))
 104       (unless (assq 'gnus-pick-mode minor-mode-map-alist)
 105         (push (cons 'gnus-pick-mode gnus-pick-mode-map)
 106               minor-mode-map-alist))
 107       (run-hooks 'gnus-pick-mode-hook))))
 108
 109 (defun gnus-pick-start-reading (&optional catch-up)
 110   "Start reading the picked articles.
 111 If given a prefix, mark all unpicked articles as read."
 112   (interactive "P")
 113   (unless gnus-newsgroup-processable
 114     (error "No articles have been picked"))
 115   (gnus-summary-limit-to-articles nil)
 116   (when catch-up
 117     (gnus-summary-limit-mark-excluded-as-read))
 118   (gnus-configure-windows (if gnus-pick-display-summary 'summary 'pick) t))
 119
 120
 121 ;;;
 122 ;;; gnus-binary-mode
 123 ;;;
 124
 125 (defvar gnus-binary-mode nil
 126   "Minor mode for provind a binary group interface in Gnus summary buffers.")
 127
 128 (defvar gnus-binary-mode-hook nil
 129   "Hook run in summary binary mode buffers.")
 130
 131 (defvar gnus-binary-mode-map nil)
 132
 133 (unless gnus-binary-mode-map
 134   (setq gnus-binary-mode-map (make-sparse-keymap))
 135
 136   (gnus-define-keys
 137    gnus-binary-mode-map
 138    "g" gnus-binary-show-article))
 139
 140 (defun gnus-binary-make-menu-bar ()
 141   (unless (boundp 'gnus-binary-menu)
 142     (easy-menu-define
 143      gnus-binary-menu gnus-binary-mode-map ""
 144      '("Pick"
 145        ["Switch binary mode off" gnus-binary-mode t]))))
 146
 147 (defun gnus-binary-mode (&optional arg)
 148   "Minor mode for providing a binary group interface in Gnus summary buffers."
 149   (interactive "P")
 150   (when (eq major-mode 'gnus-summary-mode)
 151     (make-local-variable 'gnus-binary-mode)
 152     (setq gnus-binary-mode
 153           (if (null arg) (not gnus-binary-mode)
 154             (> (prefix-numeric-value arg) 0)))
 155     (when gnus-binary-mode
 156       ;; Make sure that we don't select any articles upon group entry.
 157       (make-local-variable 'gnus-auto-select-first)
 158       (setq gnus-auto-select-first nil)
 159       (make-local-variable 'gnus-summary-display-article-function)
 160       (setq gnus-summary-display-article-function 'gnus-binary-display-article)
 161       ;; Set up the menu.
 162       (when (and menu-bar-mode
 163                  (gnus-visual-p 'binary-menu 'menu))
 164         (gnus-binary-make-menu-bar))
 165       (unless (assq 'gnus-binary-mode minor-mode-alist)
 166         (push '(gnus-binary-mode " Binary") minor-mode-alist))
 167       (unless (assq 'gnus-topic-mode minor-mode-map-alist)
 168         (push (cons 'gnus-topic-mode gnus-binary-mode-map)
 169               minor-mode-map-alist))
 170       (run-hooks 'gnus-binary-mode-hook))))
 171
 172 (defun gnus-binary-display-article (article &optional all-header)
 173   "Run ARTICLE through the binary decode functions."
 174   (when (gnus-summary-goto-subject article)
 175     (let ((gnus-view-pseudos 'automatic))
 176       (gnus-uu-decode-uu))))
 177
 178 (defun gnus-binary-show-article (&optional arg)
 179   "Bypass the binary functions and show the article."
 180   (interactive "P")
 181   (let (gnus-summary-display-article-function)
 182     (gnus-summary-show-article arg)))
 183
 184 ;;;
 185 ;;; gnus-tree-mode
 186 ;;;
 187
 188 (defvar gnus-tree-line-format "%(%[%3,3n%]%)"
 189   "Format of tree elements.")
 190
 191 (defvar gnus-tree-minimize-window t
 192   "If non-nil, minimize the tree buffer window.
 193 If a number, never let the tree buffer grow taller than that number of
 194 lines.")
 195
 196 (defvar gnus-selected-tree-face 'modeline
 197   "*Face used for highlighting selected articles in the thread tree.")
 198
 199 (defvar gnus-tree-brackets '((?\[ . ?\]) (?\( . ?\))
 200                              (?\{ . ?\}) (?< . ?>))
 201   "Brackets used in tree nodes.")
 202
 203 (defvar gnus-tree-parent-child-edges '(?- ?\\ ?|)
 204   "Charaters used to connect parents with children.")
 205
 206 (defvar gnus-tree-mode-line-format "Gnus: %%b %S %Z"
 207   "*The format specification for the tree mode line.")
 208
 209 (defvar gnus-generate-tree-function 'gnus-generate-vertical-tree
 210   "*Function for generating a thread tree.
 211 Two predefined functions are available:
 212 `gnus-generate-horizontal-tree' and `gnus-generate-vertical-tree'.")
 213
 214 (defvar gnus-tree-mode-hook nil
 215   "*Hook run in tree mode buffers.")
 216
 217 (defvar gnus-tree-buffer "*Tree*"
 218   "Buffer where Gnus thread trees are displayed.")
 219
 220 ;;; Internal variables.
 221
 222 (defvar gnus-tree-line-format-alist
 223   `((?n gnus-tmp-name ?s)
 224     (?f gnus-tmp-from ?s)
 225     (?N gnus-tmp-number ?d)
 226     (?\[ gnus-tmp-open-bracket ?c)
 227     (?\] gnus-tmp-close-bracket ?c)
 228     (?s gnus-tmp-subject ?s)))
 229
 230 (defvar gnus-tree-mode-line-format-alist gnus-summary-mode-line-format-alist)
 231
 232 (defvar gnus-tree-mode-line-format-spec nil)
 233 (defvar gnus-tree-line-format-spec nil)
 234
 235 (defvar gnus-tree-node-length nil)
 236 (defvar gnus-selected-tree-overlay nil)
 237
 238 (defvar gnus-tree-displayed-thread nil)
 239
 240 (defvar gnus-tree-mode-map nil)
 241 (put 'gnus-tree-mode 'mode-class 'special)
 242
 243 (unless gnus-tree-mode-map
 244   (setq gnus-tree-mode-map (make-keymap))
 245   (suppress-keymap gnus-tree-mode-map)
 246   (gnus-define-keys
 247    gnus-tree-mode-map
 248    "\r" gnus-tree-select-article
 249    gnus-mouse-2 gnus-tree-pick-article
 250    "\C-?" gnus-tree-read-summary-keys)
 251
 252   (substitute-key-definition
 253    'undefined 'gnus-tree-read-summary-keys gnus-tree-mode-map))
 254
 255 (defun gnus-tree-make-menu-bar ()
 256   (unless (boundp 'gnus-tree-menu)
 257     (easy-menu-define
 258      gnus-tree-menu gnus-tree-mode-map ""
 259      '("Tree"))))
 260
 261 (defun gnus-tree-mode ()
 262   "Major mode for displaying thread trees."
 263   (interactive)
 264   (setq gnus-tree-mode-line-format-spec
 265         (gnus-parse-format gnus-tree-mode-line-format
 266                            gnus-summary-mode-line-format-alist))
 267   (setq gnus-tree-line-format-spec
 268         (gnus-parse-format gnus-tree-line-format
 269                            gnus-tree-line-format-alist t))
 270   (when (and menu-bar-mode
 271              (gnus-visual-p 'tree-menu 'menu))
 272     (gnus-tree-make-menu-bar))
 273   (kill-all-local-variables)
 274   (gnus-simplify-mode-line)
 275   (setq mode-name "Tree")
 276   (setq major-mode 'gnus-tree-mode)
 277   (use-local-map gnus-tree-mode-map)
 278   (buffer-disable-undo (current-buffer))
 279   (setq buffer-read-only t)
 280   (setq truncate-lines t)
 281   (save-excursion
 282     (gnus-set-work-buffer)
 283     (gnus-tree-node-insert (make-mail-header "") nil)
 284     (setq gnus-tree-node-length (1- (point))))
 285   (run-hooks 'gnus-tree-mode-hook))
 286
 287 (defun gnus-tree-read-summary-keys (&optional arg)
 288   "Read a summary buffer key sequence and execute it."
 289   (interactive "P")
 290   (let ((buf (current-buffer))
 291         win)
 292     (gnus-article-read-summary-keys arg nil t)
 293     (when (setq win (get-buffer-window buf))
 294       (select-window win)
 295       (when gnus-selected-tree-overlay
 296         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 297       (gnus-tree-minimize))))
 298
 299 (defun gnus-tree-select-article (article)
 300   "Select the article under point, if any."
 301   (interactive (list (gnus-tree-article-number)))
 302   (let ((buf (current-buffer)))
 303     (when article
 304       (save-excursion
 305         (set-buffer gnus-summary-buffer)
 306         (gnus-summary-goto-article article))
 307       (select-window (get-buffer-window buf)))))
 308
 309 (defun gnus-tree-pick-article (e)
 310   "Select the article under the mouse pointer."
 311   (interactive "e")
 312   (mouse-set-point e)
 313   (gnus-tree-select-article (gnus-tree-article-number)))
 314
 315 (defun gnus-tree-article-number ()
 316   (get-text-property (point) 'gnus-number))
 317
 318 (defun gnus-tree-article-region (article)
 319   "Return a cons with BEG and END of the article region."
 320   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 321     (when pos
 322       (cons pos (next-single-property-change pos 'gnus-number)))))
 323
 324 (defun gnus-tree-goto-article (article)
 325   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 326     (when pos
 327       (goto-char pos))))
 328
 329 (defun gnus-tree-recenter ()
 330   "Center point in the tree window."
 331   (let ((selected (selected-window))
 332         (tree-window (get-buffer-window gnus-tree-buffer t)))
 333     (when tree-window
 334       (select-window tree-window)
 335       (when gnus-selected-tree-overlay
 336         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 337       (let* ((top (cond ((< (window-height) 4) 0)
 338                         ((< (window-height) 7) 1)
 339                         (t 2)))
 340              (height (1- (window-height)))
 341              (bottom (save-excursion (goto-char (point-max))
 342                                      (forward-line (- height))
 343                                      (point))))
 344         ;; Set the window start to either `bottom', which is the biggest
 345         ;; possible valid number, or the second line from the top,
 346         ;; whichever is the least.
 347         (set-window-start
 348          tree-window (min bottom (save-excursion
 349                                    (forward-line (- top)) (point)))))
 350       (select-window selected))))
 351
 352 (defun gnus-get-tree-buffer ()
 353   "Return the tree buffer properly initialized."
 354   (save-excursion
 355     (set-buffer (get-buffer-create gnus-tree-buffer))
 356     (unless (eq major-mode 'gnus-tree-mode)
 357       (gnus-add-current-to-buffer-list)
 358       (gnus-tree-mode))
 359     (current-buffer)))
 360
 361 (defun gnus-tree-minimize ()
 362   (when (and gnus-tree-minimize-window
 363              (not (one-window-p)))
 364     (let* ((window-min-height 2)
 365            (height (count-lines (point-min) (point-max)))
 366            (min (max (1- window-min-height) height))
 367            (tot (if (numberp gnus-tree-minimize-window)
 368                     (min gnus-tree-minimize-window min)
 369                   min))
 370            (win (get-buffer-window (current-buffer)))
 371            (wh (and win (1- (window-height win)))))
 372       (when (and win
 373                  (not (eq tot wh)))
 374         (let ((selected (selected-window)))
 375           (select-window win)
 376           (enlarge-window (- tot wh))
 377           (select-window selected))))))
 378
 379 ;;; Generating the tree.
 380
 381 (defun gnus-tree-node-insert (header sparse &optional adopted)
 382   (let* ((dummy (stringp header))
 383          (header (if (vectorp header) header
 384                    (progn
 385                      (setq header (make-mail-header "*****"))
 386                      (mail-header-set-number header 0)
 387                      (mail-header-set-lines header 0)
 388                      (mail-header-set-chars header 0)
 389                      header)))
 390          (gnus-tmp-from (mail-header-from header))
 391          (gnus-tmp-subject (mail-header-subject header))
 392          (gnus-tmp-number (mail-header-number header))
 393          (gnus-tmp-name
 394           (cond
 395            ((string-match "(.+)" gnus-tmp-from)
 396             (substring gnus-tmp-from
 397                        (1+ (match-beginning 0)) (1- (match-end 0))))
 398            ((string-match "<[^>]+> *$" gnus-tmp-from)
 399             (let ((beg (match-beginning 0)))
 400               (or (and (string-match "^\"[^\"]*\"" gnus-tmp-from)
 401                        (substring gnus-tmp-from (1+ (match-beginning 0))
 402                                   (1- (match-end 0))))
 403                   (substring gnus-tmp-from 0 beg))))
 404            ((memq gnus-tmp-number sparse)
 405             "***")
 406            (t gnus-tmp-from)))
 407          (gnus-tmp-open-bracket
 408           (cond ((memq gnus-tmp-number sparse)
 409                  (caadr gnus-tree-brackets))
 410                 (dummy (caaddr gnus-tree-brackets))
 411                 (adopted (car (nth 3 gnus-tree-brackets)))
 412                 (t (caar gnus-tree-brackets))))
 413          (gnus-tmp-close-bracket
 414           (cond ((memq gnus-tmp-number sparse)
 415                  (cdadr gnus-tree-brackets))
 416                 (adopted (cdr (nth 3 gnus-tree-brackets)))
 417                 (dummy
 418                  (cdaddr gnus-tree-brackets))
 419                 (t (cdar gnus-tree-brackets))))
 420          (buffer-read-only nil)
 421          beg end)
 422     (add-text-properties
 423      (setq beg (point))
 424      (setq end (progn (eval gnus-tree-line-format-spec) (point)))
 425      (list 'gnus-number gnus-tmp-number))
 426     (when (or t (gnus-visual-p 'tree-highlight 'highlight))
 427       (gnus-tree-highlight-node gnus-tmp-number beg end))))
 428
 429 (defun gnus-tree-highlight-node (article beg end)
 430   "Highlight current line according to `gnus-summary-highlight'."
 431   (let ((list gnus-summary-highlight)
 432         face)
 433     (save-excursion
 434       (set-buffer gnus-summary-buffer)
 435       (let* ((score (or (cdr (assq article gnus-newsgroup-scored))
 436                         gnus-summary-default-score 0))
 437              (default gnus-summary-default-score)
 438              (mark (or (gnus-summary-article-mark article) gnus-unread-mark)))
 439         ;; Eval the cars of the lists until we find a match.
 440         (while (and list
 441                     (not (eval (caar list))))
 442           (setq list (cdr list)))))
 443     (unless (eq (setq face (cdar list)) (get-text-property beg 'face))
 444       (put-text-property
 445        beg end 'face
 446        (if (boundp face) (symbol-value face) face)))))
 447
 448 (defun gnus-tree-indent (level)
 449   (insert (make-string (1- (* (1+ gnus-tree-node-length) level)) ? )))
 450
 451 (defvar gnus-tmp-limit)
 452 (defvar gnus-tmp-sparse)
 453 (defvar gnus-tmp-indent)
 454
 455 (defun gnus-generate-tree (thread)
 456   "Generate a thread tree for THREAD."
 457   (save-excursion
 458     (set-buffer (gnus-get-tree-buffer))
 459     (let ((buffer-read-only nil)
 460           (gnus-tmp-indent 0))
 461       (erase-buffer)
 462       (funcall gnus-generate-tree-function thread 0)
 463       (gnus-set-mode-line 'tree)
 464       (goto-char (point-min))
 465       (gnus-tree-minimize)
 466       (gnus-tree-recenter)
 467       (let ((selected (selected-window)))
 468         (when (get-buffer-window (set-buffer gnus-tree-buffer) t)
 469           (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 470           (gnus-horizontal-recenter)
 471           (select-window selected))))))
 472
 473 (defun gnus-generate-horizontal-tree (thread level &optional dummyp adopted)
 474   "Generate a horizontal tree."
 475   (let* ((dummy (stringp (car thread)))
 476          (do (or dummy
 477                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 478          col beg)
 479     (if (not do)
 480         ;; We don't want this article.
 481         (setq thread (cdr thread))
 482       (if (not (bolp))
 483           ;; Not the first article on the line, so we insert a "-".
 484           (insert (car gnus-tree-parent-child-edges))
 485         ;; If the level isn't zero, then we insert some indentation.
 486         (unless (zerop level)
 487           (gnus-tree-indent level)
 488           (insert (cadr gnus-tree-parent-child-edges))
 489           (setq col (- (setq beg (point)) (gnus-point-at-bol) 1))
 490           ;; Draw "|" lines upwards.
 491           (while (progn
 492                    (forward-line -1)
 493                    (forward-char col)
 494                    (= (following-char) ? ))
 495             (delete-char 1)
 496             (insert (caddr gnus-tree-parent-child-edges)))
 497           (goto-char beg)))
 498       (setq dummyp nil)
 499       ;; Insert the article node.
 500       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse adopted))
 501     (if (null thread)
 502         ;; End of the thread, so we go to the next line.
 503         (unless (bolp)
 504           (insert "\n"))
 505       ;; Recurse downwards in all children of this article.
 506       (while thread
 507         (gnus-generate-horizontal-tree
 508          (pop thread) (if do (1+ level) level)
 509          (or dummyp dummy) dummy)))))
 510
 511 (defsubst gnus-tree-indent-vertical ()
 512   (let ((len (- (* (1+ gnus-tree-node-length) gnus-tmp-indent)
 513                 (- (point) (gnus-point-at-bol)))))
 514     (when (> len 0)
 515       (insert (make-string len ? )))))
 516
 517 (defsubst gnus-tree-forward-line (n)
 518   (while (>= (decf n) 0)
 519     (unless (zerop (forward-line 1))
 520       (end-of-line)
 521       (insert "\n")))
 522   (end-of-line))
 523
 524 (defun gnus-generate-vertical-tree (thread level &optional dummyp adopted)
 525   "Generate a vertical tree."
 526   (let* ((dummy (stringp (car thread)))
 527          (do (or dummy
 528                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 529          col beg)
 530     (if (not do)
 531         ;; We don't want this article.
 532         (setq thread (cdr thread))
 533       (if (not (save-excursion (beginning-of-line) (bobp)))
 534           ;; Not the first article on the line, so we insert a "-".
 535           (progn
 536             (gnus-tree-indent-vertical)
 537             (insert (make-string (/ gnus-tree-node-length 2) ? ))
 538             (insert (caddr gnus-tree-parent-child-edges))
 539             (gnus-tree-forward-line 1))
 540         ;; If the level isn't zero, then we insert some indentation.
 541         (unless (zerop gnus-tmp-indent)
 542           (gnus-tree-forward-line (1- (* 2 level)))
 543           (gnus-tree-indent-vertical)
 544           (delete-char -1)
 545           (insert (cadr gnus-tree-parent-child-edges))
 546           (setq beg (point))
 547           ;; Draw "-" lines leftwards.
 548           (while (progn
 549                    (forward-char -2)
 550                    (= (following-char) ? ))
 551             (delete-char 1)
 552             (insert (car gnus-tree-parent-child-edges)))
 553           (goto-char beg)
 554           (gnus-tree-forward-line 1)))
 555       (setq dummyp nil)
 556       ;; Insert the article node.
 557       (gnus-tree-indent-vertical)
 558       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse adopted)
 559       (gnus-tree-forward-line 1))
 560     (if (null thread)
 561         ;; End of the thread, so we go to the next line.
 562         (progn
 563           (goto-char (point-min))
 564           (end-of-line)
 565           (incf gnus-tmp-indent))
 566       ;; Recurse downwards in all children of this article.
 567       (while thread
 568         (gnus-generate-vertical-tree
 569          (pop thread) (if do (1+ level) level)
 570          (or dummyp dummy) dummy)))))
 571
 572 ;;; Interface functions.
 573
 574 (defun gnus-possibly-generate-tree (article &optional force)
 575   "Generate the thread tree for ARTICLE if it isn't displayed already."
 576   (when (save-excursion
 577           (set-buffer gnus-summary-buffer)
 578           (and gnus-use-trees
 579                (vectorp (gnus-summary-article-header article))))
 580     (save-excursion
 581       (let ((top (save-excursion
 582                    (set-buffer gnus-summary-buffer)
 583                    (gnus-cut-thread
 584                     (gnus-remove-thread
 585                      (mail-header-id
 586                       (gnus-summary-article-header article)) t))))
 587             (gnus-tmp-limit gnus-newsgroup-limit)
 588             (gnus-tmp-sparse gnus-newsgroup-sparse))
 589         (when (or force
 590                   (not (eq top gnus-tree-displayed-thread)))
 591           (gnus-generate-tree top)
 592           (setq gnus-tree-displayed-thread top))))))
 593
 594 (defun gnus-tree-open (group)
 595   (gnus-get-tree-buffer))
 596
 597 (defun gnus-tree-close (group)
 598   ;(gnus-kill-buffer gnus-tree-buffer)
 599   )
 600
 601 (defun gnus-highlight-selected-tree (article)
 602   "Highlight the selected article in the tree."
 603   (let ((buf (current-buffer))
 604         region)
 605     (set-buffer gnus-tree-buffer)
 606     (when (setq region (gnus-tree-article-region article))
 607       (when (or (not gnus-selected-tree-overlay)
 608                 (gnus-extent-detached-p gnus-selected-tree-overlay))
 609         ;; Create a new overlay.
 610         (gnus-overlay-put
 611          (setq gnus-selected-tree-overlay (gnus-make-overlay 1 2))
 612          'face gnus-selected-tree-face))
 613       ;; Move the overlay to the article.
 614       (gnus-move-overlay
 615        gnus-selected-tree-overlay (goto-char (car region)) (cdr region))
 616       (gnus-tree-minimize)
 617       (gnus-tree-recenter)
 618       (let ((selected (selected-window)))
 619         (when (get-buffer-window (set-buffer gnus-tree-buffer) t)
 620           (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 621           (gnus-horizontal-recenter)
 622           (select-window selected))))
 623     ;; If we remove this save-excursion, it updates the wrong mode lines?!?
 624     (save-excursion
 625       (set-buffer gnus-tree-buffer)
 626       (gnus-set-mode-line 'tree))
 627     (set-buffer buf)))
 628
 629 (defun gnus-tree-highlight-article (article face)
 630   (save-excursion
 631     (set-buffer (gnus-get-tree-buffer))
 632     (let (region)
 633       (when (setq region (gnus-tree-article-region article))
 634         (put-text-property (car region) (cdr region) 'face face)
 635         (set-window-point
 636          (get-buffer-window (current-buffer) t) (cdr region))))))
 637
 638 ;;; Allow redefinition of functions.
 639 (gnus-ems-redefine)
 640
 641 (provide 'gnus-salt)
 642
 643 ;;; gnus-salt.el ends here