cgit.sxemacs.org Git - gnus/blob - lisp/gnus-html.el

   1 ;;; gnus-html.el --- Quoted-Printable functions
   2
   3 ;; Copyright (C) 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html, web
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; The idea is to provide a simple, fast and pretty minimal way to
  26 ;; render HTML (including links and images) in a buffer, based on an
  27 ;; external HTML renderer (i.e., w3m).
  28
  29 ;;; Code:
  30
  31 (defcustom gnus-html-cache-directory (nnheader-concat gnus-directory "html-cache/")
  32   "Where Gnus will cache images it downloads from the web."
  33   :group 'gnus-art
  34   :type 'directory)
  35
  36 (defcustom gnus-html-cache-size 500000000
  37   "The size of the Gnus image cache."
  38   :group 'gnus-art
  39   :type 'integer)
  40
  41 (defcustom gnus-html-frame-width 70
  42   "What width to use when rendering HTML."
  43   :group 'gnus-art
  44   :type 'integer)
  45
  46 ;;;###autoload
  47 (defun gnus-article-html (handle)
  48   (let ((article-buffer (current-buffer)))
  49     (save-restriction
  50       (narrow-to-region (point) (point))
  51       (save-excursion
  52         (set-buffer (car handle))
  53         (call-process-region (point-min) (point-max)
  54                              "w3m"
  55                              nil article-buffer nil
  56                              "-halfdump"
  57                              "-t" (format "%s" tab-width)
  58                              "-cols" (format "%s" gnus-html-frame-width)
  59                              "-o" "display_image=off"
  60                              "-T" "text/html"))
  61       (gnus-html-wash-tags))))
  62
  63 (defun gnus-html-wash-tags ()
  64   (let (tag parameters string start end images)
  65     (mm-url-decode-entities)
  66     (goto-char (point-min))
  67     (while (re-search-forward "<\\([^ />]+\\)\\([^>]*\\)>" nil t)
  68       (setq tag (match-string 1)
  69             parameters (match-string 2)
  70             start (match-beginning 0))
  71       (delete-region start (point))
  72       (when (search-forward (concat "</" tag ">"))
  73         (delete-region (match-beginning 0) (match-end 0)))
  74       (setq end (point))
  75       (cond
  76        ;; Fetch and insert a picture.
  77        ((equal tag "img_alt")
  78         (when (string-match "src=\"\\([^\"]+\\)" parameters)
  79           (setq parameters (match-string 1 parameters))
  80           (when (or (null mm-w3m-safe-url-regexp)
  81                     (string-match mm-w3m-safe-url-regexp parameters))
  82             (let ((file (gnus-html-image-id parameters)))
  83               (if (file-exists-p file)
  84                   ;; It's already cached, so just insert it.
  85                   (progn
  86                     (put-image (create-image file) (point))
  87                     ;; Delete the ALT text.
  88                     (delete-region start end))
  89                 ;; We don't have it, so schedule it for fetching
  90                 ;; asynchronously.
  91                 (push (list parameters
  92                             (set-marker (make-marker) start)
  93                             (point-marker))
  94                       images))))))
  95        ;; Add a link.
  96        ((equal tag "a")
  97         (when (string-match "href=\"\\([^\"]+\\)" parameters)
  98           (setq parameters (match-string 1 parameters))
  99           (gnus-article-add-button start end
 100                                    'browse-url parameters)
 101           (let ((overlay (gnus-make-overlay start end)))
 102             (gnus-overlay-put overlay 'evaporate t)
 103             (gnus-overlay-put overlay 'gnus-button-url parameters)
 104             (when gnus-article-mouse-face
 105               (gnus-overlay-put overlay 'mouse-face gnus-article-mouse-face)))))
 106        ;; Whatever.  Just ignore the tag.
 107        (t
 108         ))
 109       (goto-char start))
 110     ;; Delete any excessive space at the start.
 111     (goto-char (point-min))
 112     (when (and (re-search-forward "[^ \t\n]" nil t)
 113                (> (match-beginning 0) (point-min)))
 114       (delete-region (point-min) (1- (match-beginning 0))))
 115     (when images
 116       (gnus-html-schedule-image-fetching (current-buffer) (nreverse images)))))
 117
 118 (defun gnus-html-schedule-image-fetching (buffer images)
 119   (let* ((url (caar images))
 120          (process (start-process
 121                    "images" nil "curl"
 122                    "-s" "--create-dirs"
 123                    "-o" (gnus-html-image-id url)
 124                    url)))
 125     (set-process-sentinel process 'gnus-html-curl-sentinel)
 126     (set-process-plist process (list 'images images
 127                                      'buffer buffer))))
 128
 129 (defun gnus-html-image-id (url)
 130   (expand-file-name (sha1 url) gnus-html-cache-directory))
 131
 132 (defun gnus-html-curl-sentinel (process event)
 133   (when (string-match "finished" event)
 134     (let* ((images (getf (process-plist process) 'images))
 135            (buffer (getf (process-plist process) 'buffer))
 136            (spec (pop images))
 137            (file (gnus-html-image-id (car spec))))
 138       (when (file-exists-p file)
 139         (save-excursion
 140           (set-buffer buffer)
 141           (let ((buffer-read-only nil))
 142             (delete-region (cadr spec) (caddr spec))
 143             (put-image (create-image file) (cadr spec)))))
 144       (when images
 145         (gnus-html-schedule-image-fetching buffer images)))))
 146
 147 (defun gnus-html-prune-cache ()
 148   (let ((total-size 0)
 149         files)
 150     (dolist (file (directory-files gnus-html-cache-directory t nil t))
 151       (let ((attributes (file-attributes file)))
 152         (unless (nth 0 attributes)
 153           (incf total-size (nth 7 attributes))
 154           (push (list (time-to-seconds (nth 5 attributes))
 155                       (nth 7 attributes) file)
 156                 files))))
 157     (when (> total-size gnus-html-cache-size)
 158       (setq files (sort files (lambda (f1 f2)
 159                                 (< (car f1) (car f2)))))
 160       (dolist (file files)
 161         (when (> total-size gnus-html-cache-size)
 162           (decf total-size (cadr file))
 163           (delete-file (nth 2 file)))))))
 164
 165 ;;; gnus-html.el ends here