cgit.sxemacs.org Git - gnus/blob - lisp/gnus-demon.el

   1 ;;; gnus-demon.el --- daemonic Gnus behaviour
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus-load)
  29 (require 'gnus-int)
  30 (require 'nnheader)
  31 (require 'gnus)
  32 (eval-and-compile
  33   (if (string-match "XEmacs" (emacs-version))
  34       (require 'itimer)
  35     (require 'timer)))
  36
  37 (defvar gnus-demon-handlers nil
  38   "Alist of daemonic handlers to be run at intervals.
  39 Each handler is a list on the form
  40
  41 \(FUNCTION TIME IDLE)
  42
  43 FUNCTION is the function to be called.
  44 TIME is the number of `gnus-demon-timestep's between each call.
  45 If nil, never call.  If t, call each `gnus-demon-timestep'.
  46 If IDLE is t, only call if Emacs has been idle for a while.  If IDLE
  47 is a number, only call when Emacs has been idle more than this number
  48 of `gnus-demon-timestep's.  If IDLE is nil, don't care about
  49 idleness.  If IDLE is a number and TIME is nil, then call once each
  50 time Emacs has been idle for IDLE `gnus-demon-timestep's.")
  51
  52 (defvar gnus-demon-timestep 60
  53   "*Number of seconds in each demon timestep.")
  54
  55 ;;; Internal variables.
  56
  57 (defvar gnus-demon-timer nil)
  58 (defvar gnus-demon-idle-has-been-called nil)
  59 (defvar gnus-demon-idle-time 0)
  60 (defvar gnus-demon-handler-state nil)
  61 (defvar gnus-demon-is-idle nil)
  62 (defvar gnus-demon-last-keys nil)
  63
  64 (eval-and-compile
  65   (autoload 'timezone-parse-date "timezone")
  66   (autoload 'timezone-make-arpa-date "timezone"))
  67
  68 ;;; Functions.
  69
  70 (defun gnus-demon-add-handler (function time idle)
  71   "Add the handler FUNCTION to be run at TIME and IDLE."
  72   ;; First remove any old handlers that use this function.
  73   (gnus-demon-remove-handler function)
  74   ;; Then add the new one.
  75   (push (list function time idle) gnus-demon-handlers)
  76   (gnus-demon-init))
  77
  78 (defun gnus-demon-remove-handler (function &optional no-init)
  79   "Remove the handler FUNCTION from the list of handlers."
  80   (setq gnus-demon-handlers
  81         (delq (assq function gnus-demon-handlers)
  82               gnus-demon-handlers))
  83   (unless no-init
  84     (gnus-demon-init)))
  85
  86 (defun gnus-demon-init ()
  87   "Initialize the Gnus daemon."
  88   (interactive)
  89   (gnus-demon-cancel)
  90   (if (null gnus-demon-handlers)
  91       ()                                ; Nothing to do.
  92     ;; Set up timer.
  93     (setq gnus-demon-timer
  94           (nnheader-run-at-time
  95            gnus-demon-timestep gnus-demon-timestep 'gnus-demon))
  96     ;; Reset control variables.
  97     (setq gnus-demon-handler-state
  98           (mapcar
  99            (lambda (handler)
 100              (list (car handler) (gnus-demon-time-to-step (nth 1 handler))
 101                    (nth 2 handler)))
 102            gnus-demon-handlers))
 103     (setq gnus-demon-idle-time 0)
 104     (setq gnus-demon-idle-has-been-called nil)
 105     (setq gnus-use-demon t)))
 106
 107 (gnus-add-shutdown 'gnus-demon-cancel 'gnus)
 108
 109 (defun gnus-demon-cancel ()
 110   "Cancel any Gnus daemons."
 111   (interactive)
 112   (when gnus-demon-timer
 113     (nnheader-cancel-timer gnus-demon-timer))
 114   (setq gnus-demon-timer nil
 115         gnus-use-demon nil)
 116   (condition-case ()
 117       (nnheader-cancel-function-timers 'gnus-demon)
 118     (error t)))
 119
 120 (defun gnus-demon-is-idle-p ()
 121   "Whether Emacs is idle or not."
 122   ;; We do this simply by comparing the 100 most recent keystrokes
 123   ;; with the ones we had last time.  If they are the same, one might
 124   ;; guess that Emacs is indeed idle.  This only makes sense if one
 125   ;; calls this function seldom -- like once a minute, which is what
 126   ;; we do here.
 127   (let ((keys (recent-keys)))
 128     (or (equal keys gnus-demon-last-keys)
 129         (progn
 130           (setq gnus-demon-last-keys keys)
 131           nil))))
 132
 133 (defun gnus-demon-time-to-step (time)
 134   "Find out how many seconds to TIME, which is on the form \"17:43\"."
 135   (if (not (stringp time))
 136       time
 137     (let* ((date (current-time-string))
 138            (dv (timezone-parse-date date))
 139            (tdate (timezone-make-arpa-date
 140                    (string-to-number (aref dv 0))
 141                    (string-to-number (aref dv 1))
 142                    (string-to-number (aref dv 2)) time
 143                    (or (aref dv 4) "UT")))
 144            (nseconds (gnus-time-minus
 145                       (gnus-encode-date tdate) (gnus-encode-date date))))
 146       (round
 147        (/ (if (< nseconds 0)
 148               (+ nseconds (* 60 60 24))
 149             nseconds)
 150           gnus-demon-timestep)))))
 151
 152 (defun gnus-demon ()
 153   "The Gnus daemon that takes care of running all Gnus handlers."
 154   ;; Increase or reset the time Emacs has been idle.
 155   (if (gnus-demon-is-idle-p)
 156       (incf gnus-demon-idle-time)
 157     (setq gnus-demon-idle-time 0)
 158     (setq gnus-demon-idle-has-been-called nil))
 159   ;; Then we go through all the handler and call those that are
 160   ;; sufficiently ripe.
 161   (let ((handlers gnus-demon-handler-state)
 162         handler time idle)
 163     (while handlers
 164       (setq handler (pop handlers))
 165       (cond
 166        ((numberp (setq time (nth 1 handler)))
 167         ;; These handlers use a regular timeout mechanism.  We decrease
 168         ;; the timer if it hasn't reached zero yet.
 169         (unless (zerop time)
 170           (setcar (nthcdr 1 handler) (decf time)))
 171         (and (zerop time)               ; If the timer now is zero...
 172              (or (not (setq idle (nth 2 handler))) ; Don't care about idle.
 173                  (and (numberp idle)    ; Numerical idle...
 174                       (< idle gnus-demon-idle-time)) ; Idle timed out.
 175                  gnus-demon-is-idle)    ; Or just need to be idle.
 176              ;; So we call the handler.
 177              (progn
 178                (funcall (car handler))
 179                ;; And reset the timer.
 180                (setcar (nthcdr 1 handler)
 181                        (gnus-demon-time-to-step
 182                         (nth 1 (assq (car handler) gnus-demon-handlers)))))))
 183        ;; These are only supposed to be called when Emacs is idle.
 184        ((null (setq idle (nth 2 handler)))
 185         ;; We do nothing.
 186         )
 187        ((not (numberp idle))
 188         ;; We want to call this handler each and every time that
 189         ;; Emacs is idle.
 190         (funcall (car handler)))
 191        (t
 192         ;; We want to call this handler only if Emacs has been idle
 193         ;; for a specified number of timesteps.
 194         (and (not (memq (car handler) gnus-demon-idle-has-been-called))
 195              (< idle gnus-demon-idle-time)
 196              (progn
 197                (funcall (car handler))
 198                ;; Make sure the handler won't be called once more in
 199                ;; this idle-cycle.
 200                (push (car handler) gnus-demon-idle-has-been-called))))))))
 201
 202 (defun gnus-demon-add-nocem ()
 203   "Add daemonic NoCeM handling to Gnus."
 204   (gnus-demon-add-handler 'gnus-demon-scan-nocem 60 t))
 205
 206 (defun gnus-demon-scan-nocem ()
 207   "Scan NoCeM groups for NoCeM messages."
 208   (gnus-nocem-scan-groups))
 209
 210 (defun gnus-demon-add-disconnection ()
 211   "Add daemonic server disconnection to Gnus."
 212   (gnus-demon-add-handler 'gnus-demon-close-connections nil 30))
 213
 214 (defun gnus-demon-close-connections ()
 215   (gnus-close-backends))
 216
 217 (defun gnus-demon-add-scanmail ()
 218   "Add daemonic scanning of mail from the mail backends."
 219   (gnus-demon-add-handler 'gnus-demon-scan-mail 120 60))
 220
 221 (defun gnus-demon-scan-mail ()
 222   (let ((servers gnus-opened-servers)
 223         server)
 224     (while (setq server (car (pop servers)))
 225       (and (gnus-check-backend-function 'request-scan (car server))
 226            (or (gnus-server-opened server)
 227                (gnus-open-server server))
 228            (gnus-request-scan nil server)))))
 229
 230 (defun gnus-demon-add-rescan ()
 231   "Add daemonic scanning of new articles from all backends."
 232   (gnus-demon-add-handler 'gnus-demon-scan-news 120 60))
 233
 234 (defun gnus-demon-scan-news ()
 235   (when (gnus-alive-p)
 236     (save-excursion
 237       (set-buffer gnus-group-buffer)
 238       (gnus-group-get-new-news))))
 239
 240 (provide 'gnus-demon)
 241
 242 ;;; gnus-demon.el ends here