cgit.sxemacs.org Git - gnus/blob - lisp/gnus-nocem.el

   1 ;;; gnus-nocem.el --- NoCeM pseudo-cancellation treatment
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'nnmail)
  32 (require 'gnus-art)
  33 (require 'gnus-sum)
  34 (require 'gnus-range)
  35
  36 (defgroup gnus-nocem nil
  37   "NoCeM pseudo-cancellation treatment"
  38   :group 'gnus-score)
  39
  40 (defcustom gnus-nocem-groups
  41   '("news.lists.filters" "news.admin.net-abuse.bulletins"
  42     "alt.nocem.misc" "news.admin.net-abuse.announce")
  43   "List of groups that will be searched for NoCeM messages."
  44   :group 'gnus-nocem
  45   :type '(repeat (string :tag "Group")))
  46
  47 (defcustom gnus-nocem-issuers
  48   '("AutoMoose-1" "Automoose-1"         ; CancelMoose[tm]
  49     "rbraver@ohww.norman.ok.us"         ; Robert Braver
  50     "clewis@ferret.ocunix.on.ca"        ; Chris Lewis
  51     "jem@xpat.com"                      ; Despammer from Korea
  52     "snowhare@xmission.com"             ; Benjamin "Snowhare" Franz
  53     "red@redpoll.mrfs.oh.us (Richard E. Depew)" ; ARMM! ARMM!
  54     )
  55   "List of NoCeM issuers to pay attention to."
  56   :group 'gnus-nocem
  57   :type '(repeat string))
  58
  59 (defcustom gnus-nocem-directory
  60   (nnheader-concat gnus-article-save-directory "NoCeM/")
  61   "*Directory where NoCeM files will be stored."
  62   :group 'gnus-nocem
  63   :type 'directory)
  64
  65 (defcustom gnus-nocem-expiry-wait 15
  66   "*Number of days to keep NoCeM headers in the cache."
  67   :group 'gnus-nocem
  68   :type 'integer)
  69
  70 (defcustom gnus-nocem-verifyer 'mc-verify
  71   "*Function called to verify that the NoCeM message is valid.
  72 One likely value is `mc-verify'.  If the function in this variable
  73 isn't bound, the message will be used unconditionally."
  74   :group 'gnus-nocem
  75   :type '(radio (function-item mc-verify)
  76                 (function :tag "other")))
  77
  78 (defcustom gnus-nocem-liberal-fetch nil
  79   "*If t try to fetch all messages which have @@NCM in the subject.
  80 Otherwise don't fetch messages which have references or whose message-id
  81 matches an previously scanned and verified nocem message."
  82   :group 'gnus-nocem
  83   :type 'boolean)
  84
  85 ;;; Internal variables
  86
  87 (defvar gnus-nocem-active nil)
  88 (defvar gnus-nocem-alist nil)
  89 (defvar gnus-nocem-touched-alist nil)
  90 (defvar gnus-nocem-hashtb nil)
  91 (defvar gnus-nocem-seen-message-ids nil)
  92
  93 ;;; Functions
  94
  95 (defun gnus-nocem-active-file ()
  96   (concat (file-name-as-directory gnus-nocem-directory) "active"))
  97
  98 (defun gnus-nocem-cache-file ()
  99   (concat (file-name-as-directory gnus-nocem-directory) "cache"))
 100
 101 ;;
 102 ;; faster lookups for group names:
 103 ;;
 104
 105 (defvar gnus-nocem-real-group-hashtb nil
 106   "Real-name mappings of subscribed groups.")
 107
 108 (defun gnus-fill-real-hashtb ()
 109   "Fill up a hash table with the real-name mappings from the user's
 110 active file."
 111   (setq gnus-nocem-real-group-hashtb (gnus-make-hashtable
 112                                       (length gnus-newsrc-alist)))
 113   (mapcar (lambda (group)
 114             (setq group (gnus-group-real-name (car group)))
 115             (gnus-sethash group t gnus-nocem-real-group-hashtb))
 116           gnus-newsrc-alist))
 117
 118 (defun gnus-nocem-scan-groups ()
 119   "Scan all NoCeM groups for new NoCeM messages."
 120   (interactive)
 121   (let ((groups gnus-nocem-groups)
 122         (gnus-inhibit-demon t)
 123         group active gactive articles)
 124     (gnus-make-directory gnus-nocem-directory)
 125     ;; Load any previous NoCeM headers.
 126     (gnus-nocem-load-cache)
 127     ;; Get the group name mappings:
 128     (gnus-fill-real-hashtb)
 129     ;; Read the active file if it hasn't been read yet.
 130     (and (file-exists-p (gnus-nocem-active-file))
 131          (not gnus-nocem-active)
 132          (ignore-errors
 133            (load (gnus-nocem-active-file) t t t)))
 134     ;; Go through all groups and see whether new articles have
 135     ;; arrived.
 136     (while (setq group (pop groups))
 137       (if (not (setq gactive (gnus-activate-group group)))
 138           ()                            ; This group doesn't exist.
 139         (setq active (nth 1 (assoc group gnus-nocem-active)))
 140         (when (and (not (< (cdr gactive) (car gactive))) ; Empty group.
 141                    (or (not active)
 142                        (< (cdr active) (cdr gactive))))
 143           ;; Ok, there are new articles in this group, se we fetch the
 144           ;; headers.
 145           (save-excursion
 146             (let ((dependencies (make-vector 10 nil))
 147                   headers header)
 148               (nnheader-temp-write nil
 149                 (setq headers
 150                       (if (eq 'nov
 151                               (gnus-retrieve-headers
 152                                (setq articles
 153                                      (gnus-uncompress-range
 154                                       (cons
 155                                        (if active (1+ (cdr active))
 156                                          (car gactive))
 157                                        (cdr gactive))))
 158                                group))
 159                           (gnus-get-newsgroup-headers-xover
 160                            articles nil dependencies)
 161                         (gnus-get-newsgroup-headers dependencies)))
 162                 (while (setq header (pop headers))
 163                   ;; We take a closer look on all articles that have
 164                   ;; "@@NCM" in the subject.  Unless we already read
 165                   ;; this cross posted message.  Nocem messages
 166                   ;; are not allowed to have references, so we can
 167                   ;; ignore scanning followups.
 168                   (and (string-match "@@NCM" (mail-header-subject header))
 169                        (or gnus-nocem-liberal-fetch
 170                            (and (or (string= "" (mail-header-references
 171                                                  header))
 172                                     (null (mail-header-references header)))
 173                                 (not (member (mail-header-message-id header)
 174                                              gnus-nocem-seen-message-ids))))
 175                        (gnus-nocem-check-article group header)))))))
 176         (setq gnus-nocem-active
 177               (cons (list group gactive)
 178                     (delq (assoc group gnus-nocem-active)
 179                           gnus-nocem-active)))))
 180     ;; Save the results, if any.
 181     (gnus-nocem-save-cache)
 182     (gnus-nocem-save-active)))
 183
 184 (defun gnus-nocem-check-article (group header)
 185   "Check whether the current article is an NCM article and that we want it."
 186   ;; Get the article.
 187   (gnus-message 7 "Checking article %d in %s for NoCeM..."
 188                 (mail-header-number header) group)
 189   (let ((date (mail-header-date header))
 190         issuer b e)
 191     (when (or (not date)
 192               (nnmail-time-less
 193                (nnmail-time-since (nnmail-date-to-time date))
 194                (nnmail-days-to-time gnus-nocem-expiry-wait)))
 195       (gnus-request-article-this-buffer (mail-header-number header) group)
 196       (goto-char (point-min))
 197       (when (re-search-forward "-----BEGIN PGP MESSAGE-----" nil t)
 198         (delete-region (point-min) (match-beginning 0)))
 199       (when (re-search-forward "-----END PGP MESSAGE-----\n?" nil t)
 200         (delete-region (match-end 0) (point-max)))
 201       (goto-char (point-min))
 202       ;; The article has to have proper NoCeM headers.
 203       (when (and (setq b (search-forward "\n@@BEGIN NCM HEADERS\n" nil t))
 204                  (setq e (search-forward "\n@@BEGIN NCM BODY\n" nil t)))
 205         ;; We get the name of the issuer.
 206         (narrow-to-region b e)
 207         (setq issuer (mail-fetch-field "issuer"))
 208         (widen)
 209         (or (member issuer gnus-nocem-issuers)
 210             (message "invalid NoCeM issuer: %s" issuer))
 211         (and (member issuer gnus-nocem-issuers) ; We like her....
 212              (gnus-nocem-verify-issuer issuer) ; She is who she says she is...
 213              (gnus-nocem-enter-article) ; We gobble the message..
 214              (push (mail-header-message-id header) ; But don't come back for
 215                    gnus-nocem-seen-message-ids)))))) ; second helpings.
 216
 217 (defun gnus-nocem-verify-issuer (person)
 218   "Verify using PGP that the canceler is who she says she is."
 219   (if (fboundp gnus-nocem-verifyer)
 220       (ignore-errors
 221         (funcall gnus-nocem-verifyer))
 222     ;; If we don't have Mailcrypt, then we use the message anyway.
 223     t))
 224
 225 (defun gnus-nocem-enter-article ()
 226   "Enter the current article into the NoCeM cache."
 227   (goto-char (point-min))
 228   (let ((b (search-forward "\n@@BEGIN NCM BODY\n" nil t))
 229         (e (search-forward "\n@@END NCM BODY\n" nil t))
 230         (buf (current-buffer))
 231         ncm id group)
 232     (when (and b e)
 233       (narrow-to-region b (1+ (match-beginning 0)))
 234       (goto-char (point-min))
 235       (while (search-forward "\t" nil t)
 236         (cond
 237          ((not (ignore-errors
 238                  (setq group (let ((obarray gnus-active-hashtb)) (read buf)))))
 239           ;; An error.
 240           )
 241          ((not (symbolp group))
 242           ;; Ignore invalid entries.
 243           )
 244          ((not (boundp group))
 245           ;; Make sure all entries in the hashtb are bound.
 246           (set group nil))
 247          (t
 248           (when (gnus-gethash (gnus-group-real-name (symbol-name group))
 249                               gnus-nocem-real-group-hashtb)
 250             ;; Valid group.
 251             (beginning-of-line)
 252             (while (= (following-char) ?\t)
 253               (forward-line -1))
 254             (setq id (buffer-substring (point) (1- (search-forward "\t"))))
 255             (unless (gnus-gethash id gnus-nocem-hashtb)
 256               ;; only store if not already present
 257               (gnus-sethash id t gnus-nocem-hashtb)
 258               (push id ncm))
 259             (forward-line 1)
 260             (while (= (following-char) ?\t)
 261               (forward-line 1))))))
 262       (when ncm
 263         (setq gnus-nocem-touched-alist t)
 264         (push (cons (let ((time (current-time))) (setcdr (cdr time) nil) time)
 265                     ncm)
 266               gnus-nocem-alist))
 267       t)))
 268
 269 (defun gnus-nocem-load-cache ()
 270   "Load the NoCeM cache."
 271   (interactive)
 272   (unless gnus-nocem-alist
 273     ;; The buffer doesn't exist, so we create it and load the NoCeM
 274     ;; cache.
 275     (when (file-exists-p (gnus-nocem-cache-file))
 276       (load (gnus-nocem-cache-file) t t t)
 277       (gnus-nocem-alist-to-hashtb))))
 278
 279 (defun gnus-nocem-save-cache ()
 280   "Save the NoCeM cache."
 281   (when (and gnus-nocem-alist
 282              gnus-nocem-touched-alist)
 283     (nnheader-temp-write (gnus-nocem-cache-file)
 284       (gnus-prin1 `(setq gnus-nocem-alist ',gnus-nocem-alist)))
 285     (setq gnus-nocem-touched-alist nil)))
 286
 287 (defun gnus-nocem-save-active ()
 288   "Save the NoCeM active file."
 289   (nnheader-temp-write (gnus-nocem-active-file)
 290     (gnus-prin1 `(setq gnus-nocem-active ',gnus-nocem-active))))
 291
 292 (defun gnus-nocem-alist-to-hashtb ()
 293   "Create a hashtable from the Message-IDs we have."
 294   (let* ((alist gnus-nocem-alist)
 295          (pprev (cons nil alist))
 296          (prev pprev)
 297          (expiry (nnmail-days-to-time gnus-nocem-expiry-wait))
 298          entry)
 299     (setq gnus-nocem-hashtb (gnus-make-hashtable (* (length alist) 51)))
 300     (while (setq entry (car alist))
 301       (if (not (nnmail-time-less (nnmail-time-since (car entry)) expiry))
 302           ;; This entry has expired, so we remove it.
 303           (setcdr prev (cdr alist))
 304         (setq prev alist)
 305         ;; This is ok, so we enter it into the hashtable.
 306         (setq entry (cdr entry))
 307         (while entry
 308           (gnus-sethash (car entry) t gnus-nocem-hashtb)
 309           (setq entry (cdr entry))))
 310       (setq alist (cdr alist)))))
 311
 312 (gnus-add-shutdown 'gnus-nocem-close 'gnus)
 313
 314 (defun gnus-nocem-close ()
 315   "Clear internal NoCeM variables."
 316   (setq gnus-nocem-alist nil
 317         gnus-nocem-hashtb nil
 318         gnus-nocem-active nil
 319         gnus-nocem-touched-alist nil
 320         gnus-nocem-seen-message-ids nil
 321         gnus-nocem-real-group-hashtb nil))
 322
 323 (defun gnus-nocem-unwanted-article-p (id)
 324   "Say whether article ID in the current group is wanted."
 325   (gnus-gethash id gnus-nocem-hashtb))
 326
 327 (provide 'gnus-nocem)
 328
 329 ;;; gnus-nocem.el ends here