cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-ems)
  34 (require 'message)
  35 (require 'gnus-art)
  36
  37 (defcustom gnus-post-method 'current
  38   "*Preferred method for posting USENET news.
  39
  40 If this variable is `current' (which is the default), Gnus will use
  41 the \"current\" select method when posting.  If it is nil, Gnus will
  42 use the native select method when posting.
  43
  44 This method will not be used in mail groups and the like, only in
  45 \"real\" newsgroups.
  46
  47 If not nil nor `native', the value must be a valid method as discussed
  48 in the documentation of `gnus-select-method'.  It can also be a list of
  49 methods.  If that is the case, the user will be queried for what select
  50 method to use when posting."
  51   :group 'gnus-group-foreign
  52   :type `(choice (const nil)
  53                  (const current)
  54                  (const native)
  55                  (sexp :tag "Methods" ,gnus-select-method)))
  56
  57 (defcustom gnus-outgoing-message-group nil
  58   "*All outgoing messages will be put in this group.
  59 If you want to store all your outgoing mail and articles in the group
  60 \"nnml:archive\", you set this variable to that value.  This variable
  61 can also be a list of group names.
  62
  63 If you want to have greater control over what group to put each
  64 message in, you can set this variable to a function that checks the
  65 current newsgroup name and then returns a suitable group name (or list
  66 of names)."
  67   :group 'gnus-message
  68   :type '(choice (string :tag "Group")
  69                  (function)))
  70
  71 (defcustom gnus-mailing-list-groups nil
  72   "*Regexp matching groups that are really mailing lists.
  73 This is useful when you're reading a mailing list that has been
  74 gatewayed to a newsgroup, and you want to followup to an article in
  75 the group."
  76   :group 'gnus-message
  77   :type 'regexp)
  78
  79 (defcustom gnus-add-to-list nil
  80   "*If non-nil, add a `to-list' parameter automatically."
  81   :group 'gnus-message
  82   :type 'boolean)
  83
  84 (defcustom gnus-crosspost-complaint
  85   "Hi,
  86
  87 You posted the article below with the following Newsgroups header:
  88
  89 Newsgroups: %s
  90
  91 The %s group, at least, was an inappropriate recipient
  92 of this message.  Please trim your Newsgroups header to exclude this
  93 group before posting in the future.
  94
  95 Thank you.
  96
  97 "
  98   "Format string to be inserted when complaining about crossposts.
  99 The first %s will be replaced by the Newsgroups header;
 100 the second with the current group name."
 101   :group 'gnus-message
 102   :type 'string)
 103
 104 (defcustom gnus-message-setup-hook nil
 105   "Hook run after setting up a message buffer."
 106   :group 'gnus-message
 107   :type 'hook)
 108
 109 (defcustom gnus-bug-create-help-buffer t
 110   "*Should we create the *Gnus Help Bug* buffer?"
 111   :group 'gnus-message
 112   :type 'boolean)
 113
 114 (defcustom gnus-posting-styles nil
 115   "*Alist of styles to use when posting."
 116   :group 'gnus-message
 117   :type '(repeat (cons (choice (regexp)
 118                                (function)
 119                                (variable)
 120                                (sexp))
 121                        (repeat (list
 122                                 (choice (const signature)
 123                                         (const signature-file)
 124                                         (const organization)
 125                                         (const address)
 126                                         (const name)
 127                                         (const body)
 128                                         (string :tag "Header"))
 129                                 (choice (string)
 130                                         (function)
 131                                         (variable)
 132                                         (sexp)))))))
 133
 134 (defcustom gnus-inews-mark-gcc-as-read nil
 135   "If non-nil, automatically mark Gcc articles as read."
 136   :group 'gnus-message
 137   :type 'boolean)
 138
 139 (defcustom gnus-group-posting-charset-alist
 140   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 141     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 142     (message-this-is-mail nil nil)
 143     (message-this-is-news nil t))
 144   "Alist of regexps and permitted unencoded charsets for posting.
 145 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 146 TEST is either a regular expression matching the newsgroup header or a
 147 variable to query,
 148 HEADER is the charset which may be left unencoded in the header (nil
 149 means encode all charsets),
 150 BODY-LIST is a list of charsets which may be encoded using 8bit
 151 content-transfer encoding in the body, or one of the special values
 152 nil (always encode using quoted-printable) or t (always use 8bit).
 153
 154 Note that any value other than nil for HEADER infringes some RFCs, so
 155 use this option with care."
 156   :type '(repeat (list :tag "Permitted unencoded charsets"
 157                   (choice :tag "Where"
 158                    (regexp :tag "Group")
 159                    (const :tag "Mail message" :value message-this-is-mail)
 160                    (const :tag "News article" :value message-this-is-news))
 161                   (choice :tag "Header"
 162                    (const :tag "None" nil)
 163                    (symbol :tag "Charset"))
 164                   (choice :tag "Body"
 165                           (const :tag "Any" :value t)
 166                           (const :tag "None" :value nil)
 167                           (repeat :tag "Charsets"
 168                                   (symbol :tag "Charset")))))
 169   :group 'gnus-charset)
 170
 171 ;;; Internal variables.
 172
 173 (defvar gnus-inhibit-posting-styles nil
 174   "Inhibit the use of posting styles.")
 175
 176 (defvar gnus-message-buffer "*Mail Gnus*")
 177 (defvar gnus-article-copy nil)
 178 (defvar gnus-check-before-posting nil)
 179 (defvar gnus-last-posting-server nil)
 180 (defvar gnus-message-group-art nil)
 181
 182 (defvar gnus-msg-force-broken-reply-to nil)
 183
 184 (defconst gnus-bug-message
 185   "Sending a bug report to the Gnus Towers.
 186 ========================================
 187
 188 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 189 be sent to the Gnus Bug Exterminators.
 190
 191 The thing near the bottom of the buffer is how the environment
 192 settings will be included in the mail.  Please do not delete that.
 193 They will tell the Bug People what your environment is, so that it
 194 will be easier to locate the bugs.
 195
 196 If you have found a bug that makes Emacs go \"beep\", set
 197 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 198 and include the backtrace in your bug report.
 199
 200 Please describe the bug in annoying, painstaking detail.
 201
 202 Thank you for your help in stamping out bugs.
 203 ")
 204
 205 (eval-and-compile
 206   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 207   (autoload 'news-setup "rnewspost")
 208   (autoload 'news-reply-mode "rnewspost")
 209   (autoload 'rmail-dont-reply-to "mail-utils")
 210   (autoload 'rmail-output "rmailout"))
 211
 212 \f
 213 ;;;
 214 ;;; Gnus Posting Functions
 215 ;;;
 216
 217 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 218   "p" gnus-summary-post-news
 219   "f" gnus-summary-followup
 220   "F" gnus-summary-followup-with-original
 221   "c" gnus-summary-cancel-article
 222   "s" gnus-summary-supersede-article
 223   "r" gnus-summary-reply
 224   "y" gnus-summary-yank-message
 225   "R" gnus-summary-reply-with-original
 226   "w" gnus-summary-wide-reply
 227   "W" gnus-summary-wide-reply-with-original
 228   "v" gnus-summary-very-wide-reply
 229   "W" gnus-summary-very-wide-reply-with-original
 230   "n" gnus-summary-followup-to-mail
 231   "N" gnus-summary-followup-to-mail-with-original
 232   "m" gnus-summary-mail-other-window
 233   "u" gnus-uu-post-news
 234   "\M-c" gnus-summary-mail-crosspost-complaint
 235   "Br" gnus-summary-reply-broken-reply-to
 236   "BR" gnus-summary-reply-broken-reply-to-with-original
 237   "om" gnus-summary-mail-forward
 238   "op" gnus-summary-post-forward
 239   "Om" gnus-uu-digest-mail-forward
 240   "Op" gnus-uu-digest-post-forward)
 241
 242 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 243   "b" gnus-summary-resend-bounced-mail
 244   ;; "c" gnus-summary-send-draft
 245   "r" gnus-summary-resend-message)
 246
 247 ;;; Internal functions.
 248
 249 (defvar gnus-article-reply nil)
 250 (defmacro gnus-setup-message (config &rest forms)
 251   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 252         (buffer (make-symbol "gnus-setup-message-buffer"))
 253         (article (make-symbol "gnus-setup-message-article"))
 254         (group (make-symbol "gnus-setup-message-group")))
 255     `(let ((,winconf (current-window-configuration))
 256            (,buffer (buffer-name (current-buffer)))
 257            (,article gnus-article-reply)
 258            (,group gnus-newsgroup-name)
 259            (message-header-setup-hook
 260             (copy-sequence message-header-setup-hook))
 261            (mbl mml-buffer-list)
 262            (message-mode-hook (copy-sequence message-mode-hook)))
 263        (setq mml-buffer-list nil)
 264        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 265        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 266        (add-hook 'message-mode-hook 'gnus-configure-posting-styles)
 267        (unwind-protect
 268            (progn
 269              ,@forms)
 270          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config)
 271          (gnus-inews-insert-draft-meta-information ,group ,article)
 272          (setq gnus-message-buffer (current-buffer))
 273          (set (make-local-variable 'gnus-message-group-art)
 274               (cons ,group ,article))
 275          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 276          (gnus-run-hooks 'gnus-message-setup-hook)
 277          (if (eq major-mode 'message-mode)
 278              (let ((mbl1 mml-buffer-list))
 279                (setq mml-buffer-list mbl)  ;; Global value
 280                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 281                ;; LOCAL argument of add-hook differs between GNU Emacs
 282                ;; and XEmacs. make-local-hook makes sure they are local.
 283                (make-local-hook 'kill-buffer-hook)
 284                (make-local-hook 'change-major-mode-hook)
 285                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 286                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 287            (mml-destroy-buffers)
 288            (setq mml-buffer-list mbl)))
 289        (gnus-add-buffer)
 290        (gnus-configure-windows ,config t)
 291        (set-buffer-modified-p nil))))
 292
 293 (defun gnus-inews-insert-draft-meta-information (group article)
 294   (save-excursion
 295     (when (and group
 296                (not (string= group ""))
 297                (not (message-fetch-field gnus-draft-meta-information-header)))
 298       (goto-char (point-min))
 299       (insert gnus-draft-meta-information-header ": (\"" group "\" "
 300               (if article (number-to-string
 301                            (if (listp article)
 302                                (car article)
 303                              article)) "\"\"")
 304               ")\n"))))
 305
 306 ;;;###autoload
 307 (defun gnus-msg-mail (&optional to subject other-headers continue
 308                                 switch-action yank-action send-actions)
 309   "Start editing a mail message to be sent.
 310 Like `message-mail', but with Gnus paraphernalia, particularly the
 311 Gcc: header for archiving purposes."
 312   (interactive)
 313   (let ((buf (current-buffer))
 314         mail-buf)
 315     (gnus-setup-message 'message
 316       (message-mail to subject other-headers continue
 317                     nil yank-action send-actions))
 318     (when switch-action
 319       (setq mail-buf (current-buffer))
 320       (switch-to-buffer buf)
 321       (apply switch-action mail-buf nil)))
 322   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 323   t)
 324
 325 (defvar save-selected-window-window)
 326
 327 ;;;###autoload
 328 (defun gnus-button-mailto (address)
 329   "Mail to ADDRESS."
 330   (set-buffer (gnus-copy-article-buffer))
 331   (gnus-setup-message 'message
 332     (message-reply address))
 333   (and (boundp 'save-selected-window-window)
 334        (not (window-live-p save-selected-window-window))
 335        (setq save-selected-window-window (selected-window))))
 336
 337 ;;;###autoload
 338 (defun gnus-button-reply (&optional to-address wide)
 339   "Like `message-reply'."
 340   (interactive)
 341   (gnus-setup-message 'message
 342     (message-reply to-address wide))
 343   (and (boundp 'save-selected-window-window)
 344        (not (window-live-p save-selected-window-window))
 345        (setq save-selected-window-window (selected-window))))
 346
 347 ;;;###autoload
 348 (define-mail-user-agent 'gnus-user-agent
 349   'gnus-msg-mail 'message-send-and-exit
 350   'message-kill-buffer 'message-send-hook)
 351
 352 (defun gnus-setup-posting-charset (group)
 353   (let ((alist gnus-group-posting-charset-alist)
 354         (group (or group ""))
 355         elem)
 356     (when group
 357       (catch 'found
 358         (while (setq elem (pop alist))
 359           (when (or (and (stringp (car elem))
 360                          (string-match (car elem) group))
 361                     (and (gnus-functionp (car elem))
 362                          (funcall (car elem) group))
 363                     (and (symbolp (car elem))
 364                          (symbol-value (car elem))))
 365             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 366
 367 (defun gnus-inews-add-send-actions (winconf buffer article &optional config)
 368   (make-local-hook 'message-sent-hook)
 369   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 370                                  'gnus-inews-do-gcc) nil t)
 371   (when gnus-agent
 372     (make-local-hook 'message-header-hook)
 373     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 374   (setq message-post-method
 375         `(lambda (arg)
 376            (gnus-post-method arg ,gnus-newsgroup-name)))
 377   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 378   (message-add-action
 379    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 380   (message-add-action
 381    `(when (gnus-buffer-exists-p ,buffer)
 382       (save-excursion
 383         (set-buffer ,buffer)
 384         ,(when article
 385            (if (eq config 'forward)
 386                `(gnus-summary-mark-article-as-forwarded ',article)
 387              `(gnus-summary-mark-article-as-replied ',article)))))
 388    'send))
 389
 390 (put 'gnus-setup-message 'lisp-indent-function 1)
 391 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 392
 393 ;;; Post news commands of Gnus group mode and summary mode
 394
 395 (defun gnus-group-mail (&optional arg)
 396   "Start composing a mail.
 397 If ARG, use the group under the point to find a posting style.
 398 If ARG is 1, prompt for a group name to find the posting style."
 399   (interactive "P")
 400   ;; We can't `let' gnus-newsgroup-name here, since that leads
 401   ;; to local variables leaking.
 402   (let ((group gnus-newsgroup-name)
 403         (buffer (current-buffer)))
 404     (unwind-protect
 405         (progn
 406           (setq gnus-newsgroup-name
 407                 (if arg
 408                     (if (= 1 (prefix-numeric-value arg))
 409                         (completing-read "Use posting style of group: "
 410                                          gnus-active-hashtb nil
 411                                          (gnus-read-active-file-p))
 412                       (gnus-group-group-name))
 413                   ""))
 414           (gnus-setup-message 'message (message-mail)))
 415       (save-excursion
 416         (set-buffer buffer)
 417         (setq gnus-newsgroup-name group)))))
 418
 419 (defun gnus-group-post-news (&optional arg)
 420   "Start composing a news message.
 421 If ARG, post to the group under point.
 422 If ARG is 1, prompt for a group name."
 423   (interactive "P")
 424   ;; Bind this variable here to make message mode hooks work ok.
 425   (let ((gnus-newsgroup-name
 426          (if arg
 427              (if (= 1 (prefix-numeric-value arg))
 428                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 429                                   (gnus-read-active-file-p))
 430                (gnus-group-group-name))
 431            "")))
 432     (gnus-post-news 'post gnus-newsgroup-name)))
 433
 434 (defun gnus-summary-post-news ()
 435   "Start composing a news message."
 436   (interactive)
 437   (gnus-post-news 'post gnus-newsgroup-name))
 438
 439 (defun gnus-summary-followup (yank &optional force-news)
 440   "Compose a followup to an article.
 441 If prefix argument YANK is non-nil, original article is yanked automatically."
 442   (interactive
 443    (list (and current-prefix-arg
 444               (gnus-summary-work-articles 1))))
 445   (when yank
 446     (gnus-summary-goto-subject (car yank)))
 447   (save-window-excursion
 448     (gnus-summary-select-article))
 449   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 450         (gnus-newsgroup-name gnus-newsgroup-name))
 451     ;; Send a followup.
 452     (gnus-post-news nil gnus-newsgroup-name
 453                     headers gnus-article-buffer
 454                     yank nil force-news)))
 455
 456 (defun gnus-summary-followup-with-original (n &optional force-news)
 457   "Compose a followup to an article and include the original article."
 458   (interactive "P")
 459   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 460
 461 (defun gnus-summary-followup-to-mail (&optional arg)
 462   "Followup to the current mail message via news."
 463   (interactive
 464    (list (and current-prefix-arg
 465               (gnus-summary-work-articles 1))))
 466   (gnus-summary-followup arg t))
 467
 468 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 469   "Followup to the current mail message via news."
 470   (interactive "P")
 471   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 472
 473 (defun gnus-inews-yank-articles (articles)
 474   (let (beg article)
 475     (message-goto-body)
 476     (while (setq article (pop articles))
 477       (save-window-excursion
 478         (set-buffer gnus-summary-buffer)
 479         (gnus-summary-select-article nil nil nil article)
 480         (gnus-summary-remove-process-mark article))
 481       (gnus-copy-article-buffer)
 482       (let ((message-reply-buffer gnus-article-copy)
 483             (message-reply-headers
 484              (with-current-buffer gnus-article-copy
 485                ;; The headers are decoded.
 486                (nnheader-parse-head t))))
 487         (message-yank-original)
 488         (setq beg (or beg (mark t))))
 489       (when articles
 490         (insert "\n")))
 491     (push-mark)
 492     (goto-char beg)))
 493
 494 (defun gnus-summary-cancel-article (&optional n symp)
 495   "Cancel an article you posted.
 496 Uses the process-prefix convention.  If given the symbolic
 497 prefix `a', cancel using the standard posting method; if not
 498 post using the current select method."
 499   (interactive (gnus-interactive "P\ny"))
 500   (let ((articles (gnus-summary-work-articles n))
 501         (message-post-method
 502          `(lambda (arg)
 503             (gnus-post-method (not (eq symp 'a)) ,gnus-newsgroup-name)))
 504         article)
 505     (while (setq article (pop articles))
 506       (when (gnus-summary-select-article t nil nil article)
 507         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 508                 (message-cancel-news))
 509           (gnus-summary-mark-as-read article gnus-canceled-mark)
 510           (gnus-cache-remove-article 1))
 511         (gnus-article-hide-headers-if-wanted))
 512       (gnus-summary-remove-process-mark article))))
 513
 514 (defun gnus-summary-supersede-article ()
 515   "Compose an article that will supersede a previous article.
 516 This is done simply by taking the old article and adding a Supersedes
 517 header line with the old Message-ID."
 518   (interactive)
 519   (let ((article (gnus-summary-article-number)))
 520     (gnus-setup-message 'reply-yank
 521       (gnus-summary-select-article t)
 522       (set-buffer gnus-original-article-buffer)
 523       (message-supersede)
 524       (push
 525        `((lambda ()
 526            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 527              (save-excursion
 528                (set-buffer ,gnus-summary-buffer)
 529                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 530                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 531        message-send-actions))))
 532
 533 \f
 534
 535 (defun gnus-copy-article-buffer (&optional article-buffer)
 536   ;; make a copy of the article buffer with all text properties removed
 537   ;; this copy is in the buffer gnus-article-copy.
 538   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 539   ;; this buffer should be passed to all mail/news reply/post routines.
 540   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 541   (save-excursion
 542     (set-buffer gnus-article-copy)
 543     (mm-enable-multibyte))
 544   (let ((article-buffer (or article-buffer gnus-article-buffer))
 545         end beg)
 546     (if (not (and (get-buffer article-buffer)
 547                   (gnus-buffer-exists-p article-buffer)))
 548         (error "Can't find any article buffer")
 549       (save-excursion
 550         (set-buffer article-buffer)
 551         (let ((gnus-newsgroup-charset (or gnus-article-charset
 552                                           gnus-newsgroup-charset))
 553               (gnus-newsgroup-ignored-charsets
 554                (or gnus-article-ignored-charsets
 555                    gnus-newsgroup-ignored-charsets)))
 556           (save-restriction
 557             ;; Copy over the (displayed) article buffer, delete
 558             ;; hidden text and remove text properties.
 559             (widen)
 560             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 561             (set-buffer gnus-article-copy)
 562             (gnus-article-delete-text-of-type 'annotation)
 563             (gnus-remove-text-with-property 'gnus-prev)
 564             (gnus-remove-text-with-property 'gnus-next)
 565             (insert
 566              (prog1
 567                  (buffer-substring-no-properties (point-min) (point-max))
 568                (erase-buffer)))
 569             ;; Find the original headers.
 570             (set-buffer gnus-original-article-buffer)
 571             (goto-char (point-min))
 572             (while (looking-at message-unix-mail-delimiter)
 573               (forward-line 1))
 574             (setq beg (point))
 575             (setq end (or (message-goto-body) beg))
 576             ;; Delete the headers from the displayed articles.
 577             (set-buffer gnus-article-copy)
 578             (delete-region (goto-char (point-min))
 579                            (or (message-goto-body) (point-max)))
 580             ;; Insert the original article headers.
 581             (insert-buffer-substring gnus-original-article-buffer beg end)
 582             ;; Decode charsets.
 583             (let ((gnus-article-decode-hook
 584                    (delq 'article-decode-charset gnus-article-decode-hook)))
 585               (run-hooks 'gnus-article-decode-hook)))))
 586       gnus-article-copy)))
 587
 588 (defun gnus-post-news (post &optional group header article-buffer yank subject
 589                             force-news)
 590   (when article-buffer
 591     (gnus-copy-article-buffer))
 592   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 593         (add-to-list gnus-add-to-list))
 594     (gnus-setup-message (cond (yank 'reply-yank)
 595                               (article-buffer 'reply)
 596                               (t 'message))
 597       (let* ((group (or group gnus-newsgroup-name))
 598              (charset (gnus-group-name-charset nil group))
 599              (pgroup group)
 600              to-address to-group mailing-list to-list
 601              newsgroup-p)
 602         (when group
 603           (setq to-address (gnus-parameter-to-address group)
 604                 to-group (gnus-group-find-parameter group 'to-group)
 605                 to-list (gnus-parameter-to-list group)
 606                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 607                 mailing-list (when gnus-mailing-list-groups
 608                                (string-match gnus-mailing-list-groups group))
 609                 group (gnus-group-name-decode (gnus-group-real-name group)
 610                                               charset)))
 611         (if (or (and to-group
 612                      (gnus-news-group-p to-group))
 613                 newsgroup-p
 614                 force-news
 615                 (and (gnus-news-group-p
 616                       (or pgroup gnus-newsgroup-name)
 617                       (if header (mail-header-number header)
 618                         gnus-current-article))
 619                      (not mailing-list)
 620                      (not to-list)
 621                      (not to-address)))
 622             ;; This is news.
 623             (if post
 624                 (message-news (or to-group group))
 625               (set-buffer gnus-article-copy)
 626               (gnus-msg-treat-broken-reply-to)
 627               (message-followup (if (or newsgroup-p force-news)
 628                                     (if (save-restriction
 629                                           (article-narrow-to-head)
 630                                           (message-fetch-field "newsgroups"))
 631                                         nil
 632                                       "")
 633                                   to-group)))
 634           ;; The is mail.
 635           (if post
 636               (progn
 637                 (message-mail (or to-address to-list))
 638                 ;; Arrange for mail groups that have no `to-address' to
 639                 ;; get that when the user sends off the mail.
 640                 (when (and (not to-list)
 641                            (not to-address)
 642                            add-to-list)
 643                   (push (list 'gnus-inews-add-to-address pgroup)
 644                         message-send-actions)))
 645             (set-buffer gnus-article-copy)
 646             (gnus-msg-treat-broken-reply-to)
 647             (message-wide-reply to-address)))
 648         (when yank
 649           (gnus-inews-yank-articles yank))))))
 650
 651 (defun gnus-msg-treat-broken-reply-to (&optional force)
 652   "Remove the Reply-to header iff broken-reply-to."
 653   (when (or force
 654             (gnus-group-find-parameter
 655              gnus-newsgroup-name 'broken-reply-to))
 656     (save-restriction
 657       (message-narrow-to-head)
 658       (message-remove-header "reply-to"))))
 659
 660 (defun gnus-post-method (arg group &optional silent)
 661   "Return the posting method based on GROUP and ARG.
 662 If SILENT, don't prompt the user."
 663   (let ((gnus-post-method (or (gnus-parameter-post-method group)
 664                               gnus-post-method))
 665         (group-method (gnus-find-method-for-group group)))
 666     (cond
 667      ;; If the group-method is nil (which shouldn't happen) we use
 668      ;; the default method.
 669      ((null group-method)
 670       (or (and (null (eq gnus-post-method 'active)) gnus-post-method)
 671           gnus-select-method message-post-method))
 672      ;; We want the inverse of the default
 673      ((and arg (not (eq arg 0)))
 674       (if (eq gnus-post-method 'active)
 675           gnus-select-method
 676         group-method))
 677      ;; We query the user for a post method.
 678      ((or arg
 679           (and gnus-post-method
 680                (not (eq gnus-post-method 'current))
 681                (listp (car gnus-post-method))))
 682       (let* ((methods
 683               ;; Collect all methods we know about.
 684               (append
 685                (when (and gnus-post-method
 686                           (not (eq gnus-post-method 'current)))
 687                  (if (listp (car gnus-post-method))
 688                      gnus-post-method
 689                    (list gnus-post-method)))
 690                gnus-secondary-select-methods
 691                (mapcar 'cdr gnus-server-alist)
 692                (mapcar 'car gnus-opened-servers)
 693                (list gnus-select-method)
 694                (list group-method)))
 695              method-alist post-methods method)
 696         ;; Weed out all mail methods.
 697         (while methods
 698           (setq method (gnus-server-get-method "" (pop methods)))
 699           (when (and (or (gnus-method-option-p method 'post)
 700                          (gnus-method-option-p method 'post-mail))
 701                      (not (member method post-methods)))
 702             (push method post-methods)))
 703         ;; Create a name-method alist.
 704         (setq method-alist
 705               (mapcar
 706                (lambda (m)
 707                  (if (equal (cadr m) "")
 708                      (list (symbol-name (car m)) m)
 709                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
 710                post-methods))
 711         ;; Query the user.
 712         (cadr
 713          (assoc
 714           (setq gnus-last-posting-server
 715                 (if (and silent
 716                          gnus-last-posting-server)
 717                     ;; Just use the last value.
 718                     gnus-last-posting-server
 719                   (completing-read
 720                    "Posting method: " method-alist nil t
 721                    (cons (or gnus-last-posting-server "") 0))))
 722           method-alist))))
 723      ;; Override normal method.
 724      ((and (eq gnus-post-method 'current)
 725            (not (eq (car group-method) 'nndraft))
 726            (gnus-get-function group-method 'request-post t)
 727            (not arg))
 728       group-method)
 729      ((and gnus-post-method
 730            (not (eq gnus-post-method 'current)))
 731       gnus-post-method)
 732      ;; Use the normal select method.
 733      (t gnus-select-method))))
 734
 735 \f
 736
 737 ;; Dummies to avoid byte-compile warning.
 738 (eval-when-compile
 739   (defvar nnspool-rejected-article-hook)
 740   (defvar xemacs-codename))
 741
 742 (defun gnus-extended-version ()
 743   "Stringified Gnus version and Emacs version."
 744   (interactive)
 745   (concat
 746    "Gnus/" (prin1-to-string (gnus-continuum-version gnus-version) t)
 747    " (" gnus-version ")"
 748    " "
 749    (cond
 750     ((string-match "^\\(\\([.0-9]+\\)*\\)\\.[0-9]+$" emacs-version)
 751      (concat "Emacs/" (match-string 1 emacs-version)))
 752     ((string-match "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)[^(]*\\(\\((beta.*)\\|'\\)\\)?"
 753                    emacs-version)
 754      (concat (match-string 1 emacs-version)
 755              (format "/%d.%d" emacs-major-version emacs-minor-version)
 756              (if (match-beginning 3)
 757                  (match-string 3 emacs-version)
 758                "")
 759              (if (boundp 'xemacs-codename)
 760                  (concat " (" xemacs-codename ")")
 761                "")))
 762     (t emacs-version))))
 763
 764 \f
 765 ;;;
 766 ;;; Gnus Mail Functions
 767 ;;;
 768
 769 ;;; Mail reply commands of Gnus summary mode
 770
 771 (defun gnus-summary-reply (&optional yank wide very-wide)
 772   "Start composing a mail reply to the current message.
 773 If prefix argument YANK is non-nil, the original article is yanked
 774 automatically.
 775 If WIDE, make a wide reply.
 776 If VERY-WIDE, make a very wide reply."
 777   (interactive
 778    (list (and current-prefix-arg
 779               (gnus-summary-work-articles 1))))
 780   ;; Stripping headers should be specified with mail-yank-ignored-headers.
 781   (when yank
 782     (gnus-summary-goto-subject (car yank)))
 783   (let ((gnus-article-reply (or yank (gnus-summary-article-number)))
 784         (headers ""))
 785     (gnus-setup-message (if yank 'reply-yank 'reply)
 786       (if (not very-wide)
 787           (gnus-summary-select-article)
 788         (dolist (article very-wide)
 789           (gnus-summary-select-article nil nil nil article)
 790           (save-excursion
 791             (set-buffer (gnus-copy-article-buffer))
 792             (gnus-msg-treat-broken-reply-to)
 793             (save-restriction
 794               (message-narrow-to-head)
 795               (setq headers (concat headers (buffer-string)))))))
 796       (set-buffer (gnus-copy-article-buffer))
 797       (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
 798       (save-restriction
 799         (message-narrow-to-head)
 800         (when very-wide
 801           (erase-buffer)
 802           (insert headers))
 803         (goto-char (point-max)))
 804       (mml-quote-region (point) (point-max))
 805       (message-reply nil wide)
 806       (when yank
 807         (gnus-inews-yank-articles yank)))))
 808
 809 (defun gnus-summary-reply-with-original (n &optional wide)
 810   "Start composing a reply mail to the current message.
 811 The original article will be yanked."
 812   (interactive "P")
 813   (gnus-summary-reply (gnus-summary-work-articles n) wide))
 814
 815 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
 816   "Like `gnus-summary-reply' except removing reply-to field.
 817 If prefix argument YANK is non-nil, the original article is yanked
 818 automatically.
 819 If WIDE, make a wide reply.
 820 If VERY-WIDE, make a very wide reply."
 821   (interactive
 822    (list (and current-prefix-arg
 823               (gnus-summary-work-articles 1))))
 824   (let ((gnus-msg-force-broken-reply-to t))
 825     (gnus-summary-reply yank wide very-wide)))
 826
 827 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
 828   "Like `gnus-summary-reply-with-original' except removing reply-to field.
 829 The original article will be yanked."
 830   (interactive "P")
 831   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
 832
 833 (defun gnus-summary-wide-reply (&optional yank)
 834   "Start composing a wide reply mail to the current message.
 835 If prefix argument YANK is non-nil, the original article is yanked
 836 automatically."
 837   (interactive
 838    (list (and current-prefix-arg
 839               (gnus-summary-work-articles 1))))
 840   (gnus-summary-reply yank t))
 841
 842 (defun gnus-summary-wide-reply-with-original (n)
 843   "Start composing a wide reply mail to the current message.
 844 The original article will be yanked."
 845   (interactive "P")
 846   (gnus-summary-reply-with-original n t))
 847
 848 (defun gnus-summary-very-wide-reply (&optional yank)
 849   "Start composing a very wide reply mail to the current message.
 850 If prefix argument YANK is non-nil, the original article is yanked
 851 automatically."
 852   (interactive
 853    (list (and current-prefix-arg
 854               (gnus-summary-work-articles 1))))
 855   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
 856
 857 (defun gnus-summary-very-wide-reply-with-original (n)
 858   "Start composing a very wide reply mail to the current message.
 859 The original article will be yanked."
 860   (interactive "P")
 861   (gnus-summary-reply
 862    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
 863
 864 (defun gnus-summary-mail-forward (&optional arg post)
 865   "Forward the current message to another user.
 866 If ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
 867 if ARG is 1, decode the message and forward directly inline;
 868 if ARG is 2, forward message as an rfc822 MIME section;
 869 if ARG is 3, decode message and forward as an rfc822 MIME section;
 870 if ARG is 4, forward message directly inline;
 871 otherwise, use flipped `message-forward-as-mime'.
 872 If POST, post instead of mail."
 873   (interactive "P")
 874   (let ((message-forward-as-mime message-forward-as-mime)
 875         (message-forward-show-mml message-forward-show-mml))
 876     (cond
 877      ((null arg))
 878      ((eq arg 1)
 879       (setq message-forward-as-mime nil
 880             message-forward-show-mml t))
 881      ((eq arg 2)
 882       (setq message-forward-as-mime t
 883             message-forward-show-mml nil))
 884      ((eq arg 3)
 885       (setq message-forward-as-mime t
 886             message-forward-show-mml t))
 887      ((eq arg 4)
 888       (setq message-forward-as-mime nil
 889             message-forward-show-mml nil))
 890      (t
 891       (setq message-forward-as-mime (not message-forward-as-mime))))
 892     (let ((gnus-article-reply (gnus-summary-article-number)))
 893       (gnus-setup-message 'forward
 894         (gnus-summary-select-article)
 895         (let ((mail-parse-charset gnus-newsgroup-charset)
 896               (mail-parse-ignored-charsets gnus-newsgroup-ignored-charsets))
 897           (set-buffer gnus-original-article-buffer)
 898           (message-forward post))))))
 899
 900 (defun gnus-summary-resend-message (address n)
 901   "Resend the current article to ADDRESS."
 902   (interactive
 903    (list (message-read-from-minibuffer "Resend message(s) to: ")
 904          current-prefix-arg))
 905   (let ((articles (gnus-summary-work-articles n))
 906         article)
 907     (while (setq article (pop articles))
 908       (gnus-summary-select-article nil nil nil article)
 909       (save-excursion
 910         (set-buffer gnus-original-article-buffer)
 911         (message-resend address))
 912       (gnus-summary-mark-article-as-forwarded article))))
 913
 914 (defun gnus-summary-post-forward (&optional arg)
 915   "Forward the current article to a newsgroup.
 916 See `gnus-summary-mail-forward' for ARG."
 917   (interactive "P")
 918   (gnus-summary-mail-forward arg t))
 919
 920 (defvar gnus-nastygram-message
 921   "The following article was inappropriately posted to %s.\n\n"
 922   "Format string to insert in nastygrams.
 923 The current group name will be inserted at \"%s\".")
 924
 925 (defun gnus-summary-mail-nastygram (n)
 926   "Send a nastygram to the author of the current article."
 927   (interactive "P")
 928   (when (or gnus-expert-user
 929             (gnus-y-or-n-p
 930              "Really send a nastygram to the author of the current article? "))
 931     (let ((group gnus-newsgroup-name))
 932       (gnus-summary-reply-with-original n)
 933       (set-buffer gnus-message-buffer)
 934       (message-goto-body)
 935       (insert (format gnus-nastygram-message group))
 936       (message-send-and-exit))))
 937
 938 (defun gnus-summary-mail-crosspost-complaint (n)
 939   "Send a complaint about crossposting to the current article(s)."
 940   (interactive "P")
 941   (let ((articles (gnus-summary-work-articles n))
 942         article)
 943     (while (setq article (pop articles))
 944       (set-buffer gnus-summary-buffer)
 945       (gnus-summary-goto-subject article)
 946       (let ((group (gnus-group-real-name gnus-newsgroup-name))
 947             newsgroups followup-to)
 948         (gnus-summary-select-article)
 949         (set-buffer gnus-original-article-buffer)
 950         (if (and (<= (length (message-tokenize-header
 951                               (setq newsgroups
 952                                     (mail-fetch-field "newsgroups"))
 953                               ", "))
 954                      1)
 955                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
 956                      (not (member group (message-tokenize-header
 957                                          followup-to ", ")))))
 958             (if followup-to
 959                 (gnus-message 1 "Followup-to restricted")
 960               (gnus-message 1 "Not a crossposted article"))
 961           (set-buffer gnus-summary-buffer)
 962           (gnus-summary-reply-with-original 1)
 963           (set-buffer gnus-message-buffer)
 964           (message-goto-body)
 965           (insert (format gnus-crosspost-complaint newsgroups group))
 966           (message-goto-subject)
 967           (re-search-forward " *$")
 968           (replace-match " (crosspost notification)" t t)
 969           (gnus-deactivate-mark)
 970           (when (gnus-y-or-n-p "Send this complaint? ")
 971             (message-send-and-exit)))))))
 972
 973 (defun gnus-summary-mail-other-window ()
 974   "Compose mail in other window."
 975   (interactive)
 976   (gnus-setup-message 'message
 977     (message-mail)))
 978
 979 (defun gnus-mail-parse-comma-list ()
 980   (let (accumulated
 981         beg)
 982     (skip-chars-forward " ")
 983     (while (not (eobp))
 984       (setq beg (point))
 985       (skip-chars-forward "^,")
 986       (while (zerop
 987               (save-excursion
 988                 (save-restriction
 989                   (let ((i 0))
 990                     (narrow-to-region beg (point))
 991                     (goto-char beg)
 992                     (logand (progn
 993                               (while (search-forward "\"" nil t)
 994                                 (incf i))
 995                               (if (zerop i) 2 i))
 996                             2)))))
 997         (skip-chars-forward ",")
 998         (skip-chars-forward "^,"))
 999       (skip-chars-backward " ")
1000       (push (buffer-substring beg (point))
1001             accumulated)
1002       (skip-chars-forward "^,")
1003       (skip-chars-forward ", "))
1004     accumulated))
1005
1006 (defun gnus-inews-add-to-address (group)
1007   (let ((to-address (mail-fetch-field "to")))
1008     (when (and to-address
1009                (gnus-alive-p))
1010       ;; This mail group doesn't have a `to-list', so we add one
1011       ;; here.  Magic!
1012       (when (gnus-y-or-n-p
1013              (format "Do you want to add this as `to-list': %s " to-address))
1014         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1015
1016 (defun gnus-put-message ()
1017   "Put the current message in some group and return to Gnus."
1018   (interactive)
1019   (let ((reply gnus-article-reply)
1020         (winconf gnus-prev-winconf)
1021         (group gnus-newsgroup-name))
1022     (unless (and group
1023                  (not (gnus-group-read-only-p group)))
1024       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1025
1026     (when (gnus-gethash group gnus-newsrc-hashtb)
1027       (error "No such group: %s" group))
1028     (save-excursion
1029       (save-restriction
1030         (widen)
1031         (message-narrow-to-headers)
1032         (let ((gnus-deletable-headers nil))
1033           (message-generate-headers
1034            (if (message-news-p)
1035                message-required-news-headers
1036              message-required-mail-headers)))
1037         (goto-char (point-max))
1038         (insert "Gcc: " group "\n")
1039         (widen)))
1040     (gnus-inews-do-gcc)
1041     (when (and (get-buffer gnus-group-buffer)
1042                (gnus-buffer-exists-p (car-safe reply))
1043                (cdr reply))
1044       (set-buffer (car reply))
1045       (gnus-summary-mark-article-as-replied (cdr reply)))
1046     (when winconf
1047       (set-window-configuration winconf))))
1048
1049 (defun gnus-article-mail (yank)
1050   "Send a reply to the address near point.
1051 If YANK is non-nil, include the original article."
1052   (interactive "P")
1053   (let ((address
1054          (buffer-substring
1055           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1056           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1057     (when address
1058       (message-reply address)
1059       (when yank
1060         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1061
1062 (defvar nntp-server-type)
1063 (defun gnus-bug ()
1064   "Send a bug report to the Gnus maintainers."
1065   (interactive)
1066   (unless (gnus-alive-p)
1067     (error "Gnus has been shut down"))
1068   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1069     (unless (message-mail-user-agent)
1070       (delete-other-windows)
1071       (when gnus-bug-create-help-buffer
1072         (switch-to-buffer "*Gnus Help Bug*")
1073         (erase-buffer)
1074         (insert gnus-bug-message)
1075         (goto-char (point-min)))
1076       (message-pop-to-buffer "*Gnus Bug*"))
1077     (let ((message-this-is-mail t))
1078       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1079     (when gnus-bug-create-help-buffer
1080       (push `(gnus-bug-kill-buffer) message-send-actions))
1081     (goto-char (point-min))
1082     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1083     (forward-line 1)
1084     (insert (gnus-version) "\n"
1085             (emacs-version) "\n")
1086     (when (and (boundp 'nntp-server-type)
1087                (stringp nntp-server-type))
1088       (insert nntp-server-type))
1089     (insert "\n\n\n\n\n")
1090     (let (text)
1091       (save-excursion
1092         (set-buffer (gnus-get-buffer-create " *gnus environment info*"))
1093         (erase-buffer)
1094         (gnus-debug)
1095         (setq text (buffer-string)))
1096       (insert "<#part type=application/x-emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
1097     (goto-char (point-min))
1098     (search-forward "Subject: " nil t)
1099     (message "")))
1100
1101 (defun gnus-bug-kill-buffer ()
1102   (when (get-buffer "*Gnus Help Bug*")
1103     (kill-buffer "*Gnus Help Bug*")))
1104
1105 (defun gnus-summary-yank-message (buffer n)
1106   "Yank the current article into a composed message."
1107   (interactive
1108    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
1109          current-prefix-arg))
1110   (gnus-summary-iterate n
1111     (let ((gnus-display-mime-function nil)
1112           (gnus-inhibit-treatment t))
1113       (gnus-summary-select-article))
1114     (save-excursion
1115       (set-buffer buffer)
1116       (message-yank-buffer gnus-article-buffer))))
1117
1118 (defun gnus-debug ()
1119   "Attempts to go through the Gnus source file and report what variables have been changed.
1120 The source file has to be in the Emacs load path."
1121   (interactive)
1122   (let ((files '("gnus.el" "gnus-sum.el" "gnus-group.el"
1123                  "gnus-art.el" "gnus-start.el" "gnus-async.el"
1124                  "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
1125                  "nnmail.el" "message.el"))
1126         (point (point))
1127         file expr olist sym)
1128     (gnus-message 4 "Please wait while we snoop your variables...")
1129     (sit-for 0)
1130     ;; Go through all the files looking for non-default values for variables.
1131     (save-excursion
1132       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
1133       (while files
1134         (erase-buffer)
1135         (when (and (setq file (locate-library (pop files)))
1136                    (file-exists-p file))
1137           (insert-file-contents file)
1138           (goto-char (point-min))
1139           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1140               (gnus-message 4 "Malformed sources in file %s" file)
1141             (narrow-to-region (point-min) (point))
1142             (goto-char (point-min))
1143             (while (setq expr (ignore-errors (read (current-buffer))))
1144               (ignore-errors
1145                 (and (or (eq (car expr) 'defvar)
1146                          (eq (car expr) 'defcustom))
1147                      (stringp (nth 3 expr))
1148                      (or (not (boundp (nth 1 expr)))
1149                          (not (equal (eval (nth 2 expr))
1150                                      (symbol-value (nth 1 expr)))))
1151                      (push (nth 1 expr) olist)))))))
1152       (kill-buffer (current-buffer)))
1153     (when (setq olist (nreverse olist))
1154       (insert "------------------ Environment follows ------------------\n\n"))
1155     (while olist
1156       (if (boundp (car olist))
1157           (condition-case ()
1158               (pp `(setq ,(car olist)
1159                          ,(if (or (consp (setq sym (symbol-value (car olist))))
1160                                   (and (symbolp sym)
1161                                        (not (or (eq sym nil)
1162                                                 (eq sym t)))))
1163                               (list 'quote (symbol-value (car olist)))
1164                             (symbol-value (car olist))))
1165                   (current-buffer))
1166             (error
1167              (format "(setq %s 'whatever)\n" (car olist))))
1168         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1169       (setq olist (cdr olist)))
1170     (insert "\n\n")
1171     ;; Remove any control chars - they seem to cause trouble for some
1172     ;; mailers.  (Byte-compiled output from the stuff above.)
1173     (goto-char point)
1174     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
1175       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1176                      t t))))
1177
1178 ;;; Treatment of rejected articles.
1179 ;;; Bounced mail.
1180
1181 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1182   "Re-mail the current message.
1183 This only makes sense if the current message is a bounce message than
1184 contains some mail you have written which has been bounced back to
1185 you.
1186 If FETCH, try to fetch the article that this is a reply to, if indeed
1187 this is a reply."
1188   (interactive "P")
1189   (gnus-summary-select-article t)
1190   (set-buffer gnus-original-article-buffer)
1191   (gnus-setup-message 'compose-bounce
1192     (let* ((references (mail-fetch-field "references"))
1193            (parent (and references (gnus-parent-id references))))
1194       (message-bounce)
1195       ;; If there are references, we fetch the article we answered to.
1196       (and fetch parent
1197            (gnus-summary-refer-article parent)
1198            (gnus-summary-show-all-headers)))))
1199
1200 ;;; Gcc handling.
1201
1202 (defun gnus-inews-group-method (group)
1203   (cond
1204    ;; If the group doesn't exist, we assume
1205    ;; it's an archive group...
1206    ((and (null (gnus-get-info group))
1207          (eq (car (gnus-server-to-method gnus-message-archive-method))
1208              (car (gnus-server-to-method (gnus-group-method group)))))
1209     gnus-message-archive-method)
1210    ;; Use the method.
1211    ((gnus-info-method (gnus-get-info group))
1212     (gnus-info-method (gnus-get-info group)))
1213    ;; Find the method.
1214    (t (gnus-server-to-method (gnus-group-method group)))))
1215
1216 ;; Do Gcc handling, which copied the message over to some group.
1217 (defun gnus-inews-do-gcc (&optional gcc)
1218   (interactive)
1219   (save-excursion
1220     (save-restriction
1221       (message-narrow-to-headers)
1222       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1223             (cur (current-buffer))
1224             groups group method group-art)
1225         (when gcc
1226           (message-remove-header "gcc")
1227           (widen)
1228           (setq groups (message-unquote-tokens
1229                         (message-tokenize-header gcc " ,")))
1230           ;; Copy the article over to some group(s).
1231           (while (setq group (pop groups))
1232             (unless (gnus-check-server
1233                      (setq method (gnus-inews-group-method group)))
1234               (error "Can't open server %s" (if (stringp method) method
1235                                               (car method))))
1236             (unless (gnus-request-group group nil method)
1237               (gnus-request-create-group group method))
1238             (save-excursion
1239               (nnheader-set-temp-buffer " *acc*")
1240               (insert-buffer-substring cur)
1241               (message-encode-message-body)
1242               (save-restriction
1243                 (message-narrow-to-headers)
1244                 (let* ((mail-parse-charset message-default-charset)
1245                        (newsgroups-field (save-restriction
1246                                            (message-narrow-to-headers-or-head)
1247                                            (message-fetch-field "Newsgroups")))
1248                        (followup-field (save-restriction
1249                                          (message-narrow-to-headers-or-head)
1250                                          (message-fetch-field "Followup-To")))
1251                        ;; BUG: We really need to get the charset for
1252                        ;; each name in the Newsgroups and Followup-To
1253                        ;; lines to allow crossposting between group
1254                        ;; namess with incompatible character sets.
1255                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1256                        (group-field-charset
1257                         (gnus-group-name-charset method newsgroups-field))
1258                        (followup-field-charset
1259                         (gnus-group-name-charset method (or followup-field "")))
1260                        (rfc2047-header-encoding-alist
1261                         (append
1262                          (when group-field-charset
1263                            (list (cons "Newsgroups" group-field-charset)))
1264                          (when followup-field-charset
1265                            (list (cons "Followup-To" followup-field-charset)))
1266                          rfc2047-header-encoding-alist)))
1267                   (mail-encode-encoded-word-buffer)))
1268               (goto-char (point-min))
1269               (when (re-search-forward
1270                      (concat "^" (regexp-quote mail-header-separator) "$")
1271                      nil t)
1272                 (replace-match "" t t ))
1273               (unless (setq group-art
1274                             (gnus-request-accept-article group method t t))
1275                 (gnus-message 1 "Couldn't store article in group %s: %s"
1276                               group (gnus-status-message method))
1277                 (sit-for 2))
1278               (when (and group-art gnus-inews-mark-gcc-as-read)
1279                 (gnus-group-mark-article-read group (cdr group-art)))
1280               (kill-buffer (current-buffer)))))))))
1281
1282 (defun gnus-inews-insert-gcc ()
1283   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1284   (save-excursion
1285     (save-restriction
1286       (message-narrow-to-headers)
1287       (let* ((group gnus-outgoing-message-group)
1288              (gcc (cond
1289                    ((gnus-functionp group)
1290                     (funcall group))
1291                    ((or (stringp group) (list group))
1292                     group))))
1293         (when gcc
1294           (insert "Gcc: "
1295                   (if (stringp gcc) gcc
1296                     (mapconcat 'identity gcc " "))
1297                   "\n"))))))
1298
1299 (defun gnus-inews-insert-archive-gcc (&optional group)
1300   "Insert the Gcc to say where the article is to be archived."
1301   (let* ((var gnus-message-archive-group)
1302          (group (or group gnus-newsgroup-name ""))
1303          (gcc-self-val
1304           (and gnus-newsgroup-name
1305                (not (equal gnus-newsgroup-name ""))
1306                (gnus-group-find-parameter
1307                 gnus-newsgroup-name 'gcc-self)))
1308          result
1309          (groups
1310           (cond
1311            ((null gnus-message-archive-method)
1312             ;; Ignore.
1313             nil)
1314            ((stringp var)
1315             ;; Just a single group.
1316             (list var))
1317            ((null var)
1318             ;; We don't want this.
1319             nil)
1320            ((and (listp var) (stringp (car var)))
1321             ;; A list of groups.
1322             var)
1323            ((gnus-functionp var)
1324             ;; A function.
1325             (funcall var group))
1326            (t
1327             ;; An alist of regexps/functions/forms.
1328             (while (and var
1329                         (not
1330                          (setq result
1331                                (cond
1332                                 ((stringp (caar var))
1333                                  ;; Regexp.
1334                                  (when (string-match (caar var) group)
1335                                    (cdar var)))
1336                                 ((gnus-functionp (car var))
1337                                  ;; Function.
1338                                  (funcall (car var) group))
1339                                 (t
1340                                  (eval (car var)))))))
1341               (setq var (cdr var)))
1342             result)))
1343          name)
1344     (when (or groups gcc-self-val)
1345       (when (stringp groups)
1346         (setq groups (list groups)))
1347       (save-excursion
1348         (save-restriction
1349           (message-narrow-to-headers)
1350           (goto-char (point-max))
1351           (insert "Gcc: ")
1352           (if gcc-self-val
1353               ;; Use the `gcc-self' param value instead.
1354               (progn
1355                 (insert
1356                  (if (stringp gcc-self-val)
1357                      gcc-self-val
1358                    group))
1359                 (if (not (eq gcc-self-val 'none))
1360                     (insert "\n")
1361                   (progn
1362                     (beginning-of-line)
1363                     (kill-line))))
1364             ;; Use the list of groups.
1365             (while (setq name (pop groups))
1366               (insert (if (string-match ":" name)
1367                           name
1368                         (gnus-group-prefixed-name
1369                          name gnus-message-archive-method)))
1370               (when groups
1371                 (insert " ")))
1372             (insert "\n")))))))
1373
1374 ;;; Posting styles.
1375
1376 (defun gnus-configure-posting-styles ()
1377   "Configure posting styles according to `gnus-posting-styles'."
1378   (unless gnus-inhibit-posting-styles
1379     (let ((group (or gnus-newsgroup-name ""))
1380           (styles gnus-posting-styles)
1381           style match variable attribute value v results
1382           filep name address element)
1383       ;; If the group has a posting-style parameter, add it at the end with a
1384       ;; regexp matching everything, to be sure it takes precedence over all
1385       ;; the others.
1386       (when gnus-newsgroup-name
1387         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1388           (when tmp-style
1389             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1390       ;; Go through all styles and look for matches.
1391       (dolist (style styles)
1392         (setq match (pop style))
1393         (goto-char (point-min))
1394         (when (cond
1395                ((stringp match)
1396                 ;; Regexp string match on the group name.
1397                 (string-match match group))
1398                ((eq match 'header)
1399                 (and (gnus-buffer-live-p gnus-article-copy)
1400                      (with-current-buffer gnus-article-copy
1401                        (let ((header (message-fetch-field (pop style))))
1402                          (and header
1403                               (string-match (pop style) header))))))
1404                ((or (symbolp match)
1405                     (gnus-functionp match))
1406                 (cond
1407                  ((gnus-functionp match)
1408                   ;; Function to be called.
1409                   (funcall match))
1410                  ((boundp match)
1411                   ;; Variable to be checked.
1412                   (symbol-value match))))
1413                ((listp match)
1414                 ;; This is a form to be evaled.
1415                 (eval match)))
1416           ;; We have a match, so we set the variables.
1417           (dolist (attribute style)
1418             (setq element (pop attribute)
1419                   variable nil
1420                   filep nil)
1421             (setq value
1422                   (cond
1423                    ((eq (car attribute) :file)
1424                     (setq filep t)
1425                     (cadr attribute))
1426                    ((eq (car attribute) :value)
1427                     (cadr attribute))
1428                    (t
1429                     (car attribute))))
1430             ;; We get the value.
1431             (setq v
1432                   (cond
1433                    ((stringp value)
1434                     value)
1435                    ((or (symbolp value)
1436                         (gnus-functionp value))
1437                     (cond ((gnus-functionp value)
1438                            (funcall value))
1439                           ((boundp value)
1440                            (symbol-value value))))
1441                    ((listp value)
1442                     (eval value))))
1443             ;; Translate obsolescent value.
1444             (when (eq element 'signature-file)
1445               (setq element 'signature
1446                     filep t))
1447             ;; Get the contents of file elems.
1448             (when (and filep v)
1449               (setq v (with-temp-buffer
1450                         (insert-file-contents v)
1451                         (buffer-string))))
1452             (setq results (delq (assoc element results) results))
1453             (push (cons element v) results))))
1454       ;; Now we have all the styles, so we insert them.
1455       (setq name (assq 'name results)
1456             address (assq 'address results))
1457       (setq results (delq name (delq address results)))
1458       (make-local-variable 'message-setup-hook)
1459       (dolist (result results)
1460         (add-hook 'message-setup-hook
1461                   (cond
1462                    ((eq 'eval (car result))
1463                     'ignore)
1464                    ((eq 'body (car result))
1465                     `(lambda ()
1466                        (save-excursion
1467                          (message-goto-body)
1468                          (insert ,(cdr result)))))
1469                    ((eq 'signature (car result))
1470                     (set (make-local-variable 'message-signature) nil)
1471                     (set (make-local-variable 'message-signature-file) nil)
1472                     (if (not (cdr result))
1473                         'ignore
1474                       `(lambda ()
1475                          (save-excursion
1476                            (let ((message-signature ,(cdr result)))
1477                              (when message-signature
1478                                (message-insert-signature)))))))
1479                    (t
1480                     (let ((header
1481                            (if (symbolp (car result))
1482                                (capitalize (symbol-name (car result)))
1483                              (car result))))
1484                       `(lambda ()
1485                          (save-excursion
1486                            (message-remove-header ,header)
1487                            (let ((value ,(cdr result)))
1488                              (when value
1489                                (message-goto-eoh)
1490                                (insert ,header ": " value "\n"))))))))))
1491       (when (or name address)
1492         (add-hook 'message-setup-hook
1493                   `(lambda ()
1494                      (set (make-local-variable 'user-mail-address)
1495                           ,(or (cdr address) user-mail-address))
1496                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1497                            (user-mail-address
1498                             ,(or (cdr address) user-mail-address)))
1499                        (save-excursion
1500                          (message-remove-header "From")
1501                          (message-goto-eoh)
1502                          (insert "From: " (message-make-from) "\n")))))))))
1503
1504 ;;; Allow redefinition of functions.
1505
1506 (gnus-ems-redefine)
1507
1508 (provide 'gnus-msg)
1509
1510 ;;; gnus-msg.el ends here