cgit.sxemacs.org Git - gnus/blob - lisp/gnus-fun.el

   1 ;;; gnus-fun.el --- various frivoluos extension functions to Gnus
   2 ;; Copyright (C) 2002 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (defcustom gnus-x-face-directory (expand-file-name "x-faces" gnus-directory)
  29   "*Directory where X-Face PBM files are stored."
  30   :group 'gnus-fun
  31   :type 'directory)
  32
  33 (defcustom gnus-convert-pbm-to-x-face-command "pbmtoxbm %s | compface"
  34   "Command for converting a PBM to an X-Face."
  35   :group 'gnus-fun
  36   :type 'string)
  37
  38 (defcustom gnus-convert-image-to-x-face-command "giftopnm %s | ppmnorm | pnmscale -width 48 -height 48 | ppmtopgm | pgmtopbm | pbmtoxbm | compface"
  39   "Command for converting a GIF to an X-Face."
  40   :group 'gnus-fun
  41   :type 'string)
  42
  43 (defcustom gnus-convert-image-to-face-command "djpeg %s | ppmnorm | pnmscale -width 48 -height 48 | ppmquant %d | pnmtopng"
  44   "Command for converting a GIF to an X-Face."
  45   :group 'gnus-fun
  46   :type 'string)
  47
  48 (defun gnus-shell-command-to-string (command)
  49   "Like `shell-command-to-string' except not mingling ERROR."
  50   (with-output-to-string
  51     (call-process shell-file-name nil (list standard-output nil)
  52                   nil shell-command-switch command)))
  53
  54 (defun gnus-shell-command-on-region (start end command)
  55   "A simplified `shell-command-on-region'.
  56 Output to the current buffer, replace text, and don't mingle error."
  57   (call-process-region start end shell-file-name t
  58                        (list (current-buffer) nil)
  59                        nil shell-command-switch command))
  60
  61 ;;;###autoload
  62 (defun gnus-random-x-face ()
  63   "Insert a random X-Face header from `gnus-x-face-directory'."
  64   (interactive)
  65   (when (file-exists-p gnus-x-face-directory)
  66     (let* ((files (directory-files gnus-x-face-directory t "\\.pbm$"))
  67            (file (nth (random (length files)) files)))
  68       (when file
  69         (gnus-shell-command-to-string
  70          (format gnus-convert-pbm-to-x-face-command
  71                  (shell-quote-argument file)))))))
  72
  73 ;;;###autoload
  74 (defun gnus-x-face-from-file (file)
  75   "Insert an X-Face header based on an image file."
  76   (interactive "fImage file name:" )
  77   (when (file-exists-p file)
  78     (gnus-shell-command-to-string
  79      (format gnus-convert-image-to-x-face-command
  80              (shell-quote-argument file)))))
  81
  82 (defun gnus-face-from-file (file)
  83   "Return an Face header based on an image file."
  84   (interactive "fImage file name:" )
  85   (when (file-exists-p file)
  86     (let ((done nil)
  87           (attempt "")
  88           (quant 4))
  89       (while (and (not done)
  90                   (> quant 1))
  91         (setq attempt
  92               (gnus-shell-command-to-string
  93                (format gnus-convert-image-to-face-command
  94                        (shell-quote-argument file)
  95                        quant)))
  96         (if (> (length attempt) 740)
  97             (setq quant (/ quant 2))
  98           (setq done t)))
  99       (if done
 100           (mm-with-unibyte-buffer
 101             (insert attempt)
 102             (base64-encode-region (point-min) (point-max))
 103             (goto-char (point-min))
 104             (forward-line 1)
 105             (while (not (eobp))
 106               (insert " ")
 107               (forward-line 1))
 108             (buffer-string))
 109         nil))))
 110
 111 (defun gnus-convert-image-to-gray-x-face (file depth)
 112   (let* ((mapfile (mm-make-temp-file (expand-file-name "gnus."
 113                                                        mm-tmp-directory)))
 114          (levels (expt 2 depth))
 115          (step (/ 255 (1- levels)))
 116          color-alist bits bits-list mask pixel x-faces)
 117     (with-temp-file mapfile
 118       (insert "P3\n")
 119       (insert (format "%d 1\n" levels))
 120       (insert "255\n")
 121       (dotimes (i levels)
 122         (insert (format "%d %d %d\n"
 123                         (* step i) (* step i) (* step i)))
 124         (push (cons (* step i) i) color-alist)))
 125     (when (file-exists-p file)
 126       (with-temp-buffer
 127         (insert (gnus-shell-command-to-string
 128                  (format "giftopnm %s | ppmnorm | pnmscale -width 48 -height 48 | ppmquant -fs -map %s | ppmtopgm | pnmnoraw"
 129                          (shell-quote-argument file)
 130                          mapfile)))
 131         (goto-char (point-min))
 132         (forward-line 3)
 133         (while (setq pixel (ignore-errors (read (current-buffer))))
 134           (push (cdr (assq pixel color-alist)) bits-list))
 135         (setq bits-list (nreverse bits-list))
 136         (dotimes (bit-number depth)
 137           (setq mask (expt 2 bit-number))
 138           (with-temp-buffer
 139             (insert "P1\n48 48\n")
 140             (dolist (bits bits-list)
 141               (insert (if (zerop (logand bits mask)) "0 " "1 ")))
 142             (gnus-shell-command-on-region
 143              (point-min) (point-max)
 144              ;; the following is taken from xbmtoikon:
 145              "pbmtoicon | sed '/^[      ]*[*\\\\/]/d; s/[       ]//g; s/,$//' | tr , '\\012' | sed 's/^0x//; s/^/0x/' | pr -l1 -t -w22 -3 -s, | sed 's/,*$/,/' | compface")
 146             (push (buffer-string) x-faces))))
 147       (dotimes (i (length x-faces))
 148         (insert (if (zerop i) "X-Face:" (format "X-Face-%s:" i))
 149                 (nth i x-faces))))
 150     (delete-file mapfile)))
 151
 152 ;;;###autoload
 153 (defun gnus-convert-gray-x-face-to-xpm (faces)
 154   (let* ((depth (length faces))
 155          (scale (/ 255 (1- (expt 2 depth))))
 156          (ok-p t)
 157          (coding-system-for-read 'binary)
 158          (coding-system-for-write 'binary)
 159          default-enable-multibyte-characters
 160          start bit-array bit-arrays pixel)
 161     (with-temp-buffer
 162       (dolist (face faces)
 163         (erase-buffer)
 164         (insert (uncompface face))
 165         (gnus-shell-command-on-region
 166          (point-min) (point-max)
 167          "pnmnoraw")
 168         (goto-char (point-min))
 169         (forward-line 2)
 170         (setq start (point))
 171         (insert "[")
 172         (while (not (eobp))
 173           (forward-char 1)
 174           (insert " "))
 175         (insert "]")
 176         (goto-char start)
 177         (setq bit-array (read (current-buffer)))
 178         (unless (= (length bit-array) (* 48 48))
 179           (setq ok-p nil))
 180         (push bit-array bit-arrays))
 181       (when ok-p
 182         (erase-buffer)
 183         (insert "P2\n48 48\n255\n")
 184         (dotimes (i (* 48 48))
 185           (setq pixel 0)
 186           (dotimes (plane depth)
 187             (setq pixel (+ (* pixel 2) (aref (nth plane bit-arrays) i))))
 188           (insert (number-to-string (* scale pixel)) " "))
 189         (gnus-shell-command-on-region
 190          (point-min) (point-max)
 191          "ppmtoxpm")
 192         (buffer-string)))))
 193
 194 ;;;###autoload
 195 (defun gnus-convert-gray-x-face-region (beg end)
 196   "Convert the X-Faces in region to a PPM file."
 197   (interactive "r")
 198   (let ((input (buffer-substring beg end))
 199         faces)
 200     (with-temp-buffer
 201       (insert input)
 202       (goto-char (point-min))
 203       (while (not (eobp))
 204         (save-restriction
 205           (mail-header-narrow-to-field)
 206           (push (mail-header-field-value) faces)
 207           (goto-char (point-max)))))
 208     (gnus-convert-gray-x-face-to-xpm faces)))
 209
 210 (defface gnus-x-face '((t (:foreground "black" :background "white")))
 211   "Face to show X-Face.
 212 The colors from this face are used as the foreground and background
 213 colors of the displayed X-Faces."
 214   :group 'gnus-article-headers)
 215
 216 (defun gnus-display-x-face-in-from (data)
 217   "Display the X-Face DATA in the From header."
 218   (let ((default-enable-multibyte-characters nil)
 219         pbm)
 220     (when (or (gnus-image-type-available-p 'xface)
 221               (and (gnus-image-type-available-p 'pbm)
 222                    (setq pbm (uncompface data))))
 223       (save-excursion
 224         (save-restriction
 225           (article-narrow-to-head)
 226           (gnus-article-goto-header "from")
 227           (when (bobp)
 228             (insert "From: [no `from' set]\n")
 229             (forward-char -17))
 230           (gnus-add-image
 231            'xface
 232            (gnus-put-image
 233             (if (gnus-image-type-available-p 'xface)
 234                 (gnus-create-image
 235                  (concat "X-Face: " data)
 236                  'xface t :ascent 'center :face 'gnus-x-face)
 237               (gnus-create-image
 238                pbm 'pbm t :ascent 'center :face 'gnus-x-face))))
 239           (gnus-add-wash-type 'xface))))))
 240
 241 (defun gnus-grab-cam-x-face ()
 242   "Grab a picture off the camera and make it into an X-Face."
 243   (interactive)
 244   (shell-command "xawtv-remote snap ppm")
 245   (let ((file nil))
 246     (while (null (setq file (directory-files "/tftpboot/sparky/tmp"
 247                                              t "snap.*ppm")))
 248       (sleep-for 1))
 249     (setq file (car file))
 250     (with-temp-buffer
 251       (shell-command
 252        (format "pnmcut -left 110 -top 30 -width 144 -height 144 '%s' | ppmnorm 2>/dev/null | pnmscale -width 48 | ppmtopgm | pgmtopbm -threshold -value 0.92 | pbmtoxbm | compface"
 253                file)
 254        (current-buffer))
 255       ;;(sleep-for 3)
 256       (delete-file file)
 257       (buffer-string))))
 258
 259 (defun gnus-grab-gray-x-face ()
 260   "Grab a picture off the camera and make it into an X-Face."
 261   (interactive)
 262   (shell-command "xawtv-remote snap ppm")
 263   (let ((file nil))
 264     (while (null (setq file (directory-files "/tftpboot/sparky/tmp"
 265                                              t "snap.*ppm")))
 266       (sleep-for 1))
 267     (setq file (car file))
 268     (with-temp-buffer
 269       (shell-command
 270        (format "pnmcut -left 70 -top 100 -width 144 -height 144 '%s' | ppmquant 256 2>/dev/null | ppmtogif > '%s.gif'"
 271                file file)
 272        (current-buffer))
 273       (delete-file file))
 274     (gnus-convert-image-to-gray-x-face (concat file ".gif") 3)
 275     (delete-file (concat file ".gif"))))
 276
 277 (provide 'gnus-fun)
 278
 279 ;;; gnus-fun.el ends here