cgit.sxemacs.org Git - gnus/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Gnus
   2
   3 ;; Copyright (C) 1997-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28 (require 'gnus-sum)
  29 (require 'message)
  30 (require 'gnus-msg)
  31 (require 'nndraft)
  32 (require 'gnus-agent)
  33 (eval-when-compile (require 'cl))
  34 (eval-when-compile
  35   (when (featurep 'xemacs)
  36     (require 'easy-mmode))) ; for `define-minor-mode'
  37
  38 ;;; Draft minor mode
  39
  40 (defvar gnus-draft-mode-map
  41   (let ((map (make-sparse-keymap)))
  42     (gnus-define-keys map
  43      "Dt" gnus-draft-toggle-sending
  44      "e"  gnus-draft-edit-message ;; Use `B w' for `gnus-summary-edit-article'
  45      "De" gnus-draft-edit-message
  46      "Ds" gnus-draft-send-message
  47      "DS" gnus-draft-send-all-messages)
  48     map))
  49
  50 (defun gnus-draft-make-menu-bar ()
  51   (unless (boundp 'gnus-draft-menu)
  52     (easy-menu-define
  53      gnus-draft-menu gnus-draft-mode-map ""
  54      '("Drafts"
  55        ["Toggle whether to send" gnus-draft-toggle-sending t]
  56        ["Edit" gnus-draft-edit-message t]
  57        ["Send selected message(s)" gnus-draft-send-message t]
  58        ["Send all messages" gnus-draft-send-all-messages t]
  59        ["Delete draft" gnus-summary-delete-article t]))))
  60
  61 (define-minor-mode gnus-draft-mode
  62   "Minor mode for providing a draft summary buffers.
  63
  64 \\{gnus-draft-mode-map}"
  65   :lighter " Draft" :keymap gnus-draft-mode-map
  66   (cond
  67    ((not (derived-mode-p 'gnus-summary-mode)) (setq gnus-draft-mode nil))
  68    (gnus-draft-mode
  69     ;; Set up the menu.
  70     (when (gnus-visual-p 'draft-menu 'menu)
  71       (gnus-draft-make-menu-bar)))))
  72
  73 ;;; Commands
  74
  75 (defun gnus-draft-toggle-sending (article)
  76   "Toggle whether to send an article or not."
  77   (interactive (list (gnus-summary-article-number)))
  78   (if (gnus-draft-article-sendable-p article)
  79       (progn
  80         (push article gnus-newsgroup-unsendable)
  81         (gnus-summary-mark-article article gnus-unsendable-mark))
  82     (setq gnus-newsgroup-unsendable
  83           (delq article gnus-newsgroup-unsendable))
  84     (gnus-summary-mark-article article gnus-unread-mark))
  85   (gnus-summary-position-point))
  86
  87 (defun gnus-draft-edit-message ()
  88   "Enter a mail/post buffer to edit and send the draft."
  89   (interactive)
  90   (let ((article (gnus-summary-article-number))
  91         (group gnus-newsgroup-name))
  92     (gnus-draft-check-draft-articles (list article))
  93     (gnus-summary-mark-as-read article gnus-canceled-mark)
  94     (gnus-draft-setup article group t)
  95     (set-buffer-modified-p t)
  96     (save-excursion
  97       (save-restriction
  98         (message-narrow-to-headers)
  99         (message-remove-header "date")))
 100     (let ((message-draft-headers
 101            (delq 'Date (copy-sequence message-draft-headers))))
 102       (save-buffer))
 103     (let ((gnus-verbose-backends nil))
 104       (gnus-request-expire-articles (list article) group t))
 105     (push
 106      `((lambda ()
 107          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 108            (save-excursion
 109              (set-buffer ,gnus-summary-buffer)
 110              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 111      message-send-actions)))
 112
 113 (defun gnus-draft-send-message (&optional n)
 114   "Send the current draft(s).
 115 Obeys the standard process/prefix convention."
 116   (interactive "P")
 117   (let* ((articles (gnus-summary-work-articles n))
 118          (total (length articles))
 119          article)
 120     (gnus-draft-check-draft-articles articles)
 121     (while (setq article (pop articles))
 122       (gnus-summary-remove-process-mark article)
 123       (unless (memq article gnus-newsgroup-unsendable)
 124         (let ((message-sending-message
 125                (format "Sending message %d of %d..."
 126                        (- total (length articles)) total)))
 127           (gnus-draft-send article gnus-newsgroup-name t))
 128         (gnus-summary-mark-article article gnus-canceled-mark)))))
 129
 130 (defun gnus-draft-send (article &optional group interactive)
 131   "Send message ARTICLE."
 132   (let* ((is-queue (or (not group)
 133                        (equal group "nndraft:queue")))
 134          (message-syntax-checks (if interactive message-syntax-checks
 135                                   'dont-check-for-anything-just-trust-me))
 136          (message-hidden-headers nil)
 137          (message-inhibit-body-encoding (or is-queue
 138                                             message-inhibit-body-encoding))
 139          (message-send-hook (and (not is-queue)
 140                                  message-send-hook))
 141          (message-setup-hook (and (not is-queue)
 142                                   message-setup-hook))
 143          (gnus-message-setup-hook (and (not is-queue)
 144                                        gnus-message-setup-hook))
 145          (message-signature (and (not is-queue)
 146                                  message-signature))
 147          (gnus-agent-queue-mail (and (not is-queue)
 148                                      gnus-agent-queue-mail))
 149          (rfc2047-encode-encoded-words nil)
 150          type method move-to)
 151     (gnus-draft-setup article (or group "nndraft:queue"))
 152     ;; We read the meta-information that says how and where
 153     ;; this message is to be sent.
 154     (save-restriction
 155       (message-narrow-to-headers)
 156       (when (re-search-forward
 157              (concat "^" (regexp-quote gnus-agent-target-move-group-header)
 158                      ":") nil t)
 159         (skip-syntax-forward "-")
 160         (setq move-to (buffer-substring (point) (point-at-eol)))
 161         (message-remove-header gnus-agent-target-move-group-header))
 162       (goto-char (point-min))
 163       (when (re-search-forward
 164              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 165              nil t)
 166         (setq type (ignore-errors (read (current-buffer)))
 167               method (ignore-errors (read (current-buffer))))
 168         (message-remove-header gnus-agent-meta-information-header)))
 169     ;; Let Agent restore any GCC lines and have message.el perform them.
 170     (gnus-agent-restore-gcc)
 171     ;; Then we send it.  If we have no meta-information, we just send
 172     ;; it and let Message figure out how.
 173     (when (and (or (null method)
 174                    (gnus-server-opened method)
 175                    (gnus-open-server method))
 176                (if type
 177                    (let ((message-this-is-news (eq type 'news))
 178                          (message-this-is-mail (eq type 'mail))
 179                          (gnus-post-method method)
 180                          (message-post-method method))
 181                      (if move-to
 182                          (gnus-inews-do-gcc move-to)
 183                        (message-send-and-exit)))
 184                  (if move-to
 185                      (gnus-inews-do-gcc move-to)
 186                    (message-send-and-exit))))
 187       (let ((gnus-verbose-backends nil))
 188         (gnus-request-expire-articles
 189          (list article) (or group "nndraft:queue") t)))))
 190
 191 (defun gnus-draft-send-all-messages ()
 192   "Send all the sendable drafts."
 193   (interactive)
 194   (when (or
 195          gnus-expert-user
 196          (gnus-y-or-n-p
 197           "Send all drafts? "))
 198     (gnus-uu-mark-buffer)
 199     (gnus-draft-send-message)))
 200
 201 (defun gnus-group-send-queue ()
 202   "Send all sendable articles from the queue group."
 203   (interactive)
 204   (when (or gnus-plugged
 205             (not gnus-agent-prompt-send-queue)
 206             (gnus-y-or-n-p "Gnus is unplugged; really send queue? "))
 207     (gnus-activate-group "nndraft:queue")
 208     (save-excursion
 209       (let* ((articles (nndraft-articles))
 210              (unsendable (gnus-uncompress-range
 211                           (cdr (assq 'unsend
 212                                      (gnus-info-marks
 213                                       (gnus-get-info "nndraft:queue"))))))
 214              (gnus-posting-styles nil)
 215              message-send-mail-partially-limit
 216              (total (length articles))
 217              article)
 218         (while (setq article (pop articles))
 219           (unless (memq article unsendable)
 220             (let ((message-sending-message
 221                    (format "Sending message %d of %d..."
 222                            (- total (length articles)) total)))
 223               (gnus-draft-send article))))))
 224     (gnus-group-refresh-group "nndraft:queue")))
 225
 226 ;;;###autoload
 227 (defun gnus-draft-reminder ()
 228   "Reminder user if there are unsent drafts."
 229   (interactive)
 230   (if (gnus-alive-p)
 231       (let (active)
 232         (catch 'continue
 233           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 234             (setq active (gnus-activate-group group))
 235             (if (and active (>= (cdr active) (car active)))
 236                 (if (y-or-n-p "There are unsent drafts.  Confirm to exit? ")
 237                     (throw 'continue t)
 238                   (error "Stop!"))))))))
 239
 240 (defcustom gnus-draft-setup-hook nil
 241   "Hook run after setting up a draft buffer."
 242   :group 'gnus-message
 243   :version "23.1" ;; No Gnus
 244   :type 'hook)
 245
 246 ;;; Utility functions
 247
 248 ;;;!!!If this is byte-compiled, it fails miserably.
 249 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 250 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 251 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 252
 253 (progn
 254   (defun gnus-draft-setup (narticle group &optional restore)
 255     (let (ga)
 256       (gnus-setup-message 'forward
 257         (let ((article narticle))
 258           (message-mail)
 259           (erase-buffer)
 260           (if (not (gnus-request-restore-buffer article group))
 261               (error "Couldn't restore the article")
 262             (when (and restore
 263                        (equal group "nndraft:queue"))
 264               (mime-to-mml))
 265             ;; Insert the separator.
 266             (goto-char (point-min))
 267             (search-forward "\n\n")
 268             (forward-char -1)
 269             (save-restriction
 270               (narrow-to-region (point-min) (point))
 271               (setq ga
 272                     (message-fetch-field gnus-draft-meta-information-header)))
 273             (insert mail-header-separator)
 274             (forward-line 1)
 275             (message-set-auto-save-file-name))))
 276       (gnus-backlog-remove-article group narticle)
 277       (when (and ga
 278                  (ignore-errors (setq ga (car (read-from-string ga)))))
 279         (setq gnus-newsgroup-name
 280               (if (equal (car ga) "") nil (car ga)))
 281         (gnus-configure-posting-styles)
 282         (setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
 283         (setq message-post-method
 284               `(lambda (arg)
 285                  (gnus-post-method arg ,(car ga))))
 286         (unless (equal (cadr ga) "")
 287           (dolist (article (cdr ga))
 288             (message-add-action
 289              `(progn
 290                 (gnus-add-mark ,(car ga) 'replied ,article)
 291                 (gnus-request-set-mark ,(car ga) (list (list (list ,article)
 292                                                              'add '(reply)))))
 293              'send))))
 294       (run-hooks 'gnus-draft-setup-hook))))
 295
 296 (defun gnus-draft-article-sendable-p (article)
 297   "Say whether ARTICLE is sendable."
 298   (not (memq article gnus-newsgroup-unsendable)))
 299
 300 (defun gnus-draft-check-draft-articles (articles)
 301   "Check whether the draft articles ARTICLES are under edit."
 302   (when (equal gnus-newsgroup-name "nndraft:drafts")
 303     (let ((buffers (buffer-list))
 304           file buffs buff)
 305       (save-current-buffer
 306         (while (and articles
 307                     (not buff))
 308           (setq file (nndraft-article-filename (pop articles))
 309                 buffs buffers)
 310           (while buffs
 311             (set-buffer (setq buff (pop buffs)))
 312             (if (and buffer-file-name
 313                      (equal (file-remote-p file)
 314                             (file-remote-p buffer-file-name))
 315                      (string-equal (file-truename buffer-file-name)
 316                                    (file-truename file))
 317                      (buffer-modified-p))
 318                 (setq buffs nil)
 319               (setq buff nil)))))
 320       (when buff
 321         (let* ((window (get-buffer-window buff t))
 322                (frame (and window (window-frame window))))
 323           (if frame
 324               (gnus-select-frame-set-input-focus frame)
 325             (pop-to-buffer buff t)))
 326         (error "The draft %s is under edit" file)))))
 327
 328 (provide 'gnus-draft)
 329
 330 ;;; gnus-draft.el ends here