cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-ems)
  34 (require 'message)
  35 (require 'gnus-art)
  36
  37 (defcustom gnus-post-method 'current
  38   "*Preferred method for posting USENET news.
  39
  40 If this variable is `current', Gnus will use the \"current\" select
  41 method when posting.  If it is nil (which is the default), Gnus will
  42 use the native select method when posting.
  43
  44 This method will not be used in mail groups and the like, only in
  45 \"real\" newsgroups.
  46
  47 If not nil nor `native', the value must be a valid method as discussed
  48 in the documentation of `gnus-select-method'.  It can also be a list of
  49 methods.  If that is the case, the user will be queried for what select
  50 method to use when posting."
  51   :group 'gnus-group-foreign
  52   :type `(choice (const nil)
  53                  (const current)
  54                  (const native)
  55                  (sexp :tag "Methods" ,gnus-select-method)))
  56
  57 (defvar gnus-outgoing-message-group nil
  58   "*All outgoing messages will be put in this group.
  59 If you want to store all your outgoing mail and articles in the group
  60 \"nnml:archive\", you set this variable to that value.  This variable
  61 can also be a list of group names.
  62
  63 If you want to have greater control over what group to put each
  64 message in, you can set this variable to a function that checks the
  65 current newsgroup name and then returns a suitable group name (or list
  66 of names).")
  67
  68 (defvar gnus-mailing-list-groups nil
  69   "*Regexp matching groups that are really mailing lists.
  70 This is useful when you're reading a mailing list that has been
  71 gatewayed to a newsgroup, and you want to followup to an article in
  72 the group.")
  73
  74 (defvar gnus-add-to-list nil
  75   "*If non-nil, add a `to-list' parameter automatically.")
  76
  77 (defvar gnus-crosspost-complaint
  78   "Hi,
  79
  80 You posted the article below with the following Newsgroups header:
  81
  82 Newsgroups: %s
  83
  84 The %s group, at least, was an inappropriate recipient
  85 of this message.  Please trim your Newsgroups header to exclude this
  86 group before posting in the future.
  87
  88 Thank you.
  89
  90 "
  91   "Format string to be inserted when complaining about crossposts.
  92 The first %s will be replaced by the Newsgroups header;
  93 the second with the current group name.")
  94
  95 (defvar gnus-message-setup-hook nil
  96   "Hook run after setting up a message buffer.")
  97
  98 (defvar gnus-bug-create-help-buffer t
  99   "*Should we create the *Gnus Help Bug* buffer?")
 100
 101 (defvar gnus-posting-styles nil
 102   "*Alist of styles to use when posting.")
 103
 104 (defcustom gnus-group-posting-charset-alist
 105   '(("^\\(no\\|fr\\|dk\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\|dk\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 106     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 107     (message-this-is-mail nil nil)
 108     (message-this-is-news nil t))
 109   "Alist of regexps and permitted unencoded charsets for posting.
 110 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 111 TEST is either a regular expression matching the newsgroup header or a
 112 variable to query,
 113 HEADER is the charset which may be left unencoded in the header (nil
 114 means encode all charsets),
 115 BODY-LIST is a list of charsets which may be encoded using 8bit
 116 content-transfer encoding in the body, or one of the special values
 117 nil (always encode using quoted-printable) or t (always use 8bit).
 118
 119 Note that any value other than nil for HEADER infringes some RFCs, so
 120 use this option with care."
 121   :type '(repeat (list :tag "Permitted unencoded charsets"
 122                   (choice :tag "Where"
 123                    (regexp :tag "Group")
 124                    (const :tag "Mail message" :value message-this-is-mail)
 125                    (const :tag "News article" :value message-this-is-news))
 126                   (choice :tag "Header"
 127                    (const :tag "None" nil)
 128                    (symbol :tag "Charset"))
 129                   (choice :tag "Body"
 130                           (const :tag "Any" :value t)
 131                           (const :tag "None" :value nil)
 132                           (repeat :tag "Charsets"
 133                                   (symbol :tag "Charset")))))
 134   :group 'gnus-charset)
 135
 136 ;;; Internal variables.
 137
 138 (defvar gnus-inhibit-posting-styles nil
 139   "Inhibit the use of posting styles.")
 140
 141 (defvar gnus-message-buffer "*Mail Gnus*")
 142 (defvar gnus-article-copy nil)
 143 (defvar gnus-last-posting-server nil)
 144 (defvar gnus-message-group-art nil)
 145
 146 (defconst gnus-bug-message
 147   "Sending a bug report to the Gnus Towers.
 148 ========================================
 149
 150 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 151 be sent to the Gnus Bug Exterminators.
 152
 153 The thing near the bottom of the buffer is how the environment
 154 settings will be included in the mail.  Please do not delete that.
 155 They will tell the Bug People what your environment is, so that it
 156 will be easier to locate the bugs.
 157
 158 If you have found a bug that makes Emacs go \"beep\", set
 159 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 160 and include the backtrace in your bug report.
 161
 162 Please describe the bug in annoying, painstaking detail.
 163
 164 Thank you for your help in stamping out bugs.
 165 ")
 166
 167 (eval-and-compile
 168   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 169   (autoload 'news-setup "rnewspost")
 170   (autoload 'news-reply-mode "rnewspost")
 171   (autoload 'rmail-dont-reply-to "mail-utils")
 172   (autoload 'rmail-output "rmailout"))
 173
 174 \f
 175 ;;;
 176 ;;; Gnus Posting Functions
 177 ;;;
 178
 179 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 180   "p" gnus-summary-post-news
 181   "f" gnus-summary-followup
 182   "F" gnus-summary-followup-with-original
 183   "c" gnus-summary-cancel-article
 184   "s" gnus-summary-supersede-article
 185   "r" gnus-summary-reply
 186   "y" gnus-summary-yank-message
 187   "R" gnus-summary-reply-with-original
 188   "w" gnus-summary-wide-reply
 189   "W" gnus-summary-wide-reply-with-original
 190   "n" gnus-summary-followup-to-mail
 191   "N" gnus-summary-followup-to-mail-with-original
 192   "m" gnus-summary-mail-other-window
 193   "u" gnus-uu-post-news
 194   "\M-c" gnus-summary-mail-crosspost-complaint
 195   "om" gnus-summary-mail-forward
 196   "op" gnus-summary-post-forward
 197   "Om" gnus-uu-digest-mail-forward
 198   "Op" gnus-uu-digest-post-forward)
 199
 200 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 201   "b" gnus-summary-resend-bounced-mail
 202   ;; "c" gnus-summary-send-draft
 203   "r" gnus-summary-resend-message)
 204
 205 ;;; Internal functions.
 206
 207 (defvar gnus-article-reply nil)
 208 (defmacro gnus-setup-message (config &rest forms)
 209   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 210         (buffer (make-symbol "gnus-setup-message-buffer"))
 211         (article (make-symbol "gnus-setup-message-article"))
 212         (group (make-symbol "gnus-setup-message-group")))
 213     `(let ((,winconf (current-window-configuration))
 214            (,buffer (buffer-name (current-buffer)))
 215            (,article (and gnus-article-reply (gnus-summary-article-number)))
 216            (,group gnus-newsgroup-name)
 217            (message-header-setup-hook
 218             (copy-sequence message-header-setup-hook))
 219            (mbl mml-buffer-list)
 220            (message-mode-hook (copy-sequence message-mode-hook)))
 221        (setq mml-buffer-list nil)
 222        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 223        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 224        (add-hook 'message-mode-hook 'gnus-configure-posting-styles)
 225        (unwind-protect
 226            (progn
 227              ,@forms)
 228          (gnus-inews-add-send-actions ,winconf ,buffer ,article)
 229          (setq gnus-message-buffer (current-buffer))
 230          (set (make-local-variable 'gnus-message-group-art)
 231               (cons ,group ,article))
 232          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 233          (gnus-run-hooks 'gnus-message-setup-hook)
 234          (if (eq major-mode 'message-mode)
 235              ;; Make mml-buffer-list local.
 236              ;; Restore global mml-buffer-list value as mbl.
 237              ;; What a hack! -- Shenghuo
 238              (let ((mml-buffer-list mml-buffer-list))
 239                (setq mml-buffer-list mbl)
 240                (make-local-variable 'mml-buffer-list)
 241                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 242            (mml-destroy-buffers)
 243            (setq mml-buffer-list mbl)))
 244        (gnus-add-buffer)
 245        (gnus-configure-windows ,config t)
 246        (set-buffer-modified-p nil))))
 247
 248 (defun gnus-setup-posting-charset (group)
 249   (let ((alist gnus-group-posting-charset-alist)
 250         (group (or group ""))
 251         elem)
 252     (when group
 253       (catch 'found
 254         (while (setq elem (pop alist))
 255           (when (or (and (stringp (car elem))
 256                          (string-match (car elem) group))
 257                     (and (gnus-functionp (car elem))
 258                          (funcall (car elem) group))
 259                     (and (symbolp (car elem))
 260                          (symbol-value (car elem))))
 261             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 262
 263 (defun gnus-inews-add-send-actions (winconf buffer article)
 264   (make-local-hook 'message-sent-hook)
 265   (add-hook 'message-sent-hook 'gnus-inews-do-gcc nil t)
 266   (setq message-post-method
 267         `(lambda (arg)
 268            (gnus-post-method arg ,gnus-newsgroup-name)))
 269   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 270   (message-add-action
 271    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 272   (message-add-action
 273    `(when (gnus-buffer-exists-p ,buffer)
 274       (save-excursion
 275         (set-buffer ,buffer)
 276         ,(when article
 277            `(gnus-summary-mark-article-as-replied ,article))))
 278    'send))
 279
 280 (put 'gnus-setup-message 'lisp-indent-function 1)
 281 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 282
 283 ;;; Post news commands of Gnus group mode and summary mode
 284
 285 (defun gnus-group-mail (&optional arg)
 286   "Start composing a mail.
 287 If ARG, use the group under the point to find a posting style.
 288 If ARG is 1, prompt for a group name to find the posting style."
 289   (interactive "P")
 290   ;; We can't `let' gnus-newsgroup-name here, since that leads
 291   ;; to local variables leaking.
 292   (let ((group gnus-newsgroup-name)
 293         (buffer (current-buffer)))
 294     (unwind-protect
 295         (progn
 296           (setq gnus-newsgroup-name
 297                 (if arg
 298                     (if (= 1 (prefix-numeric-value arg))
 299                         (completing-read "Use posting style of group: "
 300                                          gnus-active-hashtb nil
 301                                          (gnus-read-active-file-p))
 302                       (gnus-group-group-name))
 303                   ""))
 304           (gnus-setup-message 'message (message-mail)))
 305       (save-excursion
 306         (set-buffer buffer)
 307         (setq gnus-newsgroup-name group)))))
 308
 309 (defun gnus-group-post-news (&optional arg)
 310   "Start composing a news message.
 311 If ARG, post to the group under point.
 312 If ARG is 1, prompt for a group name."
 313   (interactive "P")
 314   ;; Bind this variable here to make message mode hooks work ok.
 315   (let ((gnus-newsgroup-name
 316          (if arg
 317              (if (= 1 (prefix-numeric-value arg))
 318                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 319                                   (gnus-read-active-file-p))
 320                (gnus-group-group-name))
 321            "")))
 322     (gnus-post-news 'post gnus-newsgroup-name)))
 323
 324 (defun gnus-summary-post-news ()
 325   "Start composing a news message."
 326   (interactive)
 327   (gnus-post-news 'post gnus-newsgroup-name))
 328
 329 (defun gnus-summary-followup (yank &optional force-news)
 330   "Compose a followup to an article.
 331 If prefix argument YANK is non-nil, original article is yanked automatically."
 332   (interactive
 333    (list (and current-prefix-arg
 334               (gnus-summary-work-articles 1))))
 335   (when yank
 336     (gnus-summary-goto-subject (car yank)))
 337   (save-window-excursion
 338     (gnus-summary-select-article))
 339   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 340         (gnus-newsgroup-name gnus-newsgroup-name))
 341     ;; Send a followup.
 342     (gnus-post-news nil gnus-newsgroup-name
 343                     headers gnus-article-buffer
 344                     yank nil force-news)))
 345
 346 (defun gnus-summary-followup-with-original (n &optional force-news)
 347   "Compose a followup to an article and include the original article."
 348   (interactive "P")
 349   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 350
 351 (defun gnus-summary-followup-to-mail (&optional arg)
 352   "Followup to the current mail message via news."
 353   (interactive
 354    (list (and current-prefix-arg
 355               (gnus-summary-work-articles 1))))
 356   (gnus-summary-followup arg t))
 357
 358 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 359   "Followup to the current mail message via news."
 360   (interactive "P")
 361   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 362
 363 (defun gnus-inews-yank-articles (articles)
 364   (let (beg article)
 365     (message-goto-body)
 366     (while (setq article (pop articles))
 367       (save-window-excursion
 368         (set-buffer gnus-summary-buffer)
 369         (gnus-summary-select-article nil nil nil article)
 370         (gnus-summary-remove-process-mark article))
 371       (gnus-copy-article-buffer)
 372       (let ((message-reply-buffer gnus-article-copy)
 373             (message-reply-headers gnus-current-headers))
 374         (message-yank-original)
 375         (setq beg (or beg (mark t))))
 376       (when articles
 377         (insert "\n")))
 378     (push-mark)
 379     (goto-char beg)))
 380
 381 (defun gnus-summary-cancel-article (&optional n symp)
 382   "Cancel an article you posted.
 383 Uses the process-prefix convention.  If given the symbolic
 384 prefix `a', cancel using the standard posting method; if not
 385 post using the current select method."
 386   (interactive (gnus-interactive "P\ny"))
 387   (let ((articles (gnus-summary-work-articles n))
 388         (message-post-method
 389          `(lambda (arg)
 390             (gnus-post-method (not (eq symp 'a)) ,gnus-newsgroup-name)))
 391         article)
 392     (while (setq article (pop articles))
 393       (when (gnus-summary-select-article t nil nil article)
 394         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 395                 (message-cancel-news))
 396           (gnus-summary-mark-as-read article gnus-canceled-mark)
 397           (gnus-cache-remove-article 1))
 398         (gnus-article-hide-headers-if-wanted))
 399       (gnus-summary-remove-process-mark article))))
 400
 401 (defun gnus-summary-supersede-article ()
 402   "Compose an article that will supersede a previous article.
 403 This is done simply by taking the old article and adding a Supersedes
 404 header line with the old Message-ID."
 405   (interactive)
 406   (let ((article (gnus-summary-article-number)))
 407     (gnus-setup-message 'reply-yank
 408       (gnus-summary-select-article t)
 409       (set-buffer gnus-original-article-buffer)
 410       (message-supersede)
 411       (push
 412        `((lambda ()
 413            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 414              (save-excursion
 415                (set-buffer ,gnus-summary-buffer)
 416                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 417                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 418        message-send-actions))))
 419
 420 \f
 421
 422 (defun gnus-copy-article-buffer (&optional article-buffer)
 423   ;; make a copy of the article buffer with all text properties removed
 424   ;; this copy is in the buffer gnus-article-copy.
 425   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 426   ;; this buffer should be passed to all mail/news reply/post routines.
 427   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 428   (save-excursion
 429     (set-buffer gnus-article-copy)
 430     (mm-enable-multibyte))
 431   (let ((article-buffer (or article-buffer gnus-article-buffer))
 432         end beg)
 433     (if (not (and (get-buffer article-buffer)
 434                   (gnus-buffer-exists-p article-buffer)))
 435         (error "Can't find any article buffer")
 436       (save-excursion
 437         (set-buffer article-buffer)
 438         (save-restriction
 439           ;; Copy over the (displayed) article buffer, delete
 440           ;; hidden text and remove text properties.
 441           (widen)
 442           (copy-to-buffer gnus-article-copy (point-min) (point-max))
 443           (set-buffer gnus-article-copy)
 444           (gnus-article-delete-text-of-type 'annotation)
 445           (gnus-remove-text-with-property 'gnus-prev)
 446           (gnus-remove-text-with-property 'gnus-next)
 447           (insert
 448            (prog1
 449                (format "%s" (buffer-string))
 450              (erase-buffer)))
 451           ;; Find the original headers.
 452           (set-buffer gnus-original-article-buffer)
 453           (goto-char (point-min))
 454           (while (looking-at message-unix-mail-delimiter)
 455             (forward-line 1))
 456           (setq beg (point))
 457           (setq end (or (search-forward "\n\n" nil t) (point)))
 458           ;; Delete the headers from the displayed articles.
 459           (set-buffer gnus-article-copy)
 460           (delete-region (goto-char (point-min))
 461                          (or (search-forward "\n\n" nil t) (point-max)))
 462           ;; Insert the original article headers.
 463           (insert-buffer-substring gnus-original-article-buffer beg end)
 464           (article-decode-encoded-words)))
 465       gnus-article-copy)))
 466
 467 (defun gnus-post-news (post &optional group header article-buffer yank subject
 468                             force-news)
 469   (when article-buffer
 470     (gnus-copy-article-buffer))
 471   (let ((gnus-article-reply article-buffer)
 472         (add-to-list gnus-add-to-list))
 473     (gnus-setup-message (cond (yank 'reply-yank)
 474                               (article-buffer 'reply)
 475                               (t 'message))
 476       (let* ((group (or group gnus-newsgroup-name))
 477              (charset (gnus-group-name-charset nil group))
 478              (pgroup group)
 479              to-address to-group mailing-list to-list
 480              newsgroup-p)
 481         (when group
 482           (setq to-address (gnus-group-find-parameter group 'to-address)
 483                 to-group (gnus-group-find-parameter group 'to-group)
 484                 to-list (gnus-group-find-parameter group 'to-list)
 485                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 486                 mailing-list (when gnus-mailing-list-groups
 487                                (string-match gnus-mailing-list-groups group))
 488                 group (gnus-group-name-decode (gnus-group-real-name group)
 489                                               charset)))
 490         (if (or (and to-group
 491                      (gnus-news-group-p to-group))
 492                 newsgroup-p
 493                 force-news
 494                 (and (gnus-news-group-p
 495                       (or pgroup gnus-newsgroup-name)
 496                       (if header (mail-header-number header)
 497                         gnus-current-article))
 498                      (not mailing-list)
 499                      (not to-list)
 500                      (not to-address)))
 501             ;; This is news.
 502             (if post
 503                 (message-news (or to-group group))
 504               (set-buffer gnus-article-copy)
 505               (gnus-msg-treat-broken-reply-to)
 506               (message-followup (if (or newsgroup-p force-news) nil to-group)))
 507           ;; The is mail.
 508           (if post
 509               (progn
 510                 (message-mail (or to-address to-list))
 511                 ;; Arrange for mail groups that have no `to-address' to
 512                 ;; get that when the user sends off the mail.
 513                 (when (and (not to-list)
 514                            (not to-address)
 515                            add-to-list)
 516                   (push (list 'gnus-inews-add-to-address pgroup)
 517                         message-send-actions)))
 518             (set-buffer gnus-article-copy)
 519             (gnus-msg-treat-broken-reply-to)
 520             (message-wide-reply to-address)))
 521         (when yank
 522           (gnus-inews-yank-articles yank))))))
 523
 524 (defun gnus-msg-treat-broken-reply-to ()
 525   "Remove the Reply-to header iff broken-reply-to."
 526   (when (gnus-group-find-parameter
 527          gnus-newsgroup-name 'broken-reply-to)
 528     (save-restriction
 529       (message-narrow-to-head)
 530       (message-remove-header "reply-to"))))
 531
 532 (defun gnus-post-method (arg group &optional silent)
 533   "Return the posting method based on GROUP and ARG.
 534 If SILENT, don't prompt the user."
 535   (let ((group-method (gnus-find-method-for-group group)))
 536     (cond
 537      ;; If the group-method is nil (which shouldn't happen) we use
 538      ;; the default method.
 539      ((null group-method)
 540       (or (and (null (eq gnus-post-method 'active)) gnus-post-method)
 541           gnus-select-method message-post-method))
 542      ;; We want the inverse of the default
 543      ((and arg (not (eq arg 0)))
 544       (if (eq gnus-post-method 'active)
 545           gnus-select-method
 546         group-method))
 547      ;; We query the user for a post method.
 548      ((or arg
 549           (and gnus-post-method
 550                (not (eq gnus-post-method 'current))
 551                (listp (car gnus-post-method))))
 552       (let* ((methods
 553               ;; Collect all methods we know about.
 554               (append
 555                (when (and gnus-post-method
 556                           (not (eq gnus-post-method 'current)))
 557                  (if (listp (car gnus-post-method))
 558                      gnus-post-method
 559                    (list gnus-post-method)))
 560                gnus-secondary-select-methods
 561                (mapcar 'cdr gnus-server-alist)
 562                (mapcar 'car gnus-opened-servers)
 563                (list gnus-select-method)
 564                (list group-method)))
 565              method-alist post-methods method)
 566         ;; Weed out all mail methods.
 567         (while methods
 568           (setq method (gnus-server-get-method "" (pop methods)))
 569           (when (and (or (gnus-method-option-p method 'post)
 570                          (gnus-method-option-p method 'post-mail))
 571                      (not (member method post-methods)))
 572             (push method post-methods)))
 573         ;; Create a name-method alist.
 574         (setq method-alist
 575               (mapcar
 576                (lambda (m)
 577                  (list (concat (cadr m) " (" (symbol-name (car m)) ")") m))
 578                post-methods))
 579         ;; Query the user.
 580         (cadr
 581          (assoc
 582           (setq gnus-last-posting-server
 583                 (if (and silent
 584                          gnus-last-posting-server)
 585                     ;; Just use the last value.
 586                     gnus-last-posting-server
 587                   (completing-read
 588                    "Posting method: " method-alist nil t
 589                    (cons (or gnus-last-posting-server "") 0))))
 590           method-alist))))
 591      ;; Override normal method.
 592      ((and (eq gnus-post-method 'current)
 593            (not (eq (car group-method) 'nndraft))
 594            (gnus-get-function group-method 'request-post t)
 595            (not arg))
 596       group-method)
 597      ((and gnus-post-method
 598            (not (eq gnus-post-method 'current)))
 599       gnus-post-method)
 600      ;; Use the normal select method.
 601      (t gnus-select-method))))
 602
 603 \f
 604
 605 ;; Dummies to avoid byte-compile warning.
 606 (defvar nnspool-rejected-article-hook)
 607 (defvar xemacs-codename)
 608
 609 (defun gnus-extended-version ()
 610   "Stringified Gnus version and Emacs version."
 611   (interactive)
 612   (concat
 613    "Gnus/" (prin1-to-string (gnus-continuum-version gnus-version) t)
 614    " (" gnus-version ")"
 615    " "
 616    (cond
 617     ((string-match "^\\(\\([.0-9]+\\)*\\)\\.[0-9]+$" emacs-version)
 618      (concat "Emacs/" (match-string 1 emacs-version)))
 619     ((string-match "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)[^(]*\\(\\((beta.*)\\|'\\)\\)?"
 620                    emacs-version)
 621      (concat (match-string 1 emacs-version)
 622              (format "/%d.%d" emacs-major-version emacs-minor-version)
 623              (if (match-beginning 3)
 624                  (match-string 3 emacs-version)
 625                "")
 626              (if (boundp 'xemacs-codename)
 627                  (concat " (" xemacs-codename ")")
 628                "")))
 629     (t emacs-version))))
 630
 631 \f
 632 ;;;
 633 ;;; Gnus Mail Functions
 634 ;;;
 635
 636 ;;; Mail reply commands of Gnus summary mode
 637
 638 (defun gnus-summary-reply (&optional yank wide)
 639   "Start composing a reply mail to the current message.
 640 If prefix argument YANK is non-nil, the original article is yanked
 641 automatically."
 642   (interactive
 643    (list (and current-prefix-arg
 644               (gnus-summary-work-articles 1))))
 645   ;; Stripping headers should be specified with mail-yank-ignored-headers.
 646   (when yank
 647     (gnus-summary-goto-subject (car yank)))
 648   (let ((gnus-article-reply t))
 649     (gnus-setup-message (if yank 'reply-yank 'reply)
 650       (gnus-summary-select-article)
 651       (set-buffer (gnus-copy-article-buffer))
 652       (gnus-msg-treat-broken-reply-to)
 653       (message-reply nil wide)
 654       (when yank
 655         (gnus-inews-yank-articles yank)))))
 656
 657 (defun gnus-summary-reply-with-original (n &optional wide)
 658   "Start composing a reply mail to the current message.
 659 The original article will be yanked."
 660   (interactive "P")
 661   (gnus-summary-reply (gnus-summary-work-articles n) wide))
 662
 663 (defun gnus-summary-wide-reply (&optional yank)
 664   "Start composing a wide reply mail to the current message.
 665 If prefix argument YANK is non-nil, the original article is yanked
 666 automatically."
 667   (interactive
 668    (list (and current-prefix-arg
 669               (gnus-summary-work-articles 1))))
 670   (gnus-summary-reply yank t))
 671
 672 (defun gnus-summary-wide-reply-with-original (n)
 673   "Start composing a wide reply mail to the current message.
 674 The original article will be yanked."
 675   (interactive "P")
 676   (gnus-summary-reply-with-original n t))
 677
 678 (defun gnus-summary-mail-forward (&optional arg post)
 679   "Forward the current message to another user.
 680 If ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
 681 if ARG is 1, decode the message and forward directly inline;
 682 if ARG is 2, foward message as an rfc822 MIME section;
 683 if ARG is 3, decode message and forward as an rfc822 MIME section;
 684 if ARG is 4, foward message directly inline;
 685 otherwise, use flipped `message-forward-as-mime'.
 686 If POST, post instead of mail."
 687   (interactive "P")
 688   (let ((message-forward-as-mime message-forward-as-mime)
 689         (message-forward-show-mml message-forward-show-mml))
 690     (cond
 691      ((null arg))
 692      ((eq arg 1) (setq message-forward-as-mime nil
 693                        message-forward-show-mml t))
 694      ((eq arg 2) (setq message-forward-as-mime t
 695                        message-forward-show-mml nil))
 696      ((eq arg 3) (setq message-forward-as-mime t
 697                        message-forward-show-mml t))
 698      ((eq arg 4) (setq message-forward-as-mime nil
 699                        message-forward-show-mml nil))
 700      (t (setq message-forward-as-mime (not message-forward-as-mime))))
 701     (gnus-setup-message 'forward
 702       (gnus-summary-select-article)
 703       (let ((mail-parse-charset gnus-newsgroup-charset)
 704             (mail-parse-ignored-charsets gnus-newsgroup-ignored-charsets)
 705             text)
 706         (save-excursion
 707           (set-buffer gnus-original-article-buffer)
 708           (mm-with-unibyte-current-buffer
 709             (setq text (buffer-string))))
 710         (set-buffer
 711          (gnus-get-buffer-create
 712           (generate-new-buffer-name " *Gnus forward*")))
 713         (erase-buffer)
 714         (mm-disable-multibyte)
 715         (insert text)
 716         (goto-char (point-min))
 717         (when (looking-at "From ")
 718           (replace-match "X-From-Line: ") )
 719         (when message-forward-show-mml
 720           (mm-enable-multibyte)
 721           (mime-to-mml))
 722         (message-forward post)))))
 723
 724 (defun gnus-summary-resend-message (address n)
 725   "Resend the current article to ADDRESS."
 726   (interactive "sResend message(s) to: \nP")
 727   (let ((articles (gnus-summary-work-articles n))
 728         article)
 729     (while (setq article (pop articles))
 730       (gnus-summary-select-article nil nil nil article)
 731       (save-excursion
 732         (set-buffer gnus-original-article-buffer)
 733         (message-resend address)))))
 734
 735 (defun gnus-summary-post-forward (&optional arg)
 736   "Forward the current article to a newsgroup.
 737 See `gnus-summary-mail-forward' for ARG."
 738   (interactive "P")
 739   (gnus-summary-mail-forward arg t))
 740
 741 (defvar gnus-nastygram-message
 742   "The following article was inappropriately posted to %s.\n\n"
 743   "Format string to insert in nastygrams.
 744 The current group name will be inserted at \"%s\".")
 745
 746 (defun gnus-summary-mail-nastygram (n)
 747   "Send a nastygram to the author of the current article."
 748   (interactive "P")
 749   (when (or gnus-expert-user
 750             (gnus-y-or-n-p
 751              "Really send a nastygram to the author of the current article? "))
 752     (let ((group gnus-newsgroup-name))
 753       (gnus-summary-reply-with-original n)
 754       (set-buffer gnus-message-buffer)
 755       (message-goto-body)
 756       (insert (format gnus-nastygram-message group))
 757       (message-send-and-exit))))
 758
 759 (defun gnus-summary-mail-crosspost-complaint (n)
 760   "Send a complaint about crossposting to the current article(s)."
 761   (interactive "P")
 762   (let ((articles (gnus-summary-work-articles n))
 763         article)
 764     (while (setq article (pop articles))
 765       (set-buffer gnus-summary-buffer)
 766       (gnus-summary-goto-subject article)
 767       (let ((group (gnus-group-real-name gnus-newsgroup-name))
 768             newsgroups followup-to)
 769         (gnus-summary-select-article)
 770         (set-buffer gnus-original-article-buffer)
 771         (if (and (<= (length (message-tokenize-header
 772                               (setq newsgroups
 773                                     (mail-fetch-field "newsgroups"))
 774                               ", "))
 775                      1)
 776                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
 777                      (not (member group (message-tokenize-header
 778                                          followup-to ", ")))))
 779             (if followup-to
 780                 (gnus-message 1 "Followup-to restricted")
 781               (gnus-message 1 "Not a crossposted article"))
 782           (set-buffer gnus-summary-buffer)
 783           (gnus-summary-reply-with-original 1)
 784           (set-buffer gnus-message-buffer)
 785           (message-goto-body)
 786           (insert (format gnus-crosspost-complaint newsgroups group))
 787           (message-goto-subject)
 788           (re-search-forward " *$")
 789           (replace-match " (crosspost notification)" t t)
 790           (gnus-deactivate-mark)
 791           (when (gnus-y-or-n-p "Send this complaint? ")
 792             (message-send-and-exit)))))))
 793
 794 (defun gnus-summary-mail-other-window ()
 795   "Compose mail in other window."
 796   (interactive)
 797   (gnus-setup-message 'message
 798     (message-mail)))
 799
 800 (defun gnus-mail-parse-comma-list ()
 801   (let (accumulated
 802         beg)
 803     (skip-chars-forward " ")
 804     (while (not (eobp))
 805       (setq beg (point))
 806       (skip-chars-forward "^,")
 807       (while (zerop
 808               (save-excursion
 809                 (save-restriction
 810                   (let ((i 0))
 811                     (narrow-to-region beg (point))
 812                     (goto-char beg)
 813                     (logand (progn
 814                               (while (search-forward "\"" nil t)
 815                                 (incf i))
 816                               (if (zerop i) 2 i))
 817                             2)))))
 818         (skip-chars-forward ",")
 819         (skip-chars-forward "^,"))
 820       (skip-chars-backward " ")
 821       (push (buffer-substring beg (point))
 822             accumulated)
 823       (skip-chars-forward "^,")
 824       (skip-chars-forward ", "))
 825     accumulated))
 826
 827 (defun gnus-inews-add-to-address (group)
 828   (let ((to-address (mail-fetch-field "to")))
 829     (when (and to-address
 830                (gnus-alive-p))
 831       ;; This mail group doesn't have a `to-list', so we add one
 832       ;; here.  Magic!
 833       (when (gnus-y-or-n-p
 834              (format "Do you want to add this as `to-list': %s " to-address))
 835         (gnus-group-add-parameter group (cons 'to-list to-address))))))
 836
 837 (defun gnus-put-message ()
 838   "Put the current message in some group and return to Gnus."
 839   (interactive)
 840   (let ((reply gnus-article-reply)
 841         (winconf gnus-prev-winconf)
 842         (group gnus-newsgroup-name))
 843
 844     (or (and group (not (gnus-group-read-only-p group)))
 845         (setq group (read-string "Put in group: " nil
 846                                  (gnus-writable-groups))))
 847     (when (gnus-gethash group gnus-newsrc-hashtb)
 848       (error "No such group: %s" group))
 849
 850     (save-excursion
 851       (save-restriction
 852         (widen)
 853         (message-narrow-to-headers)
 854         (let (gnus-deletable-headers)
 855           (if (message-news-p)
 856               (message-generate-headers message-required-news-headers)
 857             (message-generate-headers message-required-mail-headers)))
 858         (goto-char (point-max))
 859         (insert "Gcc: " group "\n")
 860         (widen)))
 861
 862     (gnus-inews-do-gcc)
 863
 864     (when (get-buffer gnus-group-buffer)
 865       (when (gnus-buffer-exists-p (car-safe reply))
 866         (set-buffer (car reply))
 867         (and (cdr reply)
 868              (gnus-summary-mark-article-as-replied
 869               (cdr reply))))
 870       (when winconf
 871         (set-window-configuration winconf)))))
 872
 873 (defun gnus-article-mail (yank)
 874   "Send a reply to the address near point.
 875 If YANK is non-nil, include the original article."
 876   (interactive "P")
 877   (let ((address
 878          (buffer-substring
 879           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
 880           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
 881     (when address
 882       (message-reply address)
 883       (when yank
 884         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
 885
 886 (defvar nntp-server-type)
 887 (defun gnus-bug ()
 888   "Send a bug report to the Gnus maintainers."
 889   (interactive)
 890   (unless (gnus-alive-p)
 891     (error "Gnus has been shut down"))
 892   (gnus-setup-message 'bug
 893     (delete-other-windows)
 894     (when gnus-bug-create-help-buffer
 895       (switch-to-buffer "*Gnus Help Bug*")
 896       (erase-buffer)
 897       (insert gnus-bug-message)
 898       (goto-char (point-min)))
 899     (message-pop-to-buffer "*Gnus Bug*")
 900     (message-setup `((To . ,gnus-maintainer) (Subject . "")))
 901     (when gnus-bug-create-help-buffer
 902       (push `(gnus-bug-kill-buffer) message-send-actions))
 903     (goto-char (point-min))
 904     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
 905     (forward-line 1)
 906     (insert (gnus-version) "\n"
 907             (emacs-version) "\n")
 908     (when (and (boundp 'nntp-server-type)
 909                (stringp nntp-server-type))
 910       (insert nntp-server-type))
 911     (insert "\n\n\n\n\n")
 912     (let (text)
 913       (save-excursion
 914         (set-buffer (gnus-get-buffer-create " *gnus environment info*"))
 915         (gnus-debug)
 916         (setq text (buffer-string)))
 917       (insert "<#part type=application/x-emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
 918     (goto-char (point-min))
 919     (search-forward "Subject: " nil t)
 920     (message "")))
 921
 922 (defun gnus-bug-kill-buffer ()
 923   (when (get-buffer "*Gnus Help Bug*")
 924     (kill-buffer "*Gnus Help Bug*")))
 925
 926 (defun gnus-summary-yank-message (buffer n)
 927   "Yank the current article into a composed message."
 928   (interactive
 929    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
 930          current-prefix-arg))
 931   (gnus-summary-iterate n
 932     (let ((gnus-display-mime-function nil)
 933           (gnus-inhibit-treatment t))
 934       (gnus-summary-select-article))
 935     (save-excursion
 936       (set-buffer buffer)
 937       (message-yank-buffer gnus-article-buffer))))
 938
 939 (defun gnus-debug ()
 940   "Attempts to go through the Gnus source file and report what variables have been changed.
 941 The source file has to be in the Emacs load path."
 942   (interactive)
 943   (let ((files '("gnus.el" "gnus-sum.el" "gnus-group.el"
 944                  "gnus-art.el" "gnus-start.el" "gnus-async.el"
 945                  "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 946                  "nnmail.el" "message.el"))
 947         (point (point))
 948         file expr olist sym)
 949     (gnus-message 4 "Please wait while we snoop your variables...")
 950     (sit-for 0)
 951     ;; Go through all the files looking for non-default values for variables.
 952     (save-excursion
 953       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
 954       (while files
 955         (erase-buffer)
 956         (when (and (setq file (locate-library (pop files)))
 957                    (file-exists-p file))
 958           (insert-file-contents file)
 959           (goto-char (point-min))
 960           (if (not (re-search-forward "^;;* *Internal variables" nil t))
 961               (gnus-message 4 "Malformed sources in file %s" file)
 962             (narrow-to-region (point-min) (point))
 963             (goto-char (point-min))
 964             (while (setq expr (ignore-errors (read (current-buffer))))
 965               (ignore-errors
 966                 (and (or (eq (car expr) 'defvar)
 967                          (eq (car expr) 'defcustom))
 968                      (stringp (nth 3 expr))
 969                      (or (not (boundp (nth 1 expr)))
 970                          (not (equal (eval (nth 2 expr))
 971                                      (symbol-value (nth 1 expr)))))
 972                      (push (nth 1 expr) olist)))))))
 973       (kill-buffer (current-buffer)))
 974     (when (setq olist (nreverse olist))
 975       (insert "------------------ Environment follows ------------------\n\n"))
 976     (while olist
 977       (if (boundp (car olist))
 978           (condition-case ()
 979               (pp `(setq ,(car olist)
 980                          ,(if (or (consp (setq sym (symbol-value (car olist))))
 981                                   (and (symbolp sym)
 982                                        (not (or (eq sym nil)
 983                                                 (eq sym t)))))
 984                               (list 'quote (symbol-value (car olist)))
 985                             (symbol-value (car olist))))
 986                   (current-buffer))
 987             (error
 988              (format "(setq %s 'whatever)\n" (car olist))))
 989         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
 990       (setq olist (cdr olist)))
 991     (insert "\n\n")
 992     ;; Remove any control chars - they seem to cause trouble for some
 993     ;; mailers.  (Byte-compiled output from the stuff above.)
 994     (goto-char point)
 995     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
 996       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
 997                      t t))))
 998
 999 ;;; Treatment of rejected articles.
1000 ;;; Bounced mail.
1001
1002 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1003   "Re-mail the current message.
1004 This only makes sense if the current message is a bounce message than
1005 contains some mail you have written which has been bounced back to
1006 you.
1007 If FETCH, try to fetch the article that this is a reply to, if indeed
1008 this is a reply."
1009   (interactive "P")
1010   (gnus-summary-select-article t)
1011   (set-buffer gnus-original-article-buffer)
1012   (gnus-setup-message 'compose-bounce
1013     (let* ((references (mail-fetch-field "references"))
1014            (parent (and references (gnus-parent-id references))))
1015       (message-bounce)
1016       ;; If there are references, we fetch the article we answered to.
1017       (and fetch parent
1018            (gnus-summary-refer-article parent)
1019            (gnus-summary-show-all-headers)))))
1020
1021 ;;; Gcc handling.
1022
1023 ;; Do Gcc handling, which copied the message over to some group.
1024 (defun gnus-inews-do-gcc (&optional gcc)
1025   (interactive)
1026   (when (gnus-alive-p)
1027     (save-excursion
1028       (save-restriction
1029         (message-narrow-to-headers)
1030         (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1031               (cur (current-buffer))
1032               groups group method)
1033           (when gcc
1034             (message-remove-header "gcc")
1035             (widen)
1036             (setq groups (message-tokenize-header gcc " ,"))
1037             ;; Copy the article over to some group(s).
1038             (while (setq group (pop groups))
1039               (gnus-check-server
1040                (setq method
1041                      (cond ((and (null (gnus-get-info group))
1042                                  (eq (car gnus-message-archive-method)
1043                                      (car
1044                                       (gnus-server-to-method
1045                                        (gnus-group-method group)))))
1046                             ;; If the group doesn't exist, we assume
1047                             ;; it's an archive group...
1048                             gnus-message-archive-method)
1049                            ;; Use the method.
1050                            ((gnus-info-method (gnus-get-info group))
1051                             (gnus-info-method (gnus-get-info group)))
1052                            ;; Find the method.
1053                            (t (gnus-group-method group)))))
1054               (gnus-check-server method)
1055               (unless (gnus-request-group group t method)
1056                 (gnus-request-create-group group method))
1057               (save-excursion
1058                 (nnheader-set-temp-buffer " *acc*")
1059                 (insert-buffer-substring cur)
1060                 (message-encode-message-body)
1061                 (save-restriction
1062                   (message-narrow-to-headers)
1063                   (let ((mail-parse-charset message-default-charset)
1064                         (rfc2047-header-encoding-alist
1065                          (cons '("Newsgroups" . default)
1066                                rfc2047-header-encoding-alist)))
1067                     (mail-encode-encoded-word-buffer)))
1068                 (goto-char (point-min))
1069                 (when (re-search-forward
1070                        (concat "^" (regexp-quote mail-header-separator) "$")
1071                        nil t)
1072                   (replace-match "" t t ))
1073                 (unless (gnus-request-accept-article group method t t)
1074                   (gnus-message 1 "Couldn't store article in group %s: %s"
1075                                 group (gnus-status-message method))
1076                   (sit-for 2))
1077                 (kill-buffer (current-buffer))))))))))
1078
1079 (defun gnus-inews-insert-gcc ()
1080   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1081   (save-excursion
1082     (save-restriction
1083       (message-narrow-to-headers)
1084       (let* ((group gnus-outgoing-message-group)
1085              (gcc (cond
1086                    ((gnus-functionp group)
1087                     (funcall group))
1088                    ((or (stringp group) (list group))
1089                     group))))
1090         (when gcc
1091           (insert "Gcc: "
1092                   (if (stringp gcc) gcc
1093                     (mapconcat 'identity gcc " "))
1094                   "\n"))))))
1095
1096 (defun gnus-inews-insert-archive-gcc (&optional group)
1097   "Insert the Gcc to say where the article is to be archived."
1098   (let* ((var gnus-message-archive-group)
1099          (group (or group gnus-newsgroup-name ""))
1100          (gcc-self-val
1101           (and gnus-newsgroup-name
1102                (not (equal gnus-newsgroup-name ""))
1103                (gnus-group-find-parameter
1104                 gnus-newsgroup-name 'gcc-self)))
1105          result
1106          (groups
1107           (cond
1108            ((null gnus-message-archive-method)
1109             ;; Ignore.
1110             nil)
1111            ((stringp var)
1112             ;; Just a single group.
1113             (list var))
1114            ((null var)
1115             ;; We don't want this.
1116             nil)
1117            ((and (listp var) (stringp (car var)))
1118             ;; A list of groups.
1119             var)
1120            ((gnus-functionp var)
1121             ;; A function.
1122             (funcall var group))
1123            (t
1124             ;; An alist of regexps/functions/forms.
1125             (while (and var
1126                         (not
1127                          (setq result
1128                                (cond
1129                                 ((stringp (caar var))
1130                                  ;; Regexp.
1131                                  (when (string-match (caar var) group)
1132                                    (cdar var)))
1133                                 ((gnus-functionp (car var))
1134                                  ;; Function.
1135                                  (funcall (car var) group))
1136                                 (t
1137                                  (eval (car var)))))))
1138               (setq var (cdr var)))
1139             result)))
1140          name)
1141     (when (or groups gcc-self-val)
1142       (when (stringp groups)
1143         (setq groups (list groups)))
1144       (save-excursion
1145         (save-restriction
1146           (message-narrow-to-headers)
1147           (goto-char (point-max))
1148           (insert "Gcc: ")
1149           (if gcc-self-val
1150               ;; Use the `gcc-self' param value instead.
1151               (progn
1152                 (insert
1153                  (if (stringp gcc-self-val)
1154                      gcc-self-val
1155                    group))
1156                 (if (not (eq gcc-self-val 'none))
1157                     (insert "\n")
1158                   (progn
1159                     (beginning-of-line)
1160                     (kill-line))))
1161             ;; Use the list of groups.
1162             (while (setq name (pop groups))
1163               (insert (if (string-match ":" name)
1164                           name
1165                         (gnus-group-prefixed-name
1166                          name gnus-message-archive-method)))
1167               (when groups
1168                 (insert " ")))
1169             (insert "\n")))))))
1170
1171 ;;; Posting styles.
1172
1173 (defun gnus-configure-posting-styles ()
1174   "Configure posting styles according to `gnus-posting-styles'."
1175   (unless gnus-inhibit-posting-styles
1176     (let ((group (or gnus-newsgroup-name ""))
1177           (styles gnus-posting-styles)
1178           style match variable attribute value v results
1179           filep name address element)
1180       ;; If the group has a posting-style parameter, add it at the end with a
1181       ;; regexp matching everything, to be sure it takes precedence over all
1182       ;; the others.
1183       (when gnus-newsgroup-name
1184         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1185           (when tmp-style
1186             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1187       ;; Go through all styles and look for matches.
1188       (dolist (style styles)
1189         (setq match (pop style))
1190         (goto-char (point-min))
1191         (when (cond
1192                ((stringp match)
1193                 ;; Regexp string match on the group name.
1194                 (string-match match group))
1195                ((eq match 'header)
1196                 (let ((header (message-fetch-field (pop style))))
1197                   (and header
1198                        (string-match (pop style) header))))
1199                ((or (symbolp match)
1200                     (gnus-functionp match))
1201                 (cond
1202                  ((gnus-functionp match)
1203                   ;; Function to be called.
1204                   (funcall match))
1205                  ((boundp match)
1206                   ;; Variable to be checked.
1207                   (symbol-value match))))
1208                ((listp match)
1209                 ;; This is a form to be evaled.
1210                 (eval match)))
1211           ;; We have a match, so we set the variables.
1212           (dolist (attribute style)
1213             (setq element (pop attribute)
1214                   variable nil
1215                   filep nil)
1216             (setq value
1217                   (cond
1218                    ((eq (car attribute) :file)
1219                     (setq filep t)
1220                     (cadr attribute))
1221                    ((eq (car attribute) :value)
1222                     (cadr attribute))
1223                    (t
1224                     (car attribute))))
1225             ;; We get the value.
1226             (setq v
1227                   (cond
1228                    ((stringp value)
1229                     value)
1230                    ((or (symbolp value)
1231                         (gnus-functionp value))
1232                     (cond ((gnus-functionp value)
1233                            (funcall value))
1234                           ((boundp value)
1235                            (symbol-value value))))
1236                    ((listp value)
1237                     (eval value))))
1238             ;; Translate obsolescent value.
1239             (when (eq element 'signature-file)
1240               (setq element 'signature
1241                     filep t))
1242             ;; Get the contents of file elems.
1243             (when (and filep v)
1244               (setq v (with-temp-buffer
1245                         (insert-file-contents v)
1246                         (buffer-string))))
1247             (setq results (delq (assoc element results) results))
1248             (push (cons element v) results))))
1249       ;; Now we have all the styles, so we insert them.
1250       (setq name (assq 'name results)
1251             address (assq 'address results))
1252       (setq results (delq name (delq address results)))
1253       (make-local-variable 'message-setup-hook)
1254       (dolist (result results)
1255         (add-hook 'message-setup-hook
1256                   (cond
1257                    ((eq 'eval (car result))
1258                     'ignore)
1259                    ((eq 'body (car result))
1260                     `(lambda ()
1261                        (save-excursion
1262                          (message-goto-body)
1263                          (insert ,(cdr result)))))
1264                    ((eq 'signature (car result))
1265                     (set (make-local-variable 'message-signature) nil)
1266                     (set (make-local-variable 'message-signature-file) nil)
1267                     (if (not (cdr result))
1268                         'ignore
1269                       `(lambda ()
1270                          (save-excursion
1271                            (let ((message-signature ,(cdr result)))
1272                              (when message-signature
1273                                (message-insert-signature)))))))
1274                    (t
1275                     (let ((header
1276                            (if (symbolp (car result))
1277                                (capitalize (symbol-name (car result)))
1278                              (car result))))
1279                       `(lambda ()
1280                          (save-excursion
1281                            (message-remove-header ,header)
1282                            (let ((value ,(cdr result)))
1283                              (when value
1284                                (message-goto-eoh)
1285                                (insert ,header ": " value "\n"))))))))))
1286       (when (or name address)
1287         (add-hook 'message-setup-hook
1288                   `(lambda ()
1289                      (set (make-local-variable 'user-mail-address)
1290                           ,(or (cdr address) user-mail-address))
1291                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1292                            (user-mail-address
1293                             ,(or (cdr address) user-mail-address)))
1294                        (save-excursion
1295                          (message-remove-header "From")
1296                          (message-goto-eoh)
1297                          (insert "From: " (message-make-from) "\n")))))))))
1298
1299 ;;; Allow redefinition of functions.
1300
1301 (gnus-ems-redefine)
1302
1303 (provide 'gnus-msg)
1304
1305 ;;; gnus-msg.el ends here